configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports -Bsymbolic
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 323 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         BSYMBOLIC="-Wl,-Bsymbolic";],
 328     [AC_MSG_RESULT([no])
 329         BSYMBOLIC="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([BSYMBOLIC])
 333
 334 dnl
 335 dnl Check if linker supports garbage collection
 336 dnl
 337 save_LDFLAGS=$LDFLAGS
 338 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 339 AC_MSG_CHECKING([whether ld supports --gc-sections])
 340 AC_LINK_IFELSE(
 341     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 342     [AC_MSG_RESULT([yes])
 343         GC_SECTIONS="-Wl,--gc-sections";],
 344     [AC_MSG_RESULT([no])
 345         GC_SECTIONS="";])
 346 LDFLAGS=$save_LDFLAGS
 347
 348 AC_SUBST([GC_SECTIONS])
 349
 350 dnl
 351 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 352 dnl so when these flags are passed to ld via libtool the checks will fail
 353 dnl
 354 case "$host_os" in
 355 openbsd* | darwin* )
 356     LD_NO_UNDEFINED="" ;;
 357 *)
 358     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 359 esac
 360
 361 AC_SUBST([LD_NO_UNDEFINED])
 362
 363 dnl
 364 dnl Check if linker supports version scripts
 365 dnl
 366 AC_MSG_CHECKING([if the linker supports version-scripts])
 367 save_LDFLAGS=$LDFLAGS
 368 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 369 cat > conftest.map <<EOF
 370 VERSION_1 {
 371      global:
 372          main;
 373
 374      local:
 375          *;
 376 };
 377 EOF
 378 AC_LINK_IFELSE(
 379     [AC_LANG_SOURCE([int main() { return 0;}])],
 380     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 381     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 382 LDFLAGS=$save_LDFLAGS
 383 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 384
 385 dnl
 386 dnl compatibility symlinks
 387 dnl
 388 case "$host_os" in
 389 linux* )
 390     HAVE_COMPAT_SYMLINKS=yes ;;
 391 * )
 392     HAVE_COMPAT_SYMLINKS=no ;;
 393 esac
 394
 395 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 396
 397 dnl
 398 dnl library names
 399 dnl
 400 case "$host_os" in
 401 darwin* )
 402     LIB_EXT='dylib' ;;
 403 cygwin* )
 404     LIB_EXT='dll' ;;
 405 aix* )
 406     LIB_EXT='a' ;;
 407 * )
 408     LIB_EXT='so' ;;
 409 esac
 410
 411 AC_SUBST([LIB_EXT])
 412
 413 AC_ARG_WITH([gl-lib-name],
 414   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 415     [specify GL library name @<:@default=GL@:>@])],
 416   [GL_LIB=$withval],
 417   [GL_LIB=GL])
 418 AC_ARG_WITH([osmesa-lib-name],
 419   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 420     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 421   [OSMESA_LIB=$withval],
 422   [OSMESA_LIB=OSMesa])
 423 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 424 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 425
 426 dnl
 427 dnl Mangled Mesa support
 428 dnl
 429 AC_ARG_ENABLE([mangling],
 430   [AS_HELP_STRING([--enable-mangling],
 431     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 432   [enable_mangling="${enableval}"],
 433   [enable_mangling=no]
 434 )
 435 if test "x${enable_mangling}" = "xyes" ; then
 436   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 437   GL_LIB="Mangled${GL_LIB}"
 438   OSMESA_LIB="Mangled${OSMESA_LIB}"
 439 fi
 440 AC_SUBST([GL_LIB])
 441 AC_SUBST([OSMESA_LIB])
 442
 443 dnl
 444 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 445 dnl
 446 AC_ARG_ENABLE([texture-float],
 447     [AS_HELP_STRING([--enable-texture-float],
 448         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 449     [enable_texture_float="$enableval"],
 450     [enable_texture_float=no]
 451 )
 452 if test "x$enable_texture_float" = xyes; then
 453     AC_MSG_WARN([Floating-point textures enabled.])
 454     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 455     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 456 fi
 457
 458 dnl
 459 dnl Arch/platform-specific settings
 460 dnl
 461 AC_ARG_ENABLE([asm],
 462     [AS_HELP_STRING([--disable-asm],
 463         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 464     [enable_asm="$enableval"],
 465     [enable_asm=yes]
 466 )
 467 asm_arch=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64 | amd64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         gnu*)
 488             asm_arch=x86
 489             ;;
 490         esac
 491         ;;
 492     x86_64|amd64)
 493         case "$host_os" in
 494         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 495             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 496             ;;
 497         esac
 498         ;;
 499     sparc*)
 500         case "$host_os" in
 501         linux*)
 502             asm_arch=sparc
 503             ;;
 504         esac
 505         ;;
 506     esac
 507
 508     case "$asm_arch" in
 509     x86)
 510         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 511         AC_MSG_RESULT([yes, x86])
 512         ;;
 513     x86_64|amd64)
 514         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 515         AC_MSG_RESULT([yes, x86_64])
 516         ;;
 517     sparc)
 518         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 530     [AC_CHECK_LIB([dl], [dlopen],
 531        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 532 AC_SUBST([DLOPEN_LIBS])
 533
 534 dnl Check if that library also has dladdr
 535 save_LDFLAGS="$LDFLAGS"
 536 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 537 AC_CHECK_FUNCS([dladdr])
 538 LDFLAGS="$save_LDFLAGS"
 539
 540 case "$host_os" in
 541 darwin*|mingw*)
 542     ;;
 543 *)
 544     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 545                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 546                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 547     AC_SUBST([CLOCK_LIB])
 548     ;;
 549 esac
 550
 551 dnl See if posix_memalign is available
 552 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 553
 554 dnl Check for pthreads
 555 case "$host_os" in
 556 mingw*)
 557     ;;
 558 *)
 559     AX_PTHREAD
 560     ;;
 561 esac
 562 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 563 dnl to -pthread, which causes problems if we need -lpthread to appear in
 564 dnl pkgconfig files.
 565 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 566
 567 dnl SELinux awareness.
 568 AC_ARG_ENABLE([selinux],
 569     [AS_HELP_STRING([--enable-selinux],
 570         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 571     [MESA_SELINUX="$enableval"],
 572     [MESA_SELINUX=no])
 573 if test "x$enable_selinux" = "xyes"; then
 574     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 575         [AC_CHECK_HEADER([selinux/selinux.h],[],
 576                          [AC_MSG_ERROR([SELinux headers not found])])
 577          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 578                       [AC_MSG_ERROR([SELinux library not found])])
 579          SELINUX_LIBS="-lselinux"])
 580     DEFINES="$DEFINES -DMESA_SELINUX"
 581 fi
 582 AC_SUBST([SELINUX_CFLAGS])
 583 AC_SUBST([SELINUX_LIBS])
 584
 585 dnl Options for APIs
 586 AC_ARG_ENABLE([opengl],
 587     [AS_HELP_STRING([--disable-opengl],
 588         [disable support for standard OpenGL API @<:@default=no@:>@])],
 589     [enable_opengl="$enableval"],
 590     [enable_opengl=yes])
 591 AC_ARG_ENABLE([gles1],
 592     [AS_HELP_STRING([--enable-gles1],
 593         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 594     [enable_gles1="$enableval"],
 595     [enable_gles1=no])
 596 AC_ARG_ENABLE([gles2],
 597     [AS_HELP_STRING([--enable-gles2],
 598         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 599     [enable_gles2="$enableval"],
 600     [enable_gles2=no])
 601 AC_ARG_ENABLE([openvg],
 602     [AS_HELP_STRING([--enable-openvg],
 603         [enable support for OpenVG API @<:@default=no@:>@])],
 604     [enable_openvg="$enableval"],
 605     [enable_openvg=no])
 606
 607 AC_ARG_ENABLE([dri],
 608     [AS_HELP_STRING([--enable-dri],
 609         [enable DRI modules @<:@default=enabled@:>@])],
 610     [enable_dri="$enableval"],
 611     [enable_dri=yes])
 612
 613 case "$host_os" in
 614 linux*)
 615     dri3_default=yes
 616     ;;
 617 *)
 618     dri3_default=no
 619     ;;
 620 esac
 621 AC_ARG_ENABLE([dri3],
 622     [AS_HELP_STRING([--enable-dri3],
 623         [enable DRI3 @<:@default=auto@:>@])],
 624     [enable_dri3="$enableval"],
 625     [enable_dri3="$dri3_default"])
 626 AC_ARG_ENABLE([glx],
 627     [AS_HELP_STRING([--enable-glx],
 628         [enable GLX library @<:@default=enabled@:>@])],
 629     [enable_glx="$enableval"],
 630     [enable_glx=yes])
 631 AC_ARG_ENABLE([osmesa],
 632     [AS_HELP_STRING([--enable-osmesa],
 633         [enable OSMesa library @<:@default=disabled@:>@])],
 634     [enable_osmesa="$enableval"],
 635     [enable_osmesa=no])
 636 AC_ARG_ENABLE([gallium-osmesa],
 637     [AS_HELP_STRING([--enable-gallium-osmesa],
 638         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 639     [enable_gallium_osmesa="$enableval"],
 640     [enable_gallium_osmesa=no])
 641 AC_ARG_ENABLE([egl],
 642     [AS_HELP_STRING([--disable-egl],
 643         [disable EGL library @<:@default=enabled@:>@])],
 644     [enable_egl="$enableval"],
 645     [enable_egl=yes])
 646
 647 AC_ARG_ENABLE([xa],
 648     [AS_HELP_STRING([--enable-xa],
 649         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 650     [enable_xa="$enableval"],
 651     [enable_xa=no])
 652 AC_ARG_ENABLE([gbm],
 653    [AS_HELP_STRING([--enable-gbm],
 654          [enable gbm library @<:@default=auto@:>@])],
 655    [enable_gbm="$enableval"],
 656    [enable_gbm=auto])
 657
 658 AC_ARG_ENABLE([xvmc],
 659    [AS_HELP_STRING([--enable-xvmc],
 660          [enable xvmc library @<:@default=auto@:>@])],
 661    [enable_xvmc="$enableval"],
 662    [enable_xvmc=no])
 663 AC_ARG_ENABLE([vdpau],
 664    [AS_HELP_STRING([--enable-vdpau],
 665          [enable vdpau library @<:@default=auto@:>@])],
 666    [enable_vdpau="$enableval"],
 667    [enable_vdpau=auto])
 668 AC_ARG_ENABLE([omx],
 669    [AS_HELP_STRING([--enable-omx],
 670          [enable OpenMAX library @<:@default=no@:>@])],
 671    [enable_omx="$enableval"],
 672    [enable_omx=no])
 673 AC_ARG_ENABLE([opencl],
 674    [AS_HELP_STRING([--enable-opencl],
 675          [enable OpenCL library @<:@default=no@:>@])],
 676    [enable_opencl="$enableval"],
 677    [enable_opencl=no])
 678 AC_ARG_ENABLE([opencl_icd],
 679    [AS_HELP_STRING([--enable-opencl-icd],
 680           [Build an OpenCL ICD library to be loaded by an ICD implementation
 681            @<:@default=no@:>@])],
 682     [enable_opencl_icd="$enableval"],
 683     [enable_opencl_icd=no])
 684 AC_ARG_ENABLE([xlib-glx],
 685     [AS_HELP_STRING([--enable-xlib-glx],
 686         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 687     [enable_xlib_glx="$enableval"],
 688     [enable_xlib_glx=no])
 689 AC_ARG_ENABLE([gallium-egl],
 690     [AS_HELP_STRING([--enable-gallium-egl],
 691         [enable optional EGL state tracker (not required
 692          for EGL support in Gallium with OpenGL and OpenGL ES)
 693          @<:@default=disable@:>@])],
 694     [enable_gallium_egl="$enableval"],
 695     [enable_gallium_egl=no])
 696 AC_ARG_ENABLE([gallium-gbm],
 697     [AS_HELP_STRING([--enable-gallium-gbm],
 698         [enable optional gbm state tracker (not required for
 699          gbm support in Gallium)
 700          @<:@default=auto@:>@])],
 701     [enable_gallium_gbm="$enableval"],
 702     [enable_gallium_gbm=auto])
 703
 704 AC_ARG_ENABLE([r600-llvm-compiler],
 705     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 706         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 707     [enable_r600_llvm="$enableval"],
 708     [enable_r600_llvm=no])
 709
 710 AC_ARG_ENABLE([gallium-tests],
 711     [AS_HELP_STRING([--enable-gallium-tests],
 712         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 713     [enable_gallium_tests="$enableval"],
 714     [enable_gallium_tests=no])
 715
 716 # Option for Gallium drivers
 717
 718 # Keep this in sync with the --with-gallium-drivers help string default value
 719 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 720
 721 AC_ARG_WITH([gallium-drivers],
 722     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 723         [comma delimited Gallium drivers list, e.g.
 724         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 725         @<:@default=r300,r600,svga,swrast@:>@])],
 726     [with_gallium_drivers="$withval"],
 727     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 728
 729 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 730 # here so that the script doesn't choke on an unknown driver name later.
 731 case "$with_gallium_drivers" in
 732     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 733     no) with_gallium_drivers='' ;;
 734 esac
 735
 736 if test "x$enable_opengl" = xno -a \
 737         "x$enable_gles1" = xno -a \
 738         "x$enable_gles2" = xno -a \
 739         "x$enable_openvg" = xno -a \
 740         "x$enable_xa" = xno -a \
 741         "x$enable_xvmc" = xno -a \
 742         "x$enable_vdpau" = xno -a \
 743         "x$enable_omx" = xno -a \
 744         "x$enable_opencl" = xno; then
 745     AC_MSG_ERROR([at least one API should be enabled])
 746 fi
 747
 748 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 749 if test "x$enable_opengl" = xno -a \
 750         "x$enable_gles1" = xyes; then
 751     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 752 fi
 753
 754 if test "x$enable_opengl" = xno -a \
 755         "x$enable_gles2" = xyes; then
 756     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 757 fi
 758
 759 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 760 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 761 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 762 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 763                                         "x$enable_gles1" = xyes -o \
 764                                         "x$enable_gles2" = xyes)
 765
 766 if test "x$enable_glx" = xno; then
 767     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 768     enable_xlib_glx=no
 769 fi
 770
 771 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 772     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 773 fi
 774
 775 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 776     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 777 fi
 778
 779 # Disable GLX if OpenGL is not enabled
 780 if test "x$enable_glx$enable_opengl" = xyesno; then
 781     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 782     enable_glx=no
 783 fi
 784
 785 # Disable GLX if DRI and Xlib-GLX are not enabled
 786 if test "x$enable_glx" = xyes -a \
 787         "x$enable_dri" = xno -a \
 788         "x$enable_xlib_glx" = xno; then
 789     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 790     enable_glx=no
 791 fi
 792
 793 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 794                                   "x$enable_dri" = xyes)
 795
 796 # Select which platform-dependent DRI code gets built
 797 case "$host_os" in
 798 darwin*)
 799     dri_platform='apple' ;;
 800 gnu*|mingw*|cygwin*)
 801     dri_platform='none' ;;
 802 *)
 803     dri_platform='drm' ;;
 804 esac
 805
 806 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 807 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 808 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 809 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 810 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 811
 812 AC_ARG_ENABLE([shared-glapi],
 813     [AS_HELP_STRING([--enable-shared-glapi],
 814         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 815     [enable_shared_glapi="$enableval"],
 816     [enable_shared_glapi=yes])
 817
 818 case "x$enable_opengl$enable_gles1$enable_gles2" in
 819 x*yes*yes*)
 820     if test "x$enable_shared_glapi" = xno; then
 821         AC_MSG_ERROR([shared GLAPI required when building two or more of
 822                       the following APIs - opengl, gles1 gles2])
 823     fi
 824     ;;
 825 esac
 826
 827 # Building Xlib-GLX requires shared glapi to be disabled.
 828 if test "x$enable_xlib_glx" = xyes; then
 829     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 830     enable_shared_glapi=no
 831 fi
 832
 833 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 834
 835 dnl
 836 dnl Driver specific build directories
 837 dnl
 838 GALLIUM_TARGET_DIRS=""
 839 GALLIUM_WINSYS_DIRS="sw"
 840 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 841 GALLIUM_STATE_TRACKERS_DIRS=""
 842
 843 case "x$enable_glx$enable_xlib_glx" in
 844 xyesyes)
 845     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 846     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 847     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 848     NEED_WINSYS_XLIB="yes"
 849     ;;
 850 esac
 851
 852 if test "x$enable_dri" = xyes; then
 853     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 854     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 855 fi
 856
 857 if test "x$enable_gallium_osmesa" = xyes; then
 858     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 859         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 860     fi
 861     if test "x$enable_osmesa" = xyes; then
 862         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 863     fi
 864     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 865     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 866 fi
 867
 868 AC_SUBST([MESA_LLVM])
 869
 870 # Check for libdrm
 871 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 872                   [have_libdrm=yes], [have_libdrm=no])
 873 if test "x$have_libdrm" = xyes; then
 874         DEFINES="$DEFINES -DHAVE_LIBDRM"
 875 fi
 876
 877 case "$host_os" in
 878 linux*)
 879     need_pci_id=yes ;;
 880 *)
 881     need_pci_id=no ;;
 882 esac
 883
 884 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 885                   have_libudev=yes, have_libudev=no)
 886
 887 AC_ARG_ENABLE([sysfs],
 888     [AS_HELP_STRING([--enable-sysfs],
 889         [enable /sys PCI identification @<:@default=disabled@:>@])],
 890     [have_sysfs="$enableval"],
 891     [have_sysfs=no]
 892 )
 893
 894 if test "x$enable_dri" = xyes; then
 895     if test "$enable_static" = yes; then
 896         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 897     fi
 898
 899     # not a hard requirement as swrast does not depend on it
 900     if test "x$have_libdrm" = xyes; then
 901         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 902     fi
 903 fi
 904
 905 AC_ARG_ENABLE([driglx-direct],
 906     [AS_HELP_STRING([--disable-driglx-direct],
 907         [disable direct rendering in GLX and EGL for DRI \
 908             @<:@default=auto@:>@])],
 909     [driglx_direct="$enableval"],
 910     [driglx_direct="yes"])
 911
 912 dnl
 913 dnl libGL configuration per driver
 914 dnl
 915 case "x$enable_glx$enable_xlib_glx" in
 916 xyesyes)
 917     # Xlib-based GLX
 918     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 919     GL_PC_REQ_PRIV="x11 xext"
 920     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 921     GL_LIB_DEPS="$XLIBGL_LIBS"
 922     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 923     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 924     ;;
 925 xyesno)
 926     # DRI-based GLX
 927     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 928
 929     # find the DRI deps for libGL
 930     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 931
 932     if test x"$driglx_direct" = xyes; then
 933         if test x"$dri_platform" = xdrm ; then
 934             DEFINES="$DEFINES -DGLX_USE_DRM"
 935             if test "x$have_libdrm" != xyes; then
 936                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 937             fi
 938
 939             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 940             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 941             if test x"$enable_dri3" = xyes; then
 942                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 943                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 944             fi
 945
 946             if test x"$enable_dri" = xyes; then
 947                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 948             fi
 949
 950             if test x"$enable_dri3" = xyes; then
 951                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 952             fi
 953         fi
 954         if test x"$dri_platform" = xapple ; then
 955             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 956         fi
 957     fi
 958
 959     # add xf86vidmode if available
 960     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 961     if test "$HAVE_XF86VIDMODE" = yes ; then
 962         dri_modules="$dri_modules xxf86vm"
 963     fi
 964
 965     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 966     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 967     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 968     GL_LIB_DEPS="$DRIGL_LIBS"
 969
 970     # need DRM libs, $PTHREAD_LIBS, etc.
 971     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 972     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 973     ;;
 974 esac
 975
 976 have_pci_id=no
 977 if test "$have_libudev" = yes; then
 978     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 979     have_pci_id=yes
 980 fi
 981
 982 if test "$have_sysfs" = yes; then
 983     DEFINES="$DEFINES -DHAVE_SYSFS"
 984     have_pci_id=yes
 985 fi
 986
 987 # This is outside the case (above) so that it is invoked even for non-GLX
 988 # builds.
 989 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 990
 991 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 992 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 993 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 994 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 995
 996 AC_SUBST([X11_INCLUDES])
 997 AC_SUBST([GL_LIB_DEPS])
 998 AC_SUBST([GL_PC_REQ_PRIV])
 999 AC_SUBST([GL_PC_LIB_PRIV])
1000 AC_SUBST([GL_PC_CFLAGS])
1001 AC_SUBST([DRI_PC_REQ_PRIV])
1002 AC_SUBST([GLESv1_CM_LIB_DEPS])
1003 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1004 AC_SUBST([GLESv2_LIB_DEPS])
1005 AC_SUBST([GLESv2_PC_LIB_PRIV])
1006
1007 AC_SUBST([HAVE_XF86VIDMODE])
1008
1009 dnl
1010 dnl More GLX setup
1011 dnl
1012 case "x$enable_glx$enable_xlib_glx" in
1013 xyesyes)
1014     DEFINES="$DEFINES -DUSE_XSHM"
1015     ;;
1016 xyesno)
1017     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1018     if test "x$driglx_direct" = xyes; then
1019         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1020     fi
1021     ;;
1022 esac
1023
1024 dnl
1025 dnl TLS detection
1026 dnl
1027
1028 AC_ARG_ENABLE([glx-tls],
1029     [AS_HELP_STRING([--enable-glx-tls],
1030         [enable TLS support in GLX @<:@default=disabled@:>@])],
1031     [GLX_USE_TLS="$enableval"],
1032     [GLX_USE_TLS=no])
1033 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1034
1035 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1036       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1037
1038 dnl
1039 dnl More DRI setup
1040 dnl
1041 dnl Directory for DRI drivers
1042 AC_ARG_WITH([dri-driverdir],
1043     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1044         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1045     [DRI_DRIVER_INSTALL_DIR="$withval"],
1046     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1047 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1048 dnl Extra search path for DRI drivers
1049 AC_ARG_WITH([dri-searchpath],
1050     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1051         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1052     [DRI_DRIVER_SEARCH_DIR="$withval"],
1053     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1054 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1055 dnl Which drivers to build - default is chosen by platform
1056 AC_ARG_WITH([dri-drivers],
1057     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1058         [comma delimited classic DRI drivers list, e.g.
1059         "swrast,i965,radeon" @<:@default=auto@:>@])],
1060     [with_dri_drivers="$withval"],
1061     [with_dri_drivers=auto])
1062
1063 if test "x$with_dri_drivers" = xauto; then
1064     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1065         with_dri_drivers="yes"
1066     else
1067         with_dri_drivers="no"
1068     fi
1069 fi
1070 if test "x$with_dri_drivers" = xno; then
1071     with_dri_drivers=''
1072 fi
1073
1074 dnl If $with_dri_drivers is yes, drivers will be added through
1075 dnl platform checks. Set DEFINES and LIB_DEPS
1076 if test "x$enable_dri" = xyes; then
1077     # Platform specific settings and drivers to build
1078     case "$host_os" in
1079     linux*)
1080         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1081         DEFINES="$DEFINES -DHAVE_ALIAS"
1082         if test "x$enable_dri3" = xyes; then
1083             DEFINES="$DEFINES -DHAVE_DRI3"
1084         fi
1085
1086         if test "x$have_pci_id" != xyes; then
1087             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1088         fi
1089
1090         case "$host_cpu" in
1091         powerpc* | sparc*)
1092             # Build only the drivers for cards that exist on PowerPC/sparc
1093             if test "x$with_dri_drivers" = "xyes"; then
1094                 with_dri_drivers="r200 radeon swrast"
1095             fi
1096             ;;
1097         esac
1098         ;;
1099     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1100         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1101         DEFINES="$DEFINES -DHAVE_ALIAS"
1102         ;;
1103     gnu*)
1104         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1105         DEFINES="$DEFINES -DHAVE_ALIAS"
1106         ;;
1107     solaris*)
1108         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1109         ;;
1110     cygwin*)
1111         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1112         if test "x$with_dri_drivers" = "xyes"; then
1113             with_dri_drivers="swrast"
1114         fi
1115         ;;
1116     darwin*)
1117         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DGLX_ALIAS_UNSUPPORTED"
1118         if test "x$with_dri_drivers" = "xyes"; then
1119             with_dri_drivers="swrast"
1120         fi
1121         ;;
1122     esac
1123
1124     # default drivers
1125     if test "x$with_dri_drivers" = "xyes"; then
1126         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1127     fi
1128
1129     # Check for expat
1130     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1131     if test "x$have_expat" = "xyes"; then
1132        PKG_CHECK_MODULES([EXPAT], [expat], [],
1133                          AC_MSG_ERROR([Expat required for DRI.]))
1134     else
1135        # expat version 2.0 and earlier do not provide expat.pc
1136        EXPAT_LIBS=-lexpat
1137     fi
1138
1139     # If we are building any DRI driver other than swrast.
1140     if test -n "$with_dri_drivers"; then
1141         if test "x$with_dri_drivers" != xswrast; then
1142             # ... libdrm is required
1143             if test "x$have_libdrm" != xyes; then
1144                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1145             fi
1146             DRICOMMON_NEED_LIBDRM=yes
1147         else
1148             DRICOMMON_NEED_LIBDRM=no
1149         fi
1150     fi
1151
1152     # put all the necessary libs together
1153     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1154 fi
1155
1156 AC_SUBST([DRI_LIB_DEPS])
1157
1158 DRI_DIRS=''
1159 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1160 if test -n "$with_dri_drivers"; then
1161     if test "x$enable_opengl" != xyes; then
1162         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1163     fi
1164
1165     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1166     for driver in $dri_drivers; do
1167         DRI_DIRS="$DRI_DIRS $driver"
1168         case "x$driver" in
1169         xi915)
1170             HAVE_I915_DRI=yes;
1171             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1172             ;;
1173         xi965)
1174             HAVE_I965_DRI=yes;
1175             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1176             ;;
1177         xnouveau)
1178             HAVE_NOUVEAU_DRI=yes;
1179             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1180             ;;
1181         xradeon)
1182             HAVE_RADEON_DRI=yes;
1183             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1184             ;;
1185         xr200)
1186             HAVE_R200_DRI=yes;
1187             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1188             ;;
1189         xswrast)
1190             HAVE_SWRAST_DRI=yes;
1191             ;;
1192         *)
1193             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1194             ;;
1195         esac
1196     done
1197     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1198 fi
1199
1200 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1201 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1202                                   "x$enable_osmesa" = xyes -o \
1203                                   -n "$DRI_DIRS")
1204
1205 dnl
1206 dnl OSMesa configuration
1207 dnl
1208
1209 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1210 AC_ARG_WITH([osmesa-bits],
1211     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1212         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1213     [osmesa_bits="$withval"],
1214     [osmesa_bits=8])
1215 if test "x$osmesa_bits" != x8; then
1216     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1217         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1218         osmesa_bits=8
1219     fi
1220 fi
1221 case "x$osmesa_bits" in
1222 x8)
1223     OSMESA_LIB="${OSMESA_LIB}"
1224     ;;
1225 x16|x32)
1226     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1227     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1228     ;;
1229 *)
1230     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1231     ;;
1232 esac
1233
1234 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1235     # only link libraries with osmesa if shared
1236     if test "$enable_static" = no; then
1237         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1238     else
1239         OSMESA_LIB_DEPS=""
1240     fi
1241     OSMESA_MESA_DEPS=""
1242     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1243 fi
1244
1245 AC_SUBST([OSMESA_LIB_DEPS])
1246 AC_SUBST([OSMESA_MESA_DEPS])
1247 AC_SUBST([OSMESA_PC_REQ])
1248 AC_SUBST([OSMESA_PC_LIB_PRIV])
1249
1250 dnl
1251 dnl gbm configuration
1252 dnl
1253 if test "x$enable_gbm" = xauto; then
1254     case "$with_egl_platforms" in
1255         *drm*)
1256             enable_gbm=yes ;;
1257          *)
1258             enable_gbm=no ;;
1259     esac
1260 fi
1261 if test "x$enable_gbm" = xyes; then
1262     if test "x$need_pci_id$have_pci_id" = xyesno; then
1263         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1264     fi
1265
1266     if test "x$enable_dri" = xyes; then
1267         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1268         if test "x$enable_shared_glapi" = xno; then
1269             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1270         fi
1271     else
1272         # Strictly speaking libgbm does not require --enable-dri, although
1273         # both of its backends do. Thus one can build libgbm without any
1274         # backends if --disable-dri is set.
1275         # To avoid unnecessary complexity of checking if at least one backend
1276         # is available when building, just mandate --enable-dri.
1277         AC_MSG_ERROR([gbm requires --enable-dri])
1278     fi
1279 fi
1280 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1281 if test "x$need_pci_id$have_libudev" = xyesyes; then
1282     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1283 else
1284     GBM_PC_REQ_PRIV=""
1285 fi
1286 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1287 AC_SUBST([GBM_PC_REQ_PRIV])
1288 AC_SUBST([GBM_PC_LIB_PRIV])
1289
1290 dnl
1291 dnl EGL configuration
1292 dnl
1293 EGL_CLIENT_APIS=""
1294
1295 if test "x$enable_egl" = xyes; then
1296     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1297
1298     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1299
1300     if test "$enable_static" != yes; then
1301         if test "x$enable_dri" = xyes; then
1302             HAVE_EGL_DRIVER_DRI2=1
1303         fi
1304
1305     fi
1306 fi
1307 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1308 AC_SUBST([EGL_LIB_DEPS])
1309
1310 dnl
1311 dnl EGL Gallium configuration
1312 dnl
1313 if test "x$enable_gallium_egl" = xyes; then
1314     if test -z "$with_gallium_drivers"; then
1315         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1316     fi
1317     if test "x$enable_egl" = xno; then
1318         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1319     fi
1320     if test "x$have_libdrm" != xyes; then
1321         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1322     fi
1323
1324     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1325     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1326 fi
1327 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1328
1329 dnl
1330 dnl gbm Gallium configuration
1331 dnl
1332 if test "x$enable_gallium_gbm" = xauto; then
1333     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1334         yesyesyes*drm*)
1335             enable_gallium_gbm=yes ;;
1336          *)
1337             enable_gallium_gbm=no ;;
1338     esac
1339 fi
1340 if test "x$enable_gallium_gbm" = xyes; then
1341     if test -z "$with_gallium_drivers"; then
1342         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1343     fi
1344     if test "x$enable_gbm" = xno; then
1345         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1346     fi
1347     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1348     if test "x$enable_dri" = xno; then
1349         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1350     fi
1351
1352     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1353     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1354     enable_gallium_loader=yes
1355 fi
1356 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1357
1358 dnl
1359 dnl XA configuration
1360 dnl
1361 if test "x$enable_xa" = xyes; then
1362     if test "x$with_gallium_drivers" = xswrast; then
1363        AC_MSG_ERROR([
1364           Building xa requires at least one non swrast gallium driver.
1365           If you are looking to use libxatracker.so with vmware's virtual gpu,
1366           make sure to include svga in the gallium drivers list, apart from
1367           enabling XA.
1368           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1369     fi
1370     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1371     enable_gallium_loader=yes
1372 fi
1373 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1374
1375 dnl
1376 dnl OpenVG configuration
1377 dnl
1378 VG_LIB_DEPS=""
1379
1380 if test "x$enable_openvg" = xyes; then
1381     if test "x$enable_egl" = xno; then
1382         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1383     fi
1384     if test -z "$with_gallium_drivers"; then
1385         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1386     fi
1387     if test "x$enable_gallium_egl" = xno; then
1388         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1389     fi
1390
1391     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1392     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1393     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1394     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1395     AC_SUBST([VG_PC_LIB_PRIV])
1396 fi
1397 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1398
1399 dnl
1400 dnl Gallium G3DVL configuration
1401 dnl
1402 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1403     if test "x$enable_xvmc" = xauto; then
1404         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1405     fi
1406
1407     if test "x$enable_vdpau" = xauto; then
1408         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1409     fi
1410
1411     if test "x$enable_omx" = xauto; then
1412         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1413     fi
1414 fi
1415
1416 if test "x$enable_xvmc" = xyes; then
1417     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1418     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1419 fi
1420 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1421
1422 if test "x$enable_vdpau" = xyes; then
1423     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1424                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1425     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1426 fi
1427 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1428
1429 if test "x$enable_omx" = xyes; then
1430     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1431     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1432 fi
1433 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1434
1435 dnl
1436 dnl OpenCL configuration
1437 dnl
1438
1439 AC_ARG_WITH([libclc-path],
1440    [AS_HELP_STRING([--with-libclc-path],
1441          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1442    [LIBCLC_PATH="$withval"],
1443    [LIBCLC_PATH=''])
1444
1445 if test -n "$LIBCLC_PATH"; then
1446    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1447                   Please review the updated build instructions for clover:
1448                   http://dri.freedesktop.org/wiki/GalliumCompute])
1449 fi
1450
1451
1452 AC_ARG_WITH([clang-libdir],
1453    [AS_HELP_STRING([--with-clang-libdir],
1454          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1455    [CLANG_LIBDIR="$withval"],
1456    [CLANG_LIBDIR=''])
1457
1458 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1459
1460 if test "x$enable_opencl" = xyes; then
1461     if test -z "$with_gallium_drivers"; then
1462         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1463     fi
1464
1465     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1466         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1467     fi
1468
1469     if test "x$have_libclc" = xno; then
1470         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1471                     Make sure the directory containing libclc.pc is specified in your
1472                     PKG_CONFIG_PATH environment variable.
1473                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1474     else
1475         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1476         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1477         AC_SUBST([LIBCLC_INCLUDEDIR])
1478         AC_SUBST([LIBCLC_LIBEXECDIR])
1479     fi
1480
1481     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1482     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1483     enable_gallium_loader=yes
1484
1485     if test "x$enable_opencl_icd" = xyes; then
1486         OPENCL_LIBNAME="MesaOpenCL"
1487     else
1488         OPENCL_LIBNAME="OpenCL"
1489     fi
1490 fi
1491 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1492 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1493 AC_SUBST([OPENCL_LIBNAME])
1494
1495 dnl
1496 dnl Gallium configuration
1497 dnl
1498 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1499
1500 AC_SUBST([LLVM_BINDIR])
1501 AC_SUBST([LLVM_CFLAGS])
1502 AC_SUBST([LLVM_CPPFLAGS])
1503 AC_SUBST([LLVM_CXXFLAGS])
1504 AC_SUBST([LLVM_LIBDIR])
1505 AC_SUBST([LLVM_LIBS])
1506 AC_SUBST([LLVM_LDFLAGS])
1507 AC_SUBST([LLVM_INCLUDEDIR])
1508 AC_SUBST([LLVM_VERSION])
1509 AC_SUBST([CLANG_RESOURCE_DIR])
1510
1511 case "x$enable_opengl$enable_gles1$enable_gles2" in
1512 x*yes*)
1513     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1514     ;;
1515 esac
1516
1517 AC_SUBST([VG_LIB_DEPS])
1518 AC_SUBST([EGL_CLIENT_APIS])
1519
1520 dnl
1521 dnl EGL Platforms configuration
1522 dnl
1523 AC_ARG_WITH([egl-platforms],
1524     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1525         [comma delimited native platforms libEGL supports, e.g.
1526         "x11,drm" @<:@default=auto@:>@])],
1527     [with_egl_platforms="$withval"],
1528     [if test "x$enable_egl" = xyes; then
1529         with_egl_platforms="x11"
1530     else
1531         with_egl_platforms=""
1532     fi])
1533
1534 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1535     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1536 fi
1537
1538 # Do per-EGL platform setups and checks
1539 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1540 for plat in $egl_platforms; do
1541         case "$plat" in
1542         wayland)
1543                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1544                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1545
1546                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1547                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1548                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1549                 ;;
1550
1551         x11)
1552                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1553                 ;;
1554
1555         drm)
1556                 test "x$enable_gbm" = "xno" &&
1557                         AC_MSG_ERROR([EGL platform drm needs gbm])
1558                 test "x$have_libdrm" != xyes &&
1559                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1560                 ;;
1561
1562         android|fbdev|gdi|null)
1563                 ;;
1564
1565         *)
1566                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1567                 ;;
1568         esac
1569
1570         case "$plat$need_pci_id$have_pci_id" in
1571                 waylandyesno|drmyesno)
1572                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1573         esac
1574 done
1575
1576 # libEGL wants to default to the first platform specified in
1577 # ./configure.  parse that here.
1578 if test "x$egl_platforms" != "x"; then
1579     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1580     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1581 else
1582     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1583 fi
1584
1585 if echo "$egl_platforms" | grep -q 'x11'; then
1586     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1587     NEED_WINSYS_XLIB=yes
1588 fi
1589 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1590 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1591 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1592 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1593 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1594
1595 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1596
1597 AC_SUBST([EGL_NATIVE_PLATFORM])
1598 AC_SUBST([EGL_CFLAGS])
1599
1600 # If we don't have the X11 platform, set this define so we don't try to include
1601 # the X11 headers.
1602 if ! echo "$egl_platforms" | grep -q 'x11'; then
1603     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1604     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1605 fi
1606
1607 AC_ARG_WITH([egl-driver-dir],
1608     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1609                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1610     [EGL_DRIVER_INSTALL_DIR="$withval"],
1611     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1612 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1613
1614 AC_ARG_WITH([max-width],
1615     [AS_HELP_STRING([--with-max-width=N],
1616                     [Maximum framebuffer width (4096)])],
1617     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1618      AS_IF([test "${withval}" -gt "4096"],
1619            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1620 )
1621 AC_ARG_WITH([max-height],
1622     [AS_HELP_STRING([--with-max-height=N],
1623                     [Maximum framebuffer height (4096)])],
1624     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1625      AS_IF([test "${withval}" -gt "4096"],
1626            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1627 )
1628
1629 dnl
1630 dnl Gallium LLVM
1631 dnl
1632 AC_ARG_ENABLE([gallium-llvm],
1633     [AS_HELP_STRING([--enable-gallium-llvm],
1634         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1635     [enable_gallium_llvm="$enableval"],
1636     [enable_gallium_llvm=auto])
1637
1638 AC_ARG_ENABLE([llvm-shared-libs],
1639     [AS_HELP_STRING([--enable-llvm-shared-libs],
1640         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1641     [enable_llvm_shared_libs="$enableval"],
1642     [enable_llvm_shared_libs=yes])
1643
1644 AC_ARG_WITH([llvm-prefix],
1645     [AS_HELP_STRING([--with-llvm-prefix],
1646         [Prefix for LLVM installations in non-standard locations])],
1647     [llvm_prefix="$withval"],
1648     [llvm_prefix=''])
1649
1650
1651 # Call this inside ` ` to get the return value.
1652 # $1 is the llvm-config command with arguments.
1653 strip_unwanted_llvm_flags() {
1654     # Use \> (marks the end of the word)
1655     echo `$1` | sed \
1656         -e 's/-DNDEBUG\>//g' \
1657         -e 's/-pedantic\>//g' \
1658         -e 's/-Wcovered-switch-default\>//g' \
1659         -e 's/-O.\>//g' \
1660         -e 's/-g\>//g' \
1661         -e 's/-Wall\>//g' \
1662         -e 's/-Wcast-qual\>//g' \
1663         -e 's/-Woverloaded-virtual\>//g' \
1664         -e 's/-fcolor-diagnostics\>//g' \
1665         -e 's/-fdata-sections\>//g' \
1666         -e 's/-ffunction-sections\>//g' \
1667         -e 's/-fno-exceptions\>//g' \
1668         -e 's/-fomit-frame-pointer\>//g' \
1669         -e 's/-fvisibility-inlines-hidden\>//g' \
1670         -e 's/-fPIC\>//g' \
1671         -e 's/-fstack-protector-strong\>//g'
1672 }
1673
1674
1675 if test -z "$with_gallium_drivers"; then
1676     enable_gallium_llvm=no
1677 fi
1678 if test "x$enable_gallium_llvm" = xauto; then
1679     case "$host_cpu" in
1680     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1681     esac
1682 fi
1683 if test "x$enable_gallium_llvm" = xyes; then
1684     if test -n "$llvm_prefix"; then
1685         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1686     else
1687         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1688     fi
1689
1690     if test "x$LLVM_CONFIG" != xno; then
1691         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1692         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1693         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1694         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1695         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1696         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1697         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1698         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1699
1700         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1701             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1702         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1703             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1704
1705         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1706         dnl llvm-config.h
1707         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1708             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1709             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1710
1711         if test -n "${LLVM_VERSION_MAJOR}"; then
1712             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1713         else
1714             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1715         fi
1716
1717         LLVM_REQUIRED_VERSION_MAJOR="3"
1718         LLVM_REQUIRED_VERSION_MINOR="1"
1719         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1720             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1721         fi
1722
1723         LLVM_COMPONENTS="engine bitwriter"
1724         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1725             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1726         fi
1727
1728         if test "x$enable_opencl" = xyes; then
1729             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1730             # LLVM 3.3 >= 177971 requires IRReader
1731             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1732                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1733             fi
1734             # LLVM 3.4 requires Option
1735             if $LLVM_CONFIG --components | grep -qw 'option'; then
1736                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1737             fi
1738             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1739             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1740                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1741             fi
1742             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1743                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1744             fi
1745         fi
1746         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1747         MESA_LLVM=1
1748
1749         dnl Check for Clang internal headers
1750         if test "x$enable_opencl" = xyes; then
1751             if test -z "$CLANG_LIBDIR"; then
1752                 CLANG_LIBDIR=${LLVM_LIBDIR}
1753             fi
1754             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1755             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1756                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1757         fi
1758     else
1759         MESA_LLVM=0
1760         LLVM_VERSION_INT=0
1761     fi
1762 else
1763     MESA_LLVM=0
1764     LLVM_VERSION_INT=0
1765
1766     if test "x$enable_opencl" = xyes; then
1767         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1768     fi
1769 fi
1770
1771 dnl Directory for XVMC libs
1772 AC_ARG_WITH([xvmc-libdir],
1773     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1774         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1775     [XVMC_LIB_INSTALL_DIR="$withval"],
1776     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1777 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1778
1779 dnl
1780 dnl Gallium Tests
1781 dnl
1782 if test "x$enable_gallium_tests" = xyes; then
1783     enable_gallium_loader=yes
1784 fi
1785 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1786
1787 if test "x$enable_gallium_loader" = xyes; then
1788     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1789 fi
1790 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1791
1792 dnl Directory for VDPAU libs
1793 AC_ARG_WITH([vdpau-libdir],
1794     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1795         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1796     [VDPAU_LIB_INSTALL_DIR="$withval"],
1797     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1798 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1799
1800 OMX_LIB_INSTALL_DIR_DEFAULT=''
1801 if test "x$enable_omx" = xyes; then
1802     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1803 fi
1804
1805 AC_ARG_WITH([omx-libdir],
1806     [AS_HELP_STRING([--with-omx-libdir=DIR],
1807         [directory for the OMX libraries])],
1808     [OMX_LIB_INSTALL_DIR="$withval"],
1809     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1810 AC_SUBST([OMX_LIB_INSTALL_DIR])
1811
1812 dnl Directory for OpenCL libs
1813 AC_ARG_WITH([opencl-libdir],
1814     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1815         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1816     [OPENCL_LIB_INSTALL_DIR="$withval"],
1817     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1818 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1819
1820 dnl
1821 dnl Gallium helper functions
1822 dnl
1823 gallium_check_st() {
1824     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1825          if test "x$have_libdrm" != xyes; then
1826             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1827          fi
1828          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1829     fi
1830     if test "x$enable_dri" = xyes && test -n "$2"; then
1831          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1832     fi
1833     if test "x$enable_xa" = xyes && test -n "$3"; then
1834          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1835     fi
1836     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1837          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1838     fi
1839     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1840          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1841     fi
1842     if test "x$enable_omx" = xyes && test "x$6" != x; then
1843          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1844     fi
1845 }
1846
1847 gallium_require_llvm() {
1848     if test "x$MESA_LLVM" = x0; then
1849         case "$host_cpu" in
1850         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1851         esac
1852     fi
1853 }
1854
1855 gallium_require_drm_loader() {
1856     if test "x$enable_gallium_loader" = xyes; then
1857         if test "x$need_pci_id$have_pci_id" = xyesno; then
1858             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1859         fi
1860         if test "x$have_libdrm" != xyes; then
1861             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1862         fi
1863         enable_gallium_drm_loader=yes
1864     fi
1865 }
1866
1867 require_egl_drm() {
1868     case "$with_egl_platforms" in
1869         *drm*)
1870             ;;
1871          *)
1872             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1873             ;;
1874     esac
1875     if test "x$enable_gbm" != xyes; then
1876             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1877     fi
1878 }
1879
1880 radeon_llvm_check() {
1881     if test "x$enable_gallium_llvm" != "xyes"; then
1882         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1883     fi
1884     LLVM_REQUIRED_VERSION_MAJOR="3"
1885     LLVM_REQUIRED_VERSION_MINOR="3"
1886     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1887         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1888     fi
1889     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1890         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1891                       sources with the --enable-experimental-targets=R600
1892                       configure flag])
1893     fi
1894     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1895     NEED_RADEON_LLVM=yes
1896     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1897                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1898 }
1899
1900 dnl Gallium drivers
1901 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1902         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1903     NEED_NONNULL_WINSYS=yes
1904 fi
1905 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1906
1907 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1908 if test -n "$with_gallium_drivers"; then
1909     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1910     for driver in $gallium_drivers; do
1911         case "x$driver" in
1912         xsvga)
1913             HAVE_GALLIUM_SVGA=yes
1914             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1915             gallium_require_drm_loader
1916             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1917             ;;
1918         xi915)
1919             HAVE_GALLIUM_I915=yes
1920             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1921             gallium_require_drm_loader
1922             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1923             if test "x$MESA_LLVM" = x1; then
1924                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1925             fi
1926             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1927             gallium_check_st "i915/drm" "dri-i915"
1928             DRICOMMON_NEED_LIBDRM=yes
1929             ;;
1930         xilo)
1931             HAVE_GALLIUM_ILO=yes
1932             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1933             gallium_require_drm_loader
1934             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1935             gallium_check_st "intel/drm" "dri-ilo"
1936             DRICOMMON_NEED_LIBDRM=yes
1937             ;;
1938         xr300)
1939             HAVE_GALLIUM_R300=yes
1940             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1941             gallium_require_drm_loader
1942             gallium_require_llvm "Gallium R300"
1943             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1944             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1945             DRICOMMON_NEED_LIBDRM=yes
1946             ;;
1947         xr600)
1948             HAVE_GALLIUM_R600=yes
1949             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1950             gallium_require_drm_loader
1951             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1952             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1953                 radeon_llvm_check "r600g"
1954                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1955             fi
1956             if test "x$enable_r600_llvm" = xyes; then
1957                 USE_R600_LLVM_COMPILER=yes;
1958             fi
1959             if test "x$enable_opencl" = xyes; then
1960                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1961             fi
1962             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1963             DRICOMMON_NEED_LIBDRM=yes
1964             ;;
1965         xradeonsi)
1966             HAVE_GALLIUM_RADEONSI=yes
1967             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1968             gallium_require_drm_loader
1969             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1970             radeon_llvm_check "radeonsi"
1971             require_egl_drm "radeonsi"
1972             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1973             DRICOMMON_NEED_LIBDRM=yes
1974             ;;
1975         xnouveau)
1976             HAVE_GALLIUM_NOUVEAU=yes
1977             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1978             gallium_require_drm_loader
1979             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1980             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1981             DRICOMMON_NEED_LIBDRM=yes
1982             ;;
1983         xfreedreno)
1984             HAVE_GALLIUM_FREEDRENO=yes
1985             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1986             gallium_require_drm_loader
1987             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1988             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1989             DRICOMMON_NEED_LIBDRM=yes
1990             ;;
1991         xswrast)
1992             HAVE_GALLIUM_SOFTPIPE=yes
1993             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1994             if test "x$MESA_LLVM" = x1; then
1995                 HAVE_GALLIUM_LLVMPIPE=yes
1996                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1997             fi
1998
1999             if test "x$enable_dri" = xyes; then
2000                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2001             fi
2002             ;;
2003         *)
2004             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2005             ;;
2006         esac
2007     done
2008 fi
2009
2010 dnl Set LLVM_LIBS - This is done after the driver configuration so
2011 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2012 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2013 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2014 dnl this was causing the same libraries to be appear multiple times
2015 dnl in LLVM_LIBS.
2016
2017 if test "x$MESA_LLVM" != x0; then
2018
2019     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2020
2021     if test "x$enable_llvm_shared_libs" = xyes; then
2022         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2023         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2024         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2025
2026         if test "x$llvm_have_one_so" = xyes; then
2027             dnl LLVM was built using auto*, so there is only one shared object.
2028             LLVM_LIBS="-l$LLVM_SO_NAME"
2029         else
2030             dnl If LLVM was built with CMake, there will be one shared object per
2031             dnl component.
2032             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2033                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2034         Please make sure you have built llvm with the --enable-shared option
2035         and that your llvm libraries are installed in $LLVM_LIBDIR
2036         If you have installed your llvm libraries to a different directory you
2037         can use the --with-llvm-prefix= configure flag to specify this directory.
2038         NOTE: Mesa is attempting to use llvm shared libraries by default.
2039         If you do not want to build with llvm shared libraries and instead want to
2040         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2041         invocation and rebuild.])])
2042
2043            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2044            dnl install uses a shared object for each compoenent and we have
2045            dnl already added all of these objects to LLVM_LIBS.
2046         fi
2047     else
2048         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2049     fi
2050 fi
2051
2052 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2053 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2054 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2055 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2056 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2057 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2058 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2059                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2060 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2061 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2062 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2063 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2064
2065 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2066                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
2067                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2068 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2069                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2070                                                   && test "x$MESA_LLVM" = x1)
2071
2072 # NOTE: anything using xcb or other client side libs ends up in separate
2073 #       _CLIENT variables.  The pipe loader is built in two variants,
2074 #       one that is standalone and does not link any x client libs (for
2075 #       use by XA tracker in particular, but could be used in any case
2076 #       where communication with xserver is not desired).
2077 if test "x$enable_gallium_loader" = xyes; then
2078     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2079
2080     if test "x$NEED_WINSYS_XLIB" = xyes; then
2081         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2082     fi
2083
2084     if test "x$enable_dri" = xyes; then
2085         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2086     fi
2087
2088     if test "x$enable_gallium_drm_loader" = xyes; then
2089         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2090         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2091                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2092         if test "x$pipe_loader_have_xcb" = xyes; then
2093             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2094             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2095         fi
2096     fi
2097
2098     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2099     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2100
2101     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2102     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2103     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2104     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2105 fi
2106
2107 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2108 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2109 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2110 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2111 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2112 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2113
2114 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2115                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2116                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2117                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2118 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2119                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2120 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2121 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2122 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2123 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2124 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2125 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2126 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2127
2128 AC_SUBST([ELF_LIB])
2129
2130 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2131 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2132 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2133 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2134 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2135
2136 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2137 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2138 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2139
2140 AC_SUBST([VDPAU_MAJOR], 1)
2141 AC_SUBST([VDPAU_MINOR], 0)
2142
2143 AC_SUBST([XVMC_MAJOR], 1)
2144 AC_SUBST([XVMC_MINOR], 0)
2145
2146 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2147 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2148 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2149 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2150
2151 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2152 AC_SUBST([XA_MINOR], $XA_MINOR)
2153 AC_SUBST([XA_TINY], $XA_TINY)
2154 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2155
2156 dnl Restore LDFLAGS and CPPFLAGS
2157 LDFLAGS="$_SAVE_LDFLAGS"
2158 CPPFLAGS="$_SAVE_CPPFLAGS"
2159
2160 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2161 if test "x$acv_mesa_CLANG" = xyes; then
2162     CFLAGS="$CFLAGS -Qunused-arguments"
2163     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2164 fi
2165
2166 dnl Add user CFLAGS and CXXFLAGS
2167 CFLAGS="$CFLAGS $USER_CFLAGS"
2168 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2169
2170 dnl Substitute the config
2171 AC_CONFIG_FILES([Makefile
2172                 src/Makefile
2173                 src/egl/drivers/dri2/Makefile
2174                 src/egl/main/Makefile
2175                 src/egl/main/egl.pc
2176                 src/egl/wayland/Makefile
2177                 src/egl/wayland/wayland-drm/Makefile
2178                 src/egl/wayland/wayland-egl/Makefile
2179                 src/egl/wayland/wayland-egl/wayland-egl.pc
2180                 src/gallium/auxiliary/Makefile
2181                 src/gallium/auxiliary/pipe-loader/Makefile
2182                 src/gallium/drivers/Makefile
2183                 src/gallium/drivers/freedreno/Makefile
2184                 src/gallium/drivers/galahad/Makefile
2185                 src/gallium/drivers/i915/Makefile
2186                 src/gallium/drivers/identity/Makefile
2187                 src/gallium/drivers/ilo/Makefile
2188                 src/gallium/drivers/llvmpipe/Makefile
2189                 src/gallium/drivers/noop/Makefile
2190                 src/gallium/drivers/nouveau/Makefile
2191                 src/gallium/drivers/r300/Makefile
2192                 src/gallium/drivers/r600/Makefile
2193                 src/gallium/drivers/radeon/Makefile
2194                 src/gallium/drivers/radeonsi/Makefile
2195                 src/gallium/drivers/rbug/Makefile
2196                 src/gallium/drivers/softpipe/Makefile
2197                 src/gallium/drivers/svga/Makefile
2198                 src/gallium/drivers/trace/Makefile
2199                 src/gallium/state_trackers/Makefile
2200                 src/gallium/state_trackers/clover/Makefile
2201                 src/gallium/state_trackers/dri/Makefile
2202                 src/gallium/state_trackers/dri/drm/Makefile
2203                 src/gallium/state_trackers/dri/sw/Makefile
2204                 src/gallium/state_trackers/egl/Makefile
2205                 src/gallium/state_trackers/gbm/Makefile
2206                 src/gallium/state_trackers/glx/xlib/Makefile
2207                 src/gallium/state_trackers/omx/Makefile
2208                 src/gallium/state_trackers/osmesa/Makefile
2209                 src/gallium/state_trackers/vdpau/Makefile
2210                 src/gallium/state_trackers/vega/Makefile
2211                 src/gallium/state_trackers/xa/Makefile
2212                 src/gallium/state_trackers/xvmc/Makefile
2213                 src/gallium/targets/Makefile
2214                 src/gallium/targets/dri-freedreno/Makefile
2215                 src/gallium/targets/dri-i915/Makefile
2216                 src/gallium/targets/dri-ilo/Makefile
2217                 src/gallium/targets/dri-nouveau/Makefile
2218                 src/gallium/targets/dri-swrast/Makefile
2219                 src/gallium/targets/dri-vmwgfx/Makefile
2220                 src/gallium/targets/egl-static/Makefile
2221                 src/gallium/targets/gbm/Makefile
2222                 src/gallium/targets/opencl/Makefile
2223                 src/gallium/targets/xa/Makefile
2224                 src/gallium/targets/xa/xatracker.pc
2225                 src/gallium/targets/omx-nouveau/Makefile
2226                 src/gallium/targets/osmesa/Makefile
2227                 src/gallium/targets/osmesa/osmesa.pc
2228                 src/gallium/targets/pipe-loader/Makefile
2229                 src/gallium/targets/radeonsi/dri/Makefile
2230                 src/gallium/targets/radeonsi/omx/Makefile
2231                 src/gallium/targets/radeonsi/vdpau/Makefile
2232                 src/gallium/targets/r300/dri/Makefile
2233                 src/gallium/targets/r600/dri/Makefile
2234                 src/gallium/targets/r600/omx/Makefile
2235                 src/gallium/targets/r600/vdpau/Makefile
2236                 src/gallium/targets/r600/xvmc/Makefile
2237                 src/gallium/targets/libgl-xlib/Makefile
2238                 src/gallium/targets/vdpau-nouveau/Makefile
2239                 src/gallium/targets/xvmc-nouveau/Makefile
2240                 src/gallium/tests/trivial/Makefile
2241                 src/gallium/tests/unit/Makefile
2242                 src/gallium/winsys/Makefile
2243                 src/gallium/winsys/freedreno/drm/Makefile
2244                 src/gallium/winsys/i915/drm/Makefile
2245                 src/gallium/winsys/i915/sw/Makefile
2246                 src/gallium/winsys/intel/drm/Makefile
2247                 src/gallium/winsys/nouveau/drm/Makefile
2248                 src/gallium/winsys/radeon/drm/Makefile
2249                 src/gallium/winsys/svga/drm/Makefile
2250                 src/gallium/winsys/sw/dri/Makefile
2251                 src/gallium/winsys/sw/fbdev/Makefile
2252                 src/gallium/winsys/sw/null/Makefile
2253                 src/gallium/winsys/sw/wayland/Makefile
2254                 src/gallium/winsys/sw/wrapper/Makefile
2255                 src/gallium/winsys/sw/xlib/Makefile
2256                 src/gbm/Makefile
2257                 src/gbm/main/gbm.pc
2258                 src/glsl/Makefile
2259                 src/glx/Makefile
2260                 src/glx/apple/Makefile
2261                 src/glx/tests/Makefile
2262                 src/gtest/Makefile
2263                 src/loader/Makefile
2264                 src/mapi/Makefile
2265                 src/mapi/es1api/Makefile
2266                 src/mapi/es1api/glesv1_cm.pc
2267                 src/mapi/es2api/Makefile
2268                 src/mapi/es2api/glesv2.pc
2269                 src/mapi/glapi/Makefile
2270                 src/mapi/glapi/gen/Makefile
2271                 src/mapi/glapi/tests/Makefile
2272                 src/mapi/shared-glapi/Makefile
2273                 src/mapi/shared-glapi/tests/Makefile
2274                 src/mapi/vgapi/Makefile
2275                 src/mapi/vgapi/vg.pc
2276                 src/mesa/Makefile
2277                 src/mesa/gl.pc
2278                 src/mesa/drivers/dri/dri.pc
2279                 src/mesa/drivers/dri/common/Makefile
2280                 src/mesa/drivers/dri/common/xmlpool/Makefile
2281                 src/mesa/drivers/dri/i915/Makefile
2282                 src/mesa/drivers/dri/i965/Makefile
2283                 src/mesa/drivers/dri/Makefile
2284                 src/mesa/drivers/dri/nouveau/Makefile
2285                 src/mesa/drivers/dri/r200/Makefile
2286                 src/mesa/drivers/dri/radeon/Makefile
2287                 src/mesa/drivers/dri/swrast/Makefile
2288                 src/mesa/drivers/osmesa/Makefile
2289                 src/mesa/drivers/osmesa/osmesa.pc
2290                 src/mesa/drivers/x11/Makefile
2291                 src/mesa/main/tests/Makefile
2292                 src/mesa/main/tests/hash_table/Makefile])
2293
2294 dnl Sort the dirs alphabetically
2295 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2296 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2297 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2298 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2299
2300 AC_OUTPUT
2301
2302 dnl
2303 dnl Output some configuration info for the user
2304 dnl
2305 echo ""
2306 echo "        prefix:          $prefix"
2307 echo "        exec_prefix:     $exec_prefix"
2308 echo "        libdir:          $libdir"
2309 echo "        includedir:      $includedir"
2310
2311 dnl API info
2312 echo ""
2313 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2314 echo "        OpenVG:          $enable_openvg"
2315
2316 dnl Driver info
2317 echo ""
2318 case "x$enable_osmesa$enable_gallium_osmesa" in
2319 xnoyes)
2320         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2321         ;;
2322 xyesno)
2323         echo "        OSMesa:          lib$OSMESA_LIB"
2324         ;;
2325 xnono)
2326         echo "        OSMesa:          no"
2327         ;;
2328 esac
2329
2330 echo ""
2331 if test "x$enable_dri" != xno; then
2332         echo "        DRI platform:    $dri_platform"
2333         if test -z "$DRI_DIRS"; then
2334             echo "        DRI drivers:     no"
2335         else
2336             echo "        DRI drivers:     $DRI_DIRS"
2337         fi
2338         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2339 fi
2340
2341 case "x$enable_glx$enable_xlib_glx" in
2342 xyesyes)
2343     echo "        GLX:             Xlib-based"
2344     ;;
2345 xyesno)
2346     echo "        GLX:             DRI-based"
2347     ;;
2348 *)
2349     echo "        GLX:             $enable_glx"
2350     ;;
2351 esac
2352
2353 dnl EGL
2354 echo ""
2355 echo "        EGL:             $enable_egl"
2356 if test "$enable_egl" = yes; then
2357     echo "        EGL platforms:   $egl_platforms"
2358
2359     egl_drivers=""
2360     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2361         egl_drivers="$egl_drivers builtin:egl_dri2"
2362     fi
2363
2364     if test "x$enable_gallium_egl" = xyes; then
2365         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2366         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2367     else
2368         echo "        EGL drivers:    $egl_drivers"
2369     fi
2370 fi
2371
2372 echo ""
2373 if test "x$MESA_LLVM" = x1; then
2374     echo "        llvm:            yes"
2375     echo "        llvm-config:     $LLVM_CONFIG"
2376     echo "        llvm-version:    $LLVM_VERSION"
2377 else
2378     echo "        llvm:            no"
2379 fi
2380
2381 echo ""
2382 if test -n "$with_gallium_drivers"; then
2383     echo "        Gallium:         yes"
2384     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2385     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2386     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2387     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2388 else
2389     echo "        Gallium:         no"
2390 fi
2391
2392
2393 dnl Libraries
2394 echo ""
2395 echo "        Shared libs:     $enable_shared"
2396 echo "        Static libs:     $enable_static"
2397 echo "        Shared-glapi:    $enable_shared_glapi"
2398
2399 dnl Compiler options
2400 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2401 cflags=`echo $CFLAGS | \
2402     $SED 's/^ *//;s/  */ /;s/ *$//'`
2403 cxxflags=`echo $CXXFLAGS | \
2404     $SED 's/^ *//;s/  */ /;s/ *$//'`
2405 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2406 echo ""
2407 echo "        CFLAGS:          $cflags"
2408 echo "        CXXFLAGS:        $cxxflags"
2409 echo "        Macros:          $defines"
2410 echo ""
2411 if test "x$MESA_LLVM" = x1; then
2412     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2413     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2414     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2415     echo ""
2416 fi
2417 echo "        PYTHON2:         $PYTHON2"
2418
2419 echo ""
2420 echo "        Run '${MAKE-make}' to build Mesa"
2421 echo ""