configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 dnl http://people.gnome.org/~walters/docs/build-api.txt
  18 dnl We don't support srcdir != builddir.
  19 echo \#buildapi-variable-no-builddir >/dev/null
  20
  21 # Support silent build rules, requires at least automake-1.11. Disable
  22 # by either passing --disable-silent-rules to configure or passing V=1
  23 # to make
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  25     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  26
  27 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  28
  29 dnl Set internal versions
  30 OSMESA_VERSION=8
  31 AC_SUBST([OSMESA_VERSION])
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.46
  36 LIBDRM_INTEL_REQUIRED=2.4.38
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  39 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AX_PYTHON_MODULE([libxml2], [needed])
  54 AC_PROG_SED
  55 AC_PROG_MKDIR_P
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([disable-static])
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 GEN_ASM_OFFSETS=no
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120
 121     if test "x$cross_compiling" = xyes; then
 122         GEN_ASM_OFFSETS=yes
 123     fi
 124 fi
 125 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 126
 127 dnl Make sure the pkg-config macros are defined
 128 m4_ifndef([PKG_PROG_PKG_CONFIG],
 129     [m4_fatal([Could not locate the pkg-config autoconf macros.
 130   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 131   are in a different location, try setting the environment variable
 132   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 133 PKG_PROG_PKG_CONFIG()
 134
 135 dnl LIB_DIR - library basename
 136 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 137 AC_SUBST([LIB_DIR])
 138
 139 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 140 _SAVE_LDFLAGS="$LDFLAGS"
 141 _SAVE_CPPFLAGS="$CPPFLAGS"
 142
 143 dnl Compiler macros
 144 DEFINES=""
 145 AC_SUBST([DEFINES])
 146 case "$host_os" in
 147 linux*|*-gnu*|gnu*)
 148     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 149     ;;
 150 solaris*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 152     ;;
 153 cygwin*)
 154     DEFINES="$DEFINES -DHAVE_PTHREAD"
 155     ;;
 156 esac
 157
 158 dnl Add flags for gcc and g++
 159 if test "x$GCC" = xyes; then
 160     case "$host_os" in
 161     cygwin*)
 162         CFLAGS="$CFLAGS -Wall -std=gnu99"
 163         ;;
 164     *)
 165         CFLAGS="$CFLAGS -Wall -std=c99"
 166         ;;
 167     esac
 168
 169     # Enable -Werror=implicit-function-declaration and
 170     # -Werror=missing-prototypes, if available, or otherwise, just
 171     # -Wmissing-prototypes.  This is particularly useful to avoid
 172     # generating a loadable driver module that has undefined symbols.
 173     save_CFLAGS="$CFLAGS"
 174     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 175     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 176     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 177     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 178                    AC_MSG_RESULT([yes]),
 179                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 180                     AC_MSG_RESULT([no])]);
 181
 182     # Enable -fvisibility=hidden if using a gcc that supports it
 183     save_CFLAGS="$CFLAGS"
 184     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 185     VISIBILITY_CFLAGS="-fvisibility=hidden"
 186     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 188                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 189
 190     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 191     CFLAGS=$save_CFLAGS
 192
 193     # Work around aliasing bugs - developers should comment this out
 194     CFLAGS="$CFLAGS -fno-strict-aliasing"
 195
 196     # gcc's builtin memcmp is slower than glibc's
 197     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 198     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 199 fi
 200 if test "x$GXX" = xyes; then
 201     CXXFLAGS="$CXXFLAGS -Wall"
 202
 203     # Enable -fvisibility=hidden if using a gcc that supports it
 204     save_CXXFLAGS="$CXXFLAGS"
 205     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 206     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 207     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 208     AC_LANG_PUSH([C++])
 209     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 210                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 211     AC_LANG_POP([C++])
 212
 213     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 214     CXXFLAGS=$save_CXXFLAGS
 215
 216     # Work around aliasing bugs - developers should comment this out
 217     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 218
 219     # gcc's builtin memcmp is slower than glibc's
 220     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 221     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 222 fi
 223
 224 dnl even if the compiler appears to support it, using visibility attributes isn't
 225 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 226 case "$host_os" in
 227 cygwin*)
 228     VISIBILITY_CFLAGS=""
 229     VISIBILITY_CXXFLAGS=""
 230     ;;
 231 esac
 232
 233 AC_SUBST([VISIBILITY_CFLAGS])
 234 AC_SUBST([VISIBILITY_CXXFLAGS])
 235
 236 dnl
 237 dnl Hacks to enable 32 or 64 bit build
 238 dnl
 239 AC_ARG_ENABLE([32-bit],
 240     [AS_HELP_STRING([--enable-32-bit],
 241         [build 32-bit libraries @<:@default=auto@:>@])],
 242     [enable_32bit="$enableval"],
 243     [enable_32bit=auto]
 244 )
 245 if test "x$enable_32bit" = xyes; then
 246     if test "x$GCC" = xyes; then
 247         CFLAGS="$CFLAGS -m32"
 248         CCASFLAGS="$CCASFLAGS -m32"
 249     fi
 250     if test "x$GXX" = xyes; then
 251         CXXFLAGS="$CXXFLAGS -m32"
 252     fi
 253 fi
 254 AC_ARG_ENABLE([64-bit],
 255     [AS_HELP_STRING([--enable-64-bit],
 256         [build 64-bit libraries @<:@default=auto@:>@])],
 257     [enable_64bit="$enableval"],
 258     [enable_64bit=auto]
 259 )
 260 if test "x$enable_64bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m64"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m64"
 266     fi
 267 fi
 268
 269 dnl Can't have static and shared libraries, default to static if user
 270 dnl explicitly requested. If both disabled, set to static since shared
 271 dnl was explicitly requested.
 272 case "x$enable_static$enable_shared" in
 273 xyesyes )
 274     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 275     enable_shared=no
 276     ;;
 277 xnono )
 278     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 279     enable_static=yes
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 284
 285 dnl
 286 dnl other compiler options
 287 dnl
 288 AC_ARG_ENABLE([debug],
 289     [AS_HELP_STRING([--enable-debug],
 290         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 291     [enable_debug="$enableval"],
 292     [enable_debug=no]
 293 )
 294 if test "x$enable_debug" = xyes; then
 295     DEFINES="$DEFINES -DDEBUG"
 296     if test "x$GCC" = xyes; then
 297         CFLAGS="$CFLAGS -g -O0"
 298     fi
 299     if test "x$GXX" = xyes; then
 300         CXXFLAGS="$CXXFLAGS -g -O0"
 301     fi
 302 fi
 303
 304 dnl
 305 dnl library names
 306 dnl
 307 LIB_PREFIX_GLOB='lib'
 308 LIB_VERSION_SEPARATOR='.'
 309 if test "$enable_static" = yes; then
 310     LIB_EXTENSION='a'
 311 else
 312     case "$host_os" in
 313     darwin* )
 314         LIB_EXTENSION='dylib' ;;
 315     cygwin* )
 316         dnl prefix can be 'cyg' or 'lib'
 317         LIB_PREFIX_GLOB='???'
 318         LIB_VERSION_SEPARATOR='-'
 319         LIB_EXTENSION='dll' ;;
 320     aix* )
 321         LIB_EXTENSION='a' ;;
 322     * )
 323         LIB_EXTENSION='so' ;;
 324     esac
 325 fi
 326 AC_ARG_WITH([gl-lib-name],
 327   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 328     [specify GL library name @<:@default=GL@:>@])],
 329   [GL_LIB=$withval],
 330   [GL_LIB=GL])
 331 AC_ARG_WITH([osmesa-lib-name],
 332   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 333     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 334   [OSMESA_LIB=$withval],
 335   [OSMESA_LIB=OSMesa])
 336 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 337 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 338
 339 dnl
 340 dnl Mangled Mesa support
 341 dnl
 342 AC_ARG_ENABLE([mangling],
 343   [AS_HELP_STRING([--enable-mangling],
 344     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 345   [enable_mangling="${enableval}"],
 346   [enable_mangling=no]
 347 )
 348 if test "x${enable_mangling}" = "xyes" ; then
 349   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 350   GL_LIB="Mangled${GL_LIB}"
 351   OSMESA_LIB="Mangled${OSMESA_LIB}"
 352 fi
 353 AC_SUBST([GL_LIB])
 354 AC_SUBST([OSMESA_LIB])
 355
 356 dnl
 357 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 358 dnl
 359 AC_ARG_ENABLE([texture-float],
 360     [AS_HELP_STRING([--enable-texture-float],
 361         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 362     [enable_texture_float="$enableval"],
 363     [enable_texture_float=no]
 364 )
 365 if test "x$enable_texture_float" = xyes; then
 366     AC_MSG_WARN([Floating-point textures enabled.])
 367     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 368     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 369 fi
 370
 371 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 372 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 373 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 374 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 375 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 376 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 377 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 378
 379 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 380 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 381 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 382 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386
 387 AC_SUBST([GL_LIB_NAME])
 388 AC_SUBST([OSMESA_LIB_NAME])
 389 AC_SUBST([EGL_LIB_NAME])
 390 AC_SUBST([GLESv1_CM_LIB_NAME])
 391 AC_SUBST([GLESv2_LIB_NAME])
 392 AC_SUBST([VG_LIB_NAME])
 393 AC_SUBST([GLAPI_LIB_NAME])
 394
 395 AC_SUBST([GL_LIB_GLOB])
 396 AC_SUBST([EGL_LIB_GLOB])
 397 AC_SUBST([GLESv1_CM_LIB_GLOB])
 398 AC_SUBST([GLESv2_LIB_GLOB])
 399 AC_SUBST([VG_LIB_GLOB])
 400 AC_SUBST([GLAPI_LIB_GLOB])
 401
 402 dnl
 403 dnl Arch/platform-specific settings
 404 dnl
 405 AC_ARG_ENABLE([asm],
 406     [AS_HELP_STRING([--disable-asm],
 407         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 408     [enable_asm="$enableval"],
 409     [enable_asm=yes]
 410 )
 411 asm_arch=""
 412 AC_MSG_CHECKING([whether to enable assembly])
 413 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 414 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 415 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 416     case "$host_cpu" in
 417     i?86 | x86_64 | amd64)
 418         enable_asm=no
 419         AC_MSG_RESULT([no, cross compiling])
 420         ;;
 421     esac
 422 fi
 423 # check for supported arches
 424 if test "x$enable_asm" = xyes; then
 425     case "$host_cpu" in
 426     i?86)
 427         case "$host_os" in
 428         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 429             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 430             ;;
 431         gnu*)
 432             asm_arch=x86
 433             ;;
 434         esac
 435         ;;
 436     x86_64|amd64)
 437         case "$host_os" in
 438         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 439             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 440             ;;
 441         esac
 442         ;;
 443     sparc*)
 444         case "$host_os" in
 445         linux*)
 446             asm_arch=sparc
 447             ;;
 448         esac
 449         ;;
 450     esac
 451
 452     case "$asm_arch" in
 453     x86)
 454         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 455         AC_MSG_RESULT([yes, x86])
 456         ;;
 457     x86_64|amd64)
 458         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 459         AC_MSG_RESULT([yes, x86_64])
 460         ;;
 461     sparc)
 462         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 463         AC_MSG_RESULT([yes, sparc])
 464         ;;
 465     *)
 466         AC_MSG_RESULT([no, platform not supported])
 467         ;;
 468     esac
 469 fi
 470
 471 dnl Check to see if dlopen is in default libraries (like Solaris, which
 472 dnl has it in libc), or if libdl is needed to get it.
 473 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 474     [AC_CHECK_LIB([dl], [dlopen],
 475        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 476 AC_SUBST([DLOPEN_LIBS])
 477
 478 case "$host_os" in
 479 darwin*|mingw*)
 480     ;;
 481 *)
 482     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 483                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 484                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 485     AC_SUBST([CLOCK_LIB])
 486     ;;
 487 esac
 488
 489 dnl See if posix_memalign is available
 490 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 491
 492 dnl Check for pthreads
 493 AX_PTHREAD
 494 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 495 dnl to -pthread, which causes problems if we need -lpthread to appear in
 496 dnl pkgconfig files.
 497 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 498
 499 dnl SELinux awareness.
 500 AC_ARG_ENABLE([selinux],
 501     [AS_HELP_STRING([--enable-selinux],
 502         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 503     [MESA_SELINUX="$enableval"],
 504     [MESA_SELINUX=no])
 505 if test "x$enable_selinux" = "xyes"; then
 506     AC_CHECK_HEADER([selinux/selinux.h],[],
 507                     [AC_MSG_ERROR([SELinux headers not found])])
 508     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 509                  [AC_MSG_ERROR([SELinux library not found])])
 510     SELINUX_LIBS="-lselinux"
 511     DEFINES="$DEFINES -DMESA_SELINUX"
 512 fi
 513 AC_SUBST([SELINUX_LIBS])
 514
 515 dnl Options for APIs
 516 AC_ARG_ENABLE([opengl],
 517     [AS_HELP_STRING([--disable-opengl],
 518         [disable support for standard OpenGL API @<:@default=no@:>@])],
 519     [enable_opengl="$enableval"],
 520     [enable_opengl=yes])
 521 AC_ARG_ENABLE([gles1],
 522     [AS_HELP_STRING([--enable-gles1],
 523         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 524     [enable_gles1="$enableval"],
 525     [enable_gles1=no])
 526 AC_ARG_ENABLE([gles2],
 527     [AS_HELP_STRING([--enable-gles2],
 528         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 529     [enable_gles2="$enableval"],
 530     [enable_gles2=no])
 531 AC_ARG_ENABLE([openvg],
 532     [AS_HELP_STRING([--enable-openvg],
 533         [enable support for OpenVG API @<:@default=no@:>@])],
 534     [enable_openvg="$enableval"],
 535     [enable_openvg=no])
 536
 537 AC_ARG_ENABLE([dri],
 538     [AS_HELP_STRING([--enable-dri],
 539         [enable DRI modules @<:@default=enabled@:>@])],
 540     [enable_dri="$enableval"],
 541     [enable_dri=yes])
 542 AC_ARG_ENABLE([glx],
 543     [AS_HELP_STRING([--enable-glx],
 544         [enable GLX library @<:@default=enabled@:>@])],
 545     [enable_glx="$enableval"],
 546     [enable_glx=yes])
 547 AC_ARG_ENABLE([osmesa],
 548     [AS_HELP_STRING([--enable-osmesa],
 549         [enable OSMesa library @<:@default=disabled@:>@])],
 550     [enable_osmesa="$enableval"],
 551     [enable_osmesa=no])
 552 AC_ARG_ENABLE([gallium-osmesa],
 553     [AS_HELP_STRING([--enable-gallium-osmesa],
 554         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 555     [enable_gallium_osmesa="$enableval"],
 556     [enable_gallium_osmesa=no])
 557 AC_ARG_ENABLE([egl],
 558     [AS_HELP_STRING([--disable-egl],
 559         [disable EGL library @<:@default=enabled@:>@])],
 560     [enable_egl="$enableval"],
 561     [enable_egl=yes])
 562
 563 AC_ARG_ENABLE([xorg],
 564     [AS_HELP_STRING([--enable-xorg],
 565         [enable support for X.Org DDX API @<:@default=no@:>@])],
 566     [enable_xorg="$enableval"],
 567     [enable_xorg=no])
 568 AC_ARG_ENABLE([xa],
 569     [AS_HELP_STRING([--enable-xa],
 570         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 571     [enable_xa="$enableval"],
 572     [enable_xa=no])
 573 AC_ARG_ENABLE([gbm],
 574    [AS_HELP_STRING([--enable-gbm],
 575          [enable gbm library @<:@default=auto@:>@])],
 576    [enable_gbm="$enableval"],
 577    [enable_gbm=auto])
 578
 579 AC_ARG_ENABLE([xvmc],
 580    [AS_HELP_STRING([--enable-xvmc],
 581          [enable xvmc library @<:@default=auto@:>@])],
 582    [enable_xvmc="$enableval"],
 583    [enable_xvmc=auto])
 584 AC_ARG_ENABLE([vdpau],
 585    [AS_HELP_STRING([--enable-vdpau],
 586          [enable vdpau library @<:@default=auto@:>@])],
 587    [enable_vdpau="$enableval"],
 588    [enable_vdpau=auto])
 589 AC_ARG_ENABLE([opencl],
 590    [AS_HELP_STRING([--enable-opencl],
 591          [enable OpenCL library NOTE: Enabling this option will also enable
 592           --with-llvm-shared-libs
 593           @<:@default=no@:>@])],
 594    [],
 595    [enable_opencl=no])
 596 AC_ARG_ENABLE([opencl_icd],
 597    [AS_HELP_STRING([--enable-opencl-icd],
 598           [Build an OpenCL ICD library to be loaded by an ICD implementation
 599            @<:@default=no@:>@])],
 600     [enable_opencl_icd="$enableval"],
 601     [enable_opencl_icd=no])
 602 AC_ARG_ENABLE([xlib-glx],
 603     [AS_HELP_STRING([--enable-xlib-glx],
 604         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 605     [enable_xlib_glx="$enableval"],
 606     [enable_xlib_glx=no])
 607 AC_ARG_ENABLE([gallium-egl],
 608     [AS_HELP_STRING([--enable-gallium-egl],
 609         [enable optional EGL state tracker (not required
 610          for EGL support in Gallium with OpenGL and OpenGL ES)
 611          @<:@default=disable@:>@])],
 612     [enable_gallium_egl="$enableval"],
 613     [enable_gallium_egl=no])
 614 AC_ARG_ENABLE([gallium-gbm],
 615     [AS_HELP_STRING([--enable-gallium-gbm],
 616         [enable optional gbm state tracker (not required for
 617          gbm support in Gallium)
 618          @<:@default=auto@:>@])],
 619     [enable_gallium_gbm="$enableval"],
 620     [enable_gallium_gbm=auto])
 621
 622 AC_ARG_ENABLE([r600-llvm-compiler],
 623     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 624         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 625     [enable_r600_llvm="$enableval"],
 626     [enable_r600_llvm=no])
 627
 628 AC_ARG_ENABLE([gallium-tests],
 629     [AS_HELP_STRING([--enable-gallium-tests],
 630         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 631     [enable_gallium_tests="$enableval"],
 632     [enable_gallium_tests=no])
 633
 634 # Option for Gallium drivers
 635
 636 # Keep this in sync with the --with-gallium-drivers help string default value
 637 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 638
 639 AC_ARG_WITH([gallium-drivers],
 640     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 641         [comma delimited Gallium drivers list, e.g.
 642         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 643         @<:@default=r300,r600,svga,swrast@:>@])],
 644     [with_gallium_drivers="$withval"],
 645     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 646
 647 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 648 # here so that the script doesn't choke on an unknown driver name later.
 649 case "$with_gallium_drivers" in
 650     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 651     no) with_gallium_drivers='' ;;
 652 esac
 653
 654 if test "x$enable_opengl" = xno -a \
 655         "x$enable_gles1" = xno -a \
 656         "x$enable_gles2" = xno -a \
 657         "x$enable_openvg" = xno -a \
 658         "x$enable_xorg" = xno -a \
 659         "x$enable_xa" = xno -a \
 660         "x$enable_xvmc" = xno -a \
 661         "x$enable_vdpau" = xno -a \
 662         "x$enable_opencl" = xno; then
 663     AC_MSG_ERROR([at least one API should be enabled])
 664 fi
 665
 666 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 667 if test "x$enable_opengl" = xno -a \
 668         "x$enable_gles1" = xyes; then
 669     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 670 fi
 671
 672 if test "x$enable_opengl" = xno -a \
 673         "x$enable_gles2" = xyes; then
 674     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 675 fi
 676
 677 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 678 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 679 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 680 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 681                                         "x$enable_gles1" = xyes -o \
 682                                         "x$enable_gles2" = xyes)
 683
 684 if test "x$enable_glx" = xno; then
 685     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 686     enable_xlib_glx=no
 687 fi
 688
 689 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 690     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 691 fi
 692
 693 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 694     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 695 fi
 696
 697 # Disable GLX if OpenGL is not enabled
 698 if test "x$enable_glx$enable_opengl" = xyesno; then
 699     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 700     enable_glx=no
 701 fi
 702
 703 # Disable GLX if DRI and Xlib-GLX are not enabled
 704 if test "x$enable_glx" = xyes -a \
 705         "x$enable_dri" = xno -a \
 706         "x$enable_xlib_glx" = xno; then
 707     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 708     enable_glx=no
 709 fi
 710
 711 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 712                                   "x$enable_dri" = xyes)
 713 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 714 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 715                                   "x$enable_osmesa" = xyes)
 716
 717 AC_ARG_ENABLE([shared-glapi],
 718     [AS_HELP_STRING([--enable-shared-glapi],
 719         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 720     [enable_shared_glapi="$enableval"],
 721     [enable_shared_glapi="$enable_dri"])
 722
 723 # Shared GLAPI is only useful for DRI
 724 if test "x$enable_dri" = xno; then
 725     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 726     enable_shared_glapi=no
 727 fi
 728
 729 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 730
 731 dnl
 732 dnl Driver specific build directories
 733 dnl
 734 GALLIUM_TARGET_DIRS=""
 735 GALLIUM_WINSYS_DIRS="sw"
 736 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 737 GALLIUM_STATE_TRACKERS_DIRS=""
 738
 739 case "x$enable_glx$enable_xlib_glx" in
 740 xyesyes)
 741     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 742     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 743     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 744     NEED_WINSYS_XLIB="yes"
 745     ;;
 746 esac
 747
 748 if test "x$enable_dri" = xyes; then
 749     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 750     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 751 fi
 752
 753 if test "x$enable_gallium_osmesa" = xyes; then
 754     if test -z "$with_gallium_drivers"; then
 755         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 756     fi
 757     if test "x$enable_osmesa" = xyes; then
 758         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 759     fi
 760     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 761     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 762 fi
 763
 764 AC_SUBST([MESA_LLVM])
 765
 766 # Check for libdrm
 767 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 768                   [have_libdrm=yes], [have_libdrm=no])
 769
 770 if test "x$enable_dri" = xyes; then
 771     # DRI must be shared, I think
 772     if test "$enable_static" = yes; then
 773         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 774     fi
 775
 776     # not a hard requirement as swrast does not depend on it
 777     if test "x$have_libdrm" = xyes; then
 778         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 779     fi
 780 fi
 781
 782 dnl Direct rendering or just indirect rendering
 783 case "$host_os" in
 784 gnu*)
 785     dnl Disable by default on GNU/Hurd
 786     driglx_direct_default="no"
 787     ;;
 788 cygwin*)
 789     dnl Disable by default on cygwin
 790     driglx_direct_default="no"
 791     ;;
 792 *)
 793     driglx_direct_default="yes"
 794     ;;
 795 esac
 796 AC_ARG_ENABLE([driglx-direct],
 797     [AS_HELP_STRING([--disable-driglx-direct],
 798         [disable direct rendering in GLX and EGL for DRI \
 799             @<:@default=auto@:>@])],
 800     [driglx_direct="$enableval"],
 801     [driglx_direct="$driglx_direct_default"])
 802
 803 dnl
 804 dnl libGL configuration per driver
 805 dnl
 806 case "x$enable_glx$enable_xlib_glx" in
 807 xyesyes)
 808     # Xlib-based GLX
 809     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 810     GL_PC_REQ_PRIV="x11 xext"
 811     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 812     GL_LIB_DEPS="$XLIBGL_LIBS"
 813     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 814     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 815     ;;
 816 xyesno)
 817     # DRI-based GLX
 818     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 819     if test x"$driglx_direct" = xyes; then
 820         if test "x$have_libdrm" != xyes; then
 821             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 822         fi
 823         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 824         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 825     fi
 826
 827     # find the DRI deps for libGL
 828     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 829
 830     # add xf86vidmode if available
 831     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 832     if test "$HAVE_XF86VIDMODE" = yes ; then
 833         dri_modules="$dri_modules xxf86vm"
 834     fi
 835
 836     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 837     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 838     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 839     GL_LIB_DEPS="$DRIGL_LIBS"
 840
 841     # need DRM libs, $PTHREAD_LIBS, etc.
 842     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 843     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 844     ;;
 845 esac
 846
 847 # This is outside the case (above) so that it is invoked even for non-GLX
 848 # builds.
 849 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 850
 851 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 852 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 853 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 854 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 855
 856 AC_SUBST([X11_INCLUDES])
 857 AC_SUBST([GL_LIB_DEPS])
 858 AC_SUBST([GL_PC_REQ_PRIV])
 859 AC_SUBST([GL_PC_LIB_PRIV])
 860 AC_SUBST([GL_PC_CFLAGS])
 861 AC_SUBST([DRI_PC_REQ_PRIV])
 862 AC_SUBST([GLESv1_CM_LIB_DEPS])
 863 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 864 AC_SUBST([GLESv2_LIB_DEPS])
 865 AC_SUBST([GLESv2_PC_LIB_PRIV])
 866
 867 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 868
 869 AC_SUBST([HAVE_XF86VIDMODE])
 870
 871 dnl
 872 dnl More GLX setup
 873 dnl
 874 case "x$enable_glx$enable_xlib_glx" in
 875 xyesyes)
 876     DEFINES="$DEFINES -DUSE_XSHM"
 877     ;;
 878 xyesno)
 879     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 880     if test "x$driglx_direct" = xyes; then
 881         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 882     fi
 883     ;;
 884 esac
 885
 886 dnl
 887 dnl TLS detection
 888 dnl
 889
 890 AC_ARG_ENABLE([glx-tls],
 891     [AS_HELP_STRING([--enable-glx-tls],
 892         [enable TLS support in GLX @<:@default=disabled@:>@])],
 893     [GLX_USE_TLS="$enableval"],
 894     [GLX_USE_TLS=no])
 895 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 896
 897 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 898       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 899
 900 dnl
 901 dnl More DRI setup
 902 dnl
 903 dnl Directory for DRI drivers
 904 AC_ARG_WITH([dri-driverdir],
 905     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 906         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 907     [DRI_DRIVER_INSTALL_DIR="$withval"],
 908     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 909 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 910 dnl Extra search path for DRI drivers
 911 AC_ARG_WITH([dri-searchpath],
 912     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 913         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 914     [DRI_DRIVER_SEARCH_DIR="$withval"],
 915     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 916 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 917 dnl Which drivers to build - default is chosen by platform
 918 AC_ARG_WITH([dri-drivers],
 919     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 920         [comma delimited DRI drivers list, e.g.
 921         "swrast,i965,radeon" @<:@default=auto@:>@])],
 922     [with_dri_drivers="$withval"],
 923     [with_dri_drivers=yes])
 924 if test "x$with_dri_drivers" = x; then
 925     with_dri_drivers=no
 926 fi
 927
 928 dnl If $with_dri_drivers is yes, directories will be added through
 929 dnl platform checks
 930 DRI_DIRS=""
 931 case "$with_dri_drivers" in
 932 no) ;;
 933 yes)
 934     # classic DRI drivers
 935     if test "x$enable_opengl" = xyes; then
 936         DRI_DIRS="yes"
 937     fi
 938     ;;
 939 *)
 940     # verify the requested driver directories exist
 941     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 942     for driver in $dri_drivers; do
 943         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 944             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 945     done
 946     DRI_DIRS="$dri_drivers"
 947     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 948         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 949     fi
 950     ;;
 951 esac
 952
 953 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 954 if test "x$enable_dri" = xyes; then
 955     # Platform specific settings and drivers to build
 956     case "$host_os" in
 957     linux*)
 958         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 959         DEFINES="$DEFINES -DHAVE_ALIAS"
 960
 961         case "$host_cpu" in
 962         x86_64|amd64)
 963             if test "x$DRI_DIRS" = "xyes"; then
 964                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 965             fi
 966             ;;
 967         powerpc*)
 968             # Build only the drivers for cards that exist on PowerPC.
 969             if test "x$DRI_DIRS" = "xyes"; then
 970                 DRI_DIRS="r200 radeon swrast"
 971             fi
 972             ;;
 973         sparc*)
 974             # Build only the drivers for cards that exist on sparc
 975             if test "x$DRI_DIRS" = "xyes"; then
 976                 DRI_DIRS="r200 radeon swrast"
 977             fi
 978             ;;
 979         esac
 980         ;;
 981     freebsd* | dragonfly* | *netbsd* | openbsd*)
 982         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 983         DEFINES="$DEFINES -DHAVE_ALIAS"
 984
 985         if test "x$DRI_DIRS" = "xyes"; then
 986             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 987         fi
 988         ;;
 989     gnu*)
 990         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 991         DEFINES="$DEFINES -DHAVE_ALIAS"
 992         ;;
 993     solaris*)
 994         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 995         ;;
 996     cygwin*)
 997         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 998         if test "x$DRI_DIRS" = "xyes"; then
 999             DRI_DIRS="swrast"
1000         fi
1001         ;;
1002     esac
1003
1004     # default drivers
1005     if test "x$DRI_DIRS" = "xyes"; then
1006         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1007     fi
1008
1009     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1010
1011     # Check for expat
1012     EXPAT_INCLUDES=""
1013     EXPAT_LIB=-lexpat
1014     AC_ARG_WITH([expat],
1015         [AS_HELP_STRING([--with-expat=DIR],
1016             [expat install directory])],[
1017         EXPAT_INCLUDES="-I$withval/include"
1018         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1019         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1020         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1021         ])
1022     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1023     save_LIBS="$LIBS"
1024     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1025         [AC_MSG_ERROR([Expat required for DRI.])])
1026     LIBS="$save_LIBS"
1027
1028     # If we are building any DRI driver other than swrast.
1029     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1030         # ... libdrm is required
1031         if test "x$have_libdrm" != xyes; then
1032             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1033         fi
1034     fi
1035
1036     # put all the necessary libs together
1037     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1038     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1039
1040     DRI_DRIVER_LDFLAGS="-module -avoid-version -shared -Wl,-Bsymbolic"
1041 fi
1042 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1043 AC_SUBST([EXPAT_INCLUDES])
1044 AC_SUBST([DRI_LIB_DEPS])
1045 AC_SUBST([DRI_DRIVER_LDFLAGS])
1046 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1047
1048 case $DRI_DIRS in
1049 *i915*|*i965*)
1050     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1051
1052     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1053         case $d in
1054         i915)
1055             HAVE_I915_DRI=yes;
1056             ;;
1057         i965)
1058             HAVE_I965_DRI=yes;
1059             ;;
1060         esac
1061     done
1062
1063     ;;
1064 esac
1065
1066 case $DRI_DIRS in
1067 *nouveau*)
1068     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1069     HAVE_NOUVEAU_DRI=yes;
1070     ;;
1071 esac
1072
1073 case $DRI_DIRS in
1074 *radeon*|*r200*)
1075     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1076
1077     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1078         case $d in
1079         radeon)
1080             HAVE_RADEON_DRI=yes;
1081             ;;
1082         r200)
1083             HAVE_R200_DRI=yes;
1084             ;;
1085         esac
1086     done
1087
1088     ;;
1089 esac
1090
1091 case $DRI_DIRS in
1092 *swrast*)
1093     HAVE_SWRAST_DRI=yes;
1094     ;;
1095 esac
1096
1097 dnl
1098 dnl OSMesa configuration
1099 dnl
1100
1101 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1102 AC_ARG_WITH([osmesa-bits],
1103     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1104         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1105     [osmesa_bits="$withval"],
1106     [osmesa_bits=8])
1107 if test "x$osmesa_bits" != x8; then
1108     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1109         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1110         osmesa_bits=8
1111     fi
1112 fi
1113 case "x$osmesa_bits" in
1114 x8)
1115     OSMESA_LIB="${OSMESA_LIB}"
1116     ;;
1117 x16|x32)
1118     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1119     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1120     ;;
1121 *)
1122     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1123     ;;
1124 esac
1125
1126 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1127     # only link libraries with osmesa if shared
1128     if test "$enable_static" = no; then
1129         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1130     else
1131         OSMESA_LIB_DEPS=""
1132     fi
1133     OSMESA_MESA_DEPS=""
1134     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1135 fi
1136
1137 AC_SUBST([OSMESA_LIB_DEPS])
1138 AC_SUBST([OSMESA_MESA_DEPS])
1139 AC_SUBST([OSMESA_PC_REQ])
1140 AC_SUBST([OSMESA_PC_LIB_PRIV])
1141
1142 dnl
1143 dnl gbm configuration
1144 dnl
1145 if test "x$enable_gbm" = xauto; then
1146     case "$with_egl_platforms" in
1147         *drm*)
1148             enable_gbm=yes ;;
1149          *)
1150             enable_gbm=no ;;
1151     esac
1152 fi
1153 if test "x$enable_gbm" = xyes; then
1154     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1155                       AC_MSG_ERROR([gbm needs udev]))
1156
1157     if test "x$enable_dri" = xyes; then
1158         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1159         if test "x$enable_shared_glapi" = xno; then
1160             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1161         fi
1162     fi
1163 fi
1164 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1165 GBM_PC_REQ_PRIV="libudev"
1166 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1167 AC_SUBST([GBM_PC_REQ_PRIV])
1168 AC_SUBST([GBM_PC_LIB_PRIV])
1169
1170 dnl
1171 dnl EGL configuration
1172 dnl
1173 EGL_CLIENT_APIS=""
1174
1175 if test "x$enable_egl" = xyes; then
1176     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1177
1178     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1179
1180     if test "$enable_static" != yes; then
1181         # build egl_glx when libGL is built
1182         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1183                           [have_libudev=yes],[have_libudev=no])
1184         if test "$have_libudev" = yes; then
1185             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1186         fi
1187
1188         if test "x$enable_dri" = xyes; then
1189             HAVE_EGL_DRIVER_DRI2=1
1190         fi
1191
1192     fi
1193 fi
1194 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1195 AC_SUBST([EGL_LIB_DEPS])
1196
1197 dnl
1198 dnl EGL Gallium configuration
1199 dnl
1200 if test "x$enable_gallium_egl" = xyes; then
1201     if test "x$with_gallium_drivers" = x; then
1202         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1203     fi
1204     if test "x$enable_egl" = xno; then
1205         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1206     fi
1207     if test "x$have_libdrm" != xyes; then
1208         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1209     fi
1210
1211     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1212     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1213 fi
1214 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1215
1216 dnl
1217 dnl gbm Gallium configuration
1218 dnl
1219 if test "x$enable_gallium_gbm" = xauto; then
1220     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1221         yesyesyes*drm*)
1222             enable_gallium_gbm=yes ;;
1223          *)
1224             enable_gallium_gbm=no ;;
1225     esac
1226 fi
1227 if test "x$enable_gallium_gbm" = xyes; then
1228     if test "x$with_gallium_drivers" = x; then
1229         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1230     fi
1231     if test "x$enable_gbm" = xno; then
1232         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1233     fi
1234     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1235     if test "x$enable_dri" = xno; then
1236         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1237     fi
1238
1239     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1240     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1241     enable_gallium_loader=yes
1242 fi
1243 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1244
1245 dnl
1246 dnl X.Org DDX configuration
1247 dnl
1248 if test "x$enable_xorg" = xyes; then
1249     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1250     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1251     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1252     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1253         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1254         HAVE_XEXTPROTO_71="no")
1255     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1256 fi
1257 AM_CONDITIONAL(HAVE_ST_XORG, test "x$enable_xorg" = xyes)
1258
1259 dnl
1260 dnl XA configuration
1261 dnl
1262 if test "x$enable_xa" = xyes; then
1263     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1264 fi
1265 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1266
1267 dnl
1268 dnl OpenVG configuration
1269 dnl
1270 VG_LIB_DEPS=""
1271
1272 if test "x$enable_openvg" = xyes; then
1273     if test "x$enable_egl" = xno; then
1274         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1275     fi
1276     if test "x$with_gallium_drivers" = x; then
1277         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1278     fi
1279     if test "x$enable_gallium_egl" = xno; then
1280         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1281     fi
1282
1283     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1284     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1285     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1286     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1287     AC_SUBST([VG_PC_LIB_PRIV])
1288 fi
1289 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1290
1291 dnl
1292 dnl Gallium G3DVL configuration
1293 dnl
1294 if test -n "$with_gallium_drivers"; then
1295     if test "x$enable_xvmc" = xauto; then
1296         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1297     fi
1298
1299     if test "x$enable_vdpau" = xauto; then
1300         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1301     fi
1302 fi
1303
1304 if test "x$enable_xvmc" = xyes; then
1305     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1306     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1307 fi
1308 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1309
1310 if test "x$enable_vdpau" = xyes; then
1311     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1312     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1313 fi
1314 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1315
1316 dnl
1317 dnl OpenCL configuration
1318 dnl
1319
1320 AC_ARG_WITH([libclc-path],
1321    [AS_HELP_STRING([--with-libclc-path],
1322          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1323    [LIBCLC_PATH="$withval"],
1324    [LIBCLC_PATH=""])
1325
1326 if test "x$LIBCLC_PATH" != x; then
1327    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1328                   Please review the updated build instructions for clover:
1329                   http://dri.freedesktop.org/wiki/GalliumCompute])
1330 fi
1331
1332
1333 AC_ARG_WITH([clang-libdir],
1334    [AS_HELP_STRING([--with-clang-libdir],
1335          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1336    [CLANG_LIBDIR="$withval"],
1337    [CLANG_LIBDIR=""])
1338
1339 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1340
1341 if test "x$enable_opencl" = xyes; then
1342     if test "x$with_gallium_drivers" = x; then
1343         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1344     fi
1345
1346     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1347         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1348     fi
1349
1350     if test "x$have_libclc" = xno; then
1351         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1352                     Make sure the directory containing libclc.pc is specified in your
1353                     PKG_CONFIG_PATH environment variable.
1354                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1355     else
1356         LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1357         LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1358         AC_SUBST([LIBCLC_INCLUDEDIR])
1359         AC_SUBST([LIBCLC_LIBEXECDIR])
1360     fi
1361
1362     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1363     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1364     enable_gallium_loader=yes
1365
1366     if test "x$enable_opencl_icd" = xyes; then
1367         OPENCL_LIBNAME="MesaOpenCL"
1368     else
1369         OPENCL_LIBNAME="OpenCL"
1370     fi
1371 fi
1372 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1373 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1374 AC_SUBST([OPENCL_LIBNAME])
1375
1376 dnl
1377 dnl Gallium configuration
1378 dnl
1379 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1380
1381 AC_SUBST([LLVM_BINDIR])
1382 AC_SUBST([LLVM_CFLAGS])
1383 AC_SUBST([LLVM_CPPFLAGS])
1384 AC_SUBST([LLVM_CXXFLAGS])
1385 AC_SUBST([LLVM_LIBDIR])
1386 AC_SUBST([LLVM_LIBS])
1387 AC_SUBST([LLVM_LDFLAGS])
1388 AC_SUBST([LLVM_INCLUDEDIR])
1389 AC_SUBST([LLVM_VERSION])
1390 AC_SUBST([CLANG_RESOURCE_DIR])
1391
1392 case "x$enable_opengl$enable_gles1$enable_gles2" in
1393 x*yes*)
1394     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1395     ;;
1396 esac
1397
1398 AC_SUBST([VG_LIB_DEPS])
1399 AC_SUBST([EGL_CLIENT_APIS])
1400
1401 dnl
1402 dnl EGL Platforms configuration
1403 dnl
1404 AC_ARG_WITH([egl-platforms],
1405     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1406         [comma delimited native platforms libEGL supports, e.g.
1407         "x11,drm" @<:@default=auto@:>@])],
1408     [with_egl_platforms="$withval"],
1409     [if test "x$enable_egl" = xyes; then
1410         with_egl_platforms="x11"
1411     else
1412         with_egl_platforms=""
1413     fi])
1414
1415 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1416     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1417 fi
1418
1419 # Do per-EGL platform setups and checks
1420 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1421 for plat in $egl_platforms; do
1422         case "$plat" in
1423         wayland)
1424                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1425                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1426
1427                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1428                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1429                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1430                 ;;
1431
1432         x11)
1433                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1434
1435                 if test "x$enable_glx" = xyes; then
1436                         HAVE_EGL_DRIVER_GLX=1
1437                 fi
1438                 ;;
1439
1440         drm)
1441                 test "x$enable_gbm" = "xno" &&
1442                         AC_MSG_ERROR([EGL platform drm needs gbm])
1443                 ;;
1444
1445         android|fbdev|gdi|null)
1446                 ;;
1447
1448         *)
1449                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1450                 ;;
1451         esac
1452
1453         case "$plat$have_libudev" in
1454                 waylandno|drmno)
1455                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1456         esac
1457 done
1458
1459 # libEGL wants to default to the first platform specified in
1460 # ./configure.  parse that here.
1461 if test "x$egl_platforms" != "x"; then
1462     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1463     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1464 else
1465     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1466 fi
1467
1468 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1469     NEED_WINSYS_XLIB=yes
1470 fi
1471 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1472 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1473 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1474 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1475 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1476
1477 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1478 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1479
1480 AC_SUBST([EGL_NATIVE_PLATFORM])
1481 AC_SUBST([EGL_CFLAGS])
1482
1483 # If we don't have the X11 platform, set this define so we don't try to include
1484 # the X11 headers.
1485 if ! echo "$egl_platforms" | grep -q 'x11'; then
1486     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1487     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1488 fi
1489
1490 AC_ARG_WITH([egl-driver-dir],
1491     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1492                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1493     [EGL_DRIVER_INSTALL_DIR="$withval"],
1494     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1495 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1496
1497 AC_ARG_WITH([xorg-driver-dir],
1498     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1499                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1500     [XORG_DRIVER_INSTALL_DIR="$withval"],
1501     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1502 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1503
1504 AC_ARG_WITH([max-width],
1505     [AS_HELP_STRING([--with-max-width=N],
1506                     [Maximum framebuffer width (4096)])],
1507     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1508      AS_IF([test "${withval}" -gt "4096"],
1509            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1510 )
1511 AC_ARG_WITH([max-height],
1512     [AS_HELP_STRING([--with-max-height=N],
1513                     [Maximum framebuffer height (4096)])],
1514     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1515      AS_IF([test "${withval}" -gt "4096"],
1516            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1517 )
1518
1519 dnl
1520 dnl Gallium LLVM
1521 dnl
1522 AC_ARG_ENABLE([gallium-llvm],
1523     [AS_HELP_STRING([--enable-gallium-llvm],
1524         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1525     [enable_gallium_llvm="$enableval"],
1526     [enable_gallium_llvm=auto])
1527
1528 AC_ARG_WITH([llvm-shared-libs],
1529     [AS_HELP_STRING([--with-llvm-shared-libs],
1530         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1531     [],
1532     [with_llvm_shared_libs=no])
1533 AS_IF([test x$enable_opencl = xyes],
1534     [
1535         if test "x$with_llvm_shared_libs" != xyes; then
1536             AC_MSG_ERROR([OpenCL requires LLVM shared libraries])
1537         fi
1538     ])
1539
1540 AC_ARG_WITH([llvm-prefix],
1541     [AS_HELP_STRING([--with-llvm-prefix],
1542         [Prefix for LLVM installations in non-standard locations])],
1543     [llvm_prefix="$withval"],
1544     [llvm_prefix=""])
1545
1546
1547 # Call this inside ` ` to get the return value.
1548 # $1 is the llvm-config command with arguments.
1549 strip_unwanted_llvm_flags() {
1550     # Use \> (marks the end of the word)
1551     echo `$1` | sed \
1552         -e 's/-DNDEBUG\>//g' \
1553         -e 's/-pedantic\>//g' \
1554         -e 's/-Wcovered-switch-default\>//g' \
1555         -e 's/-O.\>//g' \
1556         -e 's/-g\>//g' \
1557         -e 's/-Wall\>//g' \
1558         -e 's/-fomit-frame-pointer\>//g'
1559 }
1560
1561
1562 if test "x$with_gallium_drivers" = x; then
1563     enable_gallium_llvm=no
1564 fi
1565 if test "x$enable_gallium_llvm" = xauto; then
1566     case "$host_cpu" in
1567     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1568     esac
1569 fi
1570 if test "x$enable_gallium_llvm" = xyes; then
1571     if test "x$llvm_prefix" != x; then
1572         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1573     else
1574         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1575     fi
1576
1577     if test "x$LLVM_CONFIG" != xno; then
1578         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1579         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1580         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1581         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1582         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1583         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1584         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1585         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1586
1587         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1588             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1589         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1590             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1591
1592         if test "x${LLVM_VERSION_MAJOR}" != x; then
1593             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1594         else
1595             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1596         fi
1597
1598         LLVM_COMPONENTS="engine bitwriter"
1599         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1600             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1601         fi
1602
1603         if test "x$enable_opencl" = xyes; then
1604             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1605             # LLVM 3.3 >= 177971 requires IRReader
1606             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1607                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1608             fi
1609             # LLVM 3.4 requires Option
1610             if $LLVM_CONFIG --components | grep -qw 'option'; then
1611                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1612             fi
1613         fi
1614         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1615         MESA_LLVM=1
1616
1617         dnl Check for Clang internal headers
1618         if test "x$enable_opencl" = xyes; then
1619             if test "x$CLANG_LIBDIR" = x; then
1620                 CLANG_LIBDIR=${LLVM_LIBDIR}
1621             fi
1622             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1623             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1624                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1625         fi
1626     else
1627         MESA_LLVM=0
1628         LLVM_VERSION_INT=0
1629     fi
1630 else
1631     MESA_LLVM=0
1632     LLVM_VERSION_INT=0
1633 fi
1634
1635 dnl Directory for XVMC libs
1636 AC_ARG_WITH([xvmc-libdir],
1637     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1638         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1639     [XVMC_LIB_INSTALL_DIR="$withval"],
1640     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1641 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1642
1643 dnl
1644 dnl Gallium Tests
1645 dnl
1646 if test "x$enable_gallium_tests" = xyes; then
1647     enable_gallium_loader=yes
1648 fi
1649 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1650
1651 if test "x$enable_gallium_loader" = xyes; then
1652     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1653 fi
1654 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1655
1656 dnl Directory for VDPAU libs
1657 AC_ARG_WITH([vdpau-libdir],
1658     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1659         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1660     [VDPAU_LIB_INSTALL_DIR="$withval"],
1661     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1662 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1663
1664 dnl Directory for OpenCL libs
1665 AC_ARG_WITH([opencl-libdir],
1666     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1667         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1668     [OPENCL_LIB_INSTALL_DIR="$withval"],
1669     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1670 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1671
1672 dnl
1673 dnl Gallium helper functions
1674 dnl
1675 gallium_check_st() {
1676     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1677          if test "x$have_libdrm" != xyes; then
1678             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1679          fi
1680          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1681     fi
1682     if test "x$enable_dri" = xyes && test "x$2" != x; then
1683          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1684     fi
1685     if test "x$enable_xorg" = xyes && test "x$3" != x; then
1686          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1687     fi
1688     if test "x$enable_xa" = xyes && test "x$4" != x; then
1689          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1690     fi
1691     if test "x$enable_xvmc" = xyes && test "x$5" != x; then
1692          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1693     fi
1694     if test "x$enable_vdpau" = xyes && test "x$6" != x; then
1695          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1696     fi
1697 }
1698
1699 gallium_require_llvm() {
1700     if test "x$MESA_LLVM" = x0; then
1701         case "$host_cpu" in
1702         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1703         esac
1704     fi
1705 }
1706
1707 gallium_require_drm_loader() {
1708     if test "x$enable_gallium_loader" = xyes; then
1709         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1710                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1711         if test "x$have_libdrm" != xyes; then
1712             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1713         fi
1714         enable_gallium_drm_loader=yes
1715     fi
1716 }
1717
1718 radeon_llvm_check() {
1719     LLVM_REQUIRED_VERSION_MAJOR="3"
1720     LLVM_REQUIRED_VERSION_MINOR="3"
1721     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1722         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1723     fi
1724     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1725         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1726                       sources with the --enable-experimental-targets=R600
1727                       configure flag])
1728     fi
1729     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1730     NEED_RADEON_LLVM=yes
1731     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1732                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1733 }
1734
1735 dnl Gallium drivers
1736 if test "x$enable_dri" = xyes -o "x$enable_xorg" = xyes -o \
1737         "x$enable_xa" = xyes -o "x$enable_xvmc" = xyes -o \
1738         "x$enable_vdpau" = xyes; then
1739     NEED_NONNULL_WINSYS=yes
1740 fi
1741 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1742
1743 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1744 if test "x$with_gallium_drivers" != x; then
1745     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1746     for driver in $gallium_drivers; do
1747         case "x$driver" in
1748         xsvga)
1749             HAVE_GALLIUM_SVGA=yes
1750             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1751             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1752             ;;
1753         xi915)
1754             HAVE_GALLIUM_I915=yes
1755             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1756             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1757             if test "x$MESA_LLVM" = x1; then
1758                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1759             fi
1760             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1761             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1762             ;;
1763         xilo)
1764             HAVE_GALLIUM_ILO=yes
1765             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1766             gallium_require_drm_loader
1767             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1768             gallium_check_st "intel/drm" "dri-ilo"
1769             ;;
1770         xr300)
1771             HAVE_GALLIUM_R300=yes
1772             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1773             gallium_require_llvm "Gallium R300"
1774             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1775             gallium_check_st "radeon/drm" "r300/dri" "" "" "r300/xvmc" "r300/vdpau"
1776             ;;
1777         xr600)
1778             HAVE_GALLIUM_R600=yes
1779             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1780             gallium_require_drm_loader
1781             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1782             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1783                 radeon_llvm_check
1784                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1785             fi
1786             if test "x$enable_r600_llvm" = xyes; then
1787                 USE_R600_LLVM_COMPILER=yes;
1788             fi
1789             if test "x$enable_opencl" = xyes; then
1790                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1791             fi
1792             gallium_check_st "radeon/drm" "r600/dri" "r600/xorg" "" "r600/xvmc" "r600/vdpau"
1793             ;;
1794         xradeonsi)
1795             HAVE_GALLIUM_RADEONSI=yes
1796             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1797             gallium_require_drm_loader
1798             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1799             radeon_llvm_check
1800             gallium_check_st "radeon/drm" "radeonsi/dri" "radeonsi/xorg" "" "" "radeonsi/vdpau" ""
1801             ;;
1802         xnouveau)
1803             HAVE_GALLIUM_NOUVEAU=yes
1804             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1805             gallium_require_drm_loader
1806             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1807             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1808             ;;
1809         xfreedreno)
1810             HAVE_GALLIUM_FREEDRENO=yes
1811             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1812             gallium_require_drm_loader
1813             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1814             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1815             ;;
1816         xswrast)
1817             HAVE_GALLIUM_SOFTPIPE=yes
1818             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1819             if test "x$MESA_LLVM" = x1; then
1820                 HAVE_GALLIUM_LLVMPIPE=yes
1821                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1822             fi
1823
1824             if test "x$enable_dri" = xyes; then
1825                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1826             fi
1827             if test "x$enable_vdpau" = xyes; then
1828                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1829             fi
1830             if test "x$enable_xvmc" = xyes; then
1831                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1832             fi
1833             if test "x$enable_vdpau" = xyes -o "x$enable_xvmc" = xyes; then
1834                 NEED_WINSYS_XLIB=yes
1835                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1836             fi
1837             ;;
1838         *)
1839             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1840             ;;
1841         esac
1842     done
1843 fi
1844
1845 dnl Set LLVM_LIBS - This is done after the driver configuration so
1846 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1847 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1848 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1849 dnl this was causing the same libraries to be appear multiple times
1850 dnl in LLVM_LIBS.
1851
1852 if test "x$MESA_LLVM" != x0; then
1853
1854     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1855
1856     if test "x$with_llvm_shared_libs" = xyes; then
1857         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1858         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1859         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1860
1861         if test "x$llvm_have_one_so" = xyes; then
1862             dnl LLVM was built using auto*, so there is only one shared object.
1863             LLVM_LIBS="-l$LLVM_SO_NAME"
1864         else
1865             dnl If LLVM was built with CMake, there will be one shared object per
1866             dnl component.
1867             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1868                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1869         Please make sure you have built llvm with the --enable-shared option
1870         and that your llvm libraries are installed in $LLVM_LIBDIR
1871         If you have installed your llvm libraries to a different directory you
1872         can use the --with-llvm-prefix= configure flag to specify this directory.
1873         NOTE: Mesa is attempting to use llvm shared libraries because you have
1874         passed one of the following options to configure:
1875                 --with-llvm-shared-libs
1876                 --enable-opencl
1877         If you do not want to build with llvm shared libraries and instead want to
1878         use llvm static libraries then remove these options from your configure
1879         invocation and reconfigure.])])
1880
1881            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1882            dnl install uses a shared object for each compoenent and we have
1883            dnl already added all of these objects to LLVM_LIBS.
1884         fi
1885     fi
1886 fi
1887
1888 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1889 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1890 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1891 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1892 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1893 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1894 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1895 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1896 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1897 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1898
1899 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1900                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1901                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1902 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1903                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1904                                                   && test "x$MESA_LLVM" = x1)
1905
1906 if test "x$enable_gallium_loader" = xyes; then
1907     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1908
1909     if test "x$enable_gallium_drm_loader" = xyes; then
1910         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1911         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1912                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1913         if test "x$pipe_loader_have_xcb" = xyes; then
1914             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1915             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1916         fi
1917     fi
1918
1919     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1920     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1921 fi
1922
1923 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1924 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1925 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1926 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1927 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1928 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1929
1930 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1931                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1932                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1933                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1934 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1935                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1936 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1937 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1938 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1939 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1940 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1941 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1942 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1943
1944 AC_SUBST([ELF_LIB])
1945
1946 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1947                                      "x$enable_xlib_glx" = xyes -o \
1948                                      "x$enable_osmesa" = xyes -o \
1949                                      "x$enable_gallium_osmesa" = xyes)
1950 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1951 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1952 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1953
1954 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1955 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1956 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1957
1958 AC_SUBST([VDPAU_MAJOR], 1)
1959 AC_SUBST([VDPAU_MINOR], 0)
1960
1961 AC_SUBST([XVMC_MAJOR], 1)
1962 AC_SUBST([XVMC_MINOR], 0)
1963
1964 AC_SUBST([XA_MAJOR], 2)
1965 AC_SUBST([XA_MINOR], 0)
1966 AC_SUBST([XA_TINY], 0)
1967 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1968
1969 dnl Restore LDFLAGS and CPPFLAGS
1970 LDFLAGS="$_SAVE_LDFLAGS"
1971 CPPFLAGS="$_SAVE_CPPFLAGS"
1972
1973 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1974 if test "x$acv_mesa_CLANG" = xyes; then
1975     CFLAGS="$CFLAGS -Qunused-arguments"
1976     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1977 fi
1978
1979 dnl Add user CFLAGS and CXXFLAGS
1980 CFLAGS="$CFLAGS $USER_CFLAGS"
1981 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1982
1983 dnl Substitute the config
1984 AC_CONFIG_FILES([Makefile
1985                 src/Makefile
1986                 src/egl/Makefile
1987                 src/egl/drivers/Makefile
1988                 src/egl/drivers/dri2/Makefile
1989                 src/egl/drivers/glx/Makefile
1990                 src/egl/main/Makefile
1991                 src/egl/main/egl.pc
1992                 src/egl/wayland/Makefile
1993                 src/egl/wayland/wayland-drm/Makefile
1994                 src/egl/wayland/wayland-egl/Makefile
1995                 src/egl/wayland/wayland-egl/wayland-egl.pc
1996                 src/gallium/auxiliary/Makefile
1997                 src/gallium/auxiliary/pipe-loader/Makefile
1998                 src/gallium/drivers/Makefile
1999                 src/gallium/drivers/freedreno/Makefile
2000                 src/gallium/drivers/freedreno/a2xx/Makefile
2001                 src/gallium/drivers/freedreno/a3xx/Makefile
2002                 src/gallium/drivers/galahad/Makefile
2003                 src/gallium/drivers/i915/Makefile
2004                 src/gallium/drivers/identity/Makefile
2005                 src/gallium/drivers/ilo/Makefile
2006                 src/gallium/drivers/llvmpipe/Makefile
2007                 src/gallium/drivers/noop/Makefile
2008                 src/gallium/drivers/nouveau/Makefile
2009                 src/gallium/drivers/r300/Makefile
2010                 src/gallium/drivers/r600/Makefile
2011                 src/gallium/drivers/radeon/Makefile
2012                 src/gallium/drivers/radeonsi/Makefile
2013                 src/gallium/drivers/rbug/Makefile
2014                 src/gallium/drivers/softpipe/Makefile
2015                 src/gallium/drivers/svga/Makefile
2016                 src/gallium/drivers/trace/Makefile
2017                 src/gallium/state_trackers/Makefile
2018                 src/gallium/state_trackers/clover/Makefile
2019                 src/gallium/state_trackers/dri/Makefile
2020                 src/gallium/state_trackers/dri/drm/Makefile
2021                 src/gallium/state_trackers/dri/sw/Makefile
2022                 src/gallium/state_trackers/egl/Makefile
2023                 src/gallium/state_trackers/gbm/Makefile
2024                 src/gallium/state_trackers/glx/xlib/Makefile
2025                 src/gallium/state_trackers/osmesa/Makefile
2026                 src/gallium/state_trackers/vdpau/Makefile
2027                 src/gallium/state_trackers/vega/Makefile
2028                 src/gallium/state_trackers/xa/Makefile
2029                 src/gallium/state_trackers/xorg/Makefile
2030                 src/gallium/state_trackers/xvmc/Makefile
2031                 src/gallium/targets/Makefile
2032                 src/gallium/targets/dri-freedreno/Makefile
2033                 src/gallium/targets/dri-i915/Makefile
2034                 src/gallium/targets/dri-ilo/Makefile
2035                 src/gallium/targets/dri-nouveau/Makefile
2036                 src/gallium/targets/dri-swrast/Makefile
2037                 src/gallium/targets/dri-vmwgfx/Makefile
2038                 src/gallium/targets/egl-static/Makefile
2039                 src/gallium/targets/gbm/Makefile
2040                 src/gallium/targets/opencl/Makefile
2041                 src/gallium/targets/osmesa/Makefile
2042                 src/gallium/targets/osmesa/osmesa.pc
2043                 src/gallium/targets/pipe-loader/Makefile
2044                 src/gallium/targets/radeonsi/dri/Makefile
2045                 src/gallium/targets/radeonsi/vdpau/Makefile
2046                 src/gallium/targets/radeonsi/xorg/Makefile
2047                 src/gallium/targets/r300/dri/Makefile
2048                 src/gallium/targets/r300/vdpau/Makefile
2049                 src/gallium/targets/r300/xvmc/Makefile
2050                 src/gallium/targets/r600/dri/Makefile
2051                 src/gallium/targets/r600/vdpau/Makefile
2052                 src/gallium/targets/r600/xorg/Makefile
2053                 src/gallium/targets/r600/xvmc/Makefile
2054                 src/gallium/targets/libgl-xlib/Makefile
2055                 src/gallium/targets/vdpau-nouveau/Makefile
2056                 src/gallium/targets/vdpau-softpipe/Makefile
2057                 src/gallium/targets/xa-vmwgfx/Makefile
2058                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2059                 src/gallium/targets/xorg-i915/Makefile
2060                 src/gallium/targets/xorg-nouveau/Makefile
2061                 src/gallium/targets/xvmc-nouveau/Makefile
2062                 src/gallium/targets/xvmc-softpipe/Makefile
2063                 src/gallium/tests/trivial/Makefile
2064                 src/gallium/tests/unit/Makefile
2065                 src/gallium/winsys/Makefile
2066                 src/gallium/winsys/freedreno/drm/Makefile
2067                 src/gallium/winsys/i915/drm/Makefile
2068                 src/gallium/winsys/i915/sw/Makefile
2069                 src/gallium/winsys/intel/drm/Makefile
2070                 src/gallium/winsys/nouveau/drm/Makefile
2071                 src/gallium/winsys/radeon/drm/Makefile
2072                 src/gallium/winsys/svga/drm/Makefile
2073                 src/gallium/winsys/sw/dri/Makefile
2074                 src/gallium/winsys/sw/fbdev/Makefile
2075                 src/gallium/winsys/sw/null/Makefile
2076                 src/gallium/winsys/sw/wayland/Makefile
2077                 src/gallium/winsys/sw/wrapper/Makefile
2078                 src/gallium/winsys/sw/xlib/Makefile
2079                 src/gbm/Makefile
2080                 src/gbm/main/gbm.pc
2081                 src/glsl/Makefile
2082                 src/glx/Makefile
2083                 src/glx/tests/Makefile
2084                 src/gtest/Makefile
2085                 src/mapi/Makefile
2086                 src/mapi/es1api/Makefile
2087                 src/mapi/es1api/glesv1_cm.pc
2088                 src/mapi/es2api/Makefile
2089                 src/mapi/es2api/glesv2.pc
2090                 src/mapi/glapi/Makefile
2091                 src/mapi/glapi/gen/Makefile
2092                 src/mapi/glapi/tests/Makefile
2093                 src/mapi/shared-glapi/Makefile
2094                 src/mapi/shared-glapi/tests/Makefile
2095                 src/mapi/vgapi/Makefile
2096                 src/mapi/vgapi/vg.pc
2097                 src/mesa/Makefile
2098                 src/mesa/gl.pc
2099                 src/mesa/drivers/dri/dri.pc
2100                 src/mesa/drivers/dri/common/Makefile
2101                 src/mesa/drivers/dri/common/xmlpool/Makefile
2102                 src/mesa/drivers/dri/i915/Makefile
2103                 src/mesa/drivers/dri/i965/Makefile
2104                 src/mesa/drivers/dri/Makefile
2105                 src/mesa/drivers/dri/nouveau/Makefile
2106                 src/mesa/drivers/dri/r200/Makefile
2107                 src/mesa/drivers/dri/radeon/Makefile
2108                 src/mesa/drivers/dri/swrast/Makefile
2109                 src/mesa/drivers/osmesa/Makefile
2110                 src/mesa/drivers/osmesa/osmesa.pc
2111                 src/mesa/drivers/x11/Makefile
2112                 src/mesa/libdricore/Makefile
2113                 src/mesa/main/tests/Makefile
2114                 src/mesa/main/tests/hash_table/Makefile
2115                 src/mesa/program/Makefile
2116                 src/mesa/x86-64/Makefile
2117                 src/mesa/x86/Makefile])
2118
2119 dnl Sort the dirs alphabetically
2120 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2121 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2122 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2123 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2124
2125 AC_OUTPUT
2126
2127 dnl
2128 dnl Output some configuration info for the user
2129 dnl
2130 echo ""
2131 echo "        prefix:          $prefix"
2132 echo "        exec_prefix:     $exec_prefix"
2133 echo "        libdir:          $libdir"
2134 echo "        includedir:      $includedir"
2135
2136 dnl API info
2137 echo ""
2138 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2139 echo "        OpenVG:          $enable_openvg"
2140
2141 dnl Driver info
2142 echo ""
2143 case "x$enable_osmesa$enable_gallium_osmesa" in
2144 xnoyes)
2145         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2146         ;;
2147 xyesno)
2148         echo "        OSMesa:          lib$OSMESA_LIB"
2149         ;;
2150 xnono)
2151         echo "        OSMesa:          no"
2152         ;;
2153 esac
2154
2155 if test "x$enable_dri" != xno; then
2156         # cleanup the drivers var
2157         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2158         if test "x$DRI_DIRS" = x; then
2159             echo "        DRI drivers:     no"
2160         else
2161             echo "        DRI drivers:     $dri_dirs"
2162         fi
2163         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2164 fi
2165
2166 case "x$enable_glx$enable_xlib_glx" in
2167 xyesyes)
2168     echo "        GLX:             Xlib-based"
2169     ;;
2170 xyesno)
2171     echo "        GLX:             DRI-based"
2172     ;;
2173 *)
2174     echo "        GLX:             $enable_glx"
2175     ;;
2176 esac
2177
2178 dnl EGL
2179 echo ""
2180 echo "        EGL:             $enable_egl"
2181 if test "$enable_egl" = yes; then
2182     echo "        EGL platforms:   $egl_platforms"
2183
2184     egl_drivers=""
2185     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2186         egl_drivers="$egl_drivers builtin:egl_glx"
2187     fi
2188     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2189         egl_drivers="$egl_drivers builtin:egl_dri2"
2190     fi
2191
2192     if test "x$enable_gallium_egl" = xyes; then
2193         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2194         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2195     else
2196         echo "        EGL drivers:    $egl_drivers"
2197     fi
2198 fi
2199
2200 echo ""
2201 if test "x$MESA_LLVM" = x1; then
2202     echo "        llvm:            yes"
2203     echo "        llvm-config:     $LLVM_CONFIG"
2204     echo "        llvm-version:    $LLVM_VERSION"
2205 else
2206     echo "        llvm:            no"
2207 fi
2208
2209 echo ""
2210 if test -n "$with_gallium_drivers"; then
2211     echo "        Gallium:         yes"
2212     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2213     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2214     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2215     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2216 else
2217     echo "        Gallium:         no"
2218 fi
2219
2220
2221 dnl Libraries
2222 echo ""
2223 echo "        Shared libs:     $enable_shared"
2224 echo "        Static libs:     $enable_static"
2225 echo "        Shared-glapi:    $enable_shared_glapi"
2226
2227 dnl Compiler options
2228 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2229 cflags=`echo $CFLAGS | \
2230     $SED 's/^ *//;s/  */ /;s/ *$//'`
2231 cxxflags=`echo $CXXFLAGS | \
2232     $SED 's/^ *//;s/  */ /;s/ *$//'`
2233 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2234 echo ""
2235 echo "        CFLAGS:          $cflags"
2236 echo "        CXXFLAGS:        $cxxflags"
2237 echo "        Macros:          $defines"
2238 echo ""
2239 if test "x$MESA_LLVM" = x1; then
2240     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2241     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2242     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2243     echo ""
2244 fi
2245 echo "        PYTHON2:         $PYTHON2"
2246
2247 echo ""
2248 echo "        Run '${MAKE-make}' to build Mesa"
2249 echo ""