configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.31
  32 LIBDRM_INTEL_REQUIRED=2.4.37
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  35 DRI2PROTO_REQUIRED=2.6
  36 GLPROTO_REQUIRED=1.4.14
  37 LIBDRM_XORG_REQUIRED=2.4.24
  38 LIBKMS_XORG_REQUIRED=1.0.0
  39
  40 dnl Check for progs
  41 AC_PROG_CPP
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AM_PROG_AS
  46 AC_CHECK_PROGS([MAKE], [gmake make])
  47 AC_CHECK_PROGS([PYTHON2], [python2 python])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50 AC_PATH_PROG([MKDEP], [makedepend])
  51
  52 if test "x$MKDEP" = "x"; then
  53     AC_MSG_ERROR([makedepend is required to build Mesa])
  54 fi
  55
  56 AC_PROG_YACC
  57 AC_PATH_PROG([YACC_INST], $YACC)
  58 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  59     if test -z "$YACC_INST"; then
  60         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  61     fi
  62 fi
  63 AC_PROG_LEX
  64
  65 AC_PATH_PROG([PERL], [perl])
  66
  67 AC_CHECK_PROG(INDENT, indent, indent, cat)
  68 if test "x$INDENT" != "xcat"; then
  69     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  70 fi
  71
  72 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  73 dnl configuration in that case.
  74 AC_PROG_INSTALL
  75 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122
 123 MKDEP_OPTIONS=-fdepend
 124 dnl Ask gcc where it's keeping its secret headers
 125 if test "x$GCC" = xyes; then
 126     for dir in include include-fixed; do
 127         GCC_INCLUDES=`$CC -print-file-name=$dir`
 128         if test "x$GCC_INCLUDES" != x && \
 129            test "$GCC_INCLUDES" != "$dir" && \
 130            test -d "$GCC_INCLUDES"; then
 131             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 132         fi
 133     done
 134 fi
 135 AC_SUBST([MKDEP_OPTIONS])
 136
 137 dnl Make sure the pkg-config macros are defined
 138 m4_ifndef([PKG_PROG_PKG_CONFIG],
 139     [m4_fatal([Could not locate the pkg-config autoconf macros.
 140   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 141   are in a different location, try setting the environment variable
 142   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 143 PKG_PROG_PKG_CONFIG()
 144
 145 dnl LIB_DIR - library basename
 146 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 147 AC_SUBST([LIB_DIR])
 148
 149 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 150 _SAVE_LDFLAGS="$LDFLAGS"
 151 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 152 AC_SUBST([EXTRA_LIB_PATH])
 153
 154 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 155 _SAVE_CPPFLAGS="$CPPFLAGS"
 156 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 157 AC_SUBST([X11_INCLUDES])
 158
 159 dnl Compiler macros
 160 DEFINES=""
 161 AC_SUBST([DEFINES])
 162 case "$host_os" in
 163 linux*|*-gnu*|gnu*)
 164     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 165     ;;
 166 solaris*)
 167     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 168     ;;
 169 cygwin*)
 170     DEFINES="$DEFINES -DPTHREADS"
 171     ;;
 172 esac
 173
 174 dnl Add flags for gcc and g++
 175 if test "x$GCC" = xyes; then
 176     CFLAGS="$CFLAGS -Wall -std=c99"
 177
 178     # Enable -Werror=implicit-function-declaration and
 179     # -Werror=missing-prototypes, if available, or otherwise, just
 180     # -Wmissing-prototypes.  This is particularly useful to avoid
 181     # generating a loadable driver module that has undefined symbols.
 182     save_CFLAGS="$CFLAGS"
 183     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 184     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 185     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 187                    AC_MSG_RESULT([yes]),
 188                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 189                     AC_MSG_RESULT([no])]);
 190
 191     # Enable -fvisibility=hidden if using a gcc that supports it
 192     save_CFLAGS="$CFLAGS"
 193     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 194     VISIBILITY_CFLAGS="-fvisibility=hidden"
 195     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 196     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 197                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 198
 199     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 200     CFLAGS=$save_CFLAGS
 201
 202     # Work around aliasing bugs - developers should comment this out
 203     CFLAGS="$CFLAGS -fno-strict-aliasing"
 204
 205     # gcc's builtin memcmp is slower than glibc's
 206     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 207     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 208 fi
 209 if test "x$GXX" = xyes; then
 210     CXXFLAGS="$CXXFLAGS -Wall"
 211
 212     # Enable -fvisibility=hidden if using a gcc that supports it
 213     save_CXXFLAGS="$CXXFLAGS"
 214     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 215     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 216     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 217     AC_LANG_PUSH([C++])
 218     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 219                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 220     AC_LANG_POP([C++])
 221
 222     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 223     CXXFLAGS=$save_CXXFLAGS
 224
 225     # Work around aliasing bugs - developers should comment this out
 226     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 227
 228     # gcc's builtin memcmp is slower than glibc's
 229     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 230     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 231
 232     # Silence C++11 warnings that we don't care about.
 233     CXXFLAGS="$CXXFLAGS -Wno-narrowing"
 234 fi
 235
 236 dnl even if the compiler appears to support it, using visibility attributes isn't
 237 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 238 case "$host_os" in
 239 cygwin*)
 240     VISIBILITY_CFLAGS=""
 241     VISIBILITY_CXXFLAGS=""
 242     ;;
 243 esac
 244
 245 AC_SUBST([VISIBILITY_CFLAGS])
 246 AC_SUBST([VISIBILITY_CXXFLAGS])
 247
 248 dnl
 249 dnl Hacks to enable 32 or 64 bit build
 250 dnl
 251 AC_ARG_ENABLE([32-bit],
 252     [AS_HELP_STRING([--enable-32-bit],
 253         [build 32-bit libraries @<:@default=auto@:>@])],
 254     [enable_32bit="$enableval"],
 255     [enable_32bit=auto]
 256 )
 257 if test "x$enable_32bit" = xyes; then
 258     if test "x$GCC" = xyes; then
 259         CFLAGS="$CFLAGS -m32"
 260         CCASFLAGS="$CCASFLAGS -m32"
 261     fi
 262     if test "x$GXX" = xyes; then
 263         CXXFLAGS="$CXXFLAGS -m32"
 264     fi
 265 fi
 266 AC_ARG_ENABLE([64-bit],
 267     [AS_HELP_STRING([--enable-64-bit],
 268         [build 64-bit libraries @<:@default=auto@:>@])],
 269     [enable_64bit="$enableval"],
 270     [enable_64bit=auto]
 271 )
 272 if test "x$enable_64bit" = xyes; then
 273     if test "x$GCC" = xyes; then
 274         CFLAGS="$CFLAGS -m64"
 275     fi
 276     if test "x$GXX" = xyes; then
 277         CXXFLAGS="$CXXFLAGS -m64"
 278     fi
 279 fi
 280
 281 dnl Can't have static and shared libraries, default to static if user
 282 dnl explicitly requested. If both disabled, set to static since shared
 283 dnl was explicitly requested.
 284 case "x$enable_static$enable_shared" in
 285 xyesyes )
 286     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 287     enable_shared=no
 288     ;;
 289 xnono )
 290     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 291     enable_static=yes
 292     ;;
 293 esac
 294
 295 dnl
 296 dnl mklib options
 297 dnl
 298 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 299 if test "$enable_static" = yes; then
 300     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 301 fi
 302 AC_SUBST([MKLIB_OPTIONS])
 303
 304 dnl
 305 dnl other compiler options
 306 dnl
 307 AC_ARG_ENABLE([debug],
 308     [AS_HELP_STRING([--enable-debug],
 309         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 310     [enable_debug="$enableval"],
 311     [enable_debug=no]
 312 )
 313 if test "x$enable_debug" = xyes; then
 314     DEFINES="$DEFINES -DDEBUG"
 315     if test "x$GCC" = xyes; then
 316         CFLAGS="$CFLAGS -g"
 317     fi
 318     if test "x$GXX" = xyes; then
 319         CXXFLAGS="$CXXFLAGS -g"
 320     fi
 321 fi
 322
 323 dnl
 324 dnl library names
 325 dnl
 326 LIB_PREFIX_GLOB='lib'
 327 LIB_VERSION_SEPARATOR='.'
 328 if test "$enable_static" = yes; then
 329     LIB_EXTENSION='a'
 330 else
 331     case "$host_os" in
 332     darwin* )
 333         LIB_EXTENSION='dylib' ;;
 334     cygwin* )
 335         dnl prefix can be 'cyg' or 'lib'
 336         LIB_PREFIX_GLOB='???'
 337         LIB_VERSION_SEPARATOR='-'
 338         LIB_EXTENSION='dll' ;;
 339     aix* )
 340         LIB_EXTENSION='a' ;;
 341     * )
 342         LIB_EXTENSION='so' ;;
 343     esac
 344 fi
 345 AC_ARG_WITH([gl-lib-name],
 346   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 347     [specify GL library name @<:@default=GL@:>@])],
 348   [GL_LIB=$withval],
 349   [GL_LIB=GL])
 350 AC_ARG_WITH([glu-lib-name],
 351   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 352     [specify GLU library name @<:@default=GLU@:>@])],
 353   [GLU_LIB=$withval],
 354   [GLU_LIB=GLU])
 355 AC_ARG_WITH([osmesa-lib-name],
 356   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 357     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 358   [OSMESA_LIB=$withval],
 359   [OSMESA_LIB=OSMesa])
 360 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 361 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 362 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 363
 364 dnl
 365 dnl Mangled Mesa support
 366 dnl
 367 AC_ARG_ENABLE([mangling],
 368   [AS_HELP_STRING([--enable-mangling],
 369     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 370   [enable_mangling="${enableval}"],
 371   [enable_mangling=no]
 372 )
 373 if test "x${enable_mangling}" = "xyes" ; then
 374   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 375   GL_LIB="Mangled${GL_LIB}"
 376   GLU_LIB="Mangled${GLU_LIB}"
 377   OSMESA_LIB="Mangled${OSMESA_LIB}"
 378 fi
 379 AC_SUBST([GL_LIB])
 380 AC_SUBST([GLU_LIB])
 381 AC_SUBST([OSMESA_LIB])
 382
 383 dnl
 384 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 385 dnl
 386 AC_ARG_ENABLE([texture-float],
 387     [AS_HELP_STRING([--enable-texture-float],
 388         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 389     [enable_texture_float="$enableval"],
 390     [enable_texture_float=no]
 391 )
 392 if test "x$enable_texture_float" = xyes; then
 393     AC_MSG_WARN([Floating-point textures enabled.])
 394     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 395     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 396 fi
 397
 398 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 399 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 400 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 401 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 402 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 403 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 404 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 405 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 406
 407 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 411 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 412 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 413 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 414 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 415
 416 AC_SUBST([GL_LIB_NAME])
 417 AC_SUBST([GLU_LIB_NAME])
 418 AC_SUBST([OSMESA_LIB_NAME])
 419 AC_SUBST([EGL_LIB_NAME])
 420 AC_SUBST([GLESv1_CM_LIB_NAME])
 421 AC_SUBST([GLESv2_LIB_NAME])
 422 AC_SUBST([VG_LIB_NAME])
 423 AC_SUBST([GLAPI_LIB_NAME])
 424
 425 AC_SUBST([GL_LIB_GLOB])
 426 AC_SUBST([GLU_LIB_GLOB])
 427 AC_SUBST([EGL_LIB_GLOB])
 428 AC_SUBST([GLESv1_CM_LIB_GLOB])
 429 AC_SUBST([GLESv2_LIB_GLOB])
 430 AC_SUBST([VG_LIB_GLOB])
 431 AC_SUBST([GLAPI_LIB_GLOB])
 432
 433 dnl
 434 dnl Arch/platform-specific settings
 435 dnl
 436 AC_ARG_ENABLE([asm],
 437     [AS_HELP_STRING([--disable-asm],
 438         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 439     [enable_asm="$enableval"],
 440     [enable_asm=yes]
 441 )
 442 asm_arch=""
 443 MESA_ASM_FILES=""
 444 AC_MSG_CHECKING([whether to enable assembly])
 445 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 446 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 447 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 448     case "$host_cpu" in
 449     i?86 | x86_64)
 450         enable_asm=no
 451         AC_MSG_RESULT([no, cross compiling])
 452         ;;
 453     esac
 454 fi
 455 # check for supported arches
 456 if test "x$enable_asm" = xyes; then
 457     case "$host_cpu" in
 458     i?86)
 459         case "$host_os" in
 460         linux* | *freebsd* | dragonfly* | *netbsd*)
 461             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 462             ;;
 463         esac
 464         ;;
 465     x86_64)
 466         case "$host_os" in
 467         linux* | *freebsd* | dragonfly* | *netbsd*)
 468             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 469             ;;
 470         esac
 471         ;;
 472     sparc*)
 473         case "$host_os" in
 474         linux*)
 475             asm_arch=sparc
 476             ;;
 477         esac
 478         ;;
 479     esac
 480
 481     case "$asm_arch" in
 482     x86)
 483         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 484         MESA_ASM_FILES='$(X86_FILES)'
 485         AC_MSG_RESULT([yes, x86])
 486         ;;
 487     x86_64)
 488         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 489         MESA_ASM_FILES='$(X86_64_FILES)'
 490         AC_MSG_RESULT([yes, x86_64])
 491         ;;
 492     sparc)
 493         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 494         MESA_ASM_FILES='$(SPARC_FILES)'
 495         AC_MSG_RESULT([yes, sparc])
 496         ;;
 497     *)
 498         AC_MSG_RESULT([no, platform not supported])
 499         ;;
 500     esac
 501 fi
 502 AC_SUBST([MESA_ASM_FILES])
 503
 504 dnl PIC code macro
 505 MESA_PIC_FLAGS
 506
 507 dnl Check to see if dlopen is in default libraries (like Solaris, which
 508 dnl has it in libc), or if libdl is needed to get it.
 509 AC_CHECK_FUNC([dlopen], [],
 510     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 511 AC_SUBST([DLOPEN_LIBS])
 512
 513 dnl See if posix_memalign is available
 514 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 515
 516 dnl SELinux awareness.
 517 AC_ARG_ENABLE([selinux],
 518     [AS_HELP_STRING([--enable-selinux],
 519         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 520     [MESA_SELINUX="$enableval"],
 521     [MESA_SELINUX=no])
 522 if test "x$enable_selinux" = "xyes"; then
 523     AC_CHECK_HEADER([selinux/selinux.h],[],
 524                     [AC_MSG_ERROR([SELinux headers not found])])
 525     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 526                  [AC_MSG_ERROR([SELinux library not found])])
 527     SELINUX_LIBS="-lselinux"
 528     DEFINES="$DEFINES -DMESA_SELINUX"
 529 fi
 530
 531 dnl Options for APIs
 532 AC_ARG_ENABLE([opengl],
 533     [AS_HELP_STRING([--disable-opengl],
 534         [disable support for standard OpenGL API @<:@default=no@:>@])],
 535     [enable_opengl="$enableval"],
 536     [enable_opengl=yes])
 537 AC_ARG_ENABLE([gles1],
 538     [AS_HELP_STRING([--enable-gles1],
 539         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 540     [enable_gles1="$enableval"],
 541     [enable_gles1=no])
 542 AC_ARG_ENABLE([gles2],
 543     [AS_HELP_STRING([--enable-gles2],
 544         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 545     [enable_gles2="$enableval"],
 546     [enable_gles2=no])
 547 AC_ARG_ENABLE([openvg],
 548     [AS_HELP_STRING([--enable-openvg],
 549         [enable support for OpenVG API @<:@default=no@:>@])],
 550     [enable_openvg="$enableval"],
 551     [enable_openvg=no])
 552
 553 AC_ARG_ENABLE([dri],
 554     [AS_HELP_STRING([--enable-dri],
 555         [enable DRI modules @<:@default=auto@:>@])],
 556     [enable_dri="$enableval"],
 557     [enable_dri=auto])
 558 AC_ARG_ENABLE([glx],
 559     [AS_HELP_STRING([--enable-glx],
 560         [enable GLX library @<:@default=auto@:>@])],
 561     [enable_glx="$enableval"],
 562     [enable_glx=auto])
 563 AC_ARG_ENABLE([osmesa],
 564     [AS_HELP_STRING([--enable-osmesa],
 565         [enable OSMesa library @<:@default=auto@:>@])],
 566     [enable_osmesa="$enableval"],
 567     [enable_osmesa=auto])
 568 AC_ARG_ENABLE([egl],
 569     [AS_HELP_STRING([--disable-egl],
 570         [disable EGL library @<:@default=enabled@:>@])],
 571     [enable_egl="$enableval"],
 572     [enable_egl=yes])
 573
 574 AC_ARG_ENABLE([xorg],
 575     [AS_HELP_STRING([--enable-xorg],
 576         [enable support for X.Org DDX API @<:@default=no@:>@])],
 577     [enable_xorg="$enableval"],
 578     [enable_xorg=no])
 579 AC_ARG_ENABLE([xa],
 580     [AS_HELP_STRING([--enable-xa],
 581         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 582     [enable_xa="$enableval"],
 583     [enable_xa=no])
 584 AC_ARG_ENABLE([d3d1x],
 585     [AS_HELP_STRING([--enable-d3d1x],
 586         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 587     [enable_d3d1x="$enableval"],
 588     [enable_d3d1x=no])
 589 AC_ARG_ENABLE([gbm],
 590    [AS_HELP_STRING([--enable-gbm],
 591          [enable gbm library @<:@default=auto@:>@])],
 592    [enable_gbm="$enableval"],
 593    [enable_gbm=auto])
 594
 595 AC_ARG_ENABLE([xvmc],
 596    [AS_HELP_STRING([--enable-xvmc],
 597          [enable xvmc library @<:@default=auto@:>@])],
 598    [enable_xvmc="$enableval"],
 599    [enable_xvmc=auto])
 600 AC_ARG_ENABLE([vdpau],
 601    [AS_HELP_STRING([--enable-vdpau],
 602          [enable vdpau library @<:@default=auto@:>@])],
 603    [enable_vdpau="$enableval"],
 604    [enable_vdpau=auto])
 605 AC_ARG_ENABLE([va],
 606    [AS_HELP_STRING([--enable-va],
 607          [enable va library @<:@default=auto@:>@])],
 608    [enable_va="$enableval"],
 609    [enable_va=auto])
 610 AC_ARG_ENABLE([opencl],
 611    [AS_HELP_STRING([--enable-opencl],
 612          [enable OpenCL library @<:@default=no@:>@])],
 613    [enable_opencl="$enableval"],
 614    [enable_opencl=no])
 615 AC_ARG_ENABLE([xlib_glx],
 616     [AS_HELP_STRING([--enable-xlib-glx],
 617         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 618     [enable_xlib_glx="$enableval"],
 619     [enable_xlib_glx=auto])
 620 AC_ARG_ENABLE([gallium_egl],
 621     [AS_HELP_STRING([--enable-gallium-egl],
 622         [enable optional EGL state tracker (not required
 623          for EGL support in Gallium with OpenGL and OpenGL ES)
 624          @<:@default=disable@:>@])],
 625     [enable_gallium_egl="$enableval"],
 626     [enable_gallium_egl=no])
 627 AC_ARG_ENABLE([gallium_gbm],
 628     [AS_HELP_STRING([--enable-gallium-gbm],
 629         [enable optional gbm state tracker (not required for
 630          gbm support in Gallium)
 631          @<:@default=auto@:>@])],
 632     [enable_gallium_gbm="$enableval"],
 633     [enable_gallium_gbm=auto])
 634
 635 AC_ARG_ENABLE([r600-llvm-compiler],
 636     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 637         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 638     [enable_r600_llvm="$enableval"],
 639     [enable_r600_llvm=no])
 640
 641 AC_ARG_ENABLE([gallium_tests],
 642     [AS_HELP_STRING([--enable-gallium-tests],
 643         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 644     [enable_gallium_tests="$enableval"],
 645     [enable_gallium_tests=no])
 646
 647 # Option for Gallium drivers
 648 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 649
 650 AC_ARG_WITH([gallium-drivers],
 651     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 652         [comma delimited Gallium drivers list, e.g.
 653         "i915,nouveau,r300,r600,svga,swrast"
 654         @<:@default=r300,r600,swrast@:>@])],
 655     [with_gallium_drivers="$withval"],
 656     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 657
 658 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 659 # here so that the script doesn't choke on an unknown driver name later.
 660 case "$with_gallium_drivers" in
 661     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 662     no) with_gallium_drivers='' ;;
 663 esac
 664
 665 if test "x$enable_opengl" = xno -a \
 666         "x$enable_gles1" = xno -a \
 667         "x$enable_gles2" = xno -a \
 668         "x$enable_openvg" = xno -a \
 669         "x$enable_xorg" = xno -a \
 670         "x$enable_xa" = xno -a \
 671         "x$enable_d3d1x" = xno -a \
 672         "x$enable_xvmc" = xno -a \
 673         "x$enable_vdpau" = xno -a \
 674         "x$enable_va" = xno -a \
 675         "x$enable_opencl" = xno; then
 676     AC_MSG_ERROR([at least one API should be enabled])
 677 fi
 678
 679 API_DEFINES=""
 680 if test "x$enable_opengl" = xno; then
 681     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 682 else
 683     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 684 fi
 685 if test "x$enable_gles1" = xyes; then
 686     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 687 fi
 688 if test "x$enable_gles2" = xyes; then
 689     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 690 fi
 691 AC_SUBST([API_DEFINES])
 692
 693 AC_ARG_ENABLE([shared-glapi],
 694     [AS_HELP_STRING([--enable-shared-glapi],
 695         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 696     [enable_shared_glapi="$enableval"],
 697     [enable_shared_glapi=yes])
 698
 699 SHARED_GLAPI="0"
 700 if test "x$enable_shared_glapi" = xyes; then
 701     SHARED_GLAPI="1"
 702     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 703     # the remap table)
 704     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 705     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 706 fi
 707 AC_SUBST([SHARED_GLAPI])
 708 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 709
 710 dnl
 711 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 712 dnl More later: fbdev, ...
 713 dnl
 714 default_driver="xlib"
 715
 716 case "$host_os" in
 717 linux*)
 718     default_driver="dri"
 719     ;;
 720 *freebsd* | dragonfly* | *netbsd*)
 721     case "$host_cpu" in
 722     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 723     esac
 724     ;;
 725 esac
 726
 727 if test "x$enable_opengl" = xno; then
 728     default_driver="no"
 729 fi
 730
 731 AC_ARG_WITH([driver],
 732     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 733     [mesa_driver="$withval"],
 734     [mesa_driver=auto])
 735 dnl Check for valid option
 736 case "x$mesa_driver" in
 737 xxlib|xdri|xosmesa|xno)
 738     if test "x$enable_dri" != xauto -o \
 739             "x$enable_glx" != xauto -o \
 740             "x$enable_osmesa" != xauto -o \
 741             "x$enable_xlib_glx" != xauto; then
 742         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 743     fi
 744     ;;
 745 xauto)
 746     mesa_driver="$default_driver"
 747     ;;
 748 *)
 749     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 750     ;;
 751 esac
 752
 753 # map $mesa_driver to APIs
 754 if test "x$enable_dri" = xauto; then
 755     case "x$mesa_driver" in
 756     xdri) enable_dri=yes ;;
 757     *)    enable_dri=no ;;
 758     esac
 759 fi
 760
 761 if test "x$enable_glx" = xauto; then
 762     case "x$mesa_driver" in
 763     xdri|xxlib) enable_glx=yes ;;
 764     *)          enable_glx=no ;;
 765     esac
 766 fi
 767
 768 if test "x$enable_osmesa" = xauto; then
 769     case "x$mesa_driver" in
 770     xxlib|xosmesa) enable_osmesa=yes ;;
 771     *)             enable_osmesa=no ;;
 772     esac
 773 fi
 774
 775 if test "x$enable_xlib_glx" = xauto; then
 776     case "x$mesa_driver" in
 777     xxlib) enable_xlib_glx=yes ;;
 778     *)     enable_xlib_glx=no ;;
 779     esac
 780 fi
 781
 782 if test "x$enable_glx" = xno; then
 783     enable_xlib_glx=no
 784 fi
 785
 786 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 787
 788 dnl
 789 dnl Driver specific build directories
 790 dnl
 791
 792 dnl this variable will be prepended to SRC_DIRS and is not exported
 793 CORE_DIRS=""
 794
 795 SRC_DIRS="gtest"
 796 GLU_DIRS="sgi"
 797 GALLIUM_DIRS="auxiliary drivers state_trackers"
 798 GALLIUM_TARGET_DIRS=""
 799 GALLIUM_WINSYS_DIRS="sw"
 800 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 801 GALLIUM_STATE_TRACKERS_DIRS=""
 802
 803 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 804 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 805 x*yes*)
 806     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 807     ;;
 808 esac
 809
 810 # build glapi if OpenGL is enabled
 811 if test "x$enable_opengl" = xyes; then
 812     CORE_DIRS="$CORE_DIRS mapi/glapi"
 813 fi
 814
 815 # build es1api if OpenGL ES 1.x is enabled
 816 if test "x$enable_gles1" = xyes; then
 817     CORE_DIRS="$CORE_DIRS mapi/es1api"
 818 fi
 819
 820 # build es2api if OpenGL ES 2.x is enabled
 821 if test "x$enable_gles2" = xyes; then
 822     CORE_DIRS="$CORE_DIRS mapi/es2api"
 823 fi
 824
 825 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 826 case "x$enable_opengl$enable_gles1$enable_gles2" in
 827 x*yes*)
 828     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 829     ;;
 830 esac
 831
 832 case "x$enable_glx$enable_xlib_glx" in
 833 xyesyes)
 834     DRIVER_DIRS="$DRIVER_DIRS x11"
 835     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 836     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 837     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 838     HAVE_WINSYS_XLIB="yes"
 839     ;;
 840 xyesno)
 841     # DRI-based GLX
 842     SRC_DIRS="$SRC_DIRS glx"
 843     ;;
 844 esac
 845
 846 if test "x$enable_dri" = xyes; then
 847     DRIVER_DIRS="$DRIVER_DIRS dri"
 848
 849     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 850     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 851     HAVE_ST_DRI="yes"
 852 fi
 853
 854 if test "x$enable_osmesa" = xyes; then
 855     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 856 fi
 857
 858 AC_SUBST([SRC_DIRS])
 859 AC_SUBST([GLU_DIRS])
 860 AC_SUBST([DRIVER_DIRS])
 861 AC_SUBST([GALLIUM_DIRS])
 862 AC_SUBST([GALLIUM_TARGET_DIRS])
 863 AC_SUBST([GALLIUM_WINSYS_DIRS])
 864 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 865 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 866 AC_SUBST([MESA_LLVM])
 867
 868 # Check for libdrm
 869 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 870                   [have_libdrm=yes], [have_libdrm=no])
 871
 872 if test "x$enable_dri" = xyes; then
 873     # DRI must be shared, I think
 874     if test "$enable_static" = yes; then
 875         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 876     fi
 877
 878     # not a hard requirement as swrast does not depend on it
 879     if test "x$have_libdrm" = xyes; then
 880         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 881     fi
 882 fi
 883
 884 dnl
 885 dnl Find out if X is available. The variable have_x is set if libX11 is
 886 dnl found to mimic AC_PATH_XTRA.
 887 dnl
 888 if test -n "$PKG_CONFIG"; then
 889     AC_MSG_CHECKING([pkg-config files for X11 are available])
 890     PKG_CHECK_EXISTS([x11],[
 891         x11_pkgconfig=yes
 892         have_x=yes
 893         ],[
 894         x11_pkgconfig=no
 895     ])
 896     AC_MSG_RESULT([$x11_pkgconfig])
 897 else
 898     x11_pkgconfig=no
 899 fi
 900 dnl Use the autoconf macro if no pkg-config files
 901 if test "$x11_pkgconfig" = yes; then
 902     PKG_CHECK_MODULES([X11], [x11])
 903 else
 904     AC_PATH_XTRA
 905     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 906     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 907     AC_SUBST([X11_CFLAGS])
 908     AC_SUBST([X11_LIBS])
 909 fi
 910
 911 dnl Try to tell the user that the --x-* options are only used when
 912 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 913 m4_divert_once([HELP_BEGIN],
 914 [These options are only used when the X libraries cannot be found by the
 915 pkg-config utility.])
 916
 917 dnl We need X for xlib and dri, so bomb now if it's not found
 918 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 919     AC_MSG_ERROR([X11 development libraries needed for GLX])
 920 fi
 921
 922 if test "x$enable_glx" = xyes; then
 923     DEFINES="$DEFINES -DUSE_XCB"
 924 fi
 925
 926 dnl Direct rendering or just indirect rendering
 927 case "$host_os" in
 928 gnu*)
 929     dnl Disable by default on GNU/Hurd
 930     driglx_direct_default="no"
 931     ;;
 932 cygwin*)
 933     dnl Disable by default on cygwin
 934     driglx_direct_default="no"
 935     ;;
 936 *)
 937     driglx_direct_default="yes"
 938     ;;
 939 esac
 940 AC_ARG_ENABLE([driglx-direct],
 941     [AS_HELP_STRING([--disable-driglx-direct],
 942         [enable direct rendering in GLX and EGL for DRI \
 943             @<:@default=auto@:>@])],
 944     [driglx_direct="$enableval"],
 945     [driglx_direct="$driglx_direct_default"])
 946
 947 dnl
 948 dnl libGL configuration per driver
 949 dnl
 950 case "x$enable_glx$enable_xlib_glx" in
 951 xyesyes)
 952     # Xlib-based GLX
 953     if test "$x11_pkgconfig" = yes; then
 954         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 955         GL_PC_REQ_PRIV="x11 xext"
 956         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 957         GL_LIB_DEPS="$XLIBGL_LIBS"
 958     else
 959         # should check these...
 960         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 961         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 962         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 963         GL_PC_CFLAGS="$X11_INCLUDES"
 964     fi
 965     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 966     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 967     ;;
 968 xyesno)
 969     # DRI-based GLX
 970     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 971     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 972     if test x"$driglx_direct" = xyes; then
 973         if test "x$have_libdrm" != xyes; then
 974             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 975         fi
 976         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 977         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 978     fi
 979
 980     # find the DRI deps for libGL
 981     if test "$x11_pkgconfig" = yes; then
 982         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 983
 984         # add xf86vidmode if available
 985         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 986         if test "$HAVE_XF86VIDMODE" = yes ; then
 987             dri_modules="$dri_modules xxf86vm"
 988         fi
 989
 990         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 991         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 992         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 993         GL_LIB_DEPS="$DRIGL_LIBS"
 994     else
 995         # should check these...
 996         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 997         if test "x$HAVE_XF86VIDMODE" == xyes; then
 998            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 999         else
1000            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1001         fi
1002         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1003         GL_PC_CFLAGS="$X11_INCLUDES"
1004
1005         # XCB can only be used from pkg-config
1006         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx >= 1.8.1])
1007         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1008         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1009         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1010     fi
1011
1012     # need DRM libs, -lpthread, etc.
1013     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1014     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1015     ;;
1016 esac
1017
1018 # This is outside the case (above) so that it is invoked even for non-GLX
1019 # builds.
1020 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1021
1022 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1023 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1024 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1025 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1026
1027 AC_SUBST([GL_LIB_DEPS])
1028 AC_SUBST([GL_PC_REQ_PRIV])
1029 AC_SUBST([GL_PC_LIB_PRIV])
1030 AC_SUBST([GL_PC_CFLAGS])
1031 AC_SUBST([DRI_PC_REQ_PRIV])
1032 AC_SUBST([GLESv1_CM_LIB_DEPS])
1033 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1034 AC_SUBST([GLESv2_LIB_DEPS])
1035 AC_SUBST([GLESv2_PC_LIB_PRIV])
1036
1037 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1038 AC_SUBST([GLAPI_LIB_DEPS])
1039
1040
1041 dnl dri libraries are linking with mesa
1042 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.la'
1043 GALLIUM_DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1044
1045 dnl ... or dricore?
1046 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1047     DRI_LIB_DEPS="\$(TOP)/src/mesa/libdricore/libdricore${VERSION}.la"
1048     GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
1049     HAVE_DRICORE=yes
1050 fi
1051 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
1052
1053 AC_SUBST([HAVE_XF86VIDMODE])
1054
1055 dnl
1056 dnl More GLX setup
1057 dnl
1058 case "x$enable_glx$enable_xlib_glx" in
1059 xyesyes)
1060     DEFINES="$DEFINES -DUSE_XSHM"
1061     ;;
1062 xyesno)
1063     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1064     if test "x$driglx_direct" = xyes; then
1065         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1066     fi
1067     ;;
1068 esac
1069
1070 dnl
1071 dnl TLS detection
1072 dnl
1073
1074 AC_ARG_ENABLE([glx-tls],
1075     [AS_HELP_STRING([--enable-glx-tls],
1076         [enable TLS support in GLX @<:@default=disabled@:>@])],
1077     [GLX_USE_TLS="$enableval"],
1078     [GLX_USE_TLS=no])
1079 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1080
1081 AS_IF([test "x$GLX_USE_TLS" = xyes],
1082       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1083
1084 dnl
1085 dnl More DRI setup
1086 dnl
1087 dnl Directory for DRI drivers
1088 AC_ARG_WITH([dri-driverdir],
1089     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1090         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1091     [DRI_DRIVER_INSTALL_DIR="$withval"],
1092     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1093 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1094 dnl Extra search path for DRI drivers
1095 AC_ARG_WITH([dri-searchpath],
1096     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1097         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1098     [DRI_DRIVER_SEARCH_DIR="$withval"],
1099     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1100 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1101 dnl Which drivers to build - default is chosen by platform
1102 AC_ARG_WITH([dri-drivers],
1103     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1104         [comma delimited DRI drivers list, e.g.
1105         "swrast,i965,radeon" @<:@default=auto@:>@])],
1106     [with_dri_drivers="$withval"],
1107     [with_dri_drivers=yes])
1108 if test "x$with_dri_drivers" = x; then
1109     with_dri_drivers=no
1110 fi
1111
1112 dnl If $with_dri_drivers is yes, directories will be added through
1113 dnl platform checks
1114 DRI_DIRS=""
1115 case "$with_dri_drivers" in
1116 no) ;;
1117 yes)
1118     # classic DRI drivers require FEATURE_GL to build
1119     if test "x$enable_opengl" = xyes; then
1120         DRI_DIRS="yes"
1121     fi
1122     ;;
1123 *)
1124     # verify the requested driver directories exist
1125     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1126     for driver in $dri_drivers; do
1127         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1128             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1129     done
1130     DRI_DIRS="$dri_drivers"
1131     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1132         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1133     fi
1134     ;;
1135 esac
1136
1137 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1138 if test "x$enable_dri" = xyes; then
1139     # Platform specific settings and drivers to build
1140     case "$host_os" in
1141     linux*)
1142         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1143         DEFINES="$DEFINES -DHAVE_ALIAS"
1144
1145         case "$host_cpu" in
1146         x86_64)
1147             if test "x$DRI_DIRS" = "xyes"; then
1148                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1149             fi
1150             ;;
1151         powerpc*)
1152             # Build only the drivers for cards that exist on PowerPC.
1153             if test "x$DRI_DIRS" = "xyes"; then
1154                 DRI_DIRS="r200 radeon swrast"
1155             fi
1156             ;;
1157         sparc*)
1158             # Build only the drivers for cards that exist on sparc
1159             if test "x$DRI_DIRS" = "xyes"; then
1160                 DRI_DIRS="r200 radeon swrast"
1161             fi
1162             ;;
1163         esac
1164         ;;
1165     freebsd* | dragonfly* | *netbsd*)
1166         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1167         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1168
1169         if test "x$DRI_DIRS" = "xyes"; then
1170             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1171         fi
1172         ;;
1173     gnu*)
1174         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1175         DEFINES="$DEFINES -DHAVE_ALIAS"
1176         ;;
1177     solaris*)
1178         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1179         ;;
1180     cygwin*)
1181         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1182         if test "x$DRI_DIRS" = "xyes"; then
1183             DRI_DIRS="swrast"
1184         fi
1185         ;;
1186     esac
1187
1188     # default drivers
1189     if test "x$DRI_DIRS" = "xyes"; then
1190         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1191     fi
1192
1193     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1194
1195     # Check for expat
1196     if test "x$enable_dri" = xyes; then
1197         EXPAT_INCLUDES=""
1198         EXPAT_LIB=-lexpat
1199         AC_ARG_WITH([expat],
1200             [AS_HELP_STRING([--with-expat=DIR],
1201                 [expat install directory])],[
1202             EXPAT_INCLUDES="-I$withval/include"
1203             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1204             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1205             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1206             ])
1207         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1208         save_LIBS="$LIBS"
1209         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1210             [AC_MSG_ERROR([Expat required for DRI.])])
1211         LIBS="$save_LIBS"
1212     fi
1213
1214     # if we are building any dri driver other than swrast ...
1215     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1216         # ... libdrm is required
1217         if test "x$have_libdrm" != xyes; then
1218             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1219         fi
1220         # ... and build dricommon
1221         HAVE_COMMON_DRI=yes
1222     fi
1223
1224     # put all the necessary libs together
1225     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1226     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1227 fi
1228 AC_SUBST([DRI_DIRS])
1229 AC_SUBST([EXPAT_INCLUDES])
1230 AC_SUBST([DRI_LIB_DEPS])
1231 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1232
1233 case $DRI_DIRS in
1234 *i915*|*i965*)
1235     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1236
1237     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1238         case $d in
1239         i915)
1240             HAVE_I915_DRI=yes;
1241             ;;
1242         i965)
1243             HAVE_I965_DRI=yes;
1244             ;;
1245         esac
1246     done
1247
1248     ;;
1249 esac
1250
1251 case $DRI_DIRS in
1252 *nouveau*)
1253     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1254     HAVE_NOUVEAU_DRI=yes;
1255     ;;
1256 esac
1257
1258 case $DRI_DIRS in
1259 *radeon*|*r200*)
1260     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1261
1262     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1263         case $d in
1264         radeon)
1265             HAVE_RADEON_DRI=yes;
1266             ;;
1267         r200)
1268             HAVE_R200_DRI=yes;
1269             ;;
1270         esac
1271     done
1272
1273     ;;
1274 esac
1275
1276 case $DRI_DIRS in
1277 *swrast*)
1278     HAVE_SWRAST_DRI=yes;
1279     ;;
1280 esac
1281
1282 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1283 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1284 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1285 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1286 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1287 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1288 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1289
1290 dnl
1291 dnl OSMesa configuration
1292 dnl
1293
1294 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1295 AC_ARG_WITH([osmesa-bits],
1296     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1297         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1298     [osmesa_bits="$withval"],
1299     [osmesa_bits=8])
1300 if test "x$osmesa_bits" != x8; then
1301     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1302         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1303         osmesa_bits=8
1304     fi
1305 fi
1306 case "x$osmesa_bits" in
1307 x8)
1308     OSMESA_LIB="${OSMESA_LIB}"
1309     ;;
1310 x16|x32)
1311     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1312     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1313     ;;
1314 *)
1315     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1316     ;;
1317 esac
1318
1319 if test "x$enable_osmesa" = xyes; then
1320     # only link libraries with osmesa if shared
1321     if test "$enable_static" = no; then
1322         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1323     else
1324         OSMESA_LIB_DEPS=""
1325     fi
1326     OSMESA_MESA_DEPS=""
1327     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1328 fi
1329
1330 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1331
1332 AC_SUBST([OSMESA_LIB_DEPS])
1333 AC_SUBST([OSMESA_MESA_DEPS])
1334 AC_SUBST([OSMESA_PC_REQ])
1335 AC_SUBST([OSMESA_PC_LIB_PRIV])
1336 AC_SUBST([OSMESA_VERSION])
1337
1338 dnl
1339 dnl gbm configuration
1340 dnl
1341 if test "x$enable_gbm" = xauto; then
1342     case "$with_egl_platforms" in
1343         *drm*)
1344             enable_gbm=yes ;;
1345          *)
1346             enable_gbm=no ;;
1347     esac
1348 fi
1349 if test "x$enable_gbm" = xyes; then
1350     SRC_DIRS="$SRC_DIRS gbm"
1351
1352     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1353                       AC_MSG_ERROR([gbm needs udev]))
1354
1355     if test "x$enable_dri" = xyes; then
1356         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1357         if test "$SHARED_GLAPI" -eq 0; then
1358             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1359         fi
1360     fi
1361 fi
1362 GBM_PC_REQ_PRIV="libudev"
1363 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1364 AC_SUBST([GBM_PC_REQ_PRIV])
1365 AC_SUBST([GBM_PC_LIB_PRIV])
1366
1367 dnl
1368 dnl EGL configuration
1369 dnl
1370 EGL_CLIENT_APIS=""
1371
1372 if test "x$enable_egl" = xyes; then
1373     SRC_DIRS="$SRC_DIRS egl"
1374     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1375
1376     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1377
1378     if test "$enable_static" != yes; then
1379         # build egl_glx when libGL is built
1380         if test "x$enable_glx" = xyes; then
1381             HAVE_EGL_DRIVER_GLX=1
1382         fi
1383
1384         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1385                           [have_libudev=yes],[have_libudev=no])
1386         if test "$have_libudev" = yes; then
1387             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1388         fi
1389
1390         if test "x$enable_dri" = xyes; then
1391             HAVE_EGL_DRIVER_DRI2=1
1392         fi
1393
1394     fi
1395 fi
1396 AC_SUBST([EGL_LIB_DEPS])
1397
1398 dnl
1399 dnl EGL Gallium configuration
1400 dnl
1401 if test "x$enable_gallium_egl" = xyes; then
1402     if test "x$with_gallium_drivers" = x; then
1403         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1404     fi
1405     if test "x$enable_egl" = xno; then
1406         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1407     fi
1408     if test "x$have_libdrm" != xyes; then
1409         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1410     fi
1411
1412     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1413     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1414     HAVE_ST_EGL="yes"
1415 fi
1416
1417 dnl
1418 dnl gbm Gallium configuration
1419 dnl
1420 if test "x$enable_gallium_gbm" = xauto; then
1421     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1422         yesyesyes*drm*)
1423             enable_gallium_gbm=yes ;;
1424          *)
1425             enable_gallium_gbm=no ;;
1426     esac
1427 fi
1428 if test "x$enable_gallium_gbm" = xyes; then
1429     if test "x$with_gallium_drivers" = x; then
1430         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1431     fi
1432     if test "x$enable_gbm" = xno; then
1433         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1434     fi
1435     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1436     if test "x$enable_dri" = xno; then
1437         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1438     fi
1439
1440     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1441     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1442     HAVE_ST_GBM="yes"
1443     enable_gallium_loader=yes
1444 fi
1445
1446 dnl
1447 dnl X.Org DDX configuration
1448 dnl
1449 if test "x$enable_xorg" = xyes; then
1450     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1451     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1452     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1453     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1454         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1455         HAVE_XEXTPROTO_71="no")
1456     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1457     HAVE_ST_XORG=yes
1458 fi
1459
1460 dnl
1461 dnl XA configuration
1462 dnl
1463 if test "x$enable_xa" = xyes; then
1464 AC_PROG_AWK
1465 AC_PROG_GREP
1466 AC_CHECK_PROG(NM, nm, "nm")
1467 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1468 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1469 enable_xa=no
1470 fi
1471 fi
1472 if test "x$enable_xa" = xyes; then
1473     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1474     HAVE_ST_XA=yes
1475     AC_SUBST(AWK)
1476     AC_SUBST(GREP)
1477     AC_SUBST(NM)
1478 fi
1479
1480 dnl
1481 dnl OpenVG configuration
1482 dnl
1483 VG_LIB_DEPS=""
1484
1485 if test "x$enable_openvg" = xyes; then
1486     if test "x$enable_egl" = xno; then
1487         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1488     fi
1489     if test "x$with_gallium_drivers" = x; then
1490         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1491     fi
1492     if test "x$enable_gallium_egl" = xno; then
1493         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1494     fi
1495
1496     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1497     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1498     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1499     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1500     HAVE_ST_VEGA=yes
1501 fi
1502
1503 dnl
1504 dnl D3D1X configuration
1505 dnl
1506
1507 if test "x$enable_d3d1x" = xyes; then
1508     if test "x$with_gallium_drivers" = x; then
1509         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1510     fi
1511
1512     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1513     HAVE_ST_D3D1X=yes
1514 fi
1515
1516 dnl
1517 dnl Gallium G3DVL configuration
1518 dnl
1519 AC_ARG_ENABLE([gallium-g3dvl],
1520     [AS_HELP_STRING([--enable-gallium-g3dvl],
1521         [build gallium g3dvl @<:@default=disabled@:>@])],
1522     [enable_gallium_g3dvl="$enableval"],
1523     [enable_gallium_g3dvl=no])
1524 if test "x$enable_gallium_g3dvl" = xyes; then
1525     if test "x$with_gallium_drivers" = x; then
1526         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1527     fi
1528
1529     if test "x$enable_xvmc" = xauto; then
1530         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1531     fi
1532
1533     if test "x$enable_vdpau" = xauto; then
1534         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1535     fi
1536
1537     if test "x$enable_va" = xauto; then
1538         #don't enable vaapi state tracker even if package exists
1539         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1540         enable_va=no
1541     fi
1542 fi
1543
1544 if test "x$enable_xvmc" = xyes; then
1545     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1546     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1547     HAVE_ST_XVMC="yes"
1548 fi
1549
1550 if test "x$enable_vdpau" = xyes; then
1551     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1552     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1553     HAVE_ST_VDPAU="yes"
1554 fi
1555
1556 if test "x$enable_va" = xyes; then
1557     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1558     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1559     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1560     HAVE_ST_VA="yes"
1561 fi
1562
1563 dnl
1564 dnl OpenCL configuration
1565 dnl
1566
1567 AC_ARG_WITH([libclc-path],
1568    [AS_HELP_STRING([--with-libclc-path],
1569          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1570    [LIBCLC_PATH="$withval"],
1571    [LIBCLC_PATH=""])
1572
1573 AC_ARG_WITH([clang-libdir],
1574    [AS_HELP_STRING([--with-clang-libdir],
1575          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1576    [CLANG_LIBDIR="$withval"],
1577    [CLANG_LIBDIR=""])
1578
1579 AC_SUBST([LIBCLC_PATH])
1580
1581 if test "x$enable_opencl" = xyes; then
1582     if test "x$with_gallium_drivers" = x; then
1583         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1584     fi
1585
1586     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1587         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1588     fi
1589
1590     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1591     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1592     enable_gallium_loader=yes
1593 fi
1594
1595 dnl
1596 dnl GLU configuration
1597 dnl
1598 AC_ARG_ENABLE([glu],
1599     [AS_HELP_STRING([--disable-glu],
1600         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1601     [enable_glu="$enableval"],
1602     [enable_glu=yes])
1603
1604 if test "x$enable_glu" = xyes; then
1605     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1606         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1607         enable_glu=no
1608     fi
1609 fi
1610
1611 if test "x$enable_glu" = xyes; then
1612     SRC_DIRS="$SRC_DIRS glu"
1613
1614     if test "x$enable_glx" = xno; then
1615         # Link libGLU to libOSMesa instead of libGL
1616         GLU_LIB_DEPS=""
1617         GLU_PC_REQ="osmesa"
1618         if test "$enable_static" = no; then
1619             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1620         else
1621             GLU_MESA_DEPS=""
1622         fi
1623     else
1624         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1625         GLU_PC_REQ="gl"
1626         GLU_PC_LIB_PRIV="-lm"
1627         if test "$enable_static" = no; then
1628             GLU_LIB_DEPS="-lm"
1629             GLU_MESA_DEPS='-l$(GL_LIB)'
1630         else
1631             GLU_LIB_DEPS=""
1632             GLU_MESA_DEPS=""
1633         fi
1634     fi
1635 fi
1636 if test "$enable_static" = no; then
1637     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1638 fi
1639 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1640 AC_SUBST([GLU_LIB_DEPS])
1641 AC_SUBST([GLU_MESA_DEPS])
1642 AC_SUBST([GLU_PC_REQ])
1643 AC_SUBST([GLU_PC_REQ_PRIV])
1644 AC_SUBST([GLU_PC_LIB_PRIV])
1645 AC_SUBST([GLU_PC_CFLAGS])
1646
1647 AC_SUBST([PROGRAM_DIRS])
1648
1649 dnl
1650 dnl Gallium configuration
1651 dnl
1652 if test "x$with_gallium_drivers" != x; then
1653     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1654 fi
1655
1656 AC_SUBST([LLVM_BINDIR])
1657 AC_SUBST([LLVM_CFLAGS])
1658 AC_SUBST([LLVM_CPPFLAGS])
1659 AC_SUBST([LLVM_CXXFLAGS])
1660 AC_SUBST([LLVM_LIBDIR])
1661 AC_SUBST([LLVM_LIBS])
1662 AC_SUBST([LLVM_LDFLAGS])
1663 AC_SUBST([LLVM_INCLUDEDIR])
1664 AC_SUBST([LLVM_VERSION])
1665 AC_SUBST([CLANG_RESOURCE_DIR])
1666
1667 case "x$enable_opengl$enable_gles1$enable_gles2" in
1668 x*yes*)
1669     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1670     ;;
1671 esac
1672
1673 AC_SUBST([VG_LIB_DEPS])
1674 AC_SUBST([EGL_CLIENT_APIS])
1675
1676 dnl
1677 dnl EGL Platforms configuration
1678 dnl
1679 AC_ARG_WITH([egl-platforms],
1680     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1681         [comma delimited native platforms libEGL supports, e.g.
1682         "x11,drm" @<:@default=auto@:>@])],
1683     [with_egl_platforms="$withval"],
1684     [if test "x$enable_egl" = xyes; then
1685         with_egl_platforms="x11"
1686     else
1687         with_egl_platforms=""
1688     fi])
1689
1690 EGL_PLATFORMS=""
1691
1692 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1693     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1694 fi
1695
1696 # Do per-EGL platform setups and checks
1697 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1698 for plat in $egl_platforms; do
1699         case "$plat" in
1700         fbdev|null)
1701                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1702                 ;;
1703
1704         wayland)
1705                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1706                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1707                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1708
1709                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1710                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1711                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1712                 ;;
1713
1714         x11)
1715                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1716                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1717                 save_LIBS="$LIBS"
1718                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1719                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1720                 LIBS="$save_LIBS"
1721                 ;;
1722
1723         drm)
1724                 test "x$enable_gbm" = "xno" &&
1725                         AC_MSG_ERROR([EGL platform drm needs gbm])
1726                 ;;
1727
1728         android|gdi)
1729                 ;;
1730
1731         *)
1732                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1733                 ;;
1734         esac
1735
1736         case "$plat$have_libudev" in
1737                 waylandno|drmno)
1738                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1739         esac
1740 done
1741
1742 # libEGL wants to default to the first platform specified in
1743 # ./configure.  parse that here.
1744 if test "x$egl_platforms" != "x"; then
1745     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1746     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1747 else
1748     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1749 fi
1750
1751 EGL_PLATFORMS="$egl_platforms"
1752
1753 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1754 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1755 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1756 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1757 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1758
1759 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1760 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1761
1762 AC_SUBST([EGL_NATIVE_PLATFORM])
1763 AC_SUBST([EGL_PLATFORMS])
1764 AC_SUBST([EGL_CFLAGS])
1765
1766 AC_ARG_WITH([egl-driver-dir],
1767     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1768                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1769     [EGL_DRIVER_INSTALL_DIR="$withval"],
1770     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1771 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1772
1773 AC_ARG_WITH([xorg-driver-dir],
1774     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1775                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1776     [XORG_DRIVER_INSTALL_DIR="$withval"],
1777     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1778 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1779
1780 AC_ARG_WITH([max-width],
1781     [AS_HELP_STRING([--with-max-width=N],
1782                     [Maximum framebuffer width (4096)])],
1783     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1784      AS_IF([test "${withval}" -gt "4096"],
1785            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1786 )
1787 AC_ARG_WITH([max-height],
1788     [AS_HELP_STRING([--with-max-height=N],
1789                     [Maximum framebuffer height (4096)])],
1790     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1791      AS_IF([test "${withval}" -gt "4096"],
1792            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1793 )
1794
1795 dnl
1796 dnl Gallium LLVM
1797 dnl
1798 AC_ARG_ENABLE([gallium-llvm],
1799     [AS_HELP_STRING([--enable-gallium-llvm],
1800         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1801     [enable_gallium_llvm="$enableval"],
1802     [enable_gallium_llvm=auto])
1803
1804 AC_ARG_WITH([llvm-shared-libs],
1805     [AS_HELP_STRING([--with-llvm-shared-libs],
1806         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1807     [with_llvm_shared_libs=yes],
1808     [with_llvm_shared_libs=no])
1809
1810 AC_ARG_WITH([llvm-prefix],
1811     [AS_HELP_STRING([--with-llvm-prefix],
1812         [Prefix for LLVM installations in non-standard locations])],
1813     [llvm_prefix="$withval"],
1814     [llvm_prefix=""])
1815
1816
1817 if test "x$with_gallium_drivers" = x; then
1818     enable_gallium_llvm=no
1819 fi
1820 if test "x$enable_gallium_llvm" = xauto; then
1821     case "$host_cpu" in
1822     i*86|x86_64) enable_gallium_llvm=yes;;
1823     esac
1824 fi
1825 if test "x$enable_gallium_llvm" = xyes; then
1826     if test "x$llvm_prefix" != x; then
1827         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1828     else
1829         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1830     fi
1831
1832     if test "x$LLVM_CONFIG" != xno; then
1833         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1834         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1835         if test "x$with_llvm_shared_libs" = xyes; then
1836             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1837             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1838         else
1839             LLVM_COMPONENTS="engine bitwriter"
1840             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1841                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1842             fi
1843             if test "x$enable_opencl" = xyes; then
1844                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1845             fi
1846             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1847         fi
1848         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1849         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1850         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1851         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1852         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1853         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1854         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1855         MESA_LLVM=1
1856
1857         dnl Check for Clang interanl headers
1858         if test "x$enable_opencl" = xyes; then
1859             if test "x$CLANG_LIBDIR" = x; then
1860                 CLANG_LIBDIR=${LLVM_LIBDIR}
1861             fi
1862             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1863             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1864                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1865         fi
1866     else
1867         MESA_LLVM=0
1868     fi
1869 else
1870     MESA_LLVM=0
1871 fi
1872
1873 dnl Directory for XVMC libs
1874 AC_ARG_WITH([xvmc-libdir],
1875     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1876         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1877     [XVMC_LIB_INSTALL_DIR="$withval"],
1878     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1879 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1880
1881 dnl
1882 dnl Gallium Tests
1883 dnl
1884 if test "x$enable_gallium_tests" = xyes; then
1885     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1886     enable_gallium_loader=yes
1887 fi
1888
1889 dnl Directory for VDPAU libs
1890 AC_ARG_WITH([vdpau-libdir],
1891     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1892         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1893     [VDPAU_LIB_INSTALL_DIR="$withval"],
1894     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1895 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1896
1897 dnl Directory for VA libs
1898 AC_ARG_WITH([va-libdir],
1899     [AS_HELP_STRING([--with-va-libdir=DIR],
1900         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1901     [VA_LIB_INSTALL_DIR="$withval"],
1902     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1903 AC_SUBST([VA_LIB_INSTALL_DIR])
1904
1905 dnl Directory for OpenCL libs
1906 AC_ARG_WITH([opencl-libdir],
1907     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1908         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1909     [OPENCL_LIB_INSTALL_DIR="$withval"],
1910     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1911 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1912
1913 dnl
1914 dnl Gallium helper functions
1915 dnl
1916 gallium_check_st() {
1917     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1918          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1919          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1920          if test "x$have_libdrm" != xyes; then
1921             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1922          fi
1923          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1924     fi
1925     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1926          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1927     fi
1928     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1929          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1930     fi
1931     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1932          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1933     fi
1934     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1935          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1936     fi
1937     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1938          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1939     fi
1940     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1941          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1942     fi
1943 }
1944
1945 gallium_require_llvm() {
1946     if test "x$MESA_LLVM" = x0; then
1947         case "$host_cpu" in
1948         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1949         esac
1950     fi
1951 }
1952
1953 gallium_require_drm_loader() {
1954     if test "x$enable_gallium_loader" = xyes; then
1955         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1956                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1957         if test "x$have_libdrm" != xyes; then
1958             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1959         fi
1960         enable_gallium_drm_loader=yes
1961     fi
1962 }
1963
1964 dnl Gallium drivers
1965 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1966 if test "x$with_gallium_drivers" != x; then
1967     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1968     for driver in $gallium_drivers; do
1969         case "x$driver" in
1970         xsvga)
1971             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1972             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1973             ;;
1974         xi915)
1975             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1976             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1977             if test "x$MESA_LLVM" = x1; then
1978                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1979             fi
1980             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1981             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1982             ;;
1983         xr300)
1984             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1985             gallium_require_llvm "Gallium R300"
1986             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1987             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1988             ;;
1989         xr600)
1990             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1991             gallium_require_drm_loader
1992             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1993             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1994                 if test "x$LLVM_VERSION" != "x3.1"; then
1995                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1996                 fi
1997                 NEED_RADEON_GALLIUM=yes;
1998             fi
1999             if test "x$enable_r600_llvm" = xyes; then
2000                 USE_R600_LLVM_COMPILER=yes;
2001             fi
2002             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
2003                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
2004             fi
2005             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
2006             ;;
2007         xradeonsi)
2008             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2009             gallium_require_drm_loader
2010             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
2011             if test "x$LLVM_VERSION" != "x3.1"; then
2012                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
2013             fi
2014             NEED_RADEON_GALLIUM=yes;
2015             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
2016             ;;
2017         xnouveau)
2018             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2019             gallium_require_drm_loader
2020             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
2021             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
2022             ;;
2023         xswrast)
2024             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2025             if test "x$MESA_LLVM" = x1; then
2026                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2027             fi
2028
2029             if test "x$HAVE_ST_DRI" = xyes; then
2030                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2031             fi
2032             if test "x$HAVE_ST_VDPAU" = xyes; then
2033                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
2034             fi
2035             if test "x$HAVE_ST_XVMC" = xyes; then
2036                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
2037             fi
2038             if test "x$HAVE_ST_VA" = xyes; then
2039                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
2040             fi
2041             if test "x$HAVE_ST_VDPAU" = xyes ||
2042                test "x$HAVE_ST_XVMC" = xyes ||
2043                test "x$HAVE_ST_VA" = xyes; then
2044                if test "x$HAVE_WINSYS_XLIB" != xyes; then
2045                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
2046                fi
2047             fi
2048             ;;
2049         *)
2050             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2051             ;;
2052         esac
2053     done
2054 fi
2055
2056 if test "x$enable_gallium_loader" = xyes; then
2057     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2058     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
2059     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
2060     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
2061
2062     if test "x$HAVE_WINSYS_XLIB" = xyes; then
2063         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2064         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
2065     fi
2066
2067     if test "x$enable_gallium_drm_loader" = xyes; then
2068         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2069         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2070                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2071         if test "x$pipe_loader_have_xcb" = xyes; then
2072             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
2073             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2074         fi
2075     fi
2076
2077     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2078     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2079 fi
2080
2081 dnl Tell Automake which drivers to build
2082 for driver in $GALLIUM_DRIVERS_DIRS; do
2083     case "x$driver" in
2084         xgalahad)
2085             HAVE_GALAHAD_GALLIUM=yes;
2086             ;;
2087         xidentity)
2088             HAVE_IDENTITY_GALLIUM=yes;
2089             ;;
2090         xnoop)
2091             HAVE_NOOP_GALLIUM=yes;
2092             ;;
2093         *)
2094             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2095             ;;
2096     esac
2097 done
2098
2099 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2100 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2101 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2102 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2103 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2104 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2105 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2106 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2107 AC_SUBST([GALLIUM_MAKE_DIRS])
2108
2109 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2110 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2111
2112 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2113 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2114 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2115
2116 dnl prepend CORE_DIRS to SRC_DIRS
2117 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2118
2119 dnl Restore LDFLAGS and CPPFLAGS
2120 LDFLAGS="$_SAVE_LDFLAGS"
2121 CPPFLAGS="$_SAVE_CPPFLAGS"
2122
2123 dnl Add user CFLAGS and CXXFLAGS
2124 CFLAGS="$CFLAGS $USER_CFLAGS"
2125 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2126
2127 dnl Substitute the config
2128 AC_CONFIG_FILES([configs/current
2129                 Makefile
2130                 src/Makefile
2131                 src/gallium/Makefile
2132                 src/gallium/auxiliary/pipe-loader/Makefile
2133                 src/gallium/state_trackers/clover/Makefile
2134                 src/gallium/drivers/Makefile
2135                 src/gallium/drivers/r300/Makefile
2136                 src/gallium/drivers/r600/Makefile
2137                 src/gallium/targets/opencl/Makefile
2138                 src/gbm/Makefile
2139                 src/gbm/main/gbm.pc
2140                 src/egl/drivers/Makefile
2141                 src/egl/drivers/dri2/Makefile
2142                 src/egl/drivers/glx/Makefile
2143                 src/egl/Makefile
2144                 src/egl/main/Makefile
2145                 src/egl/main/egl.pc
2146                 src/egl/wayland/Makefile
2147                 src/egl/wayland/wayland-egl/Makefile
2148                 src/egl/wayland/wayland-egl/wayland-egl.pc
2149                 src/egl/wayland/wayland-drm/Makefile
2150                 src/glsl/Makefile
2151                 src/glsl/glcpp/Makefile
2152                 src/glsl/tests/Makefile
2153                 src/glx/Makefile
2154                 src/glx/tests/Makefile
2155                 src/mapi/glapi/Makefile
2156                 src/mapi/glapi/gen/Makefile
2157                 src/mapi/shared-glapi/Makefile
2158                 src/mapi/glapi/tests/Makefile
2159                 src/mapi/shared-glapi/tests/Makefile
2160                 src/gtest/Makefile
2161                 src/mesa/Makefile
2162                 src/mesa/libdricore/Makefile
2163                 src/mesa/main/tests/Makefile
2164                 src/mesa/x86/Makefile
2165                 src/mesa/x86-64/Makefile
2166                 src/mesa/drivers/Makefile
2167                 src/mesa/drivers/dri/dri.pc
2168                 src/mesa/drivers/dri/Makefile
2169                 src/mesa/drivers/dri/common/Makefile
2170                 src/mesa/drivers/dri/i915/Makefile
2171                 src/mesa/drivers/dri/i965/Makefile
2172                 src/mesa/drivers/dri/nouveau/Makefile
2173                 src/mesa/drivers/dri/r200/Makefile
2174                 src/mesa/drivers/dri/radeon/Makefile
2175                 src/mesa/drivers/dri/swrast/Makefile
2176                 src/mesa/drivers/osmesa/Makefile
2177                 src/mesa/drivers/x11/Makefile
2178                 src/mesa/gl.pc
2179                 src/mesa/drivers/osmesa/osmesa.pc])
2180
2181 dnl Sort the dirs alphabetically
2182 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2183 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2184 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2185 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2186 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2187
2188 AC_OUTPUT
2189
2190 dnl
2191 dnl Output some configuration info for the user
2192 dnl
2193 echo ""
2194 echo "        prefix:          $prefix"
2195 echo "        exec_prefix:     $exec_prefix"
2196 echo "        libdir:          $libdir"
2197 echo "        includedir:      $includedir"
2198
2199 dnl API info
2200 echo ""
2201 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2202 echo "        OpenVG:          $enable_openvg"
2203
2204 dnl Driver info
2205 echo ""
2206 if test "x$enable_osmesa" != xno; then
2207         echo "        OSMesa:          lib$OSMESA_LIB"
2208 else
2209         echo "        OSMesa:          no"
2210 fi
2211
2212 if test "x$enable_dri" != xno; then
2213         # cleanup the drivers var
2214         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2215         if test "x$DRI_DIRS" = x; then
2216             echo "        DRI drivers:     no"
2217         else
2218             echo "        DRI drivers:     $dri_dirs"
2219         fi
2220         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2221 fi
2222
2223 case "x$enable_glx$enable_xlib_glx" in
2224 xyesyes)
2225     echo "        GLX:             Xlib-based"
2226     ;;
2227 xyesno)
2228     echo "        GLX:             DRI-based"
2229     ;;
2230 *)
2231     echo "        GLX:             $enable_glx"
2232     ;;
2233 esac
2234
2235 echo ""
2236 echo "        GLU:             $enable_glu"
2237
2238 dnl EGL
2239 echo ""
2240 echo "        EGL:             $enable_egl"
2241 if test "$enable_egl" = yes; then
2242     echo "        EGL platforms:   $EGL_PLATFORMS"
2243
2244     egl_drivers=""
2245     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2246         egl_drivers="$egl_drivers builtin:egl_glx"
2247     fi
2248     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2249         egl_drivers="$egl_drivers builtin:egl_dri2"
2250     fi
2251
2252     if test "x$HAVE_ST_EGL" = xyes; then
2253         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2254         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2255     else
2256         echo "        EGL drivers:    $egl_drivers"
2257     fi
2258 fi
2259
2260 echo ""
2261 if test "x$MESA_LLVM" = x1; then
2262     echo "        llvm:            yes"
2263     echo "        llvm-config:     $LLVM_CONFIG"
2264     echo "        llvm-version:    $LLVM_VERSION"
2265 else
2266     echo "        llvm:            no"
2267 fi
2268
2269 echo ""
2270 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2271     echo "        Gallium:         yes"
2272     echo "        Gallium dirs:    $GALLIUM_DIRS"
2273     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2274     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2275     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2276     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2277 else
2278     echo "        Gallium:         no"
2279 fi
2280
2281
2282 dnl Libraries
2283 echo ""
2284 echo "        Shared libs:     $enable_shared"
2285 echo "        Static libs:     $enable_static"
2286
2287 dnl Compiler options
2288 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2289 cflags=`echo $CFLAGS $PIC_FLAGS | \
2290     $SED 's/^ *//;s/  */ /;s/ *$//'`
2291 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2292     $SED 's/^ *//;s/  */ /;s/ *$//'`
2293 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2294 echo ""
2295 echo "        CFLAGS:          $cflags"
2296 echo "        CXXFLAGS:        $cxxflags"
2297 echo "        Macros:          $defines"
2298 echo ""
2299 echo "        PYTHON2:         $PYTHON2"
2300
2301 echo ""
2302 echo "        Run '${MAKE-make}' to build Mesa"
2303 echo ""