configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.55
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 GEN_ASM_OFFSETS=no
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120
 121     if test "x$cross_compiling" = xyes; then
 122         GEN_ASM_OFFSETS=yes
 123     fi
 124 fi
 125
 126 dnl Check for compiler builtins
 127 AX_GCC_BUILTIN([__builtin_bswap32])
 128 AX_GCC_BUILTIN([__builtin_bswap64])
 129
 130 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 131
 132 dnl Make sure the pkg-config macros are defined
 133 m4_ifndef([PKG_PROG_PKG_CONFIG],
 134     [m4_fatal([Could not locate the pkg-config autoconf macros.
 135   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 136   are in a different location, try setting the environment variable
 137   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 138 PKG_PROG_PKG_CONFIG()
 139
 140 dnl LIB_DIR - library basename
 141 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 142 AC_SUBST([LIB_DIR])
 143
 144 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 145 _SAVE_LDFLAGS="$LDFLAGS"
 146 _SAVE_CPPFLAGS="$CPPFLAGS"
 147
 148 dnl Compiler macros
 149 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 150 AC_SUBST([DEFINES])
 151 case "$host_os" in
 152 linux*|*-gnu*|gnu*)
 153     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 154     ;;
 155 solaris*)
 156     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 157     ;;
 158 cygwin*)
 159     DEFINES="$DEFINES -D_XOPEN_SOURCE=700 -DHAVE_PTHREAD"
 160     ;;
 161 esac
 162
 163 dnl Add flags for gcc and g++
 164 if test "x$GCC" = xyes; then
 165     CFLAGS="$CFLAGS -Wall -std=c99"
 166
 167     # Enable -Werror=implicit-function-declaration and
 168     # -Werror=missing-prototypes, if available, or otherwise, just
 169     # -Wmissing-prototypes.  This is particularly useful to avoid
 170     # generating a loadable driver module that has undefined symbols.
 171     save_CFLAGS="$CFLAGS"
 172     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 173     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 174     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 175     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 176                    AC_MSG_RESULT([yes]),
 177                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 178                     AC_MSG_RESULT([no])]);
 179
 180     # Enable -fvisibility=hidden if using a gcc that supports it
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 183     VISIBILITY_CFLAGS="-fvisibility=hidden"
 184     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 186                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 187
 188     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 189     CFLAGS=$save_CFLAGS
 190
 191     # Work around aliasing bugs - developers should comment this out
 192     CFLAGS="$CFLAGS -fno-strict-aliasing"
 193
 194     # gcc's builtin memcmp is slower than glibc's
 195     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 196     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 197 fi
 198 if test "x$GXX" = xyes; then
 199     CXXFLAGS="$CXXFLAGS -Wall"
 200
 201     # Enable -fvisibility=hidden if using a gcc that supports it
 202     save_CXXFLAGS="$CXXFLAGS"
 203     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 204     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 205     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 206     AC_LANG_PUSH([C++])
 207     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 208                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 209     AC_LANG_POP([C++])
 210
 211     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 212     CXXFLAGS=$save_CXXFLAGS
 213
 214     # Work around aliasing bugs - developers should comment this out
 215     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 216
 217     # gcc's builtin memcmp is slower than glibc's
 218     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 219     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 220 fi
 221
 222 dnl even if the compiler appears to support it, using visibility attributes isn't
 223 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 224 case "$host_os" in
 225 cygwin*)
 226     VISIBILITY_CFLAGS=""
 227     VISIBILITY_CXXFLAGS=""
 228     ;;
 229 esac
 230
 231 AC_SUBST([VISIBILITY_CFLAGS])
 232 AC_SUBST([VISIBILITY_CXXFLAGS])
 233
 234 dnl
 235 dnl Optional flags, check for compiler support
 236 dnl
 237 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 238 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 239
 240 dnl
 241 dnl Hacks to enable 32 or 64 bit build
 242 dnl
 243 AC_ARG_ENABLE([32-bit],
 244     [AS_HELP_STRING([--enable-32-bit],
 245         [build 32-bit libraries @<:@default=auto@:>@])],
 246     [enable_32bit="$enableval"],
 247     [enable_32bit=auto]
 248 )
 249 if test "x$enable_32bit" = xyes; then
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -m32"
 252         CCASFLAGS="$CCASFLAGS -m32"
 253     fi
 254     if test "x$GXX" = xyes; then
 255         CXXFLAGS="$CXXFLAGS -m32"
 256     fi
 257 fi
 258 AC_ARG_ENABLE([64-bit],
 259     [AS_HELP_STRING([--enable-64-bit],
 260         [build 64-bit libraries @<:@default=auto@:>@])],
 261     [enable_64bit="$enableval"],
 262     [enable_64bit=auto]
 263 )
 264 if test "x$enable_64bit" = xyes; then
 265     if test "x$GCC" = xyes; then
 266         CFLAGS="$CFLAGS -m64"
 267     fi
 268     if test "x$GXX" = xyes; then
 269         CXXFLAGS="$CXXFLAGS -m64"
 270     fi
 271 fi
 272
 273 dnl Can't have static and shared libraries, default to static if user
 274 dnl explicitly requested. If both disabled, set to static since shared
 275 dnl was explicitly requested.
 276 case "x$enable_static$enable_shared" in
 277 xyesyes)
 278     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 279     enable_shared=no
 280     ;;
 281 xnono)
 282     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 283     enable_shared=yes
 284     ;;
 285 esac
 286
 287 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 288
 289 dnl
 290 dnl other compiler options
 291 dnl
 292 AC_ARG_ENABLE([debug],
 293     [AS_HELP_STRING([--enable-debug],
 294         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 295     [enable_debug="$enableval"],
 296     [enable_debug=no]
 297 )
 298 if test "x$enable_debug" = xyes; then
 299     DEFINES="$DEFINES -DDEBUG"
 300     if test "x$GCC" = xyes; then
 301         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 302             CFLAGS="$CFLAGS -g"
 303         fi
 304         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 305             CFLAGS="$CFLAGS -O0"
 306         fi
 307     fi
 308     if test "x$GXX" = xyes; then
 309         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 310             CXXFLAGS="$CXXFLAGS -g"
 311         fi
 312         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 313             CXXFLAGS="$CXXFLAGS -O0"
 314         fi
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports -Bsymbolic
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 323 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         BSYMBOLIC="-Wl,-Bsymbolic";],
 328     [AC_MSG_RESULT([no])
 329         BSYMBOLIC="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([BSYMBOLIC])
 333
 334 dnl
 335 dnl Check if linker supports garbage collection
 336 dnl
 337 save_LDFLAGS=$LDFLAGS
 338 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 339 AC_MSG_CHECKING([whether ld supports --gc-sections])
 340 AC_LINK_IFELSE(
 341     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 342     [AC_MSG_RESULT([yes])
 343         GC_SECTIONS="-Wl,--gc-sections";],
 344     [AC_MSG_RESULT([no])
 345         GC_SECTIONS="";])
 346 LDFLAGS=$save_LDFLAGS
 347
 348 AC_SUBST([GC_SECTIONS])
 349
 350 dnl
 351 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 352 dnl so when these flags are passed to ld via libtool the checks will fail
 353 dnl
 354 case "$host_os" in
 355 openbsd* | darwin* )
 356     LD_NO_UNDEFINED="" ;;
 357 *)
 358     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 359 esac
 360
 361 AC_SUBST([LD_NO_UNDEFINED])
 362
 363 dnl
 364 dnl Check if linker supports version scripts
 365 dnl
 366 AC_MSG_CHECKING([if the linker supports version-scripts])
 367 save_LDFLAGS=$LDFLAGS
 368 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 369 cat > conftest.map <<EOF
 370 VERSION_1 {
 371      global:
 372          main;
 373
 374      local:
 375          *;
 376 };
 377 EOF
 378 AC_LINK_IFELSE(
 379     [AC_LANG_SOURCE([int main() { return 0;}])],
 380     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 381     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 382 LDFLAGS=$save_LDFLAGS
 383 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 384
 385 dnl
 386 dnl compatibility symlinks
 387 dnl
 388 case "$host_os" in
 389 linux* )
 390     HAVE_COMPAT_SYMLINKS=yes ;;
 391 * )
 392     HAVE_COMPAT_SYMLINKS=no ;;
 393 esac
 394
 395 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 396
 397 dnl
 398 dnl library names
 399 dnl
 400 case "$host_os" in
 401 darwin* )
 402     LIB_EXT='dylib' ;;
 403 cygwin* )
 404     LIB_EXT='dll' ;;
 405 aix* )
 406     LIB_EXT='a' ;;
 407 * )
 408     LIB_EXT='so' ;;
 409 esac
 410
 411 AC_SUBST([LIB_EXT])
 412
 413 AC_ARG_WITH([gl-lib-name],
 414   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 415     [specify GL library name @<:@default=GL@:>@])],
 416   [GL_LIB=$withval],
 417   [GL_LIB=GL])
 418 AC_ARG_WITH([osmesa-lib-name],
 419   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 420     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 421   [OSMESA_LIB=$withval],
 422   [OSMESA_LIB=OSMesa])
 423 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 424 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 425
 426 dnl
 427 dnl Mangled Mesa support
 428 dnl
 429 AC_ARG_ENABLE([mangling],
 430   [AS_HELP_STRING([--enable-mangling],
 431     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 432   [enable_mangling="${enableval}"],
 433   [enable_mangling=no]
 434 )
 435 if test "x${enable_mangling}" = "xyes" ; then
 436   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 437   GL_LIB="Mangled${GL_LIB}"
 438   OSMESA_LIB="Mangled${OSMESA_LIB}"
 439 fi
 440 AC_SUBST([GL_LIB])
 441 AC_SUBST([OSMESA_LIB])
 442
 443 dnl
 444 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 445 dnl
 446 AC_ARG_ENABLE([texture-float],
 447     [AS_HELP_STRING([--enable-texture-float],
 448         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 449     [enable_texture_float="$enableval"],
 450     [enable_texture_float=no]
 451 )
 452 if test "x$enable_texture_float" = xyes; then
 453     AC_MSG_WARN([Floating-point textures enabled.])
 454     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 455     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 456 fi
 457
 458 dnl
 459 dnl Arch/platform-specific settings
 460 dnl
 461 AC_ARG_ENABLE([asm],
 462     [AS_HELP_STRING([--disable-asm],
 463         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 464     [enable_asm="$enableval"],
 465     [enable_asm=yes]
 466 )
 467 asm_arch=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64 | amd64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         gnu*)
 488             asm_arch=x86
 489             ;;
 490         esac
 491         ;;
 492     x86_64|amd64)
 493         case "$host_os" in
 494         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 495             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 496             ;;
 497         esac
 498         ;;
 499     sparc*)
 500         case "$host_os" in
 501         linux*)
 502             asm_arch=sparc
 503             ;;
 504         esac
 505         ;;
 506     esac
 507
 508     case "$asm_arch" in
 509     x86)
 510         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 511         AC_MSG_RESULT([yes, x86])
 512         ;;
 513     x86_64|amd64)
 514         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 515         AC_MSG_RESULT([yes, x86_64])
 516         ;;
 517     sparc)
 518         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 530     [AC_CHECK_LIB([dl], [dlopen],
 531        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 532 AC_SUBST([DLOPEN_LIBS])
 533
 534 dnl Check if that library also has dladdr
 535 save_LIBS="$LIBS"
 536 LIBS="$LIBS $DLOPEN_LIBS"
 537 AC_CHECK_FUNCS([dladdr])
 538 LIBS="$save_LIBS"
 539
 540 case "$host_os" in
 541 darwin*|mingw*)
 542     ;;
 543 *)
 544     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 545                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 546                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 547     AC_SUBST([CLOCK_LIB])
 548     ;;
 549 esac
 550
 551 dnl See if posix_memalign is available
 552 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 553
 554 dnl Check for pthreads
 555 case "$host_os" in
 556 mingw*)
 557     ;;
 558 *)
 559     AX_PTHREAD
 560     ;;
 561 esac
 562 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 563 dnl to -pthread, which causes problems if we need -lpthread to appear in
 564 dnl pkgconfig files.
 565 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 566
 567 dnl SELinux awareness.
 568 AC_ARG_ENABLE([selinux],
 569     [AS_HELP_STRING([--enable-selinux],
 570         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 571     [MESA_SELINUX="$enableval"],
 572     [MESA_SELINUX=no])
 573 if test "x$enable_selinux" = "xyes"; then
 574     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 575         [AC_CHECK_HEADER([selinux/selinux.h],[],
 576                          [AC_MSG_ERROR([SELinux headers not found])])
 577          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 578                       [AC_MSG_ERROR([SELinux library not found])])
 579          SELINUX_LIBS="-lselinux"])
 580     DEFINES="$DEFINES -DMESA_SELINUX"
 581 fi
 582 AC_SUBST([SELINUX_CFLAGS])
 583 AC_SUBST([SELINUX_LIBS])
 584
 585 dnl Options for APIs
 586 AC_ARG_ENABLE([opengl],
 587     [AS_HELP_STRING([--disable-opengl],
 588         [disable support for standard OpenGL API @<:@default=no@:>@])],
 589     [enable_opengl="$enableval"],
 590     [enable_opengl=yes])
 591 AC_ARG_ENABLE([gles1],
 592     [AS_HELP_STRING([--enable-gles1],
 593         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 594     [enable_gles1="$enableval"],
 595     [enable_gles1=no])
 596 AC_ARG_ENABLE([gles2],
 597     [AS_HELP_STRING([--enable-gles2],
 598         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 599     [enable_gles2="$enableval"],
 600     [enable_gles2=no])
 601 AC_ARG_ENABLE([openvg],
 602     [AS_HELP_STRING([--enable-openvg],
 603         [enable support for OpenVG API @<:@default=no@:>@])],
 604     [enable_openvg="$enableval"],
 605     [enable_openvg=no])
 606
 607 AC_ARG_ENABLE([dri],
 608     [AS_HELP_STRING([--enable-dri],
 609         [enable DRI modules @<:@default=enabled@:>@])],
 610     [enable_dri="$enableval"],
 611     [enable_dri=yes])
 612
 613 case "$host_os" in
 614 linux*)
 615     dri3_default=yes
 616     ;;
 617 *)
 618     dri3_default=no
 619     ;;
 620 esac
 621 AC_ARG_ENABLE([dri3],
 622     [AS_HELP_STRING([--enable-dri3],
 623         [enable DRI3 @<:@default=auto@:>@])],
 624     [enable_dri3="$enableval"],
 625     [enable_dri3="$dri3_default"])
 626 AC_ARG_ENABLE([glx],
 627     [AS_HELP_STRING([--enable-glx],
 628         [enable GLX library @<:@default=enabled@:>@])],
 629     [enable_glx="$enableval"],
 630     [enable_glx=yes])
 631 AC_ARG_ENABLE([osmesa],
 632     [AS_HELP_STRING([--enable-osmesa],
 633         [enable OSMesa library @<:@default=disabled@:>@])],
 634     [enable_osmesa="$enableval"],
 635     [enable_osmesa=no])
 636 AC_ARG_ENABLE([gallium-osmesa],
 637     [AS_HELP_STRING([--enable-gallium-osmesa],
 638         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 639     [enable_gallium_osmesa="$enableval"],
 640     [enable_gallium_osmesa=no])
 641 AC_ARG_ENABLE([egl],
 642     [AS_HELP_STRING([--disable-egl],
 643         [disable EGL library @<:@default=enabled@:>@])],
 644     [enable_egl="$enableval"],
 645     [enable_egl=yes])
 646
 647 AC_ARG_ENABLE([xa],
 648     [AS_HELP_STRING([--enable-xa],
 649         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 650     [enable_xa="$enableval"],
 651     [enable_xa=no])
 652 AC_ARG_ENABLE([gbm],
 653    [AS_HELP_STRING([--enable-gbm],
 654          [enable gbm library @<:@default=auto@:>@])],
 655    [enable_gbm="$enableval"],
 656    [enable_gbm=auto])
 657
 658 AC_ARG_ENABLE([xvmc],
 659    [AS_HELP_STRING([--enable-xvmc],
 660          [enable xvmc library @<:@default=auto@:>@])],
 661    [enable_xvmc="$enableval"],
 662    [enable_xvmc=no])
 663 AC_ARG_ENABLE([vdpau],
 664    [AS_HELP_STRING([--enable-vdpau],
 665          [enable vdpau library @<:@default=auto@:>@])],
 666    [enable_vdpau="$enableval"],
 667    [enable_vdpau=auto])
 668 AC_ARG_ENABLE([omx],
 669    [AS_HELP_STRING([--enable-omx],
 670          [enable OpenMAX library @<:@default=no@:>@])],
 671    [enable_omx="$enableval"],
 672    [enable_omx=no])
 673 AC_ARG_ENABLE([opencl],
 674    [AS_HELP_STRING([--enable-opencl],
 675          [enable OpenCL library @<:@default=no@:>@])],
 676    [enable_opencl="$enableval"],
 677    [enable_opencl=no])
 678 AC_ARG_ENABLE([opencl_icd],
 679    [AS_HELP_STRING([--enable-opencl-icd],
 680           [Build an OpenCL ICD library to be loaded by an ICD implementation
 681            @<:@default=no@:>@])],
 682     [enable_opencl_icd="$enableval"],
 683     [enable_opencl_icd=no])
 684 AC_ARG_ENABLE([xlib-glx],
 685     [AS_HELP_STRING([--enable-xlib-glx],
 686         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 687     [enable_xlib_glx="$enableval"],
 688     [enable_xlib_glx=no])
 689 AC_ARG_ENABLE([gallium-egl],
 690     [AS_HELP_STRING([--enable-gallium-egl],
 691         [enable optional EGL state tracker (not required
 692          for EGL support in Gallium with OpenGL and OpenGL ES)
 693          @<:@default=disable@:>@])],
 694     [enable_gallium_egl="$enableval"],
 695     [enable_gallium_egl=no])
 696 AC_ARG_ENABLE([gallium-gbm],
 697     [AS_HELP_STRING([--enable-gallium-gbm],
 698         [enable optional gbm state tracker (not required for
 699          gbm support in Gallium)
 700          @<:@default=auto@:>@])],
 701     [enable_gallium_gbm="$enableval"],
 702     [enable_gallium_gbm=auto])
 703
 704 AC_ARG_ENABLE([r600-llvm-compiler],
 705     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 706         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 707     [enable_r600_llvm="$enableval"],
 708     [enable_r600_llvm=no])
 709
 710 AC_ARG_ENABLE([gallium-tests],
 711     [AS_HELP_STRING([--enable-gallium-tests],
 712         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 713     [enable_gallium_tests="$enableval"],
 714     [enable_gallium_tests=no])
 715
 716 # Option for Gallium drivers
 717
 718 # Keep this in sync with the --with-gallium-drivers help string default value
 719 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 720
 721 AC_ARG_WITH([gallium-drivers],
 722     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 723         [comma delimited Gallium drivers list, e.g.
 724         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 725         @<:@default=r300,r600,svga,swrast@:>@])],
 726     [with_gallium_drivers="$withval"],
 727     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 728
 729 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 730 # here so that the script doesn't choke on an unknown driver name later.
 731 case "$with_gallium_drivers" in
 732     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 733     no) with_gallium_drivers='' ;;
 734 esac
 735
 736 if test "x$enable_opengl" = xno -a \
 737         "x$enable_gles1" = xno -a \
 738         "x$enable_gles2" = xno -a \
 739         "x$enable_openvg" = xno -a \
 740         "x$enable_xa" = xno -a \
 741         "x$enable_xvmc" = xno -a \
 742         "x$enable_vdpau" = xno -a \
 743         "x$enable_omx" = xno -a \
 744         "x$enable_opencl" = xno; then
 745     AC_MSG_ERROR([at least one API should be enabled])
 746 fi
 747
 748 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 749 if test "x$enable_opengl" = xno -a \
 750         "x$enable_gles1" = xyes; then
 751     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 752 fi
 753
 754 if test "x$enable_opengl" = xno -a \
 755         "x$enable_gles2" = xyes; then
 756     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 757 fi
 758
 759 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 760 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 761 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 762 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 763                                         "x$enable_gles1" = xyes -o \
 764                                         "x$enable_gles2" = xyes)
 765
 766 if test "x$enable_glx" = xno; then
 767     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 768     enable_xlib_glx=no
 769 fi
 770
 771 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 772     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 773 fi
 774
 775 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 776     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 777 fi
 778
 779 # Disable GLX if OpenGL is not enabled
 780 if test "x$enable_glx$enable_opengl" = xyesno; then
 781     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 782     enable_glx=no
 783 fi
 784
 785 # Disable GLX if DRI and Xlib-GLX are not enabled
 786 if test "x$enable_glx" = xyes -a \
 787         "x$enable_dri" = xno -a \
 788         "x$enable_xlib_glx" = xno; then
 789     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 790     enable_glx=no
 791 fi
 792
 793 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 794                                   "x$enable_dri" = xyes)
 795
 796 # Select which platform-dependent DRI code gets built
 797 case "$host_os" in
 798 darwin*)
 799     dri_platform='apple' ;;
 800 gnu*|mingw*|cygwin*)
 801     dri_platform='none' ;;
 802 *)
 803     dri_platform='drm' ;;
 804 esac
 805
 806 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 807 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 808 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 809 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 810 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 811
 812 AC_ARG_ENABLE([shared-glapi],
 813     [AS_HELP_STRING([--enable-shared-glapi],
 814         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 815     [enable_shared_glapi="$enableval"],
 816     [enable_shared_glapi=yes])
 817
 818 case "x$enable_opengl$enable_gles1$enable_gles2" in
 819 x*yes*yes*)
 820     if test "x$enable_shared_glapi" = xno; then
 821         AC_MSG_ERROR([shared GLAPI required when building two or more of
 822                       the following APIs - opengl, gles1 gles2])
 823     fi
 824     ;;
 825 esac
 826
 827 # Building Xlib-GLX requires shared glapi to be disabled.
 828 if test "x$enable_xlib_glx" = xyes; then
 829     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 830     enable_shared_glapi=no
 831 fi
 832
 833 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 834
 835 dnl
 836 dnl Driver specific build directories
 837 dnl
 838 GALLIUM_TARGET_DIRS=""
 839 GALLIUM_WINSYS_DIRS="sw"
 840 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 841 GALLIUM_STATE_TRACKERS_DIRS=""
 842
 843 case "x$enable_glx$enable_xlib_glx" in
 844 xyesyes)
 845     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 846     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 847     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 848     NEED_WINSYS_XLIB="yes"
 849     ;;
 850 esac
 851
 852 if test "x$enable_dri" = xyes; then
 853     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 854     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 855     enable_gallium_loader=yes
 856 fi
 857
 858 if test "x$enable_gallium_osmesa" = xyes; then
 859     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 860         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 861     fi
 862     if test "x$enable_osmesa" = xyes; then
 863         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 864     fi
 865     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 866     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 867 fi
 868
 869 AC_SUBST([MESA_LLVM])
 870
 871 # Check for libdrm
 872 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 873                   [have_libdrm=yes], [have_libdrm=no])
 874 if test "x$have_libdrm" = xyes; then
 875         DEFINES="$DEFINES -DHAVE_LIBDRM"
 876 fi
 877
 878 case "$host_os" in
 879 linux*)
 880     need_pci_id=yes ;;
 881 *)
 882     need_pci_id=no ;;
 883 esac
 884
 885 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 886                   have_libudev=yes, have_libudev=no)
 887
 888 AC_ARG_ENABLE([sysfs],
 889     [AS_HELP_STRING([--enable-sysfs],
 890         [enable /sys PCI identification @<:@default=disabled@:>@])],
 891     [have_sysfs="$enableval"],
 892     [have_sysfs=no]
 893 )
 894
 895 if test "x$enable_dri" = xyes; then
 896     if test "$enable_static" = yes; then
 897         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 898     fi
 899
 900     # not a hard requirement as swrast does not depend on it
 901     if test "x$have_libdrm" = xyes; then
 902         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 903     fi
 904 fi
 905
 906 AC_ARG_ENABLE([driglx-direct],
 907     [AS_HELP_STRING([--disable-driglx-direct],
 908         [disable direct rendering in GLX and EGL for DRI \
 909             @<:@default=auto@:>@])],
 910     [driglx_direct="$enableval"],
 911     [driglx_direct="yes"])
 912
 913 dnl
 914 dnl libGL configuration per driver
 915 dnl
 916 case "x$enable_glx$enable_xlib_glx" in
 917 xyesyes)
 918     # Xlib-based GLX
 919     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 920     GL_PC_REQ_PRIV="x11 xext"
 921     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 922     GL_LIB_DEPS="$XLIBGL_LIBS"
 923     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 924     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 925     ;;
 926 xyesno)
 927     # DRI-based GLX
 928     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 929
 930     # find the DRI deps for libGL
 931     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 932
 933     if test x"$driglx_direct" = xyes; then
 934         if test x"$dri_platform" = xdrm ; then
 935             DEFINES="$DEFINES -DGLX_USE_DRM"
 936             if test "x$have_libdrm" != xyes; then
 937                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 938             fi
 939
 940             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 941             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 942             if test x"$enable_dri3" = xyes; then
 943                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 944                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 945             fi
 946
 947             if test x"$enable_dri" = xyes; then
 948                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 949             fi
 950
 951             if test x"$enable_dri3" = xyes; then
 952                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 953             fi
 954         fi
 955         if test x"$dri_platform" = xapple ; then
 956             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 957         fi
 958     fi
 959
 960     # add xf86vidmode if available
 961     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 962     if test "$HAVE_XF86VIDMODE" = yes ; then
 963         dri_modules="$dri_modules xxf86vm"
 964     fi
 965
 966     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 967     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 968     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 969     GL_LIB_DEPS="$DRIGL_LIBS"
 970
 971     # need DRM libs, $PTHREAD_LIBS, etc.
 972     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 973     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 974     ;;
 975 esac
 976
 977 have_pci_id=no
 978 if test "$have_libudev" = yes; then
 979     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 980     have_pci_id=yes
 981 fi
 982
 983 if test "$have_sysfs" = yes; then
 984     DEFINES="$DEFINES -DHAVE_SYSFS"
 985     have_pci_id=yes
 986 fi
 987
 988 # This is outside the case (above) so that it is invoked even for non-GLX
 989 # builds.
 990 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 991
 992 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 993 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 994 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 995 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 996
 997 AC_SUBST([X11_INCLUDES])
 998 AC_SUBST([GL_LIB_DEPS])
 999 AC_SUBST([GL_PC_REQ_PRIV])
1000 AC_SUBST([GL_PC_LIB_PRIV])
1001 AC_SUBST([GL_PC_CFLAGS])
1002 AC_SUBST([DRI_PC_REQ_PRIV])
1003 AC_SUBST([GLESv1_CM_LIB_DEPS])
1004 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1005 AC_SUBST([GLESv2_LIB_DEPS])
1006 AC_SUBST([GLESv2_PC_LIB_PRIV])
1007
1008 AC_SUBST([HAVE_XF86VIDMODE])
1009
1010 dnl
1011 dnl More GLX setup
1012 dnl
1013 case "x$enable_glx$enable_xlib_glx" in
1014 xyesyes)
1015     DEFINES="$DEFINES -DUSE_XSHM"
1016     ;;
1017 xyesno)
1018     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1019     if test "x$driglx_direct" = xyes; then
1020         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1021     fi
1022     ;;
1023 esac
1024
1025 dnl
1026 dnl TLS detection
1027 dnl
1028
1029 AC_ARG_ENABLE([glx-tls],
1030     [AS_HELP_STRING([--enable-glx-tls],
1031         [enable TLS support in GLX @<:@default=disabled@:>@])],
1032     [GLX_USE_TLS="$enableval"],
1033     [GLX_USE_TLS=no])
1034 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1035
1036 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1037       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1038
1039 dnl
1040 dnl More DRI setup
1041 dnl
1042 dnl Directory for DRI drivers
1043 AC_ARG_WITH([dri-driverdir],
1044     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1045         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1046     [DRI_DRIVER_INSTALL_DIR="$withval"],
1047     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1048 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1049 dnl Extra search path for DRI drivers
1050 AC_ARG_WITH([dri-searchpath],
1051     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1052         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1053     [DRI_DRIVER_SEARCH_DIR="$withval"],
1054     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1055 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1056 dnl Which drivers to build - default is chosen by platform
1057 AC_ARG_WITH([dri-drivers],
1058     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1059         [comma delimited classic DRI drivers list, e.g.
1060         "swrast,i965,radeon" @<:@default=auto@:>@])],
1061     [with_dri_drivers="$withval"],
1062     [with_dri_drivers=auto])
1063
1064 if test "x$with_dri_drivers" = xauto; then
1065     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1066         with_dri_drivers="yes"
1067     else
1068         with_dri_drivers="no"
1069     fi
1070 fi
1071 if test "x$with_dri_drivers" = xno; then
1072     with_dri_drivers=''
1073 fi
1074
1075 dnl If $with_dri_drivers is yes, drivers will be added through
1076 dnl platform checks. Set DEFINES and LIB_DEPS
1077 if test "x$enable_dri" = xyes; then
1078     # Platform specific settings and drivers to build
1079     case "$host_os" in
1080     linux*)
1081         DEFINES="$DEFINES -DHAVE_ALIAS"
1082         if test "x$enable_dri3" = xyes; then
1083             DEFINES="$DEFINES -DHAVE_DRI3"
1084         fi
1085
1086         if test "x$have_pci_id" != xyes; then
1087             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1088         fi
1089
1090         case "$host_cpu" in
1091         powerpc* | sparc*)
1092             # Build only the drivers for cards that exist on PowerPC/sparc
1093             if test "x$with_dri_drivers" = "xyes"; then
1094                 with_dri_drivers="r200 radeon swrast"
1095             fi
1096             ;;
1097         esac
1098         ;;
1099     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1100         DEFINES="$DEFINES -DHAVE_PTHREAD"
1101         DEFINES="$DEFINES -DHAVE_ALIAS"
1102         ;;
1103     gnu*)
1104         DEFINES="$DEFINES -DHAVE_ALIAS"
1105         ;;
1106     cygwin*)
1107         if test "x$with_dri_drivers" = "xyes"; then
1108             with_dri_drivers="swrast"
1109         fi
1110         ;;
1111     darwin*)
1112         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1113         if test "x$with_dri_drivers" = "xyes"; then
1114             with_dri_drivers="swrast"
1115         fi
1116         ;;
1117     esac
1118
1119     # default drivers
1120     if test "x$with_dri_drivers" = "xyes"; then
1121         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1122     fi
1123
1124     # Check for expat
1125     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1126     if test "x$have_expat" = "xyes"; then
1127        PKG_CHECK_MODULES([EXPAT], [expat], [],
1128                          AC_MSG_ERROR([Expat required for DRI.]))
1129     else
1130        # expat version 2.0 and earlier do not provide expat.pc
1131        EXPAT_LIBS=-lexpat
1132     fi
1133
1134     DRICOMMON_NEED_LIBDRM=no
1135     # If we are building any DRI driver other than swrast.
1136     if test -n "$with_dri_drivers"; then
1137         if test "x$with_dri_drivers" != xswrast; then
1138             # ... libdrm is required
1139             if test "x$have_libdrm" != xyes; then
1140                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1141             fi
1142             DRICOMMON_NEED_LIBDRM=yes
1143         fi
1144     fi
1145
1146     # If we're building any gallium DRI driver other than swrast
1147     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1148         if test "x$with_gallium_drivers" != xswrast; then
1149             # ... build a libdrm aware dricommon
1150             DRICOMMON_NEED_LIBDRM=yes
1151         fi
1152     fi
1153
1154     # put all the necessary libs together
1155     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1156 fi
1157
1158 AC_SUBST([DRI_LIB_DEPS])
1159
1160 DRI_DIRS=''
1161 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1162 if test -n "$with_dri_drivers"; then
1163     if test "x$enable_opengl" != xyes; then
1164         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1165     fi
1166
1167     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1168     for driver in $dri_drivers; do
1169         DRI_DIRS="$DRI_DIRS $driver"
1170         case "x$driver" in
1171         xi915)
1172             HAVE_I915_DRI=yes;
1173             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1174             ;;
1175         xi965)
1176             HAVE_I965_DRI=yes;
1177             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1178             ;;
1179         xnouveau)
1180             HAVE_NOUVEAU_DRI=yes;
1181             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1182             ;;
1183         xradeon)
1184             HAVE_RADEON_DRI=yes;
1185             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1186             ;;
1187         xr200)
1188             HAVE_R200_DRI=yes;
1189             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1190             ;;
1191         xswrast)
1192             HAVE_SWRAST_DRI=yes;
1193             ;;
1194         *)
1195             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1196             ;;
1197         esac
1198     done
1199     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1200 fi
1201
1202 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1203 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1204                                   "x$enable_osmesa" = xyes -o \
1205                                   -n "$DRI_DIRS")
1206
1207 dnl
1208 dnl OSMesa configuration
1209 dnl
1210
1211 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1212 AC_ARG_WITH([osmesa-bits],
1213     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1214         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1215     [osmesa_bits="$withval"],
1216     [osmesa_bits=8])
1217 if test "x$osmesa_bits" != x8; then
1218     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1219         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1220         osmesa_bits=8
1221     fi
1222 fi
1223 case "x$osmesa_bits" in
1224 x8)
1225     OSMESA_LIB="${OSMESA_LIB}"
1226     ;;
1227 x16|x32)
1228     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1229     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1230     ;;
1231 *)
1232     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1233     ;;
1234 esac
1235
1236 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1237     # only link libraries with osmesa if shared
1238     if test "$enable_static" = no; then
1239         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1240     else
1241         OSMESA_LIB_DEPS=""
1242     fi
1243     OSMESA_MESA_DEPS=""
1244     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1245 fi
1246
1247 AC_SUBST([OSMESA_LIB_DEPS])
1248 AC_SUBST([OSMESA_MESA_DEPS])
1249 AC_SUBST([OSMESA_PC_REQ])
1250 AC_SUBST([OSMESA_PC_LIB_PRIV])
1251
1252 dnl
1253 dnl gbm configuration
1254 dnl
1255 if test "x$enable_gbm" = xauto; then
1256     case "$with_egl_platforms" in
1257         *drm*)
1258             enable_gbm=yes ;;
1259          *)
1260             enable_gbm=no ;;
1261     esac
1262 fi
1263 if test "x$enable_gbm" = xyes; then
1264     if test "x$need_pci_id$have_pci_id" = xyesno; then
1265         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1266     fi
1267
1268     if test "x$enable_dri" = xyes; then
1269         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1270         if test "x$enable_shared_glapi" = xno; then
1271             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1272         fi
1273     else
1274         # Strictly speaking libgbm does not require --enable-dri, although
1275         # both of its backends do. Thus one can build libgbm without any
1276         # backends if --disable-dri is set.
1277         # To avoid unnecessary complexity of checking if at least one backend
1278         # is available when building, just mandate --enable-dri.
1279         AC_MSG_ERROR([gbm requires --enable-dri])
1280     fi
1281 fi
1282 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1283 if test "x$need_pci_id$have_libudev" = xyesyes; then
1284     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1285 else
1286     GBM_PC_REQ_PRIV=""
1287 fi
1288 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1289 AC_SUBST([GBM_PC_REQ_PRIV])
1290 AC_SUBST([GBM_PC_LIB_PRIV])
1291
1292 dnl
1293 dnl EGL configuration
1294 dnl
1295 EGL_CLIENT_APIS=""
1296
1297 if test "x$enable_egl" = xyes; then
1298     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1299
1300     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1301
1302     if test "$enable_static" != yes; then
1303         if test "x$enable_dri" = xyes; then
1304             HAVE_EGL_DRIVER_DRI2=1
1305         fi
1306
1307     fi
1308 fi
1309 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1310 AC_SUBST([EGL_LIB_DEPS])
1311
1312 dnl
1313 dnl EGL Gallium configuration
1314 dnl
1315 if test "x$enable_gallium_egl" = xyes; then
1316     if test -z "$with_gallium_drivers"; then
1317         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1318     fi
1319     if test "x$enable_egl" = xno; then
1320         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1321     fi
1322     if test "x$have_libdrm" != xyes; then
1323         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1324     fi
1325
1326     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1327     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1328 #    enable_gallium_loader=yes
1329 fi
1330 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1331
1332 dnl
1333 dnl gbm Gallium configuration
1334 dnl
1335 if test "x$enable_gallium_gbm" = xauto; then
1336     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1337         yesyesyes*drm*)
1338             enable_gallium_gbm=yes ;;
1339          *)
1340             enable_gallium_gbm=no ;;
1341     esac
1342 fi
1343 if test "x$enable_gallium_gbm" = xyes; then
1344     if test -z "$with_gallium_drivers"; then
1345         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1346     fi
1347     if test "x$enable_gbm" = xno; then
1348         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1349     fi
1350     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1351     if test "x$enable_dri" = xno; then
1352         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1353     fi
1354
1355     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1356     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1357     enable_gallium_loader=yes
1358 fi
1359 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1360
1361 dnl
1362 dnl XA configuration
1363 dnl
1364 if test "x$enable_xa" = xyes; then
1365     if test "x$with_gallium_drivers" = xswrast; then
1366        AC_MSG_ERROR([
1367           Building xa requires at least one non swrast gallium driver.
1368           If you are looking to use libxatracker.so with the VMware driver,
1369           make sure to include svga in the gallium drivers list, apart from
1370           enabling XA.
1371           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1372     fi
1373     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1374     enable_gallium_loader=yes
1375 fi
1376 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1377
1378 dnl
1379 dnl OpenVG configuration
1380 dnl
1381 VG_LIB_DEPS=""
1382
1383 if test "x$enable_openvg" = xyes; then
1384     if test "x$enable_egl" = xno; then
1385         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1386     fi
1387     if test -z "$with_gallium_drivers"; then
1388         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1389     fi
1390     if test "x$enable_gallium_egl" = xno; then
1391         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1392     fi
1393
1394     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1395     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1396     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1397     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1398     AC_SUBST([VG_PC_LIB_PRIV])
1399 fi
1400 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1401
1402 dnl
1403 dnl Gallium G3DVL configuration
1404 dnl
1405 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1406     if test "x$enable_xvmc" = xauto; then
1407         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1408     fi
1409
1410     if test "x$enable_vdpau" = xauto; then
1411         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1412     fi
1413
1414     if test "x$enable_omx" = xauto; then
1415         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1416     fi
1417 fi
1418
1419 if test "x$enable_xvmc" = xyes; then
1420     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1421     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1422     enable_gallium_loader=yes
1423 fi
1424 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1425
1426 if test "x$enable_vdpau" = xyes; then
1427     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1428                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1429     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1430     enable_gallium_loader=yes
1431 fi
1432 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1433
1434 if test "x$enable_omx" = xyes; then
1435     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1436     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1437     enable_gallium_loader=yes
1438 fi
1439 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1440
1441 dnl
1442 dnl OpenCL configuration
1443 dnl
1444
1445 AC_ARG_WITH([libclc-path],
1446    [AS_HELP_STRING([--with-libclc-path],
1447          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1448    [LIBCLC_PATH="$withval"],
1449    [LIBCLC_PATH=''])
1450
1451 if test -n "$LIBCLC_PATH"; then
1452    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1453                   Please review the updated build instructions for clover:
1454                   http://dri.freedesktop.org/wiki/GalliumCompute])
1455 fi
1456
1457
1458 AC_ARG_WITH([clang-libdir],
1459    [AS_HELP_STRING([--with-clang-libdir],
1460          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1461    [CLANG_LIBDIR="$withval"],
1462    [CLANG_LIBDIR=''])
1463
1464 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1465
1466 if test "x$enable_opencl" = xyes; then
1467     if test -z "$with_gallium_drivers"; then
1468         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1469     fi
1470
1471     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1472         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1473     fi
1474
1475     if test "x$have_libclc" = xno; then
1476         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1477                     Make sure the directory containing libclc.pc is specified in your
1478                     PKG_CONFIG_PATH environment variable.
1479                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1480     else
1481         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1482         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1483         AC_SUBST([LIBCLC_INCLUDEDIR])
1484         AC_SUBST([LIBCLC_LIBEXECDIR])
1485     fi
1486
1487     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1488     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1489     enable_gallium_loader=yes
1490
1491     if test "x$enable_opencl_icd" = xyes; then
1492         OPENCL_LIBNAME="MesaOpenCL"
1493     else
1494         OPENCL_LIBNAME="OpenCL"
1495     fi
1496 fi
1497 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1498 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1499 AC_SUBST([OPENCL_LIBNAME])
1500
1501 dnl
1502 dnl Gallium configuration
1503 dnl
1504 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1505
1506 AC_SUBST([LLVM_BINDIR])
1507 AC_SUBST([LLVM_CFLAGS])
1508 AC_SUBST([LLVM_CPPFLAGS])
1509 AC_SUBST([LLVM_CXXFLAGS])
1510 AC_SUBST([LLVM_LIBDIR])
1511 AC_SUBST([LLVM_LIBS])
1512 AC_SUBST([LLVM_LDFLAGS])
1513 AC_SUBST([LLVM_INCLUDEDIR])
1514 AC_SUBST([LLVM_VERSION])
1515 AC_SUBST([CLANG_RESOURCE_DIR])
1516
1517 case "x$enable_opengl$enable_gles1$enable_gles2" in
1518 x*yes*)
1519     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1520     ;;
1521 esac
1522
1523 AC_SUBST([VG_LIB_DEPS])
1524 AC_SUBST([EGL_CLIENT_APIS])
1525
1526 dnl
1527 dnl EGL Platforms configuration
1528 dnl
1529 AC_ARG_WITH([egl-platforms],
1530     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1531         [comma delimited native platforms libEGL supports, e.g.
1532         "x11,drm" @<:@default=auto@:>@])],
1533     [with_egl_platforms="$withval"],
1534     [if test "x$enable_egl" = xyes; then
1535         with_egl_platforms="x11"
1536     else
1537         with_egl_platforms=""
1538     fi])
1539
1540 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1541     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1542 fi
1543
1544 # Do per-EGL platform setups and checks
1545 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1546 for plat in $egl_platforms; do
1547         case "$plat" in
1548         wayland)
1549                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1550                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1551
1552                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1553                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1554                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1555                 ;;
1556
1557         x11)
1558                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1559                 ;;
1560
1561         drm)
1562                 test "x$enable_gbm" = "xno" &&
1563                         AC_MSG_ERROR([EGL platform drm needs gbm])
1564                 test "x$have_libdrm" != xyes &&
1565                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1566                 ;;
1567
1568         android|fbdev|gdi|null)
1569                 ;;
1570
1571         *)
1572                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1573                 ;;
1574         esac
1575
1576         case "$plat$need_pci_id$have_pci_id" in
1577                 waylandyesno|drmyesno)
1578                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1579         esac
1580 done
1581
1582 # libEGL wants to default to the first platform specified in
1583 # ./configure.  parse that here.
1584 if test "x$egl_platforms" != "x"; then
1585     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1586     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1587 else
1588     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1589 fi
1590
1591 if echo "$egl_platforms" | grep -q 'x11'; then
1592     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1593     NEED_WINSYS_XLIB=yes
1594 fi
1595 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1596 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1597 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1598 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1599 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1600
1601 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1602
1603 AC_SUBST([EGL_NATIVE_PLATFORM])
1604 AC_SUBST([EGL_CFLAGS])
1605
1606 # If we don't have the X11 platform, set this define so we don't try to include
1607 # the X11 headers.
1608 if ! echo "$egl_platforms" | grep -q 'x11'; then
1609     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1610     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1611 fi
1612
1613 AC_ARG_WITH([egl-driver-dir],
1614     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1615                     [directory for EGL drivers @<:@default=${libdir}/egl@:>@])],
1616     [EGL_DRIVER_INSTALL_DIR="$withval"],
1617     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1618 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1619
1620 AC_ARG_WITH([max-width],
1621     [AS_HELP_STRING([--with-max-width=N],
1622                     [Maximum framebuffer width (4096)])],
1623     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1624      AS_IF([test "${withval}" -gt "4096"],
1625            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1626 )
1627 AC_ARG_WITH([max-height],
1628     [AS_HELP_STRING([--with-max-height=N],
1629                     [Maximum framebuffer height (4096)])],
1630     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1631      AS_IF([test "${withval}" -gt "4096"],
1632            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1633 )
1634
1635 dnl
1636 dnl Gallium LLVM
1637 dnl
1638 AC_ARG_ENABLE([gallium-llvm],
1639     [AS_HELP_STRING([--enable-gallium-llvm],
1640         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1641     [enable_gallium_llvm="$enableval"],
1642     [enable_gallium_llvm=auto])
1643
1644 AC_ARG_ENABLE([llvm-shared-libs],
1645     [AS_HELP_STRING([--enable-llvm-shared-libs],
1646         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1647     [enable_llvm_shared_libs="$enableval"],
1648     [enable_llvm_shared_libs=yes])
1649
1650 AC_ARG_WITH([llvm-prefix],
1651     [AS_HELP_STRING([--with-llvm-prefix],
1652         [Prefix for LLVM installations in non-standard locations])],
1653     [llvm_prefix="$withval"],
1654     [llvm_prefix=''])
1655
1656
1657 # Call this inside ` ` to get the return value.
1658 # $1 is the llvm-config command with arguments.
1659 strip_unwanted_llvm_flags() {
1660     # Use \> (marks the end of the word)
1661     echo `$1` | sed \
1662         -e 's/-DNDEBUG\>//g' \
1663         -e 's/-pedantic\>//g' \
1664         -e 's/-Wcovered-switch-default\>//g' \
1665         -e 's/-O.\>//g' \
1666         -e 's/-g\>//g' \
1667         -e 's/-Wall\>//g' \
1668         -e 's/-Wcast-qual\>//g' \
1669         -e 's/-Woverloaded-virtual\>//g' \
1670         -e 's/-fcolor-diagnostics\>//g' \
1671         -e 's/-fdata-sections\>//g' \
1672         -e 's/-ffunction-sections\>//g' \
1673         -e 's/-fno-exceptions\>//g' \
1674         -e 's/-fomit-frame-pointer\>//g' \
1675         -e 's/-fvisibility-inlines-hidden\>//g' \
1676         -e 's/-fPIC\>//g' \
1677         -e 's/-fstack-protector-strong\>//g'
1678 }
1679
1680
1681 if test -z "$with_gallium_drivers"; then
1682     enable_gallium_llvm=no
1683 fi
1684 if test "x$enable_gallium_llvm" = xauto; then
1685     case "$host_cpu" in
1686     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1687     esac
1688 fi
1689 if test "x$enable_gallium_llvm" = xyes; then
1690     if test -n "$llvm_prefix"; then
1691         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1692     else
1693         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1694     fi
1695
1696     if test "x$LLVM_CONFIG" != xno; then
1697         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1698         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1699         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1700         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1701         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1702         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1703         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1704         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1705
1706         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1707             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1708         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1709             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1710
1711         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1712         dnl llvm-config.h
1713         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1714             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1715             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1716
1717         if test -n "${LLVM_VERSION_MAJOR}"; then
1718             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1719         else
1720             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1721         fi
1722
1723         LLVM_REQUIRED_VERSION_MAJOR="3"
1724         LLVM_REQUIRED_VERSION_MINOR="1"
1725         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1726             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1727         fi
1728
1729         LLVM_COMPONENTS="engine bitwriter"
1730         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1731             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1732         fi
1733
1734         if test "x$enable_opencl" = xyes; then
1735             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1736             # LLVM 3.3 >= 177971 requires IRReader
1737             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1738                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1739             fi
1740             # LLVM 3.4 requires Option
1741             if $LLVM_CONFIG --components | grep -qw 'option'; then
1742                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1743             fi
1744             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1745             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1746                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1747             fi
1748             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1749                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1750             fi
1751         fi
1752         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1753         MESA_LLVM=1
1754
1755         dnl Check for Clang internal headers
1756         if test "x$enable_opencl" = xyes; then
1757             if test -z "$CLANG_LIBDIR"; then
1758                 CLANG_LIBDIR=${LLVM_LIBDIR}
1759             fi
1760             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1761             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1762                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1763         fi
1764     else
1765         MESA_LLVM=0
1766         LLVM_VERSION_INT=0
1767     fi
1768 else
1769     MESA_LLVM=0
1770     LLVM_VERSION_INT=0
1771
1772     if test "x$enable_opencl" = xyes; then
1773         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1774     fi
1775 fi
1776
1777 dnl Directory for XVMC libs
1778 AC_ARG_WITH([xvmc-libdir],
1779     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1780         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1781     [XVMC_LIB_INSTALL_DIR="$withval"],
1782     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1783 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1784
1785 dnl
1786 dnl Gallium Tests
1787 dnl
1788 if test "x$enable_gallium_tests" = xyes; then
1789     enable_gallium_loader=yes
1790 fi
1791 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1792
1793 if test "x$enable_gallium_loader" = xyes; then
1794     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1795 fi
1796 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1797
1798 dnl Directory for VDPAU libs
1799 AC_ARG_WITH([vdpau-libdir],
1800     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1801         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1802     [VDPAU_LIB_INSTALL_DIR="$withval"],
1803     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1804 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1805
1806 OMX_LIB_INSTALL_DIR_DEFAULT=''
1807 if test "x$enable_omx" = xyes; then
1808     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1809 fi
1810
1811 AC_ARG_WITH([omx-libdir],
1812     [AS_HELP_STRING([--with-omx-libdir=DIR],
1813         [directory for the OMX libraries])],
1814     [OMX_LIB_INSTALL_DIR="$withval"],
1815     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1816 AC_SUBST([OMX_LIB_INSTALL_DIR])
1817
1818 dnl Directory for OpenCL libs
1819 AC_ARG_WITH([opencl-libdir],
1820     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1821         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1822     [OPENCL_LIB_INSTALL_DIR="$withval"],
1823     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1824 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1825
1826 dnl
1827 dnl Gallium helper functions
1828 dnl
1829 gallium_check_st() {
1830     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1831          if test "x$have_libdrm" != xyes; then
1832             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1833          fi
1834          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1835     fi
1836     if test "x$enable_dri" = xyes && test -n "$2"; then
1837          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1838     fi
1839     if test "x$enable_xa" = xyes && test -n "$3"; then
1840          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1841     fi
1842     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1843          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1844     fi
1845     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1846          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1847     fi
1848     if test "x$enable_omx" = xyes && test "x$6" != x; then
1849          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1850     fi
1851 }
1852
1853 gallium_require_llvm() {
1854     if test "x$MESA_LLVM" = x0; then
1855         case "$host" in *gnux32) return;; esac
1856         case "$host_cpu" in
1857         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1858         esac
1859     fi
1860 }
1861
1862 gallium_require_drm_loader() {
1863     if test "x$enable_gallium_loader" = xyes; then
1864         if test "x$need_pci_id$have_pci_id" = xyesno; then
1865             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1866         fi
1867         if test "x$have_libdrm" != xyes; then
1868             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1869         fi
1870         enable_gallium_drm_loader=yes
1871     fi
1872 }
1873
1874 require_egl_drm() {
1875     case "$with_egl_platforms" in
1876         *drm*)
1877             ;;
1878          *)
1879             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1880             ;;
1881     esac
1882     if test "x$enable_gbm" != xyes; then
1883             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1884     fi
1885 }
1886
1887 radeon_llvm_check() {
1888     if test "x$enable_gallium_llvm" != "xyes"; then
1889         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1890     fi
1891     LLVM_REQUIRED_VERSION_MAJOR="3"
1892     LLVM_REQUIRED_VERSION_MINOR="4"
1893     LLVM_REQUIRED_VERSION_PATCH="2"
1894     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1895         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1896     fi
1897     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1898         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1899                       sources with the --enable-experimental-targets=R600
1900                       configure flag])
1901     fi
1902     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1903     NEED_RADEON_LLVM=yes
1904     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1905                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1906 }
1907
1908 dnl Gallium drivers
1909 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1910         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1911     NEED_NONNULL_WINSYS=yes
1912 fi
1913 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1914
1915 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1916 if test -n "$with_gallium_drivers"; then
1917     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1918     for driver in $gallium_drivers; do
1919         case "x$driver" in
1920         xsvga)
1921             HAVE_GALLIUM_SVGA=yes
1922             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1923             gallium_require_drm_loader
1924             gallium_check_st "svga/drm" "dri/vmwgfx" "xa/vmwgfx"
1925             ;;
1926         xi915)
1927             HAVE_GALLIUM_I915=yes
1928             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1929             gallium_require_drm_loader
1930             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1931             gallium_check_st "i915/drm" "dri/i915" "xa/i915"
1932             ;;
1933         xilo)
1934             HAVE_GALLIUM_ILO=yes
1935             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1936             gallium_require_drm_loader
1937             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1938             gallium_check_st "intel/drm" "dri/ilo" "xa/ilo"
1939             ;;
1940         xr300)
1941             HAVE_GALLIUM_R300=yes
1942             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1943             gallium_require_drm_loader
1944             gallium_require_llvm "Gallium R300"
1945             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1946             gallium_check_st "radeon/drm" "dri/r300"
1947             ;;
1948         xr600)
1949             HAVE_GALLIUM_R600=yes
1950             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1951             gallium_require_drm_loader
1952             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1953             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1954                 radeon_llvm_check "r600g"
1955                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1956             fi
1957             if test "x$enable_r600_llvm" = xyes; then
1958                 USE_R600_LLVM_COMPILER=yes;
1959             fi
1960             if test "x$enable_opencl" = xyes; then
1961                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1962             fi
1963             gallium_check_st "radeon/drm" "dri/r600" "" "xvmc/r600" "vdpau/r600" "omx/r600"
1964             ;;
1965         xradeonsi)
1966             HAVE_GALLIUM_RADEONSI=yes
1967             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1968             gallium_require_drm_loader
1969             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1970             radeon_llvm_check "radeonsi"
1971             require_egl_drm "radeonsi"
1972             gallium_check_st "radeon/drm" "dri/radeonsi" "" "" "vdpau/radeonsi" "omx/radeonsi"
1973             ;;
1974         xnouveau)
1975             HAVE_GALLIUM_NOUVEAU=yes
1976             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1977             gallium_require_drm_loader
1978             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1979             gallium_check_st "nouveau/drm" "dri/nouveau" "xa/nouveau" "xvmc/nouveau" "vdpau/nouveau" "omx/nouveau"
1980             ;;
1981         xfreedreno)
1982             HAVE_GALLIUM_FREEDRENO=yes
1983             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1984             gallium_require_drm_loader
1985             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1986             gallium_check_st "freedreno/drm" "dri/freedreno" "xa/freedreno" "" ""
1987             ;;
1988         xswrast)
1989             HAVE_GALLIUM_SOFTPIPE=yes
1990             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1991             if test "x$MESA_LLVM" = x1; then
1992                 HAVE_GALLIUM_LLVMPIPE=yes
1993                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1994             fi
1995
1996             if test "x$enable_dri" = xyes; then
1997                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/swrast"
1998             fi
1999
2000             if test "x$have_libdrm" = xyes; then
2001                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/kms-swrast"
2002             fi
2003             ;;
2004         xvc4)
2005             HAVE_GALLIUM_VC4=yes
2006             gallium_require_drm_loader
2007             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS vc4"
2008             gallium_check_st "vc4/drm" "dri-vc4" "" "" ""
2009
2010             case "$host_cpu" in
2011                 i?86 | x86_64 | amd64)
2012                 USE_VC4_SIMULATOR=yes
2013                 ;;
2014             esac
2015             ;;
2016         *)
2017             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2018             ;;
2019         esac
2020     done
2021 fi
2022
2023 dnl Set LLVM_LIBS - This is done after the driver configuration so
2024 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2025 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2026 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2027 dnl this was causing the same libraries to be appear multiple times
2028 dnl in LLVM_LIBS.
2029
2030 if test "x$MESA_LLVM" != x0; then
2031
2032     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2033
2034     if test "x$enable_llvm_shared_libs" = xyes; then
2035         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2036         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2037         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2038
2039         if test "x$llvm_have_one_so" = xyes; then
2040             dnl LLVM was built using auto*, so there is only one shared object.
2041             LLVM_LIBS="-l$LLVM_SO_NAME"
2042         else
2043             dnl If LLVM was built with CMake, there will be one shared object per
2044             dnl component.
2045             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2046                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2047         Please make sure you have built llvm with the --enable-shared option
2048         and that your llvm libraries are installed in $LLVM_LIBDIR
2049         If you have installed your llvm libraries to a different directory you
2050         can use the --with-llvm-prefix= configure flag to specify this directory.
2051         NOTE: Mesa is attempting to use llvm shared libraries by default.
2052         If you do not want to build with llvm shared libraries and instead want to
2053         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2054         invocation and rebuild.])])
2055
2056            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2057            dnl install uses a shared object for each compoenent and we have
2058            dnl already added all of these objects to LLVM_LIBS.
2059         fi
2060     else
2061         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2062     fi
2063 fi
2064
2065 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2066 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2067 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2068 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2069 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2070 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2071 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2072                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2073 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2074 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2075 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2076 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2077 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2078
2079 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2080                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2081 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2082                                                   && test "x$MESA_LLVM" = x1)
2083
2084 # Enable static gallium targets for now.
2085 # Do not touch this unless you know what you are doing.
2086 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "xyes" = xyes)
2087
2088 # NOTE: anything using xcb or other client side libs ends up in separate
2089 #       _CLIENT variables.  The pipe loader is built in two variants,
2090 #       one that is standalone and does not link any x client libs (for
2091 #       use by XA tracker in particular, but could be used in any case
2092 #       where communication with xserver is not desired).
2093 if test "x$enable_gallium_loader" = xyes; then
2094     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2095
2096     if test "x$NEED_WINSYS_XLIB" = xyes; then
2097         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2098     fi
2099
2100     if test "x$enable_dri" = xyes; then
2101         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2102     fi
2103
2104     if test "x$enable_gallium_drm_loader" = xyes; then
2105         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2106         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2107                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2108         if test "x$pipe_loader_have_xcb" = xyes; then
2109             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2110             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2111         fi
2112     fi
2113
2114     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2115     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2116
2117     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2118     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2119     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2120     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2121 fi
2122
2123 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2124 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2125 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2126 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2127 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2128 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2129
2130 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2131                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2132                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2133                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2134 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2135                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2136 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2137 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2138 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2139 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2140 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2141 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2142 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2143 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2144 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2145     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2146 fi
2147
2148 AC_SUBST([ELF_LIB])
2149
2150 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2151 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2152 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2153 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2154 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2155
2156 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2157 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2158 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2159
2160 AC_SUBST([VDPAU_MAJOR], 1)
2161 AC_SUBST([VDPAU_MINOR], 0)
2162
2163 AC_SUBST([XVMC_MAJOR], 1)
2164 AC_SUBST([XVMC_MINOR], 0)
2165
2166 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2167 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2168 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2169 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2170
2171 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2172 AC_SUBST([XA_MINOR], $XA_MINOR)
2173 AC_SUBST([XA_TINY], $XA_TINY)
2174 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2175
2176 dnl Restore LDFLAGS and CPPFLAGS
2177 LDFLAGS="$_SAVE_LDFLAGS"
2178 CPPFLAGS="$_SAVE_CPPFLAGS"
2179
2180 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2181 if test "x$acv_mesa_CLANG" = xyes; then
2182     CFLAGS="$CFLAGS -Qunused-arguments"
2183     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2184 fi
2185
2186 dnl Add user CFLAGS and CXXFLAGS
2187 CFLAGS="$CFLAGS $USER_CFLAGS"
2188 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2189
2190 dnl
2191 dnl LT_INIT adds tests to determine host based on some variables like (AM_)C(XX)FLAGS and (AM_)LDFLAGS.
2192 dnl They need to be set before calling LT_INIT so the macro can configure things correctly when cross_compiling.
2193 dnl This will allow --enable-xx-bit to work as expected.
2194 dnl
2195 LT_PREREQ([2.2])
2196 LT_INIT([disable-static])
2197
2198 dnl Substitute the config
2199 AC_CONFIG_FILES([Makefile
2200                 src/Makefile
2201                 src/egl/drivers/dri2/Makefile
2202                 src/egl/main/Makefile
2203                 src/egl/main/egl.pc
2204                 src/egl/wayland/Makefile
2205                 src/egl/wayland/wayland-drm/Makefile
2206                 src/egl/wayland/wayland-egl/Makefile
2207                 src/egl/wayland/wayland-egl/wayland-egl.pc
2208                 src/gallium/auxiliary/Makefile
2209                 src/gallium/auxiliary/pipe-loader/Makefile
2210                 src/gallium/drivers/Makefile
2211                 src/gallium/drivers/freedreno/Makefile
2212                 src/gallium/drivers/galahad/Makefile
2213                 src/gallium/drivers/i915/Makefile
2214                 src/gallium/drivers/identity/Makefile
2215                 src/gallium/drivers/ilo/Makefile
2216                 src/gallium/drivers/llvmpipe/Makefile
2217                 src/gallium/drivers/noop/Makefile
2218                 src/gallium/drivers/nouveau/Makefile
2219                 src/gallium/drivers/r300/Makefile
2220                 src/gallium/drivers/r600/Makefile
2221                 src/gallium/drivers/radeon/Makefile
2222                 src/gallium/drivers/radeonsi/Makefile
2223                 src/gallium/drivers/rbug/Makefile
2224                 src/gallium/drivers/softpipe/Makefile
2225                 src/gallium/drivers/svga/Makefile
2226                 src/gallium/drivers/trace/Makefile
2227                 src/gallium/drivers/vc4/Makefile
2228                 src/gallium/state_trackers/Makefile
2229                 src/gallium/state_trackers/clover/Makefile
2230                 src/gallium/state_trackers/dri/Makefile
2231                 src/gallium/state_trackers/egl/Makefile
2232                 src/gallium/state_trackers/gbm/Makefile
2233                 src/gallium/state_trackers/glx/xlib/Makefile
2234                 src/gallium/state_trackers/omx/Makefile
2235                 src/gallium/state_trackers/osmesa/Makefile
2236                 src/gallium/state_trackers/vdpau/Makefile
2237                 src/gallium/state_trackers/vega/Makefile
2238                 src/gallium/state_trackers/xa/Makefile
2239                 src/gallium/state_trackers/xvmc/Makefile
2240                 src/gallium/targets/Makefile
2241                 src/gallium/targets/dri/Makefile
2242                 src/gallium/targets/egl-static/Makefile
2243                 src/gallium/targets/gbm/Makefile
2244                 src/gallium/targets/libgl-xlib/Makefile
2245                 src/gallium/targets/omx/Makefile
2246                 src/gallium/targets/opencl/Makefile
2247                 src/gallium/targets/osmesa/Makefile
2248                 src/gallium/targets/osmesa/osmesa.pc
2249                 src/gallium/targets/pipe-loader/Makefile
2250                 src/gallium/targets/vdpau/Makefile
2251                 src/gallium/targets/xa/Makefile
2252                 src/gallium/targets/xa/xatracker.pc
2253                 src/gallium/targets/xvmc/Makefile
2254                 src/gallium/tests/trivial/Makefile
2255                 src/gallium/tests/unit/Makefile
2256                 src/gallium/winsys/Makefile
2257                 src/gallium/winsys/freedreno/drm/Makefile
2258                 src/gallium/winsys/i915/drm/Makefile
2259                 src/gallium/winsys/intel/drm/Makefile
2260                 src/gallium/winsys/nouveau/drm/Makefile
2261                 src/gallium/winsys/radeon/drm/Makefile
2262                 src/gallium/winsys/svga/drm/Makefile
2263                 src/gallium/winsys/sw/dri/Makefile
2264                 src/gallium/winsys/sw/fbdev/Makefile
2265                 src/gallium/winsys/sw/kms-dri/Makefile
2266                 src/gallium/winsys/sw/null/Makefile
2267                 src/gallium/winsys/sw/wayland/Makefile
2268                 src/gallium/winsys/sw/wrapper/Makefile
2269                 src/gallium/winsys/sw/xlib/Makefile
2270                 src/gallium/winsys/vc4/drm/Makefile
2271                 src/gbm/Makefile
2272                 src/gbm/main/gbm.pc
2273                 src/glsl/Makefile
2274                 src/glx/Makefile
2275                 src/glx/apple/Makefile
2276                 src/glx/tests/Makefile
2277                 src/gtest/Makefile
2278                 src/loader/Makefile
2279                 src/mapi/Makefile
2280                 src/mapi/es1api/Makefile
2281                 src/mapi/es1api/glesv1_cm.pc
2282                 src/mapi/es2api/Makefile
2283                 src/mapi/es2api/glesv2.pc
2284                 src/mapi/glapi/Makefile
2285                 src/mapi/glapi/gen/Makefile
2286                 src/mapi/glapi/tests/Makefile
2287                 src/mapi/shared-glapi/Makefile
2288                 src/mapi/shared-glapi/tests/Makefile
2289                 src/mapi/vgapi/Makefile
2290                 src/mapi/vgapi/vg.pc
2291                 src/mesa/Makefile
2292                 src/mesa/gl.pc
2293                 src/mesa/drivers/dri/dri.pc
2294                 src/mesa/drivers/dri/common/Makefile
2295                 src/mesa/drivers/dri/common/xmlpool/Makefile
2296                 src/mesa/drivers/dri/i915/Makefile
2297                 src/mesa/drivers/dri/i965/Makefile
2298                 src/mesa/drivers/dri/Makefile
2299                 src/mesa/drivers/dri/nouveau/Makefile
2300                 src/mesa/drivers/dri/r200/Makefile
2301                 src/mesa/drivers/dri/radeon/Makefile
2302                 src/mesa/drivers/dri/swrast/Makefile
2303                 src/mesa/drivers/osmesa/Makefile
2304                 src/mesa/drivers/osmesa/osmesa.pc
2305                 src/mesa/drivers/x11/Makefile
2306                 src/mesa/main/tests/Makefile
2307                 src/util/Makefile
2308                 src/util/tests/hash_table/Makefile])
2309
2310 dnl Sort the dirs alphabetically
2311 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2312 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2313 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2314 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2315
2316 AC_OUTPUT
2317
2318 dnl
2319 dnl Output some configuration info for the user
2320 dnl
2321 echo ""
2322 echo "        prefix:          $prefix"
2323 echo "        exec_prefix:     $exec_prefix"
2324 echo "        libdir:          $libdir"
2325 echo "        includedir:      $includedir"
2326
2327 dnl API info
2328 echo ""
2329 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2330 echo "        OpenVG:          $enable_openvg"
2331
2332 dnl Driver info
2333 echo ""
2334 case "x$enable_osmesa$enable_gallium_osmesa" in
2335 xnoyes)
2336         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2337         ;;
2338 xyesno)
2339         echo "        OSMesa:          lib$OSMESA_LIB"
2340         ;;
2341 xnono)
2342         echo "        OSMesa:          no"
2343         ;;
2344 esac
2345
2346 echo ""
2347 if test "x$enable_dri" != xno; then
2348         echo "        DRI platform:    $dri_platform"
2349         if test -z "$DRI_DIRS"; then
2350             echo "        DRI drivers:     no"
2351         else
2352             echo "        DRI drivers:     $DRI_DIRS"
2353         fi
2354         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2355 fi
2356
2357 case "x$enable_glx$enable_xlib_glx" in
2358 xyesyes)
2359     echo "        GLX:             Xlib-based"
2360     ;;
2361 xyesno)
2362     echo "        GLX:             DRI-based"
2363     ;;
2364 *)
2365     echo "        GLX:             $enable_glx"
2366     ;;
2367 esac
2368
2369 dnl EGL
2370 echo ""
2371 echo "        EGL:             $enable_egl"
2372 if test "$enable_egl" = yes; then
2373     echo "        EGL platforms:   $egl_platforms"
2374
2375     egl_drivers=""
2376     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2377         egl_drivers="$egl_drivers builtin:egl_dri2"
2378     fi
2379
2380     if test "x$enable_gallium_egl" = xyes; then
2381         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2382         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2383     else
2384         echo "        EGL drivers:    $egl_drivers"
2385     fi
2386 fi
2387
2388 echo ""
2389 if test "x$MESA_LLVM" = x1; then
2390     echo "        llvm:            yes"
2391     echo "        llvm-config:     $LLVM_CONFIG"
2392     echo "        llvm-version:    $LLVM_VERSION"
2393 else
2394     echo "        llvm:            no"
2395 fi
2396
2397 echo ""
2398 if test -n "$with_gallium_drivers"; then
2399     echo "        Gallium:         yes"
2400     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2401     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2402     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2403     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2404 else
2405     echo "        Gallium:         no"
2406 fi
2407
2408
2409 dnl Libraries
2410 echo ""
2411 echo "        Shared libs:     $enable_shared"
2412 echo "        Static libs:     $enable_static"
2413 echo "        Shared-glapi:    $enable_shared_glapi"
2414
2415 dnl Compiler options
2416 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2417 cflags=`echo $CFLAGS | \
2418     $SED 's/^ *//;s/  */ /;s/ *$//'`
2419 cxxflags=`echo $CXXFLAGS | \
2420     $SED 's/^ *//;s/  */ /;s/ *$//'`
2421 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2422 echo ""
2423 echo "        CFLAGS:          $cflags"
2424 echo "        CXXFLAGS:        $cxxflags"
2425 echo "        Macros:          $defines"
2426 echo ""
2427 if test "x$MESA_LLVM" = x1; then
2428     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2429     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2430     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2431     echo ""
2432 fi
2433 echo "        PYTHON2:         $PYTHON2"
2434
2435 echo ""
2436 echo "        Run '${MAKE-make}' to build Mesa"
2437 echo ""