configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xnoyes )
 288     ;;
 289 * )
 290     AC_MSG_WARN([Messa build supports only shared libraries, enabling shared])
 291     enable_shared=yes
 292     enable_static=no
 293     ;;
 294 esac
 295
 296 dnl
 297 dnl other compiler options
 298 dnl
 299 AC_ARG_ENABLE([debug],
 300     [AS_HELP_STRING([--enable-debug],
 301         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 302     [enable_debug="$enableval"],
 303     [enable_debug=no]
 304 )
 305 if test "x$enable_debug" = xyes; then
 306     DEFINES="$DEFINES -DDEBUG"
 307     if test "x$GCC" = xyes; then
 308         CFLAGS="$CFLAGS -g -O0"
 309     fi
 310     if test "x$GXX" = xyes; then
 311         CXXFLAGS="$CXXFLAGS -g -O0"
 312     fi
 313 fi
 314
 315 dnl
 316 dnl compatibility symlinks
 317 dnl
 318 case "$host_os" in
 319 linux* )
 320     HAVE_COMPAT_SYMLINKS=yes ;;
 321 * )
 322     HAVE_COMPAT_SYMLINKS=no ;;
 323 esac
 324
 325 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 326
 327 dnl
 328 dnl library names
 329 dnl
 330 case "$host_os" in
 331 darwin* )
 332     LIB_EXT='dylib' ;;
 333 cygwin* )
 334     LIB_EXT='dll' ;;
 335 aix* )
 336     LIB_EXT='a' ;;
 337 * )
 338     LIB_EXT='so' ;;
 339 esac
 340
 341 AC_SUBST([LIB_EXT])
 342
 343 AC_ARG_WITH([gl-lib-name],
 344   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 345     [specify GL library name @<:@default=GL@:>@])],
 346   [GL_LIB=$withval],
 347   [GL_LIB=GL])
 348 AC_ARG_WITH([osmesa-lib-name],
 349   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 350     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 351   [OSMESA_LIB=$withval],
 352   [OSMESA_LIB=OSMesa])
 353 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 354 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 355
 356 dnl
 357 dnl Mangled Mesa support
 358 dnl
 359 AC_ARG_ENABLE([mangling],
 360   [AS_HELP_STRING([--enable-mangling],
 361     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 362   [enable_mangling="${enableval}"],
 363   [enable_mangling=no]
 364 )
 365 if test "x${enable_mangling}" = "xyes" ; then
 366   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 367   GL_LIB="Mangled${GL_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([OSMESA_LIB])
 372
 373 dnl
 374 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 375 dnl
 376 AC_ARG_ENABLE([texture-float],
 377     [AS_HELP_STRING([--enable-texture-float],
 378         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 379     [enable_texture_float="$enableval"],
 380     [enable_texture_float=no]
 381 )
 382 if test "x$enable_texture_float" = xyes; then
 383     AC_MSG_WARN([Floating-point textures enabled.])
 384     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 385     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 386 fi
 387
 388 dnl
 389 dnl Arch/platform-specific settings
 390 dnl
 391 AC_ARG_ENABLE([asm],
 392     [AS_HELP_STRING([--disable-asm],
 393         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 394     [enable_asm="$enableval"],
 395     [enable_asm=yes]
 396 )
 397 asm_arch=""
 398 AC_MSG_CHECKING([whether to enable assembly])
 399 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 400 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 401 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 402     case "$host_cpu" in
 403     i?86 | x86_64 | amd64)
 404         enable_asm=no
 405         AC_MSG_RESULT([no, cross compiling])
 406         ;;
 407     esac
 408 fi
 409 # check for supported arches
 410 if test "x$enable_asm" = xyes; then
 411     case "$host_cpu" in
 412     i?86)
 413         case "$host_os" in
 414         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 415             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 416             ;;
 417         gnu*)
 418             asm_arch=x86
 419             ;;
 420         esac
 421         ;;
 422     x86_64|amd64)
 423         case "$host_os" in
 424         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 425             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 426             ;;
 427         esac
 428         ;;
 429     sparc*)
 430         case "$host_os" in
 431         linux*)
 432             asm_arch=sparc
 433             ;;
 434         esac
 435         ;;
 436     esac
 437
 438     case "$asm_arch" in
 439     x86)
 440         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 441         AC_MSG_RESULT([yes, x86])
 442         ;;
 443     x86_64|amd64)
 444         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 445         AC_MSG_RESULT([yes, x86_64])
 446         ;;
 447     sparc)
 448         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 449         AC_MSG_RESULT([yes, sparc])
 450         ;;
 451     *)
 452         AC_MSG_RESULT([no, platform not supported])
 453         ;;
 454     esac
 455 fi
 456
 457 dnl Check to see if dlopen is in default libraries (like Solaris, which
 458 dnl has it in libc), or if libdl is needed to get it.
 459 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 460     [AC_CHECK_LIB([dl], [dlopen],
 461        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 462 AC_SUBST([DLOPEN_LIBS])
 463
 464 case "$host_os" in
 465 darwin*|mingw*)
 466     ;;
 467 *)
 468     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 469                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 470                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 471     AC_SUBST([CLOCK_LIB])
 472     ;;
 473 esac
 474
 475 dnl See if posix_memalign is available
 476 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 477
 478 dnl Check for pthreads
 479 AX_PTHREAD
 480 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 481 dnl to -pthread, which causes problems if we need -lpthread to appear in
 482 dnl pkgconfig files.
 483 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 484
 485 dnl SELinux awareness.
 486 AC_ARG_ENABLE([selinux],
 487     [AS_HELP_STRING([--enable-selinux],
 488         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 489     [MESA_SELINUX="$enableval"],
 490     [MESA_SELINUX=no])
 491 if test "x$enable_selinux" = "xyes"; then
 492     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 493         [AC_CHECK_HEADER([selinux/selinux.h],[],
 494                          [AC_MSG_ERROR([SELinux headers not found])])
 495          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 496                       [AC_MSG_ERROR([SELinux library not found])])
 497          SELINUX_LIBS="-lselinux"])
 498     DEFINES="$DEFINES -DMESA_SELINUX"
 499 fi
 500 AC_SUBST([SELINUX_CFLAGS])
 501 AC_SUBST([SELINUX_LIBS])
 502
 503 dnl Options for APIs
 504 AC_ARG_ENABLE([opengl],
 505     [AS_HELP_STRING([--disable-opengl],
 506         [disable support for standard OpenGL API @<:@default=no@:>@])],
 507     [enable_opengl="$enableval"],
 508     [enable_opengl=yes])
 509 AC_ARG_ENABLE([gles1],
 510     [AS_HELP_STRING([--enable-gles1],
 511         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 512     [enable_gles1="$enableval"],
 513     [enable_gles1=no])
 514 AC_ARG_ENABLE([gles2],
 515     [AS_HELP_STRING([--enable-gles2],
 516         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 517     [enable_gles2="$enableval"],
 518     [enable_gles2=no])
 519 AC_ARG_ENABLE([openvg],
 520     [AS_HELP_STRING([--enable-openvg],
 521         [enable support for OpenVG API @<:@default=no@:>@])],
 522     [enable_openvg="$enableval"],
 523     [enable_openvg=no])
 524
 525 AC_ARG_ENABLE([dri],
 526     [AS_HELP_STRING([--enable-dri],
 527         [enable DRI modules @<:@default=enabled@:>@])],
 528     [enable_dri="$enableval"],
 529     [enable_dri=yes])
 530
 531 case "$host_os" in
 532 linux*)
 533     dri3_default=yes
 534     ;;
 535 *)
 536     dri3_default=no
 537     ;;
 538 esac
 539 AC_ARG_ENABLE([dri3],
 540     [AS_HELP_STRING([--enable-dri3],
 541         [enable DRI3 @<:@default=auto@:>@])],
 542     [enable_dri3="$enableval"],
 543     [enable_dri3="$dri3_default"])
 544 AC_ARG_ENABLE([glx],
 545     [AS_HELP_STRING([--enable-glx],
 546         [enable GLX library @<:@default=enabled@:>@])],
 547     [enable_glx="$enableval"],
 548     [enable_glx=yes])
 549 AC_ARG_ENABLE([osmesa],
 550     [AS_HELP_STRING([--enable-osmesa],
 551         [enable OSMesa library @<:@default=disabled@:>@])],
 552     [enable_osmesa="$enableval"],
 553     [enable_osmesa=no])
 554 AC_ARG_ENABLE([gallium-osmesa],
 555     [AS_HELP_STRING([--enable-gallium-osmesa],
 556         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 557     [enable_gallium_osmesa="$enableval"],
 558     [enable_gallium_osmesa=no])
 559 AC_ARG_ENABLE([egl],
 560     [AS_HELP_STRING([--disable-egl],
 561         [disable EGL library @<:@default=enabled@:>@])],
 562     [enable_egl="$enableval"],
 563     [enable_egl=yes])
 564
 565 AC_ARG_ENABLE([xa],
 566     [AS_HELP_STRING([--enable-xa],
 567         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 568     [enable_xa="$enableval"],
 569     [enable_xa=no])
 570 AC_ARG_ENABLE([gbm],
 571    [AS_HELP_STRING([--enable-gbm],
 572          [enable gbm library @<:@default=auto@:>@])],
 573    [enable_gbm="$enableval"],
 574    [enable_gbm=auto])
 575
 576 AC_ARG_ENABLE([xvmc],
 577    [AS_HELP_STRING([--enable-xvmc],
 578          [enable xvmc library @<:@default=auto@:>@])],
 579    [enable_xvmc="$enableval"],
 580    [enable_xvmc=no])
 581 AC_ARG_ENABLE([vdpau],
 582    [AS_HELP_STRING([--enable-vdpau],
 583          [enable vdpau library @<:@default=auto@:>@])],
 584    [enable_vdpau="$enableval"],
 585    [enable_vdpau=auto])
 586 AC_ARG_ENABLE([omx],
 587    [AS_HELP_STRING([--enable-omx],
 588          [enable OpenMAX library @<:@default=no@:>@])],
 589    [enable_omx="$enableval"],
 590    [enable_omx=no])
 591 AC_ARG_ENABLE([opencl],
 592    [AS_HELP_STRING([--enable-opencl],
 593          [enable OpenCL library @<:@default=no@:>@])],
 594    [enable_opencl="$enableval"],
 595    [enable_opencl=no])
 596 AC_ARG_ENABLE([opencl_icd],
 597    [AS_HELP_STRING([--enable-opencl-icd],
 598           [Build an OpenCL ICD library to be loaded by an ICD implementation
 599            @<:@default=no@:>@])],
 600     [enable_opencl_icd="$enableval"],
 601     [enable_opencl_icd=no])
 602 AC_ARG_ENABLE([xlib-glx],
 603     [AS_HELP_STRING([--enable-xlib-glx],
 604         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 605     [enable_xlib_glx="$enableval"],
 606     [enable_xlib_glx=no])
 607 AC_ARG_ENABLE([gallium-egl],
 608     [AS_HELP_STRING([--enable-gallium-egl],
 609         [enable optional EGL state tracker (not required
 610          for EGL support in Gallium with OpenGL and OpenGL ES)
 611          @<:@default=disable@:>@])],
 612     [enable_gallium_egl="$enableval"],
 613     [enable_gallium_egl=no])
 614 AC_ARG_ENABLE([gallium-gbm],
 615     [AS_HELP_STRING([--enable-gallium-gbm],
 616         [enable optional gbm state tracker (not required for
 617          gbm support in Gallium)
 618          @<:@default=auto@:>@])],
 619     [enable_gallium_gbm="$enableval"],
 620     [enable_gallium_gbm=auto])
 621
 622 AC_ARG_ENABLE([r600-llvm-compiler],
 623     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 624         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 625     [enable_r600_llvm="$enableval"],
 626     [enable_r600_llvm=no])
 627
 628 AC_ARG_ENABLE([gallium-tests],
 629     [AS_HELP_STRING([--enable-gallium-tests],
 630         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 631     [enable_gallium_tests="$enableval"],
 632     [enable_gallium_tests=no])
 633
 634 # Option for Gallium drivers
 635
 636 # Keep this in sync with the --with-gallium-drivers help string default value
 637 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 638
 639 AC_ARG_WITH([gallium-drivers],
 640     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 641         [comma delimited Gallium drivers list, e.g.
 642         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 643         @<:@default=r300,r600,svga,swrast@:>@])],
 644     [with_gallium_drivers="$withval"],
 645     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 646
 647 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 648 # here so that the script doesn't choke on an unknown driver name later.
 649 case "$with_gallium_drivers" in
 650     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 651     no) with_gallium_drivers='' ;;
 652 esac
 653
 654 if test "x$enable_opengl" = xno -a \
 655         "x$enable_gles1" = xno -a \
 656         "x$enable_gles2" = xno -a \
 657         "x$enable_openvg" = xno -a \
 658         "x$enable_xa" = xno -a \
 659         "x$enable_xvmc" = xno -a \
 660         "x$enable_vdpau" = xno -a \
 661         "x$enable_omx" = xno -a \
 662         "x$enable_opencl" = xno; then
 663     AC_MSG_ERROR([at least one API should be enabled])
 664 fi
 665
 666 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 667 if test "x$enable_opengl" = xno -a \
 668         "x$enable_gles1" = xyes; then
 669     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 670 fi
 671
 672 if test "x$enable_opengl" = xno -a \
 673         "x$enable_gles2" = xyes; then
 674     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 675 fi
 676
 677 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 678 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 679 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 680 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 681                                         "x$enable_gles1" = xyes -o \
 682                                         "x$enable_gles2" = xyes)
 683
 684 if test "x$enable_glx" = xno; then
 685     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 686     enable_xlib_glx=no
 687 fi
 688
 689 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 690     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 691 fi
 692
 693 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 694     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 695 fi
 696
 697 # Disable GLX if OpenGL is not enabled
 698 if test "x$enable_glx$enable_opengl" = xyesno; then
 699     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 700     enable_glx=no
 701 fi
 702
 703 # Disable GLX if DRI and Xlib-GLX are not enabled
 704 if test "x$enable_glx" = xyes -a \
 705         "x$enable_dri" = xno -a \
 706         "x$enable_xlib_glx" = xno; then
 707     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 708     enable_glx=no
 709 fi
 710
 711 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 712                                   "x$enable_dri" = xyes)
 713 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 714 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 715
 716 AC_ARG_ENABLE([shared-glapi],
 717     [AS_HELP_STRING([--enable-shared-glapi],
 718         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 719     [enable_shared_glapi="$enableval"],
 720     [enable_shared_glapi=yes])
 721
 722 case "x$enable_opengl$enable_gles1$enable_gles2" in
 723 x*yes*yes*)
 724     if test "x$enable_shared_glapi" = xno; then
 725         AC_MSG_ERROR([shared GLAPI required when building two or more of
 726                       the following APIs - opengl, gles1 gles2])
 727     fi
 728     ;;
 729 esac
 730
 731 # Building Xlib-GLX requires shared glapi to be disabled.
 732 if test "x$enable_xlib_glx" = xyes; then
 733     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 734     enable_shared_glapi=no
 735 fi
 736
 737 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 738
 739 dnl
 740 dnl Driver specific build directories
 741 dnl
 742 GALLIUM_TARGET_DIRS=""
 743 GALLIUM_WINSYS_DIRS="sw"
 744 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 745 GALLIUM_STATE_TRACKERS_DIRS=""
 746
 747 case "x$enable_glx$enable_xlib_glx" in
 748 xyesyes)
 749     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 750     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 751     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 752     NEED_WINSYS_XLIB="yes"
 753     ;;
 754 esac
 755
 756 if test "x$enable_dri" = xyes; then
 757     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 758     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 759 fi
 760
 761 if test "x$enable_gallium_osmesa" = xyes; then
 762     if test -z "$with_gallium_drivers"; then
 763         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 764     fi
 765     if test "x$enable_osmesa" = xyes; then
 766         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 767     fi
 768     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 769     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 770 fi
 771
 772 AC_SUBST([MESA_LLVM])
 773
 774 # Check for libdrm
 775 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 776                   [have_libdrm=yes], [have_libdrm=no])
 777 if test "x$have_libdrm" = xyes; then
 778         DEFINES="$DEFINES -DHAVE_LIBDRM"
 779 fi
 780
 781 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 782                   have_libudev=yes, have_libudev=no)
 783
 784 if test "x$enable_dri" = xyes; then
 785     # not a hard requirement as swrast does not depend on it
 786     if test "x$have_libdrm" = xyes; then
 787         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 788     fi
 789 fi
 790
 791 dnl Direct rendering or just indirect rendering
 792 case "$host_os" in
 793 gnu*)
 794     dnl Disable by default on GNU/Hurd
 795     driglx_direct_default="no"
 796     ;;
 797 cygwin*)
 798     dnl Disable by default on cygwin
 799     driglx_direct_default="no"
 800     ;;
 801 *)
 802     driglx_direct_default="yes"
 803     ;;
 804 esac
 805 AC_ARG_ENABLE([driglx-direct],
 806     [AS_HELP_STRING([--disable-driglx-direct],
 807         [disable direct rendering in GLX and EGL for DRI \
 808             @<:@default=auto@:>@])],
 809     [driglx_direct="$enableval"],
 810     [driglx_direct="$driglx_direct_default"])
 811
 812 dnl
 813 dnl libGL configuration per driver
 814 dnl
 815 case "x$enable_glx$enable_xlib_glx" in
 816 xyesyes)
 817     # Xlib-based GLX
 818     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 819     GL_PC_REQ_PRIV="x11 xext"
 820     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 821     GL_LIB_DEPS="$XLIBGL_LIBS"
 822     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 823     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 824     ;;
 825 xyesno)
 826     # DRI-based GLX
 827     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 828     if test x"$driglx_direct" = xyes; then
 829         if test "x$have_libdrm" != xyes; then
 830             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 831         fi
 832         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 833         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 834         if test x"$enable_dri3" = xyes; then
 835             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 836             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 837         fi
 838     fi
 839
 840     # find the DRI deps for libGL
 841     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 842
 843     if test x"$enable_dri3" = xyes; then
 844         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 845     fi
 846
 847     # add xf86vidmode if available
 848     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 849     if test "$HAVE_XF86VIDMODE" = yes ; then
 850         dri_modules="$dri_modules xxf86vm"
 851     fi
 852
 853     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 854     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 855     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 856     GL_LIB_DEPS="$DRIGL_LIBS"
 857
 858     # need DRM libs, $PTHREAD_LIBS, etc.
 859     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 860     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 861     ;;
 862 esac
 863
 864 if test "$have_libudev" = yes; then
 865     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 866 fi
 867
 868 # This is outside the case (above) so that it is invoked even for non-GLX
 869 # builds.
 870 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 871
 872 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 873 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 874 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 875 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 876
 877 AC_SUBST([X11_INCLUDES])
 878 AC_SUBST([GL_LIB_DEPS])
 879 AC_SUBST([GL_PC_REQ_PRIV])
 880 AC_SUBST([GL_PC_LIB_PRIV])
 881 AC_SUBST([GL_PC_CFLAGS])
 882 AC_SUBST([DRI_PC_REQ_PRIV])
 883 AC_SUBST([GLESv1_CM_LIB_DEPS])
 884 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 885 AC_SUBST([GLESv2_LIB_DEPS])
 886 AC_SUBST([GLESv2_PC_LIB_PRIV])
 887
 888 AC_SUBST([HAVE_XF86VIDMODE])
 889
 890 dnl
 891 dnl More GLX setup
 892 dnl
 893 case "x$enable_glx$enable_xlib_glx" in
 894 xyesyes)
 895     DEFINES="$DEFINES -DUSE_XSHM"
 896     ;;
 897 xyesno)
 898     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 899     if test "x$driglx_direct" = xyes; then
 900         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 901     fi
 902     ;;
 903 esac
 904
 905 dnl
 906 dnl TLS detection
 907 dnl
 908
 909 AC_ARG_ENABLE([glx-tls],
 910     [AS_HELP_STRING([--enable-glx-tls],
 911         [enable TLS support in GLX @<:@default=disabled@:>@])],
 912     [GLX_USE_TLS="$enableval"],
 913     [GLX_USE_TLS=no])
 914 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 915
 916 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 917       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 918
 919 dnl
 920 dnl More DRI setup
 921 dnl
 922 dnl Directory for DRI drivers
 923 AC_ARG_WITH([dri-driverdir],
 924     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 925         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 926     [DRI_DRIVER_INSTALL_DIR="$withval"],
 927     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 928 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 929 dnl Extra search path for DRI drivers
 930 AC_ARG_WITH([dri-searchpath],
 931     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 932         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 933     [DRI_DRIVER_SEARCH_DIR="$withval"],
 934     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 935 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 936 dnl Which drivers to build - default is chosen by platform
 937 AC_ARG_WITH([dri-drivers],
 938     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 939         [comma delimited classic DRI drivers list, e.g.
 940         "swrast,i965,radeon" @<:@default=auto@:>@])],
 941     [with_dri_drivers="$withval"],
 942     [with_dri_drivers=auto])
 943
 944 if test "x$with_dri_drivers" = xauto; then
 945     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 946         with_dri_drivers="yes"
 947     else
 948         with_dri_drivers="no"
 949     fi
 950 fi
 951 if test "x$with_dri_drivers" = xno; then
 952     with_dri_drivers=''
 953 fi
 954
 955 dnl If $with_dri_drivers is yes, drivers will be added through
 956 dnl platform checks. Set DEFINES and LIB_DEPS
 957 if test "x$enable_dri" = xyes; then
 958     # Platform specific settings and drivers to build
 959     case "$host_os" in
 960     linux*)
 961         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 962         DEFINES="$DEFINES -DHAVE_ALIAS"
 963         if test "x$enable_dri3" = xyes; then
 964             DEFINES="$DEFINES -DHAVE_DRI3"
 965         fi
 966
 967         if test "x$have_libudev" != xyes; then
 968             AC_MSG_ERROR([libudev-dev required for building DRI])
 969         fi
 970
 971         case "$host_cpu" in
 972         powerpc* | sparc*)
 973             # Build only the drivers for cards that exist on PowerPC/sparc
 974             if test "x$with_dri_drivers" = "xyes"; then
 975                 with_dri_drivers="r200 radeon swrast"
 976             fi
 977             ;;
 978         esac
 979         ;;
 980     *freebsd* | dragonfly* | *netbsd* | openbsd*)
 981         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 982         DEFINES="$DEFINES -DHAVE_ALIAS"
 983         ;;
 984     gnu*)
 985         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 986         DEFINES="$DEFINES -DHAVE_ALIAS"
 987         ;;
 988     solaris*)
 989         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 990         ;;
 991     cygwin*)
 992         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 993         if test "x$with_dri_drivers" = "xyes"; then
 994             with_dri_drivers="swrast"
 995         fi
 996         ;;
 997     esac
 998
 999     # default drivers
1000     if test "x$with_dri_drivers" = "xyes"; then
1001         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1002     fi
1003
1004     # Check for expat
1005     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1006     if test "x$have_expat" = "xyes"; then
1007        PKG_CHECK_MODULES([EXPAT], [expat], [],
1008                          AC_MSG_ERROR([Expat required for DRI.]))
1009     else
1010        # expat version 2.0 and earlier do not provide expat.pc
1011        EXPAT_LIBS=-lexpat
1012     fi
1013
1014     # If we are building any DRI driver other than swrast.
1015     if test -n "$with_dri_drivers"; then
1016         if test "x$with_dri_drivers" != xswrast; then
1017             # ... libdrm is required
1018             if test "x$have_libdrm" != xyes; then
1019                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1020             fi
1021             DRICOMMON_NEED_LIBDRM=yes
1022         else
1023             DRICOMMON_NEED_LIBDRM=no
1024         fi
1025     fi
1026
1027     # put all the necessary libs together
1028     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1029     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1030
1031 fi
1032
1033 AC_SUBST([DRI_LIB_DEPS])
1034 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1035
1036 DRI_DIRS=''
1037 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1038 if test -n "$with_dri_drivers"; then
1039     if test "x$enable_opengl" != xyes; then
1040         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1041     fi
1042
1043     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1044     for driver in $dri_drivers; do
1045         DRI_DIRS="$DRI_DIRS $driver"
1046         case "x$driver" in
1047         xi915)
1048             HAVE_I915_DRI=yes;
1049             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1050             ;;
1051         xi965)
1052             HAVE_I965_DRI=yes;
1053             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1054             ;;
1055         xnouveau)
1056             HAVE_NOUVEAU_DRI=yes;
1057             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1058             ;;
1059         xradeon)
1060             HAVE_RADEON_DRI=yes;
1061             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1062             ;;
1063         xr200)
1064             HAVE_R200_DRI=yes;
1065             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1066             ;;
1067         xswrast)
1068             HAVE_SWRAST_DRI=yes;
1069             ;;
1070         *)
1071             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1072             ;;
1073         esac
1074     done
1075     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1076 fi
1077
1078 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1079 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1080                                   "x$enable_osmesa" = xyes -o \
1081                                   -n "$DRI_DIRS")
1082
1083 dnl
1084 dnl OSMesa configuration
1085 dnl
1086
1087 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1088 AC_ARG_WITH([osmesa-bits],
1089     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1090         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1091     [osmesa_bits="$withval"],
1092     [osmesa_bits=8])
1093 if test "x$osmesa_bits" != x8; then
1094     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1095         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1096         osmesa_bits=8
1097     fi
1098 fi
1099 case "x$osmesa_bits" in
1100 x8)
1101     OSMESA_LIB="${OSMESA_LIB}"
1102     ;;
1103 x16|x32)
1104     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1105     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1106     ;;
1107 *)
1108     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1109     ;;
1110 esac
1111
1112 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1113     OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1114     OSMESA_MESA_DEPS=""
1115     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1116 fi
1117
1118 AC_SUBST([OSMESA_LIB_DEPS])
1119 AC_SUBST([OSMESA_MESA_DEPS])
1120 AC_SUBST([OSMESA_PC_REQ])
1121 AC_SUBST([OSMESA_PC_LIB_PRIV])
1122
1123 dnl
1124 dnl gbm configuration
1125 dnl
1126 if test "x$enable_gbm" = xauto; then
1127     case "$with_egl_platforms" in
1128         *drm*)
1129             enable_gbm=yes ;;
1130          *)
1131             enable_gbm=no ;;
1132     esac
1133 fi
1134 if test "x$enable_gbm" = xyes; then
1135     if test x"$have_libudev" != xyes; then
1136         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1137     fi
1138
1139     if test "x$enable_dri" = xyes; then
1140         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1141         if test "x$enable_shared_glapi" = xno; then
1142             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1143         fi
1144     fi
1145 fi
1146 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1147 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1148 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1149 AC_SUBST([GBM_PC_REQ_PRIV])
1150 AC_SUBST([GBM_PC_LIB_PRIV])
1151
1152 dnl
1153 dnl EGL configuration
1154 dnl
1155 EGL_CLIENT_APIS=""
1156
1157 if test "x$enable_egl" = xyes; then
1158     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1159
1160     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1161
1162     if test "x$enable_dri" = xyes; then
1163         HAVE_EGL_DRIVER_DRI2=1
1164     fi
1165 fi
1166 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1167 AC_SUBST([EGL_LIB_DEPS])
1168
1169 dnl
1170 dnl EGL Gallium configuration
1171 dnl
1172 if test "x$enable_gallium_egl" = xyes; then
1173     if test -z "$with_gallium_drivers"; then
1174         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1175     fi
1176     if test "x$enable_egl" = xno; then
1177         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1178     fi
1179     if test "x$have_libdrm" != xyes; then
1180         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1181     fi
1182
1183     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1184     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1185 fi
1186 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1187
1188 dnl
1189 dnl gbm Gallium configuration
1190 dnl
1191 if test "x$enable_gallium_gbm" = xauto; then
1192     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1193         yesyesyes*drm*)
1194             enable_gallium_gbm=yes ;;
1195          *)
1196             enable_gallium_gbm=no ;;
1197     esac
1198 fi
1199 if test "x$enable_gallium_gbm" = xyes; then
1200     if test -z "$with_gallium_drivers"; then
1201         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1202     fi
1203     if test "x$enable_gbm" = xno; then
1204         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1205     fi
1206     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1207     if test "x$enable_dri" = xno; then
1208         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1209     fi
1210
1211     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1212     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1213     enable_gallium_loader=yes
1214 fi
1215 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1216
1217 dnl
1218 dnl XA configuration
1219 dnl
1220 if test "x$enable_xa" = xyes; then
1221     if test "x$with_gallium_drivers" = xswrast; then
1222        AC_MSG_ERROR([
1223           Building xa requires at least one non swrast gallium driver.
1224           If you are looking to use libxatracker.so with vmware's virtual gpu,
1225           make sure to include svga in the gallium drivers list, apart from
1226           enabling XA.
1227           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1228     fi
1229     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1230     enable_gallium_loader=yes
1231 fi
1232 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1233
1234 dnl
1235 dnl OpenVG configuration
1236 dnl
1237 VG_LIB_DEPS=""
1238
1239 if test "x$enable_openvg" = xyes; then
1240     if test "x$enable_egl" = xno; then
1241         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1242     fi
1243     if test -z "$with_gallium_drivers"; then
1244         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1245     fi
1246     if test "x$enable_gallium_egl" = xno; then
1247         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1248     fi
1249
1250     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1251     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1252     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1253     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1254     AC_SUBST([VG_PC_LIB_PRIV])
1255 fi
1256 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1257
1258 dnl
1259 dnl Gallium G3DVL configuration
1260 dnl
1261 if test -n "$with_gallium_drivers"; then
1262     if test "x$enable_xvmc" = xauto; then
1263         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1264     fi
1265
1266     if test "x$enable_vdpau" = xauto; then
1267         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1268     fi
1269
1270     if test "x$enable_omx" = xauto; then
1271         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1272     fi
1273 fi
1274
1275 if test "x$enable_xvmc" = xyes; then
1276     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1277     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1278 fi
1279 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1280
1281 if test "x$enable_vdpau" = xyes; then
1282     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1283                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1284     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1285 fi
1286 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1287
1288 if test "x$enable_omx" = xyes; then
1289     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1290     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1291 fi
1292 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1293
1294 dnl
1295 dnl OpenCL configuration
1296 dnl
1297
1298 AC_ARG_WITH([libclc-path],
1299    [AS_HELP_STRING([--with-libclc-path],
1300          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1301    [LIBCLC_PATH="$withval"],
1302    [LIBCLC_PATH=''])
1303
1304 if test -n "$LIBCLC_PATH"; then
1305    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1306                   Please review the updated build instructions for clover:
1307                   http://dri.freedesktop.org/wiki/GalliumCompute])
1308 fi
1309
1310
1311 AC_ARG_WITH([clang-libdir],
1312    [AS_HELP_STRING([--with-clang-libdir],
1313          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1314    [CLANG_LIBDIR="$withval"],
1315    [CLANG_LIBDIR=''])
1316
1317 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1318
1319 if test "x$enable_opencl" = xyes; then
1320     if test -z "$with_gallium_drivers"; then
1321         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1322     fi
1323
1324     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1325         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1326     fi
1327
1328     if test "x$have_libclc" = xno; then
1329         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1330                     Make sure the directory containing libclc.pc is specified in your
1331                     PKG_CONFIG_PATH environment variable.
1332                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1333     else
1334         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1335         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1336         AC_SUBST([LIBCLC_INCLUDEDIR])
1337         AC_SUBST([LIBCLC_LIBEXECDIR])
1338     fi
1339
1340     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1341     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1342     enable_gallium_loader=yes
1343
1344     if test "x$enable_opencl_icd" = xyes; then
1345         OPENCL_LIBNAME="MesaOpenCL"
1346     else
1347         OPENCL_LIBNAME="OpenCL"
1348     fi
1349 fi
1350 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1351 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1352 AC_SUBST([OPENCL_LIBNAME])
1353
1354 dnl
1355 dnl Gallium configuration
1356 dnl
1357 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1358
1359 AC_SUBST([LLVM_BINDIR])
1360 AC_SUBST([LLVM_CFLAGS])
1361 AC_SUBST([LLVM_CPPFLAGS])
1362 AC_SUBST([LLVM_CXXFLAGS])
1363 AC_SUBST([LLVM_LIBDIR])
1364 AC_SUBST([LLVM_LIBS])
1365 AC_SUBST([LLVM_LDFLAGS])
1366 AC_SUBST([LLVM_INCLUDEDIR])
1367 AC_SUBST([LLVM_VERSION])
1368 AC_SUBST([CLANG_RESOURCE_DIR])
1369
1370 case "x$enable_opengl$enable_gles1$enable_gles2" in
1371 x*yes*)
1372     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1373     ;;
1374 esac
1375
1376 AC_SUBST([VG_LIB_DEPS])
1377 AC_SUBST([EGL_CLIENT_APIS])
1378
1379 dnl
1380 dnl EGL Platforms configuration
1381 dnl
1382 AC_ARG_WITH([egl-platforms],
1383     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1384         [comma delimited native platforms libEGL supports, e.g.
1385         "x11,drm" @<:@default=auto@:>@])],
1386     [with_egl_platforms="$withval"],
1387     [if test "x$enable_egl" = xyes; then
1388         with_egl_platforms="x11"
1389     else
1390         with_egl_platforms=""
1391     fi])
1392
1393 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1394     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1395 fi
1396
1397 # Do per-EGL platform setups and checks
1398 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1399 for plat in $egl_platforms; do
1400         case "$plat" in
1401         wayland)
1402                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1403                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1404
1405                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1406                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1407                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1408                 ;;
1409
1410         x11)
1411                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1412                 ;;
1413
1414         drm)
1415                 test "x$enable_gbm" = "xno" &&
1416                         AC_MSG_ERROR([EGL platform drm needs gbm])
1417                 test "x$have_libdrm" != xyes &&
1418                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1419                 ;;
1420
1421         android|fbdev|gdi|null)
1422                 ;;
1423
1424         *)
1425                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1426                 ;;
1427         esac
1428
1429         case "$plat$have_libudev" in
1430                 waylandno|drmno)
1431                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1432         esac
1433 done
1434
1435 # libEGL wants to default to the first platform specified in
1436 # ./configure.  parse that here.
1437 if test "x$egl_platforms" != "x"; then
1438     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1439     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1440 else
1441     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1442 fi
1443
1444 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1445     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1446     NEED_WINSYS_XLIB=yes
1447 fi
1448 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1449 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1450 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1451 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1452 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1453
1454 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1455
1456 AC_SUBST([EGL_NATIVE_PLATFORM])
1457 AC_SUBST([EGL_CFLAGS])
1458
1459 # If we don't have the X11 platform, set this define so we don't try to include
1460 # the X11 headers.
1461 if ! echo "$egl_platforms" | grep -q 'x11'; then
1462     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1463     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1464 fi
1465
1466 AC_ARG_WITH([egl-driver-dir],
1467     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1468                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1469     [EGL_DRIVER_INSTALL_DIR="$withval"],
1470     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1471 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1472
1473 AC_ARG_WITH([max-width],
1474     [AS_HELP_STRING([--with-max-width=N],
1475                     [Maximum framebuffer width (4096)])],
1476     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1477      AS_IF([test "${withval}" -gt "4096"],
1478            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1479 )
1480 AC_ARG_WITH([max-height],
1481     [AS_HELP_STRING([--with-max-height=N],
1482                     [Maximum framebuffer height (4096)])],
1483     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1484      AS_IF([test "${withval}" -gt "4096"],
1485            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1486 )
1487
1488 dnl
1489 dnl Gallium LLVM
1490 dnl
1491 AC_ARG_ENABLE([gallium-llvm],
1492     [AS_HELP_STRING([--enable-gallium-llvm],
1493         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1494     [enable_gallium_llvm="$enableval"],
1495     [enable_gallium_llvm=auto])
1496
1497 AC_ARG_ENABLE([llvm-shared-libs],
1498     [AS_HELP_STRING([--enable-llvm-shared-libs],
1499         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1500     [enable_llvm_shared_libs="$enableval"],
1501     [enable_llvm_shared_libs=yes])
1502
1503 AC_ARG_WITH([llvm-prefix],
1504     [AS_HELP_STRING([--with-llvm-prefix],
1505         [Prefix for LLVM installations in non-standard locations])],
1506     [llvm_prefix="$withval"],
1507     [llvm_prefix=''])
1508
1509
1510 # Call this inside ` ` to get the return value.
1511 # $1 is the llvm-config command with arguments.
1512 strip_unwanted_llvm_flags() {
1513     # Use \> (marks the end of the word)
1514     echo `$1` | sed \
1515         -e 's/-DNDEBUG\>//g' \
1516         -e 's/-pedantic\>//g' \
1517         -e 's/-Wcovered-switch-default\>//g' \
1518         -e 's/-O.\>//g' \
1519         -e 's/-g\>//g' \
1520         -e 's/-Wall\>//g' \
1521         -e 's/-Wcast-qual\>//g' \
1522         -e 's/-Woverloaded-virtual\>//g' \
1523         -e 's/-fcolor-diagnostics\>//g' \
1524         -e 's/-fdata-sections\>//g' \
1525         -e 's/-ffunction-sections\>//g' \
1526         -e 's/-fno-exceptions\>//g' \
1527         -e 's/-fomit-frame-pointer\>//g' \
1528         -e 's/-fvisibility-inlines-hidden\>//g' \
1529         -e 's/-fPIC\>//g'
1530 }
1531
1532
1533 if test -z "$with_gallium_drivers"; then
1534     enable_gallium_llvm=no
1535 fi
1536 if test "x$enable_gallium_llvm" = xauto; then
1537     case "$host_cpu" in
1538     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1539     esac
1540 fi
1541 if test "x$enable_gallium_llvm" = xyes; then
1542     if test -n "$llvm_prefix"; then
1543         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1544     else
1545         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1546     fi
1547
1548     if test "x$LLVM_CONFIG" != xno; then
1549         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1550         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1551         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1552         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1553         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1554         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1555         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1556         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1557
1558         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1559             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1560         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1561             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1562
1563         if test -n "${LLVM_VERSION_MAJOR}"; then
1564             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1565         else
1566             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1567         fi
1568
1569         LLVM_COMPONENTS="engine bitwriter"
1570         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1571             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1572         fi
1573
1574         if test "x$enable_opencl" = xyes; then
1575             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1576             # LLVM 3.3 >= 177971 requires IRReader
1577             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1578                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1579             fi
1580             # LLVM 3.4 requires Option
1581             if $LLVM_CONFIG --components | grep -qw 'option'; then
1582                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1583             fi
1584         fi
1585         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1586         MESA_LLVM=1
1587
1588         dnl Check for Clang internal headers
1589         if test "x$enable_opencl" = xyes; then
1590             if test -z "$CLANG_LIBDIR"; then
1591                 CLANG_LIBDIR=${LLVM_LIBDIR}
1592             fi
1593             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1594             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1595                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1596         fi
1597     else
1598         MESA_LLVM=0
1599         LLVM_VERSION_INT=0
1600     fi
1601 else
1602     MESA_LLVM=0
1603     LLVM_VERSION_INT=0
1604 fi
1605
1606 dnl Directory for XVMC libs
1607 AC_ARG_WITH([xvmc-libdir],
1608     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1609         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1610     [XVMC_LIB_INSTALL_DIR="$withval"],
1611     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1612 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1613
1614 dnl
1615 dnl Gallium Tests
1616 dnl
1617 if test "x$enable_gallium_tests" = xyes; then
1618     enable_gallium_loader=yes
1619 fi
1620 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1621
1622 if test "x$enable_gallium_loader" = xyes; then
1623     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1624 fi
1625 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1626
1627 dnl Directory for VDPAU libs
1628 AC_ARG_WITH([vdpau-libdir],
1629     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1630         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1631     [VDPAU_LIB_INSTALL_DIR="$withval"],
1632     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1633 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1634
1635 OMX_LIB_INSTALL_DIR_DEFAULT=''
1636 if test "x$enable_omx" = xyes; then
1637     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1638 fi
1639
1640 AC_ARG_WITH([omx-libdir],
1641     [AS_HELP_STRING([--with-omx-libdir=DIR],
1642         [directory for the OMX libraries])],
1643     [OMX_LIB_INSTALL_DIR="$withval"],
1644     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1645 AC_SUBST([OMX_LIB_INSTALL_DIR])
1646
1647 dnl Directory for OpenCL libs
1648 AC_ARG_WITH([opencl-libdir],
1649     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1650         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1651     [OPENCL_LIB_INSTALL_DIR="$withval"],
1652     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1653 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1654
1655 dnl
1656 dnl Gallium helper functions
1657 dnl
1658 gallium_check_st() {
1659     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1660          if test "x$have_libdrm" != xyes; then
1661             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1662          fi
1663          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1664     fi
1665     if test "x$enable_dri" = xyes && test -n "$2"; then
1666          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1667     fi
1668     if test "x$enable_xa" = xyes && test -n "$3"; then
1669          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1670     fi
1671     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1672          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1673     fi
1674     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1675          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1676     fi
1677     if test "x$enable_omx" = xyes && test "x$6" != x; then
1678          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1679     fi
1680 }
1681
1682 gallium_require_llvm() {
1683     if test "x$MESA_LLVM" = x0; then
1684         case "$host_cpu" in
1685         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1686         esac
1687     fi
1688 }
1689
1690 gallium_require_drm_loader() {
1691     if test "x$enable_gallium_loader" = xyes; then
1692         if test "x$have_libudev" != xyes; then
1693             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1694         fi
1695         if test "x$have_libdrm" != xyes; then
1696             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1697         fi
1698         enable_gallium_drm_loader=yes
1699     fi
1700 }
1701
1702 radeon_llvm_check() {
1703     if test "x$enable_gallium_llvm" != "xyes"; then
1704         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1705     fi
1706     LLVM_REQUIRED_VERSION_MAJOR="3"
1707     LLVM_REQUIRED_VERSION_MINOR="3"
1708     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1709         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1710     fi
1711     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1712         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1713                       sources with the --enable-experimental-targets=R600
1714                       configure flag])
1715     fi
1716     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1717     NEED_RADEON_LLVM=yes
1718     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1719                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1720 }
1721
1722 dnl Gallium drivers
1723 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1724         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1725     NEED_NONNULL_WINSYS=yes
1726 fi
1727 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1728
1729 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1730 if test -n "$with_gallium_drivers"; then
1731     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1732     for driver in $gallium_drivers; do
1733         case "x$driver" in
1734         xsvga)
1735             HAVE_GALLIUM_SVGA=yes
1736             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1737             gallium_require_drm_loader
1738             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1739             ;;
1740         xi915)
1741             HAVE_GALLIUM_I915=yes
1742             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1743             gallium_require_drm_loader
1744             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1745             if test "x$MESA_LLVM" = x1; then
1746                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1747             fi
1748             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1749             gallium_check_st "i915/drm" "dri-i915"
1750             DRICOMMON_NEED_LIBDRM=yes
1751             ;;
1752         xilo)
1753             HAVE_GALLIUM_ILO=yes
1754             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1755             gallium_require_drm_loader
1756             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1757             gallium_check_st "intel/drm" "dri-ilo"
1758             DRICOMMON_NEED_LIBDRM=yes
1759             ;;
1760         xr300)
1761             HAVE_GALLIUM_R300=yes
1762             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1763             gallium_require_drm_loader
1764             gallium_require_llvm "Gallium R300"
1765             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1766             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1767             DRICOMMON_NEED_LIBDRM=yes
1768             ;;
1769         xr600)
1770             HAVE_GALLIUM_R600=yes
1771             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1772             gallium_require_drm_loader
1773             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1774             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1775                 radeon_llvm_check "r600g"
1776                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1777             fi
1778             if test "x$enable_r600_llvm" = xyes; then
1779                 USE_R600_LLVM_COMPILER=yes;
1780             fi
1781             if test "x$enable_opencl" = xyes; then
1782                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1783             fi
1784             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1785             DRICOMMON_NEED_LIBDRM=yes
1786             ;;
1787         xradeonsi)
1788             HAVE_GALLIUM_RADEONSI=yes
1789             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1790             gallium_require_drm_loader
1791             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1792             radeon_llvm_check "radeonsi"
1793             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1794             DRICOMMON_NEED_LIBDRM=yes
1795             ;;
1796         xnouveau)
1797             HAVE_GALLIUM_NOUVEAU=yes
1798             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1799             gallium_require_drm_loader
1800             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1801             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1802             DRICOMMON_NEED_LIBDRM=yes
1803             ;;
1804         xfreedreno)
1805             HAVE_GALLIUM_FREEDRENO=yes
1806             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1807             gallium_require_drm_loader
1808             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1809             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1810             DRICOMMON_NEED_LIBDRM=yes
1811             ;;
1812         xswrast)
1813             HAVE_GALLIUM_SOFTPIPE=yes
1814             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1815             if test "x$MESA_LLVM" = x1; then
1816                 HAVE_GALLIUM_LLVMPIPE=yes
1817                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1818             fi
1819
1820             if test "x$enable_dri" = xyes; then
1821                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1822             fi
1823             ;;
1824         *)
1825             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1826             ;;
1827         esac
1828     done
1829 fi
1830
1831 dnl Set LLVM_LIBS - This is done after the driver configuration so
1832 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1833 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1834 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1835 dnl this was causing the same libraries to be appear multiple times
1836 dnl in LLVM_LIBS.
1837
1838 if test "x$MESA_LLVM" != x0; then
1839
1840     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1841
1842     if test "x$enable_llvm_shared_libs" = xyes; then
1843         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1844         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1845         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1846
1847         if test "x$llvm_have_one_so" = xyes; then
1848             dnl LLVM was built using auto*, so there is only one shared object.
1849             LLVM_LIBS="-l$LLVM_SO_NAME"
1850         else
1851             dnl If LLVM was built with CMake, there will be one shared object per
1852             dnl component.
1853             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1854                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1855         Please make sure you have built llvm with the --enable-shared option
1856         and that your llvm libraries are installed in $LLVM_LIBDIR
1857         If you have installed your llvm libraries to a different directory you
1858         can use the --with-llvm-prefix= configure flag to specify this directory.
1859         NOTE: Mesa is attempting to use llvm shared libraries by default.
1860         If you do not want to build with llvm shared libraries and instead want to
1861         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1862         invocation and rebuild.])])
1863
1864            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1865            dnl install uses a shared object for each compoenent and we have
1866            dnl already added all of these objects to LLVM_LIBS.
1867         fi
1868     else
1869         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
1870     fi
1871 fi
1872
1873 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1874 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1875 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1876 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1877 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1878 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1879 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1880 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1881 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1882 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1883
1884 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1885                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1886                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1887 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1888                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1889                                                   && test "x$MESA_LLVM" = x1)
1890
1891 # NOTE: anything using xcb or other client side libs ends up in separate
1892 #       _CLIENT variables.  The pipe loader is built in two variants,
1893 #       one that is standalone and does not link any x client libs (for
1894 #       use by XA tracker in particular, but could be used in any case
1895 #       where communication with xserver is not desired).
1896 if test "x$enable_gallium_loader" = xyes; then
1897     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1898
1899     if test "x$enable_gallium_xlib_loader" = xyes; then
1900         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1901         NEED_WINSYS_XLIB="yes"
1902         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1903     fi
1904
1905     if test "x$enable_gallium_drm_loader" = xyes; then
1906         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1907         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1908                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1909         if test "x$pipe_loader_have_xcb" = xyes; then
1910             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1911             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1912         fi
1913     fi
1914
1915     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1916     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1917
1918     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1919     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1920     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1921     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1922 fi
1923 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1924
1925 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1926 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1927 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1928 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1929 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1930 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1931
1932 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1933                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1934                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1935                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1936 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1937                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1938 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1939 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1940 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1941 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1942 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1943 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1944 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1945
1946 AC_SUBST([ELF_LIB])
1947
1948 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1949 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1950 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1951 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1952 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1953
1954 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1955 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1956 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1957
1958 AC_SUBST([VDPAU_MAJOR], 1)
1959 AC_SUBST([VDPAU_MINOR], 0)
1960
1961 AC_SUBST([XVMC_MAJOR], 1)
1962 AC_SUBST([XVMC_MINOR], 0)
1963
1964 AC_SUBST([XA_MAJOR], 2)
1965 AC_SUBST([XA_MINOR], 2)
1966 AC_SUBST([XA_TINY], 0)
1967 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1968
1969 dnl Restore LDFLAGS and CPPFLAGS
1970 LDFLAGS="$_SAVE_LDFLAGS"
1971 CPPFLAGS="$_SAVE_CPPFLAGS"
1972
1973 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1974 if test "x$acv_mesa_CLANG" = xyes; then
1975     CFLAGS="$CFLAGS -Qunused-arguments"
1976     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1977 fi
1978
1979 dnl Add user CFLAGS and CXXFLAGS
1980 CFLAGS="$CFLAGS $USER_CFLAGS"
1981 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1982
1983 dnl Substitute the config
1984 AC_CONFIG_FILES([Makefile
1985                 src/Makefile
1986                 src/egl/Makefile
1987                 src/egl/drivers/Makefile
1988                 src/egl/drivers/dri2/Makefile
1989                 src/egl/main/Makefile
1990                 src/egl/main/egl.pc
1991                 src/egl/wayland/Makefile
1992                 src/egl/wayland/wayland-drm/Makefile
1993                 src/egl/wayland/wayland-egl/Makefile
1994                 src/egl/wayland/wayland-egl/wayland-egl.pc
1995                 src/gallium/auxiliary/Makefile
1996                 src/gallium/auxiliary/pipe-loader/Makefile
1997                 src/gallium/drivers/Makefile
1998                 src/gallium/drivers/freedreno/Makefile
1999                 src/gallium/drivers/galahad/Makefile
2000                 src/gallium/drivers/i915/Makefile
2001                 src/gallium/drivers/identity/Makefile
2002                 src/gallium/drivers/ilo/Makefile
2003                 src/gallium/drivers/llvmpipe/Makefile
2004                 src/gallium/drivers/noop/Makefile
2005                 src/gallium/drivers/nouveau/Makefile
2006                 src/gallium/drivers/r300/Makefile
2007                 src/gallium/drivers/r600/Makefile
2008                 src/gallium/drivers/radeon/Makefile
2009                 src/gallium/drivers/radeonsi/Makefile
2010                 src/gallium/drivers/rbug/Makefile
2011                 src/gallium/drivers/softpipe/Makefile
2012                 src/gallium/drivers/svga/Makefile
2013                 src/gallium/drivers/trace/Makefile
2014                 src/gallium/state_trackers/Makefile
2015                 src/gallium/state_trackers/clover/Makefile
2016                 src/gallium/state_trackers/dri/Makefile
2017                 src/gallium/state_trackers/dri/drm/Makefile
2018                 src/gallium/state_trackers/dri/sw/Makefile
2019                 src/gallium/state_trackers/egl/Makefile
2020                 src/gallium/state_trackers/gbm/Makefile
2021                 src/gallium/state_trackers/glx/xlib/Makefile
2022                 src/gallium/state_trackers/omx/Makefile
2023                 src/gallium/state_trackers/osmesa/Makefile
2024                 src/gallium/state_trackers/vdpau/Makefile
2025                 src/gallium/state_trackers/vega/Makefile
2026                 src/gallium/state_trackers/xa/Makefile
2027                 src/gallium/state_trackers/xvmc/Makefile
2028                 src/gallium/targets/Makefile
2029                 src/gallium/targets/dri-freedreno/Makefile
2030                 src/gallium/targets/dri-i915/Makefile
2031                 src/gallium/targets/dri-ilo/Makefile
2032                 src/gallium/targets/dri-nouveau/Makefile
2033                 src/gallium/targets/dri-swrast/Makefile
2034                 src/gallium/targets/dri-vmwgfx/Makefile
2035                 src/gallium/targets/egl-static/Makefile
2036                 src/gallium/targets/gbm/Makefile
2037                 src/gallium/targets/opencl/Makefile
2038                 src/gallium/targets/xa/Makefile
2039                 src/gallium/targets/xa/xatracker.pc
2040                 src/gallium/targets/osmesa/Makefile
2041                 src/gallium/targets/osmesa/osmesa.pc
2042                 src/gallium/targets/pipe-loader/Makefile
2043                 src/gallium/targets/radeonsi/dri/Makefile
2044                 src/gallium/targets/radeonsi/omx/Makefile
2045                 src/gallium/targets/radeonsi/vdpau/Makefile
2046                 src/gallium/targets/r300/dri/Makefile
2047                 src/gallium/targets/r600/dri/Makefile
2048                 src/gallium/targets/r600/omx/Makefile
2049                 src/gallium/targets/r600/vdpau/Makefile
2050                 src/gallium/targets/r600/xvmc/Makefile
2051                 src/gallium/targets/libgl-xlib/Makefile
2052                 src/gallium/targets/vdpau-nouveau/Makefile
2053                 src/gallium/targets/xvmc-nouveau/Makefile
2054                 src/gallium/tests/trivial/Makefile
2055                 src/gallium/tests/unit/Makefile
2056                 src/gallium/winsys/Makefile
2057                 src/gallium/winsys/freedreno/drm/Makefile
2058                 src/gallium/winsys/i915/drm/Makefile
2059                 src/gallium/winsys/i915/sw/Makefile
2060                 src/gallium/winsys/intel/drm/Makefile
2061                 src/gallium/winsys/nouveau/drm/Makefile
2062                 src/gallium/winsys/radeon/drm/Makefile
2063                 src/gallium/winsys/svga/drm/Makefile
2064                 src/gallium/winsys/sw/dri/Makefile
2065                 src/gallium/winsys/sw/fbdev/Makefile
2066                 src/gallium/winsys/sw/null/Makefile
2067                 src/gallium/winsys/sw/wayland/Makefile
2068                 src/gallium/winsys/sw/wrapper/Makefile
2069                 src/gallium/winsys/sw/xlib/Makefile
2070                 src/gbm/Makefile
2071                 src/gbm/main/gbm.pc
2072                 src/glsl/Makefile
2073                 src/glx/Makefile
2074                 src/glx/tests/Makefile
2075                 src/gtest/Makefile
2076                 src/loader/Makefile
2077                 src/mapi/Makefile
2078                 src/mapi/es1api/Makefile
2079                 src/mapi/es1api/glesv1_cm.pc
2080                 src/mapi/es2api/Makefile
2081                 src/mapi/es2api/glesv2.pc
2082                 src/mapi/glapi/Makefile
2083                 src/mapi/glapi/gen/Makefile
2084                 src/mapi/glapi/tests/Makefile
2085                 src/mapi/shared-glapi/Makefile
2086                 src/mapi/shared-glapi/tests/Makefile
2087                 src/mapi/vgapi/Makefile
2088                 src/mapi/vgapi/vg.pc
2089                 src/mesa/Makefile
2090                 src/mesa/gl.pc
2091                 src/mesa/drivers/dri/dri.pc
2092                 src/mesa/drivers/dri/common/Makefile
2093                 src/mesa/drivers/dri/common/xmlpool/Makefile
2094                 src/mesa/drivers/dri/i915/Makefile
2095                 src/mesa/drivers/dri/i965/Makefile
2096                 src/mesa/drivers/dri/Makefile
2097                 src/mesa/drivers/dri/nouveau/Makefile
2098                 src/mesa/drivers/dri/r200/Makefile
2099                 src/mesa/drivers/dri/radeon/Makefile
2100                 src/mesa/drivers/dri/swrast/Makefile
2101                 src/mesa/drivers/osmesa/Makefile
2102                 src/mesa/drivers/osmesa/osmesa.pc
2103                 src/mesa/drivers/x11/Makefile
2104                 src/mesa/main/tests/Makefile
2105                 src/mesa/main/tests/hash_table/Makefile])
2106
2107 dnl Sort the dirs alphabetically
2108 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2109 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2110 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2111 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2112
2113 AC_OUTPUT
2114
2115 dnl
2116 dnl Output some configuration info for the user
2117 dnl
2118 echo ""
2119 echo "        prefix:          $prefix"
2120 echo "        exec_prefix:     $exec_prefix"
2121 echo "        libdir:          $libdir"
2122 echo "        includedir:      $includedir"
2123
2124 dnl API info
2125 echo ""
2126 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2127 echo "        OpenVG:          $enable_openvg"
2128
2129 dnl Driver info
2130 echo ""
2131 case "x$enable_osmesa$enable_gallium_osmesa" in
2132 xnoyes)
2133         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2134         ;;
2135 xyesno)
2136         echo "        OSMesa:          lib$OSMESA_LIB"
2137         ;;
2138 xnono)
2139         echo "        OSMesa:          no"
2140         ;;
2141 esac
2142
2143 if test "x$enable_dri" != xno; then
2144         if test -z "$DRI_DIRS"; then
2145             echo "        DRI drivers:     no"
2146         else
2147             echo "        DRI drivers:     $DRI_DIRS"
2148         fi
2149         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2150 fi
2151
2152 case "x$enable_glx$enable_xlib_glx" in
2153 xyesyes)
2154     echo "        GLX:             Xlib-based"
2155     ;;
2156 xyesno)
2157     echo "        GLX:             DRI-based"
2158     ;;
2159 *)
2160     echo "        GLX:             $enable_glx"
2161     ;;
2162 esac
2163
2164 dnl EGL
2165 echo ""
2166 echo "        EGL:             $enable_egl"
2167 if test "$enable_egl" = yes; then
2168     echo "        EGL platforms:   $egl_platforms"
2169
2170     egl_drivers=""
2171     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2172         egl_drivers="$egl_drivers builtin:egl_dri2"
2173     fi
2174
2175     if test "x$enable_gallium_egl" = xyes; then
2176         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2177         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2178     else
2179         echo "        EGL drivers:    $egl_drivers"
2180     fi
2181 fi
2182
2183 echo ""
2184 if test "x$MESA_LLVM" = x1; then
2185     echo "        llvm:            yes"
2186     echo "        llvm-config:     $LLVM_CONFIG"
2187     echo "        llvm-version:    $LLVM_VERSION"
2188 else
2189     echo "        llvm:            no"
2190 fi
2191
2192 echo ""
2193 if test -n "$with_gallium_drivers"; then
2194     echo "        Gallium:         yes"
2195     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2196     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2197     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2198     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2199 else
2200     echo "        Gallium:         no"
2201 fi
2202
2203
2204 dnl Libraries
2205 echo ""
2206 echo "        Shared libs:     $enable_shared"
2207 echo "        Static libs:     $enable_static"
2208 echo "        Shared-glapi:    $enable_shared_glapi"
2209
2210 dnl Compiler options
2211 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2212 cflags=`echo $CFLAGS | \
2213     $SED 's/^ *//;s/  */ /;s/ *$//'`
2214 cxxflags=`echo $CXXFLAGS | \
2215     $SED 's/^ *//;s/  */ /;s/ *$//'`
2216 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2217 echo ""
2218 echo "        CFLAGS:          $cflags"
2219 echo "        CXXFLAGS:        $cxxflags"
2220 echo "        Macros:          $defines"
2221 echo ""
2222 if test "x$MESA_LLVM" = x1; then
2223     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2224     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2225     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2226     echo ""
2227 fi
2228 echo "        PYTHON2:         $PYTHON2"
2229
2230 echo ""
2231 echo "        Run '${MAKE-make}' to build Mesa"
2232 echo ""