configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AX_PYTHON_MODULE([libxml2], [needed])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 LT_PREREQ([2.2])
  62 LT_INIT([disable-static])
  63
  64 AX_PROG_BISON([],
  65               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  66                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  67 AX_PROG_FLEX([],
  68              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  69                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  70
  71 AC_PATH_PROG([PERL], [perl])
  72
  73 AC_CHECK_PROG(INDENT, indent, indent, cat)
  74 if test "x$INDENT" != "xcat"; then
  75     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  76 fi
  77
  78 AC_PROG_INSTALL
  79
  80 dnl We need a POSIX shell for parts of the build. Assume we have one
  81 dnl in most cases.
  82 case "$host_os" in
  83 solaris*)
  84     # Solaris /bin/sh is too old/non-POSIX compliant
  85     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  86     SHELL="$POSIX_SHELL"
  87     ;;
  88 esac
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 GEN_ASM_OFFSETS=no
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124
 125     if test "x$cross_compiling" = xyes; then
 126         GEN_ASM_OFFSETS=yes
 127     fi
 128 fi
 129
 130 dnl Check for compiler builtins
 131 AX_GCC_BUILTIN([__builtin_bswap32])
 132 AX_GCC_BUILTIN([__builtin_bswap64])
 133
 134 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 135
 136 dnl Make sure the pkg-config macros are defined
 137 m4_ifndef([PKG_PROG_PKG_CONFIG],
 138     [m4_fatal([Could not locate the pkg-config autoconf macros.
 139   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 140   are in a different location, try setting the environment variable
 141   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 142 PKG_PROG_PKG_CONFIG()
 143
 144 dnl LIB_DIR - library basename
 145 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 146 AC_SUBST([LIB_DIR])
 147
 148 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 149 _SAVE_LDFLAGS="$LDFLAGS"
 150 _SAVE_CPPFLAGS="$CPPFLAGS"
 151
 152 dnl Compiler macros
 153 DEFINES=""
 154 AC_SUBST([DEFINES])
 155 case "$host_os" in
 156 linux*|*-gnu*|gnu*)
 157     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 158     ;;
 159 solaris*)
 160     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 161     ;;
 162 cygwin*)
 163     DEFINES="$DEFINES -DHAVE_PTHREAD"
 164     ;;
 165 esac
 166
 167 dnl Add flags for gcc and g++
 168 if test "x$GCC" = xyes; then
 169     case "$host_os" in
 170     cygwin*)
 171         CFLAGS="$CFLAGS -Wall -std=gnu99"
 172         ;;
 173     *)
 174         CFLAGS="$CFLAGS -Wall -std=c99"
 175         ;;
 176     esac
 177
 178     # Enable -Werror=implicit-function-declaration and
 179     # -Werror=missing-prototypes, if available, or otherwise, just
 180     # -Wmissing-prototypes.  This is particularly useful to avoid
 181     # generating a loadable driver module that has undefined symbols.
 182     save_CFLAGS="$CFLAGS"
 183     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 184     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 185     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 187                    AC_MSG_RESULT([yes]),
 188                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 189                     AC_MSG_RESULT([no])]);
 190
 191     # Enable -fvisibility=hidden if using a gcc that supports it
 192     save_CFLAGS="$CFLAGS"
 193     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 194     VISIBILITY_CFLAGS="-fvisibility=hidden"
 195     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 196     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 197                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 198
 199     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 200     CFLAGS=$save_CFLAGS
 201
 202     # Work around aliasing bugs - developers should comment this out
 203     CFLAGS="$CFLAGS -fno-strict-aliasing"
 204
 205     # gcc's builtin memcmp is slower than glibc's
 206     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 207     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 208 fi
 209 if test "x$GXX" = xyes; then
 210     CXXFLAGS="$CXXFLAGS -Wall"
 211
 212     # Enable -fvisibility=hidden if using a gcc that supports it
 213     save_CXXFLAGS="$CXXFLAGS"
 214     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 215     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 216     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 217     AC_LANG_PUSH([C++])
 218     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 219                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 220     AC_LANG_POP([C++])
 221
 222     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 223     CXXFLAGS=$save_CXXFLAGS
 224
 225     # Work around aliasing bugs - developers should comment this out
 226     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 227
 228     # gcc's builtin memcmp is slower than glibc's
 229     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 230     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 231 fi
 232
 233 dnl even if the compiler appears to support it, using visibility attributes isn't
 234 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 235 case "$host_os" in
 236 cygwin*)
 237     VISIBILITY_CFLAGS=""
 238     VISIBILITY_CXXFLAGS=""
 239     ;;
 240 esac
 241
 242 AC_SUBST([VISIBILITY_CFLAGS])
 243 AC_SUBST([VISIBILITY_CXXFLAGS])
 244
 245 dnl
 246 dnl Optional flags, check for compiler support
 247 dnl
 248 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 249 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 250
 251 dnl
 252 dnl Hacks to enable 32 or 64 bit build
 253 dnl
 254 AC_ARG_ENABLE([32-bit],
 255     [AS_HELP_STRING([--enable-32-bit],
 256         [build 32-bit libraries @<:@default=auto@:>@])],
 257     [enable_32bit="$enableval"],
 258     [enable_32bit=auto]
 259 )
 260 if test "x$enable_32bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m32"
 263         CCASFLAGS="$CCASFLAGS -m32"
 264     fi
 265     if test "x$GXX" = xyes; then
 266         CXXFLAGS="$CXXFLAGS -m32"
 267     fi
 268 fi
 269 AC_ARG_ENABLE([64-bit],
 270     [AS_HELP_STRING([--enable-64-bit],
 271         [build 64-bit libraries @<:@default=auto@:>@])],
 272     [enable_64bit="$enableval"],
 273     [enable_64bit=auto]
 274 )
 275 if test "x$enable_64bit" = xyes; then
 276     if test "x$GCC" = xyes; then
 277         CFLAGS="$CFLAGS -m64"
 278     fi
 279     if test "x$GXX" = xyes; then
 280         CXXFLAGS="$CXXFLAGS -m64"
 281     fi
 282 fi
 283
 284 dnl Can't have static and shared libraries, default to static if user
 285 dnl explicitly requested. If both disabled, set to static since shared
 286 dnl was explicitly requested.
 287 case "x$enable_static$enable_shared" in
 288 xyesyes )
 289     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 290     enable_shared=no
 291     ;;
 292 xnono )
 293     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 294     enable_static=yes
 295     ;;
 296 esac
 297
 298 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 299
 300 dnl
 301 dnl other compiler options
 302 dnl
 303 AC_ARG_ENABLE([debug],
 304     [AS_HELP_STRING([--enable-debug],
 305         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 306     [enable_debug="$enableval"],
 307     [enable_debug=no]
 308 )
 309 if test "x$enable_debug" = xyes; then
 310     DEFINES="$DEFINES -DDEBUG"
 311     if test "x$GCC" = xyes; then
 312         CFLAGS="$CFLAGS -g -O0"
 313     fi
 314     if test "x$GXX" = xyes; then
 315         CXXFLAGS="$CXXFLAGS -g -O0"
 316     fi
 317 fi
 318
 319 dnl
 320 dnl library names
 321 dnl
 322 LIB_PREFIX_GLOB='lib'
 323 LIB_VERSION_SEPARATOR='.'
 324 if test "$enable_static" = yes; then
 325     LIB_EXTENSION='a'
 326 else
 327     case "$host_os" in
 328     darwin* )
 329         LIB_EXTENSION='dylib' ;;
 330     cygwin* )
 331         dnl prefix can be 'cyg' or 'lib'
 332         LIB_PREFIX_GLOB='???'
 333         LIB_VERSION_SEPARATOR='-'
 334         LIB_EXTENSION='dll' ;;
 335     aix* )
 336         LIB_EXTENSION='a' ;;
 337     * )
 338         LIB_EXTENSION='so' ;;
 339     esac
 340 fi
 341 AC_ARG_WITH([gl-lib-name],
 342   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 343     [specify GL library name @<:@default=GL@:>@])],
 344   [GL_LIB=$withval],
 345   [GL_LIB=GL])
 346 AC_ARG_WITH([osmesa-lib-name],
 347   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 348     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 349   [OSMESA_LIB=$withval],
 350   [OSMESA_LIB=OSMesa])
 351 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 352 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 353
 354 dnl
 355 dnl Mangled Mesa support
 356 dnl
 357 AC_ARG_ENABLE([mangling],
 358   [AS_HELP_STRING([--enable-mangling],
 359     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 360   [enable_mangling="${enableval}"],
 361   [enable_mangling=no]
 362 )
 363 if test "x${enable_mangling}" = "xyes" ; then
 364   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 365   GL_LIB="Mangled${GL_LIB}"
 366   OSMESA_LIB="Mangled${OSMESA_LIB}"
 367 fi
 368 AC_SUBST([GL_LIB])
 369 AC_SUBST([OSMESA_LIB])
 370
 371 dnl
 372 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 373 dnl
 374 AC_ARG_ENABLE([texture-float],
 375     [AS_HELP_STRING([--enable-texture-float],
 376         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 377     [enable_texture_float="$enableval"],
 378     [enable_texture_float=no]
 379 )
 380 if test "x$enable_texture_float" = xyes; then
 381     AC_MSG_WARN([Floating-point textures enabled.])
 382     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 383     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 384 fi
 385
 386 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 387 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 388 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 389 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 390 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 391 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 392 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 393
 394 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 395 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 396 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 397 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 398 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401
 402 AC_SUBST([GL_LIB_NAME])
 403 AC_SUBST([OSMESA_LIB_NAME])
 404 AC_SUBST([EGL_LIB_NAME])
 405 AC_SUBST([GLESv1_CM_LIB_NAME])
 406 AC_SUBST([GLESv2_LIB_NAME])
 407 AC_SUBST([VG_LIB_NAME])
 408 AC_SUBST([GLAPI_LIB_NAME])
 409
 410 AC_SUBST([GL_LIB_GLOB])
 411 AC_SUBST([EGL_LIB_GLOB])
 412 AC_SUBST([GLESv1_CM_LIB_GLOB])
 413 AC_SUBST([GLESv2_LIB_GLOB])
 414 AC_SUBST([VG_LIB_GLOB])
 415 AC_SUBST([GLAPI_LIB_GLOB])
 416
 417 dnl
 418 dnl Arch/platform-specific settings
 419 dnl
 420 AC_ARG_ENABLE([asm],
 421     [AS_HELP_STRING([--disable-asm],
 422         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 423     [enable_asm="$enableval"],
 424     [enable_asm=yes]
 425 )
 426 asm_arch=""
 427 AC_MSG_CHECKING([whether to enable assembly])
 428 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 429 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 430 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 431     case "$host_cpu" in
 432     i?86 | x86_64 | amd64)
 433         enable_asm=no
 434         AC_MSG_RESULT([no, cross compiling])
 435         ;;
 436     esac
 437 fi
 438 # check for supported arches
 439 if test "x$enable_asm" = xyes; then
 440     case "$host_cpu" in
 441     i?86)
 442         case "$host_os" in
 443         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 444             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 445             ;;
 446         gnu*)
 447             asm_arch=x86
 448             ;;
 449         esac
 450         ;;
 451     x86_64|amd64)
 452         case "$host_os" in
 453         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 454             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 455             ;;
 456         esac
 457         ;;
 458     sparc*)
 459         case "$host_os" in
 460         linux*)
 461             asm_arch=sparc
 462             ;;
 463         esac
 464         ;;
 465     esac
 466
 467     case "$asm_arch" in
 468     x86)
 469         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 470         AC_MSG_RESULT([yes, x86])
 471         ;;
 472     x86_64|amd64)
 473         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 474         AC_MSG_RESULT([yes, x86_64])
 475         ;;
 476     sparc)
 477         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 478         AC_MSG_RESULT([yes, sparc])
 479         ;;
 480     *)
 481         AC_MSG_RESULT([no, platform not supported])
 482         ;;
 483     esac
 484 fi
 485
 486 dnl Check to see if dlopen is in default libraries (like Solaris, which
 487 dnl has it in libc), or if libdl is needed to get it.
 488 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 489     [AC_CHECK_LIB([dl], [dlopen],
 490        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 491 AC_SUBST([DLOPEN_LIBS])
 492
 493 case "$host_os" in
 494 darwin*|mingw*)
 495     ;;
 496 *)
 497     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 498                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 499                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 500     AC_SUBST([CLOCK_LIB])
 501     ;;
 502 esac
 503
 504 dnl See if posix_memalign is available
 505 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 506
 507 dnl Check for pthreads
 508 AX_PTHREAD
 509 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 510 dnl to -pthread, which causes problems if we need -lpthread to appear in
 511 dnl pkgconfig files.
 512 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 513
 514 dnl SELinux awareness.
 515 AC_ARG_ENABLE([selinux],
 516     [AS_HELP_STRING([--enable-selinux],
 517         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 518     [MESA_SELINUX="$enableval"],
 519     [MESA_SELINUX=no])
 520 if test "x$enable_selinux" = "xyes"; then
 521     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 522         [AC_CHECK_HEADER([selinux/selinux.h],[],
 523                          [AC_MSG_ERROR([SELinux headers not found])])
 524          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 525                       [AC_MSG_ERROR([SELinux library not found])])
 526          SELINUX_LIBS="-lselinux"])
 527     DEFINES="$DEFINES -DMESA_SELINUX"
 528 fi
 529 AC_SUBST([SELINUX_CFLAGS])
 530 AC_SUBST([SELINUX_LIBS])
 531
 532 dnl Options for APIs
 533 AC_ARG_ENABLE([opengl],
 534     [AS_HELP_STRING([--disable-opengl],
 535         [disable support for standard OpenGL API @<:@default=no@:>@])],
 536     [enable_opengl="$enableval"],
 537     [enable_opengl=yes])
 538 AC_ARG_ENABLE([gles1],
 539     [AS_HELP_STRING([--enable-gles1],
 540         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 541     [enable_gles1="$enableval"],
 542     [enable_gles1=no])
 543 AC_ARG_ENABLE([gles2],
 544     [AS_HELP_STRING([--enable-gles2],
 545         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 546     [enable_gles2="$enableval"],
 547     [enable_gles2=no])
 548 AC_ARG_ENABLE([openvg],
 549     [AS_HELP_STRING([--enable-openvg],
 550         [enable support for OpenVG API @<:@default=no@:>@])],
 551     [enable_openvg="$enableval"],
 552     [enable_openvg=no])
 553
 554 AC_ARG_ENABLE([dri],
 555     [AS_HELP_STRING([--enable-dri],
 556         [enable DRI modules @<:@default=enabled@:>@])],
 557     [enable_dri="$enableval"],
 558     [enable_dri=yes])
 559 AC_ARG_ENABLE([dri3],
 560     [AS_HELP_STRING([--enable-dri3],
 561         [enable DRI3 @<:@default=enabled@:>@])],
 562     [enable_dri3="$enableval"],
 563     [enable_dri3=yes])
 564 AC_ARG_ENABLE([glx],
 565     [AS_HELP_STRING([--enable-glx],
 566         [enable GLX library @<:@default=enabled@:>@])],
 567     [enable_glx="$enableval"],
 568     [enable_glx=yes])
 569 AC_ARG_ENABLE([osmesa],
 570     [AS_HELP_STRING([--enable-osmesa],
 571         [enable OSMesa library @<:@default=disabled@:>@])],
 572     [enable_osmesa="$enableval"],
 573     [enable_osmesa=no])
 574 AC_ARG_ENABLE([gallium-osmesa],
 575     [AS_HELP_STRING([--enable-gallium-osmesa],
 576         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 577     [enable_gallium_osmesa="$enableval"],
 578     [enable_gallium_osmesa=no])
 579 AC_ARG_ENABLE([egl],
 580     [AS_HELP_STRING([--disable-egl],
 581         [disable EGL library @<:@default=enabled@:>@])],
 582     [enable_egl="$enableval"],
 583     [enable_egl=yes])
 584
 585 AC_ARG_ENABLE([xa],
 586     [AS_HELP_STRING([--enable-xa],
 587         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 588     [enable_xa="$enableval"],
 589     [enable_xa=no])
 590 AC_ARG_ENABLE([gbm],
 591    [AS_HELP_STRING([--enable-gbm],
 592          [enable gbm library @<:@default=auto@:>@])],
 593    [enable_gbm="$enableval"],
 594    [enable_gbm=auto])
 595
 596 AC_ARG_ENABLE([xvmc],
 597    [AS_HELP_STRING([--enable-xvmc],
 598          [enable xvmc library @<:@default=auto@:>@])],
 599    [enable_xvmc="$enableval"],
 600    [enable_xvmc=no])
 601 AC_ARG_ENABLE([vdpau],
 602    [AS_HELP_STRING([--enable-vdpau],
 603          [enable vdpau library @<:@default=auto@:>@])],
 604    [enable_vdpau="$enableval"],
 605    [enable_vdpau=auto])
 606 AC_ARG_ENABLE([omx],
 607    [AS_HELP_STRING([--enable-omx],
 608          [enable OpenMAX library @<:@default=no@:>@])],
 609    [enable_omx="$enableval"],
 610    [enable_omx=no])
 611 AC_ARG_ENABLE([opencl],
 612    [AS_HELP_STRING([--enable-opencl],
 613          [enable OpenCL library NOTE: Enabling this option will also enable
 614           --with-llvm-shared-libs
 615           @<:@default=no@:>@])],
 616    [],
 617    [enable_opencl=no])
 618 AC_ARG_ENABLE([opencl_icd],
 619    [AS_HELP_STRING([--enable-opencl-icd],
 620           [Build an OpenCL ICD library to be loaded by an ICD implementation
 621            @<:@default=no@:>@])],
 622     [enable_opencl_icd="$enableval"],
 623     [enable_opencl_icd=no])
 624 AC_ARG_ENABLE([xlib-glx],
 625     [AS_HELP_STRING([--enable-xlib-glx],
 626         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 627     [enable_xlib_glx="$enableval"],
 628     [enable_xlib_glx=no])
 629 AC_ARG_ENABLE([gallium-egl],
 630     [AS_HELP_STRING([--enable-gallium-egl],
 631         [enable optional EGL state tracker (not required
 632          for EGL support in Gallium with OpenGL and OpenGL ES)
 633          @<:@default=disable@:>@])],
 634     [enable_gallium_egl="$enableval"],
 635     [enable_gallium_egl=no])
 636 AC_ARG_ENABLE([gallium-gbm],
 637     [AS_HELP_STRING([--enable-gallium-gbm],
 638         [enable optional gbm state tracker (not required for
 639          gbm support in Gallium)
 640          @<:@default=auto@:>@])],
 641     [enable_gallium_gbm="$enableval"],
 642     [enable_gallium_gbm=auto])
 643
 644 AC_ARG_ENABLE([r600-llvm-compiler],
 645     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 646         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 647     [enable_r600_llvm="$enableval"],
 648     [enable_r600_llvm=no])
 649
 650 AC_ARG_ENABLE([gallium-tests],
 651     [AS_HELP_STRING([--enable-gallium-tests],
 652         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 653     [enable_gallium_tests="$enableval"],
 654     [enable_gallium_tests=no])
 655
 656 # Option for Gallium drivers
 657
 658 # Keep this in sync with the --with-gallium-drivers help string default value
 659 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 660
 661 AC_ARG_WITH([gallium-drivers],
 662     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 663         [comma delimited Gallium drivers list, e.g.
 664         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 665         @<:@default=r300,r600,svga,swrast@:>@])],
 666     [with_gallium_drivers="$withval"],
 667     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 668
 669 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 670 # here so that the script doesn't choke on an unknown driver name later.
 671 case "$with_gallium_drivers" in
 672     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 673     no) with_gallium_drivers='' ;;
 674 esac
 675
 676 if test "x$enable_opengl" = xno -a \
 677         "x$enable_gles1" = xno -a \
 678         "x$enable_gles2" = xno -a \
 679         "x$enable_openvg" = xno -a \
 680         "x$enable_xa" = xno -a \
 681         "x$enable_xvmc" = xno -a \
 682         "x$enable_vdpau" = xno -a \
 683         "x$enable_omx" = xno -a \
 684         "x$enable_opencl" = xno; then
 685     AC_MSG_ERROR([at least one API should be enabled])
 686 fi
 687
 688 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 689 if test "x$enable_opengl" = xno -a \
 690         "x$enable_gles1" = xyes; then
 691     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 692 fi
 693
 694 if test "x$enable_opengl" = xno -a \
 695         "x$enable_gles2" = xyes; then
 696     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 697 fi
 698
 699 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 700 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 701 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 702 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 703                                         "x$enable_gles1" = xyes -o \
 704                                         "x$enable_gles2" = xyes)
 705
 706 enable_dri_glx=$enable_dri
 707
 708 if test "x$enable_glx" = xno; then
 709     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 710     enable_xlib_glx=no
 711     enable_dri_glx=no
 712 fi
 713
 714 if test "x$enable_dri_glx$enable_xlib_glx" = xyesyes; then
 715     AC_MSG_ERROR([DRI-GLX and Xlib-GLX cannot be built together])
 716 fi
 717
 718 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 719     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 720 fi
 721
 722 # Disable GLX if OpenGL is not enabled
 723 if test "x$enable_glx$enable_opengl" = xyesno; then
 724     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 725     enable_glx=no
 726 fi
 727
 728 # Disable GLX if DRI-GLX and Xlib-GLX are not enabled
 729 if test "x$enable_glx" = xyes -a \
 730         "x$enable_dri_glx" = xno -a \
 731         "x$enable_xlib_glx" = xno; then
 732     AC_MSG_WARN([Neither DRI-GLX nor Xlib-GLX enabled, disabling GLX])
 733     enable_glx=no
 734 fi
 735
 736 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 737                                   "x$enable_dri_glx" = xyes)
 738 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 739 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 740
 741 AC_ARG_ENABLE([shared-glapi],
 742     [AS_HELP_STRING([--enable-shared-glapi],
 743         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 744     [enable_shared_glapi="$enableval"],
 745     [enable_shared_glapi=yes])
 746
 747 case "x$enable_opengl$enable_gles1$enable_gles2" in
 748 x*yes*yes*)
 749     if test "x$enable_shared_glapi" = xno; then
 750         AC_MSG_ERROR([shared GLAPI required when building two or more of
 751                       the following APIs - opengl, gles1 gles2])
 752     fi
 753     ;;
 754 esac
 755
 756 # Building Xlib-GLX requires shared glapi to be disabled.
 757 if test "x$enable_xlib_glx" = xyes; then
 758     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 759     enable_shared_glapi=no
 760 fi
 761
 762 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 763
 764 dnl
 765 dnl Driver specific build directories
 766 dnl
 767 GALLIUM_TARGET_DIRS=""
 768 GALLIUM_WINSYS_DIRS="sw"
 769 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 770 GALLIUM_STATE_TRACKERS_DIRS=""
 771
 772 case "x$enable_glx$enable_xlib_glx" in
 773 xyesyes)
 774     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 775     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 776     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 777     NEED_WINSYS_XLIB="yes"
 778     ;;
 779 esac
 780
 781 if test "x$enable_dri" = xyes; then
 782     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 783     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 784 fi
 785
 786 if test "x$enable_gallium_osmesa" = xyes; then
 787     if test -z "$with_gallium_drivers"; then
 788         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 789     fi
 790     if test "x$enable_osmesa" = xyes; then
 791         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 792     fi
 793     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 794     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 795 fi
 796
 797 AC_SUBST([MESA_LLVM])
 798
 799 # Check for libdrm
 800 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 801                   [have_libdrm=yes], [have_libdrm=no])
 802 if test "x$have_libdrm" = xyes; then
 803         DEFINES="$DEFINES -DHAVE_LIBDRM"
 804 fi
 805
 806 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 807                   have_libudev=yes, have_libudev=no)
 808
 809 if test "x$enable_dri" = xyes; then
 810     # DRI must be shared, I think
 811     if test "$enable_static" = yes; then
 812         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 813     fi
 814
 815     # not a hard requirement as swrast does not depend on it
 816     if test "x$have_libdrm" = xyes; then
 817         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 818     fi
 819 fi
 820
 821 dnl Direct rendering or just indirect rendering
 822 case "$host_os" in
 823 gnu*)
 824     dnl Disable by default on GNU/Hurd
 825     driglx_direct_default="no"
 826     ;;
 827 cygwin*)
 828     dnl Disable by default on cygwin
 829     driglx_direct_default="no"
 830     ;;
 831 *)
 832     driglx_direct_default="yes"
 833     ;;
 834 esac
 835 AC_ARG_ENABLE([driglx-direct],
 836     [AS_HELP_STRING([--disable-driglx-direct],
 837         [disable direct rendering in GLX and EGL for DRI \
 838             @<:@default=auto@:>@])],
 839     [driglx_direct="$enableval"],
 840     [driglx_direct="$driglx_direct_default"])
 841
 842 dnl
 843 dnl libGL configuration per driver
 844 dnl
 845 case "x$enable_glx$enable_xlib_glx" in
 846 xyesyes)
 847     # Xlib-based GLX
 848     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 849     GL_PC_REQ_PRIV="x11 xext"
 850     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 851     GL_LIB_DEPS="$XLIBGL_LIBS"
 852     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 853     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 854     ;;
 855 xyesno)
 856     # DRI-based GLX
 857     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 858     if test x"$driglx_direct" = xyes; then
 859         if test "x$have_libdrm" != xyes; then
 860             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 861         fi
 862         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 863         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 864         if test x"$enable_dri3" = xyes; then
 865             if test x"$have_libudev" != xyes; then
 866               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 867             fi
 868             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 869             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 870         fi
 871     fi
 872
 873     # find the DRI deps for libGL
 874     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 875
 876     if test x"$enable_dri3" = xyes; then
 877         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 878     fi
 879
 880     # add xf86vidmode if available
 881     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 882     if test "$HAVE_XF86VIDMODE" = yes ; then
 883         dri_modules="$dri_modules xxf86vm"
 884     fi
 885
 886     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 887     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 888     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 889     GL_LIB_DEPS="$DRIGL_LIBS"
 890
 891     # need DRM libs, $PTHREAD_LIBS, etc.
 892     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 893     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 894     ;;
 895 esac
 896
 897 if test "$have_libudev" = yes; then
 898     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 899 fi
 900
 901 # This is outside the case (above) so that it is invoked even for non-GLX
 902 # builds.
 903 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 904
 905 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 906 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 907 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 908 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 909
 910 AC_SUBST([X11_INCLUDES])
 911 AC_SUBST([GL_LIB_DEPS])
 912 AC_SUBST([GL_PC_REQ_PRIV])
 913 AC_SUBST([GL_PC_LIB_PRIV])
 914 AC_SUBST([GL_PC_CFLAGS])
 915 AC_SUBST([DRI_PC_REQ_PRIV])
 916 AC_SUBST([GLESv1_CM_LIB_DEPS])
 917 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 918 AC_SUBST([GLESv2_LIB_DEPS])
 919 AC_SUBST([GLESv2_PC_LIB_PRIV])
 920
 921 AC_SUBST([HAVE_XF86VIDMODE])
 922
 923 dnl
 924 dnl More GLX setup
 925 dnl
 926 case "x$enable_glx$enable_xlib_glx" in
 927 xyesyes)
 928     DEFINES="$DEFINES -DUSE_XSHM"
 929     ;;
 930 xyesno)
 931     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 932     if test "x$driglx_direct" = xyes; then
 933         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 934     fi
 935     ;;
 936 esac
 937
 938 dnl
 939 dnl TLS detection
 940 dnl
 941
 942 AC_ARG_ENABLE([glx-tls],
 943     [AS_HELP_STRING([--enable-glx-tls],
 944         [enable TLS support in GLX @<:@default=disabled@:>@])],
 945     [GLX_USE_TLS="$enableval"],
 946     [GLX_USE_TLS=no])
 947 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 948
 949 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 950       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 951
 952 dnl
 953 dnl More DRI setup
 954 dnl
 955 dnl Directory for DRI drivers
 956 AC_ARG_WITH([dri-driverdir],
 957     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 958         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 959     [DRI_DRIVER_INSTALL_DIR="$withval"],
 960     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 961 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 962 dnl Extra search path for DRI drivers
 963 AC_ARG_WITH([dri-searchpath],
 964     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 965         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 966     [DRI_DRIVER_SEARCH_DIR="$withval"],
 967     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 968 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 969 dnl Which drivers to build - default is chosen by platform
 970 AC_ARG_WITH([dri-drivers],
 971     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 972         [comma delimited classic DRI drivers list, e.g.
 973         "swrast,i965,radeon" @<:@default=auto@:>@])],
 974     [with_dri_drivers="$withval"],
 975     [with_dri_drivers=auto])
 976
 977 if test "x$with_dri_drivers" = xauto; then
 978     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 979         with_dri_drivers="yes"
 980     else
 981         with_dri_drivers="no"
 982     fi
 983 fi
 984 if test "x$with_dri_drivers" = xno; then
 985     with_dri_drivers=''
 986 fi
 987
 988 dnl If $with_dri_drivers is yes, drivers will be added through
 989 dnl platform checks. Set DEFINES and LIB_DEPS
 990 if test "x$enable_dri" = xyes; then
 991     # Platform specific settings and drivers to build
 992     case "$host_os" in
 993     linux*)
 994         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 995         DEFINES="$DEFINES -DHAVE_ALIAS"
 996         if test "x$enable_dri3" = xyes; then
 997             DEFINES="$DEFINES -DHAVE_DRI3"
 998         fi
 999
1000         case "$host_cpu" in
1001         powerpc* | sparc*)
1002             # Build only the drivers for cards that exist on PowerPC/sparc
1003             if test "x$with_dri_drivers" = "xyes"; then
1004                 with_dri_drivers="r200 radeon swrast"
1005             fi
1006             ;;
1007         esac
1008         ;;
1009     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1010         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1011         DEFINES="$DEFINES -DHAVE_ALIAS"
1012         ;;
1013     gnu*)
1014         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1015         DEFINES="$DEFINES -DHAVE_ALIAS"
1016         ;;
1017     solaris*)
1018         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1019         ;;
1020     cygwin*)
1021         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1022         if test "x$with_dri_drivers" = "xyes"; then
1023             with_dri_drivers="swrast"
1024         fi
1025         ;;
1026     esac
1027
1028     # default drivers
1029     if test "x$with_dri_drivers" = "xyes"; then
1030         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1031     fi
1032
1033     # Check for expat
1034     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1035     if test "x$have_expat" = "xyes"; then
1036        PKG_CHECK_MODULES([EXPAT], [expat], [],
1037                          AC_MSG_ERROR([Expat required for DRI.]))
1038     else
1039        # expat version 2.0 and earlier do not provide expat.pc
1040        EXPAT_LIBS=-lexpat
1041     fi
1042
1043     # If we are building any DRI driver other than swrast.
1044     if test -n "$with_dri_drivers"; then
1045         if test "x$with_dri_drivers" != xswrast; then
1046             # ... libdrm is required
1047             if test "x$have_libdrm" != xyes; then
1048                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1049             fi
1050             DRICOMMON_NEED_LIBDRM=yes
1051         else
1052             DRICOMMON_NEED_LIBDRM=no
1053         fi
1054     fi
1055
1056     # put all the necessary libs together
1057     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1058     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1059
1060 fi
1061
1062 AC_SUBST([DRI_LIB_DEPS])
1063 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1064
1065 DRI_DIRS=''
1066 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1067 if test -n "$with_dri_drivers"; then
1068     if test "x$enable_opengl" != xyes; then
1069         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1070     fi
1071
1072     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1073     for driver in $dri_drivers; do
1074         DRI_DIRS+="$driver "
1075         case "x$driver" in
1076         xi915)
1077             HAVE_I915_DRI=yes;
1078             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1079             ;;
1080         xi965)
1081             HAVE_I965_DRI=yes;
1082             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1083             ;;
1084         xnouveau)
1085             HAVE_NOUVEAU_DRI=yes;
1086             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1087             ;;
1088         xradeon)
1089             HAVE_RADEON_DRI=yes;
1090             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1091             ;;
1092         xr200)
1093             HAVE_R200_DRI=yes;
1094             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1095             ;;
1096         xswrast)
1097             HAVE_SWRAST_DRI=yes;
1098             ;;
1099         *)
1100             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1101             ;;
1102         esac
1103     done
1104     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1105 fi
1106
1107 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1108 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1109                                   "x$enable_osmesa" = xyes -o \
1110                                   -n "$DRI_DIRS")
1111
1112 dnl
1113 dnl OSMesa configuration
1114 dnl
1115
1116 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1117 AC_ARG_WITH([osmesa-bits],
1118     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1119         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1120     [osmesa_bits="$withval"],
1121     [osmesa_bits=8])
1122 if test "x$osmesa_bits" != x8; then
1123     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1124         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1125         osmesa_bits=8
1126     fi
1127 fi
1128 case "x$osmesa_bits" in
1129 x8)
1130     OSMESA_LIB="${OSMESA_LIB}"
1131     ;;
1132 x16|x32)
1133     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1134     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1135     ;;
1136 *)
1137     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1138     ;;
1139 esac
1140
1141 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1142     # only link libraries with osmesa if shared
1143     if test "$enable_static" = no; then
1144         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1145     else
1146         OSMESA_LIB_DEPS=""
1147     fi
1148     OSMESA_MESA_DEPS=""
1149     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1150 fi
1151
1152 AC_SUBST([OSMESA_LIB_DEPS])
1153 AC_SUBST([OSMESA_MESA_DEPS])
1154 AC_SUBST([OSMESA_PC_REQ])
1155 AC_SUBST([OSMESA_PC_LIB_PRIV])
1156
1157 dnl
1158 dnl gbm configuration
1159 dnl
1160 if test "x$enable_gbm" = xauto; then
1161     case "$with_egl_platforms" in
1162         *drm*)
1163             enable_gbm=yes ;;
1164          *)
1165             enable_gbm=no ;;
1166     esac
1167 fi
1168 if test "x$enable_gbm" = xyes; then
1169     if test x"$have_libudev" != xyes; then
1170         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1171     fi
1172
1173     if test "x$enable_dri" = xyes; then
1174         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1175         if test "x$enable_shared_glapi" = xno; then
1176             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1177         fi
1178     fi
1179 fi
1180 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1181 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1182 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1183 AC_SUBST([GBM_PC_REQ_PRIV])
1184 AC_SUBST([GBM_PC_LIB_PRIV])
1185
1186 dnl
1187 dnl EGL configuration
1188 dnl
1189 EGL_CLIENT_APIS=""
1190
1191 if test "x$enable_egl" = xyes; then
1192     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1193
1194     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1195
1196     if test "$enable_static" != yes; then
1197         if test "x$enable_dri" = xyes; then
1198             HAVE_EGL_DRIVER_DRI2=1
1199         fi
1200
1201     fi
1202 fi
1203 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1204 AC_SUBST([EGL_LIB_DEPS])
1205
1206 dnl
1207 dnl EGL Gallium configuration
1208 dnl
1209 if test "x$enable_gallium_egl" = xyes; then
1210     if test -z "$with_gallium_drivers"; then
1211         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1212     fi
1213     if test "x$enable_egl" = xno; then
1214         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1215     fi
1216     if test "x$have_libdrm" != xyes; then
1217         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1218     fi
1219
1220     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1221     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1222 fi
1223 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1224
1225 dnl
1226 dnl gbm Gallium configuration
1227 dnl
1228 if test "x$enable_gallium_gbm" = xauto; then
1229     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1230         yesyesyes*drm*)
1231             enable_gallium_gbm=yes ;;
1232          *)
1233             enable_gallium_gbm=no ;;
1234     esac
1235 fi
1236 if test "x$enable_gallium_gbm" = xyes; then
1237     if test -z "$with_gallium_drivers"; then
1238         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1239     fi
1240     if test "x$enable_gbm" = xno; then
1241         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1242     fi
1243     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1244     if test "x$enable_dri" = xno; then
1245         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1246     fi
1247
1248     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1249     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1250     enable_gallium_loader=yes
1251 fi
1252 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1253
1254 dnl
1255 dnl XA configuration
1256 dnl
1257 if test "x$enable_xa" = xyes; then
1258     if test "x$with_gallium_drivers" = xswrast; then
1259        AC_MSG_ERROR([
1260           Building xa requires at least one non swrast gallium driver.
1261           If you are looking to use libxatracker.so with vmware's virtual gpu,
1262           make sure to include svga in the gallium drivers list, apart from
1263           enabling XA.
1264           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1265     fi
1266     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1267     enable_gallium_loader=yes
1268 fi
1269 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1270
1271 dnl
1272 dnl OpenVG configuration
1273 dnl
1274 VG_LIB_DEPS=""
1275
1276 if test "x$enable_openvg" = xyes; then
1277     if test "x$enable_egl" = xno; then
1278         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1279     fi
1280     if test -z "$with_gallium_drivers"; then
1281         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1282     fi
1283     if test "x$enable_gallium_egl" = xno; then
1284         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1285     fi
1286
1287     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1288     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1289     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1290     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1291     AC_SUBST([VG_PC_LIB_PRIV])
1292 fi
1293 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1294
1295 dnl
1296 dnl Gallium G3DVL configuration
1297 dnl
1298 if test -n "$with_gallium_drivers"; then
1299     if test "x$enable_xvmc" = xauto; then
1300         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1301     fi
1302
1303     if test "x$enable_vdpau" = xauto; then
1304         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1305     fi
1306
1307     if test "x$enable_omx" = xauto; then
1308         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1309     fi
1310 fi
1311
1312 if test "x$enable_xvmc" = xyes; then
1313     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1314     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1315 fi
1316 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1317
1318 if test "x$enable_vdpau" = xyes; then
1319     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1320                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1321     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1322 fi
1323 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1324
1325 if test "x$enable_omx" = xyes; then
1326     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1327     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1328 fi
1329 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1330
1331 dnl
1332 dnl OpenCL configuration
1333 dnl
1334
1335 AC_ARG_WITH([libclc-path],
1336    [AS_HELP_STRING([--with-libclc-path],
1337          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1338    [LIBCLC_PATH="$withval"],
1339    [LIBCLC_PATH=''])
1340
1341 if test -n "$LIBCLC_PATH"; then
1342    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1343                   Please review the updated build instructions for clover:
1344                   http://dri.freedesktop.org/wiki/GalliumCompute])
1345 fi
1346
1347
1348 AC_ARG_WITH([clang-libdir],
1349    [AS_HELP_STRING([--with-clang-libdir],
1350          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1351    [CLANG_LIBDIR="$withval"],
1352    [CLANG_LIBDIR=''])
1353
1354 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1355
1356 if test "x$enable_opencl" = xyes; then
1357     if test -z "$with_gallium_drivers"; then
1358         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1359     fi
1360
1361     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1362         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1363     fi
1364
1365     if test "x$have_libclc" = xno; then
1366         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1367                     Make sure the directory containing libclc.pc is specified in your
1368                     PKG_CONFIG_PATH environment variable.
1369                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1370     else
1371         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1372         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1373         AC_SUBST([LIBCLC_INCLUDEDIR])
1374         AC_SUBST([LIBCLC_LIBEXECDIR])
1375     fi
1376
1377     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1378     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1379     enable_gallium_loader=yes
1380
1381     if test "x$enable_opencl_icd" = xyes; then
1382         OPENCL_LIBNAME="MesaOpenCL"
1383     else
1384         OPENCL_LIBNAME="OpenCL"
1385     fi
1386 fi
1387 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1388 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1389 AC_SUBST([OPENCL_LIBNAME])
1390
1391 dnl
1392 dnl Gallium configuration
1393 dnl
1394 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1395
1396 AC_SUBST([LLVM_BINDIR])
1397 AC_SUBST([LLVM_CFLAGS])
1398 AC_SUBST([LLVM_CPPFLAGS])
1399 AC_SUBST([LLVM_CXXFLAGS])
1400 AC_SUBST([LLVM_LIBDIR])
1401 AC_SUBST([LLVM_LIBS])
1402 AC_SUBST([LLVM_LDFLAGS])
1403 AC_SUBST([LLVM_INCLUDEDIR])
1404 AC_SUBST([LLVM_VERSION])
1405 AC_SUBST([CLANG_RESOURCE_DIR])
1406
1407 case "x$enable_opengl$enable_gles1$enable_gles2" in
1408 x*yes*)
1409     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1410     ;;
1411 esac
1412
1413 AC_SUBST([VG_LIB_DEPS])
1414 AC_SUBST([EGL_CLIENT_APIS])
1415
1416 dnl
1417 dnl EGL Platforms configuration
1418 dnl
1419 AC_ARG_WITH([egl-platforms],
1420     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1421         [comma delimited native platforms libEGL supports, e.g.
1422         "x11,drm" @<:@default=auto@:>@])],
1423     [with_egl_platforms="$withval"],
1424     [if test "x$enable_egl" = xyes; then
1425         with_egl_platforms="x11"
1426     else
1427         with_egl_platforms=""
1428     fi])
1429
1430 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1431     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1432 fi
1433
1434 # Do per-EGL platform setups and checks
1435 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1436 for plat in $egl_platforms; do
1437         case "$plat" in
1438         wayland)
1439                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1440                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1441
1442                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1443                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1444                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1445                 ;;
1446
1447         x11)
1448                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1449                 ;;
1450
1451         drm)
1452                 test "x$enable_gbm" = "xno" &&
1453                         AC_MSG_ERROR([EGL platform drm needs gbm])
1454                 test "x$have_libdrm" != xyes &&
1455                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1456                 ;;
1457
1458         android|fbdev|gdi|null)
1459                 ;;
1460
1461         *)
1462                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1463                 ;;
1464         esac
1465
1466         case "$plat$have_libudev" in
1467                 waylandno|drmno)
1468                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1469         esac
1470 done
1471
1472 # libEGL wants to default to the first platform specified in
1473 # ./configure.  parse that here.
1474 if test "x$egl_platforms" != "x"; then
1475     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1476     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1477 else
1478     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1479 fi
1480
1481 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1482     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1483     NEED_WINSYS_XLIB=yes
1484 fi
1485 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1486 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1487 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1488 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1489 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1490
1491 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1492
1493 AC_SUBST([EGL_NATIVE_PLATFORM])
1494 AC_SUBST([EGL_CFLAGS])
1495
1496 # If we don't have the X11 platform, set this define so we don't try to include
1497 # the X11 headers.
1498 if ! echo "$egl_platforms" | grep -q 'x11'; then
1499     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1500     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1501 fi
1502
1503 AC_ARG_WITH([egl-driver-dir],
1504     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1505                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1506     [EGL_DRIVER_INSTALL_DIR="$withval"],
1507     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1508 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1509
1510 AC_ARG_WITH([max-width],
1511     [AS_HELP_STRING([--with-max-width=N],
1512                     [Maximum framebuffer width (4096)])],
1513     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1514      AS_IF([test "${withval}" -gt "4096"],
1515            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1516 )
1517 AC_ARG_WITH([max-height],
1518     [AS_HELP_STRING([--with-max-height=N],
1519                     [Maximum framebuffer height (4096)])],
1520     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1521      AS_IF([test "${withval}" -gt "4096"],
1522            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1523 )
1524
1525 dnl
1526 dnl Gallium LLVM
1527 dnl
1528 AC_ARG_ENABLE([gallium-llvm],
1529     [AS_HELP_STRING([--enable-gallium-llvm],
1530         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1531     [enable_gallium_llvm="$enableval"],
1532     [enable_gallium_llvm=auto])
1533
1534 AC_ARG_ENABLE([llvm-shared-libs],
1535     [AS_HELP_STRING([--enable-llvm-shared-libs],
1536         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1537     [],
1538     [with_llvm_shared_libs=yes])
1539
1540 AC_ARG_WITH([llvm-prefix],
1541     [AS_HELP_STRING([--with-llvm-prefix],
1542         [Prefix for LLVM installations in non-standard locations])],
1543     [llvm_prefix="$withval"],
1544     [llvm_prefix=''])
1545
1546
1547 # Call this inside ` ` to get the return value.
1548 # $1 is the llvm-config command with arguments.
1549 strip_unwanted_llvm_flags() {
1550     # Use \> (marks the end of the word)
1551     echo `$1` | sed \
1552         -e 's/-DNDEBUG\>//g' \
1553         -e 's/-pedantic\>//g' \
1554         -e 's/-Wcovered-switch-default\>//g' \
1555         -e 's/-O.\>//g' \
1556         -e 's/-g\>//g' \
1557         -e 's/-Wall\>//g' \
1558         -e 's/-Wcast-qual\>//g' \
1559         -e 's/-Woverloaded-virtual\>//g' \
1560         -e 's/-fcolor-diagnostics\>//g' \
1561         -e 's/-fdata-sections\>//g' \
1562         -e 's/-ffunction-sections\>//g' \
1563         -e 's/-fno-exceptions\>//g' \
1564         -e 's/-fomit-frame-pointer\>//g' \
1565         -e 's/-fvisibility-inlines-hidden\>//g' \
1566         -e 's/-fPIC\>//g'
1567 }
1568
1569
1570 if test -z "$with_gallium_drivers"; then
1571     enable_gallium_llvm=no
1572 fi
1573 if test "x$enable_gallium_llvm" = xauto; then
1574     case "$host_cpu" in
1575     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1576     esac
1577 fi
1578 if test "x$enable_gallium_llvm" = xyes; then
1579     if test -n "$llvm_prefix"; then
1580         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1581     else
1582         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1583     fi
1584
1585     if test "x$LLVM_CONFIG" != xno; then
1586         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1587         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1588         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1589         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1590         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1591         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1592         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1593         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1594         LLVM_LDFLAGS="-Wl,-rpath,$LLVM_LIBDIR $LLVM_LDFLAGS"
1595
1596         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1597             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1598         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1599             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1600
1601         if test -n "${LLVM_VERSION_MAJOR}"; then
1602             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1603         else
1604             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1605         fi
1606
1607         LLVM_COMPONENTS="engine bitwriter"
1608         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1609             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1610         fi
1611
1612         if test "x$enable_opencl" = xyes; then
1613             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1614             # LLVM 3.3 >= 177971 requires IRReader
1615             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1616                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1617             fi
1618             # LLVM 3.4 requires Option
1619             if $LLVM_CONFIG --components | grep -qw 'option'; then
1620                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1621             fi
1622         fi
1623         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1624         MESA_LLVM=1
1625
1626         dnl Check for Clang internal headers
1627         if test "x$enable_opencl" = xyes; then
1628             if test -z "$CLANG_LIBDIR"; then
1629                 CLANG_LIBDIR=${LLVM_LIBDIR}
1630             fi
1631             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1632             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1633                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1634         fi
1635     else
1636         MESA_LLVM=0
1637         LLVM_VERSION_INT=0
1638     fi
1639 else
1640     MESA_LLVM=0
1641     LLVM_VERSION_INT=0
1642 fi
1643
1644 dnl Directory for XVMC libs
1645 AC_ARG_WITH([xvmc-libdir],
1646     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1647         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1648     [XVMC_LIB_INSTALL_DIR="$withval"],
1649     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1650 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1651
1652 dnl
1653 dnl Gallium Tests
1654 dnl
1655 if test "x$enable_gallium_tests" = xyes; then
1656     enable_gallium_loader=yes
1657 fi
1658 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1659
1660 if test "x$enable_gallium_loader" = xyes; then
1661     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1662 fi
1663 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1664
1665 dnl Directory for VDPAU libs
1666 AC_ARG_WITH([vdpau-libdir],
1667     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1668         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1669     [VDPAU_LIB_INSTALL_DIR="$withval"],
1670     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1671 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1672
1673 AC_ARG_WITH([omx-libdir],
1674     [AS_HELP_STRING([--with-omx-libdir=DIR],
1675         [directory for the OMX libraries])],
1676     [OMX_LIB_INSTALL_DIR="$withval"],
1677     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`])
1678 AC_SUBST([OMX_LIB_INSTALL_DIR])
1679
1680 dnl Directory for OpenCL libs
1681 AC_ARG_WITH([opencl-libdir],
1682     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1683         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1684     [OPENCL_LIB_INSTALL_DIR="$withval"],
1685     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1686 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1687
1688 dnl
1689 dnl Gallium helper functions
1690 dnl
1691 gallium_check_st() {
1692     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1693          if test "x$have_libdrm" != xyes; then
1694             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1695          fi
1696          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1697     fi
1698     if test "x$enable_dri" = xyes && test -n "$2"; then
1699          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1700     fi
1701     if test "x$enable_xa" = xyes && test -n "$3"; then
1702          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1703     fi
1704     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1705          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1706     fi
1707     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1708          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1709     fi
1710     if test "x$enable_omx" = xyes && test "x$6" != x; then
1711          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1712     fi
1713 }
1714
1715 gallium_require_llvm() {
1716     if test "x$MESA_LLVM" = x0; then
1717         case "$host_cpu" in
1718         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1719         esac
1720     fi
1721 }
1722
1723 gallium_require_drm_loader() {
1724     if test "x$enable_gallium_loader" = xyes; then
1725         if test "x$have_libudev" != xyes; then
1726             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1727         fi
1728         if test "x$have_libdrm" != xyes; then
1729             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1730         fi
1731         enable_gallium_drm_loader=yes
1732     fi
1733 }
1734
1735 radeon_llvm_check() {
1736     if test "x$enable_gallium_llvm" != "xyes"; then
1737         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1738     fi
1739     LLVM_REQUIRED_VERSION_MAJOR="3"
1740     LLVM_REQUIRED_VERSION_MINOR="3"
1741     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1742         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1743     fi
1744     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1745         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1746                       sources with the --enable-experimental-targets=R600
1747                       configure flag])
1748     fi
1749     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1750     NEED_RADEON_LLVM=yes
1751     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1752                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1753 }
1754
1755 dnl Gallium drivers
1756 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1757         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1758     NEED_NONNULL_WINSYS=yes
1759 fi
1760 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1761
1762 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1763 if test -n "$with_gallium_drivers"; then
1764     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1765     for driver in $gallium_drivers; do
1766         case "x$driver" in
1767         xsvga)
1768             HAVE_GALLIUM_SVGA=yes
1769             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1770             gallium_require_drm_loader
1771             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1772             ;;
1773         xi915)
1774             HAVE_GALLIUM_I915=yes
1775             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1776             gallium_require_drm_loader
1777             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1778             if test "x$MESA_LLVM" = x1; then
1779                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1780             fi
1781             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1782             gallium_check_st "i915/drm" "dri-i915"
1783             DRICOMMON_NEED_LIBDRM=yes
1784             ;;
1785         xilo)
1786             HAVE_GALLIUM_ILO=yes
1787             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1788             gallium_require_drm_loader
1789             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1790             gallium_check_st "intel/drm" "dri-ilo"
1791             DRICOMMON_NEED_LIBDRM=yes
1792             ;;
1793         xr300)
1794             HAVE_GALLIUM_R300=yes
1795             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1796             gallium_require_drm_loader
1797             gallium_require_llvm "Gallium R300"
1798             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1799             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1800             DRICOMMON_NEED_LIBDRM=yes
1801             ;;
1802         xr600)
1803             HAVE_GALLIUM_R600=yes
1804             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1805             gallium_require_drm_loader
1806             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1807             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1808                 radeon_llvm_check "r600g"
1809                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1810             fi
1811             if test "x$enable_r600_llvm" = xyes; then
1812                 USE_R600_LLVM_COMPILER=yes;
1813             fi
1814             if test "x$enable_opencl" = xyes; then
1815                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1816             fi
1817             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1818             DRICOMMON_NEED_LIBDRM=yes
1819             ;;
1820         xradeonsi)
1821             HAVE_GALLIUM_RADEONSI=yes
1822             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1823             gallium_require_drm_loader
1824             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1825             radeon_llvm_check "radeonsi"
1826             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1827             DRICOMMON_NEED_LIBDRM=yes
1828             ;;
1829         xnouveau)
1830             HAVE_GALLIUM_NOUVEAU=yes
1831             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1832             gallium_require_drm_loader
1833             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1834             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1835             DRICOMMON_NEED_LIBDRM=yes
1836             ;;
1837         xfreedreno)
1838             HAVE_GALLIUM_FREEDRENO=yes
1839             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1840             gallium_require_drm_loader
1841             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1842             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1843             DRICOMMON_NEED_LIBDRM=yes
1844             ;;
1845         xswrast)
1846             HAVE_GALLIUM_SOFTPIPE=yes
1847             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1848             if test "x$MESA_LLVM" = x1; then
1849                 HAVE_GALLIUM_LLVMPIPE=yes
1850                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1851             fi
1852
1853             if test "x$enable_dri" = xyes; then
1854                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1855             fi
1856             ;;
1857         *)
1858             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1859             ;;
1860         esac
1861     done
1862 fi
1863
1864 dnl Set LLVM_LIBS - This is done after the driver configuration so
1865 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1866 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1867 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1868 dnl this was causing the same libraries to be appear multiple times
1869 dnl in LLVM_LIBS.
1870
1871 if test "x$MESA_LLVM" != x0; then
1872
1873     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1874
1875     if test "x$with_llvm_shared_libs" = xyes; then
1876         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1877         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1878         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1879
1880         if test "x$llvm_have_one_so" = xyes; then
1881             dnl LLVM was built using auto*, so there is only one shared object.
1882             LLVM_LIBS="-l$LLVM_SO_NAME"
1883         else
1884             dnl If LLVM was built with CMake, there will be one shared object per
1885             dnl component.
1886             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1887                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1888         Please make sure you have built llvm with the --enable-shared option
1889         and that your llvm libraries are installed in $LLVM_LIBDIR
1890         If you have installed your llvm libraries to a different directory you
1891         can use the --with-llvm-prefix= configure flag to specify this directory.
1892         NOTE: Mesa is attempting to use llvm shared libraries because you have
1893         passed one of the following options to configure:
1894                 --with-llvm-shared-libs
1895                 --enable-opencl
1896         If you do not want to build with llvm shared libraries and instead want to
1897         use llvm static libraries then remove these options from your configure
1898         invocation and reconfigure.])])
1899
1900            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1901            dnl install uses a shared object for each compoenent and we have
1902            dnl already added all of these objects to LLVM_LIBS.
1903         fi
1904     fi
1905 fi
1906
1907 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1908 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1909 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1910 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1911 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1912 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1913 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1914 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1915 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1916 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1917
1918 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1919                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1920                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1921 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1922                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1923                                                   && test "x$MESA_LLVM" = x1)
1924
1925 # NOTE: anything using xcb or other client side libs ends up in separate
1926 #       _CLIENT variables.  The pipe loader is built in two variants,
1927 #       one that is standalone and does not link any x client libs (for
1928 #       use by XA tracker in particular, but could be used in any case
1929 #       where communication with xserver is not desired).
1930 if test "x$enable_gallium_loader" = xyes; then
1931     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1932
1933     if test "x$enable_gallium_xlib_loader" = xyes; then
1934         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1935         NEED_WINSYS_XLIB="yes"
1936         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1937     fi
1938
1939     if test "x$enable_gallium_drm_loader" = xyes; then
1940         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1941         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1942                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1943         if test "x$pipe_loader_have_xcb" = xyes; then
1944             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1945             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1946         fi
1947     fi
1948
1949     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1950     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1951
1952     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1953     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1954     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1955     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1956 fi
1957 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1958
1959 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1960 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1961 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1962 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1963 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1964 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1965
1966 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1967                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1968                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1969                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1970 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1971                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1972 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1973 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1974 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1975 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1976 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1977 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1978 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1979
1980 AC_SUBST([ELF_LIB])
1981
1982 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1983 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1984 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1985 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1986 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1987
1988 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1989 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1990 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1991
1992 AC_SUBST([VDPAU_MAJOR], 1)
1993 AC_SUBST([VDPAU_MINOR], 0)
1994
1995 AC_SUBST([XVMC_MAJOR], 1)
1996 AC_SUBST([XVMC_MINOR], 0)
1997
1998 AC_SUBST([XA_MAJOR], 2)
1999 AC_SUBST([XA_MINOR], 2)
2000 AC_SUBST([XA_TINY], 0)
2001 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2002
2003 dnl Restore LDFLAGS and CPPFLAGS
2004 LDFLAGS="$_SAVE_LDFLAGS"
2005 CPPFLAGS="$_SAVE_CPPFLAGS"
2006
2007 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2008 if test "x$acv_mesa_CLANG" = xyes; then
2009     CFLAGS="$CFLAGS -Qunused-arguments"
2010     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2011 fi
2012
2013 dnl Add user CFLAGS and CXXFLAGS
2014 CFLAGS="$CFLAGS $USER_CFLAGS"
2015 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2016
2017 dnl Substitute the config
2018 AC_CONFIG_FILES([Makefile
2019                 src/Makefile
2020                 src/egl/Makefile
2021                 src/egl/drivers/Makefile
2022                 src/egl/drivers/dri2/Makefile
2023                 src/egl/main/Makefile
2024                 src/egl/main/egl.pc
2025                 src/egl/wayland/Makefile
2026                 src/egl/wayland/wayland-drm/Makefile
2027                 src/egl/wayland/wayland-egl/Makefile
2028                 src/egl/wayland/wayland-egl/wayland-egl.pc
2029                 src/gallium/auxiliary/Makefile
2030                 src/gallium/auxiliary/pipe-loader/Makefile
2031                 src/gallium/drivers/Makefile
2032                 src/gallium/drivers/freedreno/Makefile
2033                 src/gallium/drivers/galahad/Makefile
2034                 src/gallium/drivers/i915/Makefile
2035                 src/gallium/drivers/identity/Makefile
2036                 src/gallium/drivers/ilo/Makefile
2037                 src/gallium/drivers/llvmpipe/Makefile
2038                 src/gallium/drivers/noop/Makefile
2039                 src/gallium/drivers/nouveau/Makefile
2040                 src/gallium/drivers/r300/Makefile
2041                 src/gallium/drivers/r600/Makefile
2042                 src/gallium/drivers/radeon/Makefile
2043                 src/gallium/drivers/radeonsi/Makefile
2044                 src/gallium/drivers/rbug/Makefile
2045                 src/gallium/drivers/softpipe/Makefile
2046                 src/gallium/drivers/svga/Makefile
2047                 src/gallium/drivers/trace/Makefile
2048                 src/gallium/state_trackers/Makefile
2049                 src/gallium/state_trackers/clover/Makefile
2050                 src/gallium/state_trackers/dri/Makefile
2051                 src/gallium/state_trackers/dri/drm/Makefile
2052                 src/gallium/state_trackers/dri/sw/Makefile
2053                 src/gallium/state_trackers/egl/Makefile
2054                 src/gallium/state_trackers/gbm/Makefile
2055                 src/gallium/state_trackers/glx/xlib/Makefile
2056                 src/gallium/state_trackers/omx/Makefile
2057                 src/gallium/state_trackers/osmesa/Makefile
2058                 src/gallium/state_trackers/vdpau/Makefile
2059                 src/gallium/state_trackers/vega/Makefile
2060                 src/gallium/state_trackers/xa/Makefile
2061                 src/gallium/state_trackers/xvmc/Makefile
2062                 src/gallium/targets/Makefile
2063                 src/gallium/targets/dri-freedreno/Makefile
2064                 src/gallium/targets/dri-i915/Makefile
2065                 src/gallium/targets/dri-ilo/Makefile
2066                 src/gallium/targets/dri-nouveau/Makefile
2067                 src/gallium/targets/dri-swrast/Makefile
2068                 src/gallium/targets/dri-vmwgfx/Makefile
2069                 src/gallium/targets/egl-static/Makefile
2070                 src/gallium/targets/gbm/Makefile
2071                 src/gallium/targets/opencl/Makefile
2072                 src/gallium/targets/xa/Makefile
2073                 src/gallium/targets/xa/xatracker.pc
2074                 src/gallium/targets/osmesa/Makefile
2075                 src/gallium/targets/osmesa/osmesa.pc
2076                 src/gallium/targets/pipe-loader/Makefile
2077                 src/gallium/targets/radeonsi/dri/Makefile
2078                 src/gallium/targets/radeonsi/omx/Makefile
2079                 src/gallium/targets/radeonsi/vdpau/Makefile
2080                 src/gallium/targets/r300/dri/Makefile
2081                 src/gallium/targets/r600/dri/Makefile
2082                 src/gallium/targets/r600/omx/Makefile
2083                 src/gallium/targets/r600/vdpau/Makefile
2084                 src/gallium/targets/r600/xvmc/Makefile
2085                 src/gallium/targets/libgl-xlib/Makefile
2086                 src/gallium/targets/vdpau-nouveau/Makefile
2087                 src/gallium/targets/xvmc-nouveau/Makefile
2088                 src/gallium/tests/trivial/Makefile
2089                 src/gallium/tests/unit/Makefile
2090                 src/gallium/winsys/Makefile
2091                 src/gallium/winsys/freedreno/drm/Makefile
2092                 src/gallium/winsys/i915/drm/Makefile
2093                 src/gallium/winsys/i915/sw/Makefile
2094                 src/gallium/winsys/intel/drm/Makefile
2095                 src/gallium/winsys/nouveau/drm/Makefile
2096                 src/gallium/winsys/radeon/drm/Makefile
2097                 src/gallium/winsys/svga/drm/Makefile
2098                 src/gallium/winsys/sw/dri/Makefile
2099                 src/gallium/winsys/sw/fbdev/Makefile
2100                 src/gallium/winsys/sw/null/Makefile
2101                 src/gallium/winsys/sw/wayland/Makefile
2102                 src/gallium/winsys/sw/wrapper/Makefile
2103                 src/gallium/winsys/sw/xlib/Makefile
2104                 src/gbm/Makefile
2105                 src/gbm/main/gbm.pc
2106                 src/glsl/Makefile
2107                 src/glx/Makefile
2108                 src/glx/tests/Makefile
2109                 src/gtest/Makefile
2110                 src/loader/Makefile
2111                 src/mapi/Makefile
2112                 src/mapi/es1api/Makefile
2113                 src/mapi/es1api/glesv1_cm.pc
2114                 src/mapi/es2api/Makefile
2115                 src/mapi/es2api/glesv2.pc
2116                 src/mapi/glapi/Makefile
2117                 src/mapi/glapi/gen/Makefile
2118                 src/mapi/glapi/tests/Makefile
2119                 src/mapi/shared-glapi/Makefile
2120                 src/mapi/shared-glapi/tests/Makefile
2121                 src/mapi/vgapi/Makefile
2122                 src/mapi/vgapi/vg.pc
2123                 src/mesa/Makefile
2124                 src/mesa/gl.pc
2125                 src/mesa/drivers/dri/dri.pc
2126                 src/mesa/drivers/dri/common/Makefile
2127                 src/mesa/drivers/dri/common/xmlpool/Makefile
2128                 src/mesa/drivers/dri/i915/Makefile
2129                 src/mesa/drivers/dri/i965/Makefile
2130                 src/mesa/drivers/dri/Makefile
2131                 src/mesa/drivers/dri/nouveau/Makefile
2132                 src/mesa/drivers/dri/r200/Makefile
2133                 src/mesa/drivers/dri/radeon/Makefile
2134                 src/mesa/drivers/dri/swrast/Makefile
2135                 src/mesa/drivers/osmesa/Makefile
2136                 src/mesa/drivers/osmesa/osmesa.pc
2137                 src/mesa/drivers/x11/Makefile
2138                 src/mesa/main/tests/Makefile
2139                 src/mesa/main/tests/hash_table/Makefile])
2140
2141 dnl Sort the dirs alphabetically
2142 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2143 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2144 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2145 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2146
2147 AC_OUTPUT
2148
2149 dnl
2150 dnl Output some configuration info for the user
2151 dnl
2152 echo ""
2153 echo "        prefix:          $prefix"
2154 echo "        exec_prefix:     $exec_prefix"
2155 echo "        libdir:          $libdir"
2156 echo "        includedir:      $includedir"
2157
2158 dnl API info
2159 echo ""
2160 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2161 echo "        OpenVG:          $enable_openvg"
2162
2163 dnl Driver info
2164 echo ""
2165 case "x$enable_osmesa$enable_gallium_osmesa" in
2166 xnoyes)
2167         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2168         ;;
2169 xyesno)
2170         echo "        OSMesa:          lib$OSMESA_LIB"
2171         ;;
2172 xnono)
2173         echo "        OSMesa:          no"
2174         ;;
2175 esac
2176
2177 if test "x$enable_dri" != xno; then
2178         if test -z "$DRI_DIRS"; then
2179             echo "        DRI drivers:     no"
2180         else
2181             echo "        DRI drivers:     $DRI_DIRS"
2182         fi
2183         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2184 fi
2185
2186 case "x$enable_glx$enable_xlib_glx" in
2187 xyesyes)
2188     echo "        GLX:             Xlib-based"
2189     ;;
2190 xyesno)
2191     echo "        GLX:             DRI-based"
2192     ;;
2193 *)
2194     echo "        GLX:             $enable_glx"
2195     ;;
2196 esac
2197
2198 dnl EGL
2199 echo ""
2200 echo "        EGL:             $enable_egl"
2201 if test "$enable_egl" = yes; then
2202     echo "        EGL platforms:   $egl_platforms"
2203
2204     egl_drivers=""
2205     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2206         egl_drivers="$egl_drivers builtin:egl_dri2"
2207     fi
2208
2209     if test "x$enable_gallium_egl" = xyes; then
2210         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2211         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2212     else
2213         echo "        EGL drivers:    $egl_drivers"
2214     fi
2215 fi
2216
2217 echo ""
2218 if test "x$MESA_LLVM" = x1; then
2219     echo "        llvm:            yes"
2220     echo "        llvm-config:     $LLVM_CONFIG"
2221     echo "        llvm-version:    $LLVM_VERSION"
2222 else
2223     echo "        llvm:            no"
2224 fi
2225
2226 echo ""
2227 if test -n "$with_gallium_drivers"; then
2228     echo "        Gallium:         yes"
2229     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2230     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2231     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2232     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2233 else
2234     echo "        Gallium:         no"
2235 fi
2236
2237
2238 dnl Libraries
2239 echo ""
2240 echo "        Shared libs:     $enable_shared"
2241 echo "        Static libs:     $enable_static"
2242 echo "        Shared-glapi:    $enable_shared_glapi"
2243
2244 dnl Compiler options
2245 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2246 cflags=`echo $CFLAGS | \
2247     $SED 's/^ *//;s/  */ /;s/ *$//'`
2248 cxxflags=`echo $CXXFLAGS | \
2249     $SED 's/^ *//;s/  */ /;s/ *$//'`
2250 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2251 echo ""
2252 echo "        CFLAGS:          $cflags"
2253 echo "        CXXFLAGS:        $cxxflags"
2254 echo "        Macros:          $defines"
2255 echo ""
2256 if test "x$MESA_LLVM" = x1; then
2257     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2258     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2259     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2260     echo ""
2261 fi
2262 echo "        PYTHON2:         $PYTHON2"
2263
2264 echo ""
2265 echo "        Run '${MAKE-make}' to build Mesa"
2266 echo ""