configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports -Bsymbolic
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 323 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         BSYMBOLIC="-Wl,-Bsymbolic";],
 328     [AC_MSG_RESULT([no])
 329         BSYMBOLIC="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([BSYMBOLIC])
 333
 334 dnl
 335 dnl Check if linker supports garbage collection
 336 dnl
 337 save_LDFLAGS=$LDFLAGS
 338 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 339 AC_MSG_CHECKING([whether ld supports --gc-sections])
 340 AC_LINK_IFELSE(
 341     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 342     [AC_MSG_RESULT([yes])
 343         GC_SECTIONS="-Wl,--gc-sections";],
 344     [AC_MSG_RESULT([no])
 345         GC_SECTIONS="";])
 346 LDFLAGS=$save_LDFLAGS
 347
 348 AC_SUBST([GC_SECTIONS])
 349
 350 dnl
 351 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 352 dnl so when these flags are passed to ld via libtool the checks will fail
 353 dnl
 354 case "$host_os" in
 355 openbsd* | darwin* )
 356     LD_NO_UNDEFINED="" ;;
 357 *)
 358     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 359 esac
 360
 361 AC_SUBST([LD_NO_UNDEFINED])
 362
 363 dnl
 364 dnl Check if linker supports version scripts
 365 dnl
 366 AC_MSG_CHECKING([if the linker supports version-scripts])
 367 save_LDFLAGS=$LDFLAGS
 368 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 369 cat > conftest.map <<EOF
 370 VERSION_1 {
 371      global:
 372          main;
 373
 374      local:
 375          *;
 376 };
 377 EOF
 378 AC_LINK_IFELSE(
 379     [AC_LANG_SOURCE([int main() { return 0;}])],
 380     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 381     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 382 LDFLAGS=$save_LDFLAGS
 383 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 384
 385 dnl
 386 dnl compatibility symlinks
 387 dnl
 388 case "$host_os" in
 389 linux* )
 390     HAVE_COMPAT_SYMLINKS=yes ;;
 391 * )
 392     HAVE_COMPAT_SYMLINKS=no ;;
 393 esac
 394
 395 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 396
 397 dnl
 398 dnl library names
 399 dnl
 400 case "$host_os" in
 401 darwin* )
 402     LIB_EXT='dylib' ;;
 403 cygwin* )
 404     LIB_EXT='dll' ;;
 405 aix* )
 406     LIB_EXT='a' ;;
 407 * )
 408     LIB_EXT='so' ;;
 409 esac
 410
 411 AC_SUBST([LIB_EXT])
 412
 413 AC_ARG_WITH([gl-lib-name],
 414   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 415     [specify GL library name @<:@default=GL@:>@])],
 416   [GL_LIB=$withval],
 417   [GL_LIB=GL])
 418 AC_ARG_WITH([osmesa-lib-name],
 419   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 420     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 421   [OSMESA_LIB=$withval],
 422   [OSMESA_LIB=OSMesa])
 423 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 424 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 425
 426 dnl
 427 dnl Mangled Mesa support
 428 dnl
 429 AC_ARG_ENABLE([mangling],
 430   [AS_HELP_STRING([--enable-mangling],
 431     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 432   [enable_mangling="${enableval}"],
 433   [enable_mangling=no]
 434 )
 435 if test "x${enable_mangling}" = "xyes" ; then
 436   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 437   GL_LIB="Mangled${GL_LIB}"
 438   OSMESA_LIB="Mangled${OSMESA_LIB}"
 439 fi
 440 AC_SUBST([GL_LIB])
 441 AC_SUBST([OSMESA_LIB])
 442
 443 dnl
 444 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 445 dnl
 446 AC_ARG_ENABLE([texture-float],
 447     [AS_HELP_STRING([--enable-texture-float],
 448         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 449     [enable_texture_float="$enableval"],
 450     [enable_texture_float=no]
 451 )
 452 if test "x$enable_texture_float" = xyes; then
 453     AC_MSG_WARN([Floating-point textures enabled.])
 454     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 455     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 456 fi
 457
 458 dnl
 459 dnl Arch/platform-specific settings
 460 dnl
 461 AC_ARG_ENABLE([asm],
 462     [AS_HELP_STRING([--disable-asm],
 463         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 464     [enable_asm="$enableval"],
 465     [enable_asm=yes]
 466 )
 467 asm_arch=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64 | amd64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         gnu*)
 488             asm_arch=x86
 489             ;;
 490         esac
 491         ;;
 492     x86_64|amd64)
 493         case "$host_os" in
 494         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 495             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 496             ;;
 497         esac
 498         ;;
 499     sparc*)
 500         case "$host_os" in
 501         linux*)
 502             asm_arch=sparc
 503             ;;
 504         esac
 505         ;;
 506     esac
 507
 508     case "$asm_arch" in
 509     x86)
 510         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 511         AC_MSG_RESULT([yes, x86])
 512         ;;
 513     x86_64|amd64)
 514         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 515         AC_MSG_RESULT([yes, x86_64])
 516         ;;
 517     sparc)
 518         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 530     [AC_CHECK_LIB([dl], [dlopen],
 531        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 532 AC_SUBST([DLOPEN_LIBS])
 533
 534 dnl Check if that library also has dladdr
 535 save_LDFLAGS="$LDFLAGS"
 536 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 537 AC_CHECK_FUNCS([dladdr])
 538 LDFLAGS="$save_LDFLAGS"
 539
 540 case "$host_os" in
 541 darwin*|mingw*)
 542     ;;
 543 *)
 544     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 545                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 546                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 547     AC_SUBST([CLOCK_LIB])
 548     ;;
 549 esac
 550
 551 dnl See if posix_memalign is available
 552 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 553
 554 dnl Check for pthreads
 555 AX_PTHREAD
 556 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 557 dnl to -pthread, which causes problems if we need -lpthread to appear in
 558 dnl pkgconfig files.
 559 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 560
 561 dnl SELinux awareness.
 562 AC_ARG_ENABLE([selinux],
 563     [AS_HELP_STRING([--enable-selinux],
 564         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 565     [MESA_SELINUX="$enableval"],
 566     [MESA_SELINUX=no])
 567 if test "x$enable_selinux" = "xyes"; then
 568     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 569         [AC_CHECK_HEADER([selinux/selinux.h],[],
 570                          [AC_MSG_ERROR([SELinux headers not found])])
 571          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 572                       [AC_MSG_ERROR([SELinux library not found])])
 573          SELINUX_LIBS="-lselinux"])
 574     DEFINES="$DEFINES -DMESA_SELINUX"
 575 fi
 576 AC_SUBST([SELINUX_CFLAGS])
 577 AC_SUBST([SELINUX_LIBS])
 578
 579 dnl Options for APIs
 580 AC_ARG_ENABLE([opengl],
 581     [AS_HELP_STRING([--disable-opengl],
 582         [disable support for standard OpenGL API @<:@default=no@:>@])],
 583     [enable_opengl="$enableval"],
 584     [enable_opengl=yes])
 585 AC_ARG_ENABLE([gles1],
 586     [AS_HELP_STRING([--enable-gles1],
 587         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 588     [enable_gles1="$enableval"],
 589     [enable_gles1=no])
 590 AC_ARG_ENABLE([gles2],
 591     [AS_HELP_STRING([--enable-gles2],
 592         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 593     [enable_gles2="$enableval"],
 594     [enable_gles2=no])
 595 AC_ARG_ENABLE([openvg],
 596     [AS_HELP_STRING([--enable-openvg],
 597         [enable support for OpenVG API @<:@default=no@:>@])],
 598     [enable_openvg="$enableval"],
 599     [enable_openvg=no])
 600
 601 AC_ARG_ENABLE([dri],
 602     [AS_HELP_STRING([--enable-dri],
 603         [enable DRI modules @<:@default=enabled@:>@])],
 604     [enable_dri="$enableval"],
 605     [enable_dri=yes])
 606
 607 case "$host_os" in
 608 linux*)
 609     dri3_default=yes
 610     ;;
 611 *)
 612     dri3_default=no
 613     ;;
 614 esac
 615 AC_ARG_ENABLE([dri3],
 616     [AS_HELP_STRING([--enable-dri3],
 617         [enable DRI3 @<:@default=auto@:>@])],
 618     [enable_dri3="$enableval"],
 619     [enable_dri3="$dri3_default"])
 620 AC_ARG_ENABLE([glx],
 621     [AS_HELP_STRING([--enable-glx],
 622         [enable GLX library @<:@default=enabled@:>@])],
 623     [enable_glx="$enableval"],
 624     [enable_glx=yes])
 625 AC_ARG_ENABLE([osmesa],
 626     [AS_HELP_STRING([--enable-osmesa],
 627         [enable OSMesa library @<:@default=disabled@:>@])],
 628     [enable_osmesa="$enableval"],
 629     [enable_osmesa=no])
 630 AC_ARG_ENABLE([gallium-osmesa],
 631     [AS_HELP_STRING([--enable-gallium-osmesa],
 632         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 633     [enable_gallium_osmesa="$enableval"],
 634     [enable_gallium_osmesa=no])
 635 AC_ARG_ENABLE([egl],
 636     [AS_HELP_STRING([--disable-egl],
 637         [disable EGL library @<:@default=enabled@:>@])],
 638     [enable_egl="$enableval"],
 639     [enable_egl=yes])
 640
 641 AC_ARG_ENABLE([xa],
 642     [AS_HELP_STRING([--enable-xa],
 643         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 644     [enable_xa="$enableval"],
 645     [enable_xa=no])
 646 AC_ARG_ENABLE([gbm],
 647    [AS_HELP_STRING([--enable-gbm],
 648          [enable gbm library @<:@default=auto@:>@])],
 649    [enable_gbm="$enableval"],
 650    [enable_gbm=auto])
 651
 652 AC_ARG_ENABLE([xvmc],
 653    [AS_HELP_STRING([--enable-xvmc],
 654          [enable xvmc library @<:@default=auto@:>@])],
 655    [enable_xvmc="$enableval"],
 656    [enable_xvmc=no])
 657 AC_ARG_ENABLE([vdpau],
 658    [AS_HELP_STRING([--enable-vdpau],
 659          [enable vdpau library @<:@default=auto@:>@])],
 660    [enable_vdpau="$enableval"],
 661    [enable_vdpau=auto])
 662 AC_ARG_ENABLE([omx],
 663    [AS_HELP_STRING([--enable-omx],
 664          [enable OpenMAX library @<:@default=no@:>@])],
 665    [enable_omx="$enableval"],
 666    [enable_omx=no])
 667 AC_ARG_ENABLE([opencl],
 668    [AS_HELP_STRING([--enable-opencl],
 669          [enable OpenCL library @<:@default=no@:>@])],
 670    [enable_opencl="$enableval"],
 671    [enable_opencl=no])
 672 AC_ARG_ENABLE([opencl_icd],
 673    [AS_HELP_STRING([--enable-opencl-icd],
 674           [Build an OpenCL ICD library to be loaded by an ICD implementation
 675            @<:@default=no@:>@])],
 676     [enable_opencl_icd="$enableval"],
 677     [enable_opencl_icd=no])
 678 AC_ARG_ENABLE([xlib-glx],
 679     [AS_HELP_STRING([--enable-xlib-glx],
 680         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 681     [enable_xlib_glx="$enableval"],
 682     [enable_xlib_glx=no])
 683 AC_ARG_ENABLE([gallium-egl],
 684     [AS_HELP_STRING([--enable-gallium-egl],
 685         [enable optional EGL state tracker (not required
 686          for EGL support in Gallium with OpenGL and OpenGL ES)
 687          @<:@default=disable@:>@])],
 688     [enable_gallium_egl="$enableval"],
 689     [enable_gallium_egl=no])
 690 AC_ARG_ENABLE([gallium-gbm],
 691     [AS_HELP_STRING([--enable-gallium-gbm],
 692         [enable optional gbm state tracker (not required for
 693          gbm support in Gallium)
 694          @<:@default=auto@:>@])],
 695     [enable_gallium_gbm="$enableval"],
 696     [enable_gallium_gbm=auto])
 697
 698 AC_ARG_ENABLE([r600-llvm-compiler],
 699     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 700         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 701     [enable_r600_llvm="$enableval"],
 702     [enable_r600_llvm=no])
 703
 704 AC_ARG_ENABLE([gallium-tests],
 705     [AS_HELP_STRING([--enable-gallium-tests],
 706         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 707     [enable_gallium_tests="$enableval"],
 708     [enable_gallium_tests=no])
 709
 710 # Option for Gallium drivers
 711
 712 # Keep this in sync with the --with-gallium-drivers help string default value
 713 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 714
 715 AC_ARG_WITH([gallium-drivers],
 716     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 717         [comma delimited Gallium drivers list, e.g.
 718         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 719         @<:@default=r300,r600,svga,swrast@:>@])],
 720     [with_gallium_drivers="$withval"],
 721     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 722
 723 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 724 # here so that the script doesn't choke on an unknown driver name later.
 725 case "$with_gallium_drivers" in
 726     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 727     no) with_gallium_drivers='' ;;
 728 esac
 729
 730 if test "x$enable_opengl" = xno -a \
 731         "x$enable_gles1" = xno -a \
 732         "x$enable_gles2" = xno -a \
 733         "x$enable_openvg" = xno -a \
 734         "x$enable_xa" = xno -a \
 735         "x$enable_xvmc" = xno -a \
 736         "x$enable_vdpau" = xno -a \
 737         "x$enable_omx" = xno -a \
 738         "x$enable_opencl" = xno; then
 739     AC_MSG_ERROR([at least one API should be enabled])
 740 fi
 741
 742 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 743 if test "x$enable_opengl" = xno -a \
 744         "x$enable_gles1" = xyes; then
 745     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 746 fi
 747
 748 if test "x$enable_opengl" = xno -a \
 749         "x$enable_gles2" = xyes; then
 750     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 751 fi
 752
 753 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 754 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 755 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 756 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 757                                         "x$enable_gles1" = xyes -o \
 758                                         "x$enable_gles2" = xyes)
 759
 760 if test "x$enable_glx" = xno; then
 761     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 762     enable_xlib_glx=no
 763 fi
 764
 765 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 766     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 767 fi
 768
 769 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 770     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 771 fi
 772
 773 # Disable GLX if OpenGL is not enabled
 774 if test "x$enable_glx$enable_opengl" = xyesno; then
 775     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 776     enable_glx=no
 777 fi
 778
 779 # Disable GLX if DRI and Xlib-GLX are not enabled
 780 if test "x$enable_glx" = xyes -a \
 781         "x$enable_dri" = xno -a \
 782         "x$enable_xlib_glx" = xno; then
 783     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 784     enable_glx=no
 785 fi
 786
 787 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 788                                   "x$enable_dri" = xyes)
 789
 790 # Select which platform-dependent DRI code gets built
 791 case "$host_os" in
 792 darwin*)
 793     dri_platform='apple' ;;
 794 gnu*|mingw*|cygwin*)
 795     dri_platform='none' ;;
 796 *)
 797     dri_platform='drm' ;;
 798 esac
 799
 800 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 801 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 802 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 803 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 804 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 805
 806 AC_ARG_ENABLE([shared-glapi],
 807     [AS_HELP_STRING([--enable-shared-glapi],
 808         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 809     [enable_shared_glapi="$enableval"],
 810     [enable_shared_glapi=yes])
 811
 812 case "x$enable_opengl$enable_gles1$enable_gles2" in
 813 x*yes*yes*)
 814     if test "x$enable_shared_glapi" = xno; then
 815         AC_MSG_ERROR([shared GLAPI required when building two or more of
 816                       the following APIs - opengl, gles1 gles2])
 817     fi
 818     ;;
 819 esac
 820
 821 # Building Xlib-GLX requires shared glapi to be disabled.
 822 if test "x$enable_xlib_glx" = xyes; then
 823     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 824     enable_shared_glapi=no
 825 fi
 826
 827 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 828
 829 dnl
 830 dnl Driver specific build directories
 831 dnl
 832 GALLIUM_TARGET_DIRS=""
 833 GALLIUM_WINSYS_DIRS="sw"
 834 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 835 GALLIUM_STATE_TRACKERS_DIRS=""
 836
 837 case "x$enable_glx$enable_xlib_glx" in
 838 xyesyes)
 839     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 840     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 841     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 842     NEED_WINSYS_XLIB="yes"
 843     ;;
 844 esac
 845
 846 if test "x$enable_dri" = xyes; then
 847     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 848     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 849 fi
 850
 851 if test "x$enable_gallium_osmesa" = xyes; then
 852     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 853         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 854     fi
 855     if test "x$enable_osmesa" = xyes; then
 856         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 857     fi
 858     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 859     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 860 fi
 861
 862 AC_SUBST([MESA_LLVM])
 863
 864 # Check for libdrm
 865 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 866                   [have_libdrm=yes], [have_libdrm=no])
 867 if test "x$have_libdrm" = xyes; then
 868         DEFINES="$DEFINES -DHAVE_LIBDRM"
 869 fi
 870
 871 case "$host_os" in
 872 linux*)
 873     need_libudev=yes ;;
 874 *)
 875     need_libudev=no ;;
 876 esac
 877
 878 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 879                   have_libudev=yes, have_libudev=no)
 880
 881 if test "x$enable_dri" = xyes; then
 882     if test "$enable_static" = yes; then
 883         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 884     fi
 885
 886     # not a hard requirement as swrast does not depend on it
 887     if test "x$have_libdrm" = xyes; then
 888         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 889     fi
 890 fi
 891
 892 dnl Direct rendering or just indirect rendering
 893 case "$host_os" in
 894 gnu*)
 895     dnl Disable by default on GNU/Hurd
 896     driglx_direct_default="no"
 897     ;;
 898 cygwin*)
 899     dnl Disable by default on cygwin
 900     driglx_direct_default="no"
 901     ;;
 902 *)
 903     driglx_direct_default="yes"
 904     ;;
 905 esac
 906 AC_ARG_ENABLE([driglx-direct],
 907     [AS_HELP_STRING([--disable-driglx-direct],
 908         [disable direct rendering in GLX and EGL for DRI \
 909             @<:@default=auto@:>@])],
 910     [driglx_direct="$enableval"],
 911     [driglx_direct="$driglx_direct_default"])
 912
 913 dnl
 914 dnl libGL configuration per driver
 915 dnl
 916 case "x$enable_glx$enable_xlib_glx" in
 917 xyesyes)
 918     # Xlib-based GLX
 919     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 920     GL_PC_REQ_PRIV="x11 xext"
 921     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 922     GL_LIB_DEPS="$XLIBGL_LIBS"
 923     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 924     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 925     ;;
 926 xyesno)
 927     # DRI-based GLX
 928     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 929
 930     # find the DRI deps for libGL
 931     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 932
 933     if test x"$driglx_direct" = xyes; then
 934         if test x"$dri_platform" = xdrm ; then
 935             if test "x$have_libdrm" != xyes; then
 936                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 937             fi
 938
 939             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 940             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 941             if test x"$enable_dri3" = xyes; then
 942                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 943                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 944             fi
 945
 946             if test x"$enable_dri" = xyes; then
 947                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 948             fi
 949
 950             if test x"$enable_dri3" = xyes; then
 951                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 952             fi
 953     fi
 954
 955     # add xf86vidmode if available
 956     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 957     if test "$HAVE_XF86VIDMODE" = yes ; then
 958         dri_modules="$dri_modules xxf86vm"
 959     fi
 960
 961     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 962     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 963     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 964     GL_LIB_DEPS="$DRIGL_LIBS"
 965
 966     # need DRM libs, $PTHREAD_LIBS, etc.
 967     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 968     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 969     ;;
 970 esac
 971
 972 if test "$have_libudev" = yes; then
 973     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 974 fi
 975
 976 # This is outside the case (above) so that it is invoked even for non-GLX
 977 # builds.
 978 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 979
 980 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 981 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 982 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 983 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 984
 985 AC_SUBST([X11_INCLUDES])
 986 AC_SUBST([GL_LIB_DEPS])
 987 AC_SUBST([GL_PC_REQ_PRIV])
 988 AC_SUBST([GL_PC_LIB_PRIV])
 989 AC_SUBST([GL_PC_CFLAGS])
 990 AC_SUBST([DRI_PC_REQ_PRIV])
 991 AC_SUBST([GLESv1_CM_LIB_DEPS])
 992 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 993 AC_SUBST([GLESv2_LIB_DEPS])
 994 AC_SUBST([GLESv2_PC_LIB_PRIV])
 995
 996 AC_SUBST([HAVE_XF86VIDMODE])
 997
 998 dnl
 999 dnl More GLX setup
1000 dnl
1001 case "x$enable_glx$enable_xlib_glx" in
1002 xyesyes)
1003     DEFINES="$DEFINES -DUSE_XSHM"
1004     ;;
1005 xyesno)
1006     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1007     if test "x$driglx_direct" = xyes; then
1008         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1009     fi
1010     ;;
1011 esac
1012
1013 dnl
1014 dnl TLS detection
1015 dnl
1016
1017 AC_ARG_ENABLE([glx-tls],
1018     [AS_HELP_STRING([--enable-glx-tls],
1019         [enable TLS support in GLX @<:@default=disabled@:>@])],
1020     [GLX_USE_TLS="$enableval"],
1021     [GLX_USE_TLS=no])
1022 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1023
1024 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1025       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1026
1027 dnl
1028 dnl More DRI setup
1029 dnl
1030 dnl Directory for DRI drivers
1031 AC_ARG_WITH([dri-driverdir],
1032     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1033         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1034     [DRI_DRIVER_INSTALL_DIR="$withval"],
1035     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1036 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1037 dnl Extra search path for DRI drivers
1038 AC_ARG_WITH([dri-searchpath],
1039     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1040         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1041     [DRI_DRIVER_SEARCH_DIR="$withval"],
1042     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1043 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1044 dnl Which drivers to build - default is chosen by platform
1045 AC_ARG_WITH([dri-drivers],
1046     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1047         [comma delimited classic DRI drivers list, e.g.
1048         "swrast,i965,radeon" @<:@default=auto@:>@])],
1049     [with_dri_drivers="$withval"],
1050     [with_dri_drivers=auto])
1051
1052 if test "x$with_dri_drivers" = xauto; then
1053     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1054         with_dri_drivers="yes"
1055     else
1056         with_dri_drivers="no"
1057     fi
1058 fi
1059 if test "x$with_dri_drivers" = xno; then
1060     with_dri_drivers=''
1061 fi
1062
1063 dnl If $with_dri_drivers is yes, drivers will be added through
1064 dnl platform checks. Set DEFINES and LIB_DEPS
1065 if test "x$enable_dri" = xyes; then
1066     # Platform specific settings and drivers to build
1067     case "$host_os" in
1068     linux*)
1069         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1070         DEFINES="$DEFINES -DHAVE_ALIAS"
1071         if test "x$enable_dri3" = xyes; then
1072             DEFINES="$DEFINES -DHAVE_DRI3"
1073         fi
1074
1075         if test "x$have_libudev" != xyes; then
1076             AC_MSG_ERROR([libudev-dev required for building DRI])
1077         fi
1078
1079         case "$host_cpu" in
1080         powerpc* | sparc*)
1081             # Build only the drivers for cards that exist on PowerPC/sparc
1082             if test "x$with_dri_drivers" = "xyes"; then
1083                 with_dri_drivers="r200 radeon swrast"
1084             fi
1085             ;;
1086         esac
1087         ;;
1088     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1089         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1090         DEFINES="$DEFINES -DHAVE_ALIAS"
1091         ;;
1092     gnu*)
1093         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1094         DEFINES="$DEFINES -DHAVE_ALIAS"
1095         ;;
1096     solaris*)
1097         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1098         ;;
1099     cygwin*)
1100         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1101         if test "x$with_dri_drivers" = "xyes"; then
1102             with_dri_drivers="swrast"
1103         fi
1104         ;;
1105     darwin*)
1106         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DGLX_ALIAS_UNSUPPORTED"
1107         if test "x$with_dri_drivers" = "xyes"; then
1108             with_dri_drivers="swrast"
1109         fi
1110         ;;
1111     esac
1112
1113     # default drivers
1114     if test "x$with_dri_drivers" = "xyes"; then
1115         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1116     fi
1117
1118     # Check for expat
1119     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1120     if test "x$have_expat" = "xyes"; then
1121        PKG_CHECK_MODULES([EXPAT], [expat], [],
1122                          AC_MSG_ERROR([Expat required for DRI.]))
1123     else
1124        # expat version 2.0 and earlier do not provide expat.pc
1125        EXPAT_LIBS=-lexpat
1126     fi
1127
1128     # If we are building any DRI driver other than swrast.
1129     if test -n "$with_dri_drivers"; then
1130         if test "x$with_dri_drivers" != xswrast; then
1131             # ... libdrm is required
1132             if test "x$have_libdrm" != xyes; then
1133                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1134             fi
1135             DRICOMMON_NEED_LIBDRM=yes
1136         else
1137             DRICOMMON_NEED_LIBDRM=no
1138         fi
1139     fi
1140
1141     # put all the necessary libs together
1142     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1143 fi
1144
1145 AC_SUBST([DRI_LIB_DEPS])
1146
1147 DRI_DIRS=''
1148 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1149 if test -n "$with_dri_drivers"; then
1150     if test "x$enable_opengl" != xyes; then
1151         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1152     fi
1153
1154     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1155     for driver in $dri_drivers; do
1156         DRI_DIRS="$DRI_DIRS $driver"
1157         case "x$driver" in
1158         xi915)
1159             HAVE_I915_DRI=yes;
1160             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1161             ;;
1162         xi965)
1163             HAVE_I965_DRI=yes;
1164             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1165             ;;
1166         xnouveau)
1167             HAVE_NOUVEAU_DRI=yes;
1168             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1169             ;;
1170         xradeon)
1171             HAVE_RADEON_DRI=yes;
1172             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1173             ;;
1174         xr200)
1175             HAVE_R200_DRI=yes;
1176             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1177             ;;
1178         xswrast)
1179             HAVE_SWRAST_DRI=yes;
1180             ;;
1181         *)
1182             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1183             ;;
1184         esac
1185     done
1186     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1187 fi
1188
1189 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1190 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1191                                   "x$enable_osmesa" = xyes -o \
1192                                   -n "$DRI_DIRS")
1193
1194 dnl
1195 dnl OSMesa configuration
1196 dnl
1197
1198 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1199 AC_ARG_WITH([osmesa-bits],
1200     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1201         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1202     [osmesa_bits="$withval"],
1203     [osmesa_bits=8])
1204 if test "x$osmesa_bits" != x8; then
1205     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1206         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1207         osmesa_bits=8
1208     fi
1209 fi
1210 case "x$osmesa_bits" in
1211 x8)
1212     OSMESA_LIB="${OSMESA_LIB}"
1213     ;;
1214 x16|x32)
1215     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1216     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1217     ;;
1218 *)
1219     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1220     ;;
1221 esac
1222
1223 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1224     # only link libraries with osmesa if shared
1225     if test "$enable_static" = no; then
1226         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1227     else
1228         OSMESA_LIB_DEPS=""
1229     fi
1230     OSMESA_MESA_DEPS=""
1231     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1232 fi
1233
1234 AC_SUBST([OSMESA_LIB_DEPS])
1235 AC_SUBST([OSMESA_MESA_DEPS])
1236 AC_SUBST([OSMESA_PC_REQ])
1237 AC_SUBST([OSMESA_PC_LIB_PRIV])
1238
1239 dnl
1240 dnl gbm configuration
1241 dnl
1242 if test "x$enable_gbm" = xauto; then
1243     case "$with_egl_platforms" in
1244         *drm*)
1245             enable_gbm=yes ;;
1246          *)
1247             enable_gbm=no ;;
1248     esac
1249 fi
1250 if test "x$enable_gbm" = xyes; then
1251     if test "x$need_libudev$have_libudev" = xyesno; then
1252         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1253     fi
1254
1255     if test "x$enable_dri" = xyes; then
1256         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1257         if test "x$enable_shared_glapi" = xno; then
1258             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1259         fi
1260     else
1261         # Strictly speaking libgbm does not require --enable-dri, although
1262         # both of its backends do. Thus one can build libgbm without any
1263         # backends if --disable-dri is set.
1264         # To avoid unnecessary complexity of checking if at least one backend
1265         # is available when building, just mandate --enable-dri.
1266         AC_MSG_ERROR([gbm requires --enable-dri])
1267     fi
1268 fi
1269 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1270 if test "x$need_libudev" = xyes; then
1271     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1272 else
1273     GBM_PC_REQ_PRIV=""
1274 fi
1275 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1276 AC_SUBST([GBM_PC_REQ_PRIV])
1277 AC_SUBST([GBM_PC_LIB_PRIV])
1278
1279 dnl
1280 dnl EGL configuration
1281 dnl
1282 EGL_CLIENT_APIS=""
1283
1284 if test "x$enable_egl" = xyes; then
1285     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1286
1287     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1288
1289     if test "$enable_static" != yes; then
1290         if test "x$enable_dri" = xyes; then
1291             HAVE_EGL_DRIVER_DRI2=1
1292         fi
1293
1294     fi
1295 fi
1296 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1297 AC_SUBST([EGL_LIB_DEPS])
1298
1299 dnl
1300 dnl EGL Gallium configuration
1301 dnl
1302 if test "x$enable_gallium_egl" = xyes; then
1303     if test -z "$with_gallium_drivers"; then
1304         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1305     fi
1306     if test "x$enable_egl" = xno; then
1307         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1308     fi
1309     if test "x$have_libdrm" != xyes; then
1310         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1311     fi
1312
1313     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1314     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1315 fi
1316 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1317
1318 dnl
1319 dnl gbm Gallium configuration
1320 dnl
1321 if test "x$enable_gallium_gbm" = xauto; then
1322     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1323         yesyesyes*drm*)
1324             enable_gallium_gbm=yes ;;
1325          *)
1326             enable_gallium_gbm=no ;;
1327     esac
1328 fi
1329 if test "x$enable_gallium_gbm" = xyes; then
1330     if test -z "$with_gallium_drivers"; then
1331         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1332     fi
1333     if test "x$enable_gbm" = xno; then
1334         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1335     fi
1336     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1337     if test "x$enable_dri" = xno; then
1338         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1339     fi
1340
1341     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1342     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1343     enable_gallium_loader=yes
1344 fi
1345 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1346
1347 dnl
1348 dnl XA configuration
1349 dnl
1350 if test "x$enable_xa" = xyes; then
1351     if test "x$with_gallium_drivers" = xswrast; then
1352        AC_MSG_ERROR([
1353           Building xa requires at least one non swrast gallium driver.
1354           If you are looking to use libxatracker.so with vmware's virtual gpu,
1355           make sure to include svga in the gallium drivers list, apart from
1356           enabling XA.
1357           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1358     fi
1359     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1360     enable_gallium_loader=yes
1361 fi
1362 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1363
1364 dnl
1365 dnl OpenVG configuration
1366 dnl
1367 VG_LIB_DEPS=""
1368
1369 if test "x$enable_openvg" = xyes; then
1370     if test "x$enable_egl" = xno; then
1371         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1372     fi
1373     if test -z "$with_gallium_drivers"; then
1374         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1375     fi
1376     if test "x$enable_gallium_egl" = xno; then
1377         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1378     fi
1379
1380     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1381     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1382     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1383     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1384     AC_SUBST([VG_PC_LIB_PRIV])
1385 fi
1386 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1387
1388 dnl
1389 dnl Gallium G3DVL configuration
1390 dnl
1391 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1392     if test "x$enable_xvmc" = xauto; then
1393         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1394     fi
1395
1396     if test "x$enable_vdpau" = xauto; then
1397         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1398     fi
1399
1400     if test "x$enable_omx" = xauto; then
1401         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1402     fi
1403 fi
1404
1405 if test "x$enable_xvmc" = xyes; then
1406     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1407     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1408 fi
1409 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1410
1411 if test "x$enable_vdpau" = xyes; then
1412     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1413                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1414     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1415 fi
1416 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1417
1418 if test "x$enable_omx" = xyes; then
1419     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1420     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1421 fi
1422 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1423
1424 dnl
1425 dnl OpenCL configuration
1426 dnl
1427
1428 AC_ARG_WITH([libclc-path],
1429    [AS_HELP_STRING([--with-libclc-path],
1430          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1431    [LIBCLC_PATH="$withval"],
1432    [LIBCLC_PATH=''])
1433
1434 if test -n "$LIBCLC_PATH"; then
1435    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1436                   Please review the updated build instructions for clover:
1437                   http://dri.freedesktop.org/wiki/GalliumCompute])
1438 fi
1439
1440
1441 AC_ARG_WITH([clang-libdir],
1442    [AS_HELP_STRING([--with-clang-libdir],
1443          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1444    [CLANG_LIBDIR="$withval"],
1445    [CLANG_LIBDIR=''])
1446
1447 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1448
1449 if test "x$enable_opencl" = xyes; then
1450     if test -z "$with_gallium_drivers"; then
1451         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1452     fi
1453
1454     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1455         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1456     fi
1457
1458     if test "x$have_libclc" = xno; then
1459         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1460                     Make sure the directory containing libclc.pc is specified in your
1461                     PKG_CONFIG_PATH environment variable.
1462                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1463     else
1464         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1465         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1466         AC_SUBST([LIBCLC_INCLUDEDIR])
1467         AC_SUBST([LIBCLC_LIBEXECDIR])
1468     fi
1469
1470     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1471     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1472     enable_gallium_loader=yes
1473
1474     if test "x$enable_opencl_icd" = xyes; then
1475         OPENCL_LIBNAME="MesaOpenCL"
1476     else
1477         OPENCL_LIBNAME="OpenCL"
1478     fi
1479 fi
1480 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1481 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1482 AC_SUBST([OPENCL_LIBNAME])
1483
1484 dnl
1485 dnl Gallium configuration
1486 dnl
1487 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1488
1489 AC_SUBST([LLVM_BINDIR])
1490 AC_SUBST([LLVM_CFLAGS])
1491 AC_SUBST([LLVM_CPPFLAGS])
1492 AC_SUBST([LLVM_CXXFLAGS])
1493 AC_SUBST([LLVM_LIBDIR])
1494 AC_SUBST([LLVM_LIBS])
1495 AC_SUBST([LLVM_LDFLAGS])
1496 AC_SUBST([LLVM_INCLUDEDIR])
1497 AC_SUBST([LLVM_VERSION])
1498 AC_SUBST([CLANG_RESOURCE_DIR])
1499
1500 case "x$enable_opengl$enable_gles1$enable_gles2" in
1501 x*yes*)
1502     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1503     ;;
1504 esac
1505
1506 AC_SUBST([VG_LIB_DEPS])
1507 AC_SUBST([EGL_CLIENT_APIS])
1508
1509 dnl
1510 dnl EGL Platforms configuration
1511 dnl
1512 AC_ARG_WITH([egl-platforms],
1513     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1514         [comma delimited native platforms libEGL supports, e.g.
1515         "x11,drm" @<:@default=auto@:>@])],
1516     [with_egl_platforms="$withval"],
1517     [if test "x$enable_egl" = xyes; then
1518         with_egl_platforms="x11"
1519     else
1520         with_egl_platforms=""
1521     fi])
1522
1523 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1524     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1525 fi
1526
1527 # Do per-EGL platform setups and checks
1528 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1529 for plat in $egl_platforms; do
1530         case "$plat" in
1531         wayland)
1532                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1533                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1534
1535                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1536                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1537                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1538                 ;;
1539
1540         x11)
1541                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1542                 ;;
1543
1544         drm)
1545                 test "x$enable_gbm" = "xno" &&
1546                         AC_MSG_ERROR([EGL platform drm needs gbm])
1547                 test "x$have_libdrm" != xyes &&
1548                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1549                 ;;
1550
1551         android|fbdev|gdi|null)
1552                 ;;
1553
1554         *)
1555                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1556                 ;;
1557         esac
1558
1559         case "$plat$need_libudev$have_libudev" in
1560                 waylandyesno|drmyesno)
1561                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1562         esac
1563 done
1564
1565 # libEGL wants to default to the first platform specified in
1566 # ./configure.  parse that here.
1567 if test "x$egl_platforms" != "x"; then
1568     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1569     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1570 else
1571     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1572 fi
1573
1574 if echo "$egl_platforms" | grep -q 'x11'; then
1575     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1576     NEED_WINSYS_XLIB=yes
1577 fi
1578 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1579 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1580 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1581 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1582 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1583
1584 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1585
1586 AC_SUBST([EGL_NATIVE_PLATFORM])
1587 AC_SUBST([EGL_CFLAGS])
1588
1589 # If we don't have the X11 platform, set this define so we don't try to include
1590 # the X11 headers.
1591 if ! echo "$egl_platforms" | grep -q 'x11'; then
1592     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1593     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1594 fi
1595
1596 AC_ARG_WITH([egl-driver-dir],
1597     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1598                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1599     [EGL_DRIVER_INSTALL_DIR="$withval"],
1600     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1601 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1602
1603 AC_ARG_WITH([max-width],
1604     [AS_HELP_STRING([--with-max-width=N],
1605                     [Maximum framebuffer width (4096)])],
1606     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1607      AS_IF([test "${withval}" -gt "4096"],
1608            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1609 )
1610 AC_ARG_WITH([max-height],
1611     [AS_HELP_STRING([--with-max-height=N],
1612                     [Maximum framebuffer height (4096)])],
1613     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1614      AS_IF([test "${withval}" -gt "4096"],
1615            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1616 )
1617
1618 dnl
1619 dnl Gallium LLVM
1620 dnl
1621 AC_ARG_ENABLE([gallium-llvm],
1622     [AS_HELP_STRING([--enable-gallium-llvm],
1623         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1624     [enable_gallium_llvm="$enableval"],
1625     [enable_gallium_llvm=auto])
1626
1627 AC_ARG_ENABLE([llvm-shared-libs],
1628     [AS_HELP_STRING([--enable-llvm-shared-libs],
1629         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1630     [enable_llvm_shared_libs="$enableval"],
1631     [enable_llvm_shared_libs=yes])
1632
1633 AC_ARG_WITH([llvm-prefix],
1634     [AS_HELP_STRING([--with-llvm-prefix],
1635         [Prefix for LLVM installations in non-standard locations])],
1636     [llvm_prefix="$withval"],
1637     [llvm_prefix=''])
1638
1639
1640 # Call this inside ` ` to get the return value.
1641 # $1 is the llvm-config command with arguments.
1642 strip_unwanted_llvm_flags() {
1643     # Use \> (marks the end of the word)
1644     echo `$1` | sed \
1645         -e 's/-DNDEBUG\>//g' \
1646         -e 's/-pedantic\>//g' \
1647         -e 's/-Wcovered-switch-default\>//g' \
1648         -e 's/-O.\>//g' \
1649         -e 's/-g\>//g' \
1650         -e 's/-Wall\>//g' \
1651         -e 's/-Wcast-qual\>//g' \
1652         -e 's/-Woverloaded-virtual\>//g' \
1653         -e 's/-fcolor-diagnostics\>//g' \
1654         -e 's/-fdata-sections\>//g' \
1655         -e 's/-ffunction-sections\>//g' \
1656         -e 's/-fno-exceptions\>//g' \
1657         -e 's/-fomit-frame-pointer\>//g' \
1658         -e 's/-fvisibility-inlines-hidden\>//g' \
1659         -e 's/-fPIC\>//g' \
1660         -e 's/-fstack-protector-strong\>//g'
1661 }
1662
1663
1664 if test -z "$with_gallium_drivers"; then
1665     enable_gallium_llvm=no
1666 fi
1667 if test "x$enable_gallium_llvm" = xauto; then
1668     case "$host_cpu" in
1669     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1670     esac
1671 fi
1672 if test "x$enable_gallium_llvm" = xyes; then
1673     if test -n "$llvm_prefix"; then
1674         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1675     else
1676         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1677     fi
1678
1679     if test "x$LLVM_CONFIG" != xno; then
1680         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1681         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1682         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1683         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1684         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1685         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1686         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1687         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1688
1689         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1690             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1691         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1692             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1693
1694         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1695         dnl llvm-config.h
1696         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1697             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1698             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1699
1700         if test -n "${LLVM_VERSION_MAJOR}"; then
1701             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1702         else
1703             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1704         fi
1705
1706         LLVM_REQUIRED_VERSION_MAJOR="3"
1707         LLVM_REQUIRED_VERSION_MINOR="1"
1708         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1709             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1710         fi
1711
1712         LLVM_COMPONENTS="engine bitwriter"
1713         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1714             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1715         fi
1716
1717         if test "x$enable_opencl" = xyes; then
1718             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1719             # LLVM 3.3 >= 177971 requires IRReader
1720             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1721                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1722             fi
1723             # LLVM 3.4 requires Option
1724             if $LLVM_CONFIG --components | grep -qw 'option'; then
1725                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1726             fi
1727         fi
1728         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1729         MESA_LLVM=1
1730
1731         dnl Check for Clang internal headers
1732         if test "x$enable_opencl" = xyes; then
1733             if test -z "$CLANG_LIBDIR"; then
1734                 CLANG_LIBDIR=${LLVM_LIBDIR}
1735             fi
1736             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1737             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1738                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1739         fi
1740     else
1741         MESA_LLVM=0
1742         LLVM_VERSION_INT=0
1743     fi
1744 else
1745     MESA_LLVM=0
1746     LLVM_VERSION_INT=0
1747 fi
1748
1749 dnl Directory for XVMC libs
1750 AC_ARG_WITH([xvmc-libdir],
1751     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1752         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1753     [XVMC_LIB_INSTALL_DIR="$withval"],
1754     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1755 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1756
1757 dnl
1758 dnl Gallium Tests
1759 dnl
1760 if test "x$enable_gallium_tests" = xyes; then
1761     enable_gallium_loader=yes
1762 fi
1763 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1764
1765 if test "x$enable_gallium_loader" = xyes; then
1766     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1767 fi
1768 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1769
1770 dnl Directory for VDPAU libs
1771 AC_ARG_WITH([vdpau-libdir],
1772     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1773         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1774     [VDPAU_LIB_INSTALL_DIR="$withval"],
1775     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1776 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1777
1778 OMX_LIB_INSTALL_DIR_DEFAULT=''
1779 if test "x$enable_omx" = xyes; then
1780     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1781 fi
1782
1783 AC_ARG_WITH([omx-libdir],
1784     [AS_HELP_STRING([--with-omx-libdir=DIR],
1785         [directory for the OMX libraries])],
1786     [OMX_LIB_INSTALL_DIR="$withval"],
1787     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1788 AC_SUBST([OMX_LIB_INSTALL_DIR])
1789
1790 dnl Directory for OpenCL libs
1791 AC_ARG_WITH([opencl-libdir],
1792     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1793         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1794     [OPENCL_LIB_INSTALL_DIR="$withval"],
1795     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1796 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1797
1798 dnl
1799 dnl Gallium helper functions
1800 dnl
1801 gallium_check_st() {
1802     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1803          if test "x$have_libdrm" != xyes; then
1804             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1805          fi
1806          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1807     fi
1808     if test "x$enable_dri" = xyes && test -n "$2"; then
1809          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1810     fi
1811     if test "x$enable_xa" = xyes && test -n "$3"; then
1812          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1813     fi
1814     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1815          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1816     fi
1817     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1818          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1819     fi
1820     if test "x$enable_omx" = xyes && test "x$6" != x; then
1821          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1822     fi
1823 }
1824
1825 gallium_require_llvm() {
1826     if test "x$MESA_LLVM" = x0; then
1827         case "$host_cpu" in
1828         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1829         esac
1830     fi
1831 }
1832
1833 gallium_require_drm_loader() {
1834     if test "x$enable_gallium_loader" = xyes; then
1835         if test "x$need_libudev$have_libudev" = xyesno; then
1836             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1837         fi
1838         if test "x$have_libdrm" != xyes; then
1839             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1840         fi
1841         enable_gallium_drm_loader=yes
1842     fi
1843 }
1844
1845 require_egl_drm() {
1846     case "$with_egl_platforms" in
1847         *drm*)
1848             ;;
1849          *)
1850             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1851             ;;
1852     esac
1853     if test "x$enable_gbm" != xyes; then
1854             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1855     fi
1856 }
1857
1858 radeon_llvm_check() {
1859     if test "x$enable_gallium_llvm" != "xyes"; then
1860         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1861     fi
1862     LLVM_REQUIRED_VERSION_MAJOR="3"
1863     LLVM_REQUIRED_VERSION_MINOR="3"
1864     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1865         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1866     fi
1867     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1868         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1869                       sources with the --enable-experimental-targets=R600
1870                       configure flag])
1871     fi
1872     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1873     NEED_RADEON_LLVM=yes
1874     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1875                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1876 }
1877
1878 dnl Gallium drivers
1879 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1880         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1881     NEED_NONNULL_WINSYS=yes
1882 fi
1883 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1884
1885 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1886 if test -n "$with_gallium_drivers"; then
1887     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1888     for driver in $gallium_drivers; do
1889         case "x$driver" in
1890         xsvga)
1891             HAVE_GALLIUM_SVGA=yes
1892             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1893             gallium_require_drm_loader
1894             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1895             ;;
1896         xi915)
1897             HAVE_GALLIUM_I915=yes
1898             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1899             gallium_require_drm_loader
1900             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1901             if test "x$MESA_LLVM" = x1; then
1902                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1903             fi
1904             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1905             gallium_check_st "i915/drm" "dri-i915"
1906             DRICOMMON_NEED_LIBDRM=yes
1907             ;;
1908         xilo)
1909             HAVE_GALLIUM_ILO=yes
1910             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1911             gallium_require_drm_loader
1912             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1913             gallium_check_st "intel/drm" "dri-ilo"
1914             DRICOMMON_NEED_LIBDRM=yes
1915             ;;
1916         xr300)
1917             HAVE_GALLIUM_R300=yes
1918             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1919             gallium_require_drm_loader
1920             gallium_require_llvm "Gallium R300"
1921             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1922             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1923             DRICOMMON_NEED_LIBDRM=yes
1924             ;;
1925         xr600)
1926             HAVE_GALLIUM_R600=yes
1927             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1928             gallium_require_drm_loader
1929             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1930             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1931                 radeon_llvm_check "r600g"
1932                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1933             fi
1934             if test "x$enable_r600_llvm" = xyes; then
1935                 USE_R600_LLVM_COMPILER=yes;
1936             fi
1937             if test "x$enable_opencl" = xyes; then
1938                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1939             fi
1940             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1941             DRICOMMON_NEED_LIBDRM=yes
1942             ;;
1943         xradeonsi)
1944             HAVE_GALLIUM_RADEONSI=yes
1945             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1946             gallium_require_drm_loader
1947             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1948             radeon_llvm_check "radeonsi"
1949             require_egl_drm "radeonsi"
1950             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1951             DRICOMMON_NEED_LIBDRM=yes
1952             ;;
1953         xnouveau)
1954             HAVE_GALLIUM_NOUVEAU=yes
1955             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1956             gallium_require_drm_loader
1957             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1958             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1959             DRICOMMON_NEED_LIBDRM=yes
1960             ;;
1961         xfreedreno)
1962             HAVE_GALLIUM_FREEDRENO=yes
1963             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1964             gallium_require_drm_loader
1965             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1966             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1967             DRICOMMON_NEED_LIBDRM=yes
1968             ;;
1969         xswrast)
1970             HAVE_GALLIUM_SOFTPIPE=yes
1971             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1972             if test "x$MESA_LLVM" = x1; then
1973                 HAVE_GALLIUM_LLVMPIPE=yes
1974                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1975             fi
1976
1977             if test "x$enable_dri" = xyes; then
1978                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1979             fi
1980             ;;
1981         *)
1982             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1983             ;;
1984         esac
1985     done
1986 fi
1987
1988 dnl Set LLVM_LIBS - This is done after the driver configuration so
1989 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1990 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1991 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1992 dnl this was causing the same libraries to be appear multiple times
1993 dnl in LLVM_LIBS.
1994
1995 if test "x$MESA_LLVM" != x0; then
1996
1997     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1998
1999     if test "x$enable_llvm_shared_libs" = xyes; then
2000         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2001         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2002         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2003
2004         if test "x$llvm_have_one_so" = xyes; then
2005             dnl LLVM was built using auto*, so there is only one shared object.
2006             LLVM_LIBS="-l$LLVM_SO_NAME"
2007         else
2008             dnl If LLVM was built with CMake, there will be one shared object per
2009             dnl component.
2010             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2011                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2012         Please make sure you have built llvm with the --enable-shared option
2013         and that your llvm libraries are installed in $LLVM_LIBDIR
2014         If you have installed your llvm libraries to a different directory you
2015         can use the --with-llvm-prefix= configure flag to specify this directory.
2016         NOTE: Mesa is attempting to use llvm shared libraries by default.
2017         If you do not want to build with llvm shared libraries and instead want to
2018         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2019         invocation and rebuild.])])
2020
2021            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2022            dnl install uses a shared object for each compoenent and we have
2023            dnl already added all of these objects to LLVM_LIBS.
2024         fi
2025     else
2026         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2027     fi
2028 fi
2029
2030 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2031 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2032 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2033 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2034 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2035 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2036 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2037                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2038 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2039 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2040 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2041 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2042
2043 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2044                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
2045                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2046 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2047                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2048                                                   && test "x$MESA_LLVM" = x1)
2049
2050 # NOTE: anything using xcb or other client side libs ends up in separate
2051 #       _CLIENT variables.  The pipe loader is built in two variants,
2052 #       one that is standalone and does not link any x client libs (for
2053 #       use by XA tracker in particular, but could be used in any case
2054 #       where communication with xserver is not desired).
2055 if test "x$enable_gallium_loader" = xyes; then
2056     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2057
2058     if test "x$NEED_WINSYS_XLIB" = xyes; then
2059         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2060     fi
2061
2062     if test "x$enable_dri" = xyes; then
2063         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2064     fi
2065
2066     if test "x$enable_gallium_drm_loader" = xyes; then
2067         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2068         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2069                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2070         if test "x$pipe_loader_have_xcb" = xyes; then
2071             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2072             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2073         fi
2074     fi
2075
2076     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2077     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2078
2079     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2080     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2081     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2082     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2083 fi
2084
2085 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2086 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2087 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2088 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2089 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2090 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2091
2092 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2093                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2094                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2095                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2096 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2097                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2098 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2099 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2100 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2101 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2102 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2103 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2104 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2105
2106 AC_SUBST([ELF_LIB])
2107
2108 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2109 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2110 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2111 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2112 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2113
2114 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2115 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2116 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2117
2118 AC_SUBST([VDPAU_MAJOR], 1)
2119 AC_SUBST([VDPAU_MINOR], 0)
2120
2121 AC_SUBST([XVMC_MAJOR], 1)
2122 AC_SUBST([XVMC_MINOR], 0)
2123
2124 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2125 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2126 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2127 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2128
2129 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2130 AC_SUBST([XA_MINOR], $XA_MINOR)
2131 AC_SUBST([XA_TINY], $XA_TINY)
2132 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2133
2134 dnl Restore LDFLAGS and CPPFLAGS
2135 LDFLAGS="$_SAVE_LDFLAGS"
2136 CPPFLAGS="$_SAVE_CPPFLAGS"
2137
2138 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2139 if test "x$acv_mesa_CLANG" = xyes; then
2140     CFLAGS="$CFLAGS -Qunused-arguments"
2141     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2142 fi
2143
2144 dnl Add user CFLAGS and CXXFLAGS
2145 CFLAGS="$CFLAGS $USER_CFLAGS"
2146 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2147
2148 dnl Substitute the config
2149 AC_CONFIG_FILES([Makefile
2150                 src/Makefile
2151                 src/egl/drivers/dri2/Makefile
2152                 src/egl/main/Makefile
2153                 src/egl/main/egl.pc
2154                 src/egl/wayland/Makefile
2155                 src/egl/wayland/wayland-drm/Makefile
2156                 src/egl/wayland/wayland-egl/Makefile
2157                 src/egl/wayland/wayland-egl/wayland-egl.pc
2158                 src/gallium/auxiliary/Makefile
2159                 src/gallium/auxiliary/pipe-loader/Makefile
2160                 src/gallium/drivers/Makefile
2161                 src/gallium/drivers/freedreno/Makefile
2162                 src/gallium/drivers/galahad/Makefile
2163                 src/gallium/drivers/i915/Makefile
2164                 src/gallium/drivers/identity/Makefile
2165                 src/gallium/drivers/ilo/Makefile
2166                 src/gallium/drivers/llvmpipe/Makefile
2167                 src/gallium/drivers/noop/Makefile
2168                 src/gallium/drivers/nouveau/Makefile
2169                 src/gallium/drivers/r300/Makefile
2170                 src/gallium/drivers/r600/Makefile
2171                 src/gallium/drivers/radeon/Makefile
2172                 src/gallium/drivers/radeonsi/Makefile
2173                 src/gallium/drivers/rbug/Makefile
2174                 src/gallium/drivers/softpipe/Makefile
2175                 src/gallium/drivers/svga/Makefile
2176                 src/gallium/drivers/trace/Makefile
2177                 src/gallium/state_trackers/Makefile
2178                 src/gallium/state_trackers/clover/Makefile
2179                 src/gallium/state_trackers/dri/Makefile
2180                 src/gallium/state_trackers/dri/drm/Makefile
2181                 src/gallium/state_trackers/dri/sw/Makefile
2182                 src/gallium/state_trackers/egl/Makefile
2183                 src/gallium/state_trackers/gbm/Makefile
2184                 src/gallium/state_trackers/glx/xlib/Makefile
2185                 src/gallium/state_trackers/omx/Makefile
2186                 src/gallium/state_trackers/osmesa/Makefile
2187                 src/gallium/state_trackers/vdpau/Makefile
2188                 src/gallium/state_trackers/vega/Makefile
2189                 src/gallium/state_trackers/xa/Makefile
2190                 src/gallium/state_trackers/xvmc/Makefile
2191                 src/gallium/targets/Makefile
2192                 src/gallium/targets/dri-freedreno/Makefile
2193                 src/gallium/targets/dri-i915/Makefile
2194                 src/gallium/targets/dri-ilo/Makefile
2195                 src/gallium/targets/dri-nouveau/Makefile
2196                 src/gallium/targets/dri-swrast/Makefile
2197                 src/gallium/targets/dri-vmwgfx/Makefile
2198                 src/gallium/targets/egl-static/Makefile
2199                 src/gallium/targets/gbm/Makefile
2200                 src/gallium/targets/opencl/Makefile
2201                 src/gallium/targets/xa/Makefile
2202                 src/gallium/targets/xa/xatracker.pc
2203                 src/gallium/targets/omx-nouveau/Makefile
2204                 src/gallium/targets/osmesa/Makefile
2205                 src/gallium/targets/osmesa/osmesa.pc
2206                 src/gallium/targets/pipe-loader/Makefile
2207                 src/gallium/targets/radeonsi/dri/Makefile
2208                 src/gallium/targets/radeonsi/omx/Makefile
2209                 src/gallium/targets/radeonsi/vdpau/Makefile
2210                 src/gallium/targets/r300/dri/Makefile
2211                 src/gallium/targets/r600/dri/Makefile
2212                 src/gallium/targets/r600/omx/Makefile
2213                 src/gallium/targets/r600/vdpau/Makefile
2214                 src/gallium/targets/r600/xvmc/Makefile
2215                 src/gallium/targets/libgl-xlib/Makefile
2216                 src/gallium/targets/vdpau-nouveau/Makefile
2217                 src/gallium/targets/xvmc-nouveau/Makefile
2218                 src/gallium/tests/trivial/Makefile
2219                 src/gallium/tests/unit/Makefile
2220                 src/gallium/winsys/Makefile
2221                 src/gallium/winsys/freedreno/drm/Makefile
2222                 src/gallium/winsys/i915/drm/Makefile
2223                 src/gallium/winsys/i915/sw/Makefile
2224                 src/gallium/winsys/intel/drm/Makefile
2225                 src/gallium/winsys/nouveau/drm/Makefile
2226                 src/gallium/winsys/radeon/drm/Makefile
2227                 src/gallium/winsys/svga/drm/Makefile
2228                 src/gallium/winsys/sw/dri/Makefile
2229                 src/gallium/winsys/sw/fbdev/Makefile
2230                 src/gallium/winsys/sw/null/Makefile
2231                 src/gallium/winsys/sw/wayland/Makefile
2232                 src/gallium/winsys/sw/wrapper/Makefile
2233                 src/gallium/winsys/sw/xlib/Makefile
2234                 src/gbm/Makefile
2235                 src/gbm/main/gbm.pc
2236                 src/glsl/Makefile
2237                 src/glx/Makefile
2238                 src/glx/tests/Makefile
2239                 src/gtest/Makefile
2240                 src/loader/Makefile
2241                 src/mapi/Makefile
2242                 src/mapi/es1api/Makefile
2243                 src/mapi/es1api/glesv1_cm.pc
2244                 src/mapi/es2api/Makefile
2245                 src/mapi/es2api/glesv2.pc
2246                 src/mapi/glapi/Makefile
2247                 src/mapi/glapi/gen/Makefile
2248                 src/mapi/glapi/tests/Makefile
2249                 src/mapi/shared-glapi/Makefile
2250                 src/mapi/shared-glapi/tests/Makefile
2251                 src/mapi/vgapi/Makefile
2252                 src/mapi/vgapi/vg.pc
2253                 src/mesa/Makefile
2254                 src/mesa/gl.pc
2255                 src/mesa/drivers/dri/dri.pc
2256                 src/mesa/drivers/dri/common/Makefile
2257                 src/mesa/drivers/dri/common/xmlpool/Makefile
2258                 src/mesa/drivers/dri/i915/Makefile
2259                 src/mesa/drivers/dri/i965/Makefile
2260                 src/mesa/drivers/dri/Makefile
2261                 src/mesa/drivers/dri/nouveau/Makefile
2262                 src/mesa/drivers/dri/r200/Makefile
2263                 src/mesa/drivers/dri/radeon/Makefile
2264                 src/mesa/drivers/dri/swrast/Makefile
2265                 src/mesa/drivers/osmesa/Makefile
2266                 src/mesa/drivers/osmesa/osmesa.pc
2267                 src/mesa/drivers/x11/Makefile
2268                 src/mesa/main/tests/Makefile
2269                 src/mesa/main/tests/hash_table/Makefile])
2270
2271 dnl Sort the dirs alphabetically
2272 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2273 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2274 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2275 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2276
2277 AC_OUTPUT
2278
2279 dnl
2280 dnl Output some configuration info for the user
2281 dnl
2282 echo ""
2283 echo "        prefix:          $prefix"
2284 echo "        exec_prefix:     $exec_prefix"
2285 echo "        libdir:          $libdir"
2286 echo "        includedir:      $includedir"
2287
2288 dnl API info
2289 echo ""
2290 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2291 echo "        OpenVG:          $enable_openvg"
2292
2293 dnl Driver info
2294 echo ""
2295 case "x$enable_osmesa$enable_gallium_osmesa" in
2296 xnoyes)
2297         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2298         ;;
2299 xyesno)
2300         echo "        OSMesa:          lib$OSMESA_LIB"
2301         ;;
2302 xnono)
2303         echo "        OSMesa:          no"
2304         ;;
2305 esac
2306
2307 echo ""
2308 if test "x$enable_dri" != xno; then
2309         echo "        DRI platform:    $dri_platform"
2310         if test -z "$DRI_DIRS"; then
2311             echo "        DRI drivers:     no"
2312         else
2313             echo "        DRI drivers:     $DRI_DIRS"
2314         fi
2315         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2316 fi
2317
2318 case "x$enable_glx$enable_xlib_glx" in
2319 xyesyes)
2320     echo "        GLX:             Xlib-based"
2321     ;;
2322 xyesno)
2323     echo "        GLX:             DRI-based"
2324     ;;
2325 *)
2326     echo "        GLX:             $enable_glx"
2327     ;;
2328 esac
2329
2330 dnl EGL
2331 echo ""
2332 echo "        EGL:             $enable_egl"
2333 if test "$enable_egl" = yes; then
2334     echo "        EGL platforms:   $egl_platforms"
2335
2336     egl_drivers=""
2337     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2338         egl_drivers="$egl_drivers builtin:egl_dri2"
2339     fi
2340
2341     if test "x$enable_gallium_egl" = xyes; then
2342         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2343         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2344     else
2345         echo "        EGL drivers:    $egl_drivers"
2346     fi
2347 fi
2348
2349 echo ""
2350 if test "x$MESA_LLVM" = x1; then
2351     echo "        llvm:            yes"
2352     echo "        llvm-config:     $LLVM_CONFIG"
2353     echo "        llvm-version:    $LLVM_VERSION"
2354 else
2355     echo "        llvm:            no"
2356 fi
2357
2358 echo ""
2359 if test -n "$with_gallium_drivers"; then
2360     echo "        Gallium:         yes"
2361     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2362     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2363     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2364     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2365 else
2366     echo "        Gallium:         no"
2367 fi
2368
2369
2370 dnl Libraries
2371 echo ""
2372 echo "        Shared libs:     $enable_shared"
2373 echo "        Static libs:     $enable_static"
2374 echo "        Shared-glapi:    $enable_shared_glapi"
2375
2376 dnl Compiler options
2377 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2378 cflags=`echo $CFLAGS | \
2379     $SED 's/^ *//;s/  */ /;s/ *$//'`
2380 cxxflags=`echo $CXXFLAGS | \
2381     $SED 's/^ *//;s/  */ /;s/ *$//'`
2382 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2383 echo ""
2384 echo "        CFLAGS:          $cflags"
2385 echo "        CXXFLAGS:        $cxxflags"
2386 echo "        Macros:          $defines"
2387 echo ""
2388 if test "x$MESA_LLVM" = x1; then
2389     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2390     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2391     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2392     echo ""
2393 fi
2394 echo "        PYTHON2:         $PYTHON2"
2395
2396 echo ""
2397 echo "        Run '${MAKE-make}' to build Mesa"
2398 echo ""