configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.38
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.60
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126
 127 if test -z "$PYTHON2"; then
 128     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 129         AC_MSG_ERROR([Python not found - unable to generate sources])
 130     fi
 131 else
 132     if test "x$acv_mako_found" = xno; then
 133         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 134             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 135         fi
 136     fi
 137 fi
 138
 139 AC_PROG_INSTALL
 140
 141 dnl We need a POSIX shell for parts of the build. Assume we have one
 142 dnl in most cases.
 143 case "$host_os" in
 144 solaris*)
 145     # Solaris /bin/sh is too old/non-POSIX compliant
 146     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 147     SHELL="$POSIX_SHELL"
 148     ;;
 149 esac
 150
 151 dnl clang is mostly GCC-compatible, but its version is much lower,
 152 dnl so we have to check for it.
 153 AC_MSG_CHECKING([if compiling with clang])
 154
 155 AC_COMPILE_IFELSE(
 156 [AC_LANG_PROGRAM([], [[
 157 #ifndef __clang__
 158        not clang
 159 #endif
 160 ]])],
 161 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 162
 163 AC_MSG_RESULT([$acv_mesa_CLANG])
 164
 165 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 166 dnl versions are explictly not supported.
 167 GEN_ASM_OFFSETS=no
 168 USE_GNU99=no
 169 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 170     AC_MSG_CHECKING([whether gcc version is sufficient])
 171     major=0
 172     minor=0
 173
 174     GCC_VERSION=`$CC -dumpversion`
 175     if test $? -eq 0; then
 176         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 177         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 178     fi
 179
 180     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 181         AC_MSG_RESULT([no])
 182         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 183     else
 184         AC_MSG_RESULT([yes])
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 188         USE_GNU99=yes
 189     fi
 190     if test "x$cross_compiling" = xyes; then
 191         GEN_ASM_OFFSETS=yes
 192     fi
 193 fi
 194
 195 dnl Check for compiler builtins
 196 AX_GCC_BUILTIN([__builtin_bswap32])
 197 AX_GCC_BUILTIN([__builtin_bswap64])
 198 AX_GCC_BUILTIN([__builtin_clz])
 199 AX_GCC_BUILTIN([__builtin_clzll])
 200 AX_GCC_BUILTIN([__builtin_ctz])
 201 AX_GCC_BUILTIN([__builtin_expect])
 202 AX_GCC_BUILTIN([__builtin_ffs])
 203 AX_GCC_BUILTIN([__builtin_ffsll])
 204 AX_GCC_BUILTIN([__builtin_popcount])
 205 AX_GCC_BUILTIN([__builtin_popcountll])
 206 AX_GCC_BUILTIN([__builtin_unreachable])
 207
 208 AX_GCC_FUNC_ATTRIBUTE([flatten])
 209 AX_GCC_FUNC_ATTRIBUTE([format])
 210 AX_GCC_FUNC_ATTRIBUTE([malloc])
 211 AX_GCC_FUNC_ATTRIBUTE([packed])
 212 AX_GCC_FUNC_ATTRIBUTE([unused])
 213
 214 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 215
 216 dnl Make sure the pkg-config macros are defined
 217 m4_ifndef([PKG_PROG_PKG_CONFIG],
 218     [m4_fatal([Could not locate the pkg-config autoconf macros.
 219   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 220   are in a different location, try setting the environment variable
 221   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 222 PKG_PROG_PKG_CONFIG()
 223
 224 dnl LIB_DIR - library basename
 225 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 226 AC_SUBST([LIB_DIR])
 227
 228 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 229 _SAVE_LDFLAGS="$LDFLAGS"
 230 _SAVE_CPPFLAGS="$CPPFLAGS"
 231
 232 dnl Compiler macros
 233 DEFINES=""
 234 AC_SUBST([DEFINES])
 235 case "$host_os" in
 236 linux*|*-gnu*|gnu*)
 237     DEFINES="$DEFINES -D_GNU_SOURCE"
 238     ;;
 239 solaris*)
 240     DEFINES="$DEFINES -DSVR4"
 241     ;;
 242 cygwin*)
 243     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 244     ;;
 245 esac
 246
 247 dnl Add flags for gcc and g++
 248 if test "x$GCC" = xyes; then
 249     CFLAGS="$CFLAGS -Wall"
 250
 251     if test "x$USE_GNU99" = xyes; then
 252         CFLAGS="$CFLAGS -std=gnu99"
 253     else
 254         CFLAGS="$CFLAGS -std=c99"
 255     fi
 256
 257     # Enable -Werror=implicit-function-declaration and
 258     # -Werror=missing-prototypes, if available, or otherwise, just
 259     # -Wmissing-prototypes.  This is particularly useful to avoid
 260     # generating a loadable driver module that has undefined symbols.
 261     save_CFLAGS="$CFLAGS"
 262     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 263     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 264     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 265     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 266                    AC_MSG_RESULT([yes]),
 267                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 268                     AC_MSG_RESULT([no])]);
 269
 270     # Enable -fvisibility=hidden if using a gcc that supports it
 271     save_CFLAGS="$CFLAGS"
 272     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 273     VISIBILITY_CFLAGS="-fvisibility=hidden"
 274     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 275     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 276                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 277
 278     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 279     CFLAGS=$save_CFLAGS
 280
 281     # Work around aliasing bugs - developers should comment this out
 282     CFLAGS="$CFLAGS -fno-strict-aliasing"
 283
 284     # gcc's builtin memcmp is slower than glibc's
 285     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 286     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 287
 288     # Flags to help ensure that certain portions of the code -- and only those
 289     # portions -- can be built with MSVC:
 290     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 291     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 292     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 293     #   supports most of C99)
 294     # - the rest has no compiler compiler restrictions
 295     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 296     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 297
 298     # Enable -Werror=vla if compiler supports it
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 301     CFLAGS="$CFLAGS -Werror=vla"
 302     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 303                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 304                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 305                     AC_MSG_RESULT([yes])],
 306                     AC_MSG_RESULT([no]));
 307     CFLAGS="$save_CFLAGS"
 308
 309     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 310     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 311 fi
 312 if test "x$GXX" = xyes; then
 313     CXXFLAGS="$CXXFLAGS -Wall"
 314
 315     # Enable -fvisibility=hidden if using a gcc that supports it
 316     save_CXXFLAGS="$CXXFLAGS"
 317     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 318     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 319     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 320     AC_LANG_PUSH([C++])
 321     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 322                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 323     AC_LANG_POP([C++])
 324
 325     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 326     CXXFLAGS=$save_CXXFLAGS
 327
 328     # Work around aliasing bugs - developers should comment this out
 329     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 330
 331     # gcc's builtin memcmp is slower than glibc's
 332     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 333     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 334 fi
 335
 336 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 337 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 338 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 339 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 340
 341 dnl even if the compiler appears to support it, using visibility attributes isn't
 342 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 343 case "$host_os" in
 344 cygwin*)
 345     VISIBILITY_CFLAGS=""
 346     VISIBILITY_CXXFLAGS=""
 347     ;;
 348 esac
 349
 350 AC_SUBST([VISIBILITY_CFLAGS])
 351 AC_SUBST([VISIBILITY_CXXFLAGS])
 352
 353 dnl
 354 dnl Optional flags, check for compiler support
 355 dnl
 356 SSE41_CFLAGS="-msse4.1"
 357 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 358 dnl stack, but on x86-32 such alignment is not guaranteed.
 359 case "$target_cpu" in
 360 i?86)
 361     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 362     ;;
 363 esac
 364 save_CFLAGS="$CFLAGS"
 365 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 366 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 367 #include <smmintrin.h>
 368 int main () {
 369     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 370     c = _mm_max_epu32(a, b);
 371     return 0;
 372 }]])], SSE41_SUPPORTED=1)
 373 CFLAGS="$save_CFLAGS"
 374 if test "x$SSE41_SUPPORTED" = x1; then
 375     DEFINES="$DEFINES -DUSE_SSE41"
 376 fi
 377 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 378 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 379
 380 dnl Can't have static and shared libraries, default to static if user
 381 dnl explicitly requested. If both disabled, set to static since shared
 382 dnl was explicitly requested.
 383 case "x$enable_static$enable_shared" in
 384 xyesyes)
 385     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 386     enable_shared=no
 387     ;;
 388 xnono)
 389     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 390     enable_shared=yes
 391     ;;
 392 esac
 393
 394 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 395
 396 dnl
 397 dnl other compiler options
 398 dnl
 399 AC_ARG_ENABLE([debug],
 400     [AS_HELP_STRING([--enable-debug],
 401         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 402     [enable_debug="$enableval"],
 403     [enable_debug=no]
 404 )
 405 if test "x$enable_debug" = xyes; then
 406     DEFINES="$DEFINES -DDEBUG"
 407     if test "x$GCC" = xyes; then
 408         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 409             CFLAGS="$CFLAGS -g"
 410         fi
 411         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 412             CFLAGS="$CFLAGS -O0"
 413         fi
 414     fi
 415     if test "x$GXX" = xyes; then
 416         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 417             CXXFLAGS="$CXXFLAGS -g"
 418         fi
 419         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 420             CXXFLAGS="$CXXFLAGS -O0"
 421         fi
 422     fi
 423 else
 424    DEFINES="$DEFINES -DNDEBUG"
 425 fi
 426
 427 dnl
 428 dnl Check if linker supports -Bsymbolic
 429 dnl
 430 save_LDFLAGS=$LDFLAGS
 431 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 432 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 433 AC_LINK_IFELSE(
 434     [AC_LANG_SOURCE([int main() { return 0;}])],
 435     [AC_MSG_RESULT([yes])
 436         BSYMBOLIC="-Wl,-Bsymbolic";],
 437     [AC_MSG_RESULT([no])
 438         BSYMBOLIC="";])
 439 LDFLAGS=$save_LDFLAGS
 440
 441 AC_SUBST([BSYMBOLIC])
 442
 443 dnl
 444 dnl Check if linker supports garbage collection
 445 dnl
 446 save_LDFLAGS=$LDFLAGS
 447 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 448 AC_MSG_CHECKING([whether ld supports --gc-sections])
 449 AC_LINK_IFELSE(
 450     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 451     [AC_MSG_RESULT([yes])
 452         GC_SECTIONS="-Wl,--gc-sections";],
 453     [AC_MSG_RESULT([no])
 454         GC_SECTIONS="";])
 455 LDFLAGS=$save_LDFLAGS
 456
 457 AC_SUBST([GC_SECTIONS])
 458
 459 dnl
 460 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 461 dnl so when these flags are passed to ld via libtool the checks will fail
 462 dnl
 463 case "$host_os" in
 464 openbsd* | darwin* )
 465     LD_NO_UNDEFINED="" ;;
 466 *)
 467     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 468 esac
 469
 470 AC_SUBST([LD_NO_UNDEFINED])
 471
 472 dnl
 473 dnl Check if linker supports version scripts
 474 dnl
 475 AC_MSG_CHECKING([if the linker supports version-scripts])
 476 save_LDFLAGS=$LDFLAGS
 477 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 478 cat > conftest.map <<EOF
 479 VERSION_1 {
 480      global:
 481          main;
 482
 483      local:
 484          *;
 485 };
 486 EOF
 487 AC_LINK_IFELSE(
 488     [AC_LANG_SOURCE([int main() { return 0;}])],
 489     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 490     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 491 LDFLAGS=$save_LDFLAGS
 492 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 493
 494 dnl
 495 dnl Check if linker supports dynamic list files
 496 dnl
 497 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 498 save_LDFLAGS=$LDFLAGS
 499 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 500 cat > conftest.dyn <<EOF
 501 {
 502         radeon_drm_winsys_create;
 503 };
 504 EOF
 505 AC_LINK_IFELSE(
 506     [AC_LANG_SOURCE([int main() { return 0;}])],
 507     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 508     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 509 LDFLAGS=$save_LDFLAGS
 510 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 511
 512 dnl
 513 dnl compatibility symlinks
 514 dnl
 515 case "$host_os" in
 516 linux* )
 517     HAVE_COMPAT_SYMLINKS=yes ;;
 518 * )
 519     HAVE_COMPAT_SYMLINKS=no ;;
 520 esac
 521
 522 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 523
 524 dnl
 525 dnl library names
 526 dnl
 527 case "$host_os" in
 528 darwin* )
 529     LIB_EXT='dylib' ;;
 530 cygwin* )
 531     LIB_EXT='dll' ;;
 532 aix* )
 533     LIB_EXT='a' ;;
 534 * )
 535     LIB_EXT='so' ;;
 536 esac
 537
 538 AC_SUBST([LIB_EXT])
 539
 540 AC_ARG_WITH([gl-lib-name],
 541   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 542     [specify GL library name @<:@default=GL@:>@])],
 543   [GL_LIB=$withval],
 544   [GL_LIB=GL])
 545 AC_ARG_WITH([osmesa-lib-name],
 546   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 547     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 548   [OSMESA_LIB=$withval],
 549   [OSMESA_LIB=OSMesa])
 550 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 551 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 552
 553 dnl
 554 dnl Mangled Mesa support
 555 dnl
 556 AC_ARG_ENABLE([mangling],
 557   [AS_HELP_STRING([--enable-mangling],
 558     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 559   [enable_mangling="${enableval}"],
 560   [enable_mangling=no]
 561 )
 562 if test "x${enable_mangling}" = "xyes" ; then
 563   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 564   GL_LIB="Mangled${GL_LIB}"
 565   OSMESA_LIB="Mangled${OSMESA_LIB}"
 566 fi
 567 AC_SUBST([GL_LIB])
 568 AC_SUBST([OSMESA_LIB])
 569
 570 dnl
 571 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 572 dnl
 573 AC_ARG_ENABLE([texture-float],
 574     [AS_HELP_STRING([--enable-texture-float],
 575         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 576     [enable_texture_float="$enableval"],
 577     [enable_texture_float=no]
 578 )
 579 if test "x$enable_texture_float" = xyes; then
 580     AC_MSG_WARN([Floating-point textures enabled.])
 581     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 582     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 583 fi
 584
 585 dnl
 586 dnl Arch/platform-specific settings
 587 dnl
 588 AC_ARG_ENABLE([asm],
 589     [AS_HELP_STRING([--disable-asm],
 590         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 591     [enable_asm="$enableval"],
 592     [enable_asm=yes]
 593 )
 594 asm_arch=""
 595 AC_MSG_CHECKING([whether to enable assembly])
 596 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 597 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 598 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 599     case "$host_cpu" in
 600     i?86 | x86_64 | amd64)
 601         enable_asm=no
 602         AC_MSG_RESULT([no, cross compiling])
 603         ;;
 604     esac
 605 fi
 606 # check for supported arches
 607 if test "x$enable_asm" = xyes; then
 608     case "$host_cpu" in
 609     i?86)
 610         case "$host_os" in
 611         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 612             asm_arch=x86
 613             ;;
 614         esac
 615         ;;
 616     x86_64|amd64)
 617         case "$host_os" in
 618         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 619             asm_arch=x86_64
 620             ;;
 621         esac
 622         ;;
 623     sparc*)
 624         case "$host_os" in
 625         linux*)
 626             asm_arch=sparc
 627             ;;
 628         esac
 629         ;;
 630     esac
 631
 632     case "$asm_arch" in
 633     x86)
 634         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 635         AC_MSG_RESULT([yes, x86])
 636         ;;
 637     x86_64|amd64)
 638         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 639         AC_MSG_RESULT([yes, x86_64])
 640         ;;
 641     sparc)
 642         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 643         AC_MSG_RESULT([yes, sparc])
 644         ;;
 645     *)
 646         AC_MSG_RESULT([no, platform not supported])
 647         ;;
 648     esac
 649 fi
 650
 651 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 652 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 653 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 654
 655 dnl Check to see if dlopen is in default libraries (like Solaris, which
 656 dnl has it in libc), or if libdl is needed to get it.
 657 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 658     [AC_CHECK_LIB([dl], [dlopen],
 659        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 660 AC_SUBST([DLOPEN_LIBS])
 661
 662 dnl Check if that library also has dladdr
 663 save_LIBS="$LIBS"
 664 LIBS="$LIBS $DLOPEN_LIBS"
 665 AC_CHECK_FUNCS([dladdr])
 666 LIBS="$save_LIBS"
 667
 668 case "$host_os" in
 669 darwin*)
 670     ;;
 671 *)
 672     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 673                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 674                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 675     AC_SUBST([CLOCK_LIB])
 676     ;;
 677 esac
 678
 679 dnl See if posix_memalign is available
 680 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 681
 682 dnl Check for pthreads
 683 AX_PTHREAD
 684 if test "x$ax_pthread_ok" = xno; then
 685     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 686 fi
 687 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 688 dnl to -pthread, which causes problems if we need -lpthread to appear in
 689 dnl pkgconfig files.
 690 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 691
 692 dnl SELinux awareness.
 693 AC_ARG_ENABLE([selinux],
 694     [AS_HELP_STRING([--enable-selinux],
 695         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 696     [MESA_SELINUX="$enableval"],
 697     [MESA_SELINUX=no])
 698 if test "x$enable_selinux" = "xyes"; then
 699     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 700         [AC_CHECK_HEADER([selinux/selinux.h],[],
 701                          [AC_MSG_ERROR([SELinux headers not found])])
 702          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 703                       [AC_MSG_ERROR([SELinux library not found])])
 704          SELINUX_LIBS="-lselinux"])
 705     DEFINES="$DEFINES -DMESA_SELINUX"
 706 fi
 707 AC_SUBST([SELINUX_CFLAGS])
 708 AC_SUBST([SELINUX_LIBS])
 709
 710 dnl Options for APIs
 711 AC_ARG_ENABLE([opengl],
 712     [AS_HELP_STRING([--disable-opengl],
 713         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 714     [enable_opengl="$enableval"],
 715     [enable_opengl=yes])
 716 AC_ARG_ENABLE([gles1],
 717     [AS_HELP_STRING([--disable-gles1],
 718         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 719     [enable_gles1="$enableval"],
 720     [enable_gles1=yes])
 721 AC_ARG_ENABLE([gles2],
 722     [AS_HELP_STRING([--disable-gles2],
 723         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 724     [enable_gles2="$enableval"],
 725     [enable_gles2=yes])
 726
 727 AC_ARG_ENABLE([dri],
 728     [AS_HELP_STRING([--enable-dri],
 729         [enable DRI modules @<:@default=enabled@:>@])],
 730     [enable_dri="$enableval"],
 731     [enable_dri=yes])
 732
 733 case "$host_os" in
 734 linux*)
 735     dri3_default=yes
 736     ;;
 737 *)
 738     dri3_default=no
 739     ;;
 740 esac
 741 AC_ARG_ENABLE([dri3],
 742     [AS_HELP_STRING([--enable-dri3],
 743         [enable DRI3 @<:@default=auto@:>@])],
 744     [enable_dri3="$enableval"],
 745     [enable_dri3="$dri3_default"])
 746 AC_ARG_ENABLE([glx],
 747     [AS_HELP_STRING([--enable-glx],
 748         [enable GLX library @<:@default=enabled@:>@])],
 749     [enable_glx="$enableval"],
 750     [enable_glx=yes])
 751 AC_ARG_ENABLE([osmesa],
 752     [AS_HELP_STRING([--enable-osmesa],
 753         [enable OSMesa library @<:@default=disabled@:>@])],
 754     [enable_osmesa="$enableval"],
 755     [enable_osmesa=no])
 756 AC_ARG_ENABLE([gallium-osmesa],
 757     [AS_HELP_STRING([--enable-gallium-osmesa],
 758         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 759     [enable_gallium_osmesa="$enableval"],
 760     [enable_gallium_osmesa=no])
 761 AC_ARG_ENABLE([egl],
 762     [AS_HELP_STRING([--disable-egl],
 763         [disable EGL library @<:@default=enabled@:>@])],
 764     [enable_egl="$enableval"],
 765     [enable_egl=yes])
 766
 767 AC_ARG_ENABLE([xa],
 768     [AS_HELP_STRING([--enable-xa],
 769         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 770     [enable_xa="$enableval"],
 771     [enable_xa=no])
 772 AC_ARG_ENABLE([gbm],
 773    [AS_HELP_STRING([--enable-gbm],
 774          [enable gbm library @<:@default=auto@:>@])],
 775    [enable_gbm="$enableval"],
 776    [enable_gbm=auto])
 777 AC_ARG_ENABLE([nine],
 778     [AS_HELP_STRING([--enable-nine],
 779         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 780     [enable_nine="$enableval"],
 781     [enable_nine=no])
 782
 783 AC_ARG_ENABLE([xvmc],
 784    [AS_HELP_STRING([--enable-xvmc],
 785          [enable xvmc library @<:@default=auto@:>@])],
 786    [enable_xvmc="$enableval"],
 787    [enable_xvmc=auto])
 788 AC_ARG_ENABLE([vdpau],
 789    [AS_HELP_STRING([--enable-vdpau],
 790          [enable vdpau library @<:@default=auto@:>@])],
 791    [enable_vdpau="$enableval"],
 792    [enable_vdpau=auto])
 793 AC_ARG_ENABLE([omx],
 794    [AS_HELP_STRING([--enable-omx],
 795          [enable OpenMAX library @<:@default=disabled@:>@])],
 796    [enable_omx="$enableval"],
 797    [enable_omx=no])
 798 AC_ARG_ENABLE([va],
 799    [AS_HELP_STRING([--enable-va],
 800          [enable va library @<:@default=auto@:>@])],
 801    [enable_va="$enableval"],
 802    [enable_va=auto])
 803 AC_ARG_ENABLE([opencl],
 804    [AS_HELP_STRING([--enable-opencl],
 805          [enable OpenCL library @<:@default=disabled@:>@])],
 806    [enable_opencl="$enableval"],
 807    [enable_opencl=no])
 808 AC_ARG_ENABLE([opencl_icd],
 809    [AS_HELP_STRING([--enable-opencl-icd],
 810           [Build an OpenCL ICD library to be loaded by an ICD implementation
 811            @<:@default=disabled@:>@])],
 812     [enable_opencl_icd="$enableval"],
 813     [enable_opencl_icd=no])
 814 AC_ARG_ENABLE([xlib-glx],
 815     [AS_HELP_STRING([--enable-xlib-glx],
 816         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 817     [enable_xlib_glx="$enableval"],
 818     [enable_xlib_glx=no])
 819
 820 AC_ARG_ENABLE([r600-llvm-compiler],
 821     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 822         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 823     [enable_r600_llvm="$enableval"],
 824     [enable_r600_llvm=no])
 825
 826 AC_ARG_ENABLE([gallium-tests],
 827     [AS_HELP_STRING([--enable-gallium-tests],
 828         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 829     [enable_gallium_tests="$enableval"],
 830     [enable_gallium_tests=no])
 831
 832 # Option for Gallium drivers
 833
 834 # Keep this in sync with the --with-gallium-drivers help string default value
 835 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 836
 837 AC_ARG_WITH([gallium-drivers],
 838     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 839         [comma delimited Gallium drivers list, e.g.
 840         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 841         @<:@default=r300,r600,svga,swrast@:>@])],
 842     [with_gallium_drivers="$withval"],
 843     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 844
 845 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 846 # here so that the script doesn't choke on an unknown driver name later.
 847 case "$with_gallium_drivers" in
 848     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 849     no) with_gallium_drivers='' ;;
 850 esac
 851
 852 if test "x$enable_opengl" = xno -a \
 853         "x$enable_gles1" = xno -a \
 854         "x$enable_gles2" = xno -a \
 855         "x$enable_nine" = xno -a \
 856         "x$enable_xa" = xno -a \
 857         "x$enable_xvmc" = xno -a \
 858         "x$enable_vdpau" = xno -a \
 859         "x$enable_omx" = xno -a \
 860         "x$enable_va" = xno -a \
 861         "x$enable_opencl" = xno; then
 862     AC_MSG_ERROR([at least one API should be enabled])
 863 fi
 864
 865 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 866 if test "x$enable_opengl" = xno -a \
 867         "x$enable_gles1" = xyes; then
 868     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 869 fi
 870
 871 if test "x$enable_opengl" = xno -a \
 872         "x$enable_gles2" = xyes; then
 873     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 874 fi
 875
 876 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 877 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 878 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 879 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 880                                         "x$enable_gles1" = xyes -o \
 881                                         "x$enable_gles2" = xyes)
 882
 883 if test "x$enable_glx" = xno; then
 884     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 885     enable_xlib_glx=no
 886 fi
 887
 888 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 889     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 890 fi
 891
 892 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 893     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 894 fi
 895
 896 # Disable GLX if OpenGL is not enabled
 897 if test "x$enable_glx$enable_opengl" = xyesno; then
 898     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 899     enable_glx=no
 900 fi
 901
 902 # Disable GLX if DRI and Xlib-GLX are not enabled
 903 if test "x$enable_glx" = xyes -a \
 904         "x$enable_dri" = xno -a \
 905         "x$enable_xlib_glx" = xno; then
 906     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 907     enable_glx=no
 908 fi
 909
 910 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 911                                   "x$enable_dri" = xyes)
 912
 913 # Select which platform-dependent DRI code gets built
 914 case "$host_os" in
 915 darwin*)
 916     dri_platform='apple' ;;
 917 gnu*|cygwin*)
 918     dri_platform='none' ;;
 919 *)
 920     dri_platform='drm' ;;
 921 esac
 922
 923 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 924 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 925 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 926 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 927 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 928
 929 AC_ARG_ENABLE([shared-glapi],
 930     [AS_HELP_STRING([--enable-shared-glapi],
 931         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 932     [enable_shared_glapi="$enableval"],
 933     [enable_shared_glapi=yes])
 934
 935 case "x$enable_opengl$enable_gles1$enable_gles2" in
 936 x*yes*yes*)
 937     if test "x$enable_shared_glapi" = xno; then
 938         AC_MSG_ERROR([shared GLAPI required when building two or more of
 939                       the following APIs - opengl, gles1 gles2])
 940     fi
 941     ;;
 942 esac
 943
 944 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 945
 946 # Build the pipe-drivers as separate libraries/modules.
 947 # Do not touch this unless you know what you are doing.
 948 # XXX: Expose via configure option ?
 949 enable_shared_pipe_drivers=no
 950
 951 dnl
 952 dnl Driver specific build directories
 953 dnl
 954
 955 case "x$enable_glx$enable_xlib_glx" in
 956 xyesyes)
 957     NEED_WINSYS_XLIB="yes"
 958     ;;
 959 esac
 960
 961 if test "x$enable_dri" = xyes; then
 962     enable_gallium_loader="$enable_shared_pipe_drivers"
 963 fi
 964
 965 if test "x$enable_gallium_osmesa" = xyes; then
 966     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 967         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 968     fi
 969     if test "x$enable_osmesa" = xyes; then
 970         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 971     fi
 972 fi
 973
 974 AC_SUBST([MESA_LLVM])
 975
 976 # SHA1 hashing
 977 AC_ARG_WITH([sha1],
 978         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 979         [choose SHA1 implementation])])
 980 case "x$with_sha1" in
 981 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 982   ;;
 983 *)
 984         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 985 esac
 986
 987 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 988 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 989         with_sha1=libc
 990 fi
 991 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 992         AC_MSG_ERROR([sha1 in libc requested but not found])
 993 fi
 994 if test "x$with_sha1" = xlibc; then
 995         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 996                 [Use libc SHA1 functions])
 997         SHA1_LIBS=""
 998 fi
 999 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1000 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1001         with_sha1=CommonCrypto
1002 fi
1003 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1004         AC_MSG_ERROR([CommonCrypto requested but not found])
1005 fi
1006 if test "x$with_sha1" = xCommonCrypto; then
1007         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1008                 [Use CommonCrypto SHA1 functions])
1009         SHA1_LIBS=""
1010 fi
1011 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1012 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1013 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1014         with_sha1=CryptoAPI
1015 fi
1016 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1017         AC_MSG_ERROR([CryptoAPI requested but not found])
1018 fi
1019 if test "x$with_sha1" = xCryptoAPI; then
1020         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1021                 [Use CryptoAPI SHA1 functions])
1022         SHA1_LIBS=""
1023 fi
1024 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1025 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1026         with_sha1=libmd
1027 fi
1028 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1029         AC_MSG_ERROR([libmd requested but not found])
1030 fi
1031 if test "x$with_sha1" = xlibmd; then
1032         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1033                   [Use libmd SHA1 functions])
1034         SHA1_LIBS=-lmd
1035 fi
1036 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1037 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1038    with_sha1=libsha1
1039 fi
1040 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1041         AC_MSG_ERROR([libsha1 requested but not found])
1042 fi
1043 if test "x$with_sha1" = xlibsha1; then
1044         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1045                   [Use libsha1 for SHA1])
1046         SHA1_LIBS=-lsha1
1047 fi
1048 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1049 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1050         with_sha1=libnettle
1051 fi
1052 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1053         AC_MSG_ERROR([libnettle requested but not found])
1054 fi
1055 if test "x$with_sha1" = xlibnettle; then
1056         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1057                   [Use libnettle SHA1 functions])
1058         SHA1_LIBS=-lnettle
1059 fi
1060 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1061 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1062         with_sha1=libgcrypt
1063 fi
1064 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1065         AC_MSG_ERROR([libgcrypt requested but not found])
1066 fi
1067 if test "x$with_sha1" = xlibgcrypt; then
1068         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1069                   [Use libgcrypt SHA1 functions])
1070         SHA1_LIBS=-lgcrypt
1071 fi
1072 # We don't need all of the OpenSSL libraries, just libcrypto
1073 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1074 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1075                   [HAVE_OPENSSL_PKC=no])
1076 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1077         if test "x$with_sha1" = x; then
1078                 with_sha1=libcrypto
1079         fi
1080 else
1081         if test "x$with_sha1" = xlibcrypto; then
1082                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1083         fi
1084 fi
1085 if test "x$with_sha1" = xlibcrypto; then
1086         if test "x$HAVE_LIBCRYPTO" = xyes; then
1087                 SHA1_LIBS=-lcrypto
1088         else
1089                 SHA1_LIBS="$OPENSSL_LIBS"
1090                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1091         fi
1092 fi
1093 AC_MSG_CHECKING([for SHA1 implementation])
1094 AC_MSG_RESULT([$with_sha1])
1095 AC_SUBST(SHA1_LIBS)
1096 AC_SUBST(SHA1_CFLAGS)
1097
1098 # Allow user to configure out the shader-cache feature
1099 AC_ARG_ENABLE([shader-cache],
1100     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1101     [enable_shader_cache="$enableval"],
1102     [if test "x$with_sha1" != "x"; then
1103         enable_shader_cache=yes
1104      else
1105         enable_shader_cache=no
1106      fi])
1107 if test "x$with_sha1" = "x"; then
1108     if test "x$enable_shader_cache" = "xyes"; then
1109         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1110     fi
1111 fi
1112 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1113
1114 # Check for libdrm
1115 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1116                   [have_libdrm=yes], [have_libdrm=no])
1117 if test "x$have_libdrm" = xyes; then
1118         DEFINES="$DEFINES -DHAVE_LIBDRM"
1119 fi
1120
1121 case "$host_os" in
1122 linux*)
1123     need_pci_id=yes ;;
1124 *)
1125     need_pci_id=no ;;
1126 esac
1127
1128 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1129                   have_libudev=yes, have_libudev=no)
1130
1131 AC_ARG_ENABLE([sysfs],
1132     [AS_HELP_STRING([--enable-sysfs],
1133         [enable /sys PCI identification @<:@default=disabled@:>@])],
1134     [have_sysfs="$enableval"],
1135     [have_sysfs=no]
1136 )
1137
1138 if test "x$enable_dri" = xyes; then
1139     if test "$enable_static" = yes; then
1140         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1141     fi
1142
1143     # not a hard requirement as swrast does not depend on it
1144     if test "x$have_libdrm" = xyes; then
1145         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1146     fi
1147 fi
1148
1149 AC_ARG_ENABLE([driglx-direct],
1150     [AS_HELP_STRING([--disable-driglx-direct],
1151         [disable direct rendering in GLX and EGL for DRI \
1152             @<:@default=auto@:>@])],
1153     [driglx_direct="$enableval"],
1154     [driglx_direct="yes"])
1155
1156 dnl
1157 dnl libGL configuration per driver
1158 dnl
1159 case "x$enable_glx$enable_xlib_glx" in
1160 xyesyes)
1161     # Xlib-based GLX
1162     dri_modules="x11 xext xcb"
1163     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1164     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1165     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1166     GL_LIB_DEPS="$XLIBGL_LIBS"
1167     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1168     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1169     ;;
1170 xyesno)
1171     # DRI-based GLX
1172     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1173
1174     # find the DRI deps for libGL
1175     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1176
1177     if test x"$driglx_direct" = xyes; then
1178         if test x"$dri_platform" = xdrm ; then
1179             DEFINES="$DEFINES -DGLX_USE_DRM"
1180             if test "x$have_libdrm" != xyes; then
1181                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1182             fi
1183
1184             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1185             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1186             if test x"$enable_dri3" = xyes; then
1187                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1188                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1189             fi
1190
1191             if test x"$enable_dri" = xyes; then
1192                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1193             fi
1194
1195             if test x"$enable_dri3" = xyes; then
1196                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1197                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1198             fi
1199         fi
1200         if test x"$dri_platform" = xapple ; then
1201             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1202         fi
1203     fi
1204
1205     # add xf86vidmode if available
1206     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1207     if test "$HAVE_XF86VIDMODE" = yes ; then
1208         dri_modules="$dri_modules xxf86vm"
1209     fi
1210
1211     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1212     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1213     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1214     GL_LIB_DEPS="$DRIGL_LIBS"
1215
1216     # need DRM libs, $PTHREAD_LIBS, etc.
1217     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1218     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1219     ;;
1220 esac
1221
1222 have_pci_id=no
1223 if test "$have_libudev" = yes; then
1224     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1225     have_pci_id=yes
1226 fi
1227
1228 if test "$have_sysfs" = yes; then
1229     DEFINES="$DEFINES -DHAVE_SYSFS"
1230     have_pci_id=yes
1231 fi
1232
1233 # This is outside the case (above) so that it is invoked even for non-GLX
1234 # builds.
1235 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1236
1237 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1238 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1239 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1240 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1241
1242 AC_SUBST([X11_INCLUDES])
1243 AC_SUBST([GL_LIB_DEPS])
1244 AC_SUBST([GL_PC_REQ_PRIV])
1245 AC_SUBST([GL_PC_LIB_PRIV])
1246 AC_SUBST([GL_PC_CFLAGS])
1247 AC_SUBST([DRI_PC_REQ_PRIV])
1248 AC_SUBST([GLESv1_CM_LIB_DEPS])
1249 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1250 AC_SUBST([GLESv2_LIB_DEPS])
1251 AC_SUBST([GLESv2_PC_LIB_PRIV])
1252
1253 AC_SUBST([HAVE_XF86VIDMODE])
1254
1255 dnl
1256 dnl More GLX setup
1257 dnl
1258 case "x$enable_glx$enable_xlib_glx" in
1259 xyesyes)
1260     DEFINES="$DEFINES -DUSE_XSHM"
1261     ;;
1262 xyesno)
1263     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1264     if test "x$driglx_direct" = xyes; then
1265         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1266     fi
1267     ;;
1268 esac
1269
1270 dnl
1271 dnl TLS detection
1272 dnl
1273
1274 AC_ARG_ENABLE([glx-tls],
1275     [AS_HELP_STRING([--enable-glx-tls],
1276         [enable TLS support in GLX @<:@default=disabled@:>@])],
1277     [GLX_USE_TLS="$enableval"],
1278     [GLX_USE_TLS=no])
1279 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1280
1281 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1282       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1283
1284 dnl
1285 dnl More DRI setup
1286 dnl
1287 dnl Directory for DRI drivers
1288 AC_ARG_WITH([dri-driverdir],
1289     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1290         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1291     [DRI_DRIVER_INSTALL_DIR="$withval"],
1292     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1293 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1294 dnl Extra search path for DRI drivers
1295 AC_ARG_WITH([dri-searchpath],
1296     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1297         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1298     [DRI_DRIVER_SEARCH_DIR="$withval"],
1299     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1300 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1301 dnl Which drivers to build - default is chosen by platform
1302 AC_ARG_WITH([dri-drivers],
1303     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1304         [comma delimited classic DRI drivers list, e.g.
1305         "swrast,i965,radeon" @<:@default=auto@:>@])],
1306     [with_dri_drivers="$withval"],
1307     [with_dri_drivers=auto])
1308
1309 if test "x$with_dri_drivers" = xauto; then
1310     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1311         with_dri_drivers="yes"
1312     else
1313         with_dri_drivers="no"
1314     fi
1315 fi
1316 if test "x$with_dri_drivers" = xno; then
1317     with_dri_drivers=''
1318 fi
1319
1320 dnl If $with_dri_drivers is yes, drivers will be added through
1321 dnl platform checks. Set DEFINES and LIB_DEPS
1322 if test "x$enable_dri" = xyes; then
1323     # Platform specific settings and drivers to build
1324     case "$host_os" in
1325     linux*)
1326         DEFINES="$DEFINES -DHAVE_ALIAS"
1327         if test "x$enable_dri3" = xyes; then
1328             DEFINES="$DEFINES -DHAVE_DRI3"
1329         fi
1330
1331         if test "x$have_pci_id" != xyes; then
1332             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1333         fi
1334
1335         case "$host_cpu" in
1336         powerpc* | sparc*)
1337             # Build only the drivers for cards that exist on PowerPC/sparc
1338             if test "x$with_dri_drivers" = "xyes"; then
1339                 with_dri_drivers="r200 radeon swrast"
1340             fi
1341             ;;
1342         esac
1343         ;;
1344     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1345         DEFINES="$DEFINES -DHAVE_ALIAS"
1346         ;;
1347     gnu*)
1348         DEFINES="$DEFINES -DHAVE_ALIAS"
1349         ;;
1350     cygwin*)
1351         if test "x$with_dri_drivers" = "xyes"; then
1352             with_dri_drivers="swrast"
1353         fi
1354         ;;
1355     darwin*)
1356         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1357         if test "x$with_dri_drivers" = "xyes"; then
1358             with_dri_drivers="swrast"
1359         fi
1360         ;;
1361     esac
1362
1363     # default drivers
1364     if test "x$with_dri_drivers" = "xyes"; then
1365         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1366     fi
1367
1368     # Check for expat
1369     PKG_CHECK_MODULES([EXPAT], [expat], [],
1370         # expat version 2.0 and earlier do not provide expat.pc
1371         [AC_CHECK_HEADER([expat.h],[],
1372                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1373          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1374                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1375          EXPAT_LIBS="-lexpat"])
1376
1377     DRICOMMON_NEED_LIBDRM=no
1378     # If we are building any DRI driver other than swrast.
1379     if test -n "$with_dri_drivers"; then
1380         if test "x$with_dri_drivers" != xswrast; then
1381             # ... libdrm is required
1382             if test "x$have_libdrm" != xyes; then
1383                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1384             fi
1385             DRICOMMON_NEED_LIBDRM=yes
1386         fi
1387     fi
1388
1389     # If we're building any gallium DRI driver other than swrast
1390     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1391         if test "x$with_gallium_drivers" != xswrast; then
1392             # ... build a libdrm aware dricommon
1393             DRICOMMON_NEED_LIBDRM=yes
1394         fi
1395     fi
1396
1397     # put all the necessary libs together
1398     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1399 fi
1400
1401 AC_SUBST([DRI_LIB_DEPS])
1402
1403 DRI_DIRS=''
1404 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1405 if test -n "$with_dri_drivers"; then
1406     if test "x$enable_opengl" != xyes; then
1407         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1408     fi
1409
1410     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1411     for driver in $dri_drivers; do
1412         DRI_DIRS="$DRI_DIRS $driver"
1413         case "x$driver" in
1414         xi915)
1415             HAVE_I915_DRI=yes;
1416             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1417             ;;
1418         xi965)
1419             HAVE_I965_DRI=yes;
1420             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1421             ;;
1422         xnouveau)
1423             HAVE_NOUVEAU_DRI=yes;
1424             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1425             ;;
1426         xradeon)
1427             HAVE_RADEON_DRI=yes;
1428             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1429             ;;
1430         xr200)
1431             HAVE_R200_DRI=yes;
1432             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1433             ;;
1434         xswrast)
1435             HAVE_SWRAST_DRI=yes;
1436             ;;
1437         *)
1438             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1439             ;;
1440         esac
1441     done
1442     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1443 fi
1444
1445 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1446 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1447                                   "x$enable_osmesa" = xyes -o \
1448                                   -n "$DRI_DIRS")
1449
1450 dnl
1451 dnl OSMesa configuration
1452 dnl
1453
1454 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1455 AC_ARG_WITH([osmesa-bits],
1456     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1457         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1458     [osmesa_bits="$withval"],
1459     [osmesa_bits=8])
1460 if test "x$osmesa_bits" != x8; then
1461     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1462         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1463         osmesa_bits=8
1464     fi
1465 fi
1466 case "x$osmesa_bits" in
1467 x8)
1468     OSMESA_LIB="${OSMESA_LIB}"
1469     ;;
1470 x16|x32)
1471     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1472     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1473     ;;
1474 *)
1475     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1476     ;;
1477 esac
1478
1479 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1480     # only link libraries with osmesa if shared
1481     if test "$enable_static" = no; then
1482         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1483     else
1484         OSMESA_LIB_DEPS=""
1485     fi
1486     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1487 fi
1488
1489 AC_SUBST([OSMESA_LIB_DEPS])
1490 AC_SUBST([OSMESA_PC_REQ])
1491 AC_SUBST([OSMESA_PC_LIB_PRIV])
1492
1493 dnl
1494 dnl gbm configuration
1495 dnl
1496 if test "x$enable_gbm" = xauto; then
1497     case "$with_egl_platforms" in
1498         *drm*)
1499             enable_gbm=yes ;;
1500          *)
1501             enable_gbm=no ;;
1502     esac
1503 fi
1504 if test "x$enable_gbm" = xyes; then
1505     if test "x$need_pci_id$have_pci_id" = xyesno; then
1506         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1507     fi
1508
1509     if test "x$enable_dri" = xyes; then
1510         if test "x$enable_shared_glapi" = xno; then
1511             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1512         fi
1513     else
1514         # Strictly speaking libgbm does not require --enable-dri, although
1515         # both of its backends do. Thus one can build libgbm without any
1516         # backends if --disable-dri is set.
1517         # To avoid unnecessary complexity of checking if at least one backend
1518         # is available when building, just mandate --enable-dri.
1519         AC_MSG_ERROR([gbm requires --enable-dri])
1520     fi
1521 fi
1522 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1523 if test "x$need_pci_id$have_libudev" = xyesyes; then
1524     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1525 else
1526     GBM_PC_REQ_PRIV=""
1527 fi
1528 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1529 AC_SUBST([GBM_PC_REQ_PRIV])
1530 AC_SUBST([GBM_PC_LIB_PRIV])
1531
1532 dnl
1533 dnl EGL configuration
1534 dnl
1535 EGL_CLIENT_APIS=""
1536
1537 if test "x$enable_egl" = xyes; then
1538     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1539
1540     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1541
1542     if test "$enable_static" != yes; then
1543         if test "x$enable_dri" = xyes; then
1544             HAVE_EGL_DRIVER_DRI2=1
1545             if test "x$enable_shared_glapi" = xno; then
1546                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1547             fi
1548         else
1549             # Avoid building an "empty" libEGL. Drop/update this
1550             # when other backends (haiku?) come along.
1551             AC_MSG_ERROR([egl requires --enable-dri])
1552         fi
1553
1554     fi
1555 fi
1556 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1557 AC_SUBST([EGL_LIB_DEPS])
1558
1559 dnl
1560 dnl XA configuration
1561 dnl
1562 if test "x$enable_xa" = xyes; then
1563     if test "x$with_gallium_drivers" = xswrast; then
1564        AC_MSG_ERROR([
1565           Building xa requires at least one non swrast gallium driver.
1566           If you are looking to use libxatracker.so with the VMware driver,
1567           make sure to include svga in the gallium drivers list, apart from
1568           enabling XA.
1569           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1570     fi
1571     enable_gallium_loader=$enable_shared_pipe_drivers
1572 fi
1573 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1574
1575 dnl
1576 dnl Gallium G3DVL configuration
1577 dnl
1578 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1579     if test "x$enable_xvmc" = xauto; then
1580         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1581     fi
1582
1583     if test "x$enable_vdpau" = xauto; then
1584         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1585     fi
1586
1587     if test "x$enable_omx" = xauto; then
1588         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1589     fi
1590
1591     if test "x$enable_va" = xauto; then
1592         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1593     fi
1594 fi
1595
1596 if test "x$enable_dri" = xyes -o \
1597         "x$enable_xvmc" = xyes -o \
1598         "x$enable_vdpau" = xyes -o \
1599         "x$enable_omx" = xyes -o \
1600         "x$enable_va" = xyes; then
1601     need_gallium_vl=yes
1602 fi
1603 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1604
1605 if test "x$enable_xvmc" = xyes -o \
1606         "x$enable_vdpau" = xyes -o \
1607         "x$enable_omx" = xyes -o \
1608         "x$enable_va" = xyes; then
1609     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1610     need_gallium_vl_winsys=yes
1611 fi
1612 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1613
1614 if test "x$enable_xvmc" = xyes; then
1615     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1616     enable_gallium_loader=$enable_shared_pipe_drivers
1617 fi
1618 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1619
1620 if test "x$enable_vdpau" = xyes; then
1621     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1622     enable_gallium_loader=$enable_shared_pipe_drivers
1623 fi
1624 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1625
1626 if test "x$enable_omx" = xyes; then
1627     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1628     enable_gallium_loader=$enable_shared_pipe_drivers
1629 fi
1630 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1631
1632 if test "x$enable_va" = xyes; then
1633     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1634     enable_gallium_loader=$enable_shared_pipe_drivers
1635 fi
1636 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1637
1638 dnl
1639 dnl Nine Direct3D9 configuration
1640 dnl
1641 if test "x$enable_nine" = xyes; then
1642     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1643         AC_MSG_ERROR([nine requires the gallium swrast driver])
1644     fi
1645     if test "x$with_gallium_drivers" = xswrast; then
1646         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1647     fi
1648     if test "x$enable_dri3" = xno; then
1649         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1650     fi
1651
1652     enable_gallium_loader=$enable_shared_pipe_drivers
1653 fi
1654 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1655
1656 dnl
1657 dnl OpenCL configuration
1658 dnl
1659
1660 AC_ARG_WITH([clang-libdir],
1661    [AS_HELP_STRING([--with-clang-libdir],
1662          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1663    [CLANG_LIBDIR="$withval"],
1664    [CLANG_LIBDIR=''])
1665
1666 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1667 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1668
1669 if test "x$enable_opencl" = xyes; then
1670     if test -z "$with_gallium_drivers"; then
1671         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1672     fi
1673
1674     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1675         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1676     fi
1677
1678     if test "x$have_libclc" = xno; then
1679         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1680                     Make sure the directory containing libclc.pc is specified in your
1681                     PKG_CONFIG_PATH environment variable.
1682                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1683     else
1684         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1685         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1686         AC_SUBST([LIBCLC_INCLUDEDIR])
1687         AC_SUBST([LIBCLC_LIBEXECDIR])
1688     fi
1689
1690     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1691     enable_gallium_loader=yes
1692
1693     if test "x$enable_opencl_icd" = xyes; then
1694         OPENCL_LIBNAME="MesaOpenCL"
1695     else
1696         OPENCL_LIBNAME="OpenCL"
1697     fi
1698
1699     if test "x$have_libelf" != xyes; then
1700        AC_MSG_ERROR([Clover requires libelf])
1701     fi
1702 fi
1703 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1704 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1705 AC_SUBST([OPENCL_LIBNAME])
1706
1707 dnl
1708 dnl Gallium configuration
1709 dnl
1710 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1711
1712 AC_SUBST([LLVM_BINDIR])
1713 AC_SUBST([LLVM_CFLAGS])
1714 AC_SUBST([LLVM_CPPFLAGS])
1715 AC_SUBST([LLVM_CXXFLAGS])
1716 AC_SUBST([LLVM_LIBDIR])
1717 AC_SUBST([LLVM_LIBS])
1718 AC_SUBST([LLVM_LDFLAGS])
1719 AC_SUBST([LLVM_INCLUDEDIR])
1720 AC_SUBST([LLVM_VERSION])
1721 AC_SUBST([CLANG_RESOURCE_DIR])
1722
1723 case "x$enable_opengl$enable_gles1$enable_gles2" in
1724 x*yes*)
1725     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1726     ;;
1727 esac
1728
1729 AC_SUBST([VG_LIB_DEPS])
1730 AC_SUBST([EGL_CLIENT_APIS])
1731
1732 dnl
1733 dnl EGL Platforms configuration
1734 dnl
1735 AC_ARG_WITH([egl-platforms],
1736     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1737         [comma delimited native platforms libEGL supports, e.g.
1738         "x11,drm" @<:@default=auto@:>@])],
1739     [with_egl_platforms="$withval"],
1740     [if test "x$enable_egl" = xyes; then
1741         with_egl_platforms="x11"
1742     else
1743         with_egl_platforms=""
1744     fi])
1745
1746 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1747     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1748 fi
1749
1750 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1751         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1752         WAYLAND_SCANNER='')
1753 if test "x$WAYLAND_SCANNER" = x; then
1754     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1755 fi
1756
1757 # Do per-EGL platform setups and checks
1758 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1759 for plat in $egl_platforms; do
1760         case "$plat" in
1761         wayland)
1762                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1763
1764                 if test "x$WAYLAND_SCANNER" = x; then
1765                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1766                 fi
1767                 ;;
1768
1769         x11)
1770                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1771                 ;;
1772
1773         drm)
1774                 test "x$enable_gbm" = "xno" &&
1775                         AC_MSG_ERROR([EGL platform drm needs gbm])
1776                 test "x$have_libdrm" != xyes &&
1777                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1778                 ;;
1779
1780         surfaceless)
1781                 test "x$have_libdrm" != xyes &&
1782                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1783                 ;;
1784
1785         android|gdi|null)
1786                 ;;
1787
1788         *)
1789                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1790                 ;;
1791         esac
1792
1793         case "$plat$need_pci_id$have_pci_id" in
1794                 waylandyesno|drmyesno)
1795                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1796         esac
1797 done
1798
1799 # libEGL wants to default to the first platform specified in
1800 # ./configure.  parse that here.
1801 if test "x$egl_platforms" != "x"; then
1802     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1803     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1804 else
1805     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1806 fi
1807
1808 if echo "$egl_platforms" | grep -q 'x11'; then
1809     NEED_WINSYS_XLIB=yes
1810 fi
1811 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1812 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1813 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1814 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1815 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1816
1817 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1818
1819 AC_SUBST([EGL_NATIVE_PLATFORM])
1820 AC_SUBST([EGL_CFLAGS])
1821
1822 # If we don't have the X11 platform, set this define so we don't try to include
1823 # the X11 headers.
1824 if ! echo "$egl_platforms" | grep -q 'x11'; then
1825     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1826     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1827 fi
1828
1829 dnl
1830 dnl Gallium LLVM
1831 dnl
1832 AC_ARG_ENABLE([gallium-llvm],
1833     [AS_HELP_STRING([--enable-gallium-llvm],
1834         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1835     [enable_gallium_llvm="$enableval"],
1836     [enable_gallium_llvm=auto])
1837
1838 AC_ARG_ENABLE([llvm-shared-libs],
1839     [AS_HELP_STRING([--enable-llvm-shared-libs],
1840         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1841     [enable_llvm_shared_libs="$enableval"],
1842     [enable_llvm_shared_libs=yes])
1843
1844 AC_ARG_WITH([llvm-prefix],
1845     [AS_HELP_STRING([--with-llvm-prefix],
1846         [Prefix for LLVM installations in non-standard locations])],
1847     [llvm_prefix="$withval"],
1848     [llvm_prefix=''])
1849
1850
1851 # Call this inside ` ` to get the return value.
1852 # $1 is the llvm-config command with arguments.
1853 strip_unwanted_llvm_flags() {
1854     # Use \> (marks the end of the word)
1855     echo `$1` | sed \
1856         -e 's/-DNDEBUG\>//g' \
1857         -e 's/-D_GNU_SOURCE\>//g' \
1858         -e 's/-pedantic\>//g' \
1859         -e 's/-Wcovered-switch-default\>//g' \
1860         -e 's/-O.\>//g' \
1861         -e 's/-g\>//g' \
1862         -e 's/-Wall\>//g' \
1863         -e 's/-Wcast-qual\>//g' \
1864         -e 's/-Woverloaded-virtual\>//g' \
1865         -e 's/-fcolor-diagnostics\>//g' \
1866         -e 's/-fdata-sections\>//g' \
1867         -e 's/-ffunction-sections\>//g' \
1868         -e 's/-fno-exceptions\>//g' \
1869         -e 's/-fomit-frame-pointer\>//g' \
1870         -e 's/-fvisibility-inlines-hidden\>//g' \
1871         -e 's/-fPIC\>//g' \
1872         -e 's/-fstack-protector-strong\>//g'
1873 }
1874
1875 llvm_check_version_for() {
1876     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1877         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1878     fi
1879 }
1880
1881
1882
1883 if test -z "$with_gallium_drivers"; then
1884     enable_gallium_llvm=no
1885 fi
1886 if test "x$enable_gallium_llvm" = xauto; then
1887     case "$host_cpu" in
1888     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1889     esac
1890 fi
1891 if test "x$enable_gallium_llvm" = xyes; then
1892     if test -n "$llvm_prefix"; then
1893         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1894     else
1895         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1896     fi
1897
1898     if test "x$LLVM_CONFIG" != xno; then
1899         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1900         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1901         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1902         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1903         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1904         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1905         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1906         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1907
1908         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1909             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1910         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1911             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1912
1913         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1914         if test -z "$LLVM_VERSION_PATCH"; then
1915             LLVM_VERSION_PATCH=0
1916         fi
1917
1918         if test -n "${LLVM_VERSION_MAJOR}"; then
1919             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1920         else
1921             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1922         fi
1923
1924         LLVM_REQUIRED_VERSION_MAJOR="3"
1925         LLVM_REQUIRED_VERSION_MINOR="3"
1926         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1927             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1928         fi
1929
1930         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1931
1932         if test "x$enable_opencl" = xyes; then
1933             llvm_check_version_for "3" "5" "0" "opencl"
1934
1935             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1936             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1937         fi
1938         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1939         MESA_LLVM=1
1940
1941         dnl Check for Clang internal headers
1942         if test "x$enable_opencl" = xyes; then
1943             if test -z "$CLANG_LIBDIR"; then
1944                 CLANG_LIBDIR=${LLVM_LIBDIR}
1945             fi
1946             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1947             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1948                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1949         fi
1950     else
1951         MESA_LLVM=0
1952         LLVM_VERSION_INT=0
1953     fi
1954 else
1955     MESA_LLVM=0
1956     LLVM_VERSION_INT=0
1957
1958     if test "x$enable_opencl" = xyes; then
1959         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1960     fi
1961 fi
1962
1963 dnl Directory for XVMC libs
1964 AC_ARG_WITH([xvmc-libdir],
1965     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1966         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1967     [XVMC_LIB_INSTALL_DIR="$withval"],
1968     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1969 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1970
1971 dnl
1972 dnl Gallium Tests
1973 dnl
1974 if test "x$enable_gallium_tests" = xyes; then
1975     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1976     enable_gallium_loader=yes
1977 fi
1978 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1979
1980 dnl Directory for VDPAU libs
1981 AC_ARG_WITH([vdpau-libdir],
1982     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1983         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1984     [VDPAU_LIB_INSTALL_DIR="$withval"],
1985     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1986 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1987
1988 dnl Directory for OMX libs
1989
1990 AC_ARG_WITH([omx-libdir],
1991     [AS_HELP_STRING([--with-omx-libdir=DIR],
1992         [directory for the OMX libraries])],
1993     [OMX_LIB_INSTALL_DIR="$withval"],
1994     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1995 AC_SUBST([OMX_LIB_INSTALL_DIR])
1996
1997 dnl Directory for VA libs
1998
1999 AC_ARG_WITH([va-libdir],
2000     [AS_HELP_STRING([--with-va-libdir=DIR],
2001         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2002     [VA_LIB_INSTALL_DIR="$withval"],
2003     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2004 AC_SUBST([VA_LIB_INSTALL_DIR])
2005
2006 AC_ARG_WITH([d3d-libdir],
2007     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2008         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2009     [D3D_DRIVER_INSTALL_DIR="$withval"],
2010     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2011 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2012
2013 dnl
2014 dnl Gallium helper functions
2015 dnl
2016 gallium_require_drm() {
2017     if test "x$have_libdrm" != xyes; then
2018        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2019     fi
2020 }
2021
2022 gallium_require_llvm() {
2023     if test "x$MESA_LLVM" = x0; then
2024         case "$host" in *gnux32) return;; esac
2025         case "$host_cpu" in
2026         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2027         esac
2028     fi
2029 }
2030
2031 gallium_require_drm_loader() {
2032     if test "x$enable_gallium_loader" = xyes; then
2033         if test "x$need_pci_id$have_pci_id" = xyesno; then
2034             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2035         fi
2036         enable_gallium_drm_loader=yes
2037     fi
2038     if test "x$enable_va" = xyes && test "x$7" != x; then
2039          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2040     fi
2041 }
2042
2043 require_egl_drm() {
2044     case "$with_egl_platforms" in
2045         *drm*)
2046             ;;
2047          *)
2048             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2049             ;;
2050     esac
2051     if test "x$enable_gbm" != xyes; then
2052             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2053     fi
2054 }
2055
2056 radeon_llvm_check() {
2057     if test ${LLVM_VERSION_INT} -lt 307; then
2058         amdgpu_llvm_target_name='r600'
2059     else
2060         amdgpu_llvm_target_name='amdgpu'
2061     fi
2062     if test "x$enable_gallium_llvm" != "xyes"; then
2063         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2064     fi
2065     llvm_check_version_for "3" "4" "2" $1
2066     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2067         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2068     fi
2069     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2070     NEED_RADEON_LLVM=yes
2071     if test "x$have_libelf" != xyes; then
2072        AC_MSG_ERROR([$1 requires libelf when using llvm])
2073     fi
2074 }
2075
2076 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2077 if test -n "$with_gallium_drivers"; then
2078     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2079     for driver in $gallium_drivers; do
2080         case "x$driver" in
2081         xsvga)
2082             HAVE_GALLIUM_SVGA=yes
2083             gallium_require_drm "svga"
2084             gallium_require_drm_loader
2085             ;;
2086         xi915)
2087             HAVE_GALLIUM_I915=yes
2088             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2089             gallium_require_drm "Gallium i915"
2090             gallium_require_drm_loader
2091             ;;
2092         xilo)
2093             HAVE_GALLIUM_ILO=yes
2094             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2095             gallium_require_drm "Gallium i965/ilo"
2096             gallium_require_drm_loader
2097             ;;
2098         xr300)
2099             HAVE_GALLIUM_R300=yes
2100             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2101             gallium_require_drm "Gallium R300"
2102             gallium_require_drm_loader
2103             gallium_require_llvm "Gallium R300"
2104             ;;
2105         xr600)
2106             HAVE_GALLIUM_R600=yes
2107             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2108             gallium_require_drm "Gallium R600"
2109             gallium_require_drm_loader
2110             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2111                 radeon_llvm_check "r600g"
2112                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2113             fi
2114             if test "x$enable_r600_llvm" = xyes; then
2115                 USE_R600_LLVM_COMPILER=yes;
2116             fi
2117             if test "x$enable_opencl" = xyes; then
2118                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2119             fi
2120             ;;
2121         xradeonsi)
2122             HAVE_GALLIUM_RADEONSI=yes
2123             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2124             gallium_require_drm "radeonsi"
2125             gallium_require_drm_loader
2126             radeon_llvm_check "radeonsi"
2127             require_egl_drm "radeonsi"
2128             ;;
2129         xnouveau)
2130             HAVE_GALLIUM_NOUVEAU=yes
2131             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2132             gallium_require_drm "nouveau"
2133             gallium_require_drm_loader
2134             ;;
2135         xfreedreno)
2136             HAVE_GALLIUM_FREEDRENO=yes
2137             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2138             gallium_require_drm "freedreno"
2139             gallium_require_drm_loader
2140             ;;
2141         xswrast)
2142             HAVE_GALLIUM_SOFTPIPE=yes
2143             if test "x$MESA_LLVM" = x1; then
2144                 HAVE_GALLIUM_LLVMPIPE=yes
2145             fi
2146             ;;
2147         xvc4)
2148             HAVE_GALLIUM_VC4=yes
2149             gallium_require_drm "vc4"
2150             gallium_require_drm_loader
2151
2152             case "$host_cpu" in
2153                 i?86 | x86_64 | amd64)
2154                 USE_VC4_SIMULATOR=yes
2155                 ;;
2156             esac
2157             ;;
2158         *)
2159             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2160             ;;
2161         esac
2162     done
2163 fi
2164
2165 dnl Set LLVM_LIBS - This is done after the driver configuration so
2166 dnl that drivers can add additional components to LLVM_COMPONENTS.
2167 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2168 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2169 dnl this was causing the same libraries to be appear multiple times
2170 dnl in LLVM_LIBS.
2171
2172 if test "x$MESA_LLVM" != x0; then
2173
2174     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2175
2176     if test "x$enable_llvm_shared_libs" = xyes; then
2177         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2178         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2179         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2180
2181         if test "x$llvm_have_one_so" = xyes; then
2182             dnl LLVM was built using auto*, so there is only one shared object.
2183             LLVM_LIBS="-l$LLVM_SO_NAME"
2184         else
2185             dnl If LLVM was built with CMake, there will be one shared object per
2186             dnl component.
2187             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2188                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2189         Please make sure you have built llvm with the --enable-shared option
2190         and that your llvm libraries are installed in $LLVM_LIBDIR
2191         If you have installed your llvm libraries to a different directory you
2192         can use the --with-llvm-prefix= configure flag to specify this directory.
2193         NOTE: Mesa is attempting to use llvm shared libraries by default.
2194         If you do not want to build with llvm shared libraries and instead want to
2195         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2196         invocation and rebuild.])])
2197
2198            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2199            dnl install uses a shared object for each component and we have
2200            dnl already added all of these objects to LLVM_LIBS.
2201         fi
2202     else
2203         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2204         dnl We need to link to llvm system libs when using static libs
2205         dnl However, only llvm 3.5+ provides --system-libs
2206         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2207             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2208         fi
2209     fi
2210 fi
2211
2212 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2213 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2214 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2215 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2216 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2217 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2218 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2219                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2220 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2221 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2222 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2223 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2224 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2225
2226 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2227
2228 # NOTE: anything using xcb or other client side libs ends up in separate
2229 #       _CLIENT variables.  The pipe loader is built in two variants,
2230 #       one that is standalone and does not link any x client libs (for
2231 #       use by XA tracker in particular, but could be used in any case
2232 #       where communication with xserver is not desired).
2233 if test "x$enable_gallium_loader" = xyes; then
2234     if test "x$NEED_WINSYS_XLIB" = xyes; then
2235         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2236     fi
2237
2238     if test "x$enable_dri" = xyes; then
2239         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2240     fi
2241
2242     if test "x$enable_gallium_drm_loader" = xyes; then
2243         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2244         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2245                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2246         if test "x$pipe_loader_have_xcb" = xyes; then
2247             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2248             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2249         fi
2250     fi
2251
2252     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2253     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2254
2255     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2256     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2257     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2258     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2259 fi
2260
2261 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2262 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2263 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2264 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2265 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2266 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2267
2268 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2269                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2270                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2271 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2272 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2273 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2274 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2275 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2276 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2277 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2278 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2279 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2280     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2281 fi
2282
2283 AC_SUBST([ELF_LIB])
2284
2285 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2286 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2287 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2288 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2289 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2290
2291 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2292 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2293 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2294
2295 AC_SUBST([NINE_MAJOR], 1)
2296 AC_SUBST([NINE_MINOR], 0)
2297 AC_SUBST([NINE_TINY], 0)
2298 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2299
2300 AC_SUBST([VDPAU_MAJOR], 1)
2301 AC_SUBST([VDPAU_MINOR], 0)
2302
2303 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2304 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2305 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2306 AC_SUBST([VA_MINOR], $VA_MINOR)
2307
2308 AC_SUBST([XVMC_MAJOR], 1)
2309 AC_SUBST([XVMC_MINOR], 0)
2310
2311 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2312 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2313 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2314 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2315
2316 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2317 AC_SUBST([XA_MINOR], $XA_MINOR)
2318 AC_SUBST([XA_TINY], $XA_TINY)
2319 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2320
2321 dnl Restore LDFLAGS and CPPFLAGS
2322 LDFLAGS="$_SAVE_LDFLAGS"
2323 CPPFLAGS="$_SAVE_CPPFLAGS"
2324
2325 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2326 if test "x$acv_mesa_CLANG" = xyes; then
2327     CFLAGS="$CFLAGS -Qunused-arguments"
2328     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2329 fi
2330
2331 dnl Add user CFLAGS and CXXFLAGS
2332 CFLAGS="$CFLAGS $USER_CFLAGS"
2333 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2334
2335 dnl Substitute the config
2336 AC_CONFIG_FILES([Makefile
2337                 src/Makefile
2338                 src/egl/drivers/dri2/Makefile
2339                 src/egl/main/Makefile
2340                 src/egl/main/egl.pc
2341                 src/egl/wayland/wayland-drm/Makefile
2342                 src/egl/wayland/wayland-egl/Makefile
2343                 src/egl/wayland/wayland-egl/wayland-egl.pc
2344                 src/gallium/Makefile
2345                 src/gallium/auxiliary/Makefile
2346                 src/gallium/auxiliary/pipe-loader/Makefile
2347                 src/gallium/drivers/freedreno/Makefile
2348                 src/gallium/drivers/i915/Makefile
2349                 src/gallium/drivers/ilo/Makefile
2350                 src/gallium/drivers/llvmpipe/Makefile
2351                 src/gallium/drivers/noop/Makefile
2352                 src/gallium/drivers/nouveau/Makefile
2353                 src/gallium/drivers/r300/Makefile
2354                 src/gallium/drivers/r600/Makefile
2355                 src/gallium/drivers/radeon/Makefile
2356                 src/gallium/drivers/radeonsi/Makefile
2357                 src/gallium/drivers/rbug/Makefile
2358                 src/gallium/drivers/softpipe/Makefile
2359                 src/gallium/drivers/svga/Makefile
2360                 src/gallium/drivers/trace/Makefile
2361                 src/gallium/drivers/vc4/Makefile
2362                 src/gallium/state_trackers/clover/Makefile
2363                 src/gallium/state_trackers/dri/Makefile
2364                 src/gallium/state_trackers/glx/xlib/Makefile
2365                 src/gallium/state_trackers/nine/Makefile
2366                 src/gallium/state_trackers/omx/Makefile
2367                 src/gallium/state_trackers/osmesa/Makefile
2368                 src/gallium/state_trackers/va/Makefile
2369                 src/gallium/state_trackers/vdpau/Makefile
2370                 src/gallium/state_trackers/xa/Makefile
2371                 src/gallium/state_trackers/xvmc/Makefile
2372                 src/gallium/targets/d3dadapter9/Makefile
2373                 src/gallium/targets/d3dadapter9/d3d.pc
2374                 src/gallium/targets/dri/Makefile
2375                 src/gallium/targets/libgl-xlib/Makefile
2376                 src/gallium/targets/omx/Makefile
2377                 src/gallium/targets/opencl/Makefile
2378                 src/gallium/targets/osmesa/Makefile
2379                 src/gallium/targets/osmesa/osmesa.pc
2380                 src/gallium/targets/pipe-loader/Makefile
2381                 src/gallium/targets/va/Makefile
2382                 src/gallium/targets/vdpau/Makefile
2383                 src/gallium/targets/xa/Makefile
2384                 src/gallium/targets/xa/xatracker.pc
2385                 src/gallium/targets/xvmc/Makefile
2386                 src/gallium/tests/trivial/Makefile
2387                 src/gallium/tests/unit/Makefile
2388                 src/gallium/winsys/freedreno/drm/Makefile
2389                 src/gallium/winsys/i915/drm/Makefile
2390                 src/gallium/winsys/intel/drm/Makefile
2391                 src/gallium/winsys/nouveau/drm/Makefile
2392                 src/gallium/winsys/radeon/drm/Makefile
2393                 src/gallium/winsys/svga/drm/Makefile
2394                 src/gallium/winsys/sw/dri/Makefile
2395                 src/gallium/winsys/sw/kms-dri/Makefile
2396                 src/gallium/winsys/sw/null/Makefile
2397                 src/gallium/winsys/sw/wrapper/Makefile
2398                 src/gallium/winsys/sw/xlib/Makefile
2399                 src/gallium/winsys/vc4/drm/Makefile
2400                 src/gbm/Makefile
2401                 src/gbm/main/gbm.pc
2402                 src/glsl/Makefile
2403                 src/glx/Makefile
2404                 src/glx/apple/Makefile
2405                 src/glx/tests/Makefile
2406                 src/gtest/Makefile
2407                 src/loader/Makefile
2408                 src/mapi/Makefile
2409                 src/mapi/es1api/glesv1_cm.pc
2410                 src/mapi/es2api/glesv2.pc
2411                 src/mapi/glapi/gen/Makefile
2412                 src/mesa/Makefile
2413                 src/mesa/gl.pc
2414                 src/mesa/drivers/dri/dri.pc
2415                 src/mesa/drivers/dri/common/Makefile
2416                 src/mesa/drivers/dri/common/xmlpool/Makefile
2417                 src/mesa/drivers/dri/i915/Makefile
2418                 src/mesa/drivers/dri/i965/Makefile
2419                 src/mesa/drivers/dri/Makefile
2420                 src/mesa/drivers/dri/nouveau/Makefile
2421                 src/mesa/drivers/dri/r200/Makefile
2422                 src/mesa/drivers/dri/radeon/Makefile
2423                 src/mesa/drivers/dri/swrast/Makefile
2424                 src/mesa/drivers/osmesa/Makefile
2425                 src/mesa/drivers/osmesa/osmesa.pc
2426                 src/mesa/drivers/x11/Makefile
2427                 src/mesa/main/tests/Makefile
2428                 src/util/Makefile
2429                 src/util/tests/hash_table/Makefile])
2430
2431 AC_OUTPUT
2432
2433 dnl
2434 dnl Output some configuration info for the user
2435 dnl
2436 echo ""
2437 echo "        prefix:          $prefix"
2438 echo "        exec_prefix:     $exec_prefix"
2439 echo "        libdir:          $libdir"
2440 echo "        includedir:      $includedir"
2441
2442 dnl API info
2443 echo ""
2444 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2445
2446 dnl Driver info
2447 echo ""
2448 case "x$enable_osmesa$enable_gallium_osmesa" in
2449 xnoyes)
2450         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2451         ;;
2452 xyesno)
2453         echo "        OSMesa:          lib$OSMESA_LIB"
2454         ;;
2455 xnono)
2456         echo "        OSMesa:          no"
2457         ;;
2458 esac
2459
2460 echo ""
2461 if test "x$enable_dri" != xno; then
2462         echo "        DRI platform:    $dri_platform"
2463         if test -z "$DRI_DIRS"; then
2464             echo "        DRI drivers:     no"
2465         else
2466             echo "        DRI drivers:     $DRI_DIRS"
2467         fi
2468         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2469 fi
2470
2471 case "x$enable_glx$enable_xlib_glx" in
2472 xyesyes)
2473     echo "        GLX:             Xlib-based"
2474     ;;
2475 xyesno)
2476     echo "        GLX:             DRI-based"
2477     ;;
2478 *)
2479     echo "        GLX:             $enable_glx"
2480     ;;
2481 esac
2482
2483 dnl EGL
2484 echo ""
2485 echo "        EGL:             $enable_egl"
2486 if test "$enable_egl" = yes; then
2487     echo "        EGL platforms:   $egl_platforms"
2488
2489     egl_drivers=""
2490     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2491         egl_drivers="$egl_drivers builtin:egl_dri2"
2492     fi
2493
2494     echo "        EGL drivers:    $egl_drivers"
2495 fi
2496
2497 echo ""
2498 if test "x$MESA_LLVM" = x1; then
2499     echo "        llvm:            yes"
2500     echo "        llvm-config:     $LLVM_CONFIG"
2501     echo "        llvm-version:    $LLVM_VERSION"
2502 else
2503     echo "        llvm:            no"
2504 fi
2505
2506 echo ""
2507 if test -n "$with_gallium_drivers"; then
2508     echo "        Gallium:         yes"
2509 else
2510     echo "        Gallium:         no"
2511 fi
2512
2513 dnl Shader cache
2514 echo ""
2515 echo "        Shader cache:    $enable_shader_cache"
2516 if test "x$enable_shader_cache" = "xyes"; then
2517     echo "        With SHA1 from:  $with_sha1"
2518 fi
2519
2520 dnl Libraries
2521 echo ""
2522 echo "        Shared libs:     $enable_shared"
2523 echo "        Static libs:     $enable_static"
2524 echo "        Shared-glapi:    $enable_shared_glapi"
2525
2526 dnl Compiler options
2527 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2528 cflags=`echo $CFLAGS | \
2529     $SED 's/^ *//;s/  */ /;s/ *$//'`
2530 cxxflags=`echo $CXXFLAGS | \
2531     $SED 's/^ *//;s/  */ /;s/ *$//'`
2532 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2533 echo ""
2534 echo "        CFLAGS:          $cflags"
2535 echo "        CXXFLAGS:        $cxxflags"
2536 echo "        Macros:          $defines"
2537 echo ""
2538 if test "x$MESA_LLVM" = x1; then
2539     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2540     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2541     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2542     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2543     echo ""
2544 fi
2545 echo "        PYTHON2:         $PYTHON2"
2546
2547 echo ""
2548 echo "        Run '${MAKE-make}' to build Mesa"
2549 echo ""