configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 # Support silent build rules, requires at least automake-1.11. Disable
  50 # by either passing --disable-silent-rules to configure or passing V=1
  51 # to make
  52 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  53     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  54
  55 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  56
  57 dnl Set internal versions
  58 OSMESA_VERSION=8
  59 AC_SUBST([OSMESA_VERSION])
  60
  61 dnl Versions for external dependencies
  62 LIBDRM_REQUIRED=2.4.38
  63 LIBDRM_RADEON_REQUIRED=2.4.56
  64 LIBDRM_INTEL_REQUIRED=2.4.52
  65 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  66 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  67 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  68 DRI2PROTO_REQUIRED=2.6
  69 DRI3PROTO_REQUIRED=1.0
  70 PRESENTPROTO_REQUIRED=1.0
  71 LIBUDEV_REQUIRED=151
  72 GLPROTO_REQUIRED=1.4.14
  73 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  74 LIBVA_REQUIRED=0.35.0
  75 VDPAU_REQUIRED=0.4.1
  76 WAYLAND_REQUIRED=1.2.0
  77 XCB_REQUIRED=1.9.3
  78 XCBDRI2_REQUIRED=1.8
  79 XCBGLX_REQUIRED=1.8.1
  80 XSHMFENCE_REQUIRED=1.1
  81 XVMC_REQUIRED=1.0.6
  82
  83 dnl Check for progs
  84 AC_PROG_CPP
  85 AC_PROG_CC
  86 AC_PROG_CXX
  87 AM_PROG_CC_C_O
  88 AM_PROG_AS
  89 AX_CHECK_GNU_MAKE
  90 AC_CHECK_PROGS([PYTHON2], [python2 python])
  91 AC_PROG_SED
  92 AC_PROG_MKDIR_P
  93
  94 AC_SYS_LARGEFILE
  95
  96 LT_PREREQ([2.2])
  97 LT_INIT([disable-static])
  98
  99 AX_PROG_BISON([],
 100               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 101                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 102 AX_PROG_FLEX([],
 103              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 104                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 105
 106 AC_CHECK_PROG(INDENT, indent, indent, cat)
 107 if test "x$INDENT" != "xcat"; then
 108     # Only GNU indent is supported
 109     INDENT_VERSION=`indent --version | grep GNU`
 110     if test $? -eq 0; then
 111        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 112     else
 113        INDENT="cat"
 114     fi
 115 fi
 116
 117 AX_CHECK_PYTHON_MAKO_MODULE(0.3.4)
 118
 119 AC_PROG_INSTALL
 120
 121 dnl We need a POSIX shell for parts of the build. Assume we have one
 122 dnl in most cases.
 123 case "$host_os" in
 124 solaris*)
 125     # Solaris /bin/sh is too old/non-POSIX compliant
 126     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 127     SHELL="$POSIX_SHELL"
 128     ;;
 129 esac
 130
 131 dnl clang is mostly GCC-compatible, but its version is much lower,
 132 dnl so we have to check for it.
 133 AC_MSG_CHECKING([if compiling with clang])
 134
 135 AC_COMPILE_IFELSE(
 136 [AC_LANG_PROGRAM([], [[
 137 #ifndef __clang__
 138        not clang
 139 #endif
 140 ]])],
 141 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 142
 143 AC_MSG_RESULT([$acv_mesa_CLANG])
 144
 145 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 146 dnl versions are explictly not supported.
 147 GEN_ASM_OFFSETS=no
 148 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 149     AC_MSG_CHECKING([whether gcc version is sufficient])
 150     major=0
 151     minor=0
 152
 153     GCC_VERSION=`$CC -dumpversion`
 154     if test $? -eq 0; then
 155         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 156         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 157     fi
 158
 159     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 160         AC_MSG_RESULT([no])
 161         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 162     else
 163         AC_MSG_RESULT([yes])
 164     fi
 165
 166     if test "x$cross_compiling" = xyes; then
 167         GEN_ASM_OFFSETS=yes
 168     fi
 169 fi
 170
 171 dnl Check for compiler builtins
 172 AX_GCC_BUILTIN([__builtin_bswap32])
 173 AX_GCC_BUILTIN([__builtin_bswap64])
 174 AX_GCC_BUILTIN([__builtin_clz])
 175 AX_GCC_BUILTIN([__builtin_clzll])
 176 AX_GCC_BUILTIN([__builtin_ctz])
 177 AX_GCC_BUILTIN([__builtin_expect])
 178 AX_GCC_BUILTIN([__builtin_ffs])
 179 AX_GCC_BUILTIN([__builtin_ffsll])
 180 AX_GCC_BUILTIN([__builtin_popcount])
 181 AX_GCC_BUILTIN([__builtin_popcountll])
 182 AX_GCC_BUILTIN([__builtin_unreachable])
 183
 184 AX_GCC_FUNC_ATTRIBUTE([flatten])
 185 AX_GCC_FUNC_ATTRIBUTE([format])
 186 AX_GCC_FUNC_ATTRIBUTE([malloc])
 187 AX_GCC_FUNC_ATTRIBUTE([packed])
 188
 189 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 190
 191 dnl Make sure the pkg-config macros are defined
 192 m4_ifndef([PKG_PROG_PKG_CONFIG],
 193     [m4_fatal([Could not locate the pkg-config autoconf macros.
 194   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 195   are in a different location, try setting the environment variable
 196   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 197 PKG_PROG_PKG_CONFIG()
 198
 199 dnl LIB_DIR - library basename
 200 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 201 AC_SUBST([LIB_DIR])
 202
 203 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 204 _SAVE_LDFLAGS="$LDFLAGS"
 205 _SAVE_CPPFLAGS="$CPPFLAGS"
 206
 207 dnl Compiler macros
 208 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 209 AC_SUBST([DEFINES])
 210 case "$host_os" in
 211 linux*|*-gnu*|gnu*)
 212     DEFINES="$DEFINES -D_GNU_SOURCE"
 213     ;;
 214 solaris*)
 215     DEFINES="$DEFINES -DSVR4"
 216     ;;
 217 cygwin*)
 218     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 219     ;;
 220 esac
 221
 222 dnl Add flags for gcc and g++
 223 if test "x$GCC" = xyes; then
 224     CFLAGS="$CFLAGS -Wall -std=c99"
 225
 226     # Enable -Werror=implicit-function-declaration and
 227     # -Werror=missing-prototypes, if available, or otherwise, just
 228     # -Wmissing-prototypes.  This is particularly useful to avoid
 229     # generating a loadable driver module that has undefined symbols.
 230     save_CFLAGS="$CFLAGS"
 231     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 232     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 233     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 234     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 235                    AC_MSG_RESULT([yes]),
 236                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 237                     AC_MSG_RESULT([no])]);
 238
 239     # Enable -fvisibility=hidden if using a gcc that supports it
 240     save_CFLAGS="$CFLAGS"
 241     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 242     VISIBILITY_CFLAGS="-fvisibility=hidden"
 243     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 244     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 245                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 246
 247     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 248     CFLAGS=$save_CFLAGS
 249
 250     # Work around aliasing bugs - developers should comment this out
 251     CFLAGS="$CFLAGS -fno-strict-aliasing"
 252
 253     # gcc's builtin memcmp is slower than glibc's
 254     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 255     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 256 fi
 257 if test "x$GXX" = xyes; then
 258     CXXFLAGS="$CXXFLAGS -Wall"
 259
 260     # Enable -fvisibility=hidden if using a gcc that supports it
 261     save_CXXFLAGS="$CXXFLAGS"
 262     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 263     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 264     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 265     AC_LANG_PUSH([C++])
 266     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 267                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 268     AC_LANG_POP([C++])
 269
 270     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 271     CXXFLAGS=$save_CXXFLAGS
 272
 273     # Work around aliasing bugs - developers should comment this out
 274     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 275
 276     # gcc's builtin memcmp is slower than glibc's
 277     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 278     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 279 fi
 280
 281 dnl even if the compiler appears to support it, using visibility attributes isn't
 282 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 283 case "$host_os" in
 284 cygwin*)
 285     VISIBILITY_CFLAGS=""
 286     VISIBILITY_CXXFLAGS=""
 287     ;;
 288 esac
 289
 290 AC_SUBST([VISIBILITY_CFLAGS])
 291 AC_SUBST([VISIBILITY_CXXFLAGS])
 292
 293 dnl
 294 dnl Optional flags, check for compiler support
 295 dnl
 296 SSE41_CFLAGS="-msse4.1"
 297 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 298 dnl stack, but on x86-32 such alignment is not guaranteed.
 299 case "$target_cpu" in
 300 i?86)
 301     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 302     ;;
 303 esac
 304 save_CFLAGS="$CFLAGS"
 305 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 306 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 307 #include <smmintrin.h>
 308 int main () {
 309     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 310     c = _mm_max_epu32(a, b);
 311     return 0;
 312 }]])], SSE41_SUPPORTED=1)
 313 CFLAGS="$save_CFLAGS"
 314 if test "x$SSE41_SUPPORTED" = x1; then
 315     DEFINES="$DEFINES -DUSE_SSE41"
 316 fi
 317 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 318 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 319
 320 dnl Can't have static and shared libraries, default to static if user
 321 dnl explicitly requested. If both disabled, set to static since shared
 322 dnl was explicitly requested.
 323 case "x$enable_static$enable_shared" in
 324 xyesyes)
 325     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 326     enable_shared=no
 327     ;;
 328 xnono)
 329     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 330     enable_shared=yes
 331     ;;
 332 esac
 333
 334 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 335
 336 dnl
 337 dnl other compiler options
 338 dnl
 339 AC_ARG_ENABLE([debug],
 340     [AS_HELP_STRING([--enable-debug],
 341         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 342     [enable_debug="$enableval"],
 343     [enable_debug=no]
 344 )
 345 if test "x$enable_debug" = xyes; then
 346     DEFINES="$DEFINES -DDEBUG"
 347     if test "x$GCC" = xyes; then
 348         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 349             CFLAGS="$CFLAGS -g"
 350         fi
 351         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 352             CFLAGS="$CFLAGS -O0"
 353         fi
 354     fi
 355     if test "x$GXX" = xyes; then
 356         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 357             CXXFLAGS="$CXXFLAGS -g"
 358         fi
 359         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 360             CXXFLAGS="$CXXFLAGS -O0"
 361         fi
 362     fi
 363 fi
 364
 365 dnl
 366 dnl Check if linker supports -Bsymbolic
 367 dnl
 368 save_LDFLAGS=$LDFLAGS
 369 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 370 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 371 AC_LINK_IFELSE(
 372     [AC_LANG_SOURCE([int main() { return 0;}])],
 373     [AC_MSG_RESULT([yes])
 374         BSYMBOLIC="-Wl,-Bsymbolic";],
 375     [AC_MSG_RESULT([no])
 376         BSYMBOLIC="";])
 377 LDFLAGS=$save_LDFLAGS
 378
 379 AC_SUBST([BSYMBOLIC])
 380
 381 dnl
 382 dnl Check if linker supports garbage collection
 383 dnl
 384 save_LDFLAGS=$LDFLAGS
 385 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 386 AC_MSG_CHECKING([whether ld supports --gc-sections])
 387 AC_LINK_IFELSE(
 388     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 389     [AC_MSG_RESULT([yes])
 390         GC_SECTIONS="-Wl,--gc-sections";],
 391     [AC_MSG_RESULT([no])
 392         GC_SECTIONS="";])
 393 LDFLAGS=$save_LDFLAGS
 394
 395 AC_SUBST([GC_SECTIONS])
 396
 397 dnl
 398 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 399 dnl so when these flags are passed to ld via libtool the checks will fail
 400 dnl
 401 case "$host_os" in
 402 openbsd* | darwin* )
 403     LD_NO_UNDEFINED="" ;;
 404 *)
 405     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 406 esac
 407
 408 AC_SUBST([LD_NO_UNDEFINED])
 409
 410 dnl
 411 dnl Check if linker supports version scripts
 412 dnl
 413 AC_MSG_CHECKING([if the linker supports version-scripts])
 414 save_LDFLAGS=$LDFLAGS
 415 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 416 cat > conftest.map <<EOF
 417 VERSION_1 {
 418      global:
 419          main;
 420
 421      local:
 422          *;
 423 };
 424 EOF
 425 AC_LINK_IFELSE(
 426     [AC_LANG_SOURCE([int main() { return 0;}])],
 427     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 428     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 429 LDFLAGS=$save_LDFLAGS
 430 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 431
 432 dnl
 433 dnl Check if linker supports dynamic list files
 434 dnl
 435 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 436 save_LDFLAGS=$LDFLAGS
 437 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 438 cat > conftest.dyn <<EOF
 439 {
 440         radeon_drm_winsys_create;
 441 };
 442 EOF
 443 AC_LINK_IFELSE(
 444     [AC_LANG_SOURCE([int main() { return 0;}])],
 445     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 446     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 447 LDFLAGS=$save_LDFLAGS
 448 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 449
 450 dnl
 451 dnl compatibility symlinks
 452 dnl
 453 case "$host_os" in
 454 linux* )
 455     HAVE_COMPAT_SYMLINKS=yes ;;
 456 * )
 457     HAVE_COMPAT_SYMLINKS=no ;;
 458 esac
 459
 460 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 461
 462 dnl
 463 dnl library names
 464 dnl
 465 case "$host_os" in
 466 darwin* )
 467     LIB_EXT='dylib' ;;
 468 cygwin* )
 469     LIB_EXT='dll' ;;
 470 aix* )
 471     LIB_EXT='a' ;;
 472 * )
 473     LIB_EXT='so' ;;
 474 esac
 475
 476 AC_SUBST([LIB_EXT])
 477
 478 AC_ARG_WITH([gl-lib-name],
 479   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 480     [specify GL library name @<:@default=GL@:>@])],
 481   [GL_LIB=$withval],
 482   [GL_LIB=GL])
 483 AC_ARG_WITH([osmesa-lib-name],
 484   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 485     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 486   [OSMESA_LIB=$withval],
 487   [OSMESA_LIB=OSMesa])
 488 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 489 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 490
 491 dnl
 492 dnl Mangled Mesa support
 493 dnl
 494 AC_ARG_ENABLE([mangling],
 495   [AS_HELP_STRING([--enable-mangling],
 496     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 497   [enable_mangling="${enableval}"],
 498   [enable_mangling=no]
 499 )
 500 if test "x${enable_mangling}" = "xyes" ; then
 501   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 502   GL_LIB="Mangled${GL_LIB}"
 503   OSMESA_LIB="Mangled${OSMESA_LIB}"
 504 fi
 505 AC_SUBST([GL_LIB])
 506 AC_SUBST([OSMESA_LIB])
 507
 508 dnl
 509 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 510 dnl
 511 AC_ARG_ENABLE([texture-float],
 512     [AS_HELP_STRING([--enable-texture-float],
 513         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 514     [enable_texture_float="$enableval"],
 515     [enable_texture_float=no]
 516 )
 517 if test "x$enable_texture_float" = xyes; then
 518     AC_MSG_WARN([Floating-point textures enabled.])
 519     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 520     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 521 fi
 522
 523 dnl
 524 dnl Arch/platform-specific settings
 525 dnl
 526 AC_ARG_ENABLE([asm],
 527     [AS_HELP_STRING([--disable-asm],
 528         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 529     [enable_asm="$enableval"],
 530     [enable_asm=yes]
 531 )
 532 asm_arch=""
 533 AC_MSG_CHECKING([whether to enable assembly])
 534 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 535 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 536 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 537     case "$host_cpu" in
 538     i?86 | x86_64 | amd64)
 539         enable_asm=no
 540         AC_MSG_RESULT([no, cross compiling])
 541         ;;
 542     esac
 543 fi
 544 # check for supported arches
 545 if test "x$enable_asm" = xyes; then
 546     case "$host_cpu" in
 547     i?86)
 548         case "$host_os" in
 549         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 550             asm_arch=x86
 551             ;;
 552         esac
 553         ;;
 554     x86_64|amd64)
 555         case "$host_os" in
 556         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 557             asm_arch=x86_64
 558             ;;
 559         esac
 560         ;;
 561     sparc*)
 562         case "$host_os" in
 563         linux*)
 564             asm_arch=sparc
 565             ;;
 566         esac
 567         ;;
 568     esac
 569
 570     case "$asm_arch" in
 571     x86)
 572         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 573         AC_MSG_RESULT([yes, x86])
 574         ;;
 575     x86_64|amd64)
 576         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 577         AC_MSG_RESULT([yes, x86_64])
 578         ;;
 579     sparc)
 580         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 581         AC_MSG_RESULT([yes, sparc])
 582         ;;
 583     *)
 584         AC_MSG_RESULT([no, platform not supported])
 585         ;;
 586     esac
 587 fi
 588
 589 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 590 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 591
 592 dnl Check to see if dlopen is in default libraries (like Solaris, which
 593 dnl has it in libc), or if libdl is needed to get it.
 594 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 595     [AC_CHECK_LIB([dl], [dlopen],
 596        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 597 AC_SUBST([DLOPEN_LIBS])
 598
 599 dnl Check if that library also has dladdr
 600 save_LIBS="$LIBS"
 601 LIBS="$LIBS $DLOPEN_LIBS"
 602 AC_CHECK_FUNCS([dladdr])
 603 LIBS="$save_LIBS"
 604
 605 case "$host_os" in
 606 darwin*|mingw*)
 607     ;;
 608 *)
 609     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 610                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 611                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 612     AC_SUBST([CLOCK_LIB])
 613     ;;
 614 esac
 615
 616 dnl See if posix_memalign is available
 617 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 618
 619 dnl Check for pthreads
 620 case "$host_os" in
 621 mingw*)
 622     ;;
 623 *)
 624     AX_PTHREAD
 625     ;;
 626 esac
 627 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 628 dnl to -pthread, which causes problems if we need -lpthread to appear in
 629 dnl pkgconfig files.
 630 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 631
 632 dnl SELinux awareness.
 633 AC_ARG_ENABLE([selinux],
 634     [AS_HELP_STRING([--enable-selinux],
 635         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 636     [MESA_SELINUX="$enableval"],
 637     [MESA_SELINUX=no])
 638 if test "x$enable_selinux" = "xyes"; then
 639     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 640         [AC_CHECK_HEADER([selinux/selinux.h],[],
 641                          [AC_MSG_ERROR([SELinux headers not found])])
 642          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 643                       [AC_MSG_ERROR([SELinux library not found])])
 644          SELINUX_LIBS="-lselinux"])
 645     DEFINES="$DEFINES -DMESA_SELINUX"
 646 fi
 647 AC_SUBST([SELINUX_CFLAGS])
 648 AC_SUBST([SELINUX_LIBS])
 649
 650 dnl Options for APIs
 651 AC_ARG_ENABLE([opengl],
 652     [AS_HELP_STRING([--disable-opengl],
 653         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 654     [enable_opengl="$enableval"],
 655     [enable_opengl=yes])
 656 AC_ARG_ENABLE([gles1],
 657     [AS_HELP_STRING([--enable-gles1],
 658         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 659     [enable_gles1="$enableval"],
 660     [enable_gles1=no])
 661 AC_ARG_ENABLE([gles2],
 662     [AS_HELP_STRING([--enable-gles2],
 663         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 664     [enable_gles2="$enableval"],
 665     [enable_gles2=no])
 666 AC_ARG_ENABLE([openvg],
 667     [AS_HELP_STRING([--enable-openvg],
 668         [enable support for OpenVG API @<:@default=disabled@:>@])],
 669     [enable_openvg="$enableval"],
 670     [enable_openvg=no])
 671
 672 AC_ARG_ENABLE([dri],
 673     [AS_HELP_STRING([--enable-dri],
 674         [enable DRI modules @<:@default=enabled@:>@])],
 675     [enable_dri="$enableval"],
 676     [enable_dri=yes])
 677
 678 case "$host_os" in
 679 linux*)
 680     dri3_default=yes
 681     ;;
 682 *)
 683     dri3_default=no
 684     ;;
 685 esac
 686 AC_ARG_ENABLE([dri3],
 687     [AS_HELP_STRING([--enable-dri3],
 688         [enable DRI3 @<:@default=auto@:>@])],
 689     [enable_dri3="$enableval"],
 690     [enable_dri3="$dri3_default"])
 691 AC_ARG_ENABLE([glx],
 692     [AS_HELP_STRING([--enable-glx],
 693         [enable GLX library @<:@default=enabled@:>@])],
 694     [enable_glx="$enableval"],
 695     [enable_glx=yes])
 696 AC_ARG_ENABLE([osmesa],
 697     [AS_HELP_STRING([--enable-osmesa],
 698         [enable OSMesa library @<:@default=disabled@:>@])],
 699     [enable_osmesa="$enableval"],
 700     [enable_osmesa=no])
 701 AC_ARG_ENABLE([gallium-osmesa],
 702     [AS_HELP_STRING([--enable-gallium-osmesa],
 703         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 704     [enable_gallium_osmesa="$enableval"],
 705     [enable_gallium_osmesa=no])
 706 AC_ARG_ENABLE([egl],
 707     [AS_HELP_STRING([--disable-egl],
 708         [disable EGL library @<:@default=enabled@:>@])],
 709     [enable_egl="$enableval"],
 710     [enable_egl=yes])
 711
 712 AC_ARG_ENABLE([xa],
 713     [AS_HELP_STRING([--enable-xa],
 714         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 715     [enable_xa="$enableval"],
 716     [enable_xa=no])
 717 AC_ARG_ENABLE([gbm],
 718    [AS_HELP_STRING([--enable-gbm],
 719          [enable gbm library @<:@default=auto@:>@])],
 720    [enable_gbm="$enableval"],
 721    [enable_gbm=auto])
 722 AC_ARG_ENABLE([nine],
 723     [AS_HELP_STRING([--enable-nine],
 724         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 725     [enable_nine="$enableval"],
 726     [enable_nine=no])
 727
 728 AC_ARG_ENABLE([xvmc],
 729    [AS_HELP_STRING([--enable-xvmc],
 730          [enable xvmc library @<:@default=auto@:>@])],
 731    [enable_xvmc="$enableval"],
 732    [enable_xvmc=auto])
 733 AC_ARG_ENABLE([vdpau],
 734    [AS_HELP_STRING([--enable-vdpau],
 735          [enable vdpau library @<:@default=auto@:>@])],
 736    [enable_vdpau="$enableval"],
 737    [enable_vdpau=auto])
 738 AC_ARG_ENABLE([omx],
 739    [AS_HELP_STRING([--enable-omx],
 740          [enable OpenMAX library @<:@default=disabled@:>@])],
 741    [enable_omx="$enableval"],
 742    [enable_omx=no])
 743 AC_ARG_ENABLE([va],
 744    [AS_HELP_STRING([--enable-va],
 745          [enable va library @<:@default=auto@:>@])],
 746    [enable_va="$enableval"],
 747    [enable_va=auto])
 748 AC_ARG_ENABLE([opencl],
 749    [AS_HELP_STRING([--enable-opencl],
 750          [enable OpenCL library @<:@default=disabled@:>@])],
 751    [enable_opencl="$enableval"],
 752    [enable_opencl=no])
 753 AC_ARG_ENABLE([opencl_icd],
 754    [AS_HELP_STRING([--enable-opencl-icd],
 755           [Build an OpenCL ICD library to be loaded by an ICD implementation
 756            @<:@default=disabled@:>@])],
 757     [enable_opencl_icd="$enableval"],
 758     [enable_opencl_icd=no])
 759 AC_ARG_ENABLE([xlib-glx],
 760     [AS_HELP_STRING([--enable-xlib-glx],
 761         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 762     [enable_xlib_glx="$enableval"],
 763     [enable_xlib_glx=no])
 764
 765 AC_ARG_ENABLE([r600-llvm-compiler],
 766     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 767         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 768     [enable_r600_llvm="$enableval"],
 769     [enable_r600_llvm=no])
 770
 771 AC_ARG_ENABLE([gallium-tests],
 772     [AS_HELP_STRING([--enable-gallium-tests],
 773         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 774     [enable_gallium_tests="$enableval"],
 775     [enable_gallium_tests=no])
 776
 777 # Option for Gallium drivers
 778
 779 # Keep this in sync with the --with-gallium-drivers help string default value
 780 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 781
 782 AC_ARG_WITH([gallium-drivers],
 783     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 784         [comma delimited Gallium drivers list, e.g.
 785         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 786         @<:@default=r300,r600,svga,swrast@:>@])],
 787     [with_gallium_drivers="$withval"],
 788     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 789
 790 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 791 # here so that the script doesn't choke on an unknown driver name later.
 792 case "$with_gallium_drivers" in
 793     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 794     no) with_gallium_drivers='' ;;
 795 esac
 796
 797 if test "x$enable_opengl" = xno -a \
 798         "x$enable_gles1" = xno -a \
 799         "x$enable_gles2" = xno -a \
 800         "x$enable_nine" = xno -a \
 801         "x$enable_openvg" = xno -a \
 802         "x$enable_xa" = xno -a \
 803         "x$enable_xvmc" = xno -a \
 804         "x$enable_vdpau" = xno -a \
 805         "x$enable_omx" = xno -a \
 806         "x$enable_va" = xno -a \
 807         "x$enable_opencl" = xno; then
 808     AC_MSG_ERROR([at least one API should be enabled])
 809 fi
 810
 811 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 812 if test "x$enable_opengl" = xno -a \
 813         "x$enable_gles1" = xyes; then
 814     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 815 fi
 816
 817 if test "x$enable_opengl" = xno -a \
 818         "x$enable_gles2" = xyes; then
 819     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 820 fi
 821
 822 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 823 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 824 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 825 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 826                                         "x$enable_gles1" = xyes -o \
 827                                         "x$enable_gles2" = xyes)
 828
 829 if test "x$enable_glx" = xno; then
 830     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 831     enable_xlib_glx=no
 832 fi
 833
 834 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 835     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 836 fi
 837
 838 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 839     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 840 fi
 841
 842 # Disable GLX if OpenGL is not enabled
 843 if test "x$enable_glx$enable_opengl" = xyesno; then
 844     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 845     enable_glx=no
 846 fi
 847
 848 # Disable GLX if DRI and Xlib-GLX are not enabled
 849 if test "x$enable_glx" = xyes -a \
 850         "x$enable_dri" = xno -a \
 851         "x$enable_xlib_glx" = xno; then
 852     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 853     enable_glx=no
 854 fi
 855
 856 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 857                                   "x$enable_dri" = xyes)
 858
 859 # Select which platform-dependent DRI code gets built
 860 case "$host_os" in
 861 darwin*)
 862     dri_platform='apple' ;;
 863 gnu*|mingw*|cygwin*)
 864     dri_platform='none' ;;
 865 *)
 866     dri_platform='drm' ;;
 867 esac
 868
 869 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 870 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 871 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 872 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 873 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 874
 875 AC_ARG_ENABLE([shared-glapi],
 876     [AS_HELP_STRING([--enable-shared-glapi],
 877         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 878     [enable_shared_glapi="$enableval"],
 879     [enable_shared_glapi=yes])
 880
 881 case "x$enable_opengl$enable_gles1$enable_gles2" in
 882 x*yes*yes*)
 883     if test "x$enable_shared_glapi" = xno; then
 884         AC_MSG_ERROR([shared GLAPI required when building two or more of
 885                       the following APIs - opengl, gles1 gles2])
 886     fi
 887     ;;
 888 esac
 889
 890 # Building Xlib-GLX requires shared glapi to be disabled.
 891 if test "x$enable_xlib_glx" = xyes; then
 892     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 893     enable_shared_glapi=no
 894 fi
 895
 896 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 897
 898 # Build the pipe-drivers as separate libraries/modules.
 899 # Do not touch this unless you know what you are doing.
 900 # XXX: Expose via configure option ?
 901 enable_shared_pipe_drivers=no
 902
 903 dnl
 904 dnl Driver specific build directories
 905 dnl
 906
 907 case "x$enable_glx$enable_xlib_glx" in
 908 xyesyes)
 909     NEED_WINSYS_XLIB="yes"
 910     ;;
 911 esac
 912
 913 if test "x$enable_dri" = xyes; then
 914     enable_gallium_loader="$enable_shared_pipe_drivers"
 915 fi
 916
 917 if test "x$enable_gallium_osmesa" = xyes; then
 918     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 919         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 920     fi
 921     if test "x$enable_osmesa" = xyes; then
 922         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 923     fi
 924 fi
 925
 926 AC_SUBST([MESA_LLVM])
 927
 928 # SHA1 hashing
 929 AC_ARG_WITH([sha1],
 930         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 931         [choose SHA1 implementation])])
 932 case "x$with_sha1" in
 933 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 934   ;;
 935 *)
 936         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 937 esac
 938
 939 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 940 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 941         with_sha1=libc
 942 fi
 943 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 944         AC_MSG_ERROR([sha1 in libc requested but not found])
 945 fi
 946 if test "x$with_sha1" = xlibc; then
 947         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 948                 [Use libc SHA1 functions])
 949         SHA1_LIBS=""
 950 fi
 951 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 952 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 953         with_sha1=CommonCrypto
 954 fi
 955 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
 956         AC_MSG_ERROR([CommonCrypto requested but not found])
 957 fi
 958 if test "x$with_sha1" = xCommonCrypto; then
 959         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
 960                 [Use CommonCrypto SHA1 functions])
 961         SHA1_LIBS=""
 962 fi
 963 dnl stdcall functions cannot be tested with AC_CHECK_LIB
 964 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
 965 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
 966         with_sha1=CryptoAPI
 967 fi
 968 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
 969         AC_MSG_ERROR([CryptoAPI requested but not found])
 970 fi
 971 if test "x$with_sha1" = xCryptoAPI; then
 972         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
 973                 [Use CryptoAPI SHA1 functions])
 974         SHA1_LIBS=""
 975 fi
 976 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
 977 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
 978         with_sha1=libmd
 979 fi
 980 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
 981         AC_MSG_ERROR([libmd requested but not found])
 982 fi
 983 if test "x$with_sha1" = xlibmd; then
 984         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
 985                   [Use libmd SHA1 functions])
 986         SHA1_LIBS=-lmd
 987 fi
 988 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
 989 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
 990    with_sha1=libsha1
 991 fi
 992 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
 993         AC_MSG_ERROR([libsha1 requested but not found])
 994 fi
 995 if test "x$with_sha1" = xlibsha1; then
 996         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
 997                   [Use libsha1 for SHA1])
 998         SHA1_LIBS=-lsha1
 999 fi
1000 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1001 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1002         with_sha1=libnettle
1003 fi
1004 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1005         AC_MSG_ERROR([libnettle requested but not found])
1006 fi
1007 if test "x$with_sha1" = xlibnettle; then
1008         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1009                   [Use libnettle SHA1 functions])
1010         SHA1_LIBS=-lnettle
1011 fi
1012 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1013 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1014         with_sha1=libgcrypt
1015 fi
1016 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1017         AC_MSG_ERROR([libgcrypt requested but not found])
1018 fi
1019 if test "x$with_sha1" = xlibgcrypt; then
1020         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1021                   [Use libgcrypt SHA1 functions])
1022         SHA1_LIBS=-lgcrypt
1023 fi
1024 # We don't need all of the OpenSSL libraries, just libcrypto
1025 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1026 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1027                   [HAVE_OPENSSL_PKC=no])
1028 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1029         if test "x$with_sha1" = x; then
1030                 with_sha1=libcrypto
1031         fi
1032 else
1033         if test "x$with_sha1" = xlibcrypto; then
1034                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1035         fi
1036 fi
1037 if test "x$with_sha1" = xlibcrypto; then
1038         if test "x$HAVE_LIBCRYPTO" = xyes; then
1039                 SHA1_LIBS=-lcrypto
1040         else
1041                 SHA1_LIBS="$OPENSSL_LIBS"
1042                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1043         fi
1044 fi
1045 AC_MSG_CHECKING([for SHA1 implementation])
1046 AC_MSG_RESULT([$with_sha1])
1047 AC_SUBST(SHA1_LIBS)
1048 AC_SUBST(SHA1_CFLAGS)
1049
1050 # Allow user to configure out the shader-cache feature
1051 AC_ARG_ENABLE([shader-cache],
1052     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1053     [enable_shader_cache="$enableval"],
1054     [if test "x$with_sha1" != "x"; then
1055         enable_shader_cache=yes
1056      else
1057         enable_shader_cache=no
1058      fi])
1059 if test "x$with_sha1" = "x"; then
1060     if test "x$enable_shader_cache" = "xyes"; then
1061         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1062     fi
1063 fi
1064 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1065
1066 # Check for libdrm
1067 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1068                   [have_libdrm=yes], [have_libdrm=no])
1069 if test "x$have_libdrm" = xyes; then
1070         DEFINES="$DEFINES -DHAVE_LIBDRM"
1071 fi
1072
1073 case "$host_os" in
1074 linux*)
1075     need_pci_id=yes ;;
1076 *)
1077     need_pci_id=no ;;
1078 esac
1079
1080 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1081                   have_libudev=yes, have_libudev=no)
1082
1083 AC_ARG_ENABLE([sysfs],
1084     [AS_HELP_STRING([--enable-sysfs],
1085         [enable /sys PCI identification @<:@default=disabled@:>@])],
1086     [have_sysfs="$enableval"],
1087     [have_sysfs=no]
1088 )
1089
1090 if test "x$enable_dri" = xyes; then
1091     if test "$enable_static" = yes; then
1092         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1093     fi
1094
1095     # not a hard requirement as swrast does not depend on it
1096     if test "x$have_libdrm" = xyes; then
1097         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1098     fi
1099 fi
1100
1101 AC_ARG_ENABLE([driglx-direct],
1102     [AS_HELP_STRING([--disable-driglx-direct],
1103         [disable direct rendering in GLX and EGL for DRI \
1104             @<:@default=auto@:>@])],
1105     [driglx_direct="$enableval"],
1106     [driglx_direct="yes"])
1107
1108 dnl
1109 dnl libGL configuration per driver
1110 dnl
1111 case "x$enable_glx$enable_xlib_glx" in
1112 xyesyes)
1113     # Xlib-based GLX
1114     dri_modules="x11 xext xcb"
1115     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1116     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1117     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1118     GL_LIB_DEPS="$XLIBGL_LIBS"
1119     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1120     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1121     ;;
1122 xyesno)
1123     # DRI-based GLX
1124     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1125
1126     # find the DRI deps for libGL
1127     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1128
1129     if test x"$driglx_direct" = xyes; then
1130         if test x"$dri_platform" = xdrm ; then
1131             DEFINES="$DEFINES -DGLX_USE_DRM"
1132             if test "x$have_libdrm" != xyes; then
1133                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1134             fi
1135
1136             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1137             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1138             if test x"$enable_dri3" = xyes; then
1139                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1140                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1141             fi
1142
1143             if test x"$enable_dri" = xyes; then
1144                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1145             fi
1146
1147             if test x"$enable_dri3" = xyes; then
1148                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1149                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1150             fi
1151         fi
1152         if test x"$dri_platform" = xapple ; then
1153             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1154         fi
1155     fi
1156
1157     # add xf86vidmode if available
1158     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1159     if test "$HAVE_XF86VIDMODE" = yes ; then
1160         dri_modules="$dri_modules xxf86vm"
1161     fi
1162
1163     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1164     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1165     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1166     GL_LIB_DEPS="$DRIGL_LIBS"
1167
1168     # need DRM libs, $PTHREAD_LIBS, etc.
1169     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1170     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1171     ;;
1172 esac
1173
1174 have_pci_id=no
1175 if test "$have_libudev" = yes; then
1176     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1177     have_pci_id=yes
1178 fi
1179
1180 if test "$have_sysfs" = yes; then
1181     DEFINES="$DEFINES -DHAVE_SYSFS"
1182     have_pci_id=yes
1183 fi
1184
1185 # This is outside the case (above) so that it is invoked even for non-GLX
1186 # builds.
1187 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1188
1189 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1190 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1191 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1192 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1193
1194 AC_SUBST([X11_INCLUDES])
1195 AC_SUBST([GL_LIB_DEPS])
1196 AC_SUBST([GL_PC_REQ_PRIV])
1197 AC_SUBST([GL_PC_LIB_PRIV])
1198 AC_SUBST([GL_PC_CFLAGS])
1199 AC_SUBST([DRI_PC_REQ_PRIV])
1200 AC_SUBST([GLESv1_CM_LIB_DEPS])
1201 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1202 AC_SUBST([GLESv2_LIB_DEPS])
1203 AC_SUBST([GLESv2_PC_LIB_PRIV])
1204
1205 AC_SUBST([HAVE_XF86VIDMODE])
1206
1207 dnl
1208 dnl More GLX setup
1209 dnl
1210 case "x$enable_glx$enable_xlib_glx" in
1211 xyesyes)
1212     DEFINES="$DEFINES -DUSE_XSHM"
1213     ;;
1214 xyesno)
1215     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1216     if test "x$driglx_direct" = xyes; then
1217         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1218     fi
1219     ;;
1220 esac
1221
1222 dnl
1223 dnl TLS detection
1224 dnl
1225
1226 AC_ARG_ENABLE([glx-tls],
1227     [AS_HELP_STRING([--enable-glx-tls],
1228         [enable TLS support in GLX @<:@default=disabled@:>@])],
1229     [GLX_USE_TLS="$enableval"],
1230     [GLX_USE_TLS=no])
1231 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1232
1233 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1234       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1235
1236 dnl
1237 dnl More DRI setup
1238 dnl
1239 dnl Directory for DRI drivers
1240 AC_ARG_WITH([dri-driverdir],
1241     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1242         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1243     [DRI_DRIVER_INSTALL_DIR="$withval"],
1244     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1245 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1246 dnl Extra search path for DRI drivers
1247 AC_ARG_WITH([dri-searchpath],
1248     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1249         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1250     [DRI_DRIVER_SEARCH_DIR="$withval"],
1251     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1252 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1253 dnl Which drivers to build - default is chosen by platform
1254 AC_ARG_WITH([dri-drivers],
1255     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1256         [comma delimited classic DRI drivers list, e.g.
1257         "swrast,i965,radeon" @<:@default=auto@:>@])],
1258     [with_dri_drivers="$withval"],
1259     [with_dri_drivers=auto])
1260
1261 if test "x$with_dri_drivers" = xauto; then
1262     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1263         with_dri_drivers="yes"
1264     else
1265         with_dri_drivers="no"
1266     fi
1267 fi
1268 if test "x$with_dri_drivers" = xno; then
1269     with_dri_drivers=''
1270 fi
1271
1272 dnl If $with_dri_drivers is yes, drivers will be added through
1273 dnl platform checks. Set DEFINES and LIB_DEPS
1274 if test "x$enable_dri" = xyes; then
1275     # Platform specific settings and drivers to build
1276     case "$host_os" in
1277     linux*)
1278         DEFINES="$DEFINES -DHAVE_ALIAS"
1279         if test "x$enable_dri3" = xyes; then
1280             DEFINES="$DEFINES -DHAVE_DRI3"
1281         fi
1282
1283         if test "x$have_pci_id" != xyes; then
1284             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1285         fi
1286
1287         case "$host_cpu" in
1288         powerpc* | sparc*)
1289             # Build only the drivers for cards that exist on PowerPC/sparc
1290             if test "x$with_dri_drivers" = "xyes"; then
1291                 with_dri_drivers="r200 radeon swrast"
1292             fi
1293             ;;
1294         esac
1295         ;;
1296     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1297         DEFINES="$DEFINES -DHAVE_ALIAS"
1298         ;;
1299     gnu*)
1300         DEFINES="$DEFINES -DHAVE_ALIAS"
1301         ;;
1302     cygwin*)
1303         if test "x$with_dri_drivers" = "xyes"; then
1304             with_dri_drivers="swrast"
1305         fi
1306         ;;
1307     darwin*)
1308         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1309         if test "x$with_dri_drivers" = "xyes"; then
1310             with_dri_drivers="swrast"
1311         fi
1312         ;;
1313     esac
1314
1315     # default drivers
1316     if test "x$with_dri_drivers" = "xyes"; then
1317         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1318     fi
1319
1320     # Check for expat
1321     PKG_CHECK_MODULES([EXPAT], [expat], [],
1322         # expat version 2.0 and earlier do not provide expat.pc
1323         [AC_CHECK_HEADER([expat.h],[],
1324                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1325          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1326                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1327          EXPAT_LIBS="-lexpat"])
1328
1329     DRICOMMON_NEED_LIBDRM=no
1330     # If we are building any DRI driver other than swrast.
1331     if test -n "$with_dri_drivers"; then
1332         if test "x$with_dri_drivers" != xswrast; then
1333             # ... libdrm is required
1334             if test "x$have_libdrm" != xyes; then
1335                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1336             fi
1337             DRICOMMON_NEED_LIBDRM=yes
1338         fi
1339     fi
1340
1341     # If we're building any gallium DRI driver other than swrast
1342     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1343         if test "x$with_gallium_drivers" != xswrast; then
1344             # ... build a libdrm aware dricommon
1345             DRICOMMON_NEED_LIBDRM=yes
1346         fi
1347     fi
1348
1349     # put all the necessary libs together
1350     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1351 fi
1352
1353 AC_SUBST([DRI_LIB_DEPS])
1354
1355 DRI_DIRS=''
1356 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1357 if test -n "$with_dri_drivers"; then
1358     if test "x$enable_opengl" != xyes; then
1359         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1360     fi
1361
1362     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1363     for driver in $dri_drivers; do
1364         DRI_DIRS="$DRI_DIRS $driver"
1365         case "x$driver" in
1366         xi915)
1367             HAVE_I915_DRI=yes;
1368             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1369             ;;
1370         xi965)
1371             HAVE_I965_DRI=yes;
1372             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1373             ;;
1374         xnouveau)
1375             HAVE_NOUVEAU_DRI=yes;
1376             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1377             ;;
1378         xradeon)
1379             HAVE_RADEON_DRI=yes;
1380             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1381             ;;
1382         xr200)
1383             HAVE_R200_DRI=yes;
1384             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1385             ;;
1386         xswrast)
1387             HAVE_SWRAST_DRI=yes;
1388             ;;
1389         *)
1390             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1391             ;;
1392         esac
1393     done
1394     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1395 fi
1396
1397 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1398 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1399                                   "x$enable_osmesa" = xyes -o \
1400                                   -n "$DRI_DIRS")
1401
1402 dnl
1403 dnl OSMesa configuration
1404 dnl
1405
1406 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1407 AC_ARG_WITH([osmesa-bits],
1408     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1409         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1410     [osmesa_bits="$withval"],
1411     [osmesa_bits=8])
1412 if test "x$osmesa_bits" != x8; then
1413     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1414         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1415         osmesa_bits=8
1416     fi
1417 fi
1418 case "x$osmesa_bits" in
1419 x8)
1420     OSMESA_LIB="${OSMESA_LIB}"
1421     ;;
1422 x16|x32)
1423     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1424     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1425     ;;
1426 *)
1427     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1428     ;;
1429 esac
1430
1431 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1432     # only link libraries with osmesa if shared
1433     if test "$enable_static" = no; then
1434         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1435     else
1436         OSMESA_LIB_DEPS=""
1437     fi
1438     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1439 fi
1440
1441 AC_SUBST([OSMESA_LIB_DEPS])
1442 AC_SUBST([OSMESA_PC_REQ])
1443 AC_SUBST([OSMESA_PC_LIB_PRIV])
1444
1445 dnl
1446 dnl gbm configuration
1447 dnl
1448 if test "x$enable_gbm" = xauto; then
1449     case "$with_egl_platforms" in
1450         *drm*)
1451             enable_gbm=yes ;;
1452          *)
1453             enable_gbm=no ;;
1454     esac
1455 fi
1456 if test "x$enable_gbm" = xyes; then
1457     if test "x$need_pci_id$have_pci_id" = xyesno; then
1458         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1459     fi
1460
1461     if test "x$enable_dri" = xyes; then
1462         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1463         if test "x$enable_shared_glapi" = xno; then
1464             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1465         fi
1466     else
1467         # Strictly speaking libgbm does not require --enable-dri, although
1468         # both of its backends do. Thus one can build libgbm without any
1469         # backends if --disable-dri is set.
1470         # To avoid unnecessary complexity of checking if at least one backend
1471         # is available when building, just mandate --enable-dri.
1472         AC_MSG_ERROR([gbm requires --enable-dri])
1473     fi
1474 fi
1475 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1476 if test "x$need_pci_id$have_libudev" = xyesyes; then
1477     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1478 else
1479     GBM_PC_REQ_PRIV=""
1480 fi
1481 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1482 AC_SUBST([GBM_PC_REQ_PRIV])
1483 AC_SUBST([GBM_PC_LIB_PRIV])
1484
1485 dnl
1486 dnl EGL configuration
1487 dnl
1488 EGL_CLIENT_APIS=""
1489
1490 if test "x$enable_egl" = xyes; then
1491     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1492
1493     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1494
1495     if test "$enable_static" != yes; then
1496         if test "x$enable_dri" = xyes; then
1497             HAVE_EGL_DRIVER_DRI2=1
1498         fi
1499
1500     fi
1501 fi
1502 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1503 AC_SUBST([EGL_LIB_DEPS])
1504
1505 dnl
1506 dnl XA configuration
1507 dnl
1508 if test "x$enable_xa" = xyes; then
1509     if test "x$with_gallium_drivers" = xswrast; then
1510        AC_MSG_ERROR([
1511           Building xa requires at least one non swrast gallium driver.
1512           If you are looking to use libxatracker.so with the VMware driver,
1513           make sure to include svga in the gallium drivers list, apart from
1514           enabling XA.
1515           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1516     fi
1517     enable_gallium_loader=$enable_shared_pipe_drivers
1518 fi
1519 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1520
1521 dnl
1522 dnl OpenVG configuration
1523 dnl
1524 VG_LIB_DEPS=""
1525
1526 if test "x$enable_openvg" = xyes; then
1527     if test "x$enable_egl" = xno; then
1528         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1529     fi
1530     if test -z "$with_gallium_drivers"; then
1531         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1532     fi
1533
1534     AC_MSG_ERROR([Cannot enable OpenVG, because egl_gallium has been removed and
1535                   OpenVG has not been integrated into standard libEGL yet])
1536
1537     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1538     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1539     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1540     AC_SUBST([VG_PC_LIB_PRIV])
1541 fi
1542 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1543
1544 dnl
1545 dnl Gallium G3DVL configuration
1546 dnl
1547 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1548     if test "x$enable_xvmc" = xauto; then
1549         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1550     fi
1551
1552     if test "x$enable_vdpau" = xauto; then
1553         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1554     fi
1555
1556     if test "x$enable_omx" = xauto; then
1557         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1558     fi
1559
1560     if test "x$enable_va" = xauto; then
1561         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1562     fi
1563 fi
1564
1565 if test "x$enable_xvmc" = xyes -o \
1566         "x$enable_vdpau" = xyes -o \
1567         "x$enable_omx" = xyes -o \
1568         "x$enable_va" = xyes; then
1569     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1570     need_gallium_vl=yes
1571 fi
1572 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1573
1574 if test "x$enable_xvmc" = xyes; then
1575     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1576     enable_gallium_loader=$enable_shared_pipe_drivers
1577 fi
1578 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1579
1580 if test "x$enable_vdpau" = xyes; then
1581     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1582     enable_gallium_loader=$enable_shared_pipe_drivers
1583 fi
1584 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1585
1586 if test "x$enable_omx" = xyes; then
1587     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1588     enable_gallium_loader=$enable_shared_pipe_drivers
1589 fi
1590 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1591
1592 if test "x$enable_va" = xyes; then
1593     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1594     enable_gallium_loader=$enable_shared_pipe_drivers
1595 fi
1596 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1597
1598 dnl
1599 dnl Nine Direct3D9 configuration
1600 dnl
1601 if test "x$enable_nine" = xyes; then
1602     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1603         AC_MSG_ERROR([nine requires the gallium swrast driver])
1604     fi
1605     if test "x$with_gallium_drivers" == xswrast; then
1606         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1607     fi
1608     if test "x$enable_dri3" = xno; then
1609         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1610     fi
1611
1612     enable_gallium_loader=$enable_shared_pipe_drivers
1613 fi
1614 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1615
1616 dnl
1617 dnl OpenCL configuration
1618 dnl
1619
1620 AC_ARG_WITH([libclc-path],
1621    [AS_HELP_STRING([--with-libclc-path],
1622          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1623    [LIBCLC_PATH="$withval"],
1624    [LIBCLC_PATH=''])
1625
1626 if test -n "$LIBCLC_PATH"; then
1627    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1628                   Please review the updated build instructions for clover:
1629                   http://dri.freedesktop.org/wiki/GalliumCompute])
1630 fi
1631
1632
1633 AC_ARG_WITH([clang-libdir],
1634    [AS_HELP_STRING([--with-clang-libdir],
1635          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1636    [CLANG_LIBDIR="$withval"],
1637    [CLANG_LIBDIR=''])
1638
1639 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1640 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1641
1642 if test "x$enable_opencl" = xyes; then
1643     if test -z "$with_gallium_drivers"; then
1644         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1645     fi
1646
1647     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1648         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1649     fi
1650
1651     if test "x$have_libclc" = xno; then
1652         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1653                     Make sure the directory containing libclc.pc is specified in your
1654                     PKG_CONFIG_PATH environment variable.
1655                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1656     else
1657         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1658         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1659         AC_SUBST([LIBCLC_INCLUDEDIR])
1660         AC_SUBST([LIBCLC_LIBEXECDIR])
1661     fi
1662
1663     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1664     enable_gallium_loader=yes
1665
1666     if test "x$enable_opencl_icd" = xyes; then
1667         OPENCL_LIBNAME="MesaOpenCL"
1668     else
1669         OPENCL_LIBNAME="OpenCL"
1670     fi
1671
1672     if test "x$have_libelf" != xyes; then
1673        AC_MSG_ERROR([Clover requires libelf])
1674     fi
1675 fi
1676 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1677 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1678 AC_SUBST([OPENCL_LIBNAME])
1679
1680 dnl
1681 dnl Gallium configuration
1682 dnl
1683 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1684
1685 AC_SUBST([LLVM_BINDIR])
1686 AC_SUBST([LLVM_CFLAGS])
1687 AC_SUBST([LLVM_CPPFLAGS])
1688 AC_SUBST([LLVM_CXXFLAGS])
1689 AC_SUBST([LLVM_LIBDIR])
1690 AC_SUBST([LLVM_LIBS])
1691 AC_SUBST([LLVM_LDFLAGS])
1692 AC_SUBST([LLVM_INCLUDEDIR])
1693 AC_SUBST([LLVM_VERSION])
1694 AC_SUBST([CLANG_RESOURCE_DIR])
1695
1696 case "x$enable_opengl$enable_gles1$enable_gles2" in
1697 x*yes*)
1698     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1699     ;;
1700 esac
1701
1702 AC_SUBST([VG_LIB_DEPS])
1703 AC_SUBST([EGL_CLIENT_APIS])
1704
1705 dnl
1706 dnl EGL Platforms configuration
1707 dnl
1708 AC_ARG_WITH([egl-platforms],
1709     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1710         [comma delimited native platforms libEGL supports, e.g.
1711         "x11,drm" @<:@default=auto@:>@])],
1712     [with_egl_platforms="$withval"],
1713     [if test "x$enable_egl" = xyes; then
1714         with_egl_platforms="x11"
1715     else
1716         with_egl_platforms=""
1717     fi])
1718
1719 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1720     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1721 fi
1722
1723 # Do per-EGL platform setups and checks
1724 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1725 for plat in $egl_platforms; do
1726         case "$plat" in
1727         wayland)
1728                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1729
1730                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1731                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1732                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1733                 ;;
1734
1735         x11)
1736                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1737                 ;;
1738
1739         drm)
1740                 test "x$enable_gbm" = "xno" &&
1741                         AC_MSG_ERROR([EGL platform drm needs gbm])
1742                 test "x$have_libdrm" != xyes &&
1743                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1744                 ;;
1745
1746         android|fbdev|gdi|null)
1747                 ;;
1748
1749         *)
1750                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1751                 ;;
1752         esac
1753
1754         case "$plat$need_pci_id$have_pci_id" in
1755                 waylandyesno|drmyesno)
1756                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1757         esac
1758 done
1759
1760 # libEGL wants to default to the first platform specified in
1761 # ./configure.  parse that here.
1762 if test "x$egl_platforms" != "x"; then
1763     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1764     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1765 else
1766     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1767 fi
1768
1769 if echo "$egl_platforms" | grep -q 'x11'; then
1770     NEED_WINSYS_XLIB=yes
1771 fi
1772 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1773 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1774 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1775 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1776 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1777
1778 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1779
1780 AC_SUBST([EGL_NATIVE_PLATFORM])
1781 AC_SUBST([EGL_CFLAGS])
1782
1783 # If we don't have the X11 platform, set this define so we don't try to include
1784 # the X11 headers.
1785 if ! echo "$egl_platforms" | grep -q 'x11'; then
1786     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1787     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1788 fi
1789
1790 AC_ARG_WITH([max-width],
1791     [AS_HELP_STRING([--with-max-width=N],
1792                     [Maximum framebuffer width (4096)])],
1793     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1794      AS_IF([test "${withval}" -gt "4096"],
1795            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1796 )
1797 AC_ARG_WITH([max-height],
1798     [AS_HELP_STRING([--with-max-height=N],
1799                     [Maximum framebuffer height (4096)])],
1800     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1801      AS_IF([test "${withval}" -gt "4096"],
1802            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1803 )
1804
1805 dnl
1806 dnl Gallium LLVM
1807 dnl
1808 AC_ARG_ENABLE([gallium-llvm],
1809     [AS_HELP_STRING([--enable-gallium-llvm],
1810         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1811     [enable_gallium_llvm="$enableval"],
1812     [enable_gallium_llvm=auto])
1813
1814 AC_ARG_ENABLE([llvm-shared-libs],
1815     [AS_HELP_STRING([--enable-llvm-shared-libs],
1816         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1817     [enable_llvm_shared_libs="$enableval"],
1818     [enable_llvm_shared_libs=yes])
1819
1820 AC_ARG_WITH([llvm-prefix],
1821     [AS_HELP_STRING([--with-llvm-prefix],
1822         [Prefix for LLVM installations in non-standard locations])],
1823     [llvm_prefix="$withval"],
1824     [llvm_prefix=''])
1825
1826
1827 # Call this inside ` ` to get the return value.
1828 # $1 is the llvm-config command with arguments.
1829 strip_unwanted_llvm_flags() {
1830     # Use \> (marks the end of the word)
1831     echo `$1` | sed \
1832         -e 's/-DNDEBUG\>//g' \
1833         -e 's/-D_GNU_SOURCE\>//g' \
1834         -e 's/-pedantic\>//g' \
1835         -e 's/-Wcovered-switch-default\>//g' \
1836         -e 's/-O.\>//g' \
1837         -e 's/-g\>//g' \
1838         -e 's/-Wall\>//g' \
1839         -e 's/-Wcast-qual\>//g' \
1840         -e 's/-Woverloaded-virtual\>//g' \
1841         -e 's/-fcolor-diagnostics\>//g' \
1842         -e 's/-fdata-sections\>//g' \
1843         -e 's/-ffunction-sections\>//g' \
1844         -e 's/-fno-exceptions\>//g' \
1845         -e 's/-fomit-frame-pointer\>//g' \
1846         -e 's/-fvisibility-inlines-hidden\>//g' \
1847         -e 's/-fPIC\>//g' \
1848         -e 's/-fstack-protector-strong\>//g'
1849 }
1850
1851
1852 if test -z "$with_gallium_drivers"; then
1853     enable_gallium_llvm=no
1854 fi
1855 if test "x$enable_gallium_llvm" = xauto; then
1856     case "$host_cpu" in
1857     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1858     esac
1859 fi
1860 if test "x$enable_gallium_llvm" = xyes; then
1861     if test -n "$llvm_prefix"; then
1862         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1863     else
1864         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1865     fi
1866
1867     if test "x$LLVM_CONFIG" != xno; then
1868         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1869         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1870         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1871         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1872         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1873         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1874         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1875         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1876
1877         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1878             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1879         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1880             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1881
1882         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1883         if test -z "$LLVM_VERSION_PATCH"; then
1884             LLVM_VERSION_PATCH=0
1885         fi
1886
1887         if test -n "${LLVM_VERSION_MAJOR}"; then
1888             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1889         else
1890             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1891         fi
1892
1893         LLVM_REQUIRED_VERSION_MAJOR="3"
1894         LLVM_REQUIRED_VERSION_MINOR="3"
1895         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1896             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1897         fi
1898
1899         LLVM_COMPONENTS="engine bitwriter"
1900         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1901             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1902         fi
1903
1904         if test "x$enable_opencl" = xyes; then
1905             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1906             # LLVM 3.3 >= 177971 requires IRReader
1907             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1908                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1909             fi
1910             # LLVM 3.4 requires Option
1911             if $LLVM_CONFIG --components | grep -qw 'option'; then
1912                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1913             fi
1914             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1915             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1916                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1917             fi
1918             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1919                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1920             fi
1921         fi
1922         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1923         MESA_LLVM=1
1924
1925         dnl Check for Clang internal headers
1926         if test "x$enable_opencl" = xyes; then
1927             if test -z "$CLANG_LIBDIR"; then
1928                 CLANG_LIBDIR=${LLVM_LIBDIR}
1929             fi
1930             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1931             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1932                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1933         fi
1934     else
1935         MESA_LLVM=0
1936         LLVM_VERSION_INT=0
1937     fi
1938 else
1939     MESA_LLVM=0
1940     LLVM_VERSION_INT=0
1941
1942     if test "x$enable_opencl" = xyes; then
1943         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1944     fi
1945 fi
1946
1947 dnl Directory for XVMC libs
1948 AC_ARG_WITH([xvmc-libdir],
1949     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1950         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1951     [XVMC_LIB_INSTALL_DIR="$withval"],
1952     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1953 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1954
1955 dnl
1956 dnl Gallium Tests
1957 dnl
1958 if test "x$enable_gallium_tests" = xyes; then
1959     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1960     enable_gallium_loader=yes
1961 fi
1962 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1963
1964 dnl Directory for VDPAU libs
1965 AC_ARG_WITH([vdpau-libdir],
1966     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1967         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1968     [VDPAU_LIB_INSTALL_DIR="$withval"],
1969     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1970 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1971
1972 dnl Directory for OMX libs
1973
1974 AC_ARG_WITH([omx-libdir],
1975     [AS_HELP_STRING([--with-omx-libdir=DIR],
1976         [directory for the OMX libraries])],
1977     [OMX_LIB_INSTALL_DIR="$withval"],
1978     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1979 AC_SUBST([OMX_LIB_INSTALL_DIR])
1980
1981 dnl Directory for VA libs
1982
1983 AC_ARG_WITH([va-libdir],
1984     [AS_HELP_STRING([--with-va-libdir=DIR],
1985         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1986     [VA_LIB_INSTALL_DIR="$withval"],
1987     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1988 AC_SUBST([VA_LIB_INSTALL_DIR])
1989
1990 AC_ARG_WITH([d3d-libdir],
1991     [AS_HELP_STRING([--with-d3d-libdir=DIR],
1992         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
1993     [D3D_DRIVER_INSTALL_DIR="$withval"],
1994     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
1995 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
1996
1997 dnl
1998 dnl Gallium helper functions
1999 dnl
2000 gallium_require_drm() {
2001     if test "x$have_libdrm" != xyes; then
2002        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2003     fi
2004 }
2005
2006 gallium_require_llvm() {
2007     if test "x$MESA_LLVM" = x0; then
2008         case "$host" in *gnux32) return;; esac
2009         case "$host_cpu" in
2010         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2011         esac
2012     fi
2013 }
2014
2015 gallium_require_drm_loader() {
2016     if test "x$enable_gallium_loader" = xyes; then
2017         if test "x$need_pci_id$have_pci_id" = xyesno; then
2018             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2019         fi
2020         enable_gallium_drm_loader=yes
2021     fi
2022     if test "x$enable_va" = xyes && test "x$7" != x; then
2023          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2024     fi
2025 }
2026
2027 require_egl_drm() {
2028     case "$with_egl_platforms" in
2029         *drm*)
2030             ;;
2031          *)
2032             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2033             ;;
2034     esac
2035     if test "x$enable_gbm" != xyes; then
2036             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2037     fi
2038 }
2039
2040 radeon_llvm_check() {
2041     if test "x$enable_gallium_llvm" != "xyes"; then
2042         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2043     fi
2044     LLVM_REQUIRED_VERSION_MAJOR="3"
2045     LLVM_REQUIRED_VERSION_MINOR="4"
2046     LLVM_REQUIRED_VERSION_PATCH="2"
2047     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2048         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2049     fi
2050     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2051         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2052                       sources with the --enable-experimental-targets=R600
2053                       configure flag])
2054     fi
2055     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2056     NEED_RADEON_LLVM=yes
2057     if test "x$have_libelf" != xyes; then
2058        AC_MSG_ERROR([$1 requires libelf when using llvm])
2059     fi
2060 }
2061
2062 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2063 if test -n "$with_gallium_drivers"; then
2064     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2065     for driver in $gallium_drivers; do
2066         case "x$driver" in
2067         xsvga)
2068             HAVE_GALLIUM_SVGA=yes
2069             gallium_require_drm "svga"
2070             gallium_require_drm_loader
2071             ;;
2072         xi915)
2073             HAVE_GALLIUM_I915=yes
2074             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2075             gallium_require_drm "Gallium i915"
2076             gallium_require_drm_loader
2077             ;;
2078         xilo)
2079             HAVE_GALLIUM_ILO=yes
2080             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2081             gallium_require_drm "Gallium i965/ilo"
2082             gallium_require_drm_loader
2083             ;;
2084         xr300)
2085             HAVE_GALLIUM_R300=yes
2086             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2087             gallium_require_drm "Gallium R300"
2088             gallium_require_drm_loader
2089             gallium_require_llvm "Gallium R300"
2090             ;;
2091         xr600)
2092             HAVE_GALLIUM_R600=yes
2093             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2094             gallium_require_drm "Gallium R600"
2095             gallium_require_drm_loader
2096             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2097                 radeon_llvm_check "r600g"
2098                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2099             fi
2100             if test "x$enable_r600_llvm" = xyes; then
2101                 USE_R600_LLVM_COMPILER=yes;
2102             fi
2103             if test "x$enable_opencl" = xyes; then
2104                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2105             fi
2106             ;;
2107         xradeonsi)
2108             HAVE_GALLIUM_RADEONSI=yes
2109             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2110             gallium_require_drm "radeonsi"
2111             gallium_require_drm_loader
2112             radeon_llvm_check "radeonsi"
2113             require_egl_drm "radeonsi"
2114             ;;
2115         xnouveau)
2116             HAVE_GALLIUM_NOUVEAU=yes
2117             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2118             gallium_require_drm "nouveau"
2119             gallium_require_drm_loader
2120             ;;
2121         xfreedreno)
2122             HAVE_GALLIUM_FREEDRENO=yes
2123             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2124             gallium_require_drm "freedreno"
2125             gallium_require_drm_loader
2126             ;;
2127         xswrast)
2128             HAVE_GALLIUM_SOFTPIPE=yes
2129             if test "x$MESA_LLVM" = x1; then
2130                 HAVE_GALLIUM_LLVMPIPE=yes
2131             fi
2132             ;;
2133         xvc4)
2134             HAVE_GALLIUM_VC4=yes
2135             gallium_require_drm "vc4"
2136             gallium_require_drm_loader
2137
2138             case "$host_cpu" in
2139                 i?86 | x86_64 | amd64)
2140                 USE_VC4_SIMULATOR=yes
2141                 ;;
2142             esac
2143             ;;
2144         *)
2145             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2146             ;;
2147         esac
2148     done
2149 fi
2150
2151 dnl Set LLVM_LIBS - This is done after the driver configuration so
2152 dnl that drivers can add additional components to LLVM_COMPONENTS.
2153 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2154 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2155 dnl this was causing the same libraries to be appear multiple times
2156 dnl in LLVM_LIBS.
2157
2158 if test "x$MESA_LLVM" != x0; then
2159
2160     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2161
2162     if test "x$enable_llvm_shared_libs" = xyes; then
2163         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2164         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2165         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2166
2167         if test "x$llvm_have_one_so" = xyes; then
2168             dnl LLVM was built using auto*, so there is only one shared object.
2169             LLVM_LIBS="-l$LLVM_SO_NAME"
2170         else
2171             dnl If LLVM was built with CMake, there will be one shared object per
2172             dnl component.
2173             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2174                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2175         Please make sure you have built llvm with the --enable-shared option
2176         and that your llvm libraries are installed in $LLVM_LIBDIR
2177         If you have installed your llvm libraries to a different directory you
2178         can use the --with-llvm-prefix= configure flag to specify this directory.
2179         NOTE: Mesa is attempting to use llvm shared libraries by default.
2180         If you do not want to build with llvm shared libraries and instead want to
2181         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2182         invocation and rebuild.])])
2183
2184            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2185            dnl install uses a shared object for each component and we have
2186            dnl already added all of these objects to LLVM_LIBS.
2187         fi
2188     else
2189         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2190         dnl We need to link to llvm system libs when using static libs
2191         dnl However, only llvm 3.5+ provides --system-libs
2192         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2193             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2194         fi
2195     fi
2196 fi
2197
2198 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2199 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2200 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2201 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2202 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2203 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2204 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2205                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2206 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2207 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2208 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2209 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2210 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2211
2212 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2213
2214 # NOTE: anything using xcb or other client side libs ends up in separate
2215 #       _CLIENT variables.  The pipe loader is built in two variants,
2216 #       one that is standalone and does not link any x client libs (for
2217 #       use by XA tracker in particular, but could be used in any case
2218 #       where communication with xserver is not desired).
2219 if test "x$enable_gallium_loader" = xyes; then
2220     if test "x$NEED_WINSYS_XLIB" = xyes; then
2221         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2222     fi
2223
2224     if test "x$enable_dri" = xyes; then
2225         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2226     fi
2227
2228     if test "x$enable_gallium_drm_loader" = xyes; then
2229         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2230         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2231                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2232         if test "x$pipe_loader_have_xcb" = xyes; then
2233             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2234             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2235         fi
2236     fi
2237
2238     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2239     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2240
2241     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2242     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2243     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2244     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2245 fi
2246
2247 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2248 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2249 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2250 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2251 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2252 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2253
2254 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2255                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2256                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2257 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2258 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2259 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2260 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2261 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2262 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2263 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2264 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2265 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2266     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2267 fi
2268
2269 AC_SUBST([ELF_LIB])
2270
2271 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2272 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2273 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2274 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2275 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2276
2277 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2278 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2279 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2280
2281 AC_SUBST([NINE_MAJOR], 1)
2282 AC_SUBST([NINE_MINOR], 0)
2283 AC_SUBST([NINE_TINY], 0)
2284 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2285
2286 AC_SUBST([VDPAU_MAJOR], 1)
2287 AC_SUBST([VDPAU_MINOR], 0)
2288
2289 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2290 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2291 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2292 AC_SUBST([VA_MINOR], $VA_MINOR)
2293
2294 AC_SUBST([XVMC_MAJOR], 1)
2295 AC_SUBST([XVMC_MINOR], 0)
2296
2297 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2298 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2299 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2300 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2301
2302 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2303 AC_SUBST([XA_MINOR], $XA_MINOR)
2304 AC_SUBST([XA_TINY], $XA_TINY)
2305 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2306
2307 dnl Restore LDFLAGS and CPPFLAGS
2308 LDFLAGS="$_SAVE_LDFLAGS"
2309 CPPFLAGS="$_SAVE_CPPFLAGS"
2310
2311 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2312 if test "x$acv_mesa_CLANG" = xyes; then
2313     CFLAGS="$CFLAGS -Qunused-arguments"
2314     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2315 fi
2316
2317 dnl Add user CFLAGS and CXXFLAGS
2318 CFLAGS="$CFLAGS $USER_CFLAGS"
2319 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2320
2321 dnl Substitute the config
2322 AC_CONFIG_FILES([Makefile
2323                 src/Makefile
2324                 src/egl/drivers/dri2/Makefile
2325                 src/egl/main/Makefile
2326                 src/egl/main/egl.pc
2327                 src/egl/wayland/wayland-drm/Makefile
2328                 src/egl/wayland/wayland-egl/Makefile
2329                 src/egl/wayland/wayland-egl/wayland-egl.pc
2330                 src/gallium/Makefile
2331                 src/gallium/auxiliary/Makefile
2332                 src/gallium/auxiliary/pipe-loader/Makefile
2333                 src/gallium/drivers/freedreno/Makefile
2334                 src/gallium/drivers/galahad/Makefile
2335                 src/gallium/drivers/i915/Makefile
2336                 src/gallium/drivers/identity/Makefile
2337                 src/gallium/drivers/ilo/Makefile
2338                 src/gallium/drivers/llvmpipe/Makefile
2339                 src/gallium/drivers/noop/Makefile
2340                 src/gallium/drivers/nouveau/Makefile
2341                 src/gallium/drivers/r300/Makefile
2342                 src/gallium/drivers/r600/Makefile
2343                 src/gallium/drivers/radeon/Makefile
2344                 src/gallium/drivers/radeonsi/Makefile
2345                 src/gallium/drivers/rbug/Makefile
2346                 src/gallium/drivers/softpipe/Makefile
2347                 src/gallium/drivers/svga/Makefile
2348                 src/gallium/drivers/trace/Makefile
2349                 src/gallium/drivers/vc4/Makefile
2350                 src/gallium/drivers/vc4/kernel/Makefile
2351                 src/gallium/state_trackers/clover/Makefile
2352                 src/gallium/state_trackers/dri/Makefile
2353                 src/gallium/state_trackers/glx/xlib/Makefile
2354                 src/gallium/state_trackers/nine/Makefile
2355                 src/gallium/state_trackers/omx/Makefile
2356                 src/gallium/state_trackers/osmesa/Makefile
2357                 src/gallium/state_trackers/va/Makefile
2358                 src/gallium/state_trackers/vdpau/Makefile
2359                 src/gallium/state_trackers/vega/Makefile
2360                 src/gallium/state_trackers/xa/Makefile
2361                 src/gallium/state_trackers/xvmc/Makefile
2362                 src/gallium/targets/d3dadapter9/Makefile
2363                 src/gallium/targets/d3dadapter9/d3d.pc
2364                 src/gallium/targets/dri/Makefile
2365                 src/gallium/targets/libgl-xlib/Makefile
2366                 src/gallium/targets/omx/Makefile
2367                 src/gallium/targets/opencl/Makefile
2368                 src/gallium/targets/osmesa/Makefile
2369                 src/gallium/targets/osmesa/osmesa.pc
2370                 src/gallium/targets/pipe-loader/Makefile
2371                 src/gallium/targets/va/Makefile
2372                 src/gallium/targets/vdpau/Makefile
2373                 src/gallium/targets/xa/Makefile
2374                 src/gallium/targets/xa/xatracker.pc
2375                 src/gallium/targets/xvmc/Makefile
2376                 src/gallium/tests/trivial/Makefile
2377                 src/gallium/tests/unit/Makefile
2378                 src/gallium/winsys/freedreno/drm/Makefile
2379                 src/gallium/winsys/i915/drm/Makefile
2380                 src/gallium/winsys/intel/drm/Makefile
2381                 src/gallium/winsys/nouveau/drm/Makefile
2382                 src/gallium/winsys/radeon/drm/Makefile
2383                 src/gallium/winsys/svga/drm/Makefile
2384                 src/gallium/winsys/sw/dri/Makefile
2385                 src/gallium/winsys/sw/fbdev/Makefile
2386                 src/gallium/winsys/sw/kms-dri/Makefile
2387                 src/gallium/winsys/sw/null/Makefile
2388                 src/gallium/winsys/sw/wayland/Makefile
2389                 src/gallium/winsys/sw/wrapper/Makefile
2390                 src/gallium/winsys/sw/xlib/Makefile
2391                 src/gallium/winsys/vc4/drm/Makefile
2392                 src/gbm/Makefile
2393                 src/gbm/main/gbm.pc
2394                 src/glsl/Makefile
2395                 src/glx/Makefile
2396                 src/glx/apple/Makefile
2397                 src/glx/tests/Makefile
2398                 src/gtest/Makefile
2399                 src/loader/Makefile
2400                 src/mapi/Makefile
2401                 src/mapi/es1api/glesv1_cm.pc
2402                 src/mapi/es2api/glesv2.pc
2403                 src/mapi/glapi/gen/Makefile
2404                 src/mesa/Makefile
2405                 src/mesa/gl.pc
2406                 src/mesa/drivers/dri/dri.pc
2407                 src/mesa/drivers/dri/common/Makefile
2408                 src/mesa/drivers/dri/common/xmlpool/Makefile
2409                 src/mesa/drivers/dri/i915/Makefile
2410                 src/mesa/drivers/dri/i965/Makefile
2411                 src/mesa/drivers/dri/Makefile
2412                 src/mesa/drivers/dri/nouveau/Makefile
2413                 src/mesa/drivers/dri/r200/Makefile
2414                 src/mesa/drivers/dri/radeon/Makefile
2415                 src/mesa/drivers/dri/swrast/Makefile
2416                 src/mesa/drivers/osmesa/Makefile
2417                 src/mesa/drivers/osmesa/osmesa.pc
2418                 src/mesa/drivers/x11/Makefile
2419                 src/mesa/main/tests/Makefile
2420                 src/util/Makefile
2421                 src/util/tests/hash_table/Makefile])
2422
2423 AC_OUTPUT
2424
2425 dnl
2426 dnl Output some configuration info for the user
2427 dnl
2428 echo ""
2429 echo "        prefix:          $prefix"
2430 echo "        exec_prefix:     $exec_prefix"
2431 echo "        libdir:          $libdir"
2432 echo "        includedir:      $includedir"
2433
2434 dnl API info
2435 echo ""
2436 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2437 echo "        OpenVG:          $enable_openvg"
2438
2439 dnl Driver info
2440 echo ""
2441 case "x$enable_osmesa$enable_gallium_osmesa" in
2442 xnoyes)
2443         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2444         ;;
2445 xyesno)
2446         echo "        OSMesa:          lib$OSMESA_LIB"
2447         ;;
2448 xnono)
2449         echo "        OSMesa:          no"
2450         ;;
2451 esac
2452
2453 echo ""
2454 if test "x$enable_dri" != xno; then
2455         echo "        DRI platform:    $dri_platform"
2456         if test -z "$DRI_DIRS"; then
2457             echo "        DRI drivers:     no"
2458         else
2459             echo "        DRI drivers:     $DRI_DIRS"
2460         fi
2461         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2462 fi
2463
2464 case "x$enable_glx$enable_xlib_glx" in
2465 xyesyes)
2466     echo "        GLX:             Xlib-based"
2467     ;;
2468 xyesno)
2469     echo "        GLX:             DRI-based"
2470     ;;
2471 *)
2472     echo "        GLX:             $enable_glx"
2473     ;;
2474 esac
2475
2476 dnl EGL
2477 echo ""
2478 echo "        EGL:             $enable_egl"
2479 if test "$enable_egl" = yes; then
2480     echo "        EGL platforms:   $egl_platforms"
2481
2482     egl_drivers=""
2483     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2484         egl_drivers="$egl_drivers builtin:egl_dri2"
2485     fi
2486
2487     echo "        EGL drivers:    $egl_drivers"
2488 fi
2489
2490 echo ""
2491 if test "x$MESA_LLVM" = x1; then
2492     echo "        llvm:            yes"
2493     echo "        llvm-config:     $LLVM_CONFIG"
2494     echo "        llvm-version:    $LLVM_VERSION"
2495 else
2496     echo "        llvm:            no"
2497 fi
2498
2499 echo ""
2500 if test -n "$with_gallium_drivers"; then
2501     echo "        Gallium:         yes"
2502 else
2503     echo "        Gallium:         no"
2504 fi
2505
2506 dnl Shader cache
2507 echo ""
2508 echo "        Shader cache:    $enable_shader_cache"
2509 if test "x$enable_shader_cache" = "xyes"; then
2510     echo "        With SHA1 from:  $with_sha1"
2511 fi
2512
2513 dnl Libraries
2514 echo ""
2515 echo "        Shared libs:     $enable_shared"
2516 echo "        Static libs:     $enable_static"
2517 echo "        Shared-glapi:    $enable_shared_glapi"
2518
2519 dnl Compiler options
2520 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2521 cflags=`echo $CFLAGS | \
2522     $SED 's/^ *//;s/  */ /;s/ *$//'`
2523 cxxflags=`echo $CXXFLAGS | \
2524     $SED 's/^ *//;s/  */ /;s/ *$//'`
2525 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2526 echo ""
2527 echo "        CFLAGS:          $cflags"
2528 echo "        CXXFLAGS:        $cxxflags"
2529 echo "        Macros:          $defines"
2530 echo ""
2531 if test "x$MESA_LLVM" = x1; then
2532     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2533     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2534     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2535     echo ""
2536 fi
2537 echo "        PYTHON2:         $PYTHON2"
2538
2539 echo ""
2540 echo "        Run '${MAKE-make}' to build Mesa"
2541 echo ""