configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AX_PYTHON_MODULE([libxml2], [needed])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 LT_PREREQ([2.2])
  62 LT_INIT([disable-static])
  63
  64 AX_PROG_BISON([],
  65               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  66                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  67 AX_PROG_FLEX([],
  68              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  69                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  70
  71 AC_PATH_PROG([PERL], [perl])
  72
  73 AC_CHECK_PROG(INDENT, indent, indent, cat)
  74 if test "x$INDENT" != "xcat"; then
  75     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  76 fi
  77
  78 AC_PROG_INSTALL
  79
  80 dnl We need a POSIX shell for parts of the build. Assume we have one
  81 dnl in most cases.
  82 case "$host_os" in
  83 solaris*)
  84     # Solaris /bin/sh is too old/non-POSIX compliant
  85     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  86     SHELL="$POSIX_SHELL"
  87     ;;
  88 esac
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 GEN_ASM_OFFSETS=no
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124
 125     if test "x$cross_compiling" = xyes; then
 126         GEN_ASM_OFFSETS=yes
 127     fi
 128 fi
 129
 130 dnl Check for compiler builtins
 131 AX_GCC_BUILTIN([__builtin_bswap32])
 132 AX_GCC_BUILTIN([__builtin_bswap64])
 133
 134 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 135
 136 dnl Make sure the pkg-config macros are defined
 137 m4_ifndef([PKG_PROG_PKG_CONFIG],
 138     [m4_fatal([Could not locate the pkg-config autoconf macros.
 139   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 140   are in a different location, try setting the environment variable
 141   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 142 PKG_PROG_PKG_CONFIG()
 143
 144 dnl LIB_DIR - library basename
 145 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 146 AC_SUBST([LIB_DIR])
 147
 148 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 149 _SAVE_LDFLAGS="$LDFLAGS"
 150 _SAVE_CPPFLAGS="$CPPFLAGS"
 151
 152 dnl Compiler macros
 153 DEFINES=""
 154 AC_SUBST([DEFINES])
 155 case "$host_os" in
 156 linux*|*-gnu*|gnu*)
 157     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 158     ;;
 159 solaris*)
 160     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 161     ;;
 162 cygwin*)
 163     DEFINES="$DEFINES -DHAVE_PTHREAD"
 164     ;;
 165 esac
 166
 167 dnl Add flags for gcc and g++
 168 if test "x$GCC" = xyes; then
 169     case "$host_os" in
 170     cygwin*)
 171         CFLAGS="$CFLAGS -Wall -std=gnu99"
 172         ;;
 173     *)
 174         CFLAGS="$CFLAGS -Wall -std=c99"
 175         ;;
 176     esac
 177
 178     # Enable -Werror=implicit-function-declaration and
 179     # -Werror=missing-prototypes, if available, or otherwise, just
 180     # -Wmissing-prototypes.  This is particularly useful to avoid
 181     # generating a loadable driver module that has undefined symbols.
 182     save_CFLAGS="$CFLAGS"
 183     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 184     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 185     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 187                    AC_MSG_RESULT([yes]),
 188                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 189                     AC_MSG_RESULT([no])]);
 190
 191     # Enable -fvisibility=hidden if using a gcc that supports it
 192     save_CFLAGS="$CFLAGS"
 193     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 194     VISIBILITY_CFLAGS="-fvisibility=hidden"
 195     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 196     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 197                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 198
 199     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 200     CFLAGS=$save_CFLAGS
 201
 202     # Work around aliasing bugs - developers should comment this out
 203     CFLAGS="$CFLAGS -fno-strict-aliasing"
 204
 205     # gcc's builtin memcmp is slower than glibc's
 206     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 207     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 208 fi
 209 if test "x$GXX" = xyes; then
 210     CXXFLAGS="$CXXFLAGS -Wall"
 211
 212     # Enable -fvisibility=hidden if using a gcc that supports it
 213     save_CXXFLAGS="$CXXFLAGS"
 214     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 215     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 216     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 217     AC_LANG_PUSH([C++])
 218     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 219                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 220     AC_LANG_POP([C++])
 221
 222     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 223     CXXFLAGS=$save_CXXFLAGS
 224
 225     # Work around aliasing bugs - developers should comment this out
 226     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 227
 228     # gcc's builtin memcmp is slower than glibc's
 229     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 230     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 231 fi
 232
 233 dnl even if the compiler appears to support it, using visibility attributes isn't
 234 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 235 case "$host_os" in
 236 cygwin*)
 237     VISIBILITY_CFLAGS=""
 238     VISIBILITY_CXXFLAGS=""
 239     ;;
 240 esac
 241
 242 AC_SUBST([VISIBILITY_CFLAGS])
 243 AC_SUBST([VISIBILITY_CXXFLAGS])
 244
 245 dnl
 246 dnl Optional flags, check for compiler support
 247 dnl
 248 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 249 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 250
 251 dnl
 252 dnl Hacks to enable 32 or 64 bit build
 253 dnl
 254 AC_ARG_ENABLE([32-bit],
 255     [AS_HELP_STRING([--enable-32-bit],
 256         [build 32-bit libraries @<:@default=auto@:>@])],
 257     [enable_32bit="$enableval"],
 258     [enable_32bit=auto]
 259 )
 260 if test "x$enable_32bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m32"
 263         CCASFLAGS="$CCASFLAGS -m32"
 264     fi
 265     if test "x$GXX" = xyes; then
 266         CXXFLAGS="$CXXFLAGS -m32"
 267     fi
 268 fi
 269 AC_ARG_ENABLE([64-bit],
 270     [AS_HELP_STRING([--enable-64-bit],
 271         [build 64-bit libraries @<:@default=auto@:>@])],
 272     [enable_64bit="$enableval"],
 273     [enable_64bit=auto]
 274 )
 275 if test "x$enable_64bit" = xyes; then
 276     if test "x$GCC" = xyes; then
 277         CFLAGS="$CFLAGS -m64"
 278     fi
 279     if test "x$GXX" = xyes; then
 280         CXXFLAGS="$CXXFLAGS -m64"
 281     fi
 282 fi
 283
 284 dnl Can't have static and shared libraries, default to static if user
 285 dnl explicitly requested. If both disabled, set to static since shared
 286 dnl was explicitly requested.
 287 case "x$enable_static$enable_shared" in
 288 xyesyes )
 289     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 290     enable_shared=no
 291     ;;
 292 xnono )
 293     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 294     enable_static=yes
 295     ;;
 296 esac
 297
 298 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 299
 300 dnl
 301 dnl other compiler options
 302 dnl
 303 AC_ARG_ENABLE([debug],
 304     [AS_HELP_STRING([--enable-debug],
 305         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 306     [enable_debug="$enableval"],
 307     [enable_debug=no]
 308 )
 309 if test "x$enable_debug" = xyes; then
 310     DEFINES="$DEFINES -DDEBUG"
 311     if test "x$GCC" = xyes; then
 312         CFLAGS="$CFLAGS -g -O0"
 313     fi
 314     if test "x$GXX" = xyes; then
 315         CXXFLAGS="$CXXFLAGS -g -O0"
 316     fi
 317 fi
 318
 319 dnl
 320 dnl compatibility symlinks
 321 dnl
 322 case "$host_os" in
 323 linux* )
 324     HAVE_COMPAT_SYMLINKS=yes ;;
 325 * )
 326     HAVE_COMPAT_SYMLINKS=no ;;
 327 esac
 328
 329 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 330
 331 dnl
 332 dnl library names
 333 dnl
 334 if test "$enable_static" = yes; then
 335     LIB_EXT='a'
 336 else
 337     case "$host_os" in
 338     darwin* )
 339         LIB_EXT='dylib' ;;
 340     cygwin* )
 341         LIB_EXT='dll' ;;
 342     aix* )
 343         LIB_EXT='a' ;;
 344     * )
 345         LIB_EXT='so' ;;
 346     esac
 347 fi
 348
 349 AC_SUBST([LIB_EXT])
 350
 351 AC_ARG_WITH([gl-lib-name],
 352   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 353     [specify GL library name @<:@default=GL@:>@])],
 354   [GL_LIB=$withval],
 355   [GL_LIB=GL])
 356 AC_ARG_WITH([osmesa-lib-name],
 357   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 358     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 359   [OSMESA_LIB=$withval],
 360   [OSMESA_LIB=OSMesa])
 361 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 362 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 363
 364 dnl
 365 dnl Mangled Mesa support
 366 dnl
 367 AC_ARG_ENABLE([mangling],
 368   [AS_HELP_STRING([--enable-mangling],
 369     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 370   [enable_mangling="${enableval}"],
 371   [enable_mangling=no]
 372 )
 373 if test "x${enable_mangling}" = "xyes" ; then
 374   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 375   GL_LIB="Mangled${GL_LIB}"
 376   OSMESA_LIB="Mangled${OSMESA_LIB}"
 377 fi
 378 AC_SUBST([GL_LIB])
 379 AC_SUBST([OSMESA_LIB])
 380
 381 dnl
 382 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 383 dnl
 384 AC_ARG_ENABLE([texture-float],
 385     [AS_HELP_STRING([--enable-texture-float],
 386         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 387     [enable_texture_float="$enableval"],
 388     [enable_texture_float=no]
 389 )
 390 if test "x$enable_texture_float" = xyes; then
 391     AC_MSG_WARN([Floating-point textures enabled.])
 392     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 393     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 394 fi
 395
 396 dnl
 397 dnl Arch/platform-specific settings
 398 dnl
 399 AC_ARG_ENABLE([asm],
 400     [AS_HELP_STRING([--disable-asm],
 401         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 402     [enable_asm="$enableval"],
 403     [enable_asm=yes]
 404 )
 405 asm_arch=""
 406 AC_MSG_CHECKING([whether to enable assembly])
 407 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 408 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 409 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 410     case "$host_cpu" in
 411     i?86 | x86_64 | amd64)
 412         enable_asm=no
 413         AC_MSG_RESULT([no, cross compiling])
 414         ;;
 415     esac
 416 fi
 417 # check for supported arches
 418 if test "x$enable_asm" = xyes; then
 419     case "$host_cpu" in
 420     i?86)
 421         case "$host_os" in
 422         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 423             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 424             ;;
 425         gnu*)
 426             asm_arch=x86
 427             ;;
 428         esac
 429         ;;
 430     x86_64|amd64)
 431         case "$host_os" in
 432         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 433             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 434             ;;
 435         esac
 436         ;;
 437     sparc*)
 438         case "$host_os" in
 439         linux*)
 440             asm_arch=sparc
 441             ;;
 442         esac
 443         ;;
 444     esac
 445
 446     case "$asm_arch" in
 447     x86)
 448         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 449         AC_MSG_RESULT([yes, x86])
 450         ;;
 451     x86_64|amd64)
 452         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 453         AC_MSG_RESULT([yes, x86_64])
 454         ;;
 455     sparc)
 456         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 457         AC_MSG_RESULT([yes, sparc])
 458         ;;
 459     *)
 460         AC_MSG_RESULT([no, platform not supported])
 461         ;;
 462     esac
 463 fi
 464
 465 dnl Check to see if dlopen is in default libraries (like Solaris, which
 466 dnl has it in libc), or if libdl is needed to get it.
 467 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 468     [AC_CHECK_LIB([dl], [dlopen],
 469        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 470 AC_SUBST([DLOPEN_LIBS])
 471
 472 case "$host_os" in
 473 darwin*|mingw*)
 474     ;;
 475 *)
 476     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 477                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 478                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 479     AC_SUBST([CLOCK_LIB])
 480     ;;
 481 esac
 482
 483 dnl See if posix_memalign is available
 484 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 485
 486 dnl Check for pthreads
 487 AX_PTHREAD
 488 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 489 dnl to -pthread, which causes problems if we need -lpthread to appear in
 490 dnl pkgconfig files.
 491 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 492
 493 dnl SELinux awareness.
 494 AC_ARG_ENABLE([selinux],
 495     [AS_HELP_STRING([--enable-selinux],
 496         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 497     [MESA_SELINUX="$enableval"],
 498     [MESA_SELINUX=no])
 499 if test "x$enable_selinux" = "xyes"; then
 500     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 501         [AC_CHECK_HEADER([selinux/selinux.h],[],
 502                          [AC_MSG_ERROR([SELinux headers not found])])
 503          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 504                       [AC_MSG_ERROR([SELinux library not found])])
 505          SELINUX_LIBS="-lselinux"])
 506     DEFINES="$DEFINES -DMESA_SELINUX"
 507 fi
 508 AC_SUBST([SELINUX_CFLAGS])
 509 AC_SUBST([SELINUX_LIBS])
 510
 511 dnl Options for APIs
 512 AC_ARG_ENABLE([opengl],
 513     [AS_HELP_STRING([--disable-opengl],
 514         [disable support for standard OpenGL API @<:@default=no@:>@])],
 515     [enable_opengl="$enableval"],
 516     [enable_opengl=yes])
 517 AC_ARG_ENABLE([gles1],
 518     [AS_HELP_STRING([--enable-gles1],
 519         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 520     [enable_gles1="$enableval"],
 521     [enable_gles1=no])
 522 AC_ARG_ENABLE([gles2],
 523     [AS_HELP_STRING([--enable-gles2],
 524         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 525     [enable_gles2="$enableval"],
 526     [enable_gles2=no])
 527 AC_ARG_ENABLE([openvg],
 528     [AS_HELP_STRING([--enable-openvg],
 529         [enable support for OpenVG API @<:@default=no@:>@])],
 530     [enable_openvg="$enableval"],
 531     [enable_openvg=no])
 532
 533 AC_ARG_ENABLE([dri],
 534     [AS_HELP_STRING([--enable-dri],
 535         [enable DRI modules @<:@default=enabled@:>@])],
 536     [enable_dri="$enableval"],
 537     [enable_dri=yes])
 538 AC_ARG_ENABLE([dri3],
 539     [AS_HELP_STRING([--enable-dri3],
 540         [enable DRI3 @<:@default=enabled@:>@])],
 541     [enable_dri3="$enableval"],
 542     [enable_dri3=yes])
 543 AC_ARG_ENABLE([glx],
 544     [AS_HELP_STRING([--enable-glx],
 545         [enable GLX library @<:@default=enabled@:>@])],
 546     [enable_glx="$enableval"],
 547     [enable_glx=yes])
 548 AC_ARG_ENABLE([osmesa],
 549     [AS_HELP_STRING([--enable-osmesa],
 550         [enable OSMesa library @<:@default=disabled@:>@])],
 551     [enable_osmesa="$enableval"],
 552     [enable_osmesa=no])
 553 AC_ARG_ENABLE([gallium-osmesa],
 554     [AS_HELP_STRING([--enable-gallium-osmesa],
 555         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 556     [enable_gallium_osmesa="$enableval"],
 557     [enable_gallium_osmesa=no])
 558 AC_ARG_ENABLE([egl],
 559     [AS_HELP_STRING([--disable-egl],
 560         [disable EGL library @<:@default=enabled@:>@])],
 561     [enable_egl="$enableval"],
 562     [enable_egl=yes])
 563
 564 AC_ARG_ENABLE([xa],
 565     [AS_HELP_STRING([--enable-xa],
 566         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 567     [enable_xa="$enableval"],
 568     [enable_xa=no])
 569 AC_ARG_ENABLE([gbm],
 570    [AS_HELP_STRING([--enable-gbm],
 571          [enable gbm library @<:@default=auto@:>@])],
 572    [enable_gbm="$enableval"],
 573    [enable_gbm=auto])
 574
 575 AC_ARG_ENABLE([xvmc],
 576    [AS_HELP_STRING([--enable-xvmc],
 577          [enable xvmc library @<:@default=auto@:>@])],
 578    [enable_xvmc="$enableval"],
 579    [enable_xvmc=no])
 580 AC_ARG_ENABLE([vdpau],
 581    [AS_HELP_STRING([--enable-vdpau],
 582          [enable vdpau library @<:@default=auto@:>@])],
 583    [enable_vdpau="$enableval"],
 584    [enable_vdpau=auto])
 585 AC_ARG_ENABLE([omx],
 586    [AS_HELP_STRING([--enable-omx],
 587          [enable OpenMAX library @<:@default=no@:>@])],
 588    [enable_omx="$enableval"],
 589    [enable_omx=no])
 590 AC_ARG_ENABLE([opencl],
 591    [AS_HELP_STRING([--enable-opencl],
 592          [enable OpenCL library @<:@default=no@:>@])],
 593    [enable_opencl="$enableval"],
 594    [enable_opencl=no])
 595 AC_ARG_ENABLE([opencl_icd],
 596    [AS_HELP_STRING([--enable-opencl-icd],
 597           [Build an OpenCL ICD library to be loaded by an ICD implementation
 598            @<:@default=no@:>@])],
 599     [enable_opencl_icd="$enableval"],
 600     [enable_opencl_icd=no])
 601 AC_ARG_ENABLE([xlib-glx],
 602     [AS_HELP_STRING([--enable-xlib-glx],
 603         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 604     [enable_xlib_glx="$enableval"],
 605     [enable_xlib_glx=no])
 606 AC_ARG_ENABLE([gallium-egl],
 607     [AS_HELP_STRING([--enable-gallium-egl],
 608         [enable optional EGL state tracker (not required
 609          for EGL support in Gallium with OpenGL and OpenGL ES)
 610          @<:@default=disable@:>@])],
 611     [enable_gallium_egl="$enableval"],
 612     [enable_gallium_egl=no])
 613 AC_ARG_ENABLE([gallium-gbm],
 614     [AS_HELP_STRING([--enable-gallium-gbm],
 615         [enable optional gbm state tracker (not required for
 616          gbm support in Gallium)
 617          @<:@default=auto@:>@])],
 618     [enable_gallium_gbm="$enableval"],
 619     [enable_gallium_gbm=auto])
 620
 621 AC_ARG_ENABLE([r600-llvm-compiler],
 622     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 623         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 624     [enable_r600_llvm="$enableval"],
 625     [enable_r600_llvm=no])
 626
 627 AC_ARG_ENABLE([gallium-tests],
 628     [AS_HELP_STRING([--enable-gallium-tests],
 629         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 630     [enable_gallium_tests="$enableval"],
 631     [enable_gallium_tests=no])
 632
 633 # Option for Gallium drivers
 634
 635 # Keep this in sync with the --with-gallium-drivers help string default value
 636 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 637
 638 AC_ARG_WITH([gallium-drivers],
 639     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 640         [comma delimited Gallium drivers list, e.g.
 641         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 642         @<:@default=r300,r600,svga,swrast@:>@])],
 643     [with_gallium_drivers="$withval"],
 644     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 645
 646 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 647 # here so that the script doesn't choke on an unknown driver name later.
 648 case "$with_gallium_drivers" in
 649     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 650     no) with_gallium_drivers='' ;;
 651 esac
 652
 653 if test "x$enable_opengl" = xno -a \
 654         "x$enable_gles1" = xno -a \
 655         "x$enable_gles2" = xno -a \
 656         "x$enable_openvg" = xno -a \
 657         "x$enable_xa" = xno -a \
 658         "x$enable_xvmc" = xno -a \
 659         "x$enable_vdpau" = xno -a \
 660         "x$enable_omx" = xno -a \
 661         "x$enable_opencl" = xno; then
 662     AC_MSG_ERROR([at least one API should be enabled])
 663 fi
 664
 665 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 666 if test "x$enable_opengl" = xno -a \
 667         "x$enable_gles1" = xyes; then
 668     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 669 fi
 670
 671 if test "x$enable_opengl" = xno -a \
 672         "x$enable_gles2" = xyes; then
 673     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 674 fi
 675
 676 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 677 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 678 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 679 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 680                                         "x$enable_gles1" = xyes -o \
 681                                         "x$enable_gles2" = xyes)
 682
 683 if test "x$enable_glx" = xno; then
 684     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 685     enable_xlib_glx=no
 686 fi
 687
 688 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 689     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 690 fi
 691
 692 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 693     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 694 fi
 695
 696 # Disable GLX if OpenGL is not enabled
 697 if test "x$enable_glx$enable_opengl" = xyesno; then
 698     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 699     enable_glx=no
 700 fi
 701
 702 # Disable GLX if DRI and Xlib-GLX are not enabled
 703 if test "x$enable_glx" = xyes -a \
 704         "x$enable_dri" = xno -a \
 705         "x$enable_xlib_glx" = xno; then
 706     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 707     enable_glx=no
 708 fi
 709
 710 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 711                                   "x$enable_dri" = xyes)
 712 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 713 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 714
 715 AC_ARG_ENABLE([shared-glapi],
 716     [AS_HELP_STRING([--enable-shared-glapi],
 717         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 718     [enable_shared_glapi="$enableval"],
 719     [enable_shared_glapi=yes])
 720
 721 case "x$enable_opengl$enable_gles1$enable_gles2" in
 722 x*yes*yes*)
 723     if test "x$enable_shared_glapi" = xno; then
 724         AC_MSG_ERROR([shared GLAPI required when building two or more of
 725                       the following APIs - opengl, gles1 gles2])
 726     fi
 727     ;;
 728 esac
 729
 730 # Building Xlib-GLX requires shared glapi to be disabled.
 731 if test "x$enable_xlib_glx" = xyes; then
 732     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 733     enable_shared_glapi=no
 734 fi
 735
 736 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 737
 738 dnl
 739 dnl Driver specific build directories
 740 dnl
 741 GALLIUM_TARGET_DIRS=""
 742 GALLIUM_WINSYS_DIRS="sw"
 743 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 744 GALLIUM_STATE_TRACKERS_DIRS=""
 745
 746 case "x$enable_glx$enable_xlib_glx" in
 747 xyesyes)
 748     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 749     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 750     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 751     NEED_WINSYS_XLIB="yes"
 752     ;;
 753 esac
 754
 755 if test "x$enable_dri" = xyes; then
 756     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 757     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 758 fi
 759
 760 if test "x$enable_gallium_osmesa" = xyes; then
 761     if test -z "$with_gallium_drivers"; then
 762         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 763     fi
 764     if test "x$enable_osmesa" = xyes; then
 765         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 766     fi
 767     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 768     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 769 fi
 770
 771 AC_SUBST([MESA_LLVM])
 772
 773 # Check for libdrm
 774 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 775                   [have_libdrm=yes], [have_libdrm=no])
 776 if test "x$have_libdrm" = xyes; then
 777         DEFINES="$DEFINES -DHAVE_LIBDRM"
 778 fi
 779
 780 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 781                   have_libudev=yes, have_libudev=no)
 782
 783 if test "x$enable_dri" = xyes; then
 784     # DRI must be shared, I think
 785     if test "$enable_static" = yes; then
 786         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 787     fi
 788
 789     # not a hard requirement as swrast does not depend on it
 790     if test "x$have_libdrm" = xyes; then
 791         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 792     fi
 793 fi
 794
 795 dnl Direct rendering or just indirect rendering
 796 case "$host_os" in
 797 gnu*)
 798     dnl Disable by default on GNU/Hurd
 799     driglx_direct_default="no"
 800     ;;
 801 cygwin*)
 802     dnl Disable by default on cygwin
 803     driglx_direct_default="no"
 804     ;;
 805 *)
 806     driglx_direct_default="yes"
 807     ;;
 808 esac
 809 AC_ARG_ENABLE([driglx-direct],
 810     [AS_HELP_STRING([--disable-driglx-direct],
 811         [disable direct rendering in GLX and EGL for DRI \
 812             @<:@default=auto@:>@])],
 813     [driglx_direct="$enableval"],
 814     [driglx_direct="$driglx_direct_default"])
 815
 816 dnl
 817 dnl libGL configuration per driver
 818 dnl
 819 case "x$enable_glx$enable_xlib_glx" in
 820 xyesyes)
 821     # Xlib-based GLX
 822     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 823     GL_PC_REQ_PRIV="x11 xext"
 824     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 825     GL_LIB_DEPS="$XLIBGL_LIBS"
 826     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 827     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 828     ;;
 829 xyesno)
 830     # DRI-based GLX
 831     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 832     if test x"$driglx_direct" = xyes; then
 833         if test "x$have_libdrm" != xyes; then
 834             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 835         fi
 836         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 837         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 838         if test x"$enable_dri3" = xyes; then
 839             if test x"$have_libudev" != xyes; then
 840               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 841             fi
 842             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 843             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 844         fi
 845     fi
 846
 847     # find the DRI deps for libGL
 848     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 849
 850     if test x"$enable_dri3" = xyes; then
 851         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 852     fi
 853
 854     # add xf86vidmode if available
 855     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 856     if test "$HAVE_XF86VIDMODE" = yes ; then
 857         dri_modules="$dri_modules xxf86vm"
 858     fi
 859
 860     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 861     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 862     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 863     GL_LIB_DEPS="$DRIGL_LIBS"
 864
 865     # need DRM libs, $PTHREAD_LIBS, etc.
 866     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 867     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 868     ;;
 869 esac
 870
 871 if test "$have_libudev" = yes; then
 872     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 873 fi
 874
 875 # This is outside the case (above) so that it is invoked even for non-GLX
 876 # builds.
 877 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 878
 879 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 880 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 881 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 882 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 883
 884 AC_SUBST([X11_INCLUDES])
 885 AC_SUBST([GL_LIB_DEPS])
 886 AC_SUBST([GL_PC_REQ_PRIV])
 887 AC_SUBST([GL_PC_LIB_PRIV])
 888 AC_SUBST([GL_PC_CFLAGS])
 889 AC_SUBST([DRI_PC_REQ_PRIV])
 890 AC_SUBST([GLESv1_CM_LIB_DEPS])
 891 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 892 AC_SUBST([GLESv2_LIB_DEPS])
 893 AC_SUBST([GLESv2_PC_LIB_PRIV])
 894
 895 AC_SUBST([HAVE_XF86VIDMODE])
 896
 897 dnl
 898 dnl More GLX setup
 899 dnl
 900 case "x$enable_glx$enable_xlib_glx" in
 901 xyesyes)
 902     DEFINES="$DEFINES -DUSE_XSHM"
 903     ;;
 904 xyesno)
 905     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 906     if test "x$driglx_direct" = xyes; then
 907         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 908     fi
 909     ;;
 910 esac
 911
 912 dnl
 913 dnl TLS detection
 914 dnl
 915
 916 AC_ARG_ENABLE([glx-tls],
 917     [AS_HELP_STRING([--enable-glx-tls],
 918         [enable TLS support in GLX @<:@default=disabled@:>@])],
 919     [GLX_USE_TLS="$enableval"],
 920     [GLX_USE_TLS=no])
 921 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 922
 923 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 924       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 925
 926 dnl
 927 dnl More DRI setup
 928 dnl
 929 dnl Directory for DRI drivers
 930 AC_ARG_WITH([dri-driverdir],
 931     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 932         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 933     [DRI_DRIVER_INSTALL_DIR="$withval"],
 934     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 935 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 936 dnl Extra search path for DRI drivers
 937 AC_ARG_WITH([dri-searchpath],
 938     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 939         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 940     [DRI_DRIVER_SEARCH_DIR="$withval"],
 941     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 942 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 943 dnl Which drivers to build - default is chosen by platform
 944 AC_ARG_WITH([dri-drivers],
 945     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 946         [comma delimited classic DRI drivers list, e.g.
 947         "swrast,i965,radeon" @<:@default=auto@:>@])],
 948     [with_dri_drivers="$withval"],
 949     [with_dri_drivers=auto])
 950
 951 if test "x$with_dri_drivers" = xauto; then
 952     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 953         with_dri_drivers="yes"
 954     else
 955         with_dri_drivers="no"
 956     fi
 957 fi
 958 if test "x$with_dri_drivers" = xno; then
 959     with_dri_drivers=''
 960 fi
 961
 962 dnl If $with_dri_drivers is yes, drivers will be added through
 963 dnl platform checks. Set DEFINES and LIB_DEPS
 964 if test "x$enable_dri" = xyes; then
 965     # Platform specific settings and drivers to build
 966     case "$host_os" in
 967     linux*)
 968         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 969         DEFINES="$DEFINES -DHAVE_ALIAS"
 970         if test "x$enable_dri3" = xyes; then
 971             DEFINES="$DEFINES -DHAVE_DRI3"
 972         fi
 973
 974         if test "x$have_libudev" != xyes; then
 975             AC_MSG_ERROR([libudev-dev required for building DRI])
 976         fi
 977
 978         case "$host_cpu" in
 979         powerpc* | sparc*)
 980             # Build only the drivers for cards that exist on PowerPC/sparc
 981             if test "x$with_dri_drivers" = "xyes"; then
 982                 with_dri_drivers="r200 radeon swrast"
 983             fi
 984             ;;
 985         esac
 986         ;;
 987     *freebsd* | dragonfly* | *netbsd* | openbsd*)
 988         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 989         DEFINES="$DEFINES -DHAVE_ALIAS"
 990         ;;
 991     gnu*)
 992         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 993         DEFINES="$DEFINES -DHAVE_ALIAS"
 994         ;;
 995     solaris*)
 996         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 997         ;;
 998     cygwin*)
 999         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1000         if test "x$with_dri_drivers" = "xyes"; then
1001             with_dri_drivers="swrast"
1002         fi
1003         ;;
1004     esac
1005
1006     # default drivers
1007     if test "x$with_dri_drivers" = "xyes"; then
1008         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1009     fi
1010
1011     # Check for expat
1012     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1013     if test "x$have_expat" = "xyes"; then
1014        PKG_CHECK_MODULES([EXPAT], [expat], [],
1015                          AC_MSG_ERROR([Expat required for DRI.]))
1016     else
1017        # expat version 2.0 and earlier do not provide expat.pc
1018        EXPAT_LIBS=-lexpat
1019     fi
1020
1021     # If we are building any DRI driver other than swrast.
1022     if test -n "$with_dri_drivers"; then
1023         if test "x$with_dri_drivers" != xswrast; then
1024             # ... libdrm is required
1025             if test "x$have_libdrm" != xyes; then
1026                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1027             fi
1028             DRICOMMON_NEED_LIBDRM=yes
1029         else
1030             DRICOMMON_NEED_LIBDRM=no
1031         fi
1032     fi
1033
1034     # put all the necessary libs together
1035     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1036     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1037
1038 fi
1039
1040 AC_SUBST([DRI_LIB_DEPS])
1041 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1042
1043 DRI_DIRS=''
1044 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1045 if test -n "$with_dri_drivers"; then
1046     if test "x$enable_opengl" != xyes; then
1047         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1048     fi
1049
1050     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1051     for driver in $dri_drivers; do
1052         DRI_DIRS="$DRI_DIRS $driver"
1053         case "x$driver" in
1054         xi915)
1055             HAVE_I915_DRI=yes;
1056             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1057             ;;
1058         xi965)
1059             HAVE_I965_DRI=yes;
1060             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1061             ;;
1062         xnouveau)
1063             HAVE_NOUVEAU_DRI=yes;
1064             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1065             ;;
1066         xradeon)
1067             HAVE_RADEON_DRI=yes;
1068             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1069             ;;
1070         xr200)
1071             HAVE_R200_DRI=yes;
1072             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1073             ;;
1074         xswrast)
1075             HAVE_SWRAST_DRI=yes;
1076             ;;
1077         *)
1078             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1079             ;;
1080         esac
1081     done
1082     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1083 fi
1084
1085 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1086 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1087                                   "x$enable_osmesa" = xyes -o \
1088                                   -n "$DRI_DIRS")
1089
1090 dnl
1091 dnl OSMesa configuration
1092 dnl
1093
1094 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1095 AC_ARG_WITH([osmesa-bits],
1096     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1097         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1098     [osmesa_bits="$withval"],
1099     [osmesa_bits=8])
1100 if test "x$osmesa_bits" != x8; then
1101     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1102         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1103         osmesa_bits=8
1104     fi
1105 fi
1106 case "x$osmesa_bits" in
1107 x8)
1108     OSMESA_LIB="${OSMESA_LIB}"
1109     ;;
1110 x16|x32)
1111     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1112     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1113     ;;
1114 *)
1115     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1116     ;;
1117 esac
1118
1119 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1120     # only link libraries with osmesa if shared
1121     if test "$enable_static" = no; then
1122         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1123     else
1124         OSMESA_LIB_DEPS=""
1125     fi
1126     OSMESA_MESA_DEPS=""
1127     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1128 fi
1129
1130 AC_SUBST([OSMESA_LIB_DEPS])
1131 AC_SUBST([OSMESA_MESA_DEPS])
1132 AC_SUBST([OSMESA_PC_REQ])
1133 AC_SUBST([OSMESA_PC_LIB_PRIV])
1134
1135 dnl
1136 dnl gbm configuration
1137 dnl
1138 if test "x$enable_gbm" = xauto; then
1139     case "$with_egl_platforms" in
1140         *drm*)
1141             enable_gbm=yes ;;
1142          *)
1143             enable_gbm=no ;;
1144     esac
1145 fi
1146 if test "x$enable_gbm" = xyes; then
1147     if test x"$have_libudev" != xyes; then
1148         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1149     fi
1150
1151     if test "x$enable_dri" = xyes; then
1152         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1153         if test "x$enable_shared_glapi" = xno; then
1154             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1155         fi
1156     fi
1157 fi
1158 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1159 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1160 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1161 AC_SUBST([GBM_PC_REQ_PRIV])
1162 AC_SUBST([GBM_PC_LIB_PRIV])
1163
1164 dnl
1165 dnl EGL configuration
1166 dnl
1167 EGL_CLIENT_APIS=""
1168
1169 if test "x$enable_egl" = xyes; then
1170     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1171
1172     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1173
1174     if test "$enable_static" != yes; then
1175         if test "x$enable_dri" = xyes; then
1176             HAVE_EGL_DRIVER_DRI2=1
1177         fi
1178
1179     fi
1180 fi
1181 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1182 AC_SUBST([EGL_LIB_DEPS])
1183
1184 dnl
1185 dnl EGL Gallium configuration
1186 dnl
1187 if test "x$enable_gallium_egl" = xyes; then
1188     if test -z "$with_gallium_drivers"; then
1189         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1190     fi
1191     if test "x$enable_egl" = xno; then
1192         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1193     fi
1194     if test "x$have_libdrm" != xyes; then
1195         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1196     fi
1197
1198     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1199     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1200 fi
1201 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1202
1203 dnl
1204 dnl gbm Gallium configuration
1205 dnl
1206 if test "x$enable_gallium_gbm" = xauto; then
1207     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1208         yesyesyes*drm*)
1209             enable_gallium_gbm=yes ;;
1210          *)
1211             enable_gallium_gbm=no ;;
1212     esac
1213 fi
1214 if test "x$enable_gallium_gbm" = xyes; then
1215     if test -z "$with_gallium_drivers"; then
1216         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1217     fi
1218     if test "x$enable_gbm" = xno; then
1219         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1220     fi
1221     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1222     if test "x$enable_dri" = xno; then
1223         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1224     fi
1225
1226     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1227     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1228     enable_gallium_loader=yes
1229 fi
1230 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1231
1232 dnl
1233 dnl XA configuration
1234 dnl
1235 if test "x$enable_xa" = xyes; then
1236     if test "x$with_gallium_drivers" = xswrast; then
1237        AC_MSG_ERROR([
1238           Building xa requires at least one non swrast gallium driver.
1239           If you are looking to use libxatracker.so with vmware's virtual gpu,
1240           make sure to include svga in the gallium drivers list, apart from
1241           enabling XA.
1242           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1243     fi
1244     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1245     enable_gallium_loader=yes
1246 fi
1247 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1248
1249 dnl
1250 dnl OpenVG configuration
1251 dnl
1252 VG_LIB_DEPS=""
1253
1254 if test "x$enable_openvg" = xyes; then
1255     if test "x$enable_egl" = xno; then
1256         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1257     fi
1258     if test -z "$with_gallium_drivers"; then
1259         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1260     fi
1261     if test "x$enable_gallium_egl" = xno; then
1262         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1263     fi
1264
1265     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1266     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1267     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1268     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1269     AC_SUBST([VG_PC_LIB_PRIV])
1270 fi
1271 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1272
1273 dnl
1274 dnl Gallium G3DVL configuration
1275 dnl
1276 if test -n "$with_gallium_drivers"; then
1277     if test "x$enable_xvmc" = xauto; then
1278         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1279     fi
1280
1281     if test "x$enable_vdpau" = xauto; then
1282         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1283     fi
1284
1285     if test "x$enable_omx" = xauto; then
1286         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1287     fi
1288 fi
1289
1290 if test "x$enable_xvmc" = xyes; then
1291     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1292     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1293 fi
1294 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1295
1296 if test "x$enable_vdpau" = xyes; then
1297     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1298                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1299     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1300 fi
1301 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1302
1303 if test "x$enable_omx" = xyes; then
1304     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1305     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1306 fi
1307 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1308
1309 dnl
1310 dnl OpenCL configuration
1311 dnl
1312
1313 AC_ARG_WITH([libclc-path],
1314    [AS_HELP_STRING([--with-libclc-path],
1315          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1316    [LIBCLC_PATH="$withval"],
1317    [LIBCLC_PATH=''])
1318
1319 if test -n "$LIBCLC_PATH"; then
1320    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1321                   Please review the updated build instructions for clover:
1322                   http://dri.freedesktop.org/wiki/GalliumCompute])
1323 fi
1324
1325
1326 AC_ARG_WITH([clang-libdir],
1327    [AS_HELP_STRING([--with-clang-libdir],
1328          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1329    [CLANG_LIBDIR="$withval"],
1330    [CLANG_LIBDIR=''])
1331
1332 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1333
1334 if test "x$enable_opencl" = xyes; then
1335     if test -z "$with_gallium_drivers"; then
1336         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1337     fi
1338
1339     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1340         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1341     fi
1342
1343     if test "x$have_libclc" = xno; then
1344         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1345                     Make sure the directory containing libclc.pc is specified in your
1346                     PKG_CONFIG_PATH environment variable.
1347                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1348     else
1349         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1350         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1351         AC_SUBST([LIBCLC_INCLUDEDIR])
1352         AC_SUBST([LIBCLC_LIBEXECDIR])
1353     fi
1354
1355     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1356     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1357     enable_gallium_loader=yes
1358
1359     if test "x$enable_opencl_icd" = xyes; then
1360         OPENCL_LIBNAME="MesaOpenCL"
1361     else
1362         OPENCL_LIBNAME="OpenCL"
1363     fi
1364 fi
1365 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1366 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1367 AC_SUBST([OPENCL_LIBNAME])
1368
1369 dnl
1370 dnl Gallium configuration
1371 dnl
1372 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1373
1374 AC_SUBST([LLVM_BINDIR])
1375 AC_SUBST([LLVM_CFLAGS])
1376 AC_SUBST([LLVM_CPPFLAGS])
1377 AC_SUBST([LLVM_CXXFLAGS])
1378 AC_SUBST([LLVM_LIBDIR])
1379 AC_SUBST([LLVM_LIBS])
1380 AC_SUBST([LLVM_LDFLAGS])
1381 AC_SUBST([LLVM_INCLUDEDIR])
1382 AC_SUBST([LLVM_VERSION])
1383 AC_SUBST([CLANG_RESOURCE_DIR])
1384
1385 case "x$enable_opengl$enable_gles1$enable_gles2" in
1386 x*yes*)
1387     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1388     ;;
1389 esac
1390
1391 AC_SUBST([VG_LIB_DEPS])
1392 AC_SUBST([EGL_CLIENT_APIS])
1393
1394 dnl
1395 dnl EGL Platforms configuration
1396 dnl
1397 AC_ARG_WITH([egl-platforms],
1398     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1399         [comma delimited native platforms libEGL supports, e.g.
1400         "x11,drm" @<:@default=auto@:>@])],
1401     [with_egl_platforms="$withval"],
1402     [if test "x$enable_egl" = xyes; then
1403         with_egl_platforms="x11"
1404     else
1405         with_egl_platforms=""
1406     fi])
1407
1408 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1409     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1410 fi
1411
1412 # Do per-EGL platform setups and checks
1413 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1414 for plat in $egl_platforms; do
1415         case "$plat" in
1416         wayland)
1417                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1418                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1419
1420                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1421                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1422                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1423                 ;;
1424
1425         x11)
1426                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1427                 ;;
1428
1429         drm)
1430                 test "x$enable_gbm" = "xno" &&
1431                         AC_MSG_ERROR([EGL platform drm needs gbm])
1432                 test "x$have_libdrm" != xyes &&
1433                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1434                 ;;
1435
1436         android|fbdev|gdi|null)
1437                 ;;
1438
1439         *)
1440                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1441                 ;;
1442         esac
1443
1444         case "$plat$have_libudev" in
1445                 waylandno|drmno)
1446                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1447         esac
1448 done
1449
1450 # libEGL wants to default to the first platform specified in
1451 # ./configure.  parse that here.
1452 if test "x$egl_platforms" != "x"; then
1453     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1454     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1455 else
1456     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1457 fi
1458
1459 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1460     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1461     NEED_WINSYS_XLIB=yes
1462 fi
1463 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1464 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1465 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1466 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1467 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1468
1469 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1470
1471 AC_SUBST([EGL_NATIVE_PLATFORM])
1472 AC_SUBST([EGL_CFLAGS])
1473
1474 # If we don't have the X11 platform, set this define so we don't try to include
1475 # the X11 headers.
1476 if ! echo "$egl_platforms" | grep -q 'x11'; then
1477     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1478     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1479 fi
1480
1481 AC_ARG_WITH([egl-driver-dir],
1482     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1483                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1484     [EGL_DRIVER_INSTALL_DIR="$withval"],
1485     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1486 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1487
1488 AC_ARG_WITH([max-width],
1489     [AS_HELP_STRING([--with-max-width=N],
1490                     [Maximum framebuffer width (4096)])],
1491     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1492      AS_IF([test "${withval}" -gt "4096"],
1493            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1494 )
1495 AC_ARG_WITH([max-height],
1496     [AS_HELP_STRING([--with-max-height=N],
1497                     [Maximum framebuffer height (4096)])],
1498     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1499      AS_IF([test "${withval}" -gt "4096"],
1500            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1501 )
1502
1503 dnl
1504 dnl Gallium LLVM
1505 dnl
1506 AC_ARG_ENABLE([gallium-llvm],
1507     [AS_HELP_STRING([--enable-gallium-llvm],
1508         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1509     [enable_gallium_llvm="$enableval"],
1510     [enable_gallium_llvm=auto])
1511
1512 AC_ARG_ENABLE([llvm-shared-libs],
1513     [AS_HELP_STRING([--enable-llvm-shared-libs],
1514         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1515     [enable_llvm_shared_libs="$enableval"],
1516     [enable_llvm_shared_libs=yes])
1517
1518 AC_ARG_WITH([llvm-prefix],
1519     [AS_HELP_STRING([--with-llvm-prefix],
1520         [Prefix for LLVM installations in non-standard locations])],
1521     [llvm_prefix="$withval"],
1522     [llvm_prefix=''])
1523
1524
1525 # Call this inside ` ` to get the return value.
1526 # $1 is the llvm-config command with arguments.
1527 strip_unwanted_llvm_flags() {
1528     # Use \> (marks the end of the word)
1529     echo `$1` | sed \
1530         -e 's/-DNDEBUG\>//g' \
1531         -e 's/-pedantic\>//g' \
1532         -e 's/-Wcovered-switch-default\>//g' \
1533         -e 's/-O.\>//g' \
1534         -e 's/-g\>//g' \
1535         -e 's/-Wall\>//g' \
1536         -e 's/-Wcast-qual\>//g' \
1537         -e 's/-Woverloaded-virtual\>//g' \
1538         -e 's/-fcolor-diagnostics\>//g' \
1539         -e 's/-fdata-sections\>//g' \
1540         -e 's/-ffunction-sections\>//g' \
1541         -e 's/-fno-exceptions\>//g' \
1542         -e 's/-fomit-frame-pointer\>//g' \
1543         -e 's/-fvisibility-inlines-hidden\>//g' \
1544         -e 's/-fPIC\>//g'
1545 }
1546
1547
1548 if test -z "$with_gallium_drivers"; then
1549     enable_gallium_llvm=no
1550 fi
1551 if test "x$enable_gallium_llvm" = xauto; then
1552     case "$host_cpu" in
1553     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1554     esac
1555 fi
1556 if test "x$enable_gallium_llvm" = xyes; then
1557     if test -n "$llvm_prefix"; then
1558         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1559     else
1560         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1561     fi
1562
1563     if test "x$LLVM_CONFIG" != xno; then
1564         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1565         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1566         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1567         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1568         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1569         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1570         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1571         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1572         LLVM_LDFLAGS="-Wl,-rpath,$LLVM_LIBDIR $LLVM_LDFLAGS"
1573
1574         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1575             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1576         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1577             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1578
1579         if test -n "${LLVM_VERSION_MAJOR}"; then
1580             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1581         else
1582             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1583         fi
1584
1585         LLVM_COMPONENTS="engine bitwriter"
1586         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1587             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1588         fi
1589
1590         if test "x$enable_opencl" = xyes; then
1591             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1592             # LLVM 3.3 >= 177971 requires IRReader
1593             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1594                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1595             fi
1596             # LLVM 3.4 requires Option
1597             if $LLVM_CONFIG --components | grep -qw 'option'; then
1598                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1599             fi
1600         fi
1601         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1602         MESA_LLVM=1
1603
1604         dnl Check for Clang internal headers
1605         if test "x$enable_opencl" = xyes; then
1606             if test -z "$CLANG_LIBDIR"; then
1607                 CLANG_LIBDIR=${LLVM_LIBDIR}
1608             fi
1609             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1610             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1611                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1612         fi
1613     else
1614         MESA_LLVM=0
1615         LLVM_VERSION_INT=0
1616     fi
1617 else
1618     MESA_LLVM=0
1619     LLVM_VERSION_INT=0
1620 fi
1621
1622 dnl Directory for XVMC libs
1623 AC_ARG_WITH([xvmc-libdir],
1624     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1625         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1626     [XVMC_LIB_INSTALL_DIR="$withval"],
1627     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1628 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1629
1630 dnl
1631 dnl Gallium Tests
1632 dnl
1633 if test "x$enable_gallium_tests" = xyes; then
1634     enable_gallium_loader=yes
1635 fi
1636 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1637
1638 if test "x$enable_gallium_loader" = xyes; then
1639     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1640 fi
1641 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1642
1643 dnl Directory for VDPAU libs
1644 AC_ARG_WITH([vdpau-libdir],
1645     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1646         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1647     [VDPAU_LIB_INSTALL_DIR="$withval"],
1648     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1649 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1650
1651 OMX_LIB_INSTALL_DIR_DEFAULT=''
1652 if test "x$enable_omx" = xyes; then
1653     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1654 fi
1655
1656 AC_ARG_WITH([omx-libdir],
1657     [AS_HELP_STRING([--with-omx-libdir=DIR],
1658         [directory for the OMX libraries])],
1659     [OMX_LIB_INSTALL_DIR="$withval"],
1660     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1661 AC_SUBST([OMX_LIB_INSTALL_DIR])
1662
1663 dnl Directory for OpenCL libs
1664 AC_ARG_WITH([opencl-libdir],
1665     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1666         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1667     [OPENCL_LIB_INSTALL_DIR="$withval"],
1668     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1669 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1670
1671 dnl
1672 dnl Gallium helper functions
1673 dnl
1674 gallium_check_st() {
1675     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1676          if test "x$have_libdrm" != xyes; then
1677             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1678          fi
1679          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1680     fi
1681     if test "x$enable_dri" = xyes && test -n "$2"; then
1682          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1683     fi
1684     if test "x$enable_xa" = xyes && test -n "$3"; then
1685          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1686     fi
1687     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1688          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1689     fi
1690     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1691          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1692     fi
1693     if test "x$enable_omx" = xyes && test "x$6" != x; then
1694          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1695     fi
1696 }
1697
1698 gallium_require_llvm() {
1699     if test "x$MESA_LLVM" = x0; then
1700         case "$host_cpu" in
1701         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1702         esac
1703     fi
1704 }
1705
1706 gallium_require_drm_loader() {
1707     if test "x$enable_gallium_loader" = xyes; then
1708         if test "x$have_libudev" != xyes; then
1709             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1710         fi
1711         if test "x$have_libdrm" != xyes; then
1712             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1713         fi
1714         enable_gallium_drm_loader=yes
1715     fi
1716 }
1717
1718 radeon_llvm_check() {
1719     if test "x$enable_gallium_llvm" != "xyes"; then
1720         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1721     fi
1722     LLVM_REQUIRED_VERSION_MAJOR="3"
1723     LLVM_REQUIRED_VERSION_MINOR="3"
1724     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1725         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1726     fi
1727     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1728         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1729                       sources with the --enable-experimental-targets=R600
1730                       configure flag])
1731     fi
1732     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1733     NEED_RADEON_LLVM=yes
1734     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1735                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1736 }
1737
1738 dnl Gallium drivers
1739 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1740         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1741     NEED_NONNULL_WINSYS=yes
1742 fi
1743 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1744
1745 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1746 if test -n "$with_gallium_drivers"; then
1747     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1748     for driver in $gallium_drivers; do
1749         case "x$driver" in
1750         xsvga)
1751             HAVE_GALLIUM_SVGA=yes
1752             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1753             gallium_require_drm_loader
1754             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1755             ;;
1756         xi915)
1757             HAVE_GALLIUM_I915=yes
1758             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1759             gallium_require_drm_loader
1760             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1761             if test "x$MESA_LLVM" = x1; then
1762                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1763             fi
1764             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1765             gallium_check_st "i915/drm" "dri-i915"
1766             DRICOMMON_NEED_LIBDRM=yes
1767             ;;
1768         xilo)
1769             HAVE_GALLIUM_ILO=yes
1770             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1771             gallium_require_drm_loader
1772             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1773             gallium_check_st "intel/drm" "dri-ilo"
1774             DRICOMMON_NEED_LIBDRM=yes
1775             ;;
1776         xr300)
1777             HAVE_GALLIUM_R300=yes
1778             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1779             gallium_require_drm_loader
1780             gallium_require_llvm "Gallium R300"
1781             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1782             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1783             DRICOMMON_NEED_LIBDRM=yes
1784             ;;
1785         xr600)
1786             HAVE_GALLIUM_R600=yes
1787             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1788             gallium_require_drm_loader
1789             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1790             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1791                 radeon_llvm_check "r600g"
1792                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1793             fi
1794             if test "x$enable_r600_llvm" = xyes; then
1795                 USE_R600_LLVM_COMPILER=yes;
1796             fi
1797             if test "x$enable_opencl" = xyes; then
1798                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1799             fi
1800             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1801             DRICOMMON_NEED_LIBDRM=yes
1802             ;;
1803         xradeonsi)
1804             HAVE_GALLIUM_RADEONSI=yes
1805             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1806             gallium_require_drm_loader
1807             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1808             radeon_llvm_check "radeonsi"
1809             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1810             DRICOMMON_NEED_LIBDRM=yes
1811             ;;
1812         xnouveau)
1813             HAVE_GALLIUM_NOUVEAU=yes
1814             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1815             gallium_require_drm_loader
1816             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1817             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1818             DRICOMMON_NEED_LIBDRM=yes
1819             ;;
1820         xfreedreno)
1821             HAVE_GALLIUM_FREEDRENO=yes
1822             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1823             gallium_require_drm_loader
1824             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1825             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1826             DRICOMMON_NEED_LIBDRM=yes
1827             ;;
1828         xswrast)
1829             HAVE_GALLIUM_SOFTPIPE=yes
1830             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1831             if test "x$MESA_LLVM" = x1; then
1832                 HAVE_GALLIUM_LLVMPIPE=yes
1833                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1834             fi
1835
1836             if test "x$enable_dri" = xyes; then
1837                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1838             fi
1839             ;;
1840         *)
1841             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1842             ;;
1843         esac
1844     done
1845 fi
1846
1847 dnl Set LLVM_LIBS - This is done after the driver configuration so
1848 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1849 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1850 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1851 dnl this was causing the same libraries to be appear multiple times
1852 dnl in LLVM_LIBS.
1853
1854 if test "x$MESA_LLVM" != x0; then
1855
1856     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1857
1858     if test "x$enable_llvm_shared_libs" = xyes; then
1859         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1860         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1861         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1862
1863         if test "x$llvm_have_one_so" = xyes; then
1864             dnl LLVM was built using auto*, so there is only one shared object.
1865             LLVM_LIBS="-l$LLVM_SO_NAME"
1866         else
1867             dnl If LLVM was built with CMake, there will be one shared object per
1868             dnl component.
1869             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1870                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1871         Please make sure you have built llvm with the --enable-shared option
1872         and that your llvm libraries are installed in $LLVM_LIBDIR
1873         If you have installed your llvm libraries to a different directory you
1874         can use the --with-llvm-prefix= configure flag to specify this directory.
1875         NOTE: Mesa is attempting to use llvm shared libraries by default.
1876         If you do not want to build with llvm shared libraries and instead want to
1877         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1878         invocation and rebuild.])])
1879
1880            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1881            dnl install uses a shared object for each compoenent and we have
1882            dnl already added all of these objects to LLVM_LIBS.
1883         fi
1884     else
1885         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
1886     fi
1887 fi
1888
1889 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1890 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1891 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1892 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1893 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1894 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1895 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1896 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1897 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1898 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1899
1900 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1901                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1902                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1903 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1904                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1905                                                   && test "x$MESA_LLVM" = x1)
1906
1907 # NOTE: anything using xcb or other client side libs ends up in separate
1908 #       _CLIENT variables.  The pipe loader is built in two variants,
1909 #       one that is standalone and does not link any x client libs (for
1910 #       use by XA tracker in particular, but could be used in any case
1911 #       where communication with xserver is not desired).
1912 if test "x$enable_gallium_loader" = xyes; then
1913     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1914
1915     if test "x$enable_gallium_xlib_loader" = xyes; then
1916         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1917         NEED_WINSYS_XLIB="yes"
1918         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1919     fi
1920
1921     if test "x$enable_gallium_drm_loader" = xyes; then
1922         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1923         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1924                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1925         if test "x$pipe_loader_have_xcb" = xyes; then
1926             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1927             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1928         fi
1929     fi
1930
1931     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1932     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1933
1934     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1935     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1936     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1937     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1938 fi
1939 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1940
1941 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1942 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1943 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1944 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1945 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1946 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1947
1948 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1949                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1950                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1951                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1952 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1953                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1954 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1955 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1956 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1957 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1958 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1959 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1960 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1961
1962 AC_SUBST([ELF_LIB])
1963
1964 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1965 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1966 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1967 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1968 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1969
1970 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1971 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1972 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1973
1974 AC_SUBST([VDPAU_MAJOR], 1)
1975 AC_SUBST([VDPAU_MINOR], 0)
1976
1977 AC_SUBST([XVMC_MAJOR], 1)
1978 AC_SUBST([XVMC_MINOR], 0)
1979
1980 AC_SUBST([XA_MAJOR], 2)
1981 AC_SUBST([XA_MINOR], 2)
1982 AC_SUBST([XA_TINY], 0)
1983 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1984
1985 dnl Restore LDFLAGS and CPPFLAGS
1986 LDFLAGS="$_SAVE_LDFLAGS"
1987 CPPFLAGS="$_SAVE_CPPFLAGS"
1988
1989 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1990 if test "x$acv_mesa_CLANG" = xyes; then
1991     CFLAGS="$CFLAGS -Qunused-arguments"
1992     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1993 fi
1994
1995 dnl Add user CFLAGS and CXXFLAGS
1996 CFLAGS="$CFLAGS $USER_CFLAGS"
1997 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1998
1999 dnl Substitute the config
2000 AC_CONFIG_FILES([Makefile
2001                 src/Makefile
2002                 src/egl/Makefile
2003                 src/egl/drivers/Makefile
2004                 src/egl/drivers/dri2/Makefile
2005                 src/egl/main/Makefile
2006                 src/egl/main/egl.pc
2007                 src/egl/wayland/Makefile
2008                 src/egl/wayland/wayland-drm/Makefile
2009                 src/egl/wayland/wayland-egl/Makefile
2010                 src/egl/wayland/wayland-egl/wayland-egl.pc
2011                 src/gallium/auxiliary/Makefile
2012                 src/gallium/auxiliary/pipe-loader/Makefile
2013                 src/gallium/drivers/Makefile
2014                 src/gallium/drivers/freedreno/Makefile
2015                 src/gallium/drivers/galahad/Makefile
2016                 src/gallium/drivers/i915/Makefile
2017                 src/gallium/drivers/identity/Makefile
2018                 src/gallium/drivers/ilo/Makefile
2019                 src/gallium/drivers/llvmpipe/Makefile
2020                 src/gallium/drivers/noop/Makefile
2021                 src/gallium/drivers/nouveau/Makefile
2022                 src/gallium/drivers/r300/Makefile
2023                 src/gallium/drivers/r600/Makefile
2024                 src/gallium/drivers/radeon/Makefile
2025                 src/gallium/drivers/radeonsi/Makefile
2026                 src/gallium/drivers/rbug/Makefile
2027                 src/gallium/drivers/softpipe/Makefile
2028                 src/gallium/drivers/svga/Makefile
2029                 src/gallium/drivers/trace/Makefile
2030                 src/gallium/state_trackers/Makefile
2031                 src/gallium/state_trackers/clover/Makefile
2032                 src/gallium/state_trackers/dri/Makefile
2033                 src/gallium/state_trackers/dri/drm/Makefile
2034                 src/gallium/state_trackers/dri/sw/Makefile
2035                 src/gallium/state_trackers/egl/Makefile
2036                 src/gallium/state_trackers/gbm/Makefile
2037                 src/gallium/state_trackers/glx/xlib/Makefile
2038                 src/gallium/state_trackers/omx/Makefile
2039                 src/gallium/state_trackers/osmesa/Makefile
2040                 src/gallium/state_trackers/vdpau/Makefile
2041                 src/gallium/state_trackers/vega/Makefile
2042                 src/gallium/state_trackers/xa/Makefile
2043                 src/gallium/state_trackers/xvmc/Makefile
2044                 src/gallium/targets/Makefile
2045                 src/gallium/targets/dri-freedreno/Makefile
2046                 src/gallium/targets/dri-i915/Makefile
2047                 src/gallium/targets/dri-ilo/Makefile
2048                 src/gallium/targets/dri-nouveau/Makefile
2049                 src/gallium/targets/dri-swrast/Makefile
2050                 src/gallium/targets/dri-vmwgfx/Makefile
2051                 src/gallium/targets/egl-static/Makefile
2052                 src/gallium/targets/gbm/Makefile
2053                 src/gallium/targets/opencl/Makefile
2054                 src/gallium/targets/xa/Makefile
2055                 src/gallium/targets/xa/xatracker.pc
2056                 src/gallium/targets/osmesa/Makefile
2057                 src/gallium/targets/osmesa/osmesa.pc
2058                 src/gallium/targets/pipe-loader/Makefile
2059                 src/gallium/targets/radeonsi/dri/Makefile
2060                 src/gallium/targets/radeonsi/omx/Makefile
2061                 src/gallium/targets/radeonsi/vdpau/Makefile
2062                 src/gallium/targets/r300/dri/Makefile
2063                 src/gallium/targets/r600/dri/Makefile
2064                 src/gallium/targets/r600/omx/Makefile
2065                 src/gallium/targets/r600/vdpau/Makefile
2066                 src/gallium/targets/r600/xvmc/Makefile
2067                 src/gallium/targets/libgl-xlib/Makefile
2068                 src/gallium/targets/vdpau-nouveau/Makefile
2069                 src/gallium/targets/xvmc-nouveau/Makefile
2070                 src/gallium/tests/trivial/Makefile
2071                 src/gallium/tests/unit/Makefile
2072                 src/gallium/winsys/Makefile
2073                 src/gallium/winsys/freedreno/drm/Makefile
2074                 src/gallium/winsys/i915/drm/Makefile
2075                 src/gallium/winsys/i915/sw/Makefile
2076                 src/gallium/winsys/intel/drm/Makefile
2077                 src/gallium/winsys/nouveau/drm/Makefile
2078                 src/gallium/winsys/radeon/drm/Makefile
2079                 src/gallium/winsys/svga/drm/Makefile
2080                 src/gallium/winsys/sw/dri/Makefile
2081                 src/gallium/winsys/sw/fbdev/Makefile
2082                 src/gallium/winsys/sw/null/Makefile
2083                 src/gallium/winsys/sw/wayland/Makefile
2084                 src/gallium/winsys/sw/wrapper/Makefile
2085                 src/gallium/winsys/sw/xlib/Makefile
2086                 src/gbm/Makefile
2087                 src/gbm/main/gbm.pc
2088                 src/glsl/Makefile
2089                 src/glx/Makefile
2090                 src/glx/tests/Makefile
2091                 src/gtest/Makefile
2092                 src/loader/Makefile
2093                 src/mapi/Makefile
2094                 src/mapi/es1api/Makefile
2095                 src/mapi/es1api/glesv1_cm.pc
2096                 src/mapi/es2api/Makefile
2097                 src/mapi/es2api/glesv2.pc
2098                 src/mapi/glapi/Makefile
2099                 src/mapi/glapi/gen/Makefile
2100                 src/mapi/glapi/tests/Makefile
2101                 src/mapi/shared-glapi/Makefile
2102                 src/mapi/shared-glapi/tests/Makefile
2103                 src/mapi/vgapi/Makefile
2104                 src/mapi/vgapi/vg.pc
2105                 src/mesa/Makefile
2106                 src/mesa/gl.pc
2107                 src/mesa/drivers/dri/dri.pc
2108                 src/mesa/drivers/dri/common/Makefile
2109                 src/mesa/drivers/dri/common/xmlpool/Makefile
2110                 src/mesa/drivers/dri/i915/Makefile
2111                 src/mesa/drivers/dri/i965/Makefile
2112                 src/mesa/drivers/dri/Makefile
2113                 src/mesa/drivers/dri/nouveau/Makefile
2114                 src/mesa/drivers/dri/r200/Makefile
2115                 src/mesa/drivers/dri/radeon/Makefile
2116                 src/mesa/drivers/dri/swrast/Makefile
2117                 src/mesa/drivers/osmesa/Makefile
2118                 src/mesa/drivers/osmesa/osmesa.pc
2119                 src/mesa/drivers/x11/Makefile
2120                 src/mesa/main/tests/Makefile
2121                 src/mesa/main/tests/hash_table/Makefile])
2122
2123 dnl Sort the dirs alphabetically
2124 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2125 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2126 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2127 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2128
2129 AC_OUTPUT
2130
2131 dnl
2132 dnl Output some configuration info for the user
2133 dnl
2134 echo ""
2135 echo "        prefix:          $prefix"
2136 echo "        exec_prefix:     $exec_prefix"
2137 echo "        libdir:          $libdir"
2138 echo "        includedir:      $includedir"
2139
2140 dnl API info
2141 echo ""
2142 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2143 echo "        OpenVG:          $enable_openvg"
2144
2145 dnl Driver info
2146 echo ""
2147 case "x$enable_osmesa$enable_gallium_osmesa" in
2148 xnoyes)
2149         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2150         ;;
2151 xyesno)
2152         echo "        OSMesa:          lib$OSMESA_LIB"
2153         ;;
2154 xnono)
2155         echo "        OSMesa:          no"
2156         ;;
2157 esac
2158
2159 if test "x$enable_dri" != xno; then
2160         if test -z "$DRI_DIRS"; then
2161             echo "        DRI drivers:     no"
2162         else
2163             echo "        DRI drivers:     $DRI_DIRS"
2164         fi
2165         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2166 fi
2167
2168 case "x$enable_glx$enable_xlib_glx" in
2169 xyesyes)
2170     echo "        GLX:             Xlib-based"
2171     ;;
2172 xyesno)
2173     echo "        GLX:             DRI-based"
2174     ;;
2175 *)
2176     echo "        GLX:             $enable_glx"
2177     ;;
2178 esac
2179
2180 dnl EGL
2181 echo ""
2182 echo "        EGL:             $enable_egl"
2183 if test "$enable_egl" = yes; then
2184     echo "        EGL platforms:   $egl_platforms"
2185
2186     egl_drivers=""
2187     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2188         egl_drivers="$egl_drivers builtin:egl_dri2"
2189     fi
2190
2191     if test "x$enable_gallium_egl" = xyes; then
2192         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2193         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2194     else
2195         echo "        EGL drivers:    $egl_drivers"
2196     fi
2197 fi
2198
2199 echo ""
2200 if test "x$MESA_LLVM" = x1; then
2201     echo "        llvm:            yes"
2202     echo "        llvm-config:     $LLVM_CONFIG"
2203     echo "        llvm-version:    $LLVM_VERSION"
2204 else
2205     echo "        llvm:            no"
2206 fi
2207
2208 echo ""
2209 if test -n "$with_gallium_drivers"; then
2210     echo "        Gallium:         yes"
2211     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2212     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2213     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2214     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2215 else
2216     echo "        Gallium:         no"
2217 fi
2218
2219
2220 dnl Libraries
2221 echo ""
2222 echo "        Shared libs:     $enable_shared"
2223 echo "        Static libs:     $enable_static"
2224 echo "        Shared-glapi:    $enable_shared_glapi"
2225
2226 dnl Compiler options
2227 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2228 cflags=`echo $CFLAGS | \
2229     $SED 's/^ *//;s/  */ /;s/ *$//'`
2230 cxxflags=`echo $CXXFLAGS | \
2231     $SED 's/^ *//;s/  */ /;s/ *$//'`
2232 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2233 echo ""
2234 echo "        CFLAGS:          $cflags"
2235 echo "        CXXFLAGS:        $cxxflags"
2236 echo "        Macros:          $defines"
2237 echo ""
2238 if test "x$MESA_LLVM" = x1; then
2239     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2240     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2241     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2242     echo ""
2243 fi
2244 echo "        PYTHON2:         $PYTHON2"
2245
2246 echo ""
2247 echo "        Run '${MAKE-make}' to build Mesa"
2248 echo ""