configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 LIBVA_REQUIRED=0.35.0
  43 VDPAU_REQUIRED=0.4.1
  44 WAYLAND_REQUIRED=1.2.0
  45 XCB_REQUIRED=1.9.3
  46 XCBDRI2_REQUIRED=1.8
  47 XCBGLX_REQUIRED=1.8.1
  48 XSHMFENCE_REQUIRED=1.1
  49 XVMC_REQUIRED=1.0.6
  50
  51 dnl Check for progs
  52 AC_PROG_CPP
  53 AC_PROG_CC
  54 AC_PROG_CXX
  55 AM_PROG_CC_C_O
  56 AM_PROG_AS
  57 AX_CHECK_GNU_MAKE
  58 AC_CHECK_PROGS([PYTHON2], [python2 python])
  59 AC_PROG_SED
  60 AC_PROG_MKDIR_P
  61
  62 AC_SYS_LARGEFILE
  63
  64 LT_PREREQ([2.2])
  65 LT_INIT([disable-static])
  66
  67 AX_PROG_BISON([],
  68               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  69                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  70 AX_PROG_FLEX([],
  71              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  72                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  73
  74 AC_CHECK_PROG(INDENT, indent, indent, cat)
  75 if test "x$INDENT" != "xcat"; then
  76     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  77 fi
  78
  79 AC_PROG_INSTALL
  80
  81 dnl We need a POSIX shell for parts of the build. Assume we have one
  82 dnl in most cases.
  83 case "$host_os" in
  84 solaris*)
  85     # Solaris /bin/sh is too old/non-POSIX compliant
  86     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  87     SHELL="$POSIX_SHELL"
  88     ;;
  89 esac
  90
  91 dnl clang is mostly GCC-compatible, but its version is much lower,
  92 dnl so we have to check for it.
  93 AC_MSG_CHECKING([if compiling with clang])
  94
  95 AC_COMPILE_IFELSE(
  96 [AC_LANG_PROGRAM([], [[
  97 #ifndef __clang__
  98        not clang
  99 #endif
 100 ]])],
 101 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 102
 103 AC_MSG_RESULT([$acv_mesa_CLANG])
 104
 105 dnl If we're using GCC, make sure that it is at least version 4.1.0.  Older
 106 dnl versions are explictly not supported.
 107 GEN_ASM_OFFSETS=no
 108 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 109     AC_MSG_CHECKING([whether gcc version is sufficient])
 110     major=0
 111     minor=0
 112
 113     GCC_VERSION=`$CC -dumpversion`
 114     if test $? -eq 0; then
 115         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 116         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 117     fi
 118
 119     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 1 ; then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([If using GCC, version 4.1.0 or later is required.])
 122     else
 123         AC_MSG_RESULT([yes])
 124     fi
 125
 126     if test "x$cross_compiling" = xyes; then
 127         GEN_ASM_OFFSETS=yes
 128     fi
 129 fi
 130
 131 dnl Check for compiler builtins
 132 AX_GCC_BUILTIN([__builtin_bswap32])
 133 AX_GCC_BUILTIN([__builtin_bswap64])
 134 AX_GCC_BUILTIN([__builtin_clz])
 135 AX_GCC_BUILTIN([__builtin_clzll])
 136 AX_GCC_BUILTIN([__builtin_ctz])
 137 AX_GCC_BUILTIN([__builtin_expect])
 138 AX_GCC_BUILTIN([__builtin_ffs])
 139 AX_GCC_BUILTIN([__builtin_ffsll])
 140 AX_GCC_BUILTIN([__builtin_popcount])
 141 AX_GCC_BUILTIN([__builtin_popcountll])
 142 AX_GCC_BUILTIN([__builtin_unreachable])
 143
 144 AX_GCC_FUNC_ATTRIBUTE([flatten])
 145 AX_GCC_FUNC_ATTRIBUTE([format])
 146 AX_GCC_FUNC_ATTRIBUTE([malloc])
 147 AX_GCC_FUNC_ATTRIBUTE([packed])
 148
 149 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 150
 151 dnl Make sure the pkg-config macros are defined
 152 m4_ifndef([PKG_PROG_PKG_CONFIG],
 153     [m4_fatal([Could not locate the pkg-config autoconf macros.
 154   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 155   are in a different location, try setting the environment variable
 156   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 157 PKG_PROG_PKG_CONFIG()
 158
 159 dnl LIB_DIR - library basename
 160 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 161 AC_SUBST([LIB_DIR])
 162
 163 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 164 _SAVE_LDFLAGS="$LDFLAGS"
 165 _SAVE_CPPFLAGS="$CPPFLAGS"
 166
 167 dnl Compiler macros
 168 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 169 AC_SUBST([DEFINES])
 170 case "$host_os" in
 171 linux*|*-gnu*|gnu*)
 172     DEFINES="$DEFINES -D_GNU_SOURCE"
 173     ;;
 174 solaris*)
 175     DEFINES="$DEFINES -DSVR4"
 176     ;;
 177 cygwin*)
 178     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 179     ;;
 180 esac
 181
 182 dnl Add flags for gcc and g++
 183 if test "x$GCC" = xyes; then
 184     CFLAGS="$CFLAGS -Wall -std=c99"
 185
 186     # Enable -Werror=implicit-function-declaration and
 187     # -Werror=missing-prototypes, if available, or otherwise, just
 188     # -Wmissing-prototypes.  This is particularly useful to avoid
 189     # generating a loadable driver module that has undefined symbols.
 190     save_CFLAGS="$CFLAGS"
 191     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 192     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 193     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 194     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 195                    AC_MSG_RESULT([yes]),
 196                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 197                     AC_MSG_RESULT([no])]);
 198
 199     # Enable -fvisibility=hidden if using a gcc that supports it
 200     save_CFLAGS="$CFLAGS"
 201     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 202     VISIBILITY_CFLAGS="-fvisibility=hidden"
 203     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 204     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 205                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 206
 207     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 208     CFLAGS=$save_CFLAGS
 209
 210     # Work around aliasing bugs - developers should comment this out
 211     CFLAGS="$CFLAGS -fno-strict-aliasing"
 212
 213     # gcc's builtin memcmp is slower than glibc's
 214     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 215     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 216 fi
 217 if test "x$GXX" = xyes; then
 218     CXXFLAGS="$CXXFLAGS -Wall"
 219
 220     # Enable -fvisibility=hidden if using a gcc that supports it
 221     save_CXXFLAGS="$CXXFLAGS"
 222     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 223     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 224     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 225     AC_LANG_PUSH([C++])
 226     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 227                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 228     AC_LANG_POP([C++])
 229
 230     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 231     CXXFLAGS=$save_CXXFLAGS
 232
 233     # Work around aliasing bugs - developers should comment this out
 234     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 235
 236     # gcc's builtin memcmp is slower than glibc's
 237     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 238     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 239 fi
 240
 241 dnl even if the compiler appears to support it, using visibility attributes isn't
 242 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 243 case "$host_os" in
 244 cygwin*)
 245     VISIBILITY_CFLAGS=""
 246     VISIBILITY_CXXFLAGS=""
 247     ;;
 248 esac
 249
 250 AC_SUBST([VISIBILITY_CFLAGS])
 251 AC_SUBST([VISIBILITY_CXXFLAGS])
 252
 253 dnl
 254 dnl Optional flags, check for compiler support
 255 dnl
 256 SSE41_CFLAGS="-msse4.1"
 257 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 258 dnl stack, but on x86-32 such alignment is not guaranteed.
 259 case "$target_cpu" in
 260 i?86)
 261     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 262     ;;
 263 esac
 264 save_CFLAGS="$CFLAGS"
 265 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 266 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 267 #include <smmintrin.h>
 268 int main () {
 269     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 270     c = _mm_max_epu32(a, b);
 271     return 0;
 272 }]])], SSE41_SUPPORTED=1)
 273 CFLAGS="$save_CFLAGS"
 274 if test "x$SSE41_SUPPORTED" = x1; then
 275     DEFINES="$DEFINES -DUSE_SSE41"
 276 fi
 277 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 278 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 279
 280 dnl Can't have static and shared libraries, default to static if user
 281 dnl explicitly requested. If both disabled, set to static since shared
 282 dnl was explicitly requested.
 283 case "x$enable_static$enable_shared" in
 284 xyesyes)
 285     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 286     enable_shared=no
 287     ;;
 288 xnono)
 289     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 290     enable_shared=yes
 291     ;;
 292 esac
 293
 294 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 295
 296 dnl
 297 dnl other compiler options
 298 dnl
 299 AC_ARG_ENABLE([debug],
 300     [AS_HELP_STRING([--enable-debug],
 301         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 302     [enable_debug="$enableval"],
 303     [enable_debug=no]
 304 )
 305 if test "x$enable_debug" = xyes; then
 306     DEFINES="$DEFINES -DDEBUG"
 307     if test "x$GCC" = xyes; then
 308         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 309             CFLAGS="$CFLAGS -g"
 310         fi
 311         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 312             CFLAGS="$CFLAGS -O0"
 313         fi
 314     fi
 315     if test "x$GXX" = xyes; then
 316         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 317             CXXFLAGS="$CXXFLAGS -g"
 318         fi
 319         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 320             CXXFLAGS="$CXXFLAGS -O0"
 321         fi
 322     fi
 323 fi
 324
 325 dnl
 326 dnl Check if linker supports -Bsymbolic
 327 dnl
 328 save_LDFLAGS=$LDFLAGS
 329 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 330 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 331 AC_LINK_IFELSE(
 332     [AC_LANG_SOURCE([int main() { return 0;}])],
 333     [AC_MSG_RESULT([yes])
 334         BSYMBOLIC="-Wl,-Bsymbolic";],
 335     [AC_MSG_RESULT([no])
 336         BSYMBOLIC="";])
 337 LDFLAGS=$save_LDFLAGS
 338
 339 AC_SUBST([BSYMBOLIC])
 340
 341 dnl
 342 dnl Check if linker supports garbage collection
 343 dnl
 344 save_LDFLAGS=$LDFLAGS
 345 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 346 AC_MSG_CHECKING([whether ld supports --gc-sections])
 347 AC_LINK_IFELSE(
 348     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 349     [AC_MSG_RESULT([yes])
 350         GC_SECTIONS="-Wl,--gc-sections";],
 351     [AC_MSG_RESULT([no])
 352         GC_SECTIONS="";])
 353 LDFLAGS=$save_LDFLAGS
 354
 355 AC_SUBST([GC_SECTIONS])
 356
 357 dnl
 358 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 359 dnl so when these flags are passed to ld via libtool the checks will fail
 360 dnl
 361 case "$host_os" in
 362 openbsd* | darwin* )
 363     LD_NO_UNDEFINED="" ;;
 364 *)
 365     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 366 esac
 367
 368 AC_SUBST([LD_NO_UNDEFINED])
 369
 370 dnl
 371 dnl Check if linker supports version scripts
 372 dnl
 373 AC_MSG_CHECKING([if the linker supports version-scripts])
 374 save_LDFLAGS=$LDFLAGS
 375 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 376 cat > conftest.map <<EOF
 377 VERSION_1 {
 378      global:
 379          main;
 380
 381      local:
 382          *;
 383 };
 384 EOF
 385 AC_LINK_IFELSE(
 386     [AC_LANG_SOURCE([int main() { return 0;}])],
 387     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 388     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 389 LDFLAGS=$save_LDFLAGS
 390 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 391
 392 dnl
 393 dnl Check if linker supports dynamic list files
 394 dnl
 395 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 396 save_LDFLAGS=$LDFLAGS
 397 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 398 cat > conftest.dyn <<EOF
 399 {
 400         radeon_drm_winsys_create;
 401 };
 402 EOF
 403 AC_LINK_IFELSE(
 404     [AC_LANG_SOURCE([int main() { return 0;}])],
 405     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 406     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 407 LDFLAGS=$save_LDFLAGS
 408 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 409
 410 dnl
 411 dnl compatibility symlinks
 412 dnl
 413 case "$host_os" in
 414 linux* )
 415     HAVE_COMPAT_SYMLINKS=yes ;;
 416 * )
 417     HAVE_COMPAT_SYMLINKS=no ;;
 418 esac
 419
 420 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 421
 422 dnl
 423 dnl library names
 424 dnl
 425 case "$host_os" in
 426 darwin* )
 427     LIB_EXT='dylib' ;;
 428 cygwin* )
 429     LIB_EXT='dll' ;;
 430 aix* )
 431     LIB_EXT='a' ;;
 432 * )
 433     LIB_EXT='so' ;;
 434 esac
 435
 436 AC_SUBST([LIB_EXT])
 437
 438 AC_ARG_WITH([gl-lib-name],
 439   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 440     [specify GL library name @<:@default=GL@:>@])],
 441   [GL_LIB=$withval],
 442   [GL_LIB=GL])
 443 AC_ARG_WITH([osmesa-lib-name],
 444   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 445     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 446   [OSMESA_LIB=$withval],
 447   [OSMESA_LIB=OSMesa])
 448 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 449 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 450
 451 dnl
 452 dnl Mangled Mesa support
 453 dnl
 454 AC_ARG_ENABLE([mangling],
 455   [AS_HELP_STRING([--enable-mangling],
 456     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 457   [enable_mangling="${enableval}"],
 458   [enable_mangling=no]
 459 )
 460 if test "x${enable_mangling}" = "xyes" ; then
 461   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 462   GL_LIB="Mangled${GL_LIB}"
 463   OSMESA_LIB="Mangled${OSMESA_LIB}"
 464 fi
 465 AC_SUBST([GL_LIB])
 466 AC_SUBST([OSMESA_LIB])
 467
 468 dnl
 469 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 470 dnl
 471 AC_ARG_ENABLE([texture-float],
 472     [AS_HELP_STRING([--enable-texture-float],
 473         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 474     [enable_texture_float="$enableval"],
 475     [enable_texture_float=no]
 476 )
 477 if test "x$enable_texture_float" = xyes; then
 478     AC_MSG_WARN([Floating-point textures enabled.])
 479     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 480     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 481 fi
 482
 483 dnl
 484 dnl Arch/platform-specific settings
 485 dnl
 486 AC_ARG_ENABLE([asm],
 487     [AS_HELP_STRING([--disable-asm],
 488         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 489     [enable_asm="$enableval"],
 490     [enable_asm=yes]
 491 )
 492 asm_arch=""
 493 AC_MSG_CHECKING([whether to enable assembly])
 494 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 495 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 496 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 497     case "$host_cpu" in
 498     i?86 | x86_64 | amd64)
 499         enable_asm=no
 500         AC_MSG_RESULT([no, cross compiling])
 501         ;;
 502     esac
 503 fi
 504 # check for supported arches
 505 if test "x$enable_asm" = xyes; then
 506     case "$host_cpu" in
 507     i?86)
 508         case "$host_os" in
 509         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 510             asm_arch=x86
 511             ;;
 512         esac
 513         ;;
 514     x86_64|amd64)
 515         case "$host_os" in
 516         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 517             asm_arch=x86_64
 518             ;;
 519         esac
 520         ;;
 521     sparc*)
 522         case "$host_os" in
 523         linux*)
 524             asm_arch=sparc
 525             ;;
 526         esac
 527         ;;
 528     esac
 529
 530     case "$asm_arch" in
 531     x86)
 532         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 533         AC_MSG_RESULT([yes, x86])
 534         ;;
 535     x86_64|amd64)
 536         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 537         AC_MSG_RESULT([yes, x86_64])
 538         ;;
 539     sparc)
 540         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 541         AC_MSG_RESULT([yes, sparc])
 542         ;;
 543     *)
 544         AC_MSG_RESULT([no, platform not supported])
 545         ;;
 546     esac
 547 fi
 548
 549 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 550 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 551
 552 dnl Check to see if dlopen is in default libraries (like Solaris, which
 553 dnl has it in libc), or if libdl is needed to get it.
 554 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 555     [AC_CHECK_LIB([dl], [dlopen],
 556        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 557 AC_SUBST([DLOPEN_LIBS])
 558
 559 dnl Check if that library also has dladdr
 560 save_LIBS="$LIBS"
 561 LIBS="$LIBS $DLOPEN_LIBS"
 562 AC_CHECK_FUNCS([dladdr])
 563 LIBS="$save_LIBS"
 564
 565 case "$host_os" in
 566 darwin*|mingw*)
 567     ;;
 568 *)
 569     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 570                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 571                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 572     AC_SUBST([CLOCK_LIB])
 573     ;;
 574 esac
 575
 576 dnl See if posix_memalign is available
 577 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 578
 579 dnl Check for pthreads
 580 case "$host_os" in
 581 mingw*)
 582     ;;
 583 *)
 584     AX_PTHREAD
 585     ;;
 586 esac
 587 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 588 dnl to -pthread, which causes problems if we need -lpthread to appear in
 589 dnl pkgconfig files.
 590 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 591
 592 dnl SELinux awareness.
 593 AC_ARG_ENABLE([selinux],
 594     [AS_HELP_STRING([--enable-selinux],
 595         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 596     [MESA_SELINUX="$enableval"],
 597     [MESA_SELINUX=no])
 598 if test "x$enable_selinux" = "xyes"; then
 599     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 600         [AC_CHECK_HEADER([selinux/selinux.h],[],
 601                          [AC_MSG_ERROR([SELinux headers not found])])
 602          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 603                       [AC_MSG_ERROR([SELinux library not found])])
 604          SELINUX_LIBS="-lselinux"])
 605     DEFINES="$DEFINES -DMESA_SELINUX"
 606 fi
 607 AC_SUBST([SELINUX_CFLAGS])
 608 AC_SUBST([SELINUX_LIBS])
 609
 610 dnl Options for APIs
 611 AC_ARG_ENABLE([opengl],
 612     [AS_HELP_STRING([--disable-opengl],
 613         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 614     [enable_opengl="$enableval"],
 615     [enable_opengl=yes])
 616 AC_ARG_ENABLE([gles1],
 617     [AS_HELP_STRING([--enable-gles1],
 618         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 619     [enable_gles1="$enableval"],
 620     [enable_gles1=no])
 621 AC_ARG_ENABLE([gles2],
 622     [AS_HELP_STRING([--enable-gles2],
 623         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 624     [enable_gles2="$enableval"],
 625     [enable_gles2=no])
 626 AC_ARG_ENABLE([openvg],
 627     [AS_HELP_STRING([--enable-openvg],
 628         [enable support for OpenVG API @<:@default=disabled@:>@])],
 629     [enable_openvg="$enableval"],
 630     [enable_openvg=no])
 631
 632 AC_ARG_ENABLE([dri],
 633     [AS_HELP_STRING([--enable-dri],
 634         [enable DRI modules @<:@default=enabled@:>@])],
 635     [enable_dri="$enableval"],
 636     [enable_dri=yes])
 637
 638 case "$host_os" in
 639 linux*)
 640     dri3_default=yes
 641     ;;
 642 *)
 643     dri3_default=no
 644     ;;
 645 esac
 646 AC_ARG_ENABLE([dri3],
 647     [AS_HELP_STRING([--enable-dri3],
 648         [enable DRI3 @<:@default=auto@:>@])],
 649     [enable_dri3="$enableval"],
 650     [enable_dri3="$dri3_default"])
 651 AC_ARG_ENABLE([glx],
 652     [AS_HELP_STRING([--enable-glx],
 653         [enable GLX library @<:@default=enabled@:>@])],
 654     [enable_glx="$enableval"],
 655     [enable_glx=yes])
 656 AC_ARG_ENABLE([osmesa],
 657     [AS_HELP_STRING([--enable-osmesa],
 658         [enable OSMesa library @<:@default=disabled@:>@])],
 659     [enable_osmesa="$enableval"],
 660     [enable_osmesa=no])
 661 AC_ARG_ENABLE([gallium-osmesa],
 662     [AS_HELP_STRING([--enable-gallium-osmesa],
 663         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 664     [enable_gallium_osmesa="$enableval"],
 665     [enable_gallium_osmesa=no])
 666 AC_ARG_ENABLE([egl],
 667     [AS_HELP_STRING([--disable-egl],
 668         [disable EGL library @<:@default=enabled@:>@])],
 669     [enable_egl="$enableval"],
 670     [enable_egl=yes])
 671
 672 AC_ARG_ENABLE([xa],
 673     [AS_HELP_STRING([--enable-xa],
 674         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 675     [enable_xa="$enableval"],
 676     [enable_xa=no])
 677 AC_ARG_ENABLE([gbm],
 678    [AS_HELP_STRING([--enable-gbm],
 679          [enable gbm library @<:@default=auto@:>@])],
 680    [enable_gbm="$enableval"],
 681    [enable_gbm=auto])
 682 AC_ARG_ENABLE([nine],
 683     [AS_HELP_STRING([--enable-nine],
 684         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 685     [enable_nine="$enableval"],
 686     [enable_nine=no])
 687
 688 AC_ARG_ENABLE([xvmc],
 689    [AS_HELP_STRING([--enable-xvmc],
 690          [enable xvmc library @<:@default=auto@:>@])],
 691    [enable_xvmc="$enableval"],
 692    [enable_xvmc=auto])
 693 AC_ARG_ENABLE([vdpau],
 694    [AS_HELP_STRING([--enable-vdpau],
 695          [enable vdpau library @<:@default=auto@:>@])],
 696    [enable_vdpau="$enableval"],
 697    [enable_vdpau=auto])
 698 AC_ARG_ENABLE([omx],
 699    [AS_HELP_STRING([--enable-omx],
 700          [enable OpenMAX library @<:@default=disabled@:>@])],
 701    [enable_omx="$enableval"],
 702    [enable_omx=no])
 703 AC_ARG_ENABLE([va],
 704    [AS_HELP_STRING([--enable-va],
 705          [enable va library @<:@default=auto@:>@])],
 706    [enable_va="$enableval"],
 707    [enable_va=auto])
 708 AC_ARG_ENABLE([opencl],
 709    [AS_HELP_STRING([--enable-opencl],
 710          [enable OpenCL library @<:@default=disabled@:>@])],
 711    [enable_opencl="$enableval"],
 712    [enable_opencl=no])
 713 AC_ARG_ENABLE([opencl_icd],
 714    [AS_HELP_STRING([--enable-opencl-icd],
 715           [Build an OpenCL ICD library to be loaded by an ICD implementation
 716            @<:@default=disabled@:>@])],
 717     [enable_opencl_icd="$enableval"],
 718     [enable_opencl_icd=no])
 719 AC_ARG_ENABLE([xlib-glx],
 720     [AS_HELP_STRING([--enable-xlib-glx],
 721         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 722     [enable_xlib_glx="$enableval"],
 723     [enable_xlib_glx=no])
 724
 725 AC_ARG_ENABLE([r600-llvm-compiler],
 726     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 727         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 728     [enable_r600_llvm="$enableval"],
 729     [enable_r600_llvm=no])
 730
 731 AC_ARG_ENABLE([gallium-tests],
 732     [AS_HELP_STRING([--enable-gallium-tests],
 733         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 734     [enable_gallium_tests="$enableval"],
 735     [enable_gallium_tests=no])
 736
 737 # Option for Gallium drivers
 738
 739 # Keep this in sync with the --with-gallium-drivers help string default value
 740 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 741
 742 AC_ARG_WITH([gallium-drivers],
 743     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 744         [comma delimited Gallium drivers list, e.g.
 745         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 746         @<:@default=r300,r600,svga,swrast@:>@])],
 747     [with_gallium_drivers="$withval"],
 748     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 749
 750 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 751 # here so that the script doesn't choke on an unknown driver name later.
 752 case "$with_gallium_drivers" in
 753     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 754     no) with_gallium_drivers='' ;;
 755 esac
 756
 757 if test "x$enable_opengl" = xno -a \
 758         "x$enable_gles1" = xno -a \
 759         "x$enable_gles2" = xno -a \
 760         "x$enable_nine" = xno -a \
 761         "x$enable_openvg" = xno -a \
 762         "x$enable_xa" = xno -a \
 763         "x$enable_xvmc" = xno -a \
 764         "x$enable_vdpau" = xno -a \
 765         "x$enable_omx" = xno -a \
 766         "x$enable_va" = xno -a \
 767         "x$enable_opencl" = xno; then
 768     AC_MSG_ERROR([at least one API should be enabled])
 769 fi
 770
 771 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 772 if test "x$enable_opengl" = xno -a \
 773         "x$enable_gles1" = xyes; then
 774     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 775 fi
 776
 777 if test "x$enable_opengl" = xno -a \
 778         "x$enable_gles2" = xyes; then
 779     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 780 fi
 781
 782 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 783 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 784 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 785 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 786                                         "x$enable_gles1" = xyes -o \
 787                                         "x$enable_gles2" = xyes)
 788
 789 if test "x$enable_glx" = xno; then
 790     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 791     enable_xlib_glx=no
 792 fi
 793
 794 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 795     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 796 fi
 797
 798 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 799     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 800 fi
 801
 802 # Disable GLX if OpenGL is not enabled
 803 if test "x$enable_glx$enable_opengl" = xyesno; then
 804     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 805     enable_glx=no
 806 fi
 807
 808 # Disable GLX if DRI and Xlib-GLX are not enabled
 809 if test "x$enable_glx" = xyes -a \
 810         "x$enable_dri" = xno -a \
 811         "x$enable_xlib_glx" = xno; then
 812     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 813     enable_glx=no
 814 fi
 815
 816 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 817                                   "x$enable_dri" = xyes)
 818
 819 # Select which platform-dependent DRI code gets built
 820 case "$host_os" in
 821 darwin*)
 822     dri_platform='apple' ;;
 823 gnu*|mingw*|cygwin*)
 824     dri_platform='none' ;;
 825 *)
 826     dri_platform='drm' ;;
 827 esac
 828
 829 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 830 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 831 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 832 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 833 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 834
 835 AC_ARG_ENABLE([shared-glapi],
 836     [AS_HELP_STRING([--enable-shared-glapi],
 837         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 838     [enable_shared_glapi="$enableval"],
 839     [enable_shared_glapi=yes])
 840
 841 case "x$enable_opengl$enable_gles1$enable_gles2" in
 842 x*yes*yes*)
 843     if test "x$enable_shared_glapi" = xno; then
 844         AC_MSG_ERROR([shared GLAPI required when building two or more of
 845                       the following APIs - opengl, gles1 gles2])
 846     fi
 847     ;;
 848 esac
 849
 850 # Building Xlib-GLX requires shared glapi to be disabled.
 851 if test "x$enable_xlib_glx" = xyes; then
 852     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 853     enable_shared_glapi=no
 854 fi
 855
 856 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 857
 858 # Build the pipe-drivers as separate libraries/modules.
 859 # Do not touch this unless you know what you are doing.
 860 # XXX: Expose via configure option ?
 861 enable_shared_pipe_drivers=no
 862
 863 dnl
 864 dnl Driver specific build directories
 865 dnl
 866
 867 case "x$enable_glx$enable_xlib_glx" in
 868 xyesyes)
 869     NEED_WINSYS_XLIB="yes"
 870     ;;
 871 esac
 872
 873 if test "x$enable_dri" = xyes; then
 874     enable_gallium_loader="$enable_shared_pipe_drivers"
 875 fi
 876
 877 if test "x$enable_gallium_osmesa" = xyes; then
 878     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 879         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 880     fi
 881     if test "x$enable_osmesa" = xyes; then
 882         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 883     fi
 884 fi
 885
 886 AC_SUBST([MESA_LLVM])
 887
 888 # Check for libdrm
 889 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 890                   [have_libdrm=yes], [have_libdrm=no])
 891 if test "x$have_libdrm" = xyes; then
 892         DEFINES="$DEFINES -DHAVE_LIBDRM"
 893 fi
 894
 895 case "$host_os" in
 896 linux*)
 897     need_pci_id=yes ;;
 898 *)
 899     need_pci_id=no ;;
 900 esac
 901
 902 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 903                   have_libudev=yes, have_libudev=no)
 904
 905 AC_ARG_ENABLE([sysfs],
 906     [AS_HELP_STRING([--enable-sysfs],
 907         [enable /sys PCI identification @<:@default=disabled@:>@])],
 908     [have_sysfs="$enableval"],
 909     [have_sysfs=no]
 910 )
 911
 912 if test "x$enable_dri" = xyes; then
 913     if test "$enable_static" = yes; then
 914         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 915     fi
 916
 917     # not a hard requirement as swrast does not depend on it
 918     if test "x$have_libdrm" = xyes; then
 919         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 920     fi
 921 fi
 922
 923 AC_ARG_ENABLE([driglx-direct],
 924     [AS_HELP_STRING([--disable-driglx-direct],
 925         [disable direct rendering in GLX and EGL for DRI \
 926             @<:@default=auto@:>@])],
 927     [driglx_direct="$enableval"],
 928     [driglx_direct="yes"])
 929
 930 dnl
 931 dnl libGL configuration per driver
 932 dnl
 933 case "x$enable_glx$enable_xlib_glx" in
 934 xyesyes)
 935     # Xlib-based GLX
 936     dri_modules="x11 xext xcb"
 937     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
 938     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 939     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 940     GL_LIB_DEPS="$XLIBGL_LIBS"
 941     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 942     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 943     ;;
 944 xyesno)
 945     # DRI-based GLX
 946     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 947
 948     # find the DRI deps for libGL
 949     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
 950
 951     if test x"$driglx_direct" = xyes; then
 952         if test x"$dri_platform" = xdrm ; then
 953             DEFINES="$DEFINES -DGLX_USE_DRM"
 954             if test "x$have_libdrm" != xyes; then
 955                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 956             fi
 957
 958             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 959             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 960             if test x"$enable_dri3" = xyes; then
 961                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 962                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 963             fi
 964
 965             if test x"$enable_dri" = xyes; then
 966                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 967             fi
 968
 969             if test x"$enable_dri3" = xyes; then
 970                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
 971                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 972             fi
 973         fi
 974         if test x"$dri_platform" = xapple ; then
 975             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 976         fi
 977     fi
 978
 979     # add xf86vidmode if available
 980     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 981     if test "$HAVE_XF86VIDMODE" = yes ; then
 982         dri_modules="$dri_modules xxf86vm"
 983     fi
 984
 985     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 986     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 987     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 988     GL_LIB_DEPS="$DRIGL_LIBS"
 989
 990     # need DRM libs, $PTHREAD_LIBS, etc.
 991     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 992     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 993     ;;
 994 esac
 995
 996 have_pci_id=no
 997 if test "$have_libudev" = yes; then
 998     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 999     have_pci_id=yes
1000 fi
1001
1002 if test "$have_sysfs" = yes; then
1003     DEFINES="$DEFINES -DHAVE_SYSFS"
1004     have_pci_id=yes
1005 fi
1006
1007 # This is outside the case (above) so that it is invoked even for non-GLX
1008 # builds.
1009 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1010
1011 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1012 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1013 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1014 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1015
1016 AC_SUBST([X11_INCLUDES])
1017 AC_SUBST([GL_LIB_DEPS])
1018 AC_SUBST([GL_PC_REQ_PRIV])
1019 AC_SUBST([GL_PC_LIB_PRIV])
1020 AC_SUBST([GL_PC_CFLAGS])
1021 AC_SUBST([DRI_PC_REQ_PRIV])
1022 AC_SUBST([GLESv1_CM_LIB_DEPS])
1023 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1024 AC_SUBST([GLESv2_LIB_DEPS])
1025 AC_SUBST([GLESv2_PC_LIB_PRIV])
1026
1027 AC_SUBST([HAVE_XF86VIDMODE])
1028
1029 dnl
1030 dnl More GLX setup
1031 dnl
1032 case "x$enable_glx$enable_xlib_glx" in
1033 xyesyes)
1034     DEFINES="$DEFINES -DUSE_XSHM"
1035     ;;
1036 xyesno)
1037     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1038     if test "x$driglx_direct" = xyes; then
1039         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1040     fi
1041     ;;
1042 esac
1043
1044 dnl
1045 dnl TLS detection
1046 dnl
1047
1048 AC_ARG_ENABLE([glx-tls],
1049     [AS_HELP_STRING([--enable-glx-tls],
1050         [enable TLS support in GLX @<:@default=disabled@:>@])],
1051     [GLX_USE_TLS="$enableval"],
1052     [GLX_USE_TLS=no])
1053 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1054
1055 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1056       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1057
1058 dnl
1059 dnl More DRI setup
1060 dnl
1061 dnl Directory for DRI drivers
1062 AC_ARG_WITH([dri-driverdir],
1063     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1064         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1065     [DRI_DRIVER_INSTALL_DIR="$withval"],
1066     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1067 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1068 dnl Extra search path for DRI drivers
1069 AC_ARG_WITH([dri-searchpath],
1070     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1071         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1072     [DRI_DRIVER_SEARCH_DIR="$withval"],
1073     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1074 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1075 dnl Which drivers to build - default is chosen by platform
1076 AC_ARG_WITH([dri-drivers],
1077     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1078         [comma delimited classic DRI drivers list, e.g.
1079         "swrast,i965,radeon" @<:@default=auto@:>@])],
1080     [with_dri_drivers="$withval"],
1081     [with_dri_drivers=auto])
1082
1083 if test "x$with_dri_drivers" = xauto; then
1084     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1085         with_dri_drivers="yes"
1086     else
1087         with_dri_drivers="no"
1088     fi
1089 fi
1090 if test "x$with_dri_drivers" = xno; then
1091     with_dri_drivers=''
1092 fi
1093
1094 dnl If $with_dri_drivers is yes, drivers will be added through
1095 dnl platform checks. Set DEFINES and LIB_DEPS
1096 if test "x$enable_dri" = xyes; then
1097     # Platform specific settings and drivers to build
1098     case "$host_os" in
1099     linux*)
1100         DEFINES="$DEFINES -DHAVE_ALIAS"
1101         if test "x$enable_dri3" = xyes; then
1102             DEFINES="$DEFINES -DHAVE_DRI3"
1103         fi
1104
1105         if test "x$have_pci_id" != xyes; then
1106             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1107         fi
1108
1109         case "$host_cpu" in
1110         powerpc* | sparc*)
1111             # Build only the drivers for cards that exist on PowerPC/sparc
1112             if test "x$with_dri_drivers" = "xyes"; then
1113                 with_dri_drivers="r200 radeon swrast"
1114             fi
1115             ;;
1116         esac
1117         ;;
1118     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1119         DEFINES="$DEFINES -DHAVE_ALIAS"
1120         ;;
1121     gnu*)
1122         DEFINES="$DEFINES -DHAVE_ALIAS"
1123         ;;
1124     cygwin*)
1125         if test "x$with_dri_drivers" = "xyes"; then
1126             with_dri_drivers="swrast"
1127         fi
1128         ;;
1129     darwin*)
1130         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1131         if test "x$with_dri_drivers" = "xyes"; then
1132             with_dri_drivers="swrast"
1133         fi
1134         ;;
1135     esac
1136
1137     # default drivers
1138     if test "x$with_dri_drivers" = "xyes"; then
1139         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1140     fi
1141
1142     # Check for expat
1143     PKG_CHECK_MODULES([EXPAT], [expat], [],
1144         # expat version 2.0 and earlier do not provide expat.pc
1145         [AC_CHECK_HEADER([expat.h],[],
1146                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1147          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1148                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1149          EXPAT_LIBS="-lexpat"])
1150
1151     DRICOMMON_NEED_LIBDRM=no
1152     # If we are building any DRI driver other than swrast.
1153     if test -n "$with_dri_drivers"; then
1154         if test "x$with_dri_drivers" != xswrast; then
1155             # ... libdrm is required
1156             if test "x$have_libdrm" != xyes; then
1157                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1158             fi
1159             DRICOMMON_NEED_LIBDRM=yes
1160         fi
1161     fi
1162
1163     # If we're building any gallium DRI driver other than swrast
1164     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1165         if test "x$with_gallium_drivers" != xswrast; then
1166             # ... build a libdrm aware dricommon
1167             DRICOMMON_NEED_LIBDRM=yes
1168         fi
1169     fi
1170
1171     # put all the necessary libs together
1172     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1173 fi
1174
1175 AC_SUBST([DRI_LIB_DEPS])
1176
1177 DRI_DIRS=''
1178 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1179 if test -n "$with_dri_drivers"; then
1180     if test "x$enable_opengl" != xyes; then
1181         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1182     fi
1183
1184     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1185     for driver in $dri_drivers; do
1186         DRI_DIRS="$DRI_DIRS $driver"
1187         case "x$driver" in
1188         xi915)
1189             HAVE_I915_DRI=yes;
1190             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1191             ;;
1192         xi965)
1193             HAVE_I965_DRI=yes;
1194             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1195             ;;
1196         xnouveau)
1197             HAVE_NOUVEAU_DRI=yes;
1198             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1199             ;;
1200         xradeon)
1201             HAVE_RADEON_DRI=yes;
1202             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1203             ;;
1204         xr200)
1205             HAVE_R200_DRI=yes;
1206             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1207             ;;
1208         xswrast)
1209             HAVE_SWRAST_DRI=yes;
1210             ;;
1211         *)
1212             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1213             ;;
1214         esac
1215     done
1216     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1217 fi
1218
1219 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1220 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1221                                   "x$enable_osmesa" = xyes -o \
1222                                   -n "$DRI_DIRS")
1223
1224 dnl
1225 dnl OSMesa configuration
1226 dnl
1227
1228 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1229 AC_ARG_WITH([osmesa-bits],
1230     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1231         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1232     [osmesa_bits="$withval"],
1233     [osmesa_bits=8])
1234 if test "x$osmesa_bits" != x8; then
1235     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1236         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1237         osmesa_bits=8
1238     fi
1239 fi
1240 case "x$osmesa_bits" in
1241 x8)
1242     OSMESA_LIB="${OSMESA_LIB}"
1243     ;;
1244 x16|x32)
1245     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1246     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1247     ;;
1248 *)
1249     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1250     ;;
1251 esac
1252
1253 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1254     # only link libraries with osmesa if shared
1255     if test "$enable_static" = no; then
1256         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1257     else
1258         OSMESA_LIB_DEPS=""
1259     fi
1260     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1261 fi
1262
1263 AC_SUBST([OSMESA_LIB_DEPS])
1264 AC_SUBST([OSMESA_PC_REQ])
1265 AC_SUBST([OSMESA_PC_LIB_PRIV])
1266
1267 dnl
1268 dnl gbm configuration
1269 dnl
1270 if test "x$enable_gbm" = xauto; then
1271     case "$with_egl_platforms" in
1272         *drm*)
1273             enable_gbm=yes ;;
1274          *)
1275             enable_gbm=no ;;
1276     esac
1277 fi
1278 if test "x$enable_gbm" = xyes; then
1279     if test "x$need_pci_id$have_pci_id" = xyesno; then
1280         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1281     fi
1282
1283     if test "x$enable_dri" = xyes; then
1284         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1285         if test "x$enable_shared_glapi" = xno; then
1286             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1287         fi
1288     else
1289         # Strictly speaking libgbm does not require --enable-dri, although
1290         # both of its backends do. Thus one can build libgbm without any
1291         # backends if --disable-dri is set.
1292         # To avoid unnecessary complexity of checking if at least one backend
1293         # is available when building, just mandate --enable-dri.
1294         AC_MSG_ERROR([gbm requires --enable-dri])
1295     fi
1296 fi
1297 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1298 if test "x$need_pci_id$have_libudev" = xyesyes; then
1299     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1300 else
1301     GBM_PC_REQ_PRIV=""
1302 fi
1303 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1304 AC_SUBST([GBM_PC_REQ_PRIV])
1305 AC_SUBST([GBM_PC_LIB_PRIV])
1306
1307 dnl
1308 dnl EGL configuration
1309 dnl
1310 EGL_CLIENT_APIS=""
1311
1312 if test "x$enable_egl" = xyes; then
1313     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1314
1315     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1316
1317     if test "$enable_static" != yes; then
1318         if test "x$enable_dri" = xyes; then
1319             HAVE_EGL_DRIVER_DRI2=1
1320         fi
1321
1322     fi
1323 fi
1324 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1325 AC_SUBST([EGL_LIB_DEPS])
1326
1327 dnl
1328 dnl XA configuration
1329 dnl
1330 if test "x$enable_xa" = xyes; then
1331     if test "x$with_gallium_drivers" = xswrast; then
1332        AC_MSG_ERROR([
1333           Building xa requires at least one non swrast gallium driver.
1334           If you are looking to use libxatracker.so with the VMware driver,
1335           make sure to include svga in the gallium drivers list, apart from
1336           enabling XA.
1337           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1338     fi
1339     enable_gallium_loader=$enable_shared_pipe_drivers
1340 fi
1341 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1342
1343 dnl
1344 dnl OpenVG configuration
1345 dnl
1346 VG_LIB_DEPS=""
1347
1348 if test "x$enable_openvg" = xyes; then
1349     if test "x$enable_egl" = xno; then
1350         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1351     fi
1352     if test -z "$with_gallium_drivers"; then
1353         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1354     fi
1355
1356     AC_MSG_ERROR([Cannot enable OpenVG, because egl_gallium has been removed and
1357                   OpenVG has not been integrated into standard libEGL yet])
1358
1359     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1360     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1361     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1362     AC_SUBST([VG_PC_LIB_PRIV])
1363 fi
1364 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1365
1366 dnl
1367 dnl Gallium G3DVL configuration
1368 dnl
1369 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1370     if test "x$enable_xvmc" = xauto; then
1371         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1372     fi
1373
1374     if test "x$enable_vdpau" = xauto; then
1375         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1376     fi
1377
1378     if test "x$enable_omx" = xauto; then
1379         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1380     fi
1381
1382     if test "x$enable_va" = xauto; then
1383         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1384     fi
1385 fi
1386
1387 if test "x$enable_xvmc" = xyes -o \
1388         "x$enable_vdpau" = xyes -o \
1389         "x$enable_omx" = xyes -o \
1390         "x$enable_va" = xyes; then
1391     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1392     need_gallium_vl=yes
1393 fi
1394 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1395
1396 if test "x$enable_xvmc" = xyes; then
1397     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1398     enable_gallium_loader=$enable_shared_pipe_drivers
1399 fi
1400 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1401
1402 if test "x$enable_vdpau" = xyes; then
1403     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1404     enable_gallium_loader=$enable_shared_pipe_drivers
1405 fi
1406 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1407
1408 if test "x$enable_omx" = xyes; then
1409     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1410     enable_gallium_loader=$enable_shared_pipe_drivers
1411 fi
1412 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1413
1414 if test "x$enable_va" = xyes; then
1415     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1416     enable_gallium_loader=$enable_shared_pipe_drivers
1417 fi
1418 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1419
1420 dnl
1421 dnl Nine Direct3D9 configuration
1422 dnl
1423 if test "x$enable_nine" = xyes; then
1424     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1425         AC_MSG_ERROR([nine requires the gallium swrast driver])
1426     fi
1427     if test "x$with_gallium_drivers" == xswrast; then
1428         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1429     fi
1430     if test "x$enable_dri3" = xno; then
1431         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1432     fi
1433
1434     enable_gallium_loader=$enable_shared_pipe_drivers
1435 fi
1436 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1437
1438 dnl
1439 dnl OpenCL configuration
1440 dnl
1441
1442 AC_ARG_WITH([libclc-path],
1443    [AS_HELP_STRING([--with-libclc-path],
1444          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1445    [LIBCLC_PATH="$withval"],
1446    [LIBCLC_PATH=''])
1447
1448 if test -n "$LIBCLC_PATH"; then
1449    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1450                   Please review the updated build instructions for clover:
1451                   http://dri.freedesktop.org/wiki/GalliumCompute])
1452 fi
1453
1454
1455 AC_ARG_WITH([clang-libdir],
1456    [AS_HELP_STRING([--with-clang-libdir],
1457          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1458    [CLANG_LIBDIR="$withval"],
1459    [CLANG_LIBDIR=''])
1460
1461 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1462 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1463
1464 if test "x$enable_opencl" = xyes; then
1465     if test -z "$with_gallium_drivers"; then
1466         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1467     fi
1468
1469     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1470         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1471     fi
1472
1473     if test "x$have_libclc" = xno; then
1474         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1475                     Make sure the directory containing libclc.pc is specified in your
1476                     PKG_CONFIG_PATH environment variable.
1477                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1478     else
1479         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1480         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1481         AC_SUBST([LIBCLC_INCLUDEDIR])
1482         AC_SUBST([LIBCLC_LIBEXECDIR])
1483     fi
1484
1485     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1486     enable_gallium_loader=yes
1487
1488     if test "x$enable_opencl_icd" = xyes; then
1489         OPENCL_LIBNAME="MesaOpenCL"
1490     else
1491         OPENCL_LIBNAME="OpenCL"
1492     fi
1493
1494     if test "x$have_libelf" != xyes; then
1495        AC_MSG_ERROR([Clover requires libelf])
1496     fi
1497 fi
1498 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1499 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1500 AC_SUBST([OPENCL_LIBNAME])
1501
1502 dnl
1503 dnl Gallium configuration
1504 dnl
1505 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1506
1507 AC_SUBST([LLVM_BINDIR])
1508 AC_SUBST([LLVM_CFLAGS])
1509 AC_SUBST([LLVM_CPPFLAGS])
1510 AC_SUBST([LLVM_CXXFLAGS])
1511 AC_SUBST([LLVM_LIBDIR])
1512 AC_SUBST([LLVM_LIBS])
1513 AC_SUBST([LLVM_LDFLAGS])
1514 AC_SUBST([LLVM_INCLUDEDIR])
1515 AC_SUBST([LLVM_VERSION])
1516 AC_SUBST([CLANG_RESOURCE_DIR])
1517
1518 case "x$enable_opengl$enable_gles1$enable_gles2" in
1519 x*yes*)
1520     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1521     ;;
1522 esac
1523
1524 AC_SUBST([VG_LIB_DEPS])
1525 AC_SUBST([EGL_CLIENT_APIS])
1526
1527 dnl
1528 dnl EGL Platforms configuration
1529 dnl
1530 AC_ARG_WITH([egl-platforms],
1531     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1532         [comma delimited native platforms libEGL supports, e.g.
1533         "x11,drm" @<:@default=auto@:>@])],
1534     [with_egl_platforms="$withval"],
1535     [if test "x$enable_egl" = xyes; then
1536         with_egl_platforms="x11"
1537     else
1538         with_egl_platforms=""
1539     fi])
1540
1541 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1542     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1543 fi
1544
1545 # Do per-EGL platform setups and checks
1546 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1547 for plat in $egl_platforms; do
1548         case "$plat" in
1549         wayland)
1550                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1551
1552                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1553                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1554                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1555                 ;;
1556
1557         x11)
1558                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1559                 ;;
1560
1561         drm)
1562                 test "x$enable_gbm" = "xno" &&
1563                         AC_MSG_ERROR([EGL platform drm needs gbm])
1564                 test "x$have_libdrm" != xyes &&
1565                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1566                 ;;
1567
1568         android|fbdev|gdi|null)
1569                 ;;
1570
1571         *)
1572                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1573                 ;;
1574         esac
1575
1576         case "$plat$need_pci_id$have_pci_id" in
1577                 waylandyesno|drmyesno)
1578                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1579         esac
1580 done
1581
1582 # libEGL wants to default to the first platform specified in
1583 # ./configure.  parse that here.
1584 if test "x$egl_platforms" != "x"; then
1585     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1586     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1587 else
1588     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1589 fi
1590
1591 if echo "$egl_platforms" | grep -q 'x11'; then
1592     NEED_WINSYS_XLIB=yes
1593 fi
1594 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1595 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1596 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1597 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1598 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1599
1600 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1601
1602 AC_SUBST([EGL_NATIVE_PLATFORM])
1603 AC_SUBST([EGL_CFLAGS])
1604
1605 # If we don't have the X11 platform, set this define so we don't try to include
1606 # the X11 headers.
1607 if ! echo "$egl_platforms" | grep -q 'x11'; then
1608     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1609     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1610 fi
1611
1612 AC_ARG_WITH([max-width],
1613     [AS_HELP_STRING([--with-max-width=N],
1614                     [Maximum framebuffer width (4096)])],
1615     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1616      AS_IF([test "${withval}" -gt "4096"],
1617            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1618 )
1619 AC_ARG_WITH([max-height],
1620     [AS_HELP_STRING([--with-max-height=N],
1621                     [Maximum framebuffer height (4096)])],
1622     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1623      AS_IF([test "${withval}" -gt "4096"],
1624            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1625 )
1626
1627 dnl
1628 dnl Gallium LLVM
1629 dnl
1630 AC_ARG_ENABLE([gallium-llvm],
1631     [AS_HELP_STRING([--enable-gallium-llvm],
1632         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1633     [enable_gallium_llvm="$enableval"],
1634     [enable_gallium_llvm=auto])
1635
1636 AC_ARG_ENABLE([llvm-shared-libs],
1637     [AS_HELP_STRING([--enable-llvm-shared-libs],
1638         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1639     [enable_llvm_shared_libs="$enableval"],
1640     [enable_llvm_shared_libs=yes])
1641
1642 AC_ARG_WITH([llvm-prefix],
1643     [AS_HELP_STRING([--with-llvm-prefix],
1644         [Prefix for LLVM installations in non-standard locations])],
1645     [llvm_prefix="$withval"],
1646     [llvm_prefix=''])
1647
1648
1649 # Call this inside ` ` to get the return value.
1650 # $1 is the llvm-config command with arguments.
1651 strip_unwanted_llvm_flags() {
1652     # Use \> (marks the end of the word)
1653     echo `$1` | sed \
1654         -e 's/-DNDEBUG\>//g' \
1655         -e 's/-D_GNU_SOURCE\>//g' \
1656         -e 's/-pedantic\>//g' \
1657         -e 's/-Wcovered-switch-default\>//g' \
1658         -e 's/-O.\>//g' \
1659         -e 's/-g\>//g' \
1660         -e 's/-Wall\>//g' \
1661         -e 's/-Wcast-qual\>//g' \
1662         -e 's/-Woverloaded-virtual\>//g' \
1663         -e 's/-fcolor-diagnostics\>//g' \
1664         -e 's/-fdata-sections\>//g' \
1665         -e 's/-ffunction-sections\>//g' \
1666         -e 's/-fno-exceptions\>//g' \
1667         -e 's/-fomit-frame-pointer\>//g' \
1668         -e 's/-fvisibility-inlines-hidden\>//g' \
1669         -e 's/-fPIC\>//g' \
1670         -e 's/-fstack-protector-strong\>//g'
1671 }
1672
1673
1674 if test -z "$with_gallium_drivers"; then
1675     enable_gallium_llvm=no
1676 fi
1677 if test "x$enable_gallium_llvm" = xauto; then
1678     case "$host_cpu" in
1679     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1680     esac
1681 fi
1682 if test "x$enable_gallium_llvm" = xyes; then
1683     if test -n "$llvm_prefix"; then
1684         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1685     else
1686         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1687     fi
1688
1689     if test "x$LLVM_CONFIG" != xno; then
1690         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1691         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1692         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1693         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1694         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1695         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1696         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1697         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1698
1699         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1700             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1701         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1702             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1703
1704         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1705         if test -z "$LLVM_VERSION_PATCH"; then
1706             LLVM_VERSION_PATCH=0
1707         fi
1708
1709         if test -n "${LLVM_VERSION_MAJOR}"; then
1710             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1711         else
1712             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1713         fi
1714
1715         LLVM_REQUIRED_VERSION_MAJOR="3"
1716         LLVM_REQUIRED_VERSION_MINOR="3"
1717         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1718             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1719         fi
1720
1721         LLVM_COMPONENTS="engine bitwriter"
1722         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1723             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1724         fi
1725
1726         if test "x$enable_opencl" = xyes; then
1727             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1728             # LLVM 3.3 >= 177971 requires IRReader
1729             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1730                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1731             fi
1732             # LLVM 3.4 requires Option
1733             if $LLVM_CONFIG --components | grep -qw 'option'; then
1734                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1735             fi
1736             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1737             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1738                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1739             fi
1740             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1741                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1742             fi
1743         fi
1744         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1745         MESA_LLVM=1
1746
1747         dnl Check for Clang internal headers
1748         if test "x$enable_opencl" = xyes; then
1749             if test -z "$CLANG_LIBDIR"; then
1750                 CLANG_LIBDIR=${LLVM_LIBDIR}
1751             fi
1752             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1753             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1754                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1755         fi
1756     else
1757         MESA_LLVM=0
1758         LLVM_VERSION_INT=0
1759     fi
1760 else
1761     MESA_LLVM=0
1762     LLVM_VERSION_INT=0
1763
1764     if test "x$enable_opencl" = xyes; then
1765         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1766     fi
1767 fi
1768
1769 dnl Directory for XVMC libs
1770 AC_ARG_WITH([xvmc-libdir],
1771     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1772         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1773     [XVMC_LIB_INSTALL_DIR="$withval"],
1774     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1775 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1776
1777 dnl
1778 dnl Gallium Tests
1779 dnl
1780 if test "x$enable_gallium_tests" = xyes; then
1781     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1782     enable_gallium_loader=yes
1783 fi
1784 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1785
1786 dnl Directory for VDPAU libs
1787 AC_ARG_WITH([vdpau-libdir],
1788     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1789         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1790     [VDPAU_LIB_INSTALL_DIR="$withval"],
1791     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1792 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1793
1794 dnl Directory for OMX libs
1795
1796 AC_ARG_WITH([omx-libdir],
1797     [AS_HELP_STRING([--with-omx-libdir=DIR],
1798         [directory for the OMX libraries])],
1799     [OMX_LIB_INSTALL_DIR="$withval"],
1800     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1801 AC_SUBST([OMX_LIB_INSTALL_DIR])
1802
1803 dnl Directory for VA libs
1804
1805 AC_ARG_WITH([va-libdir],
1806     [AS_HELP_STRING([--with-va-libdir=DIR],
1807         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1808     [VA_LIB_INSTALL_DIR="$withval"],
1809     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1810 AC_SUBST([VA_LIB_INSTALL_DIR])
1811
1812 AC_ARG_WITH([d3d-libdir],
1813     [AS_HELP_STRING([--with-d3d-libdir=DIR],
1814         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
1815     [D3D_DRIVER_INSTALL_DIR="$withval"],
1816     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
1817 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
1818
1819 dnl
1820 dnl Gallium helper functions
1821 dnl
1822 gallium_require_drm() {
1823     if test "x$have_libdrm" != xyes; then
1824        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1825     fi
1826 }
1827
1828 gallium_require_llvm() {
1829     if test "x$MESA_LLVM" = x0; then
1830         case "$host" in *gnux32) return;; esac
1831         case "$host_cpu" in
1832         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1833         esac
1834     fi
1835 }
1836
1837 gallium_require_drm_loader() {
1838     if test "x$enable_gallium_loader" = xyes; then
1839         if test "x$need_pci_id$have_pci_id" = xyesno; then
1840             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1841         fi
1842         enable_gallium_drm_loader=yes
1843     fi
1844     if test "x$enable_va" = xyes && test "x$7" != x; then
1845          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1846     fi
1847 }
1848
1849 require_egl_drm() {
1850     case "$with_egl_platforms" in
1851         *drm*)
1852             ;;
1853          *)
1854             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1855             ;;
1856     esac
1857     if test "x$enable_gbm" != xyes; then
1858             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1859     fi
1860 }
1861
1862 radeon_llvm_check() {
1863     if test "x$enable_gallium_llvm" != "xyes"; then
1864         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1865     fi
1866     LLVM_REQUIRED_VERSION_MAJOR="3"
1867     LLVM_REQUIRED_VERSION_MINOR="4"
1868     LLVM_REQUIRED_VERSION_PATCH="2"
1869     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1870         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1871     fi
1872     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1873         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1874                       sources with the --enable-experimental-targets=R600
1875                       configure flag])
1876     fi
1877     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1878     NEED_RADEON_LLVM=yes
1879     if test "x$have_libelf" != xyes; then
1880        AC_MSG_ERROR([$1 requires libelf when using llvm])
1881     fi
1882 }
1883
1884 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1885 if test -n "$with_gallium_drivers"; then
1886     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1887     for driver in $gallium_drivers; do
1888         case "x$driver" in
1889         xsvga)
1890             HAVE_GALLIUM_SVGA=yes
1891             gallium_require_drm "svga"
1892             gallium_require_drm_loader
1893             ;;
1894         xi915)
1895             HAVE_GALLIUM_I915=yes
1896             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1897             gallium_require_drm "Gallium i915"
1898             gallium_require_drm_loader
1899             ;;
1900         xilo)
1901             HAVE_GALLIUM_ILO=yes
1902             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1903             gallium_require_drm "Gallium i965/ilo"
1904             gallium_require_drm_loader
1905             ;;
1906         xr300)
1907             HAVE_GALLIUM_R300=yes
1908             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1909             gallium_require_drm "Gallium R300"
1910             gallium_require_drm_loader
1911             gallium_require_llvm "Gallium R300"
1912             ;;
1913         xr600)
1914             HAVE_GALLIUM_R600=yes
1915             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1916             gallium_require_drm "Gallium R600"
1917             gallium_require_drm_loader
1918             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1919                 radeon_llvm_check "r600g"
1920                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1921             fi
1922             if test "x$enable_r600_llvm" = xyes; then
1923                 USE_R600_LLVM_COMPILER=yes;
1924             fi
1925             if test "x$enable_opencl" = xyes; then
1926                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1927             fi
1928             ;;
1929         xradeonsi)
1930             HAVE_GALLIUM_RADEONSI=yes
1931             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1932             gallium_require_drm "radeonsi"
1933             gallium_require_drm_loader
1934             radeon_llvm_check "radeonsi"
1935             require_egl_drm "radeonsi"
1936             ;;
1937         xnouveau)
1938             HAVE_GALLIUM_NOUVEAU=yes
1939             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1940             gallium_require_drm "nouveau"
1941             gallium_require_drm_loader
1942             ;;
1943         xfreedreno)
1944             HAVE_GALLIUM_FREEDRENO=yes
1945             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1946             gallium_require_drm "freedreno"
1947             gallium_require_drm_loader
1948             ;;
1949         xswrast)
1950             HAVE_GALLIUM_SOFTPIPE=yes
1951             if test "x$MESA_LLVM" = x1; then
1952                 HAVE_GALLIUM_LLVMPIPE=yes
1953             fi
1954             ;;
1955         xvc4)
1956             HAVE_GALLIUM_VC4=yes
1957             gallium_require_drm "vc4"
1958             gallium_require_drm_loader
1959
1960             case "$host_cpu" in
1961                 i?86 | x86_64 | amd64)
1962                 USE_VC4_SIMULATOR=yes
1963                 ;;
1964             esac
1965             ;;
1966         *)
1967             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1968             ;;
1969         esac
1970     done
1971 fi
1972
1973 dnl Set LLVM_LIBS - This is done after the driver configuration so
1974 dnl that drivers can add additional components to LLVM_COMPONENTS.
1975 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1976 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1977 dnl this was causing the same libraries to be appear multiple times
1978 dnl in LLVM_LIBS.
1979
1980 if test "x$MESA_LLVM" != x0; then
1981
1982     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1983
1984     if test "x$enable_llvm_shared_libs" = xyes; then
1985         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1986         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1987         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1988
1989         if test "x$llvm_have_one_so" = xyes; then
1990             dnl LLVM was built using auto*, so there is only one shared object.
1991             LLVM_LIBS="-l$LLVM_SO_NAME"
1992         else
1993             dnl If LLVM was built with CMake, there will be one shared object per
1994             dnl component.
1995             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1996                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1997         Please make sure you have built llvm with the --enable-shared option
1998         and that your llvm libraries are installed in $LLVM_LIBDIR
1999         If you have installed your llvm libraries to a different directory you
2000         can use the --with-llvm-prefix= configure flag to specify this directory.
2001         NOTE: Mesa is attempting to use llvm shared libraries by default.
2002         If you do not want to build with llvm shared libraries and instead want to
2003         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2004         invocation and rebuild.])])
2005
2006            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2007            dnl install uses a shared object for each component and we have
2008            dnl already added all of these objects to LLVM_LIBS.
2009         fi
2010     else
2011         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2012         dnl We need to link to llvm system libs when using static libs
2013         dnl However, only llvm 3.5+ provides --system-libs
2014         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2015             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2016         fi
2017     fi
2018 fi
2019
2020 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2021 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2022 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2023 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2024 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2025 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2026 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2027                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2028 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2029 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2030 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2031 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2032 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2033
2034 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2035
2036 # NOTE: anything using xcb or other client side libs ends up in separate
2037 #       _CLIENT variables.  The pipe loader is built in two variants,
2038 #       one that is standalone and does not link any x client libs (for
2039 #       use by XA tracker in particular, but could be used in any case
2040 #       where communication with xserver is not desired).
2041 if test "x$enable_gallium_loader" = xyes; then
2042     if test "x$NEED_WINSYS_XLIB" = xyes; then
2043         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2044     fi
2045
2046     if test "x$enable_dri" = xyes; then
2047         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2048     fi
2049
2050     if test "x$enable_gallium_drm_loader" = xyes; then
2051         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2052         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2053                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2054         if test "x$pipe_loader_have_xcb" = xyes; then
2055             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2056             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2057         fi
2058     fi
2059
2060     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2061     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2062
2063     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2064     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2065     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2066     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2067 fi
2068
2069 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2070 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2071 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2072 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2073 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2074 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2075
2076 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2077                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2078                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2079 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2080 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2081 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2082 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2083 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2084 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2085 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2086 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2087 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2088     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2089 fi
2090
2091 AC_SUBST([ELF_LIB])
2092
2093 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2094 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2095 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2096 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2097 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2098
2099 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2100 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2101 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2102
2103 AC_SUBST([NINE_MAJOR], 1)
2104 AC_SUBST([NINE_MINOR], 0)
2105 AC_SUBST([NINE_TINY], 0)
2106 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2107
2108 AC_SUBST([VDPAU_MAJOR], 1)
2109 AC_SUBST([VDPAU_MINOR], 0)
2110
2111 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2112 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2113 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2114 AC_SUBST([VA_MINOR], $VA_MINOR)
2115
2116 AC_SUBST([XVMC_MAJOR], 1)
2117 AC_SUBST([XVMC_MINOR], 0)
2118
2119 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2120 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2121 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2122 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2123
2124 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2125 AC_SUBST([XA_MINOR], $XA_MINOR)
2126 AC_SUBST([XA_TINY], $XA_TINY)
2127 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2128
2129 dnl Restore LDFLAGS and CPPFLAGS
2130 LDFLAGS="$_SAVE_LDFLAGS"
2131 CPPFLAGS="$_SAVE_CPPFLAGS"
2132
2133 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2134 if test "x$acv_mesa_CLANG" = xyes; then
2135     CFLAGS="$CFLAGS -Qunused-arguments"
2136     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2137 fi
2138
2139 dnl Add user CFLAGS and CXXFLAGS
2140 CFLAGS="$CFLAGS $USER_CFLAGS"
2141 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2142
2143 dnl Substitute the config
2144 AC_CONFIG_FILES([Makefile
2145                 src/Makefile
2146                 src/egl/drivers/dri2/Makefile
2147                 src/egl/main/Makefile
2148                 src/egl/main/egl.pc
2149                 src/egl/wayland/wayland-drm/Makefile
2150                 src/egl/wayland/wayland-egl/Makefile
2151                 src/egl/wayland/wayland-egl/wayland-egl.pc
2152                 src/gallium/Makefile
2153                 src/gallium/auxiliary/Makefile
2154                 src/gallium/auxiliary/pipe-loader/Makefile
2155                 src/gallium/drivers/freedreno/Makefile
2156                 src/gallium/drivers/galahad/Makefile
2157                 src/gallium/drivers/i915/Makefile
2158                 src/gallium/drivers/identity/Makefile
2159                 src/gallium/drivers/ilo/Makefile
2160                 src/gallium/drivers/llvmpipe/Makefile
2161                 src/gallium/drivers/noop/Makefile
2162                 src/gallium/drivers/nouveau/Makefile
2163                 src/gallium/drivers/r300/Makefile
2164                 src/gallium/drivers/r600/Makefile
2165                 src/gallium/drivers/radeon/Makefile
2166                 src/gallium/drivers/radeonsi/Makefile
2167                 src/gallium/drivers/rbug/Makefile
2168                 src/gallium/drivers/softpipe/Makefile
2169                 src/gallium/drivers/svga/Makefile
2170                 src/gallium/drivers/trace/Makefile
2171                 src/gallium/drivers/vc4/Makefile
2172                 src/gallium/drivers/vc4/kernel/Makefile
2173                 src/gallium/state_trackers/clover/Makefile
2174                 src/gallium/state_trackers/dri/Makefile
2175                 src/gallium/state_trackers/glx/xlib/Makefile
2176                 src/gallium/state_trackers/nine/Makefile
2177                 src/gallium/state_trackers/omx/Makefile
2178                 src/gallium/state_trackers/osmesa/Makefile
2179                 src/gallium/state_trackers/va/Makefile
2180                 src/gallium/state_trackers/vdpau/Makefile
2181                 src/gallium/state_trackers/vega/Makefile
2182                 src/gallium/state_trackers/xa/Makefile
2183                 src/gallium/state_trackers/xvmc/Makefile
2184                 src/gallium/targets/d3dadapter9/Makefile
2185                 src/gallium/targets/d3dadapter9/d3d.pc
2186                 src/gallium/targets/dri/Makefile
2187                 src/gallium/targets/libgl-xlib/Makefile
2188                 src/gallium/targets/omx/Makefile
2189                 src/gallium/targets/opencl/Makefile
2190                 src/gallium/targets/osmesa/Makefile
2191                 src/gallium/targets/osmesa/osmesa.pc
2192                 src/gallium/targets/pipe-loader/Makefile
2193                 src/gallium/targets/va/Makefile
2194                 src/gallium/targets/vdpau/Makefile
2195                 src/gallium/targets/xa/Makefile
2196                 src/gallium/targets/xa/xatracker.pc
2197                 src/gallium/targets/xvmc/Makefile
2198                 src/gallium/tests/trivial/Makefile
2199                 src/gallium/tests/unit/Makefile
2200                 src/gallium/winsys/freedreno/drm/Makefile
2201                 src/gallium/winsys/i915/drm/Makefile
2202                 src/gallium/winsys/intel/drm/Makefile
2203                 src/gallium/winsys/nouveau/drm/Makefile
2204                 src/gallium/winsys/radeon/drm/Makefile
2205                 src/gallium/winsys/svga/drm/Makefile
2206                 src/gallium/winsys/sw/dri/Makefile
2207                 src/gallium/winsys/sw/fbdev/Makefile
2208                 src/gallium/winsys/sw/kms-dri/Makefile
2209                 src/gallium/winsys/sw/null/Makefile
2210                 src/gallium/winsys/sw/wayland/Makefile
2211                 src/gallium/winsys/sw/wrapper/Makefile
2212                 src/gallium/winsys/sw/xlib/Makefile
2213                 src/gallium/winsys/vc4/drm/Makefile
2214                 src/gbm/Makefile
2215                 src/gbm/main/gbm.pc
2216                 src/glsl/Makefile
2217                 src/glx/Makefile
2218                 src/glx/apple/Makefile
2219                 src/glx/tests/Makefile
2220                 src/gtest/Makefile
2221                 src/loader/Makefile
2222                 src/mapi/Makefile
2223                 src/mapi/es1api/glesv1_cm.pc
2224                 src/mapi/es2api/glesv2.pc
2225                 src/mapi/glapi/gen/Makefile
2226                 src/mapi/vgapi/Makefile
2227                 src/mapi/vgapi/vg.pc
2228                 src/mesa/Makefile
2229                 src/mesa/gl.pc
2230                 src/mesa/drivers/dri/dri.pc
2231                 src/mesa/drivers/dri/common/Makefile
2232                 src/mesa/drivers/dri/common/xmlpool/Makefile
2233                 src/mesa/drivers/dri/i915/Makefile
2234                 src/mesa/drivers/dri/i965/Makefile
2235                 src/mesa/drivers/dri/Makefile
2236                 src/mesa/drivers/dri/nouveau/Makefile
2237                 src/mesa/drivers/dri/r200/Makefile
2238                 src/mesa/drivers/dri/radeon/Makefile
2239                 src/mesa/drivers/dri/swrast/Makefile
2240                 src/mesa/drivers/osmesa/Makefile
2241                 src/mesa/drivers/osmesa/osmesa.pc
2242                 src/mesa/drivers/x11/Makefile
2243                 src/mesa/main/tests/Makefile
2244                 src/util/Makefile
2245                 src/util/tests/hash_table/Makefile])
2246
2247 AC_OUTPUT
2248
2249 dnl
2250 dnl Output some configuration info for the user
2251 dnl
2252 echo ""
2253 echo "        prefix:          $prefix"
2254 echo "        exec_prefix:     $exec_prefix"
2255 echo "        libdir:          $libdir"
2256 echo "        includedir:      $includedir"
2257
2258 dnl API info
2259 echo ""
2260 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2261 echo "        OpenVG:          $enable_openvg"
2262
2263 dnl Driver info
2264 echo ""
2265 case "x$enable_osmesa$enable_gallium_osmesa" in
2266 xnoyes)
2267         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2268         ;;
2269 xyesno)
2270         echo "        OSMesa:          lib$OSMESA_LIB"
2271         ;;
2272 xnono)
2273         echo "        OSMesa:          no"
2274         ;;
2275 esac
2276
2277 echo ""
2278 if test "x$enable_dri" != xno; then
2279         echo "        DRI platform:    $dri_platform"
2280         if test -z "$DRI_DIRS"; then
2281             echo "        DRI drivers:     no"
2282         else
2283             echo "        DRI drivers:     $DRI_DIRS"
2284         fi
2285         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2286 fi
2287
2288 case "x$enable_glx$enable_xlib_glx" in
2289 xyesyes)
2290     echo "        GLX:             Xlib-based"
2291     ;;
2292 xyesno)
2293     echo "        GLX:             DRI-based"
2294     ;;
2295 *)
2296     echo "        GLX:             $enable_glx"
2297     ;;
2298 esac
2299
2300 dnl EGL
2301 echo ""
2302 echo "        EGL:             $enable_egl"
2303 if test "$enable_egl" = yes; then
2304     echo "        EGL platforms:   $egl_platforms"
2305
2306     egl_drivers=""
2307     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2308         egl_drivers="$egl_drivers builtin:egl_dri2"
2309     fi
2310
2311     echo "        EGL drivers:    $egl_drivers"
2312 fi
2313
2314 echo ""
2315 if test "x$MESA_LLVM" = x1; then
2316     echo "        llvm:            yes"
2317     echo "        llvm-config:     $LLVM_CONFIG"
2318     echo "        llvm-version:    $LLVM_VERSION"
2319 else
2320     echo "        llvm:            no"
2321 fi
2322
2323 echo ""
2324 if test -n "$with_gallium_drivers"; then
2325     echo "        Gallium:         yes"
2326 else
2327     echo "        Gallium:         no"
2328 fi
2329
2330
2331 dnl Libraries
2332 echo ""
2333 echo "        Shared libs:     $enable_shared"
2334 echo "        Static libs:     $enable_static"
2335 echo "        Shared-glapi:    $enable_shared_glapi"
2336
2337 dnl Compiler options
2338 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2339 cflags=`echo $CFLAGS | \
2340     $SED 's/^ *//;s/  */ /;s/ *$//'`
2341 cxxflags=`echo $CXXFLAGS | \
2342     $SED 's/^ *//;s/  */ /;s/ *$//'`
2343 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2344 echo ""
2345 echo "        CFLAGS:          $cflags"
2346 echo "        CXXFLAGS:        $cxxflags"
2347 echo "        Macros:          $defines"
2348 echo ""
2349 if test "x$MESA_LLVM" = x1; then
2350     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2351     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2352     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2353     echo ""
2354 fi
2355 echo "        PYTHON2:         $PYTHON2"
2356
2357 echo ""
2358 echo "        Run '${MAKE-make}' to build Mesa"
2359 echo ""