configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_CHECK_PROGS([PYTHON2], [python2 python])
  34 AC_PATH_PROG([MKDEP], [makedepend])
  35 AC_PATH_PROG([SED], [sed])
  36
  37 if test "x$MKDEP" = "x"; then
  38     AC_MSG_ERROR([makedepend is required to build Mesa])
  39 fi
  40
  41 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  42 dnl configuration in that case.
  43 AC_PROG_INSTALL
  44 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  45
  46 dnl We need a POSIX shell for parts of the build. Assume we have one
  47 dnl in most cases.
  48 case "$host_os" in
  49 solaris*)
  50     # Solaris /bin/sh is too old/non-POSIX compliant
  51     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  52     SHELL="$POSIX_SHELL"
  53     ;;
  54 esac
  55
  56 dnl clang is mostly GCC-compatible, but its version is much lower,
  57 dnl so we have to check for it.
  58 AC_MSG_CHECKING([if compiling with clang])
  59
  60 AC_COMPILE_IFELSE(
  61 [AC_LANG_PROGRAM([], [[
  62 #ifndef __clang__
  63        not clang
  64 #endif
  65 ]])],
  66 [CLANG=yes], [CLANG=no])
  67
  68 AC_MSG_RESULT([$CLANG])
  69
  70 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  71 dnl versions are explictly not supported.
  72 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  73     AC_MSG_CHECKING([whether gcc version is sufficient])
  74     major=0
  75     minor=0
  76
  77     GCC_VERSION=`$CC -dumpversion`
  78     if test $? -eq 0; then
  79         major=`echo $GCC_VERSION | cut -d. -f1`
  80         minor=`echo $GCC_VERSION | cut -d. -f1`
  81     fi
  82
  83     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  86     else
  87         AC_MSG_RESULT([yes])
  88     fi
  89 fi
  90
  91
  92 MKDEP_OPTIONS=-fdepend
  93 dnl Ask gcc where it's keeping its secret headers
  94 if test "x$GCC" = xyes; then
  95     for dir in include include-fixed; do
  96         GCC_INCLUDES=`$CC -print-file-name=$dir`
  97         if test "x$GCC_INCLUDES" != x && \
  98            test "$GCC_INCLUDES" != "$dir" && \
  99            test -d "$GCC_INCLUDES"; then
 100             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 101         fi
 102     done
 103 fi
 104 AC_SUBST([MKDEP_OPTIONS])
 105
 106 dnl Make sure the pkg-config macros are defined
 107 m4_ifndef([PKG_PROG_PKG_CONFIG],
 108     [m4_fatal([Could not locate the pkg-config autoconf macros.
 109   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 110   are in a different location, try setting the environment variable
 111   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 112 PKG_PROG_PKG_CONFIG()
 113
 114 dnl LIB_DIR - library basename
 115 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 116 AC_SUBST([LIB_DIR])
 117
 118 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 119 _SAVE_LDFLAGS="$LDFLAGS"
 120 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 121 AC_SUBST([EXTRA_LIB_PATH])
 122
 123 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 124 _SAVE_CPPFLAGS="$CPPFLAGS"
 125 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 126 AC_SUBST([X11_INCLUDES])
 127
 128 dnl Compiler macros
 129 DEFINES=""
 130 AC_SUBST([DEFINES])
 131 case "$host_os" in
 132 linux*|*-gnu*|gnu*)
 133     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 134     ;;
 135 solaris*)
 136     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 137     ;;
 138 cygwin*)
 139     DEFINES="$DEFINES -DPTHREADS"
 140     ;;
 141 esac
 142
 143 dnl Add flags for gcc and g++
 144 if test "x$GCC" = xyes; then
 145     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 146     if test "x$CLANG" = "xno"; then
 147        CFLAGS="$CFLAGS -ffast-math"
 148     fi
 149
 150     # Enable -fvisibility=hidden if using a gcc that supports it
 151     save_CFLAGS="$CFLAGS"
 152     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 153     CFLAGS="$CFLAGS -fvisibility=hidden"
 154     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 155                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 156
 157     # Work around aliasing bugs - developers should comment this out
 158     CFLAGS="$CFLAGS -fno-strict-aliasing"
 159 fi
 160 if test "x$GXX" = xyes; then
 161     CXXFLAGS="$CXXFLAGS -Wall"
 162
 163     # Enable -fvisibility=hidden if using a gcc that supports it
 164     save_CXXFLAGS="$CXXFLAGS"
 165     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 166     CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
 167     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 168                    [CXXFLAGS="$save_CXXFLAGS" ; AC_MSG_RESULT([no])]);
 169
 170     # Work around aliasing bugs - developers should comment this out
 171     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 172 fi
 173
 174 dnl These should be unnecessary, but let the user set them if they want
 175 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 176     Default is to use CFLAGS.])
 177 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 178     compiler. Default is to use CFLAGS.])
 179 AC_SUBST([OPT_FLAGS])
 180 AC_SUBST([ARCH_FLAGS])
 181
 182 dnl
 183 dnl Hacks to enable 32 or 64 bit build
 184 dnl
 185 AC_ARG_ENABLE([32-bit],
 186     [AS_HELP_STRING([--enable-32-bit],
 187         [build 32-bit libraries @<:@default=auto@:>@])],
 188     [enable_32bit="$enableval"],
 189     [enable_32bit=auto]
 190 )
 191 if test "x$enable_32bit" = xyes; then
 192     if test "x$GCC" = xyes; then
 193         CFLAGS="$CFLAGS -m32"
 194         ARCH_FLAGS="$ARCH_FLAGS -m32"
 195     fi
 196     if test "x$GXX" = xyes; then
 197         CXXFLAGS="$CXXFLAGS -m32"
 198     fi
 199 fi
 200 AC_ARG_ENABLE([64-bit],
 201     [AS_HELP_STRING([--enable-64-bit],
 202         [build 64-bit libraries @<:@default=auto@:>@])],
 203     [enable_64bit="$enableval"],
 204     [enable_64bit=auto]
 205 )
 206 if test "x$enable_64bit" = xyes; then
 207     if test "x$GCC" = xyes; then
 208         CFLAGS="$CFLAGS -m64"
 209     fi
 210     if test "x$GXX" = xyes; then
 211         CXXFLAGS="$CXXFLAGS -m64"
 212     fi
 213 fi
 214
 215 dnl
 216 dnl shared/static libraries, mimic libtool options
 217 dnl
 218 AC_ARG_ENABLE([static],
 219     [AS_HELP_STRING([--enable-static],
 220         [build static libraries @<:@default=disabled@:>@])],
 221     [enable_static="$enableval"],
 222     [enable_static=no]
 223 )
 224 case "x$enable_static" in
 225 xyes|xno ) ;;
 226 x ) enable_static=no ;;
 227 * )
 228     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 229     ;;
 230 esac
 231 AC_ARG_ENABLE([shared],
 232     [AS_HELP_STRING([--disable-shared],
 233         [build shared libraries @<:@default=enabled@:>@])],
 234     [enable_shared="$enableval"],
 235     [enable_shared=yes]
 236 )
 237 case "x$enable_shared" in
 238 xyes|xno ) ;;
 239 x ) enable_shared=yes ;;
 240 * )
 241     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 242     ;;
 243 esac
 244
 245 dnl Can't have static and shared libraries, default to static if user
 246 dnl explicitly requested. If both disabled, set to static since shared
 247 dnl was explicitly requirested.
 248 case "x$enable_static$enable_shared" in
 249 xyesyes )
 250     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 251     enable_shared=no
 252     ;;
 253 xnono )
 254     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 255     enable_static=yes
 256     ;;
 257 esac
 258
 259 dnl
 260 dnl mklib options
 261 dnl
 262 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 263 if test "$enable_static" = yes; then
 264     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 265 fi
 266 AC_SUBST([MKLIB_OPTIONS])
 267
 268 dnl
 269 dnl other compiler options
 270 dnl
 271 AC_ARG_ENABLE([debug],
 272     [AS_HELP_STRING([--enable-debug],
 273         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 274     [enable_debug="$enableval"],
 275     [enable_debug=no]
 276 )
 277 if test "x$enable_debug" = xyes; then
 278     DEFINES="$DEFINES -DDEBUG"
 279     if test "x$GCC" = xyes; then
 280         CFLAGS="$CFLAGS -g"
 281     fi
 282     if test "x$GXX" = xyes; then
 283         CXXFLAGS="$CXXFLAGS -g"
 284     fi
 285 fi
 286
 287 dnl
 288 dnl library names
 289 dnl
 290 LIB_PREFIX_GLOB='lib'
 291 LIB_VERSION_SEPARATOR='.'
 292 if test "$enable_static" = yes; then
 293     LIB_EXTENSION='a'
 294 else
 295     case "$host_os" in
 296     darwin* )
 297         LIB_EXTENSION='dylib' ;;
 298     cygwin* )
 299         dnl prefix can be 'cyg' or 'lib'
 300         LIB_PREFIX_GLOB='???'
 301         LIB_VERSION_SEPARATOR='-'
 302         LIB_EXTENSION='dll' ;;
 303     aix* )
 304         LIB_EXTENSION='a' ;;
 305     * )
 306         LIB_EXTENSION='so' ;;
 307     esac
 308 fi
 309
 310 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 311 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 312 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 313 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 314 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 315 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 316 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 317 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 318 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 319
 320 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 321 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 322 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 323 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 324 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 325 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 326 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 327 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 328 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 329 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 330
 331 AC_SUBST([GL_LIB_NAME])
 332 AC_SUBST([GLU_LIB_NAME])
 333 AC_SUBST([GLUT_LIB_NAME])
 334 AC_SUBST([GLW_LIB_NAME])
 335 AC_SUBST([OSMESA_LIB_NAME])
 336 AC_SUBST([EGL_LIB_NAME])
 337 AC_SUBST([GLESv1_CM_LIB_NAME])
 338 AC_SUBST([GLESv2_LIB_NAME])
 339 AC_SUBST([VG_LIB_NAME])
 340
 341 AC_SUBST([GL_LIB_GLOB])
 342 AC_SUBST([GLU_LIB_GLOB])
 343 AC_SUBST([GLUT_LIB_GLOB])
 344 AC_SUBST([GLW_LIB_GLOB])
 345 AC_SUBST([OSMESA_LIB_GLOB])
 346 AC_SUBST([EGL_LIB_GLOB])
 347 AC_SUBST([GLESv1_CM_LIB_GLOB])
 348 AC_SUBST([GLESv2_LIB_GLOB])
 349 AC_SUBST([VG_LIB_GLOB])
 350
 351 dnl
 352 dnl Arch/platform-specific settings
 353 dnl
 354 AC_ARG_ENABLE([asm],
 355     [AS_HELP_STRING([--disable-asm],
 356         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 357     [enable_asm="$enableval"],
 358     [enable_asm=yes]
 359 )
 360 asm_arch=""
 361 ASM_FLAGS=""
 362 MESA_ASM_SOURCES=""
 363 GLAPI_ASM_SOURCES=""
 364 AC_MSG_CHECKING([whether to enable assembly])
 365 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 366 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 367 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 368     case "$host_cpu" in
 369     i?86 | x86_64)
 370         enable_asm=no
 371         AC_MSG_RESULT([no, cross compiling])
 372         ;;
 373     esac
 374 fi
 375 # check for supported arches
 376 if test "x$enable_asm" = xyes; then
 377     case "$host_cpu" in
 378     i?86)
 379         case "$host_os" in
 380         linux* | *freebsd* | dragonfly*)
 381             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 382             ;;
 383         esac
 384         ;;
 385     x86_64)
 386         case "$host_os" in
 387         linux* | *freebsd* | dragonfly*)
 388             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 389             ;;
 390         esac
 391         ;;
 392     powerpc)
 393         case "$host_os" in
 394         linux*)
 395             asm_arch=ppc
 396             ;;
 397         esac
 398         ;;
 399     sparc*)
 400         case "$host_os" in
 401         linux*)
 402             asm_arch=sparc
 403             ;;
 404         esac
 405         ;;
 406     esac
 407
 408     case "$asm_arch" in
 409     x86)
 410         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 411         MESA_ASM_SOURCES='$(X86_SOURCES)'
 412         GLAPI_ASM_SOURCES='$(X86_API)'
 413         AC_MSG_RESULT([yes, x86])
 414         ;;
 415     x86_64)
 416         ASM_FLAGS="-DUSE_X86_64_ASM"
 417         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 418         GLAPI_ASM_SOURCES='$(X86-64_API)'
 419         AC_MSG_RESULT([yes, x86_64])
 420         ;;
 421     ppc)
 422         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 423         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 424         AC_MSG_RESULT([yes, ppc])
 425         ;;
 426     sparc)
 427         ASM_FLAGS="-DUSE_SPARC_ASM"
 428         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 429         GLAPI_ASM_SOURCES='$(SPARC_API)'
 430         AC_MSG_RESULT([yes, sparc])
 431         ;;
 432     *)
 433         AC_MSG_RESULT([no, platform not supported])
 434         ;;
 435     esac
 436 fi
 437 AC_SUBST([ASM_FLAGS])
 438 AC_SUBST([MESA_ASM_SOURCES])
 439 AC_SUBST([GLAPI_ASM_SOURCES])
 440
 441 dnl PIC code macro
 442 MESA_PIC_FLAGS
 443
 444 dnl Check to see if dlopen is in default libraries (like Solaris, which
 445 dnl has it in libc), or if libdl is needed to get it.
 446 AC_CHECK_FUNC([dlopen], [],
 447     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 448 AC_SUBST([DLOPEN_LIBS])
 449
 450 dnl See if posix_memalign is available
 451 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 452
 453 dnl SELinux awareness.
 454 AC_ARG_ENABLE([selinux],
 455     [AS_HELP_STRING([--enable-selinux],
 456         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 457     [MESA_SELINUX="$enableval"],
 458     [MESA_SELINUX=no])
 459 if test "x$enable_selinux" = "xyes"; then
 460     AC_CHECK_HEADER([selinux/selinux.h],[],
 461                     [AC_MSG_ERROR([SELinux headers not found])])
 462     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 463                  [AC_MSG_ERROR([SELinux library not found])])
 464     SELINUX_LIBS="-lselinux"
 465     DEFINES="$DEFINES -DMESA_SELINUX"
 466 fi
 467
 468 dnl
 469 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 470 dnl More later: fbdev, ...
 471 dnl
 472 default_driver="xlib"
 473
 474 case "$host_os" in
 475 linux*)
 476     case "$host_cpu" in
 477     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 478     esac
 479     ;;
 480 *freebsd* | dragonfly*)
 481     case "$host_cpu" in
 482     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 483     esac
 484     ;;
 485 esac
 486
 487 AC_ARG_WITH([driver],
 488     [AS_HELP_STRING([--with-driver=DRIVER],
 489         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 490     [mesa_driver="$withval"],
 491     [mesa_driver="$default_driver"])
 492 dnl Check for valid option
 493 case "x$mesa_driver" in
 494 xxlib|xdri|xosmesa)
 495     ;;
 496 *)
 497     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 498     ;;
 499 esac
 500
 501 PKG_CHECK_MODULES([TALLOC], [talloc])
 502 AC_SUBST([TALLOC_LIBS])
 503 AC_SUBST([TALLOC_CFLAGS])
 504
 505 dnl
 506 dnl Driver specific build directories
 507 dnl
 508
 509 dnl this variable will be prepended to SRC_DIRS and is not exported
 510 CORE_DIRS="mapi/glapi glsl mesa"
 511
 512 SRC_DIRS=""
 513 GLU_DIRS="sgi"
 514 GALLIUM_DIRS="auxiliary drivers state_trackers"
 515 GALLIUM_TARGET_DIRS=""
 516 GALLIUM_WINSYS_DIRS="sw"
 517 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug identity"
 518 GALLIUM_STATE_TRACKERS_DIRS=""
 519
 520 case "$mesa_driver" in
 521 xlib)
 522     DRIVER_DIRS="x11"
 523     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 524     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 525     ;;
 526 dri)
 527     SRC_DIRS="$SRC_DIRS glx"
 528     DRIVER_DIRS="dri"
 529     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 530     ;;
 531 osmesa)
 532     DRIVER_DIRS="osmesa"
 533     ;;
 534 esac
 535 AC_SUBST([SRC_DIRS])
 536 AC_SUBST([GLU_DIRS])
 537 AC_SUBST([DRIVER_DIRS])
 538 AC_SUBST([GALLIUM_DIRS])
 539 AC_SUBST([GALLIUM_TARGET_DIRS])
 540 AC_SUBST([GALLIUM_WINSYS_DIRS])
 541 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 542 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 543 AC_SUBST([MESA_LLVM])
 544
 545 dnl
 546 dnl Find out if X is available. The variable have_x is set if libX11 is
 547 dnl found to mimic AC_PATH_XTRA.
 548 dnl
 549 if test -n "$PKG_CONFIG"; then
 550     AC_MSG_CHECKING([pkg-config files for X11 are available])
 551     PKG_CHECK_EXISTS([x11],[
 552         x11_pkgconfig=yes
 553         have_x=yes
 554         ],[
 555         x11_pkgconfig=no
 556     ])
 557     AC_MSG_RESULT([$x11_pkgconfig])
 558 else
 559     x11_pkgconfig=no
 560 fi
 561 dnl Use the autoconf macro if no pkg-config files
 562 if test "$x11_pkgconfig" = yes; then
 563     PKG_CHECK_MODULES([X11], [x11])
 564 else
 565     AC_PATH_XTRA
 566     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 567     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 568     AC_SUBST([X11_CFLAGS])
 569     AC_SUBST([X11_LIBS])
 570 fi
 571
 572 dnl Try to tell the user that the --x-* options are only used when
 573 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 574 m4_divert_once([HELP_BEGIN],
 575 [These options are only used when the X libraries cannot be found by the
 576 pkg-config utility.])
 577
 578 dnl We need X for xlib and dri, so bomb now if it's not found
 579 case "$mesa_driver" in
 580 xlib|dri)
 581     if test "$no_x" = yes; then
 582         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 583     fi
 584     ;;
 585 esac
 586
 587 dnl XCB - this is only used for GLX right now
 588 AC_ARG_ENABLE([xcb],
 589     [AS_HELP_STRING([--enable-xcb],
 590         [use XCB for GLX @<:@default=disabled@:>@])],
 591     [enable_xcb="$enableval"],
 592     [enable_xcb=no])
 593 if test "x$enable_xcb" = xyes; then
 594     DEFINES="$DEFINES -DUSE_XCB"
 595 else
 596     enable_xcb=no
 597 fi
 598
 599 dnl
 600 dnl libGL configuration per driver
 601 dnl
 602 case "$mesa_driver" in
 603 xlib)
 604     if test "$x11_pkgconfig" = yes; then
 605         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 606         GL_PC_REQ_PRIV="x11 xext"
 607         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 608         GL_LIB_DEPS="$XLIBGL_LIBS"
 609     else
 610         # should check these...
 611         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 612         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 613         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 614         GL_PC_CFLAGS="$X11_INCLUDES"
 615     fi
 616     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 617     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 618
 619     # if static, move the external libraries to the programs
 620     # and empty the libraries for libGL
 621     if test "$enable_static" = yes; then
 622         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 623         GL_LIB_DEPS=""
 624     fi
 625     ;;
 626 dri)
 627     # DRI must be shared, I think
 628     if test "$enable_static" = yes; then
 629         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 630     fi
 631
 632     # Check for libdrm
 633     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 634     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 635     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 636     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 637     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 638
 639     # find the DRI deps for libGL
 640     if test "$x11_pkgconfig" = yes; then
 641         dri_modules="x11 xext xdamage xfixes"
 642
 643         # add xf86vidmode if available
 644         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 645         if test "$HAVE_XF86VIDMODE" = yes ; then
 646             dri_modules="$dri_modules xxf86vm"
 647         fi
 648
 649         # add xcb modules if necessary
 650         if test "$enable_xcb" = yes; then
 651             dri_modules="$dri_modules x11-xcb xcb-glx"
 652         fi
 653
 654         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 655         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 656         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 657         GL_LIB_DEPS="$DRIGL_LIBS"
 658     else
 659         # should check these...
 660         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 661         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 662         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 663         GL_PC_CFLAGS="$X11_INCLUDES"
 664
 665         # XCB can only be used from pkg-config
 666         if test "$enable_xcb" = yes; then
 667             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 668             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 669             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 670             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 671         fi
 672     fi
 673
 674     # need DRM libs, -lpthread, etc.
 675     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 676     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 677     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 678     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 679     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 680     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 681     ;;
 682 osmesa)
 683     # No libGL for osmesa
 684     GL_LIB_DEPS=""
 685     ;;
 686 esac
 687 AC_SUBST([GL_LIB_DEPS])
 688 AC_SUBST([GL_PC_REQ_PRIV])
 689 AC_SUBST([GL_PC_LIB_PRIV])
 690 AC_SUBST([GL_PC_CFLAGS])
 691 AC_SUBST([DRI_PC_REQ_PRIV])
 692 AC_SUBST([GLESv1_CM_LIB_DEPS])
 693 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 694 AC_SUBST([GLESv2_LIB_DEPS])
 695 AC_SUBST([GLESv2_PC_LIB_PRIV])
 696
 697
 698 AC_SUBST([HAVE_XF86VIDMODE])
 699
 700 PKG_CHECK_MODULES([LIBDRM_RADEON],
 701                   [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 702                   HAVE_LIBDRM_RADEON=yes,
 703                   HAVE_LIBDRM_RADEON=no)
 704
 705 dnl
 706 dnl More X11 setup
 707 dnl
 708 if test "$mesa_driver" = xlib; then
 709     DEFINES="$DEFINES -DUSE_XSHM"
 710 fi
 711
 712 dnl
 713 dnl More DRI setup
 714 dnl
 715 AC_ARG_ENABLE([glx-tls],
 716     [AS_HELP_STRING([--enable-glx-tls],
 717         [enable TLS support in GLX @<:@default=disabled@:>@])],
 718     [GLX_USE_TLS="$enableval"],
 719     [GLX_USE_TLS=no])
 720 dnl Directory for DRI drivers
 721 AC_ARG_WITH([dri-driverdir],
 722     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 723         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 724     [DRI_DRIVER_INSTALL_DIR="$withval"],
 725     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 726 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 727 dnl Extra search path for DRI drivers
 728 AC_ARG_WITH([dri-searchpath],
 729     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 730         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 731     [DRI_DRIVER_SEARCH_DIR="$withval"],
 732     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 733 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 734 dnl Direct rendering or just indirect rendering
 735 AC_ARG_ENABLE([driglx-direct],
 736     [AS_HELP_STRING([--disable-driglx-direct],
 737         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 738     [driglx_direct="$enableval"],
 739     [driglx_direct="yes"])
 740 dnl Which drivers to build - default is chosen by platform
 741 AC_ARG_WITH([dri-drivers],
 742     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 743         [comma delimited DRI drivers list, e.g.
 744         "swrast,i965,radeon" @<:@default=auto@:>@])],
 745     [with_dri_drivers="$withval"],
 746     [with_dri_drivers=yes])
 747 if test "x$with_dri_drivers" = x; then
 748     with_dri_drivers=no
 749 fi
 750
 751 dnl Determine which APIs to support
 752 AC_ARG_ENABLE([opengl],
 753     [AS_HELP_STRING([--disable-opengl],
 754         [disable support for standard OpenGL API @<:@default=no@:>@])],
 755     [enable_opengl="$enableval"],
 756     [enable_opengl=yes])
 757 AC_ARG_ENABLE([gles1],
 758     [AS_HELP_STRING([--enable-gles1],
 759         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 760     [enable_gles1="$enableval"],
 761     [enable_gles1=no])
 762 AC_ARG_ENABLE([gles2],
 763     [AS_HELP_STRING([--enable-gles2],
 764         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 765     [enable_gles2="$enableval"],
 766     [enable_gles2=no])
 767 AC_ARG_ENABLE([gles-overlay],
 768     [AS_HELP_STRING([--enable-gles-overlay],
 769         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 770     [enable_gles_overlay="$enableval"],
 771     [enable_gles_overlay=no])
 772
 773 API_DEFINES=""
 774 GLES_OVERLAY=0
 775 if test "x$enable_opengl" = xno; then
 776     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 777 else
 778     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 779 fi
 780 if test "x$enable_gles1" = xyes; then
 781     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 782 fi
 783 if test "x$enable_gles2" = xyes; then
 784     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 785 fi
 786 if test "x$enable_gles_overlay" = xyes -o \
 787     "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 788     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
 789     if test "x$enable_gles_overlay" = xyes; then
 790         GLES_OVERLAY=1
 791     fi
 792 fi
 793 AC_SUBST([API_DEFINES])
 794 AC_SUBST([GLES_OVERLAY])
 795
 796 dnl If $with_dri_drivers is yes, directories will be added through
 797 dnl platform checks
 798 DRI_DIRS=""
 799 case "$with_dri_drivers" in
 800 no) ;;
 801 yes)
 802     DRI_DIRS="yes"
 803     ;;
 804 *)
 805     # verify the requested driver directories exist
 806     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 807     for driver in $dri_drivers; do
 808         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 809             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 810     done
 811     DRI_DIRS="$dri_drivers"
 812     ;;
 813 esac
 814
 815 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 816 if test "$mesa_driver" = dri; then
 817     # Use TLS in GLX?
 818     if test "x$GLX_USE_TLS" = xyes; then
 819         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 820     fi
 821
 822     # Platform specific settings and drivers to build
 823     case "$host_os" in
 824     linux*)
 825         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 826         if test "x$driglx_direct" = xyes; then
 827             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 828         fi
 829         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 830
 831         case "$host_cpu" in
 832         x86_64)
 833             # sis is missing because they have not be converted to use
 834             # the new interface.  i810 are missing because there is no
 835             # x86-64 system where they could *ever* be used.
 836             if test "x$DRI_DIRS" = "xyes"; then
 837                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 838                     savage tdfx unichrome swrast"
 839             fi
 840             ;;
 841         powerpc*)
 842             # Build only the drivers for cards that exist on PowerPC.
 843             # At some point MGA will be added, but not yet.
 844             if test "x$DRI_DIRS" = "xyes"; then
 845                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 846             fi
 847             ;;
 848         sparc*)
 849             # Build only the drivers for cards that exist on sparc`
 850             if test "x$DRI_DIRS" = "xyes"; then
 851                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 852             fi
 853             ;;
 854         esac
 855         ;;
 856     freebsd* | dragonfly*)
 857         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 858         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 859         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 860         if test "x$driglx_direct" = xyes; then
 861             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 862         fi
 863         if test "x$GXX" = xyes; then
 864             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 865         fi
 866
 867         if test "x$DRI_DIRS" = "xyes"; then
 868             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 869                 unichrome savage sis swrast"
 870         fi
 871         ;;
 872     gnu*)
 873         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 874         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 875         ;;
 876     solaris*)
 877         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 878         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 879         if test "x$driglx_direct" = xyes; then
 880             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 881         fi
 882         ;;
 883     esac
 884
 885     # default drivers
 886     if test "x$DRI_DIRS" = "xyes"; then
 887         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 888             savage sis tdfx unichrome swrast"
 889     fi
 890
 891     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 892
 893     # Check for expat
 894     EXPAT_INCLUDES=""
 895     EXPAT_LIB=-lexpat
 896     AC_ARG_WITH([expat],
 897         [AS_HELP_STRING([--with-expat=DIR],
 898             [expat install directory])],[
 899         EXPAT_INCLUDES="-I$withval/include"
 900         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 901         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 902         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 903         ])
 904     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 905     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 906         [AC_MSG_ERROR([Expat required for DRI.])])
 907
 908     # put all the necessary libs together
 909     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 910 fi
 911 AC_SUBST([DRI_DIRS])
 912 AC_SUBST([EXPAT_INCLUDES])
 913 AC_SUBST([DRI_LIB_DEPS])
 914
 915 case $DRI_DIRS in
 916 *i915*|*i965*)
 917     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.21])
 918     ;;
 919 esac
 920
 921 case $DRI_DIRS in
 922 *radeon*|*r200*|*r300*|*r600*)
 923     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
 924         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 925         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 926     fi
 927     ;;
 928 esac
 929 AC_SUBST([RADEON_CFLAGS])
 930 AC_SUBST([RADEON_LDFLAGS])
 931
 932
 933 dnl
 934 dnl OSMesa configuration
 935 dnl
 936 if test "$mesa_driver" = xlib; then
 937     default_gl_osmesa=yes
 938 else
 939     default_gl_osmesa=no
 940 fi
 941 AC_ARG_ENABLE([gl-osmesa],
 942     [AS_HELP_STRING([--enable-gl-osmesa],
 943         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
 944     [gl_osmesa="$enableval"],
 945     [gl_osmesa="$default_gl_osmesa"])
 946 if test "x$gl_osmesa" = xyes; then
 947     if test "$mesa_driver" = osmesa; then
 948         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 949     else
 950         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 951     fi
 952 fi
 953
 954 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 955 AC_ARG_WITH([osmesa-bits],
 956     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 957         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 958     [osmesa_bits="$withval"],
 959     [osmesa_bits=8])
 960 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 961     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 962     osmesa_bits=8
 963 fi
 964 case "x$osmesa_bits" in
 965 x8)
 966     OSMESA_LIB=OSMesa
 967     ;;
 968 x16|x32)
 969     OSMESA_LIB="OSMesa$osmesa_bits"
 970     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 971     ;;
 972 *)
 973     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 974     ;;
 975 esac
 976 AC_SUBST([OSMESA_LIB])
 977
 978 case "$DRIVER_DIRS" in
 979 *osmesa*)
 980     # only link libraries with osmesa if shared
 981     if test "$enable_static" = no; then
 982         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
 983     else
 984         OSMESA_LIB_DEPS=""
 985     fi
 986     OSMESA_MESA_DEPS=""
 987     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
 988     ;;
 989 esac
 990 AC_SUBST([OSMESA_LIB_DEPS])
 991 AC_SUBST([OSMESA_MESA_DEPS])
 992 AC_SUBST([OSMESA_PC_REQ])
 993 AC_SUBST([OSMESA_PC_LIB_PRIV])
 994
 995 dnl
 996 dnl EGL configuration
 997 dnl
 998 AC_ARG_ENABLE([egl],
 999     [AS_HELP_STRING([--disable-egl],
1000         [disable EGL library @<:@default=enabled@:>@])],
1001     [enable_egl="$enableval"],
1002     [enable_egl=yes])
1003 if test "x$enable_egl" = xyes; then
1004     SRC_DIRS="$SRC_DIRS egl"
1005     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1006     EGL_DRIVERS_DIRS=""
1007     if test "$enable_static" != yes; then
1008         # build egl_glx when libGL is built
1009         if test "$mesa_driver" != osmesa; then
1010             EGL_DRIVERS_DIRS="glx"
1011         fi
1012
1013         if test "$mesa_driver" = dri; then
1014             # build egl_dri2 when xcb-dri2 is available
1015             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1016                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1017             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1018                           [have_libudev=yes],[have_libudev=no])
1019
1020             if test "$have_xcb_dri2" = yes; then
1021                 EGL_DRIVER_DRI2=dri2
1022                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1023                 if test "$have_libudev" = yes; then
1024                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1025                 fi
1026             fi
1027         fi
1028
1029         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1030     fi
1031 fi
1032 AC_SUBST([EGL_LIB_DEPS])
1033 AC_SUBST([EGL_DRIVERS_DIRS])
1034
1035 dnl
1036 dnl GLU configuration
1037 dnl
1038 AC_ARG_ENABLE([glu],
1039     [AS_HELP_STRING([--disable-glu],
1040         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1041     [enable_glu="$enableval"],
1042     [enable_glu=yes])
1043 if test "x$enable_glu" = xyes; then
1044     SRC_DIRS="$SRC_DIRS glu"
1045
1046     case "$mesa_driver" in
1047     osmesa)
1048         # Link libGLU to libOSMesa instead of libGL
1049         GLU_LIB_DEPS=""
1050         GLU_PC_REQ="osmesa"
1051         if test "$enable_static" = no; then
1052             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1053         else
1054             GLU_MESA_DEPS=""
1055         fi
1056         ;;
1057     *)
1058         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1059         GLU_PC_REQ="gl"
1060         GLU_PC_LIB_PRIV="-lm"
1061         if test "$enable_static" = no; then
1062             GLU_LIB_DEPS="-lm"
1063             GLU_MESA_DEPS='-l$(GL_LIB)'
1064         else
1065             GLU_LIB_DEPS=""
1066             GLU_MESA_DEPS=""
1067             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1068         fi
1069         ;;
1070     esac
1071 fi
1072 if test "$enable_static" = no; then
1073     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1074 fi
1075 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1076 AC_SUBST([GLU_LIB_DEPS])
1077 AC_SUBST([GLU_MESA_DEPS])
1078 AC_SUBST([GLU_PC_REQ])
1079 AC_SUBST([GLU_PC_REQ_PRIV])
1080 AC_SUBST([GLU_PC_LIB_PRIV])
1081 AC_SUBST([GLU_PC_CFLAGS])
1082
1083 dnl
1084 dnl GLw configuration
1085 dnl
1086 AC_ARG_ENABLE([glw],
1087     [AS_HELP_STRING([--disable-glw],
1088         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1089     [enable_glw="$enableval"],
1090     [enable_glw=yes])
1091 dnl Don't build GLw on osmesa
1092 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1093     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1094     enable_glw=no
1095 fi
1096 AC_ARG_ENABLE([motif],
1097     [AS_HELP_STRING([--enable-motif],
1098         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1099     [enable_motif="$enableval"],
1100     [enable_motif=no])
1101
1102 if test "x$enable_glw" = xyes; then
1103     SRC_DIRS="$SRC_DIRS glw"
1104     if test "$x11_pkgconfig" = yes; then
1105         PKG_CHECK_MODULES([GLW],[x11 xt])
1106         GLW_PC_REQ_PRIV="x11 xt"
1107         GLW_LIB_DEPS="$GLW_LIBS"
1108     else
1109         # should check these...
1110         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1111         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1112         GLW_PC_CFLAGS="$X11_INCLUDES"
1113     fi
1114
1115     GLW_SOURCES="GLwDrawA.c"
1116     MOTIF_CFLAGS=
1117     if test "x$enable_motif" = xyes; then
1118         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1119         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1120         if test "x$MOTIF_CONFIG" != xno; then
1121             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1122             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1123         else
1124             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1125                 [AC_MSG_ERROR([Can't locate Motif headers])])
1126             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1127                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1128         fi
1129         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1130         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1131         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1132         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1133     fi
1134
1135     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1136     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1137     if test "$enable_static" = no; then
1138         GLW_MESA_DEPS='-l$(GL_LIB)'
1139         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1140     else
1141         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1142         GLW_LIB_DEPS=""
1143         GLW_MESA_DEPS=""
1144     fi
1145 fi
1146 AC_SUBST([GLW_LIB_DEPS])
1147 AC_SUBST([GLW_MESA_DEPS])
1148 AC_SUBST([GLW_SOURCES])
1149 AC_SUBST([MOTIF_CFLAGS])
1150 AC_SUBST([GLW_PC_REQ_PRIV])
1151 AC_SUBST([GLW_PC_LIB_PRIV])
1152 AC_SUBST([GLW_PC_CFLAGS])
1153
1154 dnl
1155 dnl GLUT configuration
1156 dnl
1157 if test -f "$srcdir/include/GL/glut.h"; then
1158     default_glut=yes
1159 else
1160     default_glut=no
1161 fi
1162 AC_ARG_ENABLE([glut],
1163     [AS_HELP_STRING([--disable-glut],
1164         [enable GLUT library @<:@default=enabled if source available@:>@])],
1165     [enable_glut="$enableval"],
1166     [enable_glut="$default_glut"])
1167
1168 dnl Can't build glut if GLU not available
1169 if test "x$enable_glu$enable_glut" = xnoyes; then
1170     AC_MSG_WARN([Disabling glut since GLU is disabled])
1171     enable_glut=no
1172 fi
1173 dnl Don't build glut on osmesa
1174 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1175     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1176     enable_glut=no
1177 fi
1178
1179 if test "x$enable_glut" = xyes; then
1180     SRC_DIRS="$SRC_DIRS glut/glx"
1181     if test "$x11_pkgconfig" = yes; then
1182         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1183         GLUT_PC_REQ_PRIV="x11 xmu xi"
1184         GLUT_LIB_DEPS="$GLUT_LIBS"
1185     else
1186         # should check these...
1187         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1188         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1189         GLUT_PC_CFLAGS="$X11_INCLUDES"
1190     fi
1191     if test "x$GCC" = xyes; then
1192         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1193     fi
1194     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1195     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1196
1197     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1198     if test "$enable_static" = no; then
1199         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1200     else
1201         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1202         GLUT_LIB_DEPS=""
1203         GLUT_MESA_DEPS=""
1204     fi
1205 fi
1206 AC_SUBST([GLUT_LIB_DEPS])
1207 AC_SUBST([GLUT_MESA_DEPS])
1208 AC_SUBST([GLUT_CFLAGS])
1209 AC_SUBST([GLUT_PC_REQ_PRIV])
1210 AC_SUBST([GLUT_PC_LIB_PRIV])
1211 AC_SUBST([GLUT_PC_CFLAGS])
1212
1213 dnl
1214 dnl Program library dependencies
1215 dnl    Only libm is added here if necessary as the libraries should
1216 dnl    be pulled in by the linker
1217 dnl
1218 if test "x$APP_LIB_DEPS" = x; then
1219     case "$host_os" in
1220     solaris*)
1221         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1222         ;;
1223     cygwin*)
1224         APP_LIB_DEPS="-lX11"
1225         ;;
1226     *)
1227         APP_LIB_DEPS="-lm"
1228         ;;
1229     esac
1230 fi
1231 AC_SUBST([APP_LIB_DEPS])
1232 AC_SUBST([PROGRAM_DIRS])
1233
1234 dnl
1235 dnl Gallium configuration
1236 dnl
1237 AC_ARG_ENABLE([gallium],
1238     [AS_HELP_STRING([--disable-gallium],
1239         [build gallium @<:@default=enabled@:>@])],
1240     [enable_gallium="$enableval"],
1241     [enable_gallium=yes])
1242 if test "x$enable_gallium" = xyes; then
1243     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1244     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1245                 [HAS_UDIS86="no"])
1246     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1247 fi
1248
1249 AC_SUBST([LLVM_CFLAGS])
1250 AC_SUBST([LLVM_LIBS])
1251 AC_SUBST([LLVM_LDFLAGS])
1252 AC_SUBST([LLVM_VERSION])
1253
1254 VG_LIB_DEPS=""
1255 EGL_CLIENT_APIS='$(GL_LIB)'
1256 if test "x$enable_gles_overlay" = xyes; then
1257     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1258 fi
1259
1260 dnl
1261 dnl Gallium state trackers configuration
1262 dnl
1263 AC_ARG_WITH([state-trackers],
1264     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1265         [comma delimited state_trackers list, e.g.
1266         "egl,glx" @<:@default=auto@:>@])],
1267     [with_state_trackers="$withval"],
1268     [with_state_trackers=yes])
1269
1270 case "$with_state_trackers" in
1271 no)
1272     GALLIUM_STATE_TRACKERS_DIRS=""
1273     ;;
1274 yes)
1275     # look at what else is built
1276     case "$mesa_driver" in
1277     xlib)
1278         GALLIUM_STATE_TRACKERS_DIRS=glx
1279         ;;
1280     dri)
1281         GALLIUM_STATE_TRACKERS_DIRS="dri"
1282         HAVE_ST_DRI="yes"
1283         if test "x$enable_egl" = xyes; then
1284             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1285             HAVE_ST_EGL="yes"
1286         fi
1287         # Have only tested st/xorg on 1.6.0 servers
1288         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1289             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1290             HAVE_ST_XORG="no")
1291         ;;
1292     esac
1293     ;;
1294 *)
1295     # verify the requested state tracker exist
1296     state_trackers=""
1297     _state_trackers=`IFS=', '; echo $with_state_trackers`
1298     for tracker in $_state_trackers; do
1299         case "$tracker" in
1300         dri)
1301             if test "x$mesa_driver" != xdri; then
1302                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1303             fi
1304             HAVE_ST_DRI="yes"
1305             ;;
1306         egl)
1307             if test "x$enable_egl" != xyes; then
1308                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1309             fi
1310             HAVE_ST_EGL="yes"
1311             ;;
1312         xorg)
1313             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1314             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1315             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1316             HAVE_ST_XORG="yes"
1317             ;;
1318         es)
1319             AC_MSG_WARN([state tracker 'es' has been replaced by --enable-gles-overlay])
1320
1321             if test "x$enable_gles_overlay" != xyes; then
1322                 if test "x$enable_gles1" != xyes -a "x$enable_gles2" != xyes; then
1323                     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
1324                 fi
1325                 GLES_OVERLAY=1
1326                 EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1327             fi
1328             tracker=""
1329             ;;
1330         vega)
1331             CORE_DIRS="$CORE_DIRS mapi/vgapi"
1332             VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1333             EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1334             ;;
1335         esac
1336
1337         if test -n "$tracker"; then
1338             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1339                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1340             if test -n "$state_trackers"; then
1341                 state_trackers="$state_trackers $tracker"
1342             else
1343                 state_trackers="$tracker"
1344             fi
1345         fi
1346     done
1347     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1348     ;;
1349 esac
1350
1351 AC_SUBST([VG_LIB_DEPS])
1352 AC_SUBST([EGL_CLIENT_APIS])
1353
1354 if test "x$HAVE_ST_EGL" = xyes; then
1355         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1356         # define GLX_DIRECT_RENDERING even when the driver is not dri
1357         if test "x$mesa_driver" != xdri -a "x$driglx_direct" = xyes; then
1358             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1359         fi
1360 fi
1361
1362 if test "x$HAVE_ST_XORG" = xyes; then
1363     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1364         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1365         HAVE_XEXTPROTO_71="no")
1366 fi
1367
1368 AC_ARG_WITH([egl-platforms],
1369     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1370         [comma delimited native platforms libEGL supports, e.g.
1371         "x11,drm" @<:@default=auto@:>@])],
1372     [with_egl_platforms="$withval"],
1373     [with_egl_platforms=yes])
1374 AC_ARG_WITH([egl-displays],
1375     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1376         [DEPRECATED.  Use --with-egl-platforms instead])],
1377     [with_egl_platforms="$withval"])
1378
1379 EGL_PLATFORMS=""
1380 case "$with_egl_platforms" in
1381 yes)
1382     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1383         EGL_PLATFORMS="x11"
1384         if test "$mesa_driver" = dri; then
1385             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1386         fi
1387     fi
1388     ;;
1389 *)
1390     if test "x$enable_egl" != xyes; then
1391         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1392     fi
1393     # verify the requested driver directories exist
1394     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1395     for plat in $egl_platforms; do
1396         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1397             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1398         if test "$plat" = "fbdev"; then
1399                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1400         fi
1401     done
1402     EGL_PLATFORMS="$egl_platforms"
1403     ;;
1404 esac
1405 AC_SUBST([EGL_PLATFORMS])
1406
1407 AC_ARG_WITH([egl-driver-dir],
1408     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1409                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1410     [EGL_DRIVER_INSTALL_DIR="$withval"],
1411     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1412 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1413
1414 AC_ARG_WITH([xorg-driver-dir],
1415     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1416                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1417     [XORG_DRIVER_INSTALL_DIR="$withval"],
1418     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1419 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1420
1421 AC_ARG_WITH([max-width],
1422     [AS_HELP_STRING([--with-max-width=N],
1423                     [Maximum framebuffer width (4096)])],
1424     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1425      AS_IF([test "${withval}" -gt "4096"],
1426            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1427 )
1428 AC_ARG_WITH([max-height],
1429     [AS_HELP_STRING([--with-max-height=N],
1430                     [Maximum framebuffer height (4096)])],
1431     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1432      AS_IF([test "${withval}" -gt "4096"],
1433            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1434 )
1435
1436 dnl
1437 dnl Gallium LLVM
1438 dnl
1439 AC_ARG_ENABLE([gallium-llvm],
1440     [AS_HELP_STRING([--enable-gallium-llvm],
1441         [build gallium LLVM support @<:@default=disabled@:>@])],
1442     [enable_gallium_llvm="$enableval"],
1443     [enable_gallium_llvm=auto])
1444 if test "x$enable_gallium_llvm" = xyes; then
1445     if test "x$LLVM_CONFIG" != xno; then
1446         LLVM_VERSION=`$LLVM_CONFIG --version`
1447         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1448         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1449
1450         if test "x$HAS_UDIS86" != xno; then
1451             LLVM_LIBS="$LLVM_LIBS -ludis86"
1452             DEFINES="$DEFINES -DHAVE_UDIS86"
1453         fi
1454         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1455         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1456         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1457         MESA_LLVM=1
1458     else
1459         MESA_LLVM=0
1460     fi
1461 else
1462     MESA_LLVM=0
1463 fi
1464
1465 dnl
1466 dnl Gallium helper functions
1467 dnl
1468 gallium_check_st() {
1469     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1470          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1471     fi
1472     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1473          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1474     fi
1475     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1476          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1477     fi
1478 }
1479
1480
1481 dnl
1482 dnl Gallium SVGA configuration
1483 dnl
1484 AC_ARG_ENABLE([gallium-svga],
1485     [AS_HELP_STRING([--enable-gallium-svga],
1486         [build gallium SVGA @<:@default=disabled@:>@])],
1487     [enable_gallium_svga="$enableval"],
1488     [enable_gallium_svga=auto])
1489 if test "x$enable_gallium_svga" = xyes; then
1490     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1491     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1492 elif test "x$enable_gallium_svga" = xauto; then
1493     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1494 fi
1495
1496 dnl
1497 dnl Gallium i915 configuration
1498 dnl
1499 AC_ARG_ENABLE([gallium-i915],
1500     [AS_HELP_STRING([--enable-gallium-i915],
1501         [build gallium i915 @<:@default=disabled@:>@])],
1502     [enable_gallium_i915="$enableval"],
1503     [enable_gallium_i915=auto])
1504 if test "x$enable_gallium_i915" = xyes; then
1505     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1506     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1507     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1508 elif test "x$enable_gallium_i915" = xauto; then
1509     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1510     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1511 fi
1512
1513 dnl
1514 dnl Gallium i965 configuration
1515 dnl
1516 AC_ARG_ENABLE([gallium-i965],
1517     [AS_HELP_STRING([--enable-gallium-i965],
1518         [build gallium i965 @<:@default=disabled@:>@])],
1519     [enable_gallium_i965="$enableval"],
1520     [enable_gallium_i965=auto])
1521 if test "x$enable_gallium_i965" = xyes; then
1522     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1523     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1524 elif test "x$enable_gallium_i965" = xauto; then
1525     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1526 fi
1527
1528 dnl
1529 dnl Gallium Radeon r300g configuration
1530 dnl
1531 AC_ARG_ENABLE([gallium-radeon],
1532     [AS_HELP_STRING([--enable-gallium-radeon],
1533         [build gallium radeon @<:@default=disabled@:>@])],
1534     [enable_gallium_radeon="$enableval"],
1535     [enable_gallium_radeon=auto])
1536 if test "x$enable_gallium_radeon" = xauto; then
1537     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1538         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1539         gallium_check_st "radeon/drm" "dri-r300"
1540     else
1541         AC_MSG_WARN([libdrm_radeon is missing, not building gallium-radeon (r300)])
1542     fi
1543 fi
1544 if test "x$enable_gallium_radeon" = xyes; then
1545     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1546         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1547         gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1548     else
1549         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-radeon (r300)])
1550     fi
1551 fi
1552
1553 dnl
1554 dnl Gallium Radeon r600g configuration
1555 dnl
1556 AC_ARG_ENABLE([gallium-r600],
1557     [AS_HELP_STRING([--enable-gallium-r600],
1558         [build gallium radeon @<:@default=disabled@:>@])],
1559     [enable_gallium_r600="$enableval"],
1560     [enable_gallium_r600=auto])
1561 if test "x$enable_gallium_r600" = xyes; then
1562     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1563         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1564         gallium_check_st "r600/drm" "dri-r600"
1565     else
1566         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-r600])
1567     fi
1568 fi
1569
1570 dnl
1571 dnl Gallium Nouveau configuration
1572 dnl
1573 AC_ARG_ENABLE([gallium-nouveau],
1574     [AS_HELP_STRING([--enable-gallium-nouveau],
1575         [build gallium nouveau @<:@default=disabled@:>@])],
1576     [enable_gallium_nouveau="$enableval"],
1577     [enable_gallium_nouveau=no])
1578 if test "x$enable_gallium_nouveau" = xyes; then
1579     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1580     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1581 fi
1582
1583 dnl
1584 dnl Gallium swrast configuration
1585 dnl
1586 AC_ARG_ENABLE([gallium-swrast],
1587     [AS_HELP_STRING([--enable-gallium-swrast],
1588         [build gallium swrast @<:@default=auto@:>@])],
1589     [enable_gallium_swrast="$enableval"],
1590     [enable_gallium_swrast=auto])
1591 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1592     if test "x$HAVE_ST_DRI" = xyes; then
1593         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1594     fi
1595 fi
1596
1597 dnl prepend CORE_DIRS to SRC_DIRS
1598 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1599
1600 dnl Restore LDFLAGS and CPPFLAGS
1601 LDFLAGS="$_SAVE_LDFLAGS"
1602 CPPFLAGS="$_SAVE_CPPFLAGS"
1603
1604 dnl Substitute the config
1605 AC_CONFIG_FILES([configs/autoconf])
1606
1607 dnl Replace the configs/current symlink
1608 AC_CONFIG_COMMANDS([configs],[
1609 if test -f configs/current || test -L configs/current; then
1610     rm -f configs/current
1611 fi
1612 ln -s autoconf configs/current
1613 ])
1614
1615 AC_OUTPUT
1616
1617 dnl
1618 dnl Output some configuration info for the user
1619 dnl
1620 echo ""
1621 echo "        prefix:          $prefix"
1622 echo "        exec_prefix:     $exec_prefix"
1623 echo "        libdir:          $libdir"
1624 echo "        includedir:      $includedir"
1625
1626 dnl Driver info
1627 echo ""
1628 echo "        Driver:          $mesa_driver"
1629 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1630     echo "        OSMesa:          lib$OSMESA_LIB"
1631 else
1632     echo "        OSMesa:          no"
1633 fi
1634 if test "$mesa_driver" = dri; then
1635     # cleanup the drivers var
1636     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1637 if test "x$DRI_DIRS" = x; then
1638     echo "        DRI drivers:     no"
1639 else
1640     echo "        DRI drivers:     $dri_dirs"
1641 fi
1642     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1643 fi
1644 echo "        Use XCB:         $enable_xcb"
1645
1646 echo ""
1647 if test "x$MESA_LLVM" = x1; then
1648     echo "        llvm:            yes"
1649     echo "        llvm-config:     $LLVM_CONFIG"
1650     echo "        llvm-version:    $LLVM_VERSION"
1651 else
1652     echo "        llvm:            no"
1653 fi
1654
1655 echo ""
1656 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1657     echo "        Gallium:         yes"
1658     echo "        Gallium dirs:    $GALLIUM_DIRS"
1659     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1660     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1661     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1662     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1663     if test "x$HAVE_ST_EGL" = xyes; then
1664         echo "        EGL client APIs: $EGL_CLIENT_APIS"
1665     fi
1666 else
1667     echo "        Gallium:         no"
1668 fi
1669
1670 dnl Libraries
1671 echo ""
1672 echo "        Shared libs:     $enable_shared"
1673 echo "        Static libs:     $enable_static"
1674 if test "$enable_egl" = yes; then
1675     echo "        EGL:             $EGL_DRIVERS_DIRS"
1676     echo "        EGL platforms:   $EGL_PLATFORMS"
1677 else
1678     echo "        EGL:             no"
1679 fi
1680 echo "        GLU:             $enable_glu"
1681 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1682 echo "        glut:            $enable_glut"
1683
1684 dnl Compiler options
1685 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1686 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1687     $SED 's/^ *//;s/  */ /;s/ *$//'`
1688 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1689     $SED 's/^ *//;s/  */ /;s/ *$//'`
1690 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1691 echo ""
1692 echo "        CFLAGS:          $cflags"
1693 echo "        CXXFLAGS:        $cxxflags"
1694 echo "        Macros:          $defines"
1695 echo ""
1696 echo "        PYTHON2:         $PYTHON2"
1697
1698 echo ""
1699 echo "        Run '${MAKE-make}' to build Mesa"
1700 echo ""