configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 # Support silent build rules, requires at least automake-1.11. Disable
  50 # by either passing --disable-silent-rules to configure or passing V=1
  51 # to make
  52 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  53     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  54
  55 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  56
  57 dnl Set internal versions
  58 OSMESA_VERSION=8
  59 AC_SUBST([OSMESA_VERSION])
  60
  61 dnl Versions for external dependencies
  62 LIBDRM_REQUIRED=2.4.38
  63 LIBDRM_RADEON_REQUIRED=2.4.56
  64 LIBDRM_INTEL_REQUIRED=2.4.60
  65 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  66 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  67 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  68 DRI2PROTO_REQUIRED=2.6
  69 DRI3PROTO_REQUIRED=1.0
  70 PRESENTPROTO_REQUIRED=1.0
  71 LIBUDEV_REQUIRED=151
  72 GLPROTO_REQUIRED=1.4.14
  73 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  74 LIBVA_REQUIRED=0.35.0
  75 VDPAU_REQUIRED=0.4.1
  76 WAYLAND_REQUIRED=1.2.0
  77 XCB_REQUIRED=1.9.3
  78 XCBDRI2_REQUIRED=1.8
  79 XCBGLX_REQUIRED=1.8.1
  80 XSHMFENCE_REQUIRED=1.1
  81 XVMC_REQUIRED=1.0.6
  82 PYTHON_MAKO_REQUIRED=0.3.4
  83
  84 dnl Check for progs
  85 AC_PROG_CPP
  86 AC_PROG_CC
  87 AC_PROG_CXX
  88 AM_PROG_CC_C_O
  89 AM_PROG_AS
  90 AX_CHECK_GNU_MAKE
  91 AC_CHECK_PROGS([PYTHON2], [python2 python])
  92 AC_PROG_SED
  93 AC_PROG_MKDIR_P
  94
  95 AC_SYS_LARGEFILE
  96
  97 LT_PREREQ([2.2])
  98 LT_INIT([disable-static])
  99
 100 AX_PROG_BISON([],
 101               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 102                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 103 AX_PROG_FLEX([],
 104              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 105                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 106
 107 AC_CHECK_PROG(INDENT, indent, indent, cat)
 108 if test "x$INDENT" != "xcat"; then
 109     # Only GNU indent is supported
 110     INDENT_VERSION=`indent --version | grep GNU`
 111     if test $? -eq 0; then
 112        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 113     else
 114        INDENT="cat"
 115     fi
 116 fi
 117
 118 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 119 if test -n "$PYTHON2" -a "x$acv_mako_found" = "xyes"; then
 120     AC_MSG_RESULT(yes)
 121 else
 122     AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 123 fi
 124
 125 AC_PROG_INSTALL
 126
 127 dnl We need a POSIX shell for parts of the build. Assume we have one
 128 dnl in most cases.
 129 case "$host_os" in
 130 solaris*)
 131     # Solaris /bin/sh is too old/non-POSIX compliant
 132     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 133     SHELL="$POSIX_SHELL"
 134     ;;
 135 esac
 136
 137 dnl clang is mostly GCC-compatible, but its version is much lower,
 138 dnl so we have to check for it.
 139 AC_MSG_CHECKING([if compiling with clang])
 140
 141 AC_COMPILE_IFELSE(
 142 [AC_LANG_PROGRAM([], [[
 143 #ifndef __clang__
 144        not clang
 145 #endif
 146 ]])],
 147 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 148
 149 AC_MSG_RESULT([$acv_mesa_CLANG])
 150
 151 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 152 dnl versions are explictly not supported.
 153 GEN_ASM_OFFSETS=no
 154 USE_GNU99=no
 155 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 156     AC_MSG_CHECKING([whether gcc version is sufficient])
 157     major=0
 158     minor=0
 159
 160     GCC_VERSION=`$CC -dumpversion`
 161     if test $? -eq 0; then
 162         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 163         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 164     fi
 165
 166     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 167         AC_MSG_RESULT([no])
 168         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 169     else
 170         AC_MSG_RESULT([yes])
 171     fi
 172
 173     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 174         USE_GNU99=yes
 175     fi
 176     if test "x$cross_compiling" = xyes; then
 177         GEN_ASM_OFFSETS=yes
 178     fi
 179 fi
 180
 181 dnl Check for compiler builtins
 182 AX_GCC_BUILTIN([__builtin_bswap32])
 183 AX_GCC_BUILTIN([__builtin_bswap64])
 184 AX_GCC_BUILTIN([__builtin_clz])
 185 AX_GCC_BUILTIN([__builtin_clzll])
 186 AX_GCC_BUILTIN([__builtin_ctz])
 187 AX_GCC_BUILTIN([__builtin_expect])
 188 AX_GCC_BUILTIN([__builtin_ffs])
 189 AX_GCC_BUILTIN([__builtin_ffsll])
 190 AX_GCC_BUILTIN([__builtin_popcount])
 191 AX_GCC_BUILTIN([__builtin_popcountll])
 192 AX_GCC_BUILTIN([__builtin_unreachable])
 193
 194 AX_GCC_FUNC_ATTRIBUTE([flatten])
 195 AX_GCC_FUNC_ATTRIBUTE([format])
 196 AX_GCC_FUNC_ATTRIBUTE([malloc])
 197 AX_GCC_FUNC_ATTRIBUTE([packed])
 198 AX_GCC_FUNC_ATTRIBUTE([unused])
 199
 200 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 201
 202 dnl Make sure the pkg-config macros are defined
 203 m4_ifndef([PKG_PROG_PKG_CONFIG],
 204     [m4_fatal([Could not locate the pkg-config autoconf macros.
 205   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 206   are in a different location, try setting the environment variable
 207   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 208 PKG_PROG_PKG_CONFIG()
 209
 210 dnl LIB_DIR - library basename
 211 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 212 AC_SUBST([LIB_DIR])
 213
 214 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 215 _SAVE_LDFLAGS="$LDFLAGS"
 216 _SAVE_CPPFLAGS="$CPPFLAGS"
 217
 218 dnl Compiler macros
 219 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 220 AC_SUBST([DEFINES])
 221 case "$host_os" in
 222 linux*|*-gnu*|gnu*)
 223     DEFINES="$DEFINES -D_GNU_SOURCE"
 224     ;;
 225 solaris*)
 226     DEFINES="$DEFINES -DSVR4"
 227     ;;
 228 cygwin*)
 229     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 230     ;;
 231 esac
 232
 233 dnl Add flags for gcc and g++
 234 if test "x$GCC" = xyes; then
 235     CFLAGS="$CFLAGS -Wall"
 236
 237     if test "x$USE_GNU99" = xyes; then
 238         CFLAGS="$CFLAGS -std=gnu99"
 239     else
 240         CFLAGS="$CFLAGS -std=c99"
 241     fi
 242
 243     # Enable -Werror=implicit-function-declaration and
 244     # -Werror=missing-prototypes, if available, or otherwise, just
 245     # -Wmissing-prototypes.  This is particularly useful to avoid
 246     # generating a loadable driver module that has undefined symbols.
 247     save_CFLAGS="$CFLAGS"
 248     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 249     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 250     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 251     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 252                    AC_MSG_RESULT([yes]),
 253                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 254                     AC_MSG_RESULT([no])]);
 255
 256     # Enable -fvisibility=hidden if using a gcc that supports it
 257     save_CFLAGS="$CFLAGS"
 258     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 259     VISIBILITY_CFLAGS="-fvisibility=hidden"
 260     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 261     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 262                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 263
 264     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 265     CFLAGS=$save_CFLAGS
 266
 267     # Work around aliasing bugs - developers should comment this out
 268     CFLAGS="$CFLAGS -fno-strict-aliasing"
 269
 270     # gcc's builtin memcmp is slower than glibc's
 271     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 272     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 273
 274     # Flags to help ensure that certain portions of the code -- and only those
 275     # portions -- can be built with MSVC:
 276     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 277     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 278     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 279     #   supports most of C99)
 280     # - the rest has no compiler compiler restrictions
 281     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 282     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 283
 284     # Enable -Werror=vla if compiler supports it
 285     save_CFLAGS="$CFLAGS"
 286     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 287     CFLAGS="$CFLAGS -Werror=vla"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 290                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 291                     AC_MSG_RESULT([yes])],
 292                     AC_MSG_RESULT([no]));
 293     CFLAGS="$save_CFLAGS"
 294
 295     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 296     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 297 fi
 298 if test "x$GXX" = xyes; then
 299     CXXFLAGS="$CXXFLAGS -Wall"
 300
 301     # Enable -fvisibility=hidden if using a gcc that supports it
 302     save_CXXFLAGS="$CXXFLAGS"
 303     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 304     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 305     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 306     AC_LANG_PUSH([C++])
 307     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 308                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 309     AC_LANG_POP([C++])
 310
 311     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 312     CXXFLAGS=$save_CXXFLAGS
 313
 314     # Work around aliasing bugs - developers should comment this out
 315     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 316
 317     # gcc's builtin memcmp is slower than glibc's
 318     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 319     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 320 fi
 321
 322 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 323 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 324 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 325 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 326
 327 dnl even if the compiler appears to support it, using visibility attributes isn't
 328 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 329 case "$host_os" in
 330 cygwin*)
 331     VISIBILITY_CFLAGS=""
 332     VISIBILITY_CXXFLAGS=""
 333     ;;
 334 esac
 335
 336 AC_SUBST([VISIBILITY_CFLAGS])
 337 AC_SUBST([VISIBILITY_CXXFLAGS])
 338
 339 dnl
 340 dnl Optional flags, check for compiler support
 341 dnl
 342 SSE41_CFLAGS="-msse4.1"
 343 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 344 dnl stack, but on x86-32 such alignment is not guaranteed.
 345 case "$target_cpu" in
 346 i?86)
 347     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 348     ;;
 349 esac
 350 save_CFLAGS="$CFLAGS"
 351 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 352 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 353 #include <smmintrin.h>
 354 int main () {
 355     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 356     c = _mm_max_epu32(a, b);
 357     return 0;
 358 }]])], SSE41_SUPPORTED=1)
 359 CFLAGS="$save_CFLAGS"
 360 if test "x$SSE41_SUPPORTED" = x1; then
 361     DEFINES="$DEFINES -DUSE_SSE41"
 362 fi
 363 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 364 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 365
 366 dnl Can't have static and shared libraries, default to static if user
 367 dnl explicitly requested. If both disabled, set to static since shared
 368 dnl was explicitly requested.
 369 case "x$enable_static$enable_shared" in
 370 xyesyes)
 371     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 372     enable_shared=no
 373     ;;
 374 xnono)
 375     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 376     enable_shared=yes
 377     ;;
 378 esac
 379
 380 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 381
 382 dnl
 383 dnl other compiler options
 384 dnl
 385 AC_ARG_ENABLE([debug],
 386     [AS_HELP_STRING([--enable-debug],
 387         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 388     [enable_debug="$enableval"],
 389     [enable_debug=no]
 390 )
 391 if test "x$enable_debug" = xyes; then
 392     DEFINES="$DEFINES -DDEBUG"
 393     if test "x$GCC" = xyes; then
 394         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 395             CFLAGS="$CFLAGS -g"
 396         fi
 397         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 398             CFLAGS="$CFLAGS -O0"
 399         fi
 400     fi
 401     if test "x$GXX" = xyes; then
 402         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 403             CXXFLAGS="$CXXFLAGS -g"
 404         fi
 405         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 406             CXXFLAGS="$CXXFLAGS -O0"
 407         fi
 408     fi
 409 else
 410    DEFINES="$DEFINES -DNDEBUG"
 411 fi
 412
 413 dnl
 414 dnl Check if linker supports -Bsymbolic
 415 dnl
 416 save_LDFLAGS=$LDFLAGS
 417 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 418 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 419 AC_LINK_IFELSE(
 420     [AC_LANG_SOURCE([int main() { return 0;}])],
 421     [AC_MSG_RESULT([yes])
 422         BSYMBOLIC="-Wl,-Bsymbolic";],
 423     [AC_MSG_RESULT([no])
 424         BSYMBOLIC="";])
 425 LDFLAGS=$save_LDFLAGS
 426
 427 AC_SUBST([BSYMBOLIC])
 428
 429 dnl
 430 dnl Check if linker supports garbage collection
 431 dnl
 432 save_LDFLAGS=$LDFLAGS
 433 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 434 AC_MSG_CHECKING([whether ld supports --gc-sections])
 435 AC_LINK_IFELSE(
 436     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 437     [AC_MSG_RESULT([yes])
 438         GC_SECTIONS="-Wl,--gc-sections";],
 439     [AC_MSG_RESULT([no])
 440         GC_SECTIONS="";])
 441 LDFLAGS=$save_LDFLAGS
 442
 443 AC_SUBST([GC_SECTIONS])
 444
 445 dnl
 446 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 447 dnl so when these flags are passed to ld via libtool the checks will fail
 448 dnl
 449 case "$host_os" in
 450 openbsd* | darwin* )
 451     LD_NO_UNDEFINED="" ;;
 452 *)
 453     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 454 esac
 455
 456 AC_SUBST([LD_NO_UNDEFINED])
 457
 458 dnl
 459 dnl Check if linker supports version scripts
 460 dnl
 461 AC_MSG_CHECKING([if the linker supports version-scripts])
 462 save_LDFLAGS=$LDFLAGS
 463 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 464 cat > conftest.map <<EOF
 465 VERSION_1 {
 466      global:
 467          main;
 468
 469      local:
 470          *;
 471 };
 472 EOF
 473 AC_LINK_IFELSE(
 474     [AC_LANG_SOURCE([int main() { return 0;}])],
 475     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 476     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 477 LDFLAGS=$save_LDFLAGS
 478 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 479
 480 dnl
 481 dnl Check if linker supports dynamic list files
 482 dnl
 483 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 484 save_LDFLAGS=$LDFLAGS
 485 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 486 cat > conftest.dyn <<EOF
 487 {
 488         radeon_drm_winsys_create;
 489 };
 490 EOF
 491 AC_LINK_IFELSE(
 492     [AC_LANG_SOURCE([int main() { return 0;}])],
 493     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 494     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 495 LDFLAGS=$save_LDFLAGS
 496 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 497
 498 dnl
 499 dnl compatibility symlinks
 500 dnl
 501 case "$host_os" in
 502 linux* )
 503     HAVE_COMPAT_SYMLINKS=yes ;;
 504 * )
 505     HAVE_COMPAT_SYMLINKS=no ;;
 506 esac
 507
 508 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 509
 510 dnl
 511 dnl library names
 512 dnl
 513 case "$host_os" in
 514 darwin* )
 515     LIB_EXT='dylib' ;;
 516 cygwin* )
 517     LIB_EXT='dll' ;;
 518 aix* )
 519     LIB_EXT='a' ;;
 520 * )
 521     LIB_EXT='so' ;;
 522 esac
 523
 524 AC_SUBST([LIB_EXT])
 525
 526 AC_ARG_WITH([gl-lib-name],
 527   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 528     [specify GL library name @<:@default=GL@:>@])],
 529   [GL_LIB=$withval],
 530   [GL_LIB=GL])
 531 AC_ARG_WITH([osmesa-lib-name],
 532   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 533     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 534   [OSMESA_LIB=$withval],
 535   [OSMESA_LIB=OSMesa])
 536 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 537 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 538
 539 dnl
 540 dnl Mangled Mesa support
 541 dnl
 542 AC_ARG_ENABLE([mangling],
 543   [AS_HELP_STRING([--enable-mangling],
 544     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 545   [enable_mangling="${enableval}"],
 546   [enable_mangling=no]
 547 )
 548 if test "x${enable_mangling}" = "xyes" ; then
 549   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 550   GL_LIB="Mangled${GL_LIB}"
 551   OSMESA_LIB="Mangled${OSMESA_LIB}"
 552 fi
 553 AC_SUBST([GL_LIB])
 554 AC_SUBST([OSMESA_LIB])
 555
 556 dnl
 557 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 558 dnl
 559 AC_ARG_ENABLE([texture-float],
 560     [AS_HELP_STRING([--enable-texture-float],
 561         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 562     [enable_texture_float="$enableval"],
 563     [enable_texture_float=no]
 564 )
 565 if test "x$enable_texture_float" = xyes; then
 566     AC_MSG_WARN([Floating-point textures enabled.])
 567     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 568     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 569 fi
 570
 571 dnl
 572 dnl Arch/platform-specific settings
 573 dnl
 574 AC_ARG_ENABLE([asm],
 575     [AS_HELP_STRING([--disable-asm],
 576         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 577     [enable_asm="$enableval"],
 578     [enable_asm=yes]
 579 )
 580 asm_arch=""
 581 AC_MSG_CHECKING([whether to enable assembly])
 582 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 583 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 584 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 585     case "$host_cpu" in
 586     i?86 | x86_64 | amd64)
 587         enable_asm=no
 588         AC_MSG_RESULT([no, cross compiling])
 589         ;;
 590     esac
 591 fi
 592 # check for supported arches
 593 if test "x$enable_asm" = xyes; then
 594     case "$host_cpu" in
 595     i?86)
 596         case "$host_os" in
 597         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 598             asm_arch=x86
 599             ;;
 600         esac
 601         ;;
 602     x86_64|amd64)
 603         case "$host_os" in
 604         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 605             asm_arch=x86_64
 606             ;;
 607         esac
 608         ;;
 609     sparc*)
 610         case "$host_os" in
 611         linux*)
 612             asm_arch=sparc
 613             ;;
 614         esac
 615         ;;
 616     esac
 617
 618     case "$asm_arch" in
 619     x86)
 620         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 621         AC_MSG_RESULT([yes, x86])
 622         ;;
 623     x86_64|amd64)
 624         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 625         AC_MSG_RESULT([yes, x86_64])
 626         ;;
 627     sparc)
 628         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 629         AC_MSG_RESULT([yes, sparc])
 630         ;;
 631     *)
 632         AC_MSG_RESULT([no, platform not supported])
 633         ;;
 634     esac
 635 fi
 636
 637 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 638 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 639
 640 dnl Check to see if dlopen is in default libraries (like Solaris, which
 641 dnl has it in libc), or if libdl is needed to get it.
 642 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 643     [AC_CHECK_LIB([dl], [dlopen],
 644        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 645 AC_SUBST([DLOPEN_LIBS])
 646
 647 dnl Check if that library also has dladdr
 648 save_LIBS="$LIBS"
 649 LIBS="$LIBS $DLOPEN_LIBS"
 650 AC_CHECK_FUNCS([dladdr])
 651 LIBS="$save_LIBS"
 652
 653 case "$host_os" in
 654 darwin*|mingw*)
 655     ;;
 656 *)
 657     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 658                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 659                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 660     AC_SUBST([CLOCK_LIB])
 661     ;;
 662 esac
 663
 664 dnl See if posix_memalign is available
 665 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 666
 667 dnl Check for pthreads
 668 case "$host_os" in
 669 mingw*)
 670     ;;
 671 *)
 672     AX_PTHREAD
 673     if test "x$ax_pthread_ok" = xno; then
 674         AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 675     fi
 676     ;;
 677 esac
 678 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 679 dnl to -pthread, which causes problems if we need -lpthread to appear in
 680 dnl pkgconfig files.
 681 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 682
 683 dnl SELinux awareness.
 684 AC_ARG_ENABLE([selinux],
 685     [AS_HELP_STRING([--enable-selinux],
 686         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 687     [MESA_SELINUX="$enableval"],
 688     [MESA_SELINUX=no])
 689 if test "x$enable_selinux" = "xyes"; then
 690     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 691         [AC_CHECK_HEADER([selinux/selinux.h],[],
 692                          [AC_MSG_ERROR([SELinux headers not found])])
 693          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 694                       [AC_MSG_ERROR([SELinux library not found])])
 695          SELINUX_LIBS="-lselinux"])
 696     DEFINES="$DEFINES -DMESA_SELINUX"
 697 fi
 698 AC_SUBST([SELINUX_CFLAGS])
 699 AC_SUBST([SELINUX_LIBS])
 700
 701 dnl Options for APIs
 702 AC_ARG_ENABLE([opengl],
 703     [AS_HELP_STRING([--disable-opengl],
 704         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 705     [enable_opengl="$enableval"],
 706     [enable_opengl=yes])
 707 AC_ARG_ENABLE([gles1],
 708     [AS_HELP_STRING([--enable-gles1],
 709         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 710     [enable_gles1="$enableval"],
 711     [enable_gles1=no])
 712 AC_ARG_ENABLE([gles2],
 713     [AS_HELP_STRING([--enable-gles2],
 714         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 715     [enable_gles2="$enableval"],
 716     [enable_gles2=no])
 717
 718 AC_ARG_ENABLE([dri],
 719     [AS_HELP_STRING([--enable-dri],
 720         [enable DRI modules @<:@default=enabled@:>@])],
 721     [enable_dri="$enableval"],
 722     [enable_dri=yes])
 723
 724 case "$host_os" in
 725 linux*)
 726     dri3_default=yes
 727     ;;
 728 *)
 729     dri3_default=no
 730     ;;
 731 esac
 732 AC_ARG_ENABLE([dri3],
 733     [AS_HELP_STRING([--enable-dri3],
 734         [enable DRI3 @<:@default=auto@:>@])],
 735     [enable_dri3="$enableval"],
 736     [enable_dri3="$dri3_default"])
 737 AC_ARG_ENABLE([glx],
 738     [AS_HELP_STRING([--enable-glx],
 739         [enable GLX library @<:@default=enabled@:>@])],
 740     [enable_glx="$enableval"],
 741     [enable_glx=yes])
 742 AC_ARG_ENABLE([osmesa],
 743     [AS_HELP_STRING([--enable-osmesa],
 744         [enable OSMesa library @<:@default=disabled@:>@])],
 745     [enable_osmesa="$enableval"],
 746     [enable_osmesa=no])
 747 AC_ARG_ENABLE([gallium-osmesa],
 748     [AS_HELP_STRING([--enable-gallium-osmesa],
 749         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 750     [enable_gallium_osmesa="$enableval"],
 751     [enable_gallium_osmesa=no])
 752 AC_ARG_ENABLE([egl],
 753     [AS_HELP_STRING([--disable-egl],
 754         [disable EGL library @<:@default=enabled@:>@])],
 755     [enable_egl="$enableval"],
 756     [enable_egl=yes])
 757
 758 AC_ARG_ENABLE([xa],
 759     [AS_HELP_STRING([--enable-xa],
 760         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 761     [enable_xa="$enableval"],
 762     [enable_xa=no])
 763 AC_ARG_ENABLE([gbm],
 764    [AS_HELP_STRING([--enable-gbm],
 765          [enable gbm library @<:@default=auto@:>@])],
 766    [enable_gbm="$enableval"],
 767    [enable_gbm=auto])
 768 AC_ARG_ENABLE([nine],
 769     [AS_HELP_STRING([--enable-nine],
 770         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 771     [enable_nine="$enableval"],
 772     [enable_nine=no])
 773
 774 AC_ARG_ENABLE([xvmc],
 775    [AS_HELP_STRING([--enable-xvmc],
 776          [enable xvmc library @<:@default=auto@:>@])],
 777    [enable_xvmc="$enableval"],
 778    [enable_xvmc=auto])
 779 AC_ARG_ENABLE([vdpau],
 780    [AS_HELP_STRING([--enable-vdpau],
 781          [enable vdpau library @<:@default=auto@:>@])],
 782    [enable_vdpau="$enableval"],
 783    [enable_vdpau=auto])
 784 AC_ARG_ENABLE([omx],
 785    [AS_HELP_STRING([--enable-omx],
 786          [enable OpenMAX library @<:@default=disabled@:>@])],
 787    [enable_omx="$enableval"],
 788    [enable_omx=no])
 789 AC_ARG_ENABLE([va],
 790    [AS_HELP_STRING([--enable-va],
 791          [enable va library @<:@default=auto@:>@])],
 792    [enable_va="$enableval"],
 793    [enable_va=auto])
 794 AC_ARG_ENABLE([opencl],
 795    [AS_HELP_STRING([--enable-opencl],
 796          [enable OpenCL library @<:@default=disabled@:>@])],
 797    [enable_opencl="$enableval"],
 798    [enable_opencl=no])
 799 AC_ARG_ENABLE([opencl_icd],
 800    [AS_HELP_STRING([--enable-opencl-icd],
 801           [Build an OpenCL ICD library to be loaded by an ICD implementation
 802            @<:@default=disabled@:>@])],
 803     [enable_opencl_icd="$enableval"],
 804     [enable_opencl_icd=no])
 805 AC_ARG_ENABLE([xlib-glx],
 806     [AS_HELP_STRING([--enable-xlib-glx],
 807         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 808     [enable_xlib_glx="$enableval"],
 809     [enable_xlib_glx=no])
 810
 811 AC_ARG_ENABLE([r600-llvm-compiler],
 812     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 813         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 814     [enable_r600_llvm="$enableval"],
 815     [enable_r600_llvm=no])
 816
 817 AC_ARG_ENABLE([gallium-tests],
 818     [AS_HELP_STRING([--enable-gallium-tests],
 819         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 820     [enable_gallium_tests="$enableval"],
 821     [enable_gallium_tests=no])
 822
 823 # Option for Gallium drivers
 824
 825 # Keep this in sync with the --with-gallium-drivers help string default value
 826 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 827
 828 AC_ARG_WITH([gallium-drivers],
 829     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 830         [comma delimited Gallium drivers list, e.g.
 831         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 832         @<:@default=r300,r600,svga,swrast@:>@])],
 833     [with_gallium_drivers="$withval"],
 834     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 835
 836 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 837 # here so that the script doesn't choke on an unknown driver name later.
 838 case "$with_gallium_drivers" in
 839     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 840     no) with_gallium_drivers='' ;;
 841 esac
 842
 843 if test "x$enable_opengl" = xno -a \
 844         "x$enable_gles1" = xno -a \
 845         "x$enable_gles2" = xno -a \
 846         "x$enable_nine" = xno -a \
 847         "x$enable_xa" = xno -a \
 848         "x$enable_xvmc" = xno -a \
 849         "x$enable_vdpau" = xno -a \
 850         "x$enable_omx" = xno -a \
 851         "x$enable_va" = xno -a \
 852         "x$enable_opencl" = xno; then
 853     AC_MSG_ERROR([at least one API should be enabled])
 854 fi
 855
 856 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 857 if test "x$enable_opengl" = xno -a \
 858         "x$enable_gles1" = xyes; then
 859     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 860 fi
 861
 862 if test "x$enable_opengl" = xno -a \
 863         "x$enable_gles2" = xyes; then
 864     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 865 fi
 866
 867 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 868 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 869 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 870 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 871                                         "x$enable_gles1" = xyes -o \
 872                                         "x$enable_gles2" = xyes)
 873
 874 if test "x$enable_glx" = xno; then
 875     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 876     enable_xlib_glx=no
 877 fi
 878
 879 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 880     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 881 fi
 882
 883 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 884     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 885 fi
 886
 887 # Disable GLX if OpenGL is not enabled
 888 if test "x$enable_glx$enable_opengl" = xyesno; then
 889     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 890     enable_glx=no
 891 fi
 892
 893 # Disable GLX if DRI and Xlib-GLX are not enabled
 894 if test "x$enable_glx" = xyes -a \
 895         "x$enable_dri" = xno -a \
 896         "x$enable_xlib_glx" = xno; then
 897     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 898     enable_glx=no
 899 fi
 900
 901 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 902                                   "x$enable_dri" = xyes)
 903
 904 # Select which platform-dependent DRI code gets built
 905 case "$host_os" in
 906 darwin*)
 907     dri_platform='apple' ;;
 908 gnu*|mingw*|cygwin*)
 909     dri_platform='none' ;;
 910 *)
 911     dri_platform='drm' ;;
 912 esac
 913
 914 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 915 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 916 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 917 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 918 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 919
 920 AC_ARG_ENABLE([shared-glapi],
 921     [AS_HELP_STRING([--enable-shared-glapi],
 922         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 923     [enable_shared_glapi="$enableval"],
 924     [enable_shared_glapi=yes])
 925
 926 case "x$enable_opengl$enable_gles1$enable_gles2" in
 927 x*yes*yes*)
 928     if test "x$enable_shared_glapi" = xno; then
 929         AC_MSG_ERROR([shared GLAPI required when building two or more of
 930                       the following APIs - opengl, gles1 gles2])
 931     fi
 932     ;;
 933 esac
 934
 935 # Building Xlib-GLX requires shared glapi to be disabled.
 936 if test "x$enable_xlib_glx" = xyes; then
 937     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 938     enable_shared_glapi=no
 939 fi
 940
 941 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 942
 943 # Build the pipe-drivers as separate libraries/modules.
 944 # Do not touch this unless you know what you are doing.
 945 # XXX: Expose via configure option ?
 946 enable_shared_pipe_drivers=no
 947
 948 dnl
 949 dnl Driver specific build directories
 950 dnl
 951
 952 case "x$enable_glx$enable_xlib_glx" in
 953 xyesyes)
 954     NEED_WINSYS_XLIB="yes"
 955     ;;
 956 esac
 957
 958 if test "x$enable_dri" = xyes; then
 959     enable_gallium_loader="$enable_shared_pipe_drivers"
 960 fi
 961
 962 if test "x$enable_gallium_osmesa" = xyes; then
 963     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 964         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 965     fi
 966     if test "x$enable_osmesa" = xyes; then
 967         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 968     fi
 969 fi
 970
 971 AC_SUBST([MESA_LLVM])
 972
 973 # SHA1 hashing
 974 AC_ARG_WITH([sha1],
 975         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 976         [choose SHA1 implementation])])
 977 case "x$with_sha1" in
 978 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 979   ;;
 980 *)
 981         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 982 esac
 983
 984 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 985 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 986         with_sha1=libc
 987 fi
 988 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 989         AC_MSG_ERROR([sha1 in libc requested but not found])
 990 fi
 991 if test "x$with_sha1" = xlibc; then
 992         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 993                 [Use libc SHA1 functions])
 994         SHA1_LIBS=""
 995 fi
 996 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 997 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 998         with_sha1=CommonCrypto
 999 fi
1000 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1001         AC_MSG_ERROR([CommonCrypto requested but not found])
1002 fi
1003 if test "x$with_sha1" = xCommonCrypto; then
1004         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1005                 [Use CommonCrypto SHA1 functions])
1006         SHA1_LIBS=""
1007 fi
1008 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1009 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1010 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1011         with_sha1=CryptoAPI
1012 fi
1013 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1014         AC_MSG_ERROR([CryptoAPI requested but not found])
1015 fi
1016 if test "x$with_sha1" = xCryptoAPI; then
1017         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1018                 [Use CryptoAPI SHA1 functions])
1019         SHA1_LIBS=""
1020 fi
1021 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1022 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1023         with_sha1=libmd
1024 fi
1025 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1026         AC_MSG_ERROR([libmd requested but not found])
1027 fi
1028 if test "x$with_sha1" = xlibmd; then
1029         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1030                   [Use libmd SHA1 functions])
1031         SHA1_LIBS=-lmd
1032 fi
1033 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1034 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1035    with_sha1=libsha1
1036 fi
1037 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1038         AC_MSG_ERROR([libsha1 requested but not found])
1039 fi
1040 if test "x$with_sha1" = xlibsha1; then
1041         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1042                   [Use libsha1 for SHA1])
1043         SHA1_LIBS=-lsha1
1044 fi
1045 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1046 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1047         with_sha1=libnettle
1048 fi
1049 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1050         AC_MSG_ERROR([libnettle requested but not found])
1051 fi
1052 if test "x$with_sha1" = xlibnettle; then
1053         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1054                   [Use libnettle SHA1 functions])
1055         SHA1_LIBS=-lnettle
1056 fi
1057 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1058 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1059         with_sha1=libgcrypt
1060 fi
1061 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1062         AC_MSG_ERROR([libgcrypt requested but not found])
1063 fi
1064 if test "x$with_sha1" = xlibgcrypt; then
1065         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1066                   [Use libgcrypt SHA1 functions])
1067         SHA1_LIBS=-lgcrypt
1068 fi
1069 # We don't need all of the OpenSSL libraries, just libcrypto
1070 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1071 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1072                   [HAVE_OPENSSL_PKC=no])
1073 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1074         if test "x$with_sha1" = x; then
1075                 with_sha1=libcrypto
1076         fi
1077 else
1078         if test "x$with_sha1" = xlibcrypto; then
1079                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1080         fi
1081 fi
1082 if test "x$with_sha1" = xlibcrypto; then
1083         if test "x$HAVE_LIBCRYPTO" = xyes; then
1084                 SHA1_LIBS=-lcrypto
1085         else
1086                 SHA1_LIBS="$OPENSSL_LIBS"
1087                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1088         fi
1089 fi
1090 AC_MSG_CHECKING([for SHA1 implementation])
1091 AC_MSG_RESULT([$with_sha1])
1092 AC_SUBST(SHA1_LIBS)
1093 AC_SUBST(SHA1_CFLAGS)
1094
1095 # Allow user to configure out the shader-cache feature
1096 AC_ARG_ENABLE([shader-cache],
1097     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1098     [enable_shader_cache="$enableval"],
1099     [if test "x$with_sha1" != "x"; then
1100         enable_shader_cache=yes
1101      else
1102         enable_shader_cache=no
1103      fi])
1104 if test "x$with_sha1" = "x"; then
1105     if test "x$enable_shader_cache" = "xyes"; then
1106         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1107     fi
1108 fi
1109 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1110
1111 # Check for libdrm
1112 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1113                   [have_libdrm=yes], [have_libdrm=no])
1114 if test "x$have_libdrm" = xyes; then
1115         DEFINES="$DEFINES -DHAVE_LIBDRM"
1116 fi
1117
1118 case "$host_os" in
1119 linux*)
1120     need_pci_id=yes ;;
1121 *)
1122     need_pci_id=no ;;
1123 esac
1124
1125 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1126                   have_libudev=yes, have_libudev=no)
1127
1128 AC_ARG_ENABLE([sysfs],
1129     [AS_HELP_STRING([--enable-sysfs],
1130         [enable /sys PCI identification @<:@default=disabled@:>@])],
1131     [have_sysfs="$enableval"],
1132     [have_sysfs=no]
1133 )
1134
1135 if test "x$enable_dri" = xyes; then
1136     if test "$enable_static" = yes; then
1137         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1138     fi
1139
1140     # not a hard requirement as swrast does not depend on it
1141     if test "x$have_libdrm" = xyes; then
1142         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1143     fi
1144 fi
1145
1146 AC_ARG_ENABLE([driglx-direct],
1147     [AS_HELP_STRING([--disable-driglx-direct],
1148         [disable direct rendering in GLX and EGL for DRI \
1149             @<:@default=auto@:>@])],
1150     [driglx_direct="$enableval"],
1151     [driglx_direct="yes"])
1152
1153 dnl
1154 dnl libGL configuration per driver
1155 dnl
1156 case "x$enable_glx$enable_xlib_glx" in
1157 xyesyes)
1158     # Xlib-based GLX
1159     dri_modules="x11 xext xcb"
1160     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1161     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1162     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1163     GL_LIB_DEPS="$XLIBGL_LIBS"
1164     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1165     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1166     ;;
1167 xyesno)
1168     # DRI-based GLX
1169     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1170
1171     # find the DRI deps for libGL
1172     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1173
1174     if test x"$driglx_direct" = xyes; then
1175         if test x"$dri_platform" = xdrm ; then
1176             DEFINES="$DEFINES -DGLX_USE_DRM"
1177             if test "x$have_libdrm" != xyes; then
1178                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1179             fi
1180
1181             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1182             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1183             if test x"$enable_dri3" = xyes; then
1184                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1185                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1186             fi
1187
1188             if test x"$enable_dri" = xyes; then
1189                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1190             fi
1191
1192             if test x"$enable_dri3" = xyes; then
1193                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1194                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1195             fi
1196         fi
1197         if test x"$dri_platform" = xapple ; then
1198             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1199         fi
1200     fi
1201
1202     # add xf86vidmode if available
1203     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1204     if test "$HAVE_XF86VIDMODE" = yes ; then
1205         dri_modules="$dri_modules xxf86vm"
1206     fi
1207
1208     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1209     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1210     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1211     GL_LIB_DEPS="$DRIGL_LIBS"
1212
1213     # need DRM libs, $PTHREAD_LIBS, etc.
1214     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1215     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1216     ;;
1217 esac
1218
1219 have_pci_id=no
1220 if test "$have_libudev" = yes; then
1221     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1222     have_pci_id=yes
1223 fi
1224
1225 if test "$have_sysfs" = yes; then
1226     DEFINES="$DEFINES -DHAVE_SYSFS"
1227     have_pci_id=yes
1228 fi
1229
1230 # This is outside the case (above) so that it is invoked even for non-GLX
1231 # builds.
1232 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1233
1234 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1235 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1236 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1237 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1238
1239 AC_SUBST([X11_INCLUDES])
1240 AC_SUBST([GL_LIB_DEPS])
1241 AC_SUBST([GL_PC_REQ_PRIV])
1242 AC_SUBST([GL_PC_LIB_PRIV])
1243 AC_SUBST([GL_PC_CFLAGS])
1244 AC_SUBST([DRI_PC_REQ_PRIV])
1245 AC_SUBST([GLESv1_CM_LIB_DEPS])
1246 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1247 AC_SUBST([GLESv2_LIB_DEPS])
1248 AC_SUBST([GLESv2_PC_LIB_PRIV])
1249
1250 AC_SUBST([HAVE_XF86VIDMODE])
1251
1252 dnl
1253 dnl More GLX setup
1254 dnl
1255 case "x$enable_glx$enable_xlib_glx" in
1256 xyesyes)
1257     DEFINES="$DEFINES -DUSE_XSHM"
1258     ;;
1259 xyesno)
1260     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1261     if test "x$driglx_direct" = xyes; then
1262         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1263     fi
1264     ;;
1265 esac
1266
1267 dnl
1268 dnl TLS detection
1269 dnl
1270
1271 AC_ARG_ENABLE([glx-tls],
1272     [AS_HELP_STRING([--enable-glx-tls],
1273         [enable TLS support in GLX @<:@default=disabled@:>@])],
1274     [GLX_USE_TLS="$enableval"],
1275     [GLX_USE_TLS=no])
1276 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1277
1278 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1279       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1280
1281 dnl
1282 dnl More DRI setup
1283 dnl
1284 dnl Directory for DRI drivers
1285 AC_ARG_WITH([dri-driverdir],
1286     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1287         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1288     [DRI_DRIVER_INSTALL_DIR="$withval"],
1289     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1290 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1291 dnl Extra search path for DRI drivers
1292 AC_ARG_WITH([dri-searchpath],
1293     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1294         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1295     [DRI_DRIVER_SEARCH_DIR="$withval"],
1296     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1297 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1298 dnl Which drivers to build - default is chosen by platform
1299 AC_ARG_WITH([dri-drivers],
1300     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1301         [comma delimited classic DRI drivers list, e.g.
1302         "swrast,i965,radeon" @<:@default=auto@:>@])],
1303     [with_dri_drivers="$withval"],
1304     [with_dri_drivers=auto])
1305
1306 if test "x$with_dri_drivers" = xauto; then
1307     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1308         with_dri_drivers="yes"
1309     else
1310         with_dri_drivers="no"
1311     fi
1312 fi
1313 if test "x$with_dri_drivers" = xno; then
1314     with_dri_drivers=''
1315 fi
1316
1317 dnl If $with_dri_drivers is yes, drivers will be added through
1318 dnl platform checks. Set DEFINES and LIB_DEPS
1319 if test "x$enable_dri" = xyes; then
1320     # Platform specific settings and drivers to build
1321     case "$host_os" in
1322     linux*)
1323         DEFINES="$DEFINES -DHAVE_ALIAS"
1324         if test "x$enable_dri3" = xyes; then
1325             DEFINES="$DEFINES -DHAVE_DRI3"
1326         fi
1327
1328         if test "x$have_pci_id" != xyes; then
1329             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1330         fi
1331
1332         case "$host_cpu" in
1333         powerpc* | sparc*)
1334             # Build only the drivers for cards that exist on PowerPC/sparc
1335             if test "x$with_dri_drivers" = "xyes"; then
1336                 with_dri_drivers="r200 radeon swrast"
1337             fi
1338             ;;
1339         esac
1340         ;;
1341     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1342         DEFINES="$DEFINES -DHAVE_ALIAS"
1343         ;;
1344     gnu*)
1345         DEFINES="$DEFINES -DHAVE_ALIAS"
1346         ;;
1347     cygwin*)
1348         if test "x$with_dri_drivers" = "xyes"; then
1349             with_dri_drivers="swrast"
1350         fi
1351         ;;
1352     darwin*)
1353         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1354         if test "x$with_dri_drivers" = "xyes"; then
1355             with_dri_drivers="swrast"
1356         fi
1357         ;;
1358     esac
1359
1360     # default drivers
1361     if test "x$with_dri_drivers" = "xyes"; then
1362         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1363     fi
1364
1365     # Check for expat
1366     PKG_CHECK_MODULES([EXPAT], [expat], [],
1367         # expat version 2.0 and earlier do not provide expat.pc
1368         [AC_CHECK_HEADER([expat.h],[],
1369                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1370          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1371                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1372          EXPAT_LIBS="-lexpat"])
1373
1374     DRICOMMON_NEED_LIBDRM=no
1375     # If we are building any DRI driver other than swrast.
1376     if test -n "$with_dri_drivers"; then
1377         if test "x$with_dri_drivers" != xswrast; then
1378             # ... libdrm is required
1379             if test "x$have_libdrm" != xyes; then
1380                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1381             fi
1382             DRICOMMON_NEED_LIBDRM=yes
1383         fi
1384     fi
1385
1386     # If we're building any gallium DRI driver other than swrast
1387     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1388         if test "x$with_gallium_drivers" != xswrast; then
1389             # ... build a libdrm aware dricommon
1390             DRICOMMON_NEED_LIBDRM=yes
1391         fi
1392     fi
1393
1394     # put all the necessary libs together
1395     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1396 fi
1397
1398 AC_SUBST([DRI_LIB_DEPS])
1399
1400 DRI_DIRS=''
1401 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1402 if test -n "$with_dri_drivers"; then
1403     if test "x$enable_opengl" != xyes; then
1404         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1405     fi
1406
1407     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1408     for driver in $dri_drivers; do
1409         DRI_DIRS="$DRI_DIRS $driver"
1410         case "x$driver" in
1411         xi915)
1412             HAVE_I915_DRI=yes;
1413             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1414             ;;
1415         xi965)
1416             HAVE_I965_DRI=yes;
1417             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1418             ;;
1419         xnouveau)
1420             HAVE_NOUVEAU_DRI=yes;
1421             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1422             ;;
1423         xradeon)
1424             HAVE_RADEON_DRI=yes;
1425             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1426             ;;
1427         xr200)
1428             HAVE_R200_DRI=yes;
1429             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1430             ;;
1431         xswrast)
1432             HAVE_SWRAST_DRI=yes;
1433             ;;
1434         *)
1435             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1436             ;;
1437         esac
1438     done
1439     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1440 fi
1441
1442 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1443 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1444                                   "x$enable_osmesa" = xyes -o \
1445                                   -n "$DRI_DIRS")
1446
1447 dnl
1448 dnl OSMesa configuration
1449 dnl
1450
1451 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1452 AC_ARG_WITH([osmesa-bits],
1453     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1454         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1455     [osmesa_bits="$withval"],
1456     [osmesa_bits=8])
1457 if test "x$osmesa_bits" != x8; then
1458     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1459         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1460         osmesa_bits=8
1461     fi
1462 fi
1463 case "x$osmesa_bits" in
1464 x8)
1465     OSMESA_LIB="${OSMESA_LIB}"
1466     ;;
1467 x16|x32)
1468     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1469     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1470     ;;
1471 *)
1472     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1473     ;;
1474 esac
1475
1476 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1477     # only link libraries with osmesa if shared
1478     if test "$enable_static" = no; then
1479         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1480     else
1481         OSMESA_LIB_DEPS=""
1482     fi
1483     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1484 fi
1485
1486 AC_SUBST([OSMESA_LIB_DEPS])
1487 AC_SUBST([OSMESA_PC_REQ])
1488 AC_SUBST([OSMESA_PC_LIB_PRIV])
1489
1490 dnl
1491 dnl gbm configuration
1492 dnl
1493 if test "x$enable_gbm" = xauto; then
1494     case "$with_egl_platforms" in
1495         *drm*)
1496             enable_gbm=yes ;;
1497          *)
1498             enable_gbm=no ;;
1499     esac
1500 fi
1501 if test "x$enable_gbm" = xyes; then
1502     if test "x$need_pci_id$have_pci_id" = xyesno; then
1503         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1504     fi
1505
1506     if test "x$enable_dri" = xyes; then
1507         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1508         if test "x$enable_shared_glapi" = xno; then
1509             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1510         fi
1511     else
1512         # Strictly speaking libgbm does not require --enable-dri, although
1513         # both of its backends do. Thus one can build libgbm without any
1514         # backends if --disable-dri is set.
1515         # To avoid unnecessary complexity of checking if at least one backend
1516         # is available when building, just mandate --enable-dri.
1517         AC_MSG_ERROR([gbm requires --enable-dri])
1518     fi
1519 fi
1520 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1521 if test "x$need_pci_id$have_libudev" = xyesyes; then
1522     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1523 else
1524     GBM_PC_REQ_PRIV=""
1525 fi
1526 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1527 AC_SUBST([GBM_PC_REQ_PRIV])
1528 AC_SUBST([GBM_PC_LIB_PRIV])
1529
1530 dnl
1531 dnl EGL configuration
1532 dnl
1533 EGL_CLIENT_APIS=""
1534
1535 if test "x$enable_egl" = xyes; then
1536     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1537
1538     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1539
1540     if test "$enable_static" != yes; then
1541         if test "x$enable_dri" = xyes; then
1542             HAVE_EGL_DRIVER_DRI2=1
1543         fi
1544
1545     fi
1546 fi
1547 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1548 AC_SUBST([EGL_LIB_DEPS])
1549
1550 dnl
1551 dnl XA configuration
1552 dnl
1553 if test "x$enable_xa" = xyes; then
1554     if test "x$with_gallium_drivers" = xswrast; then
1555        AC_MSG_ERROR([
1556           Building xa requires at least one non swrast gallium driver.
1557           If you are looking to use libxatracker.so with the VMware driver,
1558           make sure to include svga in the gallium drivers list, apart from
1559           enabling XA.
1560           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1561     fi
1562     enable_gallium_loader=$enable_shared_pipe_drivers
1563 fi
1564 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1565
1566 dnl
1567 dnl Gallium G3DVL configuration
1568 dnl
1569 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1570     if test "x$enable_xvmc" = xauto; then
1571         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1572     fi
1573
1574     if test "x$enable_vdpau" = xauto; then
1575         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1576     fi
1577
1578     if test "x$enable_omx" = xauto; then
1579         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1580     fi
1581
1582     if test "x$enable_va" = xauto; then
1583         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1584     fi
1585 fi
1586
1587 if test "x$enable_dri" = xyes -o \
1588         "x$enable_xvmc" = xyes -o \
1589         "x$enable_vdpau" = xyes -o \
1590         "x$enable_omx" = xyes -o \
1591         "x$enable_va" = xyes; then
1592     need_gallium_vl=yes
1593 fi
1594 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1595
1596 if test "x$enable_xvmc" = xyes -o \
1597         "x$enable_vdpau" = xyes -o \
1598         "x$enable_omx" = xyes -o \
1599         "x$enable_va" = xyes; then
1600     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1601     need_gallium_vl_winsys=yes
1602 fi
1603 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1604
1605 if test "x$enable_xvmc" = xyes; then
1606     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1607     enable_gallium_loader=$enable_shared_pipe_drivers
1608 fi
1609 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1610
1611 if test "x$enable_vdpau" = xyes; then
1612     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1613     enable_gallium_loader=$enable_shared_pipe_drivers
1614 fi
1615 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1616
1617 if test "x$enable_omx" = xyes; then
1618     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1619     enable_gallium_loader=$enable_shared_pipe_drivers
1620 fi
1621 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1622
1623 if test "x$enable_va" = xyes; then
1624     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1625     enable_gallium_loader=$enable_shared_pipe_drivers
1626 fi
1627 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1628
1629 dnl
1630 dnl Nine Direct3D9 configuration
1631 dnl
1632 if test "x$enable_nine" = xyes; then
1633     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1634         AC_MSG_ERROR([nine requires the gallium swrast driver])
1635     fi
1636     if test "x$with_gallium_drivers" == xswrast; then
1637         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1638     fi
1639     if test "x$enable_dri3" = xno; then
1640         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1641     fi
1642
1643     enable_gallium_loader=$enable_shared_pipe_drivers
1644 fi
1645 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1646
1647 dnl
1648 dnl OpenCL configuration
1649 dnl
1650
1651 AC_ARG_WITH([libclc-path],
1652    [AS_HELP_STRING([--with-libclc-path],
1653          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1654    [LIBCLC_PATH="$withval"],
1655    [LIBCLC_PATH=''])
1656
1657 if test -n "$LIBCLC_PATH"; then
1658    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1659                   Please review the updated build instructions for clover:
1660                   http://dri.freedesktop.org/wiki/GalliumCompute])
1661 fi
1662
1663
1664 AC_ARG_WITH([clang-libdir],
1665    [AS_HELP_STRING([--with-clang-libdir],
1666          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1667    [CLANG_LIBDIR="$withval"],
1668    [CLANG_LIBDIR=''])
1669
1670 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1671 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1672
1673 if test "x$enable_opencl" = xyes; then
1674     if test -z "$with_gallium_drivers"; then
1675         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1676     fi
1677
1678     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1679         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1680     fi
1681
1682     if test "x$have_libclc" = xno; then
1683         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1684                     Make sure the directory containing libclc.pc is specified in your
1685                     PKG_CONFIG_PATH environment variable.
1686                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1687     else
1688         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1689         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1690         AC_SUBST([LIBCLC_INCLUDEDIR])
1691         AC_SUBST([LIBCLC_LIBEXECDIR])
1692     fi
1693
1694     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1695     enable_gallium_loader=yes
1696
1697     if test "x$enable_opencl_icd" = xyes; then
1698         OPENCL_LIBNAME="MesaOpenCL"
1699     else
1700         OPENCL_LIBNAME="OpenCL"
1701     fi
1702
1703     if test "x$have_libelf" != xyes; then
1704        AC_MSG_ERROR([Clover requires libelf])
1705     fi
1706 fi
1707 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1708 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1709 AC_SUBST([OPENCL_LIBNAME])
1710
1711 dnl
1712 dnl Gallium configuration
1713 dnl
1714 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1715
1716 AC_SUBST([LLVM_BINDIR])
1717 AC_SUBST([LLVM_CFLAGS])
1718 AC_SUBST([LLVM_CPPFLAGS])
1719 AC_SUBST([LLVM_CXXFLAGS])
1720 AC_SUBST([LLVM_LIBDIR])
1721 AC_SUBST([LLVM_LIBS])
1722 AC_SUBST([LLVM_LDFLAGS])
1723 AC_SUBST([LLVM_INCLUDEDIR])
1724 AC_SUBST([LLVM_VERSION])
1725 AC_SUBST([CLANG_RESOURCE_DIR])
1726
1727 case "x$enable_opengl$enable_gles1$enable_gles2" in
1728 x*yes*)
1729     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1730     ;;
1731 esac
1732
1733 AC_SUBST([VG_LIB_DEPS])
1734 AC_SUBST([EGL_CLIENT_APIS])
1735
1736 dnl
1737 dnl EGL Platforms configuration
1738 dnl
1739 AC_ARG_WITH([egl-platforms],
1740     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1741         [comma delimited native platforms libEGL supports, e.g.
1742         "x11,drm" @<:@default=auto@:>@])],
1743     [with_egl_platforms="$withval"],
1744     [if test "x$enable_egl" = xyes; then
1745         with_egl_platforms="x11"
1746     else
1747         with_egl_platforms=""
1748     fi])
1749
1750 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1751     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1752 fi
1753
1754 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1755         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1756         WAYLAND_SCANNER='')
1757 if test "x$WAYLAND_SCANNER" = x; then
1758     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1759 fi
1760
1761 # Do per-EGL platform setups and checks
1762 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1763 for plat in $egl_platforms; do
1764         case "$plat" in
1765         wayland)
1766                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1767
1768                 if test "x$WAYLAND_SCANNER" = x; then
1769                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1770                 fi
1771                 ;;
1772
1773         x11)
1774                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1775                 ;;
1776
1777         drm)
1778                 test "x$enable_gbm" = "xno" &&
1779                         AC_MSG_ERROR([EGL platform drm needs gbm])
1780                 test "x$have_libdrm" != xyes &&
1781                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1782                 ;;
1783
1784         android|gdi|null)
1785                 ;;
1786
1787         *)
1788                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1789                 ;;
1790         esac
1791
1792         case "$plat$need_pci_id$have_pci_id" in
1793                 waylandyesno|drmyesno)
1794                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1795         esac
1796 done
1797
1798 # libEGL wants to default to the first platform specified in
1799 # ./configure.  parse that here.
1800 if test "x$egl_platforms" != "x"; then
1801     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1802     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1803 else
1804     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1805 fi
1806
1807 if echo "$egl_platforms" | grep -q 'x11'; then
1808     NEED_WINSYS_XLIB=yes
1809 fi
1810 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1811 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1812 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1813 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1814
1815 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1816
1817 AC_SUBST([EGL_NATIVE_PLATFORM])
1818 AC_SUBST([EGL_CFLAGS])
1819
1820 # If we don't have the X11 platform, set this define so we don't try to include
1821 # the X11 headers.
1822 if ! echo "$egl_platforms" | grep -q 'x11'; then
1823     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1824     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1825 fi
1826
1827 AC_ARG_WITH([max-width],
1828     [AS_HELP_STRING([--with-max-width=N],
1829                     [Maximum framebuffer width (4096)])],
1830     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1831      AS_IF([test "${withval}" -gt "4096"],
1832            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1833 )
1834 AC_ARG_WITH([max-height],
1835     [AS_HELP_STRING([--with-max-height=N],
1836                     [Maximum framebuffer height (4096)])],
1837     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1838      AS_IF([test "${withval}" -gt "4096"],
1839            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1840 )
1841
1842 dnl
1843 dnl Gallium LLVM
1844 dnl
1845 AC_ARG_ENABLE([gallium-llvm],
1846     [AS_HELP_STRING([--enable-gallium-llvm],
1847         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1848     [enable_gallium_llvm="$enableval"],
1849     [enable_gallium_llvm=auto])
1850
1851 AC_ARG_ENABLE([llvm-shared-libs],
1852     [AS_HELP_STRING([--enable-llvm-shared-libs],
1853         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1854     [enable_llvm_shared_libs="$enableval"],
1855     [enable_llvm_shared_libs=yes])
1856
1857 AC_ARG_WITH([llvm-prefix],
1858     [AS_HELP_STRING([--with-llvm-prefix],
1859         [Prefix for LLVM installations in non-standard locations])],
1860     [llvm_prefix="$withval"],
1861     [llvm_prefix=''])
1862
1863
1864 # Call this inside ` ` to get the return value.
1865 # $1 is the llvm-config command with arguments.
1866 strip_unwanted_llvm_flags() {
1867     # Use \> (marks the end of the word)
1868     echo `$1` | sed \
1869         -e 's/-DNDEBUG\>//g' \
1870         -e 's/-D_GNU_SOURCE\>//g' \
1871         -e 's/-pedantic\>//g' \
1872         -e 's/-Wcovered-switch-default\>//g' \
1873         -e 's/-O.\>//g' \
1874         -e 's/-g\>//g' \
1875         -e 's/-Wall\>//g' \
1876         -e 's/-Wcast-qual\>//g' \
1877         -e 's/-Woverloaded-virtual\>//g' \
1878         -e 's/-fcolor-diagnostics\>//g' \
1879         -e 's/-fdata-sections\>//g' \
1880         -e 's/-ffunction-sections\>//g' \
1881         -e 's/-fno-exceptions\>//g' \
1882         -e 's/-fomit-frame-pointer\>//g' \
1883         -e 's/-fvisibility-inlines-hidden\>//g' \
1884         -e 's/-fPIC\>//g' \
1885         -e 's/-fstack-protector-strong\>//g'
1886 }
1887
1888
1889 if test -z "$with_gallium_drivers"; then
1890     enable_gallium_llvm=no
1891 fi
1892 if test "x$enable_gallium_llvm" = xauto; then
1893     case "$host_cpu" in
1894     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1895     esac
1896 fi
1897 if test "x$enable_gallium_llvm" = xyes; then
1898     if test -n "$llvm_prefix"; then
1899         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1900     else
1901         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1902     fi
1903
1904     if test "x$LLVM_CONFIG" != xno; then
1905         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1906         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1907         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1908         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1909         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1910         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1911         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1912         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1913
1914         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1915             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1916         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1917             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1918
1919         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1920         if test -z "$LLVM_VERSION_PATCH"; then
1921             LLVM_VERSION_PATCH=0
1922         fi
1923
1924         if test -n "${LLVM_VERSION_MAJOR}"; then
1925             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1926         else
1927             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1928         fi
1929
1930         LLVM_REQUIRED_VERSION_MAJOR="3"
1931         LLVM_REQUIRED_VERSION_MINOR="3"
1932         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1933             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1934         fi
1935
1936         LLVM_COMPONENTS="engine bitwriter"
1937         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1938             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1939         fi
1940
1941         if test "x$enable_opencl" = xyes; then
1942             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1943             # LLVM 3.3 >= 177971 requires IRReader
1944             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1945                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1946             fi
1947             # LLVM 3.4 requires Option
1948             if $LLVM_CONFIG --components | grep -qw 'option'; then
1949                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1950             fi
1951             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1952             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1953                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1954             fi
1955             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1956                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1957             fi
1958         fi
1959         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1960         MESA_LLVM=1
1961
1962         dnl Check for Clang internal headers
1963         if test "x$enable_opencl" = xyes; then
1964             if test -z "$CLANG_LIBDIR"; then
1965                 CLANG_LIBDIR=${LLVM_LIBDIR}
1966             fi
1967             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1968             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1969                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1970         fi
1971     else
1972         MESA_LLVM=0
1973         LLVM_VERSION_INT=0
1974     fi
1975 else
1976     MESA_LLVM=0
1977     LLVM_VERSION_INT=0
1978
1979     if test "x$enable_opencl" = xyes; then
1980         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1981     fi
1982 fi
1983
1984 dnl Directory for XVMC libs
1985 AC_ARG_WITH([xvmc-libdir],
1986     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1987         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1988     [XVMC_LIB_INSTALL_DIR="$withval"],
1989     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1990 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1991
1992 dnl
1993 dnl Gallium Tests
1994 dnl
1995 if test "x$enable_gallium_tests" = xyes; then
1996     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1997     enable_gallium_loader=yes
1998 fi
1999 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2000
2001 dnl Directory for VDPAU libs
2002 AC_ARG_WITH([vdpau-libdir],
2003     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2004         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2005     [VDPAU_LIB_INSTALL_DIR="$withval"],
2006     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2007 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2008
2009 dnl Directory for OMX libs
2010
2011 AC_ARG_WITH([omx-libdir],
2012     [AS_HELP_STRING([--with-omx-libdir=DIR],
2013         [directory for the OMX libraries])],
2014     [OMX_LIB_INSTALL_DIR="$withval"],
2015     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2016 AC_SUBST([OMX_LIB_INSTALL_DIR])
2017
2018 dnl Directory for VA libs
2019
2020 AC_ARG_WITH([va-libdir],
2021     [AS_HELP_STRING([--with-va-libdir=DIR],
2022         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2023     [VA_LIB_INSTALL_DIR="$withval"],
2024     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2025 AC_SUBST([VA_LIB_INSTALL_DIR])
2026
2027 AC_ARG_WITH([d3d-libdir],
2028     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2029         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2030     [D3D_DRIVER_INSTALL_DIR="$withval"],
2031     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2032 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2033
2034 dnl
2035 dnl Gallium helper functions
2036 dnl
2037 gallium_require_drm() {
2038     if test "x$have_libdrm" != xyes; then
2039        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2040     fi
2041 }
2042
2043 gallium_require_llvm() {
2044     if test "x$MESA_LLVM" = x0; then
2045         case "$host" in *gnux32) return;; esac
2046         case "$host_cpu" in
2047         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2048         esac
2049     fi
2050 }
2051
2052 gallium_require_drm_loader() {
2053     if test "x$enable_gallium_loader" = xyes; then
2054         if test "x$need_pci_id$have_pci_id" = xyesno; then
2055             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2056         fi
2057         enable_gallium_drm_loader=yes
2058     fi
2059     if test "x$enable_va" = xyes && test "x$7" != x; then
2060          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2061     fi
2062 }
2063
2064 require_egl_drm() {
2065     case "$with_egl_platforms" in
2066         *drm*)
2067             ;;
2068          *)
2069             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2070             ;;
2071     esac
2072     if test "x$enable_gbm" != xyes; then
2073             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2074     fi
2075 }
2076
2077 radeon_llvm_check() {
2078     if test "x$enable_gallium_llvm" != "xyes"; then
2079         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2080     fi
2081     LLVM_REQUIRED_VERSION_MAJOR="3"
2082     LLVM_REQUIRED_VERSION_MINOR="4"
2083     LLVM_REQUIRED_VERSION_PATCH="2"
2084     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2085         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2086     fi
2087     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2088         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2089                       sources with the --enable-experimental-targets=R600
2090                       configure flag])
2091     fi
2092     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2093     NEED_RADEON_LLVM=yes
2094     if test "x$have_libelf" != xyes; then
2095        AC_MSG_ERROR([$1 requires libelf when using llvm])
2096     fi
2097 }
2098
2099 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2100 if test -n "$with_gallium_drivers"; then
2101     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2102     for driver in $gallium_drivers; do
2103         case "x$driver" in
2104         xsvga)
2105             HAVE_GALLIUM_SVGA=yes
2106             gallium_require_drm "svga"
2107             gallium_require_drm_loader
2108             ;;
2109         xi915)
2110             HAVE_GALLIUM_I915=yes
2111             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2112             gallium_require_drm "Gallium i915"
2113             gallium_require_drm_loader
2114             ;;
2115         xilo)
2116             HAVE_GALLIUM_ILO=yes
2117             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2118             gallium_require_drm "Gallium i965/ilo"
2119             gallium_require_drm_loader
2120             ;;
2121         xr300)
2122             HAVE_GALLIUM_R300=yes
2123             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2124             gallium_require_drm "Gallium R300"
2125             gallium_require_drm_loader
2126             gallium_require_llvm "Gallium R300"
2127             ;;
2128         xr600)
2129             HAVE_GALLIUM_R600=yes
2130             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2131             gallium_require_drm "Gallium R600"
2132             gallium_require_drm_loader
2133             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2134                 radeon_llvm_check "r600g"
2135                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2136             fi
2137             if test "x$enable_r600_llvm" = xyes; then
2138                 USE_R600_LLVM_COMPILER=yes;
2139             fi
2140             if test "x$enable_opencl" = xyes; then
2141                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2142             fi
2143             ;;
2144         xradeonsi)
2145             HAVE_GALLIUM_RADEONSI=yes
2146             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2147             gallium_require_drm "radeonsi"
2148             gallium_require_drm_loader
2149             radeon_llvm_check "radeonsi"
2150             require_egl_drm "radeonsi"
2151             ;;
2152         xnouveau)
2153             HAVE_GALLIUM_NOUVEAU=yes
2154             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2155             gallium_require_drm "nouveau"
2156             gallium_require_drm_loader
2157             ;;
2158         xfreedreno)
2159             HAVE_GALLIUM_FREEDRENO=yes
2160             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2161             gallium_require_drm "freedreno"
2162             gallium_require_drm_loader
2163             ;;
2164         xswrast)
2165             HAVE_GALLIUM_SOFTPIPE=yes
2166             if test "x$MESA_LLVM" = x1; then
2167                 HAVE_GALLIUM_LLVMPIPE=yes
2168             fi
2169             ;;
2170         xvc4)
2171             HAVE_GALLIUM_VC4=yes
2172             gallium_require_drm "vc4"
2173             gallium_require_drm_loader
2174
2175             case "$host_cpu" in
2176                 i?86 | x86_64 | amd64)
2177                 USE_VC4_SIMULATOR=yes
2178                 ;;
2179             esac
2180             ;;
2181         *)
2182             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2183             ;;
2184         esac
2185     done
2186 fi
2187
2188 dnl Set LLVM_LIBS - This is done after the driver configuration so
2189 dnl that drivers can add additional components to LLVM_COMPONENTS.
2190 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2191 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2192 dnl this was causing the same libraries to be appear multiple times
2193 dnl in LLVM_LIBS.
2194
2195 if test "x$MESA_LLVM" != x0; then
2196
2197     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2198
2199     if test "x$enable_llvm_shared_libs" = xyes; then
2200         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2201         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2202         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2203
2204         if test "x$llvm_have_one_so" = xyes; then
2205             dnl LLVM was built using auto*, so there is only one shared object.
2206             LLVM_LIBS="-l$LLVM_SO_NAME"
2207         else
2208             dnl If LLVM was built with CMake, there will be one shared object per
2209             dnl component.
2210             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2211                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2212         Please make sure you have built llvm with the --enable-shared option
2213         and that your llvm libraries are installed in $LLVM_LIBDIR
2214         If you have installed your llvm libraries to a different directory you
2215         can use the --with-llvm-prefix= configure flag to specify this directory.
2216         NOTE: Mesa is attempting to use llvm shared libraries by default.
2217         If you do not want to build with llvm shared libraries and instead want to
2218         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2219         invocation and rebuild.])])
2220
2221            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2222            dnl install uses a shared object for each component and we have
2223            dnl already added all of these objects to LLVM_LIBS.
2224         fi
2225     else
2226         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2227         dnl We need to link to llvm system libs when using static libs
2228         dnl However, only llvm 3.5+ provides --system-libs
2229         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2230             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2231         fi
2232     fi
2233 fi
2234
2235 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2236 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2237 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2238 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2239 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2240 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2241 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2242                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2243 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2244 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2245 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2246 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2247 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2248
2249 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2250
2251 # NOTE: anything using xcb or other client side libs ends up in separate
2252 #       _CLIENT variables.  The pipe loader is built in two variants,
2253 #       one that is standalone and does not link any x client libs (for
2254 #       use by XA tracker in particular, but could be used in any case
2255 #       where communication with xserver is not desired).
2256 if test "x$enable_gallium_loader" = xyes; then
2257     if test "x$NEED_WINSYS_XLIB" = xyes; then
2258         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2259     fi
2260
2261     if test "x$enable_dri" = xyes; then
2262         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2263     fi
2264
2265     if test "x$enable_gallium_drm_loader" = xyes; then
2266         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2267         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2268                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2269         if test "x$pipe_loader_have_xcb" = xyes; then
2270             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2271             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2272         fi
2273     fi
2274
2275     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2276     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2277
2278     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2279     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2280     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2281     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2282 fi
2283
2284 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2285 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2286 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2287 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2288 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2289 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2290
2291 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2292                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2293                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2294 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2295 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2296 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2297 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2298 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2299 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2300 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2301 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2302 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2303     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2304 fi
2305
2306 AC_SUBST([ELF_LIB])
2307
2308 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2309 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2310 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2311 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2312 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2313
2314 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2315 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2316 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2317
2318 AC_SUBST([NINE_MAJOR], 1)
2319 AC_SUBST([NINE_MINOR], 0)
2320 AC_SUBST([NINE_TINY], 0)
2321 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2322
2323 AC_SUBST([VDPAU_MAJOR], 1)
2324 AC_SUBST([VDPAU_MINOR], 0)
2325
2326 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2327 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2328 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2329 AC_SUBST([VA_MINOR], $VA_MINOR)
2330
2331 AC_SUBST([XVMC_MAJOR], 1)
2332 AC_SUBST([XVMC_MINOR], 0)
2333
2334 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2335 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2336 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2337 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2338
2339 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2340 AC_SUBST([XA_MINOR], $XA_MINOR)
2341 AC_SUBST([XA_TINY], $XA_TINY)
2342 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2343
2344 dnl Restore LDFLAGS and CPPFLAGS
2345 LDFLAGS="$_SAVE_LDFLAGS"
2346 CPPFLAGS="$_SAVE_CPPFLAGS"
2347
2348 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2349 if test "x$acv_mesa_CLANG" = xyes; then
2350     CFLAGS="$CFLAGS -Qunused-arguments"
2351     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2352 fi
2353
2354 dnl Add user CFLAGS and CXXFLAGS
2355 CFLAGS="$CFLAGS $USER_CFLAGS"
2356 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2357
2358 dnl Substitute the config
2359 AC_CONFIG_FILES([Makefile
2360                 src/Makefile
2361                 src/egl/drivers/dri2/Makefile
2362                 src/egl/main/Makefile
2363                 src/egl/main/egl.pc
2364                 src/egl/wayland/wayland-drm/Makefile
2365                 src/egl/wayland/wayland-egl/Makefile
2366                 src/egl/wayland/wayland-egl/wayland-egl.pc
2367                 src/gallium/Makefile
2368                 src/gallium/auxiliary/Makefile
2369                 src/gallium/auxiliary/pipe-loader/Makefile
2370                 src/gallium/drivers/freedreno/Makefile
2371                 src/gallium/drivers/i915/Makefile
2372                 src/gallium/drivers/ilo/Makefile
2373                 src/gallium/drivers/llvmpipe/Makefile
2374                 src/gallium/drivers/noop/Makefile
2375                 src/gallium/drivers/nouveau/Makefile
2376                 src/gallium/drivers/r300/Makefile
2377                 src/gallium/drivers/r600/Makefile
2378                 src/gallium/drivers/radeon/Makefile
2379                 src/gallium/drivers/radeonsi/Makefile
2380                 src/gallium/drivers/rbug/Makefile
2381                 src/gallium/drivers/softpipe/Makefile
2382                 src/gallium/drivers/svga/Makefile
2383                 src/gallium/drivers/trace/Makefile
2384                 src/gallium/drivers/vc4/Makefile
2385                 src/gallium/drivers/vc4/kernel/Makefile
2386                 src/gallium/state_trackers/clover/Makefile
2387                 src/gallium/state_trackers/dri/Makefile
2388                 src/gallium/state_trackers/glx/xlib/Makefile
2389                 src/gallium/state_trackers/nine/Makefile
2390                 src/gallium/state_trackers/omx/Makefile
2391                 src/gallium/state_trackers/osmesa/Makefile
2392                 src/gallium/state_trackers/va/Makefile
2393                 src/gallium/state_trackers/vdpau/Makefile
2394                 src/gallium/state_trackers/xa/Makefile
2395                 src/gallium/state_trackers/xvmc/Makefile
2396                 src/gallium/targets/d3dadapter9/Makefile
2397                 src/gallium/targets/d3dadapter9/d3d.pc
2398                 src/gallium/targets/dri/Makefile
2399                 src/gallium/targets/libgl-xlib/Makefile
2400                 src/gallium/targets/omx/Makefile
2401                 src/gallium/targets/opencl/Makefile
2402                 src/gallium/targets/osmesa/Makefile
2403                 src/gallium/targets/osmesa/osmesa.pc
2404                 src/gallium/targets/pipe-loader/Makefile
2405                 src/gallium/targets/va/Makefile
2406                 src/gallium/targets/vdpau/Makefile
2407                 src/gallium/targets/xa/Makefile
2408                 src/gallium/targets/xa/xatracker.pc
2409                 src/gallium/targets/xvmc/Makefile
2410                 src/gallium/tests/trivial/Makefile
2411                 src/gallium/tests/unit/Makefile
2412                 src/gallium/winsys/freedreno/drm/Makefile
2413                 src/gallium/winsys/i915/drm/Makefile
2414                 src/gallium/winsys/intel/drm/Makefile
2415                 src/gallium/winsys/nouveau/drm/Makefile
2416                 src/gallium/winsys/radeon/drm/Makefile
2417                 src/gallium/winsys/svga/drm/Makefile
2418                 src/gallium/winsys/sw/dri/Makefile
2419                 src/gallium/winsys/sw/kms-dri/Makefile
2420                 src/gallium/winsys/sw/null/Makefile
2421                 src/gallium/winsys/sw/wrapper/Makefile
2422                 src/gallium/winsys/sw/xlib/Makefile
2423                 src/gallium/winsys/vc4/drm/Makefile
2424                 src/gbm/Makefile
2425                 src/gbm/main/gbm.pc
2426                 src/glsl/Makefile
2427                 src/glx/Makefile
2428                 src/glx/apple/Makefile
2429                 src/glx/tests/Makefile
2430                 src/gtest/Makefile
2431                 src/loader/Makefile
2432                 src/mapi/Makefile
2433                 src/mapi/es1api/glesv1_cm.pc
2434                 src/mapi/es2api/glesv2.pc
2435                 src/mapi/glapi/gen/Makefile
2436                 src/mesa/Makefile
2437                 src/mesa/gl.pc
2438                 src/mesa/drivers/dri/dri.pc
2439                 src/mesa/drivers/dri/common/Makefile
2440                 src/mesa/drivers/dri/common/xmlpool/Makefile
2441                 src/mesa/drivers/dri/i915/Makefile
2442                 src/mesa/drivers/dri/i965/Makefile
2443                 src/mesa/drivers/dri/Makefile
2444                 src/mesa/drivers/dri/nouveau/Makefile
2445                 src/mesa/drivers/dri/r200/Makefile
2446                 src/mesa/drivers/dri/radeon/Makefile
2447                 src/mesa/drivers/dri/swrast/Makefile
2448                 src/mesa/drivers/osmesa/Makefile
2449                 src/mesa/drivers/osmesa/osmesa.pc
2450                 src/mesa/drivers/x11/Makefile
2451                 src/mesa/main/tests/Makefile
2452                 src/util/Makefile
2453                 src/util/tests/hash_table/Makefile])
2454
2455 AC_OUTPUT
2456
2457 dnl
2458 dnl Output some configuration info for the user
2459 dnl
2460 echo ""
2461 echo "        prefix:          $prefix"
2462 echo "        exec_prefix:     $exec_prefix"
2463 echo "        libdir:          $libdir"
2464 echo "        includedir:      $includedir"
2465
2466 dnl API info
2467 echo ""
2468 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2469
2470 dnl Driver info
2471 echo ""
2472 case "x$enable_osmesa$enable_gallium_osmesa" in
2473 xnoyes)
2474         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2475         ;;
2476 xyesno)
2477         echo "        OSMesa:          lib$OSMESA_LIB"
2478         ;;
2479 xnono)
2480         echo "        OSMesa:          no"
2481         ;;
2482 esac
2483
2484 echo ""
2485 if test "x$enable_dri" != xno; then
2486         echo "        DRI platform:    $dri_platform"
2487         if test -z "$DRI_DIRS"; then
2488             echo "        DRI drivers:     no"
2489         else
2490             echo "        DRI drivers:     $DRI_DIRS"
2491         fi
2492         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2493 fi
2494
2495 case "x$enable_glx$enable_xlib_glx" in
2496 xyesyes)
2497     echo "        GLX:             Xlib-based"
2498     ;;
2499 xyesno)
2500     echo "        GLX:             DRI-based"
2501     ;;
2502 *)
2503     echo "        GLX:             $enable_glx"
2504     ;;
2505 esac
2506
2507 dnl EGL
2508 echo ""
2509 echo "        EGL:             $enable_egl"
2510 if test "$enable_egl" = yes; then
2511     echo "        EGL platforms:   $egl_platforms"
2512
2513     egl_drivers=""
2514     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2515         egl_drivers="$egl_drivers builtin:egl_dri2"
2516     fi
2517
2518     echo "        EGL drivers:    $egl_drivers"
2519 fi
2520
2521 echo ""
2522 if test "x$MESA_LLVM" = x1; then
2523     echo "        llvm:            yes"
2524     echo "        llvm-config:     $LLVM_CONFIG"
2525     echo "        llvm-version:    $LLVM_VERSION"
2526 else
2527     echo "        llvm:            no"
2528 fi
2529
2530 echo ""
2531 if test -n "$with_gallium_drivers"; then
2532     echo "        Gallium:         yes"
2533 else
2534     echo "        Gallium:         no"
2535 fi
2536
2537 dnl Shader cache
2538 echo ""
2539 echo "        Shader cache:    $enable_shader_cache"
2540 if test "x$enable_shader_cache" = "xyes"; then
2541     echo "        With SHA1 from:  $with_sha1"
2542 fi
2543
2544 dnl Libraries
2545 echo ""
2546 echo "        Shared libs:     $enable_shared"
2547 echo "        Static libs:     $enable_static"
2548 echo "        Shared-glapi:    $enable_shared_glapi"
2549
2550 dnl Compiler options
2551 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2552 cflags=`echo $CFLAGS | \
2553     $SED 's/^ *//;s/  */ /;s/ *$//'`
2554 cxxflags=`echo $CXXFLAGS | \
2555     $SED 's/^ *//;s/  */ /;s/ *$//'`
2556 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2557 echo ""
2558 echo "        CFLAGS:          $cflags"
2559 echo "        CXXFLAGS:        $cxxflags"
2560 echo "        Macros:          $defines"
2561 echo ""
2562 if test "x$MESA_LLVM" = x1; then
2563     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2564     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2565     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2566     echo ""
2567 fi
2568 echo "        PYTHON2:         $PYTHON2"
2569
2570 echo ""
2571 echo "        Run '${MAKE-make}' to build Mesa"
2572 echo ""