configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl compatibility symlinks
 320 dnl
 321 case "$host_os" in
 322 linux* )
 323     HAVE_COMPAT_SYMLINKS=yes ;;
 324 * )
 325     HAVE_COMPAT_SYMLINKS=no ;;
 326 esac
 327
 328 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 329
 330 dnl
 331 dnl library names
 332 dnl
 333 case "$host_os" in
 334 darwin* )
 335     LIB_EXT='dylib' ;;
 336 cygwin* )
 337     LIB_EXT='dll' ;;
 338 aix* )
 339     LIB_EXT='a' ;;
 340 * )
 341     LIB_EXT='so' ;;
 342 esac
 343
 344 AC_SUBST([LIB_EXT])
 345
 346 AC_ARG_WITH([gl-lib-name],
 347   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 348     [specify GL library name @<:@default=GL@:>@])],
 349   [GL_LIB=$withval],
 350   [GL_LIB=GL])
 351 AC_ARG_WITH([osmesa-lib-name],
 352   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 353     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 354   [OSMESA_LIB=$withval],
 355   [OSMESA_LIB=OSMesa])
 356 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 357 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 358
 359 dnl
 360 dnl Mangled Mesa support
 361 dnl
 362 AC_ARG_ENABLE([mangling],
 363   [AS_HELP_STRING([--enable-mangling],
 364     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 365   [enable_mangling="${enableval}"],
 366   [enable_mangling=no]
 367 )
 368 if test "x${enable_mangling}" = "xyes" ; then
 369   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 370   GL_LIB="Mangled${GL_LIB}"
 371   OSMESA_LIB="Mangled${OSMESA_LIB}"
 372 fi
 373 AC_SUBST([GL_LIB])
 374 AC_SUBST([OSMESA_LIB])
 375
 376 dnl
 377 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 378 dnl
 379 AC_ARG_ENABLE([texture-float],
 380     [AS_HELP_STRING([--enable-texture-float],
 381         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 382     [enable_texture_float="$enableval"],
 383     [enable_texture_float=no]
 384 )
 385 if test "x$enable_texture_float" = xyes; then
 386     AC_MSG_WARN([Floating-point textures enabled.])
 387     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 388     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 389 fi
 390
 391 dnl
 392 dnl Arch/platform-specific settings
 393 dnl
 394 AC_ARG_ENABLE([asm],
 395     [AS_HELP_STRING([--disable-asm],
 396         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 397     [enable_asm="$enableval"],
 398     [enable_asm=yes]
 399 )
 400 asm_arch=""
 401 AC_MSG_CHECKING([whether to enable assembly])
 402 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 403 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 404 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 405     case "$host_cpu" in
 406     i?86 | x86_64 | amd64)
 407         enable_asm=no
 408         AC_MSG_RESULT([no, cross compiling])
 409         ;;
 410     esac
 411 fi
 412 # check for supported arches
 413 if test "x$enable_asm" = xyes; then
 414     case "$host_cpu" in
 415     i?86)
 416         case "$host_os" in
 417         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 418             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 419             ;;
 420         gnu*)
 421             asm_arch=x86
 422             ;;
 423         esac
 424         ;;
 425     x86_64|amd64)
 426         case "$host_os" in
 427         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 428             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 429             ;;
 430         esac
 431         ;;
 432     sparc*)
 433         case "$host_os" in
 434         linux*)
 435             asm_arch=sparc
 436             ;;
 437         esac
 438         ;;
 439     esac
 440
 441     case "$asm_arch" in
 442     x86)
 443         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 444         AC_MSG_RESULT([yes, x86])
 445         ;;
 446     x86_64|amd64)
 447         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 448         AC_MSG_RESULT([yes, x86_64])
 449         ;;
 450     sparc)
 451         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 452         AC_MSG_RESULT([yes, sparc])
 453         ;;
 454     *)
 455         AC_MSG_RESULT([no, platform not supported])
 456         ;;
 457     esac
 458 fi
 459
 460 dnl Check to see if dlopen is in default libraries (like Solaris, which
 461 dnl has it in libc), or if libdl is needed to get it.
 462 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 463     [AC_CHECK_LIB([dl], [dlopen],
 464        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 465 AC_SUBST([DLOPEN_LIBS])
 466
 467 case "$host_os" in
 468 darwin*|mingw*)
 469     ;;
 470 *)
 471     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 472                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 473                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 474     AC_SUBST([CLOCK_LIB])
 475     ;;
 476 esac
 477
 478 dnl See if posix_memalign is available
 479 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 480
 481 dnl Check for pthreads
 482 AX_PTHREAD
 483 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 484 dnl to -pthread, which causes problems if we need -lpthread to appear in
 485 dnl pkgconfig files.
 486 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 487
 488 dnl SELinux awareness.
 489 AC_ARG_ENABLE([selinux],
 490     [AS_HELP_STRING([--enable-selinux],
 491         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 492     [MESA_SELINUX="$enableval"],
 493     [MESA_SELINUX=no])
 494 if test "x$enable_selinux" = "xyes"; then
 495     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 496         [AC_CHECK_HEADER([selinux/selinux.h],[],
 497                          [AC_MSG_ERROR([SELinux headers not found])])
 498          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 499                       [AC_MSG_ERROR([SELinux library not found])])
 500          SELINUX_LIBS="-lselinux"])
 501     DEFINES="$DEFINES -DMESA_SELINUX"
 502 fi
 503 AC_SUBST([SELINUX_CFLAGS])
 504 AC_SUBST([SELINUX_LIBS])
 505
 506 dnl Options for APIs
 507 AC_ARG_ENABLE([opengl],
 508     [AS_HELP_STRING([--disable-opengl],
 509         [disable support for standard OpenGL API @<:@default=no@:>@])],
 510     [enable_opengl="$enableval"],
 511     [enable_opengl=yes])
 512 AC_ARG_ENABLE([gles1],
 513     [AS_HELP_STRING([--enable-gles1],
 514         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 515     [enable_gles1="$enableval"],
 516     [enable_gles1=no])
 517 AC_ARG_ENABLE([gles2],
 518     [AS_HELP_STRING([--enable-gles2],
 519         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 520     [enable_gles2="$enableval"],
 521     [enable_gles2=no])
 522 AC_ARG_ENABLE([openvg],
 523     [AS_HELP_STRING([--enable-openvg],
 524         [enable support for OpenVG API @<:@default=no@:>@])],
 525     [enable_openvg="$enableval"],
 526     [enable_openvg=no])
 527
 528 AC_ARG_ENABLE([dri],
 529     [AS_HELP_STRING([--enable-dri],
 530         [enable DRI modules @<:@default=enabled@:>@])],
 531     [enable_dri="$enableval"],
 532     [enable_dri=yes])
 533
 534 case "$host_os" in
 535 linux*)
 536     dri3_default=yes
 537     ;;
 538 *)
 539     dri3_default=no
 540     ;;
 541 esac
 542 AC_ARG_ENABLE([dri3],
 543     [AS_HELP_STRING([--enable-dri3],
 544         [enable DRI3 @<:@default=auto@:>@])],
 545     [enable_dri3="$enableval"],
 546     [enable_dri3="$dri3_default"])
 547 AC_ARG_ENABLE([glx],
 548     [AS_HELP_STRING([--enable-glx],
 549         [enable GLX library @<:@default=enabled@:>@])],
 550     [enable_glx="$enableval"],
 551     [enable_glx=yes])
 552 AC_ARG_ENABLE([osmesa],
 553     [AS_HELP_STRING([--enable-osmesa],
 554         [enable OSMesa library @<:@default=disabled@:>@])],
 555     [enable_osmesa="$enableval"],
 556     [enable_osmesa=no])
 557 AC_ARG_ENABLE([gallium-osmesa],
 558     [AS_HELP_STRING([--enable-gallium-osmesa],
 559         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 560     [enable_gallium_osmesa="$enableval"],
 561     [enable_gallium_osmesa=no])
 562 AC_ARG_ENABLE([egl],
 563     [AS_HELP_STRING([--disable-egl],
 564         [disable EGL library @<:@default=enabled@:>@])],
 565     [enable_egl="$enableval"],
 566     [enable_egl=yes])
 567
 568 AC_ARG_ENABLE([xa],
 569     [AS_HELP_STRING([--enable-xa],
 570         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 571     [enable_xa="$enableval"],
 572     [enable_xa=no])
 573 AC_ARG_ENABLE([gbm],
 574    [AS_HELP_STRING([--enable-gbm],
 575          [enable gbm library @<:@default=auto@:>@])],
 576    [enable_gbm="$enableval"],
 577    [enable_gbm=auto])
 578
 579 AC_ARG_ENABLE([xvmc],
 580    [AS_HELP_STRING([--enable-xvmc],
 581          [enable xvmc library @<:@default=auto@:>@])],
 582    [enable_xvmc="$enableval"],
 583    [enable_xvmc=no])
 584 AC_ARG_ENABLE([vdpau],
 585    [AS_HELP_STRING([--enable-vdpau],
 586          [enable vdpau library @<:@default=auto@:>@])],
 587    [enable_vdpau="$enableval"],
 588    [enable_vdpau=auto])
 589 AC_ARG_ENABLE([omx],
 590    [AS_HELP_STRING([--enable-omx],
 591          [enable OpenMAX library @<:@default=no@:>@])],
 592    [enable_omx="$enableval"],
 593    [enable_omx=no])
 594 AC_ARG_ENABLE([opencl],
 595    [AS_HELP_STRING([--enable-opencl],
 596          [enable OpenCL library @<:@default=no@:>@])],
 597    [enable_opencl="$enableval"],
 598    [enable_opencl=no])
 599 AC_ARG_ENABLE([opencl_icd],
 600    [AS_HELP_STRING([--enable-opencl-icd],
 601           [Build an OpenCL ICD library to be loaded by an ICD implementation
 602            @<:@default=no@:>@])],
 603     [enable_opencl_icd="$enableval"],
 604     [enable_opencl_icd=no])
 605 AC_ARG_ENABLE([xlib-glx],
 606     [AS_HELP_STRING([--enable-xlib-glx],
 607         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 608     [enable_xlib_glx="$enableval"],
 609     [enable_xlib_glx=no])
 610 AC_ARG_ENABLE([gallium-egl],
 611     [AS_HELP_STRING([--enable-gallium-egl],
 612         [enable optional EGL state tracker (not required
 613          for EGL support in Gallium with OpenGL and OpenGL ES)
 614          @<:@default=disable@:>@])],
 615     [enable_gallium_egl="$enableval"],
 616     [enable_gallium_egl=no])
 617 AC_ARG_ENABLE([gallium-gbm],
 618     [AS_HELP_STRING([--enable-gallium-gbm],
 619         [enable optional gbm state tracker (not required for
 620          gbm support in Gallium)
 621          @<:@default=auto@:>@])],
 622     [enable_gallium_gbm="$enableval"],
 623     [enable_gallium_gbm=auto])
 624
 625 AC_ARG_ENABLE([r600-llvm-compiler],
 626     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 627         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 628     [enable_r600_llvm="$enableval"],
 629     [enable_r600_llvm=no])
 630
 631 AC_ARG_ENABLE([gallium-tests],
 632     [AS_HELP_STRING([--enable-gallium-tests],
 633         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 634     [enable_gallium_tests="$enableval"],
 635     [enable_gallium_tests=no])
 636
 637 # Option for Gallium drivers
 638
 639 # Keep this in sync with the --with-gallium-drivers help string default value
 640 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 641
 642 AC_ARG_WITH([gallium-drivers],
 643     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 644         [comma delimited Gallium drivers list, e.g.
 645         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 646         @<:@default=r300,r600,svga,swrast@:>@])],
 647     [with_gallium_drivers="$withval"],
 648     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 649
 650 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 651 # here so that the script doesn't choke on an unknown driver name later.
 652 case "$with_gallium_drivers" in
 653     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 654     no) with_gallium_drivers='' ;;
 655 esac
 656
 657 if test "x$enable_opengl" = xno -a \
 658         "x$enable_gles1" = xno -a \
 659         "x$enable_gles2" = xno -a \
 660         "x$enable_openvg" = xno -a \
 661         "x$enable_xa" = xno -a \
 662         "x$enable_xvmc" = xno -a \
 663         "x$enable_vdpau" = xno -a \
 664         "x$enable_omx" = xno -a \
 665         "x$enable_opencl" = xno; then
 666     AC_MSG_ERROR([at least one API should be enabled])
 667 fi
 668
 669 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 670 if test "x$enable_opengl" = xno -a \
 671         "x$enable_gles1" = xyes; then
 672     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 673 fi
 674
 675 if test "x$enable_opengl" = xno -a \
 676         "x$enable_gles2" = xyes; then
 677     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 678 fi
 679
 680 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 681 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 682 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 683 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 684                                         "x$enable_gles1" = xyes -o \
 685                                         "x$enable_gles2" = xyes)
 686
 687 if test "x$enable_glx" = xno; then
 688     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 689     enable_xlib_glx=no
 690 fi
 691
 692 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 693     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 694 fi
 695
 696 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 697     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 698 fi
 699
 700 # Disable GLX if OpenGL is not enabled
 701 if test "x$enable_glx$enable_opengl" = xyesno; then
 702     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 703     enable_glx=no
 704 fi
 705
 706 # Disable GLX if DRI and Xlib-GLX are not enabled
 707 if test "x$enable_glx" = xyes -a \
 708         "x$enable_dri" = xno -a \
 709         "x$enable_xlib_glx" = xno; then
 710     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 711     enable_glx=no
 712 fi
 713
 714 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 715                                   "x$enable_dri" = xyes)
 716 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 717 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 718
 719 AC_ARG_ENABLE([shared-glapi],
 720     [AS_HELP_STRING([--enable-shared-glapi],
 721         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 722     [enable_shared_glapi="$enableval"],
 723     [enable_shared_glapi=yes])
 724
 725 case "x$enable_opengl$enable_gles1$enable_gles2" in
 726 x*yes*yes*)
 727     if test "x$enable_shared_glapi" = xno; then
 728         AC_MSG_ERROR([shared GLAPI required when building two or more of
 729                       the following APIs - opengl, gles1 gles2])
 730     fi
 731     ;;
 732 esac
 733
 734 # Building Xlib-GLX requires shared glapi to be disabled.
 735 if test "x$enable_xlib_glx" = xyes; then
 736     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 737     enable_shared_glapi=no
 738 fi
 739
 740 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 741
 742 dnl
 743 dnl Driver specific build directories
 744 dnl
 745 GALLIUM_TARGET_DIRS=""
 746 GALLIUM_WINSYS_DIRS="sw"
 747 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 748 GALLIUM_STATE_TRACKERS_DIRS=""
 749
 750 case "x$enable_glx$enable_xlib_glx" in
 751 xyesyes)
 752     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 753     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 754     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 755     NEED_WINSYS_XLIB="yes"
 756     ;;
 757 esac
 758
 759 if test "x$enable_dri" = xyes; then
 760     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 761     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 762 fi
 763
 764 if test "x$enable_gallium_osmesa" = xyes; then
 765     if test -z "$with_gallium_drivers"; then
 766         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 767     fi
 768     if test "x$enable_osmesa" = xyes; then
 769         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 770     fi
 771     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 772     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 773 fi
 774
 775 AC_SUBST([MESA_LLVM])
 776
 777 # Check for libdrm
 778 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 779                   [have_libdrm=yes], [have_libdrm=no])
 780 if test "x$have_libdrm" = xyes; then
 781         DEFINES="$DEFINES -DHAVE_LIBDRM"
 782 fi
 783
 784 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 785                   have_libudev=yes, have_libudev=no)
 786
 787 if test "x$enable_dri" = xyes; then
 788     if test "$enable_static" = yes; then
 789         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 790     fi
 791
 792     # not a hard requirement as swrast does not depend on it
 793     if test "x$have_libdrm" = xyes; then
 794         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 795     fi
 796 fi
 797
 798 dnl Direct rendering or just indirect rendering
 799 case "$host_os" in
 800 gnu*)
 801     dnl Disable by default on GNU/Hurd
 802     driglx_direct_default="no"
 803     ;;
 804 cygwin*)
 805     dnl Disable by default on cygwin
 806     driglx_direct_default="no"
 807     ;;
 808 *)
 809     driglx_direct_default="yes"
 810     ;;
 811 esac
 812 AC_ARG_ENABLE([driglx-direct],
 813     [AS_HELP_STRING([--disable-driglx-direct],
 814         [disable direct rendering in GLX and EGL for DRI \
 815             @<:@default=auto@:>@])],
 816     [driglx_direct="$enableval"],
 817     [driglx_direct="$driglx_direct_default"])
 818
 819 dnl
 820 dnl libGL configuration per driver
 821 dnl
 822 case "x$enable_glx$enable_xlib_glx" in
 823 xyesyes)
 824     # Xlib-based GLX
 825     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 826     GL_PC_REQ_PRIV="x11 xext"
 827     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 828     GL_LIB_DEPS="$XLIBGL_LIBS"
 829     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 830     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 831     ;;
 832 xyesno)
 833     # DRI-based GLX
 834     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 835     if test x"$driglx_direct" = xyes; then
 836         if test "x$have_libdrm" != xyes; then
 837             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 838         fi
 839         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 840         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 841         if test x"$enable_dri3" = xyes; then
 842             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 843             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 844         fi
 845     fi
 846
 847     # find the DRI deps for libGL
 848     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 849
 850     if test x"$enable_dri3" = xyes; then
 851         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 852     fi
 853
 854     # add xf86vidmode if available
 855     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 856     if test "$HAVE_XF86VIDMODE" = yes ; then
 857         dri_modules="$dri_modules xxf86vm"
 858     fi
 859
 860     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 861     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 862     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 863     GL_LIB_DEPS="$DRIGL_LIBS"
 864
 865     # need DRM libs, $PTHREAD_LIBS, etc.
 866     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 867     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 868     ;;
 869 esac
 870
 871 if test "$have_libudev" = yes; then
 872     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 873 fi
 874
 875 # This is outside the case (above) so that it is invoked even for non-GLX
 876 # builds.
 877 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 878
 879 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 880 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 881 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 882 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 883
 884 AC_SUBST([X11_INCLUDES])
 885 AC_SUBST([GL_LIB_DEPS])
 886 AC_SUBST([GL_PC_REQ_PRIV])
 887 AC_SUBST([GL_PC_LIB_PRIV])
 888 AC_SUBST([GL_PC_CFLAGS])
 889 AC_SUBST([DRI_PC_REQ_PRIV])
 890 AC_SUBST([GLESv1_CM_LIB_DEPS])
 891 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 892 AC_SUBST([GLESv2_LIB_DEPS])
 893 AC_SUBST([GLESv2_PC_LIB_PRIV])
 894
 895 AC_SUBST([HAVE_XF86VIDMODE])
 896
 897 dnl
 898 dnl More GLX setup
 899 dnl
 900 case "x$enable_glx$enable_xlib_glx" in
 901 xyesyes)
 902     DEFINES="$DEFINES -DUSE_XSHM"
 903     ;;
 904 xyesno)
 905     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 906     if test "x$driglx_direct" = xyes; then
 907         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 908     fi
 909     ;;
 910 esac
 911
 912 dnl
 913 dnl TLS detection
 914 dnl
 915
 916 AC_ARG_ENABLE([glx-tls],
 917     [AS_HELP_STRING([--enable-glx-tls],
 918         [enable TLS support in GLX @<:@default=disabled@:>@])],
 919     [GLX_USE_TLS="$enableval"],
 920     [GLX_USE_TLS=no])
 921 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 922
 923 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 924       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 925
 926 dnl
 927 dnl More DRI setup
 928 dnl
 929 dnl Directory for DRI drivers
 930 AC_ARG_WITH([dri-driverdir],
 931     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 932         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 933     [DRI_DRIVER_INSTALL_DIR="$withval"],
 934     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 935 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 936 dnl Extra search path for DRI drivers
 937 AC_ARG_WITH([dri-searchpath],
 938     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 939         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 940     [DRI_DRIVER_SEARCH_DIR="$withval"],
 941     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 942 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 943 dnl Which drivers to build - default is chosen by platform
 944 AC_ARG_WITH([dri-drivers],
 945     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 946         [comma delimited classic DRI drivers list, e.g.
 947         "swrast,i965,radeon" @<:@default=auto@:>@])],
 948     [with_dri_drivers="$withval"],
 949     [with_dri_drivers=auto])
 950
 951 if test "x$with_dri_drivers" = xauto; then
 952     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 953         with_dri_drivers="yes"
 954     else
 955         with_dri_drivers="no"
 956     fi
 957 fi
 958 if test "x$with_dri_drivers" = xno; then
 959     with_dri_drivers=''
 960 fi
 961
 962 dnl If $with_dri_drivers is yes, drivers will be added through
 963 dnl platform checks. Set DEFINES and LIB_DEPS
 964 if test "x$enable_dri" = xyes; then
 965     # Platform specific settings and drivers to build
 966     case "$host_os" in
 967     linux*)
 968         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 969         DEFINES="$DEFINES -DHAVE_ALIAS"
 970         if test "x$enable_dri3" = xyes; then
 971             DEFINES="$DEFINES -DHAVE_DRI3"
 972         fi
 973
 974         if test "x$have_libudev" != xyes; then
 975             AC_MSG_ERROR([libudev-dev required for building DRI])
 976         fi
 977
 978         case "$host_cpu" in
 979         powerpc* | sparc*)
 980             # Build only the drivers for cards that exist on PowerPC/sparc
 981             if test "x$with_dri_drivers" = "xyes"; then
 982                 with_dri_drivers="r200 radeon swrast"
 983             fi
 984             ;;
 985         esac
 986         ;;
 987     *freebsd* | dragonfly* | *netbsd* | openbsd*)
 988         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 989         DEFINES="$DEFINES -DHAVE_ALIAS"
 990         ;;
 991     gnu*)
 992         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 993         DEFINES="$DEFINES -DHAVE_ALIAS"
 994         ;;
 995     solaris*)
 996         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 997         ;;
 998     cygwin*)
 999         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1000         if test "x$with_dri_drivers" = "xyes"; then
1001             with_dri_drivers="swrast"
1002         fi
1003         ;;
1004     esac
1005
1006     # default drivers
1007     if test "x$with_dri_drivers" = "xyes"; then
1008         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1009     fi
1010
1011     # Check for expat
1012     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1013     if test "x$have_expat" = "xyes"; then
1014        PKG_CHECK_MODULES([EXPAT], [expat], [],
1015                          AC_MSG_ERROR([Expat required for DRI.]))
1016     else
1017        # expat version 2.0 and earlier do not provide expat.pc
1018        EXPAT_LIBS=-lexpat
1019     fi
1020
1021     # If we are building any DRI driver other than swrast.
1022     if test -n "$with_dri_drivers"; then
1023         if test "x$with_dri_drivers" != xswrast; then
1024             # ... libdrm is required
1025             if test "x$have_libdrm" != xyes; then
1026                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1027             fi
1028             DRICOMMON_NEED_LIBDRM=yes
1029         else
1030             DRICOMMON_NEED_LIBDRM=no
1031         fi
1032     fi
1033
1034     # put all the necessary libs together
1035     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1036     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1037
1038 fi
1039
1040 AC_SUBST([DRI_LIB_DEPS])
1041 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1042
1043 DRI_DIRS=''
1044 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1045 if test -n "$with_dri_drivers"; then
1046     if test "x$enable_opengl" != xyes; then
1047         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1048     fi
1049
1050     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1051     for driver in $dri_drivers; do
1052         DRI_DIRS="$DRI_DIRS $driver"
1053         case "x$driver" in
1054         xi915)
1055             HAVE_I915_DRI=yes;
1056             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1057             ;;
1058         xi965)
1059             HAVE_I965_DRI=yes;
1060             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1061             ;;
1062         xnouveau)
1063             HAVE_NOUVEAU_DRI=yes;
1064             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1065             ;;
1066         xradeon)
1067             HAVE_RADEON_DRI=yes;
1068             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1069             ;;
1070         xr200)
1071             HAVE_R200_DRI=yes;
1072             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1073             ;;
1074         xswrast)
1075             HAVE_SWRAST_DRI=yes;
1076             ;;
1077         *)
1078             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1079             ;;
1080         esac
1081     done
1082     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1083 fi
1084
1085 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1086 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1087                                   "x$enable_osmesa" = xyes -o \
1088                                   -n "$DRI_DIRS")
1089
1090 dnl
1091 dnl OSMesa configuration
1092 dnl
1093
1094 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1095 AC_ARG_WITH([osmesa-bits],
1096     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1097         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1098     [osmesa_bits="$withval"],
1099     [osmesa_bits=8])
1100 if test "x$osmesa_bits" != x8; then
1101     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1102         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1103         osmesa_bits=8
1104     fi
1105 fi
1106 case "x$osmesa_bits" in
1107 x8)
1108     OSMESA_LIB="${OSMESA_LIB}"
1109     ;;
1110 x16|x32)
1111     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1112     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1113     ;;
1114 *)
1115     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1116     ;;
1117 esac
1118
1119 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1120     # only link libraries with osmesa if shared
1121     if test "$enable_static" = no; then
1122         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1123     else
1124         OSMESA_LIB_DEPS=""
1125     fi
1126     OSMESA_MESA_DEPS=""
1127     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1128 fi
1129
1130 AC_SUBST([OSMESA_LIB_DEPS])
1131 AC_SUBST([OSMESA_MESA_DEPS])
1132 AC_SUBST([OSMESA_PC_REQ])
1133 AC_SUBST([OSMESA_PC_LIB_PRIV])
1134
1135 dnl
1136 dnl gbm configuration
1137 dnl
1138 if test "x$enable_gbm" = xauto; then
1139     case "$with_egl_platforms" in
1140         *drm*)
1141             enable_gbm=yes ;;
1142          *)
1143             enable_gbm=no ;;
1144     esac
1145 fi
1146 if test "x$enable_gbm" = xyes; then
1147     if test x"$have_libudev" != xyes; then
1148         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1149     fi
1150
1151     if test "x$enable_dri" = xyes; then
1152         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1153         if test "x$enable_shared_glapi" = xno; then
1154             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1155         fi
1156     fi
1157 fi
1158 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1159 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1160 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1161 AC_SUBST([GBM_PC_REQ_PRIV])
1162 AC_SUBST([GBM_PC_LIB_PRIV])
1163
1164 dnl
1165 dnl EGL configuration
1166 dnl
1167 EGL_CLIENT_APIS=""
1168
1169 if test "x$enable_egl" = xyes; then
1170     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1171
1172     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1173
1174     if test "$enable_static" != yes; then
1175         if test "x$enable_dri" = xyes; then
1176             HAVE_EGL_DRIVER_DRI2=1
1177         fi
1178
1179     fi
1180 fi
1181 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1182 AC_SUBST([EGL_LIB_DEPS])
1183
1184 dnl
1185 dnl EGL Gallium configuration
1186 dnl
1187 if test "x$enable_gallium_egl" = xyes; then
1188     if test -z "$with_gallium_drivers"; then
1189         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1190     fi
1191     if test "x$enable_egl" = xno; then
1192         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1193     fi
1194     if test "x$have_libdrm" != xyes; then
1195         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1196     fi
1197
1198     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1199     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1200 fi
1201 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1202
1203 dnl
1204 dnl gbm Gallium configuration
1205 dnl
1206 if test "x$enable_gallium_gbm" = xauto; then
1207     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1208         yesyesyes*drm*)
1209             enable_gallium_gbm=yes ;;
1210          *)
1211             enable_gallium_gbm=no ;;
1212     esac
1213 fi
1214 if test "x$enable_gallium_gbm" = xyes; then
1215     if test -z "$with_gallium_drivers"; then
1216         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1217     fi
1218     if test "x$enable_gbm" = xno; then
1219         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1220     fi
1221     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1222     if test "x$enable_dri" = xno; then
1223         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1224     fi
1225
1226     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1227     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1228     enable_gallium_loader=yes
1229 fi
1230 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1231
1232 dnl
1233 dnl XA configuration
1234 dnl
1235 if test "x$enable_xa" = xyes; then
1236     if test "x$with_gallium_drivers" = xswrast; then
1237        AC_MSG_ERROR([
1238           Building xa requires at least one non swrast gallium driver.
1239           If you are looking to use libxatracker.so with vmware's virtual gpu,
1240           make sure to include svga in the gallium drivers list, apart from
1241           enabling XA.
1242           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1243     fi
1244     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1245     enable_gallium_loader=yes
1246 fi
1247 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1248
1249 dnl
1250 dnl OpenVG configuration
1251 dnl
1252 VG_LIB_DEPS=""
1253
1254 if test "x$enable_openvg" = xyes; then
1255     if test "x$enable_egl" = xno; then
1256         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1257     fi
1258     if test -z "$with_gallium_drivers"; then
1259         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1260     fi
1261     if test "x$enable_gallium_egl" = xno; then
1262         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1263     fi
1264
1265     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1266     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1267     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1268     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1269     AC_SUBST([VG_PC_LIB_PRIV])
1270 fi
1271 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1272
1273 dnl
1274 dnl Gallium G3DVL configuration
1275 dnl
1276 if test -n "$with_gallium_drivers"; then
1277     if test "x$enable_xvmc" = xauto; then
1278         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1279     fi
1280
1281     if test "x$enable_vdpau" = xauto; then
1282         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1283     fi
1284
1285     if test "x$enable_omx" = xauto; then
1286         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1287     fi
1288 fi
1289
1290 if test "x$enable_xvmc" = xyes; then
1291     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1292     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1293 fi
1294 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1295
1296 if test "x$enable_vdpau" = xyes; then
1297     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1298                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1299     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1300 fi
1301 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1302
1303 if test "x$enable_omx" = xyes; then
1304     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1305     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1306 fi
1307 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1308
1309 dnl
1310 dnl OpenCL configuration
1311 dnl
1312
1313 AC_ARG_WITH([libclc-path],
1314    [AS_HELP_STRING([--with-libclc-path],
1315          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1316    [LIBCLC_PATH="$withval"],
1317    [LIBCLC_PATH=''])
1318
1319 if test -n "$LIBCLC_PATH"; then
1320    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1321                   Please review the updated build instructions for clover:
1322                   http://dri.freedesktop.org/wiki/GalliumCompute])
1323 fi
1324
1325
1326 AC_ARG_WITH([clang-libdir],
1327    [AS_HELP_STRING([--with-clang-libdir],
1328          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1329    [CLANG_LIBDIR="$withval"],
1330    [CLANG_LIBDIR=''])
1331
1332 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1333
1334 if test "x$enable_opencl" = xyes; then
1335     if test -z "$with_gallium_drivers"; then
1336         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1337     fi
1338
1339     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1340         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1341     fi
1342
1343     if test "x$have_libclc" = xno; then
1344         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1345                     Make sure the directory containing libclc.pc is specified in your
1346                     PKG_CONFIG_PATH environment variable.
1347                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1348     else
1349         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1350         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1351         AC_SUBST([LIBCLC_INCLUDEDIR])
1352         AC_SUBST([LIBCLC_LIBEXECDIR])
1353     fi
1354
1355     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1356     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1357     enable_gallium_loader=yes
1358
1359     if test "x$enable_opencl_icd" = xyes; then
1360         OPENCL_LIBNAME="MesaOpenCL"
1361     else
1362         OPENCL_LIBNAME="OpenCL"
1363     fi
1364 fi
1365 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1366 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1367 AC_SUBST([OPENCL_LIBNAME])
1368
1369 dnl
1370 dnl Gallium configuration
1371 dnl
1372 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1373
1374 AC_SUBST([LLVM_BINDIR])
1375 AC_SUBST([LLVM_CFLAGS])
1376 AC_SUBST([LLVM_CPPFLAGS])
1377 AC_SUBST([LLVM_CXXFLAGS])
1378 AC_SUBST([LLVM_LIBDIR])
1379 AC_SUBST([LLVM_LIBS])
1380 AC_SUBST([LLVM_LDFLAGS])
1381 AC_SUBST([LLVM_INCLUDEDIR])
1382 AC_SUBST([LLVM_VERSION])
1383 AC_SUBST([CLANG_RESOURCE_DIR])
1384
1385 case "x$enable_opengl$enable_gles1$enable_gles2" in
1386 x*yes*)
1387     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1388     ;;
1389 esac
1390
1391 AC_SUBST([VG_LIB_DEPS])
1392 AC_SUBST([EGL_CLIENT_APIS])
1393
1394 dnl
1395 dnl EGL Platforms configuration
1396 dnl
1397 AC_ARG_WITH([egl-platforms],
1398     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1399         [comma delimited native platforms libEGL supports, e.g.
1400         "x11,drm" @<:@default=auto@:>@])],
1401     [with_egl_platforms="$withval"],
1402     [if test "x$enable_egl" = xyes; then
1403         with_egl_platforms="x11"
1404     else
1405         with_egl_platforms=""
1406     fi])
1407
1408 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1409     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1410 fi
1411
1412 # Do per-EGL platform setups and checks
1413 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1414 for plat in $egl_platforms; do
1415         case "$plat" in
1416         wayland)
1417                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1418                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1419
1420                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1421                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1422                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1423                 ;;
1424
1425         x11)
1426                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1427                 ;;
1428
1429         drm)
1430                 test "x$enable_gbm" = "xno" &&
1431                         AC_MSG_ERROR([EGL platform drm needs gbm])
1432                 test "x$have_libdrm" != xyes &&
1433                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1434                 ;;
1435
1436         android|fbdev|gdi|null)
1437                 ;;
1438
1439         *)
1440                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1441                 ;;
1442         esac
1443
1444         case "$plat$have_libudev" in
1445                 waylandno|drmno)
1446                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1447         esac
1448 done
1449
1450 # libEGL wants to default to the first platform specified in
1451 # ./configure.  parse that here.
1452 if test "x$egl_platforms" != "x"; then
1453     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1454     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1455 else
1456     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1457 fi
1458
1459 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1460     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1461     NEED_WINSYS_XLIB=yes
1462 fi
1463 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1464 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1465 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1466 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1467 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1468
1469 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1470
1471 AC_SUBST([EGL_NATIVE_PLATFORM])
1472 AC_SUBST([EGL_CFLAGS])
1473
1474 # If we don't have the X11 platform, set this define so we don't try to include
1475 # the X11 headers.
1476 if ! echo "$egl_platforms" | grep -q 'x11'; then
1477     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1478     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1479 fi
1480
1481 AC_ARG_WITH([egl-driver-dir],
1482     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1483                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1484     [EGL_DRIVER_INSTALL_DIR="$withval"],
1485     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1486 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1487
1488 AC_ARG_WITH([max-width],
1489     [AS_HELP_STRING([--with-max-width=N],
1490                     [Maximum framebuffer width (4096)])],
1491     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1492      AS_IF([test "${withval}" -gt "4096"],
1493            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1494 )
1495 AC_ARG_WITH([max-height],
1496     [AS_HELP_STRING([--with-max-height=N],
1497                     [Maximum framebuffer height (4096)])],
1498     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1499      AS_IF([test "${withval}" -gt "4096"],
1500            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1501 )
1502
1503 dnl
1504 dnl Gallium LLVM
1505 dnl
1506 AC_ARG_ENABLE([gallium-llvm],
1507     [AS_HELP_STRING([--enable-gallium-llvm],
1508         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1509     [enable_gallium_llvm="$enableval"],
1510     [enable_gallium_llvm=auto])
1511
1512 AC_ARG_ENABLE([llvm-shared-libs],
1513     [AS_HELP_STRING([--enable-llvm-shared-libs],
1514         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1515     [enable_llvm_shared_libs="$enableval"],
1516     [enable_llvm_shared_libs=yes])
1517
1518 AC_ARG_WITH([llvm-prefix],
1519     [AS_HELP_STRING([--with-llvm-prefix],
1520         [Prefix for LLVM installations in non-standard locations])],
1521     [llvm_prefix="$withval"],
1522     [llvm_prefix=''])
1523
1524
1525 # Call this inside ` ` to get the return value.
1526 # $1 is the llvm-config command with arguments.
1527 strip_unwanted_llvm_flags() {
1528     # Use \> (marks the end of the word)
1529     echo `$1` | sed \
1530         -e 's/-DNDEBUG\>//g' \
1531         -e 's/-pedantic\>//g' \
1532         -e 's/-Wcovered-switch-default\>//g' \
1533         -e 's/-O.\>//g' \
1534         -e 's/-g\>//g' \
1535         -e 's/-Wall\>//g' \
1536         -e 's/-Wcast-qual\>//g' \
1537         -e 's/-Woverloaded-virtual\>//g' \
1538         -e 's/-fcolor-diagnostics\>//g' \
1539         -e 's/-fdata-sections\>//g' \
1540         -e 's/-ffunction-sections\>//g' \
1541         -e 's/-fno-exceptions\>//g' \
1542         -e 's/-fomit-frame-pointer\>//g' \
1543         -e 's/-fvisibility-inlines-hidden\>//g' \
1544         -e 's/-fPIC\>//g'
1545 }
1546
1547
1548 if test -z "$with_gallium_drivers"; then
1549     enable_gallium_llvm=no
1550 fi
1551 if test "x$enable_gallium_llvm" = xauto; then
1552     case "$host_cpu" in
1553     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1554     esac
1555 fi
1556 if test "x$enable_gallium_llvm" = xyes; then
1557     if test -n "$llvm_prefix"; then
1558         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1559     else
1560         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1561     fi
1562
1563     if test "x$LLVM_CONFIG" != xno; then
1564         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1565         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1566         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1567         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1568         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1569         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1570         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1571         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1572
1573         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1574             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1575         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1576             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1577
1578         if test -n "${LLVM_VERSION_MAJOR}"; then
1579             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1580         else
1581             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1582         fi
1583
1584         LLVM_COMPONENTS="engine bitwriter"
1585         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1586             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1587         fi
1588
1589         if test "x$enable_opencl" = xyes; then
1590             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1591             # LLVM 3.3 >= 177971 requires IRReader
1592             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1593                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1594             fi
1595             # LLVM 3.4 requires Option
1596             if $LLVM_CONFIG --components | grep -qw 'option'; then
1597                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1598             fi
1599         fi
1600         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1601         MESA_LLVM=1
1602
1603         dnl Check for Clang internal headers
1604         if test "x$enable_opencl" = xyes; then
1605             if test -z "$CLANG_LIBDIR"; then
1606                 CLANG_LIBDIR=${LLVM_LIBDIR}
1607             fi
1608             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1609             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1610                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1611         fi
1612     else
1613         MESA_LLVM=0
1614         LLVM_VERSION_INT=0
1615     fi
1616 else
1617     MESA_LLVM=0
1618     LLVM_VERSION_INT=0
1619 fi
1620
1621 dnl Directory for XVMC libs
1622 AC_ARG_WITH([xvmc-libdir],
1623     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1624         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1625     [XVMC_LIB_INSTALL_DIR="$withval"],
1626     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1627 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1628
1629 dnl
1630 dnl Gallium Tests
1631 dnl
1632 if test "x$enable_gallium_tests" = xyes; then
1633     enable_gallium_loader=yes
1634 fi
1635 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1636
1637 if test "x$enable_gallium_loader" = xyes; then
1638     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1639 fi
1640 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1641
1642 dnl Directory for VDPAU libs
1643 AC_ARG_WITH([vdpau-libdir],
1644     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1645         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1646     [VDPAU_LIB_INSTALL_DIR="$withval"],
1647     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1648 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1649
1650 OMX_LIB_INSTALL_DIR_DEFAULT=''
1651 if test "x$enable_omx" = xyes; then
1652     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1653 fi
1654
1655 AC_ARG_WITH([omx-libdir],
1656     [AS_HELP_STRING([--with-omx-libdir=DIR],
1657         [directory for the OMX libraries])],
1658     [OMX_LIB_INSTALL_DIR="$withval"],
1659     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1660 AC_SUBST([OMX_LIB_INSTALL_DIR])
1661
1662 dnl Directory for OpenCL libs
1663 AC_ARG_WITH([opencl-libdir],
1664     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1665         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1666     [OPENCL_LIB_INSTALL_DIR="$withval"],
1667     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1668 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1669
1670 dnl
1671 dnl Gallium helper functions
1672 dnl
1673 gallium_check_st() {
1674     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1675          if test "x$have_libdrm" != xyes; then
1676             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1677          fi
1678          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1679     fi
1680     if test "x$enable_dri" = xyes && test -n "$2"; then
1681          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1682     fi
1683     if test "x$enable_xa" = xyes && test -n "$3"; then
1684          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1685     fi
1686     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1687          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1688     fi
1689     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1690          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1691     fi
1692     if test "x$enable_omx" = xyes && test "x$6" != x; then
1693          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1694     fi
1695 }
1696
1697 gallium_require_llvm() {
1698     if test "x$MESA_LLVM" = x0; then
1699         case "$host_cpu" in
1700         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1701         esac
1702     fi
1703 }
1704
1705 gallium_require_drm_loader() {
1706     if test "x$enable_gallium_loader" = xyes; then
1707         if test "x$have_libudev" != xyes; then
1708             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1709         fi
1710         if test "x$have_libdrm" != xyes; then
1711             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1712         fi
1713         enable_gallium_drm_loader=yes
1714     fi
1715 }
1716
1717 radeon_llvm_check() {
1718     if test "x$enable_gallium_llvm" != "xyes"; then
1719         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1720     fi
1721     LLVM_REQUIRED_VERSION_MAJOR="3"
1722     LLVM_REQUIRED_VERSION_MINOR="3"
1723     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1724         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1725     fi
1726     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1727         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1728                       sources with the --enable-experimental-targets=R600
1729                       configure flag])
1730     fi
1731     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1732     NEED_RADEON_LLVM=yes
1733     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1734                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1735 }
1736
1737 dnl Gallium drivers
1738 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1739         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1740     NEED_NONNULL_WINSYS=yes
1741 fi
1742 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1743
1744 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1745 if test -n "$with_gallium_drivers"; then
1746     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1747     for driver in $gallium_drivers; do
1748         case "x$driver" in
1749         xsvga)
1750             HAVE_GALLIUM_SVGA=yes
1751             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1752             gallium_require_drm_loader
1753             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1754             ;;
1755         xi915)
1756             HAVE_GALLIUM_I915=yes
1757             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1758             gallium_require_drm_loader
1759             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1760             if test "x$MESA_LLVM" = x1; then
1761                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1762             fi
1763             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1764             gallium_check_st "i915/drm" "dri-i915"
1765             DRICOMMON_NEED_LIBDRM=yes
1766             ;;
1767         xilo)
1768             HAVE_GALLIUM_ILO=yes
1769             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1770             gallium_require_drm_loader
1771             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1772             gallium_check_st "intel/drm" "dri-ilo"
1773             DRICOMMON_NEED_LIBDRM=yes
1774             ;;
1775         xr300)
1776             HAVE_GALLIUM_R300=yes
1777             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1778             gallium_require_drm_loader
1779             gallium_require_llvm "Gallium R300"
1780             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1781             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1782             DRICOMMON_NEED_LIBDRM=yes
1783             ;;
1784         xr600)
1785             HAVE_GALLIUM_R600=yes
1786             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1787             gallium_require_drm_loader
1788             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1789             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1790                 radeon_llvm_check "r600g"
1791                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1792             fi
1793             if test "x$enable_r600_llvm" = xyes; then
1794                 USE_R600_LLVM_COMPILER=yes;
1795             fi
1796             if test "x$enable_opencl" = xyes; then
1797                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1798             fi
1799             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1800             DRICOMMON_NEED_LIBDRM=yes
1801             ;;
1802         xradeonsi)
1803             HAVE_GALLIUM_RADEONSI=yes
1804             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1805             gallium_require_drm_loader
1806             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1807             radeon_llvm_check "radeonsi"
1808             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1809             DRICOMMON_NEED_LIBDRM=yes
1810             ;;
1811         xnouveau)
1812             HAVE_GALLIUM_NOUVEAU=yes
1813             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1814             gallium_require_drm_loader
1815             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1816             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1817             DRICOMMON_NEED_LIBDRM=yes
1818             ;;
1819         xfreedreno)
1820             HAVE_GALLIUM_FREEDRENO=yes
1821             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1822             gallium_require_drm_loader
1823             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1824             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1825             DRICOMMON_NEED_LIBDRM=yes
1826             ;;
1827         xswrast)
1828             HAVE_GALLIUM_SOFTPIPE=yes
1829             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1830             if test "x$MESA_LLVM" = x1; then
1831                 HAVE_GALLIUM_LLVMPIPE=yes
1832                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1833             fi
1834
1835             if test "x$enable_dri" = xyes; then
1836                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1837             fi
1838             ;;
1839         *)
1840             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1841             ;;
1842         esac
1843     done
1844 fi
1845
1846 dnl Set LLVM_LIBS - This is done after the driver configuration so
1847 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1848 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1849 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1850 dnl this was causing the same libraries to be appear multiple times
1851 dnl in LLVM_LIBS.
1852
1853 if test "x$MESA_LLVM" != x0; then
1854
1855     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1856
1857     if test "x$enable_llvm_shared_libs" = xyes; then
1858         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1859         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1860         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1861
1862         if test "x$llvm_have_one_so" = xyes; then
1863             dnl LLVM was built using auto*, so there is only one shared object.
1864             LLVM_LIBS="-l$LLVM_SO_NAME"
1865         else
1866             dnl If LLVM was built with CMake, there will be one shared object per
1867             dnl component.
1868             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1869                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1870         Please make sure you have built llvm with the --enable-shared option
1871         and that your llvm libraries are installed in $LLVM_LIBDIR
1872         If you have installed your llvm libraries to a different directory you
1873         can use the --with-llvm-prefix= configure flag to specify this directory.
1874         NOTE: Mesa is attempting to use llvm shared libraries by default.
1875         If you do not want to build with llvm shared libraries and instead want to
1876         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1877         invocation and rebuild.])])
1878
1879            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1880            dnl install uses a shared object for each compoenent and we have
1881            dnl already added all of these objects to LLVM_LIBS.
1882         fi
1883     else
1884         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
1885     fi
1886 fi
1887
1888 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1889 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1890 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1891 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1892 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1893 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1894 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1895 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1896 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1897 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1898
1899 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1900                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1901                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1902 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1903                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1904                                                   && test "x$MESA_LLVM" = x1)
1905
1906 # NOTE: anything using xcb or other client side libs ends up in separate
1907 #       _CLIENT variables.  The pipe loader is built in two variants,
1908 #       one that is standalone and does not link any x client libs (for
1909 #       use by XA tracker in particular, but could be used in any case
1910 #       where communication with xserver is not desired).
1911 if test "x$enable_gallium_loader" = xyes; then
1912     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1913
1914     if test "x$enable_gallium_xlib_loader" = xyes; then
1915         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1916         NEED_WINSYS_XLIB="yes"
1917         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1918     fi
1919
1920     if test "x$enable_gallium_drm_loader" = xyes; then
1921         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1922         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1923                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1924         if test "x$pipe_loader_have_xcb" = xyes; then
1925             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1926             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1927         fi
1928     fi
1929
1930     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1931     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1932
1933     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1934     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1935     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1936     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1937 fi
1938 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1939
1940 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1941 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1942 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1943 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1944 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1945 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1946
1947 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1948                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1949                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1950                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1951 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1952                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1953 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1954 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1955 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1956 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1957 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1958 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1959 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1960
1961 AC_SUBST([ELF_LIB])
1962
1963 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1964 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1965 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1966 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1967 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1968
1969 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1970 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1971 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1972
1973 AC_SUBST([VDPAU_MAJOR], 1)
1974 AC_SUBST([VDPAU_MINOR], 0)
1975
1976 AC_SUBST([XVMC_MAJOR], 1)
1977 AC_SUBST([XVMC_MINOR], 0)
1978
1979 AC_SUBST([XA_MAJOR], 2)
1980 AC_SUBST([XA_MINOR], 2)
1981 AC_SUBST([XA_TINY], 0)
1982 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1983
1984 dnl Restore LDFLAGS and CPPFLAGS
1985 LDFLAGS="$_SAVE_LDFLAGS"
1986 CPPFLAGS="$_SAVE_CPPFLAGS"
1987
1988 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1989 if test "x$acv_mesa_CLANG" = xyes; then
1990     CFLAGS="$CFLAGS -Qunused-arguments"
1991     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1992 fi
1993
1994 dnl Add user CFLAGS and CXXFLAGS
1995 CFLAGS="$CFLAGS $USER_CFLAGS"
1996 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1997
1998 dnl Substitute the config
1999 AC_CONFIG_FILES([Makefile
2000                 src/Makefile
2001                 src/egl/Makefile
2002                 src/egl/drivers/Makefile
2003                 src/egl/drivers/dri2/Makefile
2004                 src/egl/main/Makefile
2005                 src/egl/main/egl.pc
2006                 src/egl/wayland/Makefile
2007                 src/egl/wayland/wayland-drm/Makefile
2008                 src/egl/wayland/wayland-egl/Makefile
2009                 src/egl/wayland/wayland-egl/wayland-egl.pc
2010                 src/gallium/auxiliary/Makefile
2011                 src/gallium/auxiliary/pipe-loader/Makefile
2012                 src/gallium/drivers/Makefile
2013                 src/gallium/drivers/freedreno/Makefile
2014                 src/gallium/drivers/galahad/Makefile
2015                 src/gallium/drivers/i915/Makefile
2016                 src/gallium/drivers/identity/Makefile
2017                 src/gallium/drivers/ilo/Makefile
2018                 src/gallium/drivers/llvmpipe/Makefile
2019                 src/gallium/drivers/noop/Makefile
2020                 src/gallium/drivers/nouveau/Makefile
2021                 src/gallium/drivers/r300/Makefile
2022                 src/gallium/drivers/r600/Makefile
2023                 src/gallium/drivers/radeon/Makefile
2024                 src/gallium/drivers/radeonsi/Makefile
2025                 src/gallium/drivers/rbug/Makefile
2026                 src/gallium/drivers/softpipe/Makefile
2027                 src/gallium/drivers/svga/Makefile
2028                 src/gallium/drivers/trace/Makefile
2029                 src/gallium/state_trackers/Makefile
2030                 src/gallium/state_trackers/clover/Makefile
2031                 src/gallium/state_trackers/dri/Makefile
2032                 src/gallium/state_trackers/dri/drm/Makefile
2033                 src/gallium/state_trackers/dri/sw/Makefile
2034                 src/gallium/state_trackers/egl/Makefile
2035                 src/gallium/state_trackers/gbm/Makefile
2036                 src/gallium/state_trackers/glx/xlib/Makefile
2037                 src/gallium/state_trackers/omx/Makefile
2038                 src/gallium/state_trackers/osmesa/Makefile
2039                 src/gallium/state_trackers/vdpau/Makefile
2040                 src/gallium/state_trackers/vega/Makefile
2041                 src/gallium/state_trackers/xa/Makefile
2042                 src/gallium/state_trackers/xvmc/Makefile
2043                 src/gallium/targets/Makefile
2044                 src/gallium/targets/dri-freedreno/Makefile
2045                 src/gallium/targets/dri-i915/Makefile
2046                 src/gallium/targets/dri-ilo/Makefile
2047                 src/gallium/targets/dri-nouveau/Makefile
2048                 src/gallium/targets/dri-swrast/Makefile
2049                 src/gallium/targets/dri-vmwgfx/Makefile
2050                 src/gallium/targets/egl-static/Makefile
2051                 src/gallium/targets/gbm/Makefile
2052                 src/gallium/targets/opencl/Makefile
2053                 src/gallium/targets/xa/Makefile
2054                 src/gallium/targets/xa/xatracker.pc
2055                 src/gallium/targets/osmesa/Makefile
2056                 src/gallium/targets/osmesa/osmesa.pc
2057                 src/gallium/targets/pipe-loader/Makefile
2058                 src/gallium/targets/radeonsi/dri/Makefile
2059                 src/gallium/targets/radeonsi/omx/Makefile
2060                 src/gallium/targets/radeonsi/vdpau/Makefile
2061                 src/gallium/targets/r300/dri/Makefile
2062                 src/gallium/targets/r600/dri/Makefile
2063                 src/gallium/targets/r600/omx/Makefile
2064                 src/gallium/targets/r600/vdpau/Makefile
2065                 src/gallium/targets/r600/xvmc/Makefile
2066                 src/gallium/targets/libgl-xlib/Makefile
2067                 src/gallium/targets/vdpau-nouveau/Makefile
2068                 src/gallium/targets/xvmc-nouveau/Makefile
2069                 src/gallium/tests/trivial/Makefile
2070                 src/gallium/tests/unit/Makefile
2071                 src/gallium/winsys/Makefile
2072                 src/gallium/winsys/freedreno/drm/Makefile
2073                 src/gallium/winsys/i915/drm/Makefile
2074                 src/gallium/winsys/i915/sw/Makefile
2075                 src/gallium/winsys/intel/drm/Makefile
2076                 src/gallium/winsys/nouveau/drm/Makefile
2077                 src/gallium/winsys/radeon/drm/Makefile
2078                 src/gallium/winsys/svga/drm/Makefile
2079                 src/gallium/winsys/sw/dri/Makefile
2080                 src/gallium/winsys/sw/fbdev/Makefile
2081                 src/gallium/winsys/sw/null/Makefile
2082                 src/gallium/winsys/sw/wayland/Makefile
2083                 src/gallium/winsys/sw/wrapper/Makefile
2084                 src/gallium/winsys/sw/xlib/Makefile
2085                 src/gbm/Makefile
2086                 src/gbm/main/gbm.pc
2087                 src/glsl/Makefile
2088                 src/glx/Makefile
2089                 src/glx/tests/Makefile
2090                 src/gtest/Makefile
2091                 src/loader/Makefile
2092                 src/mapi/Makefile
2093                 src/mapi/es1api/Makefile
2094                 src/mapi/es1api/glesv1_cm.pc
2095                 src/mapi/es2api/Makefile
2096                 src/mapi/es2api/glesv2.pc
2097                 src/mapi/glapi/Makefile
2098                 src/mapi/glapi/gen/Makefile
2099                 src/mapi/glapi/tests/Makefile
2100                 src/mapi/shared-glapi/Makefile
2101                 src/mapi/shared-glapi/tests/Makefile
2102                 src/mapi/vgapi/Makefile
2103                 src/mapi/vgapi/vg.pc
2104                 src/mesa/Makefile
2105                 src/mesa/gl.pc
2106                 src/mesa/drivers/dri/dri.pc
2107                 src/mesa/drivers/dri/common/Makefile
2108                 src/mesa/drivers/dri/common/xmlpool/Makefile
2109                 src/mesa/drivers/dri/i915/Makefile
2110                 src/mesa/drivers/dri/i965/Makefile
2111                 src/mesa/drivers/dri/Makefile
2112                 src/mesa/drivers/dri/nouveau/Makefile
2113                 src/mesa/drivers/dri/r200/Makefile
2114                 src/mesa/drivers/dri/radeon/Makefile
2115                 src/mesa/drivers/dri/swrast/Makefile
2116                 src/mesa/drivers/osmesa/Makefile
2117                 src/mesa/drivers/osmesa/osmesa.pc
2118                 src/mesa/drivers/x11/Makefile
2119                 src/mesa/main/tests/Makefile
2120                 src/mesa/main/tests/hash_table/Makefile])
2121
2122 dnl Sort the dirs alphabetically
2123 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2124 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2125 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2126 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2127
2128 AC_OUTPUT
2129
2130 dnl
2131 dnl Output some configuration info for the user
2132 dnl
2133 echo ""
2134 echo "        prefix:          $prefix"
2135 echo "        exec_prefix:     $exec_prefix"
2136 echo "        libdir:          $libdir"
2137 echo "        includedir:      $includedir"
2138
2139 dnl API info
2140 echo ""
2141 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2142 echo "        OpenVG:          $enable_openvg"
2143
2144 dnl Driver info
2145 echo ""
2146 case "x$enable_osmesa$enable_gallium_osmesa" in
2147 xnoyes)
2148         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2149         ;;
2150 xyesno)
2151         echo "        OSMesa:          lib$OSMESA_LIB"
2152         ;;
2153 xnono)
2154         echo "        OSMesa:          no"
2155         ;;
2156 esac
2157
2158 if test "x$enable_dri" != xno; then
2159         if test -z "$DRI_DIRS"; then
2160             echo "        DRI drivers:     no"
2161         else
2162             echo "        DRI drivers:     $DRI_DIRS"
2163         fi
2164         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2165 fi
2166
2167 case "x$enable_glx$enable_xlib_glx" in
2168 xyesyes)
2169     echo "        GLX:             Xlib-based"
2170     ;;
2171 xyesno)
2172     echo "        GLX:             DRI-based"
2173     ;;
2174 *)
2175     echo "        GLX:             $enable_glx"
2176     ;;
2177 esac
2178
2179 dnl EGL
2180 echo ""
2181 echo "        EGL:             $enable_egl"
2182 if test "$enable_egl" = yes; then
2183     echo "        EGL platforms:   $egl_platforms"
2184
2185     egl_drivers=""
2186     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2187         egl_drivers="$egl_drivers builtin:egl_dri2"
2188     fi
2189
2190     if test "x$enable_gallium_egl" = xyes; then
2191         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2192         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2193     else
2194         echo "        EGL drivers:    $egl_drivers"
2195     fi
2196 fi
2197
2198 echo ""
2199 if test "x$MESA_LLVM" = x1; then
2200     echo "        llvm:            yes"
2201     echo "        llvm-config:     $LLVM_CONFIG"
2202     echo "        llvm-version:    $LLVM_VERSION"
2203 else
2204     echo "        llvm:            no"
2205 fi
2206
2207 echo ""
2208 if test -n "$with_gallium_drivers"; then
2209     echo "        Gallium:         yes"
2210     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2211     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2212     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2213     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2214 else
2215     echo "        Gallium:         no"
2216 fi
2217
2218
2219 dnl Libraries
2220 echo ""
2221 echo "        Shared libs:     $enable_shared"
2222 echo "        Static libs:     $enable_static"
2223 echo "        Shared-glapi:    $enable_shared_glapi"
2224
2225 dnl Compiler options
2226 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2227 cflags=`echo $CFLAGS | \
2228     $SED 's/^ *//;s/  */ /;s/ *$//'`
2229 cxxflags=`echo $CXXFLAGS | \
2230     $SED 's/^ *//;s/  */ /;s/ *$//'`
2231 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2232 echo ""
2233 echo "        CFLAGS:          $cflags"
2234 echo "        CXXFLAGS:        $cxxflags"
2235 echo "        Macros:          $defines"
2236 echo ""
2237 if test "x$MESA_LLVM" = x1; then
2238     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2239     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2240     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2241     echo ""
2242 fi
2243 echo "        PYTHON2:         $PYTHON2"
2244
2245 echo ""
2246 echo "        Run '${MAKE-make}' to build Mesa"
2247 echo ""