configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll.a' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 283 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 284 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 285
 286 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 287 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 288 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 289 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 290 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 291 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 292 GLESv1_CM_LIB_GLOB='lib$(GLESv1_CM_LIB).*'${LIB_EXTENSION}'*'
 293 GLESv2_LIB_GLOB='lib$(GLESv2_LIB).*'${LIB_EXTENSION}'*'
 294 VG_LIB_GLOB='lib$(VG_LIB).*'${LIB_EXTENSION}'*'
 295
 296 AC_SUBST([GL_LIB_NAME])
 297 AC_SUBST([GLU_LIB_NAME])
 298 AC_SUBST([GLUT_LIB_NAME])
 299 AC_SUBST([GLW_LIB_NAME])
 300 AC_SUBST([OSMESA_LIB_NAME])
 301 AC_SUBST([EGL_LIB_NAME])
 302 AC_SUBST([GLESv1_CM_LIB_NAME])
 303 AC_SUBST([GLESv2_LIB_NAME])
 304 AC_SUBST([VG_LIB_NAME])
 305
 306 AC_SUBST([GL_LIB_GLOB])
 307 AC_SUBST([GLU_LIB_GLOB])
 308 AC_SUBST([GLUT_LIB_GLOB])
 309 AC_SUBST([GLW_LIB_GLOB])
 310 AC_SUBST([OSMESA_LIB_GLOB])
 311 AC_SUBST([EGL_LIB_GLOB])
 312 AC_SUBST([GLESv1_CM_LIB_GLOB])
 313 AC_SUBST([GLESv2_LIB_GLOB])
 314 AC_SUBST([VG_LIB_GLOB])
 315
 316 dnl
 317 dnl Arch/platform-specific settings
 318 dnl
 319 AC_ARG_ENABLE([asm],
 320     [AS_HELP_STRING([--disable-asm],
 321         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 322     [enable_asm="$enableval"],
 323     [enable_asm=yes]
 324 )
 325 asm_arch=""
 326 ASM_FLAGS=""
 327 MESA_ASM_SOURCES=""
 328 GLAPI_ASM_SOURCES=""
 329 AC_MSG_CHECKING([whether to enable assembly])
 330 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 331 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 332 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 333     case "$host_cpu" in
 334     i?86 | x86_64)
 335         enable_asm=no
 336         AC_MSG_RESULT([no, cross compiling])
 337         ;;
 338     esac
 339 fi
 340 # check for supported arches
 341 if test "x$enable_asm" = xyes; then
 342     case "$host_cpu" in
 343     i?86)
 344         case "$host_os" in
 345         linux* | *freebsd* | dragonfly*)
 346             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 347             ;;
 348         esac
 349         ;;
 350     x86_64)
 351         case "$host_os" in
 352         linux* | *freebsd* | dragonfly*)
 353             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 354             ;;
 355         esac
 356         ;;
 357     powerpc)
 358         case "$host_os" in
 359         linux*)
 360             asm_arch=ppc
 361             ;;
 362         esac
 363         ;;
 364     sparc*)
 365         case "$host_os" in
 366         linux*)
 367             asm_arch=sparc
 368             ;;
 369         esac
 370         ;;
 371     esac
 372
 373     case "$asm_arch" in
 374     x86)
 375         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 376         MESA_ASM_SOURCES='$(X86_SOURCES)'
 377         GLAPI_ASM_SOURCES='$(X86_API)'
 378         AC_MSG_RESULT([yes, x86])
 379         ;;
 380     x86_64)
 381         ASM_FLAGS="-DUSE_X86_64_ASM"
 382         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 383         GLAPI_ASM_SOURCES='$(X86-64_API)'
 384         AC_MSG_RESULT([yes, x86_64])
 385         ;;
 386     ppc)
 387         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 388         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 389         AC_MSG_RESULT([yes, ppc])
 390         ;;
 391     sparc)
 392         ASM_FLAGS="-DUSE_SPARC_ASM"
 393         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 394         GLAPI_ASM_SOURCES='$(SPARC_API)'
 395         AC_MSG_RESULT([yes, sparc])
 396         ;;
 397     *)
 398         AC_MSG_RESULT([no, platform not supported])
 399         ;;
 400     esac
 401 fi
 402 AC_SUBST([ASM_FLAGS])
 403 AC_SUBST([MESA_ASM_SOURCES])
 404 AC_SUBST([GLAPI_ASM_SOURCES])
 405
 406 dnl PIC code macro
 407 MESA_PIC_FLAGS
 408
 409 dnl Check to see if dlopen is in default libraries (like Solaris, which
 410 dnl has it in libc), or if libdl is needed to get it.
 411 AC_CHECK_FUNC([dlopen], [],
 412     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 413
 414 dnl See if posix_memalign is available
 415 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 416
 417 dnl SELinux awareness.
 418 AC_ARG_ENABLE([selinux],
 419     [AS_HELP_STRING([--enable-selinux],
 420         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 421     [MESA_SELINUX="$enableval"],
 422     [MESA_SELINUX=no])
 423 if test "x$enable_selinux" = "xyes"; then
 424     AC_CHECK_HEADER([selinux/selinux.h],[],
 425                     [AC_MSG_ERROR([SELinux headers not found])])
 426     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 427                  [AC_MSG_ERROR([SELinux library not found])])
 428     SELINUX_LIBS="-lselinux"
 429     DEFINES="$DEFINES -DMESA_SELINUX"
 430 fi
 431
 432 dnl
 433 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 434 dnl More later: fbdev, ...
 435 dnl
 436 default_driver="xlib"
 437
 438 case "$host_os" in
 439 linux*)
 440     case "$host_cpu" in
 441     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 442     esac
 443     ;;
 444 *freebsd* | dragonfly*)
 445     case "$host_cpu" in
 446     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 447     esac
 448     ;;
 449 esac
 450
 451 AC_ARG_WITH([driver],
 452     [AS_HELP_STRING([--with-driver=DRIVER],
 453         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 454     [mesa_driver="$withval"],
 455     [mesa_driver="$default_driver"])
 456 dnl Check for valid option
 457 case "x$mesa_driver" in
 458 xxlib|xdri|xosmesa)
 459     ;;
 460 *)
 461     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 462     ;;
 463 esac
 464
 465 dnl
 466 dnl Driver specific build directories
 467 dnl
 468
 469 dnl this variable will be prepended to SRC_DIRS and is not exported
 470 CORE_DIRS="mapi/glapi glsl mesa"
 471
 472 SRC_DIRS=""
 473 GLU_DIRS="sgi"
 474 GALLIUM_DIRS="auxiliary drivers state_trackers"
 475 GALLIUM_TARGET_DIRS=""
 476 GALLIUM_WINSYS_DIRS="sw"
 477 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug identity"
 478 GALLIUM_STATE_TRACKERS_DIRS=""
 479
 480 case "$mesa_driver" in
 481 xlib)
 482     DRIVER_DIRS="x11"
 483     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 484     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 485     ;;
 486 dri)
 487     SRC_DIRS="$SRC_DIRS glx"
 488     DRIVER_DIRS="dri"
 489     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 490     ;;
 491 osmesa)
 492     DRIVER_DIRS="osmesa"
 493     ;;
 494 esac
 495 AC_SUBST([SRC_DIRS])
 496 AC_SUBST([GLU_DIRS])
 497 AC_SUBST([DRIVER_DIRS])
 498 AC_SUBST([GALLIUM_DIRS])
 499 AC_SUBST([GALLIUM_TARGET_DIRS])
 500 AC_SUBST([GALLIUM_WINSYS_DIRS])
 501 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 502 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 503 AC_SUBST([MESA_LLVM])
 504
 505 dnl
 506 dnl Find out if X is available. The variable have_x is set if libX11 is
 507 dnl found to mimic AC_PATH_XTRA.
 508 dnl
 509 if test -n "$PKG_CONFIG"; then
 510     AC_MSG_CHECKING([pkg-config files for X11 are available])
 511     PKG_CHECK_EXISTS([x11],[
 512         x11_pkgconfig=yes
 513         have_x=yes
 514         ],[
 515         x11_pkgconfig=no
 516     ])
 517     AC_MSG_RESULT([$x11_pkgconfig])
 518 else
 519     x11_pkgconfig=no
 520 fi
 521 dnl Use the autoconf macro if no pkg-config files
 522 if test "$x11_pkgconfig" = yes; then
 523     PKG_CHECK_MODULES([X11], [x11])
 524 else
 525     AC_PATH_XTRA
 526     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 527     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 528     AC_SUBST([X11_CFLAGS])
 529     AC_SUBST([X11_LIBS])
 530 fi
 531
 532 dnl Try to tell the user that the --x-* options are only used when
 533 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 534 m4_divert_once([HELP_BEGIN],
 535 [These options are only used when the X libraries cannot be found by the
 536 pkg-config utility.])
 537
 538 dnl We need X for xlib and dri, so bomb now if it's not found
 539 case "$mesa_driver" in
 540 xlib|dri)
 541     if test "$no_x" = yes; then
 542         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 543     fi
 544     ;;
 545 esac
 546
 547 dnl XCB - this is only used for GLX right now
 548 AC_ARG_ENABLE([xcb],
 549     [AS_HELP_STRING([--enable-xcb],
 550         [use XCB for GLX @<:@default=disabled@:>@])],
 551     [enable_xcb="$enableval"],
 552     [enable_xcb=no])
 553 if test "x$enable_xcb" = xyes; then
 554     DEFINES="$DEFINES -DUSE_XCB"
 555 else
 556     enable_xcb=no
 557 fi
 558
 559 dnl
 560 dnl libGL configuration per driver
 561 dnl
 562 case "$mesa_driver" in
 563 xlib)
 564     if test "$x11_pkgconfig" = yes; then
 565         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 566         GL_PC_REQ_PRIV="x11 xext"
 567         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 568         GL_LIB_DEPS="$XLIBGL_LIBS"
 569     else
 570         # should check these...
 571         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 572         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 573         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 574         GL_PC_CFLAGS="$X11_INCLUDES"
 575     fi
 576     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 577     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 578
 579     # if static, move the external libraries to the programs
 580     # and empty the libraries for libGL
 581     if test "$enable_static" = yes; then
 582         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 583         GL_LIB_DEPS=""
 584     fi
 585     ;;
 586 dri)
 587     # DRI must be shared, I think
 588     if test "$enable_static" = yes; then
 589         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 590     fi
 591
 592     # Check for libdrm
 593     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 594     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 595     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 596     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 597     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 598
 599     # find the DRI deps for libGL
 600     if test "$x11_pkgconfig" = yes; then
 601         # add xcb modules if necessary
 602         dri_modules="x11 xext xxf86vm xdamage xfixes"
 603         if test "$enable_xcb" = yes; then
 604             dri_modules="$dri_modules x11-xcb xcb-glx"
 605         fi
 606
 607         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 608         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 609         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 610         GL_LIB_DEPS="$DRIGL_LIBS"
 611     else
 612         # should check these...
 613         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 614         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 615         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 616         GL_PC_CFLAGS="$X11_INCLUDES"
 617
 618         # XCB can only be used from pkg-config
 619         if test "$enable_xcb" = yes; then
 620             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 621             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 622             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 623             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 624         fi
 625     fi
 626
 627     # need DRM libs, -lpthread, etc.
 628     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 629     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 630     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 631     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 632     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 633     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 634     ;;
 635 osmesa)
 636     # No libGL for osmesa
 637     GL_LIB_DEPS=""
 638     ;;
 639 esac
 640 AC_SUBST([GL_LIB_DEPS])
 641 AC_SUBST([GL_PC_REQ_PRIV])
 642 AC_SUBST([GL_PC_LIB_PRIV])
 643 AC_SUBST([GL_PC_CFLAGS])
 644 AC_SUBST([DRI_PC_REQ_PRIV])
 645 AC_SUBST([GLESv1_LIB_DEPS])
 646 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 647 AC_SUBST([GLESv2_LIB_DEPS])
 648 AC_SUBST([GLESv2_PC_LIB_PRIV])
 649
 650
 651 dnl
 652 dnl More X11 setup
 653 dnl
 654 if test "$mesa_driver" = xlib; then
 655     DEFINES="$DEFINES -DUSE_XSHM"
 656 fi
 657
 658 dnl
 659 dnl More DRI setup
 660 dnl
 661 AC_ARG_ENABLE([glx-tls],
 662     [AS_HELP_STRING([--enable-glx-tls],
 663         [enable TLS support in GLX @<:@default=disabled@:>@])],
 664     [GLX_USE_TLS="$enableval"],
 665     [GLX_USE_TLS=no])
 666 dnl Directory for DRI drivers
 667 AC_ARG_WITH([dri-driverdir],
 668     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 669         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 670     [DRI_DRIVER_INSTALL_DIR="$withval"],
 671     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 672 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 673 dnl Extra search path for DRI drivers
 674 AC_ARG_WITH([dri-searchpath],
 675     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 676         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 677     [DRI_DRIVER_SEARCH_DIR="$withval"],
 678     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 679 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 680 dnl Direct rendering or just indirect rendering
 681 AC_ARG_ENABLE([driglx-direct],
 682     [AS_HELP_STRING([--disable-driglx-direct],
 683         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 684     [driglx_direct="$enableval"],
 685     [driglx_direct="yes"])
 686 dnl Which drivers to build - default is chosen by platform
 687 AC_ARG_WITH([dri-drivers],
 688     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 689         [comma delimited DRI drivers list, e.g.
 690         "swrast,i965,radeon" @<:@default=auto@:>@])],
 691     [with_dri_drivers="$withval"],
 692     [with_dri_drivers=yes])
 693 if test "x$with_dri_drivers" = x; then
 694     with_dri_drivers=no
 695 fi
 696
 697 dnl Determine which APIs to support
 698 AC_ARG_ENABLE([opengl],
 699     [AS_HELP_STRING([--disable-opengl],
 700         [disable support for standard OpenGL API @<:@default=no@:>@])],
 701     [enable_opengl="$enableval"],
 702     [enable_opengl=yes])
 703 AC_ARG_ENABLE([gles1],
 704     [AS_HELP_STRING([--enable-gles1],
 705         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 706     [enable_gles1="$enableval"],
 707     [enable_gles1=no])
 708 AC_ARG_ENABLE([gles2],
 709     [AS_HELP_STRING([--enable-gles2],
 710         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 711     [enable_gles2="$enableval"],
 712     [enable_gles2=no])
 713 AC_ARG_ENABLE([gles-overlay],
 714     [AS_HELP_STRING([--enable-gles-overlay],
 715         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 716     [enable_gles_overlay="$enableval"],
 717     [enable_gles_overlay=no])
 718
 719 API_DEFINES=""
 720 GLES_OVERLAY=0
 721 if test "x$enable_opengl" = xno; then
 722     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 723 else
 724     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 725 fi
 726 if test "x$enable_gles1" = xyes; then
 727     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 728 fi
 729 if test "x$enable_gles2" = xyes; then
 730     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 731 fi
 732 if test "x$enable_gles_overlay" = xyes -o \
 733     "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 734     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
 735     if test "x$enable_gles_overlay" = xyes; then
 736         GLES_OVERLAY=1
 737     fi
 738 fi
 739 AC_SUBST([API_DEFINES])
 740 AC_SUBST([GLES_OVERLAY])
 741
 742 dnl If $with_dri_drivers is yes, directories will be added through
 743 dnl platform checks
 744 DRI_DIRS=""
 745 case "$with_dri_drivers" in
 746 no) ;;
 747 yes)
 748     DRI_DIRS="yes"
 749     ;;
 750 *)
 751     # verify the requested driver directories exist
 752     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 753     for driver in $dri_drivers; do
 754         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 755             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 756     done
 757     DRI_DIRS="$dri_drivers"
 758     ;;
 759 esac
 760
 761 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 762 if test "$mesa_driver" = dri; then
 763     # Use TLS in GLX?
 764     if test "x$GLX_USE_TLS" = xyes; then
 765         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 766     fi
 767
 768     # Platform specific settings and drivers to build
 769     case "$host_os" in
 770     linux*)
 771         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 772         if test "x$driglx_direct" = xyes; then
 773             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 774         fi
 775         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 776
 777         case "$host_cpu" in
 778         x86_64)
 779             # sis is missing because they have not be converted to use
 780             # the new interface.  i810 are missing because there is no
 781             # x86-64 system where they could *ever* be used.
 782             if test "x$DRI_DIRS" = "xyes"; then
 783                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 784                     savage tdfx unichrome swrast"
 785             fi
 786             ;;
 787         powerpc*)
 788             # Build only the drivers for cards that exist on PowerPC.
 789             # At some point MGA will be added, but not yet.
 790             if test "x$DRI_DIRS" = "xyes"; then
 791                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 792             fi
 793             ;;
 794         sparc*)
 795             # Build only the drivers for cards that exist on sparc`
 796             if test "x$DRI_DIRS" = "xyes"; then
 797                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 798             fi
 799             ;;
 800         esac
 801         ;;
 802     freebsd* | dragonfly*)
 803         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 804         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 805         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 806         if test "x$driglx_direct" = xyes; then
 807             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 808         fi
 809         if test "x$GXX" = xyes; then
 810             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 811         fi
 812
 813         if test "x$DRI_DIRS" = "xyes"; then
 814             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 815                 unichrome savage sis swrast"
 816         fi
 817         ;;
 818     gnu*)
 819         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 820         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 821         ;;
 822     solaris*)
 823         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 824         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 825         if test "x$driglx_direct" = xyes; then
 826             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 827         fi
 828         ;;
 829     esac
 830
 831     # default drivers
 832     if test "x$DRI_DIRS" = "xyes"; then
 833         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 834             savage sis tdfx unichrome swrast"
 835     fi
 836
 837     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 838
 839     # Check for expat
 840     EXPAT_INCLUDES=""
 841     EXPAT_LIB=-lexpat
 842     AC_ARG_WITH([expat],
 843         [AS_HELP_STRING([--with-expat=DIR],
 844             [expat install directory])],[
 845         EXPAT_INCLUDES="-I$withval/include"
 846         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 847         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 848         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 849         ])
 850     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 851     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 852         [AC_MSG_ERROR([Expat required for DRI.])])
 853
 854     # put all the necessary libs together
 855     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 856 fi
 857 AC_SUBST([DRI_DIRS])
 858 AC_SUBST([EXPAT_INCLUDES])
 859 AC_SUBST([DRI_LIB_DEPS])
 860
 861 case $DRI_DIRS in
 862 *i915*|*i965*)
 863     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.21])
 864     ;;
 865 esac
 866
 867 case $DRI_DIRS in
 868 *radeon*|*r200*|*r300*|*r600*)
 869     PKG_CHECK_MODULES([LIBDRM_RADEON],
 870                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 871                       HAVE_LIBDRM_RADEON=yes,
 872                       HAVE_LIBDRM_RADEON=no)
 873
 874     if test "$HAVE_LIBDRM_RADEON" = yes; then
 875         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 876         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 877     fi
 878     ;;
 879 esac
 880 AC_SUBST([RADEON_CFLAGS])
 881 AC_SUBST([RADEON_LDFLAGS])
 882
 883
 884 dnl
 885 dnl OSMesa configuration
 886 dnl
 887 if test "$mesa_driver" = xlib; then
 888     default_gl_osmesa=yes
 889 else
 890     default_gl_osmesa=no
 891 fi
 892 AC_ARG_ENABLE([gl-osmesa],
 893     [AS_HELP_STRING([--enable-gl-osmesa],
 894         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
 895     [gl_osmesa="$enableval"],
 896     [gl_osmesa="$default_gl_osmesa"])
 897 if test "x$gl_osmesa" = xyes; then
 898     if test "$mesa_driver" = osmesa; then
 899         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 900     else
 901         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 902     fi
 903 fi
 904
 905 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 906 AC_ARG_WITH([osmesa-bits],
 907     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 908         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 909     [osmesa_bits="$withval"],
 910     [osmesa_bits=8])
 911 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 912     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 913     osmesa_bits=8
 914 fi
 915 case "x$osmesa_bits" in
 916 x8)
 917     OSMESA_LIB=OSMesa
 918     ;;
 919 x16|x32)
 920     OSMESA_LIB="OSMesa$osmesa_bits"
 921     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 922     ;;
 923 *)
 924     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 925     ;;
 926 esac
 927 AC_SUBST([OSMESA_LIB])
 928
 929 case "$DRIVER_DIRS" in
 930 *osmesa*)
 931     # only link libraries with osmesa if shared
 932     if test "$enable_static" = no; then
 933         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 934     else
 935         OSMESA_LIB_DEPS=""
 936     fi
 937     OSMESA_MESA_DEPS=""
 938     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 939     ;;
 940 esac
 941 AC_SUBST([OSMESA_LIB_DEPS])
 942 AC_SUBST([OSMESA_MESA_DEPS])
 943 AC_SUBST([OSMESA_PC_REQ])
 944 AC_SUBST([OSMESA_PC_LIB_PRIV])
 945
 946 dnl
 947 dnl EGL configuration
 948 dnl
 949 AC_ARG_ENABLE([egl],
 950     [AS_HELP_STRING([--disable-egl],
 951         [disable EGL library @<:@default=enabled@:>@])],
 952     [enable_egl="$enableval"],
 953     [enable_egl=yes])
 954 if test "x$enable_egl" = xyes; then
 955     SRC_DIRS="$SRC_DIRS egl"
 956     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 957     EGL_DRIVERS_DIRS=""
 958     if test "$enable_static" != yes; then
 959         # build egl_glx when libGL is built
 960         if test "$mesa_driver" != osmesa; then
 961             EGL_DRIVERS_DIRS="glx"
 962         fi
 963
 964         if test "$mesa_driver" = dri; then
 965             # build egl_dri2 when xcb-dri2 is available
 966             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
 967                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
 968             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
 969                           [have_libudev=yes],[have_libudev=no])
 970
 971             if test "$have_xcb_dri2" = yes; then
 972                 EGL_DRIVER_DRI2=dri2
 973                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
 974                 if test "$have_libudev" = yes; then
 975                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 976                 fi
 977             fi
 978         fi
 979
 980         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
 981     fi
 982 fi
 983 AC_SUBST([EGL_LIB_DEPS])
 984 AC_SUBST([EGL_DRIVERS_DIRS])
 985
 986 dnl
 987 dnl GLU configuration
 988 dnl
 989 AC_ARG_ENABLE([glu],
 990     [AS_HELP_STRING([--disable-glu],
 991         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 992     [enable_glu="$enableval"],
 993     [enable_glu=yes])
 994 if test "x$enable_glu" = xyes; then
 995     SRC_DIRS="$SRC_DIRS glu"
 996
 997     case "$mesa_driver" in
 998     osmesa)
 999         # Link libGLU to libOSMesa instead of libGL
1000         GLU_LIB_DEPS=""
1001         GLU_PC_REQ="osmesa"
1002         if test "$enable_static" = no; then
1003             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1004         else
1005             GLU_MESA_DEPS=""
1006         fi
1007         ;;
1008     *)
1009         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1010         GLU_PC_REQ="gl"
1011         GLU_PC_LIB_PRIV="-lm"
1012         if test "$enable_static" = no; then
1013             GLU_LIB_DEPS="-lm"
1014             GLU_MESA_DEPS='-l$(GL_LIB)'
1015         else
1016             GLU_LIB_DEPS=""
1017             GLU_MESA_DEPS=""
1018             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1019         fi
1020         ;;
1021     esac
1022 fi
1023 if test "$enable_static" = no; then
1024     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1025 fi
1026 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1027 AC_SUBST([GLU_LIB_DEPS])
1028 AC_SUBST([GLU_MESA_DEPS])
1029 AC_SUBST([GLU_PC_REQ])
1030 AC_SUBST([GLU_PC_REQ_PRIV])
1031 AC_SUBST([GLU_PC_LIB_PRIV])
1032 AC_SUBST([GLU_PC_CFLAGS])
1033
1034 dnl
1035 dnl GLw configuration
1036 dnl
1037 AC_ARG_ENABLE([glw],
1038     [AS_HELP_STRING([--disable-glw],
1039         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1040     [enable_glw="$enableval"],
1041     [enable_glw=yes])
1042 dnl Don't build GLw on osmesa
1043 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1044     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1045     enable_glw=no
1046 fi
1047 AC_ARG_ENABLE([motif],
1048     [AS_HELP_STRING([--enable-motif],
1049         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1050     [enable_motif="$enableval"],
1051     [enable_motif=no])
1052
1053 if test "x$enable_glw" = xyes; then
1054     SRC_DIRS="$SRC_DIRS glw"
1055     if test "$x11_pkgconfig" = yes; then
1056         PKG_CHECK_MODULES([GLW],[x11 xt])
1057         GLW_PC_REQ_PRIV="x11 xt"
1058         GLW_LIB_DEPS="$GLW_LIBS"
1059     else
1060         # should check these...
1061         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1062         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1063         GLW_PC_CFLAGS="$X11_INCLUDES"
1064     fi
1065
1066     GLW_SOURCES="GLwDrawA.c"
1067     MOTIF_CFLAGS=
1068     if test "x$enable_motif" = xyes; then
1069         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1070         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1071         if test "x$MOTIF_CONFIG" != xno; then
1072             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1073             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1074         else
1075             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1076                 [AC_MSG_ERROR([Can't locate Motif headers])])
1077             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1078                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1079         fi
1080         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1081         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1082         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1083         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1084     fi
1085
1086     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1087     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1088     if test "$enable_static" = no; then
1089         GLW_MESA_DEPS='-l$(GL_LIB)'
1090         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1091     else
1092         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1093         GLW_LIB_DEPS=""
1094         GLW_MESA_DEPS=""
1095     fi
1096 fi
1097 AC_SUBST([GLW_LIB_DEPS])
1098 AC_SUBST([GLW_MESA_DEPS])
1099 AC_SUBST([GLW_SOURCES])
1100 AC_SUBST([MOTIF_CFLAGS])
1101 AC_SUBST([GLW_PC_REQ_PRIV])
1102 AC_SUBST([GLW_PC_LIB_PRIV])
1103 AC_SUBST([GLW_PC_CFLAGS])
1104
1105 dnl
1106 dnl GLUT configuration
1107 dnl
1108 if test -f "$srcdir/include/GL/glut.h"; then
1109     default_glut=yes
1110 else
1111     default_glut=no
1112 fi
1113 AC_ARG_ENABLE([glut],
1114     [AS_HELP_STRING([--disable-glut],
1115         [enable GLUT library @<:@default=enabled if source available@:>@])],
1116     [enable_glut="$enableval"],
1117     [enable_glut="$default_glut"])
1118
1119 dnl Can't build glut if GLU not available
1120 if test "x$enable_glu$enable_glut" = xnoyes; then
1121     AC_MSG_WARN([Disabling glut since GLU is disabled])
1122     enable_glut=no
1123 fi
1124 dnl Don't build glut on osmesa
1125 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1126     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1127     enable_glut=no
1128 fi
1129
1130 if test "x$enable_glut" = xyes; then
1131     SRC_DIRS="$SRC_DIRS glut/glx"
1132     if test "$x11_pkgconfig" = yes; then
1133         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1134         GLUT_PC_REQ_PRIV="x11 xmu xi"
1135         GLUT_LIB_DEPS="$GLUT_LIBS"
1136     else
1137         # should check these...
1138         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1139         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1140         GLUT_PC_CFLAGS="$X11_INCLUDES"
1141     fi
1142     if test "x$GCC" = xyes; then
1143         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1144     fi
1145     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1146     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1147
1148     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1149     if test "$enable_static" = no; then
1150         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1151     else
1152         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1153         GLUT_LIB_DEPS=""
1154         GLUT_MESA_DEPS=""
1155     fi
1156 fi
1157 AC_SUBST([GLUT_LIB_DEPS])
1158 AC_SUBST([GLUT_MESA_DEPS])
1159 AC_SUBST([GLUT_CFLAGS])
1160 AC_SUBST([GLUT_PC_REQ_PRIV])
1161 AC_SUBST([GLUT_PC_LIB_PRIV])
1162 AC_SUBST([GLUT_PC_CFLAGS])
1163
1164 dnl
1165 dnl Program library dependencies
1166 dnl    Only libm is added here if necessary as the libraries should
1167 dnl    be pulled in by the linker
1168 dnl
1169 if test "x$APP_LIB_DEPS" = x; then
1170     case "$host_os" in
1171     solaris*)
1172         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1173         ;;
1174     cygwin*)
1175         APP_LIB_DEPS="-lX11"
1176         ;;
1177     *)
1178         APP_LIB_DEPS="-lm"
1179         ;;
1180     esac
1181 fi
1182 AC_SUBST([APP_LIB_DEPS])
1183 AC_SUBST([PROGRAM_DIRS])
1184
1185 dnl
1186 dnl Gallium configuration
1187 dnl
1188 AC_ARG_ENABLE([gallium],
1189     [AS_HELP_STRING([--disable-gallium],
1190         [build gallium @<:@default=enabled@:>@])],
1191     [enable_gallium="$enableval"],
1192     [enable_gallium=yes])
1193 if test "x$enable_gallium" = xyes; then
1194     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1195     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1196                 [HAS_UDIS86="no"])
1197     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1198 fi
1199
1200 AC_SUBST([LLVM_CFLAGS])
1201 AC_SUBST([LLVM_LIBS])
1202 AC_SUBST([LLVM_LDFLAGS])
1203 AC_SUBST([LLVM_VERSION])
1204
1205 VG_LIB_DEPS=""
1206 EGL_CLIENT_APIS='$(GL_LIB)'
1207 if test "x$enable_gles_overlay" = xyes; then
1208     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1209 fi
1210
1211 dnl
1212 dnl Gallium state trackers configuration
1213 dnl
1214 AC_ARG_WITH([state-trackers],
1215     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1216         [comma delimited state_trackers list, e.g.
1217         "egl,glx" @<:@default=auto@:>@])],
1218     [with_state_trackers="$withval"],
1219     [with_state_trackers=yes])
1220
1221 case "$with_state_trackers" in
1222 no)
1223     GALLIUM_STATE_TRACKERS_DIRS=""
1224     ;;
1225 yes)
1226     # look at what else is built
1227     case "$mesa_driver" in
1228     xlib)
1229         GALLIUM_STATE_TRACKERS_DIRS=glx
1230         ;;
1231     dri)
1232         GALLIUM_STATE_TRACKERS_DIRS="dri"
1233         HAVE_ST_DRI="yes"
1234         if test "x$enable_egl" = xyes; then
1235             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1236             HAVE_ST_EGL="yes"
1237         fi
1238         # Have only tested st/xorg on 1.6.0 servers
1239         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1240             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1241             HAVE_ST_XORG="no")
1242         ;;
1243     esac
1244     ;;
1245 *)
1246     # verify the requested state tracker exist
1247     state_trackers=""
1248     _state_trackers=`IFS=', '; echo $with_state_trackers`
1249     for tracker in $_state_trackers; do
1250         case "$tracker" in
1251         dri)
1252             if test "x$mesa_driver" != xdri; then
1253                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1254             fi
1255             HAVE_ST_DRI="yes"
1256             ;;
1257         egl)
1258             if test "x$enable_egl" != xyes; then
1259                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1260             fi
1261             HAVE_ST_EGL="yes"
1262             ;;
1263         xorg)
1264             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1265             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1266             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1267             HAVE_ST_XORG="yes"
1268             ;;
1269         es)
1270             AC_MSG_WARN([state tracker 'es' has been replaced by --enable-gles-overlay])
1271
1272             if test "x$enable_gles_overlay" != xyes; then
1273                 if test "x$enable_gles1" != xyes -a "x$enable_gles2" != xyes; then
1274                     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
1275                 fi
1276                 GLES_OVERLAY=1
1277                 EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1278             fi
1279             tracker=""
1280             ;;
1281         vega)
1282             CORE_DIRS="$CORE_DIRS mapi/vgapi"
1283             VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1284             EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1285             ;;
1286         esac
1287
1288         if test -n "$tracker"; then
1289             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1290                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1291             if test -n "$state_trackers"; then
1292                 state_trackers="$state_trackers $tracker"
1293             else
1294                 state_trackers="$tracker"
1295             fi
1296         fi
1297     done
1298     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1299     ;;
1300 esac
1301
1302 AC_SUBST([VG_LIB_DEPS])
1303 AC_SUBST([EGL_CLIENT_APIS])
1304
1305 if test "x$HAVE_ST_EGL" = xyes; then
1306         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1307         # define GLX_DIRECT_RENDERING even when the driver is not dri
1308         if test "x$mesa_driver" != xdri -a "x$driglx_direct" = xyes; then
1309             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1310         fi
1311 fi
1312
1313 if test "x$HAVE_ST_XORG" = xyes; then
1314     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1315         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1316         HAVE_XEXTPROTO_71="no")
1317 fi
1318
1319 AC_ARG_WITH([egl-platforms],
1320     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1321         [comma delimited native platforms libEGL supports, e.g.
1322         "x11,kms" @<:@default=auto@:>@])],
1323     [with_egl_platforms="$withval"],
1324     [with_egl_platforms=yes])
1325 AC_ARG_WITH([egl-displays],
1326     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1327         [DEPRECATED.  Use --with-egl-platforms instead])],
1328     [with_egl_platforms="$withval"])
1329
1330 EGL_PLATFORMS=""
1331 case "$with_egl_platforms" in
1332 yes)
1333     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1334         EGL_PLATFORMS="x11"
1335     fi
1336     ;;
1337 *)
1338     if test "x$enable_egl" != xyes; then
1339         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1340     fi
1341     # verify the requested driver directories exist
1342     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1343     for plat in $egl_platforms; do
1344         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1345             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1346         if test "$plat" = "fbdev"; then
1347                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1348         fi
1349     done
1350     EGL_PLATFORMS="$egl_platforms"
1351     ;;
1352 esac
1353 AC_SUBST([EGL_PLATFORMS])
1354
1355 AC_ARG_WITH([egl-driver-dir],
1356     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1357                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1358     [EGL_DRIVER_INSTALL_DIR="$withval"],
1359     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1360 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1361
1362 AC_ARG_WITH([xorg-driver-dir],
1363     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1364                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1365     [XORG_DRIVER_INSTALL_DIR="$withval"],
1366     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1367 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1368
1369 AC_ARG_WITH([max-width],
1370     [AS_HELP_STRING([--with-max-width=N],
1371                     [Maximum framebuffer width (4096)])],
1372     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1373      AS_IF([test "${withval}" -gt "4096"],
1374            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1375 )
1376 AC_ARG_WITH([max-height],
1377     [AS_HELP_STRING([--with-max-height=N],
1378                     [Maximum framebuffer height (4096)])],
1379     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1380      AS_IF([test "${withval}" -gt "4096"],
1381            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1382 )
1383
1384 dnl
1385 dnl Gallium LLVM
1386 dnl
1387 AC_ARG_ENABLE([gallium-llvm],
1388     [AS_HELP_STRING([--enable-gallium-llvm],
1389         [build gallium LLVM support @<:@default=disabled@:>@])],
1390     [enable_gallium_llvm="$enableval"],
1391     [enable_gallium_llvm=auto])
1392 if test "x$enable_gallium_llvm" = xyes; then
1393     if test "x$LLVM_CONFIG" != xno; then
1394         LLVM_VERSION=`$LLVM_CONFIG --version`
1395         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1396         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1397
1398         if test "x$HAS_UDIS86" != xno; then
1399             LLVM_LIBS="$LLVM_LIBS -ludis86"
1400             DEFINES="$DEFINES -DHAVE_UDIS86"
1401         fi
1402         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1403         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1404         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1405         MESA_LLVM=1
1406     else
1407         MESA_LLVM=0
1408     fi
1409 else
1410     MESA_LLVM=0
1411 fi
1412
1413 dnl
1414 dnl Gallium helper functions
1415 dnl
1416 gallium_check_st() {
1417     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1418          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1419     fi
1420     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1421          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1422     fi
1423     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1424          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1425     fi
1426 }
1427
1428
1429 dnl
1430 dnl Gallium SVGA configuration
1431 dnl
1432 AC_ARG_ENABLE([gallium-svga],
1433     [AS_HELP_STRING([--enable-gallium-svga],
1434         [build gallium SVGA @<:@default=disabled@:>@])],
1435     [enable_gallium_svga="$enableval"],
1436     [enable_gallium_svga=auto])
1437 if test "x$enable_gallium_svga" = xyes; then
1438     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1439     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1440 elif test "x$enable_gallium_svga" = xauto; then
1441     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1442 fi
1443
1444 dnl
1445 dnl Gallium i915 configuration
1446 dnl
1447 AC_ARG_ENABLE([gallium-i915],
1448     [AS_HELP_STRING([--enable-gallium-i915],
1449         [build gallium i915 @<:@default=disabled@:>@])],
1450     [enable_gallium_i915="$enableval"],
1451     [enable_gallium_i915=auto])
1452 if test "x$enable_gallium_i915" = xyes; then
1453     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1454     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1455     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1456 elif test "x$enable_gallium_i915" = xauto; then
1457     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1458     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1459 fi
1460
1461 dnl
1462 dnl Gallium i965 configuration
1463 dnl
1464 AC_ARG_ENABLE([gallium-i965],
1465     [AS_HELP_STRING([--enable-gallium-i965],
1466         [build gallium i965 @<:@default=disabled@:>@])],
1467     [enable_gallium_i965="$enableval"],
1468     [enable_gallium_i965=auto])
1469 if test "x$enable_gallium_i965" = xyes; then
1470     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1471     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1472 elif test "x$enable_gallium_i965" = xauto; then
1473     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1474 fi
1475
1476 dnl
1477 dnl Gallium Radeon configuration
1478 dnl
1479 AC_ARG_ENABLE([gallium-radeon],
1480     [AS_HELP_STRING([--enable-gallium-radeon],
1481         [build gallium radeon @<:@default=disabled@:>@])],
1482     [enable_gallium_radeon="$enableval"],
1483     [enable_gallium_radeon=auto])
1484 if test "x$enable_gallium_radeon" = xyes; then
1485     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1486     gallium_check_st "radeon/drm" "dri-radeong" "xorg-radeon"
1487 elif test "x$enable_gallium_radeon" = xauto; then
1488     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1489 fi
1490
1491 dnl
1492 dnl Gallium Radeon r600g configuration
1493 dnl
1494 AC_ARG_ENABLE([gallium-r600],
1495     [AS_HELP_STRING([--enable-gallium-r600],
1496         [build gallium radeon @<:@default=disabled@:>@])],
1497     [enable_gallium_r600="$enableval"],
1498     [enable_gallium_r600=auto])
1499 if test "x$enable_gallium_r600" = xyes; then
1500     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1501     gallium_check_st "r600/drm" "dri-r600"
1502 fi
1503
1504 dnl
1505 dnl Gallium Nouveau configuration
1506 dnl
1507 AC_ARG_ENABLE([gallium-nouveau],
1508     [AS_HELP_STRING([--enable-gallium-nouveau],
1509         [build gallium nouveau @<:@default=disabled@:>@])],
1510     [enable_gallium_nouveau="$enableval"],
1511     [enable_gallium_nouveau=no])
1512 if test "x$enable_gallium_nouveau" = xyes; then
1513     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1514     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1515 fi
1516
1517 dnl
1518 dnl Gallium swrast configuration
1519 dnl
1520 AC_ARG_ENABLE([gallium-swrast],
1521     [AS_HELP_STRING([--enable-gallium-swrast],
1522         [build gallium swrast @<:@default=auto@:>@])],
1523     [enable_gallium_swrast="$enableval"],
1524     [enable_gallium_swrast=auto])
1525 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1526     if test "x$HAVE_ST_DRI" = xyes; then
1527         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1528     fi
1529 fi
1530
1531 dnl prepend CORE_DIRS to SRC_DIRS
1532 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1533
1534 dnl Restore LDFLAGS and CPPFLAGS
1535 LDFLAGS="$_SAVE_LDFLAGS"
1536 CPPFLAGS="$_SAVE_CPPFLAGS"
1537
1538 dnl Substitute the config
1539 AC_CONFIG_FILES([configs/autoconf])
1540
1541 dnl Replace the configs/current symlink
1542 AC_CONFIG_COMMANDS([configs],[
1543 if test -f configs/current || test -L configs/current; then
1544     rm -f configs/current
1545 fi
1546 ln -s autoconf configs/current
1547 ])
1548
1549 AC_OUTPUT
1550
1551 dnl
1552 dnl Output some configuration info for the user
1553 dnl
1554 echo ""
1555 echo "        prefix:          $prefix"
1556 echo "        exec_prefix:     $exec_prefix"
1557 echo "        libdir:          $libdir"
1558 echo "        includedir:      $includedir"
1559
1560 dnl Driver info
1561 echo ""
1562 echo "        Driver:          $mesa_driver"
1563 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1564     echo "        OSMesa:          lib$OSMESA_LIB"
1565 else
1566     echo "        OSMesa:          no"
1567 fi
1568 if test "$mesa_driver" = dri; then
1569     # cleanup the drivers var
1570     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1571 if test "x$DRI_DIRS" = x; then
1572     echo "        DRI drivers:     no"
1573 else
1574     echo "        DRI drivers:     $dri_dirs"
1575 fi
1576     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1577 fi
1578 echo "        Use XCB:         $enable_xcb"
1579
1580 echo ""
1581 if test "x$MESA_LLVM" = x1; then
1582     echo "        llvm:            yes"
1583     echo "        llvm-config:     $LLVM_CONFIG"
1584     echo "        llvm-version:    $LLVM_VERSION"
1585 else
1586     echo "        llvm:            no"
1587 fi
1588
1589 echo ""
1590 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1591     echo "        Gallium:         yes"
1592     echo "        Gallium dirs:    $GALLIUM_DIRS"
1593     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1594     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1595     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1596     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1597     if test "x$HAVE_ST_EGL" = xyes; then
1598         echo "        EGL client APIs: $EGL_CLIENT_APIS"
1599     fi
1600 else
1601     echo "        Gallium:         no"
1602 fi
1603
1604 dnl Libraries
1605 echo ""
1606 echo "        Shared libs:     $enable_shared"
1607 echo "        Static libs:     $enable_static"
1608 if test "$enable_egl" = yes; then
1609     echo "        EGL:             $EGL_DRIVERS_DIRS"
1610     echo "        EGL platforms:   $EGL_PLATFORMS"
1611 else
1612     echo "        EGL:             no"
1613 fi
1614 echo "        GLU:             $enable_glu"
1615 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1616 echo "        glut:            $enable_glut"
1617
1618 dnl Compiler options
1619 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1620 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1621     $SED 's/^ *//;s/  */ /;s/ *$//'`
1622 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1623     $SED 's/^ *//;s/  */ /;s/ *$//'`
1624 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1625 echo ""
1626 echo "        CFLAGS:          $cflags"
1627 echo "        CXXFLAGS:        $cxxflags"
1628 echo "        Macros:          $defines"
1629
1630 echo ""
1631 echo "        Run '${MAKE-make}' to build Mesa"
1632 echo ""