configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 dnl http://people.gnome.org/~walters/docs/build-api.txt
  18 dnl We don't support srcdir != builddir.
  19 echo \#buildapi-variable-no-builddir >/dev/null
  20
  21 # Support silent build rules, requires at least automake-1.11. Disable
  22 # by either passing --disable-silent-rules to configure or passing V=1
  23 # to make
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  25     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  26
  27 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  28
  29 dnl Set internal versions
  30 OSMESA_VERSION=8
  31 AC_SUBST([OSMESA_VERSION])
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.46
  36 LIBDRM_INTEL_REQUIRED=2.4.38
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  39 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AX_PYTHON_MODULE([libxml2], [needed])
  54 AC_PROG_SED
  55 AC_PROG_MKDIR_P
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([disable-static])
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 GEN_ASM_OFFSETS=no
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120
 121     if test "x$cross_compiling" = xyes; then
 122         GEN_ASM_OFFSETS=yes
 123     fi
 124 fi
 125 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 126
 127 dnl Make sure the pkg-config macros are defined
 128 m4_ifndef([PKG_PROG_PKG_CONFIG],
 129     [m4_fatal([Could not locate the pkg-config autoconf macros.
 130   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 131   are in a different location, try setting the environment variable
 132   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 133 PKG_PROG_PKG_CONFIG()
 134
 135 dnl LIB_DIR - library basename
 136 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 137 AC_SUBST([LIB_DIR])
 138
 139 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 140 _SAVE_LDFLAGS="$LDFLAGS"
 141 _SAVE_CPPFLAGS="$CPPFLAGS"
 142
 143 dnl Compiler macros
 144 DEFINES=""
 145 AC_SUBST([DEFINES])
 146 case "$host_os" in
 147 linux*|*-gnu*|gnu*)
 148     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 149     ;;
 150 solaris*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 152     ;;
 153 cygwin*)
 154     DEFINES="$DEFINES -DHAVE_PTHREAD"
 155     ;;
 156 esac
 157
 158 dnl Add flags for gcc and g++
 159 if test "x$GCC" = xyes; then
 160     case "$host_os" in
 161     cygwin*)
 162         CFLAGS="$CFLAGS -Wall -std=gnu99"
 163         ;;
 164     *)
 165         CFLAGS="$CFLAGS -Wall -std=c99"
 166         ;;
 167     esac
 168
 169     # Enable -Werror=implicit-function-declaration and
 170     # -Werror=missing-prototypes, if available, or otherwise, just
 171     # -Wmissing-prototypes.  This is particularly useful to avoid
 172     # generating a loadable driver module that has undefined symbols.
 173     save_CFLAGS="$CFLAGS"
 174     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 175     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 176     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 177     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 178                    AC_MSG_RESULT([yes]),
 179                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 180                     AC_MSG_RESULT([no])]);
 181
 182     # Enable -fvisibility=hidden if using a gcc that supports it
 183     save_CFLAGS="$CFLAGS"
 184     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 185     VISIBILITY_CFLAGS="-fvisibility=hidden"
 186     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 188                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 189
 190     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 191     CFLAGS=$save_CFLAGS
 192
 193     # Work around aliasing bugs - developers should comment this out
 194     CFLAGS="$CFLAGS -fno-strict-aliasing"
 195
 196     # gcc's builtin memcmp is slower than glibc's
 197     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 198     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 199 fi
 200 if test "x$GXX" = xyes; then
 201     CXXFLAGS="$CXXFLAGS -Wall"
 202
 203     # Enable -fvisibility=hidden if using a gcc that supports it
 204     save_CXXFLAGS="$CXXFLAGS"
 205     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 206     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 207     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 208     AC_LANG_PUSH([C++])
 209     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 210                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 211     AC_LANG_POP([C++])
 212
 213     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 214     CXXFLAGS=$save_CXXFLAGS
 215
 216     # Work around aliasing bugs - developers should comment this out
 217     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 218
 219     # gcc's builtin memcmp is slower than glibc's
 220     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 221     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 222 fi
 223
 224 dnl even if the compiler appears to support it, using visibility attributes isn't
 225 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 226 case "$host_os" in
 227 cygwin*)
 228     VISIBILITY_CFLAGS=""
 229     VISIBILITY_CXXFLAGS=""
 230     ;;
 231 esac
 232
 233 AC_SUBST([VISIBILITY_CFLAGS])
 234 AC_SUBST([VISIBILITY_CXXFLAGS])
 235
 236 dnl
 237 dnl Hacks to enable 32 or 64 bit build
 238 dnl
 239 AC_ARG_ENABLE([32-bit],
 240     [AS_HELP_STRING([--enable-32-bit],
 241         [build 32-bit libraries @<:@default=auto@:>@])],
 242     [enable_32bit="$enableval"],
 243     [enable_32bit=auto]
 244 )
 245 if test "x$enable_32bit" = xyes; then
 246     if test "x$GCC" = xyes; then
 247         CFLAGS="$CFLAGS -m32"
 248         CCASFLAGS="$CCASFLAGS -m32"
 249     fi
 250     if test "x$GXX" = xyes; then
 251         CXXFLAGS="$CXXFLAGS -m32"
 252     fi
 253 fi
 254 AC_ARG_ENABLE([64-bit],
 255     [AS_HELP_STRING([--enable-64-bit],
 256         [build 64-bit libraries @<:@default=auto@:>@])],
 257     [enable_64bit="$enableval"],
 258     [enable_64bit=auto]
 259 )
 260 if test "x$enable_64bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m64"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m64"
 266     fi
 267 fi
 268
 269 dnl Can't have static and shared libraries, default to static if user
 270 dnl explicitly requested. If both disabled, set to static since shared
 271 dnl was explicitly requested.
 272 case "x$enable_static$enable_shared" in
 273 xyesyes )
 274     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 275     enable_shared=no
 276     ;;
 277 xnono )
 278     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 279     enable_static=yes
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 284
 285 dnl
 286 dnl other compiler options
 287 dnl
 288 AC_ARG_ENABLE([debug],
 289     [AS_HELP_STRING([--enable-debug],
 290         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 291     [enable_debug="$enableval"],
 292     [enable_debug=no]
 293 )
 294 if test "x$enable_debug" = xyes; then
 295     DEFINES="$DEFINES -DDEBUG"
 296     if test "x$GCC" = xyes; then
 297         CFLAGS="$CFLAGS -g -O0"
 298     fi
 299     if test "x$GXX" = xyes; then
 300         CXXFLAGS="$CXXFLAGS -g -O0"
 301     fi
 302 fi
 303
 304 dnl
 305 dnl library names
 306 dnl
 307 LIB_PREFIX_GLOB='lib'
 308 LIB_VERSION_SEPARATOR='.'
 309 if test "$enable_static" = yes; then
 310     LIB_EXTENSION='a'
 311 else
 312     case "$host_os" in
 313     darwin* )
 314         LIB_EXTENSION='dylib' ;;
 315     cygwin* )
 316         dnl prefix can be 'cyg' or 'lib'
 317         LIB_PREFIX_GLOB='???'
 318         LIB_VERSION_SEPARATOR='-'
 319         LIB_EXTENSION='dll' ;;
 320     aix* )
 321         LIB_EXTENSION='a' ;;
 322     * )
 323         LIB_EXTENSION='so' ;;
 324     esac
 325 fi
 326 AC_ARG_WITH([gl-lib-name],
 327   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 328     [specify GL library name @<:@default=GL@:>@])],
 329   [GL_LIB=$withval],
 330   [GL_LIB=GL])
 331 AC_ARG_WITH([osmesa-lib-name],
 332   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 333     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 334   [OSMESA_LIB=$withval],
 335   [OSMESA_LIB=OSMesa])
 336 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 337 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 338
 339 dnl
 340 dnl Mangled Mesa support
 341 dnl
 342 AC_ARG_ENABLE([mangling],
 343   [AS_HELP_STRING([--enable-mangling],
 344     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 345   [enable_mangling="${enableval}"],
 346   [enable_mangling=no]
 347 )
 348 if test "x${enable_mangling}" = "xyes" ; then
 349   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 350   GL_LIB="Mangled${GL_LIB}"
 351   OSMESA_LIB="Mangled${OSMESA_LIB}"
 352 fi
 353 AC_SUBST([GL_LIB])
 354 AC_SUBST([OSMESA_LIB])
 355
 356 dnl
 357 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 358 dnl
 359 AC_ARG_ENABLE([texture-float],
 360     [AS_HELP_STRING([--enable-texture-float],
 361         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 362     [enable_texture_float="$enableval"],
 363     [enable_texture_float=no]
 364 )
 365 if test "x$enable_texture_float" = xyes; then
 366     AC_MSG_WARN([Floating-point textures enabled.])
 367     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 368     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 369 fi
 370
 371 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 372 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 373 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 374 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 375 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 376 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 377 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 378
 379 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 380 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 381 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 382 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386
 387 AC_SUBST([GL_LIB_NAME])
 388 AC_SUBST([OSMESA_LIB_NAME])
 389 AC_SUBST([EGL_LIB_NAME])
 390 AC_SUBST([GLESv1_CM_LIB_NAME])
 391 AC_SUBST([GLESv2_LIB_NAME])
 392 AC_SUBST([VG_LIB_NAME])
 393 AC_SUBST([GLAPI_LIB_NAME])
 394
 395 AC_SUBST([GL_LIB_GLOB])
 396 AC_SUBST([EGL_LIB_GLOB])
 397 AC_SUBST([GLESv1_CM_LIB_GLOB])
 398 AC_SUBST([GLESv2_LIB_GLOB])
 399 AC_SUBST([VG_LIB_GLOB])
 400 AC_SUBST([GLAPI_LIB_GLOB])
 401
 402 dnl
 403 dnl Arch/platform-specific settings
 404 dnl
 405 AC_ARG_ENABLE([asm],
 406     [AS_HELP_STRING([--disable-asm],
 407         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 408     [enable_asm="$enableval"],
 409     [enable_asm=yes]
 410 )
 411 asm_arch=""
 412 AC_MSG_CHECKING([whether to enable assembly])
 413 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 414 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 415 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 416     case "$host_cpu" in
 417     i?86 | x86_64 | amd64)
 418         enable_asm=no
 419         AC_MSG_RESULT([no, cross compiling])
 420         ;;
 421     esac
 422 fi
 423 # check for supported arches
 424 if test "x$enable_asm" = xyes; then
 425     case "$host_cpu" in
 426     i?86)
 427         case "$host_os" in
 428         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 429             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 430             ;;
 431         gnu*)
 432             asm_arch=x86
 433             ;;
 434         esac
 435         ;;
 436     x86_64|amd64)
 437         case "$host_os" in
 438         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 439             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 440             ;;
 441         esac
 442         ;;
 443     sparc*)
 444         case "$host_os" in
 445         linux*)
 446             asm_arch=sparc
 447             ;;
 448         esac
 449         ;;
 450     esac
 451
 452     case "$asm_arch" in
 453     x86)
 454         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 455         AC_MSG_RESULT([yes, x86])
 456         ;;
 457     x86_64|amd64)
 458         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 459         AC_MSG_RESULT([yes, x86_64])
 460         ;;
 461     sparc)
 462         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 463         AC_MSG_RESULT([yes, sparc])
 464         ;;
 465     *)
 466         AC_MSG_RESULT([no, platform not supported])
 467         ;;
 468     esac
 469 fi
 470
 471 dnl Check to see if dlopen is in default libraries (like Solaris, which
 472 dnl has it in libc), or if libdl is needed to get it.
 473 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 474     [AC_CHECK_LIB([dl], [dlopen],
 475        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 476 AC_SUBST([DLOPEN_LIBS])
 477
 478 case "$host_os" in
 479 darwin*|mingw*)
 480     ;;
 481 *)
 482     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 483                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 484                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 485     AC_SUBST([CLOCK_LIB])
 486     ;;
 487 esac
 488
 489 dnl See if posix_memalign is available
 490 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 491
 492 dnl Check for pthreads
 493 AX_PTHREAD
 494 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 495 dnl to -pthread, which causes problems if we need -lpthread to appear in
 496 dnl pkgconfig files.
 497 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 498
 499 dnl SELinux awareness.
 500 AC_ARG_ENABLE([selinux],
 501     [AS_HELP_STRING([--enable-selinux],
 502         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 503     [MESA_SELINUX="$enableval"],
 504     [MESA_SELINUX=no])
 505 if test "x$enable_selinux" = "xyes"; then
 506     AC_CHECK_HEADER([selinux/selinux.h],[],
 507                     [AC_MSG_ERROR([SELinux headers not found])])
 508     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 509                  [AC_MSG_ERROR([SELinux library not found])])
 510     SELINUX_LIBS="-lselinux"
 511     DEFINES="$DEFINES -DMESA_SELINUX"
 512 fi
 513 AC_SUBST([SELINUX_LIBS])
 514
 515 dnl Options for APIs
 516 AC_ARG_ENABLE([opengl],
 517     [AS_HELP_STRING([--disable-opengl],
 518         [disable support for standard OpenGL API @<:@default=no@:>@])],
 519     [enable_opengl="$enableval"],
 520     [enable_opengl=yes])
 521 AC_ARG_ENABLE([gles1],
 522     [AS_HELP_STRING([--enable-gles1],
 523         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 524     [enable_gles1="$enableval"],
 525     [enable_gles1=no])
 526 AC_ARG_ENABLE([gles2],
 527     [AS_HELP_STRING([--enable-gles2],
 528         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 529     [enable_gles2="$enableval"],
 530     [enable_gles2=no])
 531 AC_ARG_ENABLE([openvg],
 532     [AS_HELP_STRING([--enable-openvg],
 533         [enable support for OpenVG API @<:@default=no@:>@])],
 534     [enable_openvg="$enableval"],
 535     [enable_openvg=no])
 536
 537 AC_ARG_ENABLE([dri],
 538     [AS_HELP_STRING([--enable-dri],
 539         [enable DRI modules @<:@default=enabled@:>@])],
 540     [enable_dri="$enableval"],
 541     [enable_dri=yes])
 542 AC_ARG_ENABLE([glx],
 543     [AS_HELP_STRING([--enable-glx],
 544         [enable GLX library @<:@default=enabled@:>@])],
 545     [enable_glx="$enableval"],
 546     [enable_glx=yes])
 547 AC_ARG_ENABLE([osmesa],
 548     [AS_HELP_STRING([--enable-osmesa],
 549         [enable OSMesa library @<:@default=disabled@:>@])],
 550     [enable_osmesa="$enableval"],
 551     [enable_osmesa=no])
 552 AC_ARG_ENABLE([gallium-osmesa],
 553     [AS_HELP_STRING([--enable-gallium-osmesa],
 554         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 555     [enable_gallium_osmesa="$enableval"],
 556     [enable_gallium_osmesa=no])
 557 AC_ARG_ENABLE([egl],
 558     [AS_HELP_STRING([--disable-egl],
 559         [disable EGL library @<:@default=enabled@:>@])],
 560     [enable_egl="$enableval"],
 561     [enable_egl=yes])
 562
 563 AC_ARG_ENABLE([xorg],
 564     [AS_HELP_STRING([--enable-xorg],
 565         [enable support for X.Org DDX API @<:@default=no@:>@])],
 566     [enable_xorg="$enableval"],
 567     [enable_xorg=no])
 568 AC_ARG_ENABLE([xa],
 569     [AS_HELP_STRING([--enable-xa],
 570         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 571     [enable_xa="$enableval"],
 572     [enable_xa=no])
 573 AC_ARG_ENABLE([gbm],
 574    [AS_HELP_STRING([--enable-gbm],
 575          [enable gbm library @<:@default=auto@:>@])],
 576    [enable_gbm="$enableval"],
 577    [enable_gbm=auto])
 578
 579 AC_ARG_ENABLE([xvmc],
 580    [AS_HELP_STRING([--enable-xvmc],
 581          [enable xvmc library @<:@default=auto@:>@])],
 582    [enable_xvmc="$enableval"],
 583    [enable_xvmc=auto])
 584 AC_ARG_ENABLE([vdpau],
 585    [AS_HELP_STRING([--enable-vdpau],
 586          [enable vdpau library @<:@default=auto@:>@])],
 587    [enable_vdpau="$enableval"],
 588    [enable_vdpau=auto])
 589 AC_ARG_ENABLE([opencl],
 590    [AS_HELP_STRING([--enable-opencl],
 591          [enable OpenCL library NOTE: Enabling this option will also enable
 592           --with-llvm-shared-libs
 593           @<:@default=no@:>@])],
 594    [],
 595    [enable_opencl=no])
 596 AC_ARG_ENABLE([xlib-glx],
 597     [AS_HELP_STRING([--enable-xlib-glx],
 598         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 599     [enable_xlib_glx="$enableval"],
 600     [enable_xlib_glx=no])
 601 AC_ARG_ENABLE([gallium-egl],
 602     [AS_HELP_STRING([--enable-gallium-egl],
 603         [enable optional EGL state tracker (not required
 604          for EGL support in Gallium with OpenGL and OpenGL ES)
 605          @<:@default=disable@:>@])],
 606     [enable_gallium_egl="$enableval"],
 607     [enable_gallium_egl=no])
 608 AC_ARG_ENABLE([gallium-gbm],
 609     [AS_HELP_STRING([--enable-gallium-gbm],
 610         [enable optional gbm state tracker (not required for
 611          gbm support in Gallium)
 612          @<:@default=auto@:>@])],
 613     [enable_gallium_gbm="$enableval"],
 614     [enable_gallium_gbm=auto])
 615
 616 AC_ARG_ENABLE([r600-llvm-compiler],
 617     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 618         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 619     [enable_r600_llvm="$enableval"],
 620     [enable_r600_llvm=no])
 621
 622 AC_ARG_ENABLE([gallium-tests],
 623     [AS_HELP_STRING([--enable-gallium-tests],
 624         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 625     [enable_gallium_tests="$enableval"],
 626     [enable_gallium_tests=no])
 627
 628 # Option for Gallium drivers
 629
 630 # Keep this in sync with the --with-gallium-drivers help string default value
 631 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 632
 633 AC_ARG_WITH([gallium-drivers],
 634     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 635         [comma delimited Gallium drivers list, e.g.
 636         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 637         @<:@default=r300,r600,svga,swrast@:>@])],
 638     [with_gallium_drivers="$withval"],
 639     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 640
 641 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 642 # here so that the script doesn't choke on an unknown driver name later.
 643 case "$with_gallium_drivers" in
 644     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 645     no) with_gallium_drivers='' ;;
 646 esac
 647
 648 if test "x$enable_opengl" = xno -a \
 649         "x$enable_gles1" = xno -a \
 650         "x$enable_gles2" = xno -a \
 651         "x$enable_openvg" = xno -a \
 652         "x$enable_xorg" = xno -a \
 653         "x$enable_xa" = xno -a \
 654         "x$enable_xvmc" = xno -a \
 655         "x$enable_vdpau" = xno -a \
 656         "x$enable_opencl" = xno; then
 657     AC_MSG_ERROR([at least one API should be enabled])
 658 fi
 659
 660 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 661 if test "x$enable_opengl" = xno -a \
 662         "x$enable_gles1" = xyes; then
 663     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 664 fi
 665
 666 if test "x$enable_opengl" = xno -a \
 667         "x$enable_gles2" = xyes; then
 668     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 669 fi
 670
 671 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 672 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 673 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 674 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 675                                         "x$enable_gles1" = xyes -o \
 676                                         "x$enable_gles2" = xyes)
 677
 678 if test "x$enable_glx" = xno; then
 679     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 680     enable_xlib_glx=no
 681 fi
 682
 683 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 684     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 685 fi
 686
 687 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 688     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 689 fi
 690
 691 # Disable GLX if OpenGL is not enabled
 692 if test "x$enable_glx$enable_opengl" = xyesno; then
 693     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 694     enable_glx=no
 695 fi
 696
 697 # Disable GLX if DRI and Xlib-GLX are not enabled
 698 if test "x$enable_glx" = xyes -a \
 699         "x$enable_dri" = xno -a \
 700         "x$enable_xlib_glx" = xno; then
 701     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 702     enable_glx=no
 703 fi
 704
 705 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 706                                   "x$enable_dri" = xyes)
 707 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 708 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 709                                   "x$enable_osmesa" = xyes)
 710
 711 AC_ARG_ENABLE([shared-glapi],
 712     [AS_HELP_STRING([--enable-shared-glapi],
 713         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 714     [enable_shared_glapi="$enableval"],
 715     [enable_shared_glapi="$enable_dri"])
 716
 717 # Shared GLAPI is only useful for DRI
 718 if test "x$enable_dri" = xno; then
 719     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 720     enable_shared_glapi=no
 721 fi
 722
 723 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 724
 725 dnl
 726 dnl Driver specific build directories
 727 dnl
 728 GALLIUM_TARGET_DIRS=""
 729 GALLIUM_WINSYS_DIRS="sw"
 730 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 731 GALLIUM_STATE_TRACKERS_DIRS=""
 732
 733 case "x$enable_glx$enable_xlib_glx" in
 734 xyesyes)
 735     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 736     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 737     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 738     NEED_WINSYS_XLIB="yes"
 739     ;;
 740 esac
 741
 742 if test "x$enable_dri" = xyes; then
 743     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 744     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 745 fi
 746
 747 if test "x$enable_gallium_osmesa" = xyes; then
 748     if test -z "$with_gallium_drivers"; then
 749         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 750     fi
 751     if test "x$enable_osmesa" = xyes; then
 752         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 753     fi
 754     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 755     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 756 fi
 757
 758 AC_SUBST([MESA_LLVM])
 759
 760 # Check for libdrm
 761 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 762                   [have_libdrm=yes], [have_libdrm=no])
 763
 764 if test "x$enable_dri" = xyes; then
 765     # DRI must be shared, I think
 766     if test "$enable_static" = yes; then
 767         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 768     fi
 769
 770     # not a hard requirement as swrast does not depend on it
 771     if test "x$have_libdrm" = xyes; then
 772         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 773     fi
 774 fi
 775
 776 dnl Direct rendering or just indirect rendering
 777 case "$host_os" in
 778 gnu*)
 779     dnl Disable by default on GNU/Hurd
 780     driglx_direct_default="no"
 781     ;;
 782 cygwin*)
 783     dnl Disable by default on cygwin
 784     driglx_direct_default="no"
 785     ;;
 786 *)
 787     driglx_direct_default="yes"
 788     ;;
 789 esac
 790 AC_ARG_ENABLE([driglx-direct],
 791     [AS_HELP_STRING([--disable-driglx-direct],
 792         [disable direct rendering in GLX and EGL for DRI \
 793             @<:@default=auto@:>@])],
 794     [driglx_direct="$enableval"],
 795     [driglx_direct="$driglx_direct_default"])
 796
 797 dnl
 798 dnl libGL configuration per driver
 799 dnl
 800 case "x$enable_glx$enable_xlib_glx" in
 801 xyesyes)
 802     # Xlib-based GLX
 803     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 804     GL_PC_REQ_PRIV="x11 xext"
 805     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 806     GL_LIB_DEPS="$XLIBGL_LIBS"
 807     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 808     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 809     ;;
 810 xyesno)
 811     # DRI-based GLX
 812     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 813     if test x"$driglx_direct" = xyes; then
 814         if test "x$have_libdrm" != xyes; then
 815             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 816         fi
 817         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 818         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 819     fi
 820
 821     # find the DRI deps for libGL
 822     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 823
 824     # add xf86vidmode if available
 825     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 826     if test "$HAVE_XF86VIDMODE" = yes ; then
 827         dri_modules="$dri_modules xxf86vm"
 828     fi
 829
 830     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 831     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 832     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 833     GL_LIB_DEPS="$DRIGL_LIBS"
 834
 835     # need DRM libs, $PTHREAD_LIBS, etc.
 836     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 837     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 838     ;;
 839 esac
 840
 841 # This is outside the case (above) so that it is invoked even for non-GLX
 842 # builds.
 843 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 844
 845 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 846 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 847 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 848 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 849
 850 AC_SUBST([X11_INCLUDES])
 851 AC_SUBST([GL_LIB_DEPS])
 852 AC_SUBST([GL_PC_REQ_PRIV])
 853 AC_SUBST([GL_PC_LIB_PRIV])
 854 AC_SUBST([GL_PC_CFLAGS])
 855 AC_SUBST([DRI_PC_REQ_PRIV])
 856 AC_SUBST([GLESv1_CM_LIB_DEPS])
 857 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 858 AC_SUBST([GLESv2_LIB_DEPS])
 859 AC_SUBST([GLESv2_PC_LIB_PRIV])
 860
 861 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 862
 863 AC_SUBST([HAVE_XF86VIDMODE])
 864
 865 dnl
 866 dnl More GLX setup
 867 dnl
 868 case "x$enable_glx$enable_xlib_glx" in
 869 xyesyes)
 870     DEFINES="$DEFINES -DUSE_XSHM"
 871     ;;
 872 xyesno)
 873     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 874     if test "x$driglx_direct" = xyes; then
 875         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 876     fi
 877     ;;
 878 esac
 879
 880 dnl
 881 dnl TLS detection
 882 dnl
 883
 884 AC_ARG_ENABLE([glx-tls],
 885     [AS_HELP_STRING([--enable-glx-tls],
 886         [enable TLS support in GLX @<:@default=disabled@:>@])],
 887     [GLX_USE_TLS="$enableval"],
 888     [GLX_USE_TLS=no])
 889 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 890
 891 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 892       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 893
 894 dnl
 895 dnl More DRI setup
 896 dnl
 897 dnl Directory for DRI drivers
 898 AC_ARG_WITH([dri-driverdir],
 899     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 900         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 901     [DRI_DRIVER_INSTALL_DIR="$withval"],
 902     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 903 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 904 dnl Extra search path for DRI drivers
 905 AC_ARG_WITH([dri-searchpath],
 906     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 907         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 908     [DRI_DRIVER_SEARCH_DIR="$withval"],
 909     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 910 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 911 dnl Which drivers to build - default is chosen by platform
 912 AC_ARG_WITH([dri-drivers],
 913     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 914         [comma delimited DRI drivers list, e.g.
 915         "swrast,i965,radeon" @<:@default=auto@:>@])],
 916     [with_dri_drivers="$withval"],
 917     [with_dri_drivers=yes])
 918 if test "x$with_dri_drivers" = x; then
 919     with_dri_drivers=no
 920 fi
 921
 922 dnl If $with_dri_drivers is yes, directories will be added through
 923 dnl platform checks
 924 DRI_DIRS=""
 925 case "$with_dri_drivers" in
 926 no) ;;
 927 yes)
 928     # classic DRI drivers
 929     if test "x$enable_opengl" = xyes; then
 930         DRI_DIRS="yes"
 931     fi
 932     ;;
 933 *)
 934     # verify the requested driver directories exist
 935     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 936     for driver in $dri_drivers; do
 937         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 938             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 939     done
 940     DRI_DIRS="$dri_drivers"
 941     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 942         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 943     fi
 944     ;;
 945 esac
 946
 947 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 948 if test "x$enable_dri" = xyes; then
 949     # Platform specific settings and drivers to build
 950     case "$host_os" in
 951     linux*)
 952         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 953         DEFINES="$DEFINES -DHAVE_ALIAS"
 954
 955         case "$host_cpu" in
 956         x86_64|amd64)
 957             if test "x$DRI_DIRS" = "xyes"; then
 958                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 959             fi
 960             ;;
 961         powerpc*)
 962             # Build only the drivers for cards that exist on PowerPC.
 963             if test "x$DRI_DIRS" = "xyes"; then
 964                 DRI_DIRS="r200 radeon swrast"
 965             fi
 966             ;;
 967         sparc*)
 968             # Build only the drivers for cards that exist on sparc
 969             if test "x$DRI_DIRS" = "xyes"; then
 970                 DRI_DIRS="r200 radeon swrast"
 971             fi
 972             ;;
 973         esac
 974         ;;
 975     freebsd* | dragonfly* | *netbsd* | openbsd*)
 976         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 977         DEFINES="$DEFINES -DHAVE_ALIAS"
 978
 979         if test "x$DRI_DIRS" = "xyes"; then
 980             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 981         fi
 982         ;;
 983     gnu*)
 984         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 985         DEFINES="$DEFINES -DHAVE_ALIAS"
 986         ;;
 987     solaris*)
 988         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 989         ;;
 990     cygwin*)
 991         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 992         if test "x$DRI_DIRS" = "xyes"; then
 993             DRI_DIRS="swrast"
 994         fi
 995         ;;
 996     esac
 997
 998     # default drivers
 999     if test "x$DRI_DIRS" = "xyes"; then
1000         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1001     fi
1002
1003     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1004
1005     # Check for expat
1006     EXPAT_INCLUDES=""
1007     EXPAT_LIB=-lexpat
1008     AC_ARG_WITH([expat],
1009         [AS_HELP_STRING([--with-expat=DIR],
1010             [expat install directory])],[
1011         EXPAT_INCLUDES="-I$withval/include"
1012         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1013         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1014         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1015         ])
1016     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1017     save_LIBS="$LIBS"
1018     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1019         [AC_MSG_ERROR([Expat required for DRI.])])
1020     LIBS="$save_LIBS"
1021
1022     # If we are building any DRI driver other than swrast.
1023     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1024         # ... libdrm is required
1025         if test "x$have_libdrm" != xyes; then
1026             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1027         fi
1028         # ... and build dricommon
1029         HAVE_COMMON_DRI=yes
1030     fi
1031
1032     # put all the necessary libs together
1033     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1034     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1035
1036     DRI_DRIVER_LDFLAGS="-module -avoid-version -shared -Wl,-Bsymbolic"
1037 fi
1038 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1039 AC_SUBST([EXPAT_INCLUDES])
1040 AC_SUBST([DRI_LIB_DEPS])
1041 AC_SUBST([DRI_DRIVER_LDFLAGS])
1042 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1043
1044 case $DRI_DIRS in
1045 *i915*|*i965*)
1046     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1047
1048     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1049         case $d in
1050         i915)
1051             HAVE_I915_DRI=yes;
1052             ;;
1053         i965)
1054             HAVE_I965_DRI=yes;
1055             ;;
1056         esac
1057     done
1058
1059     ;;
1060 esac
1061
1062 case $DRI_DIRS in
1063 *nouveau*)
1064     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1065     HAVE_NOUVEAU_DRI=yes;
1066     ;;
1067 esac
1068
1069 case $DRI_DIRS in
1070 *radeon*|*r200*)
1071     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1072
1073     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1074         case $d in
1075         radeon)
1076             HAVE_RADEON_DRI=yes;
1077             ;;
1078         r200)
1079             HAVE_R200_DRI=yes;
1080             ;;
1081         esac
1082     done
1083
1084     ;;
1085 esac
1086
1087 case $DRI_DIRS in
1088 *swrast*)
1089     HAVE_SWRAST_DRI=yes;
1090     ;;
1091 esac
1092
1093 dnl
1094 dnl OSMesa configuration
1095 dnl
1096
1097 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1098 AC_ARG_WITH([osmesa-bits],
1099     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1100         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1101     [osmesa_bits="$withval"],
1102     [osmesa_bits=8])
1103 if test "x$osmesa_bits" != x8; then
1104     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1105         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1106         osmesa_bits=8
1107     fi
1108 fi
1109 case "x$osmesa_bits" in
1110 x8)
1111     OSMESA_LIB="${OSMESA_LIB}"
1112     ;;
1113 x16|x32)
1114     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1115     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1116     ;;
1117 *)
1118     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1119     ;;
1120 esac
1121
1122 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1123     # only link libraries with osmesa if shared
1124     if test "$enable_static" = no; then
1125         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1126     else
1127         OSMESA_LIB_DEPS=""
1128     fi
1129     OSMESA_MESA_DEPS=""
1130     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1131 fi
1132
1133 AC_SUBST([OSMESA_LIB_DEPS])
1134 AC_SUBST([OSMESA_MESA_DEPS])
1135 AC_SUBST([OSMESA_PC_REQ])
1136 AC_SUBST([OSMESA_PC_LIB_PRIV])
1137
1138 dnl
1139 dnl gbm configuration
1140 dnl
1141 if test "x$enable_gbm" = xauto; then
1142     case "$with_egl_platforms" in
1143         *drm*)
1144             enable_gbm=yes ;;
1145          *)
1146             enable_gbm=no ;;
1147     esac
1148 fi
1149 if test "x$enable_gbm" = xyes; then
1150     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1151                       AC_MSG_ERROR([gbm needs udev]))
1152
1153     if test "x$enable_dri" = xyes; then
1154         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1155         if test "x$enable_shared_glapi" = xno; then
1156             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1157         fi
1158     fi
1159 fi
1160 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1161 GBM_PC_REQ_PRIV="libudev"
1162 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1163 AC_SUBST([GBM_PC_REQ_PRIV])
1164 AC_SUBST([GBM_PC_LIB_PRIV])
1165
1166 dnl
1167 dnl EGL configuration
1168 dnl
1169 EGL_CLIENT_APIS=""
1170
1171 if test "x$enable_egl" = xyes; then
1172     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1173
1174     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1175
1176     if test "$enable_static" != yes; then
1177         # build egl_glx when libGL is built
1178         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1179                           [have_libudev=yes],[have_libudev=no])
1180         if test "$have_libudev" = yes; then
1181             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1182         fi
1183
1184         if test "x$enable_dri" = xyes; then
1185             HAVE_EGL_DRIVER_DRI2=1
1186         fi
1187
1188     fi
1189 fi
1190 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1191 AC_SUBST([EGL_LIB_DEPS])
1192
1193 dnl
1194 dnl EGL Gallium configuration
1195 dnl
1196 if test "x$enable_gallium_egl" = xyes; then
1197     if test "x$with_gallium_drivers" = x; then
1198         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1199     fi
1200     if test "x$enable_egl" = xno; then
1201         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1202     fi
1203     if test "x$have_libdrm" != xyes; then
1204         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1205     fi
1206
1207     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1208     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1209 fi
1210 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1211
1212 dnl
1213 dnl gbm Gallium configuration
1214 dnl
1215 if test "x$enable_gallium_gbm" = xauto; then
1216     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1217         yesyesyes*drm*)
1218             enable_gallium_gbm=yes ;;
1219          *)
1220             enable_gallium_gbm=no ;;
1221     esac
1222 fi
1223 if test "x$enable_gallium_gbm" = xyes; then
1224     if test "x$with_gallium_drivers" = x; then
1225         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1226     fi
1227     if test "x$enable_gbm" = xno; then
1228         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1229     fi
1230     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1231     if test "x$enable_dri" = xno; then
1232         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1233     fi
1234
1235     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1236     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1237     enable_gallium_loader=yes
1238 fi
1239 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1240
1241 dnl
1242 dnl X.Org DDX configuration
1243 dnl
1244 if test "x$enable_xorg" = xyes; then
1245     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1246     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1247     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1248     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1249         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1250         HAVE_XEXTPROTO_71="no")
1251     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1252 fi
1253 AM_CONDITIONAL(HAVE_ST_XORG, test "x$enable_xorg" = xyes)
1254
1255 dnl
1256 dnl XA configuration
1257 dnl
1258 if test "x$enable_xa" = xyes; then
1259 AC_PROG_AWK
1260 AC_PROG_GREP
1261 AC_CHECK_PROG(NM, nm, "nm")
1262 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1263 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1264 enable_xa=no
1265 fi
1266 fi
1267 if test "x$enable_xa" = xyes; then
1268     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1269     AC_SUBST(AWK)
1270     AC_SUBST(GREP)
1271     AC_SUBST(NM)
1272 fi
1273 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1274
1275 dnl
1276 dnl OpenVG configuration
1277 dnl
1278 VG_LIB_DEPS=""
1279
1280 if test "x$enable_openvg" = xyes; then
1281     if test "x$enable_egl" = xno; then
1282         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1283     fi
1284     if test "x$with_gallium_drivers" = x; then
1285         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1286     fi
1287     if test "x$enable_gallium_egl" = xno; then
1288         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1289     fi
1290
1291     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1292     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1293     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1294     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1295     AC_SUBST([VG_PC_LIB_PRIV])
1296 fi
1297 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1298
1299 dnl
1300 dnl Gallium G3DVL configuration
1301 dnl
1302 if test -n "$with_gallium_drivers"; then
1303     if test "x$enable_xvmc" = xauto; then
1304         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1305     fi
1306
1307     if test "x$enable_vdpau" = xauto; then
1308         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1309     fi
1310 fi
1311
1312 if test "x$enable_xvmc" = xyes; then
1313     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1314     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1315 fi
1316 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1317
1318 if test "x$enable_vdpau" = xyes; then
1319     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1320     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1321 fi
1322 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1323
1324 dnl
1325 dnl OpenCL configuration
1326 dnl
1327
1328 AC_ARG_WITH([libclc-path],
1329    [AS_HELP_STRING([--with-libclc-path],
1330          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1331    [LIBCLC_PATH="$withval"],
1332    [LIBCLC_PATH=""])
1333
1334 if test "x$LIBCLC_PATH" != x; then
1335    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1336                   Please review the updated build instructions for clover:
1337                   http://dri.freedesktop.org/wiki/GalliumCompute])
1338 fi
1339
1340
1341 AC_ARG_WITH([clang-libdir],
1342    [AS_HELP_STRING([--with-clang-libdir],
1343          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1344    [CLANG_LIBDIR="$withval"],
1345    [CLANG_LIBDIR=""])
1346
1347 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1348
1349 if test "x$enable_opencl" = xyes; then
1350     if test "x$with_gallium_drivers" = x; then
1351         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1352     fi
1353
1354     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1355         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1356     fi
1357
1358     if test "x$have_libclc" = xno; then
1359         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1360                     Make sure the directory containing libclc.pc is specified in your
1361                     PKG_CONFIG_PATH environment variable.
1362                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1363     else
1364         LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1365         LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1366         AC_SUBST([LIBCLC_INCLUDEDIR])
1367         AC_SUBST([LIBCLC_LIBEXECDIR])
1368     fi
1369
1370     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1371     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1372     enable_gallium_loader=yes
1373 fi
1374 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1375
1376 dnl
1377 dnl Gallium configuration
1378 dnl
1379 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1380
1381 AC_SUBST([LLVM_BINDIR])
1382 AC_SUBST([LLVM_CFLAGS])
1383 AC_SUBST([LLVM_CPPFLAGS])
1384 AC_SUBST([LLVM_CXXFLAGS])
1385 AC_SUBST([LLVM_LIBDIR])
1386 AC_SUBST([LLVM_LIBS])
1387 AC_SUBST([LLVM_LDFLAGS])
1388 AC_SUBST([LLVM_INCLUDEDIR])
1389 AC_SUBST([LLVM_VERSION])
1390 AC_SUBST([CLANG_RESOURCE_DIR])
1391
1392 case "x$enable_opengl$enable_gles1$enable_gles2" in
1393 x*yes*)
1394     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1395     ;;
1396 esac
1397
1398 AC_SUBST([VG_LIB_DEPS])
1399 AC_SUBST([EGL_CLIENT_APIS])
1400
1401 dnl
1402 dnl EGL Platforms configuration
1403 dnl
1404 AC_ARG_WITH([egl-platforms],
1405     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1406         [comma delimited native platforms libEGL supports, e.g.
1407         "x11,drm" @<:@default=auto@:>@])],
1408     [with_egl_platforms="$withval"],
1409     [if test "x$enable_egl" = xyes; then
1410         with_egl_platforms="x11"
1411     else
1412         with_egl_platforms=""
1413     fi])
1414
1415 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1416     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1417 fi
1418
1419 # Do per-EGL platform setups and checks
1420 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1421 for plat in $egl_platforms; do
1422         case "$plat" in
1423         wayland)
1424                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1425                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1426
1427                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1428                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1429                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1430                 ;;
1431
1432         x11)
1433                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1434
1435                 if test "x$enable_glx" = xyes; then
1436                         HAVE_EGL_DRIVER_GLX=1
1437                 fi
1438                 ;;
1439
1440         drm)
1441                 test "x$enable_gbm" = "xno" &&
1442                         AC_MSG_ERROR([EGL platform drm needs gbm])
1443                 ;;
1444
1445         android|fbdev|gdi|null)
1446                 ;;
1447
1448         *)
1449                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1450                 ;;
1451         esac
1452
1453         case "$plat$have_libudev" in
1454                 waylandno|drmno)
1455                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1456         esac
1457 done
1458
1459 # libEGL wants to default to the first platform specified in
1460 # ./configure.  parse that here.
1461 if test "x$egl_platforms" != "x"; then
1462     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1463     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1464 else
1465     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1466 fi
1467
1468 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1469     NEED_WINSYS_XLIB=yes
1470 fi
1471 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1472 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1473 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1474 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1475 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1476
1477 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1478 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1479
1480 AC_SUBST([EGL_NATIVE_PLATFORM])
1481 AC_SUBST([EGL_CFLAGS])
1482
1483 # If we don't have the X11 platform, set this define so we don't try to include
1484 # the X11 headers.
1485 if ! echo "$egl_platforms" | grep -q 'x11'; then
1486     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1487     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1488 fi
1489
1490 AC_ARG_WITH([egl-driver-dir],
1491     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1492                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1493     [EGL_DRIVER_INSTALL_DIR="$withval"],
1494     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1495 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1496
1497 AC_ARG_WITH([xorg-driver-dir],
1498     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1499                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1500     [XORG_DRIVER_INSTALL_DIR="$withval"],
1501     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1502 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1503
1504 AC_ARG_WITH([max-width],
1505     [AS_HELP_STRING([--with-max-width=N],
1506                     [Maximum framebuffer width (4096)])],
1507     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1508      AS_IF([test "${withval}" -gt "4096"],
1509            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1510 )
1511 AC_ARG_WITH([max-height],
1512     [AS_HELP_STRING([--with-max-height=N],
1513                     [Maximum framebuffer height (4096)])],
1514     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1515      AS_IF([test "${withval}" -gt "4096"],
1516            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1517 )
1518
1519 dnl
1520 dnl Gallium LLVM
1521 dnl
1522 AC_ARG_ENABLE([gallium-llvm],
1523     [AS_HELP_STRING([--enable-gallium-llvm],
1524         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1525     [enable_gallium_llvm="$enableval"],
1526     [enable_gallium_llvm=auto])
1527
1528 AC_ARG_WITH([llvm-shared-libs],
1529     [AS_HELP_STRING([--with-llvm-shared-libs],
1530         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1531     [],
1532     [with_llvm_shared_libs=no])
1533 AS_IF([test x$enable_opencl = xyes],
1534     [
1535         if test "x$with_llvm_shared_libs" != xyes; then
1536             AC_MSG_ERROR([OpenCL requires LLVM shared libraries])
1537         fi
1538     ])
1539
1540 AC_ARG_WITH([llvm-prefix],
1541     [AS_HELP_STRING([--with-llvm-prefix],
1542         [Prefix for LLVM installations in non-standard locations])],
1543     [llvm_prefix="$withval"],
1544     [llvm_prefix=""])
1545
1546
1547 # Call this inside ` ` to get the return value.
1548 # $1 is the llvm-config command with arguments.
1549 strip_unwanted_llvm_flags() {
1550     # Use \> (marks the end of the word)
1551     echo `$1` | sed \
1552         -e 's/-DNDEBUG\>//g' \
1553         -e 's/-pedantic\>//g' \
1554         -e 's/-Wcovered-switch-default\>//g' \
1555         -e 's/-O.\>//g' \
1556         -e 's/-g\>//g' \
1557         -e 's/-Wall\>//g' \
1558         -e 's/-fomit-frame-pointer\>//g'
1559 }
1560
1561
1562 if test "x$with_gallium_drivers" = x; then
1563     enable_gallium_llvm=no
1564 fi
1565 if test "x$enable_gallium_llvm" = xauto; then
1566     case "$host_cpu" in
1567     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1568     esac
1569 fi
1570 if test "x$enable_gallium_llvm" = xyes; then
1571     if test "x$llvm_prefix" != x; then
1572         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1573     else
1574         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1575     fi
1576
1577     if test "x$LLVM_CONFIG" != xno; then
1578         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1579         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1580         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1581         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1582         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1583         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1584         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1585         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1586
1587         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1588             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1589         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1590             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1591
1592         if test "x${LLVM_VERSION_MAJOR}" != x; then
1593             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1594         else
1595             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1596         fi
1597
1598         LLVM_COMPONENTS="engine bitwriter"
1599         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1600             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1601         fi
1602
1603         if test "x$enable_opencl" = xyes; then
1604             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1605             # LLVM 3.3 >= 177971 requires IRReader
1606             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1607                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1608             fi
1609             # LLVM 3.4 requires Option
1610             if $LLVM_CONFIG --components | grep -qw 'option'; then
1611                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1612             fi
1613         fi
1614         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1615         MESA_LLVM=1
1616
1617         dnl Check for Clang internal headers
1618         if test "x$enable_opencl" = xyes; then
1619             if test "x$CLANG_LIBDIR" = x; then
1620                 CLANG_LIBDIR=${LLVM_LIBDIR}
1621             fi
1622             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1623             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1624                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1625         fi
1626     else
1627         MESA_LLVM=0
1628         LLVM_VERSION_INT=0
1629     fi
1630 else
1631     MESA_LLVM=0
1632     LLVM_VERSION_INT=0
1633 fi
1634
1635 dnl Directory for XVMC libs
1636 AC_ARG_WITH([xvmc-libdir],
1637     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1638         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1639     [XVMC_LIB_INSTALL_DIR="$withval"],
1640     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1641 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1642
1643 dnl
1644 dnl Gallium Tests
1645 dnl
1646 if test "x$enable_gallium_tests" = xyes; then
1647     enable_gallium_loader=yes
1648 fi
1649 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1650
1651 if test "x$enable_gallium_loader" = xyes; then
1652     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1653 fi
1654 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1655
1656 dnl Directory for VDPAU libs
1657 AC_ARG_WITH([vdpau-libdir],
1658     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1659         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1660     [VDPAU_LIB_INSTALL_DIR="$withval"],
1661     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1662 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1663
1664 dnl Directory for OpenCL libs
1665 AC_ARG_WITH([opencl-libdir],
1666     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1667         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1668     [OPENCL_LIB_INSTALL_DIR="$withval"],
1669     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1670 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1671
1672 dnl
1673 dnl Gallium helper functions
1674 dnl
1675 gallium_check_st() {
1676     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1677          if test "x$have_libdrm" != xyes; then
1678             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1679          fi
1680          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1681     fi
1682     if test "x$enable_dri" = xyes && test "x$2" != x; then
1683          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1684          HAVE_COMMON_DRI=yes
1685     fi
1686     if test "x$enable_xorg" = xyes && test "x$3" != x; then
1687          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1688     fi
1689     if test "x$enable_xa" = xyes && test "x$4" != x; then
1690          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1691     fi
1692     if test "x$enable_xvmc" = xyes && test "x$5" != x; then
1693          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1694     fi
1695     if test "x$enable_vdpau" = xyes && test "x$6" != x; then
1696          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1697     fi
1698 }
1699
1700 gallium_require_llvm() {
1701     if test "x$MESA_LLVM" = x0; then
1702         case "$host_cpu" in
1703         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1704         esac
1705     fi
1706 }
1707
1708 gallium_require_drm_loader() {
1709     if test "x$enable_gallium_loader" = xyes; then
1710         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1711                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1712         if test "x$have_libdrm" != xyes; then
1713             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1714         fi
1715         enable_gallium_drm_loader=yes
1716     fi
1717 }
1718
1719 radeon_llvm_check() {
1720     LLVM_REQUIRED_VERSION_MAJOR="3"
1721     LLVM_REQUIRED_VERSION_MINOR="3"
1722     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1723         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1724     fi
1725     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1726         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1727                       sources with the --enable-experimental-targets=R600
1728                       configure flag])
1729     fi
1730     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1731     NEED_RADEON_LLVM=yes
1732     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1733                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1734 }
1735
1736 dnl Gallium drivers
1737 if test "x$enable_dri" = xyes -o "x$enable_xorg" = xyes -o \
1738         "x$enable_xa" = xyes -o "x$enable_xvmc" = xyes -o \
1739         "x$enable_vdpau" = xyes; then
1740     NEED_NONNULL_WINSYS=yes
1741 fi
1742 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1743
1744 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1745 if test "x$with_gallium_drivers" != x; then
1746     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1747     for driver in $gallium_drivers; do
1748         case "x$driver" in
1749         xsvga)
1750             HAVE_GALLIUM_SVGA=yes
1751             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1752             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1753             ;;
1754         xi915)
1755             HAVE_GALLIUM_I915=yes
1756             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1757             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1758             if test "x$MESA_LLVM" = x1; then
1759                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1760             fi
1761             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1762             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1763             ;;
1764         xilo)
1765             HAVE_GALLIUM_ILO=yes
1766             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1767             gallium_require_drm_loader
1768             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1769             gallium_check_st "intel/drm" "dri-ilo"
1770             ;;
1771         xr300)
1772             HAVE_GALLIUM_R300=yes
1773             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1774             gallium_require_llvm "Gallium R300"
1775             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1776             gallium_check_st "radeon/drm" "r300/dri" "" "" "r300/xvmc" "r300/vdpau"
1777             ;;
1778         xr600)
1779             HAVE_GALLIUM_R600=yes
1780             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1781             gallium_require_drm_loader
1782             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1783             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1784                 radeon_llvm_check
1785                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1786             fi
1787             if test "x$enable_r600_llvm" = xyes; then
1788                 USE_R600_LLVM_COMPILER=yes;
1789             fi
1790             if test "x$enable_opencl" = xyes; then
1791                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1792             fi
1793             gallium_check_st "radeon/drm" "r600/dri" "r600/xorg" "" "r600/xvmc" "r600/vdpau"
1794             ;;
1795         xradeonsi)
1796             HAVE_GALLIUM_RADEONSI=yes
1797             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1798             gallium_require_drm_loader
1799             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1800             radeon_llvm_check
1801             gallium_check_st "radeon/drm" "radeonsi/dri" "radeonsi/xorg" "" "" "radeonsi/vdpau" ""
1802             ;;
1803         xnouveau)
1804             HAVE_GALLIUM_NOUVEAU=yes
1805             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1806             gallium_require_drm_loader
1807             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1808             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1809             ;;
1810         xfreedreno)
1811             HAVE_GALLIUM_FREEDRENO=yes
1812             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1813             gallium_require_drm_loader
1814             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1815             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1816             ;;
1817         xswrast)
1818             HAVE_GALLIUM_SOFTPIPE=yes
1819             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1820             if test "x$MESA_LLVM" = x1; then
1821                 HAVE_GALLIUM_LLVMPIPE=yes
1822                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1823             fi
1824
1825             if test "x$enable_dri" = xyes; then
1826                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1827                 HAVE_COMMON_DRI=yes
1828             fi
1829             if test "x$enable_vdpau" = xyes; then
1830                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1831             fi
1832             if test "x$enable_xvmc" = xyes; then
1833                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1834             fi
1835             if test "x$enable_vdpau" = xyes -o "x$enable_xvmc" = xyes; then
1836                 NEED_WINSYS_XLIB=yes
1837                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1838             fi
1839             ;;
1840         *)
1841             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1842             ;;
1843         esac
1844     done
1845 fi
1846
1847 dnl Set LLVM_LIBS - This is done after the driver configuration so
1848 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1849 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1850 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1851 dnl this was causing the same libraries to be appear multiple times
1852 dnl in LLVM_LIBS.
1853
1854 if test "x$MESA_LLVM" != x0; then
1855
1856     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1857
1858     if test "x$with_llvm_shared_libs" = xyes; then
1859         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1860         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1861         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1862
1863         if test "x$llvm_have_one_so" = xyes; then
1864             dnl LLVM was built using auto*, so there is only one shared object.
1865             LLVM_LIBS="-l$LLVM_SO_NAME"
1866         else
1867             dnl If LLVM was built with CMake, there will be one shared object per
1868             dnl component.
1869             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1870                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1871         Please make sure you have built llvm with the --enable-shared option
1872         and that your llvm libraries are installed in $LLVM_LIBDIR
1873         If you have installed your llvm libraries to a different directory you
1874         can use the --with-llvm-prefix= configure flag to specify this directory.
1875         NOTE: Mesa is attempting to use llvm shared libraries because you have
1876         passed one of the following options to configure:
1877                 --with-llvm-shared-libs
1878                 --enable-opencl
1879         If you do not want to build with llvm shared libraries and instead want to
1880         use llvm static libraries then remove these options from your configure
1881         invocation and reconfigure.])])
1882
1883            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1884            dnl install uses a shared object for each compoenent and we have
1885            dnl already added all of these objects to LLVM_LIBS.
1886         fi
1887     fi
1888 fi
1889
1890 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1891 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1892 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1893 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1894 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1895 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1896 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1897 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1898 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1899 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1900
1901 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1902                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1903                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1904 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1905                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1906                                                   && test "x$MESA_LLVM" = x1)
1907
1908 if test "x$enable_gallium_loader" = xyes; then
1909     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1910
1911     if test "x$enable_gallium_drm_loader" = xyes; then
1912         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1913         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1914                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1915         if test "x$pipe_loader_have_xcb" = xyes; then
1916             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1917             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1918         fi
1919     fi
1920
1921     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1922     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1923 fi
1924
1925 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1926 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1927 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1928 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1929 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1930 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1931 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1932
1933 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1934                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1935                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1936                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1937 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1938                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1939 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1940 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1941 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1942 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1943 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1944 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1945 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1946 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1947
1948 AC_SUBST([ELF_LIB])
1949
1950 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1951                                      "x$enable_xlib_glx" = xyes -o \
1952                                      "x$enable_osmesa" = xyes -o \
1953                                      "x$enable_gallium_osmesa" = xyes)
1954 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1955 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1956 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1957
1958 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1959 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1960 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1961
1962 AC_SUBST([VDPAU_MAJOR], 1)
1963 AC_SUBST([VDPAU_MINOR], 0)
1964
1965 AC_SUBST([XVMC_MAJOR], 1)
1966 AC_SUBST([XVMC_MINOR], 0)
1967
1968 AC_SUBST([XA_MAJOR], 2)
1969 AC_SUBST([XA_MINOR], 0)
1970 AC_SUBST([XA_TINY], 0)
1971 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1972
1973 dnl Restore LDFLAGS and CPPFLAGS
1974 LDFLAGS="$_SAVE_LDFLAGS"
1975 CPPFLAGS="$_SAVE_CPPFLAGS"
1976
1977 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1978 if test "x$acv_mesa_CLANG" = xyes; then
1979     CFLAGS="$CFLAGS -Qunused-arguments"
1980     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1981 fi
1982
1983 dnl Add user CFLAGS and CXXFLAGS
1984 CFLAGS="$CFLAGS $USER_CFLAGS"
1985 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1986
1987 dnl Substitute the config
1988 AC_CONFIG_FILES([Makefile
1989                 src/Makefile
1990                 src/egl/Makefile
1991                 src/egl/drivers/Makefile
1992                 src/egl/drivers/dri2/Makefile
1993                 src/egl/drivers/glx/Makefile
1994                 src/egl/main/Makefile
1995                 src/egl/main/egl.pc
1996                 src/egl/wayland/Makefile
1997                 src/egl/wayland/wayland-drm/Makefile
1998                 src/egl/wayland/wayland-egl/Makefile
1999                 src/egl/wayland/wayland-egl/wayland-egl.pc
2000                 src/gallium/auxiliary/Makefile
2001                 src/gallium/auxiliary/pipe-loader/Makefile
2002                 src/gallium/drivers/Makefile
2003                 src/gallium/drivers/freedreno/Makefile
2004                 src/gallium/drivers/freedreno/a2xx/Makefile
2005                 src/gallium/drivers/freedreno/a3xx/Makefile
2006                 src/gallium/drivers/galahad/Makefile
2007                 src/gallium/drivers/i915/Makefile
2008                 src/gallium/drivers/identity/Makefile
2009                 src/gallium/drivers/ilo/Makefile
2010                 src/gallium/drivers/llvmpipe/Makefile
2011                 src/gallium/drivers/noop/Makefile
2012                 src/gallium/drivers/nouveau/Makefile
2013                 src/gallium/drivers/r300/Makefile
2014                 src/gallium/drivers/r600/Makefile
2015                 src/gallium/drivers/radeon/Makefile
2016                 src/gallium/drivers/radeonsi/Makefile
2017                 src/gallium/drivers/rbug/Makefile
2018                 src/gallium/drivers/softpipe/Makefile
2019                 src/gallium/drivers/svga/Makefile
2020                 src/gallium/drivers/trace/Makefile
2021                 src/gallium/state_trackers/Makefile
2022                 src/gallium/state_trackers/clover/Makefile
2023                 src/gallium/state_trackers/dri/Makefile
2024                 src/gallium/state_trackers/dri/drm/Makefile
2025                 src/gallium/state_trackers/dri/sw/Makefile
2026                 src/gallium/state_trackers/egl/Makefile
2027                 src/gallium/state_trackers/gbm/Makefile
2028                 src/gallium/state_trackers/glx/xlib/Makefile
2029                 src/gallium/state_trackers/osmesa/Makefile
2030                 src/gallium/state_trackers/vdpau/Makefile
2031                 src/gallium/state_trackers/vega/Makefile
2032                 src/gallium/state_trackers/xa/Makefile
2033                 src/gallium/state_trackers/xorg/Makefile
2034                 src/gallium/state_trackers/xvmc/Makefile
2035                 src/gallium/targets/Makefile
2036                 src/gallium/targets/dri-freedreno/Makefile
2037                 src/gallium/targets/dri-i915/Makefile
2038                 src/gallium/targets/dri-ilo/Makefile
2039                 src/gallium/targets/dri-nouveau/Makefile
2040                 src/gallium/targets/dri-swrast/Makefile
2041                 src/gallium/targets/dri-vmwgfx/Makefile
2042                 src/gallium/targets/egl-static/Makefile
2043                 src/gallium/targets/gbm/Makefile
2044                 src/gallium/targets/opencl/Makefile
2045                 src/gallium/targets/osmesa/Makefile
2046                 src/gallium/targets/osmesa/osmesa.pc
2047                 src/gallium/targets/pipe-loader/Makefile
2048                 src/gallium/targets/radeonsi/dri/Makefile
2049                 src/gallium/targets/radeonsi/vdpau/Makefile
2050                 src/gallium/targets/radeonsi/xorg/Makefile
2051                 src/gallium/targets/r300/dri/Makefile
2052                 src/gallium/targets/r300/vdpau/Makefile
2053                 src/gallium/targets/r300/xvmc/Makefile
2054                 src/gallium/targets/r600/dri/Makefile
2055                 src/gallium/targets/r600/vdpau/Makefile
2056                 src/gallium/targets/r600/xorg/Makefile
2057                 src/gallium/targets/r600/xvmc/Makefile
2058                 src/gallium/targets/libgl-xlib/Makefile
2059                 src/gallium/targets/vdpau-nouveau/Makefile
2060                 src/gallium/targets/vdpau-softpipe/Makefile
2061                 src/gallium/targets/xa-vmwgfx/Makefile
2062                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2063                 src/gallium/targets/xorg-i915/Makefile
2064                 src/gallium/targets/xorg-nouveau/Makefile
2065                 src/gallium/targets/xvmc-nouveau/Makefile
2066                 src/gallium/targets/xvmc-softpipe/Makefile
2067                 src/gallium/tests/trivial/Makefile
2068                 src/gallium/tests/unit/Makefile
2069                 src/gallium/winsys/Makefile
2070                 src/gallium/winsys/freedreno/drm/Makefile
2071                 src/gallium/winsys/i915/drm/Makefile
2072                 src/gallium/winsys/i915/sw/Makefile
2073                 src/gallium/winsys/intel/drm/Makefile
2074                 src/gallium/winsys/nouveau/drm/Makefile
2075                 src/gallium/winsys/radeon/drm/Makefile
2076                 src/gallium/winsys/svga/drm/Makefile
2077                 src/gallium/winsys/sw/dri/Makefile
2078                 src/gallium/winsys/sw/fbdev/Makefile
2079                 src/gallium/winsys/sw/null/Makefile
2080                 src/gallium/winsys/sw/wayland/Makefile
2081                 src/gallium/winsys/sw/wrapper/Makefile
2082                 src/gallium/winsys/sw/xlib/Makefile
2083                 src/gbm/Makefile
2084                 src/gbm/main/gbm.pc
2085                 src/glsl/Makefile
2086                 src/glx/Makefile
2087                 src/glx/tests/Makefile
2088                 src/gtest/Makefile
2089                 src/mapi/Makefile
2090                 src/mapi/es1api/Makefile
2091                 src/mapi/es1api/glesv1_cm.pc
2092                 src/mapi/es2api/Makefile
2093                 src/mapi/es2api/glesv2.pc
2094                 src/mapi/glapi/Makefile
2095                 src/mapi/glapi/gen/Makefile
2096                 src/mapi/glapi/tests/Makefile
2097                 src/mapi/shared-glapi/Makefile
2098                 src/mapi/shared-glapi/tests/Makefile
2099                 src/mapi/vgapi/Makefile
2100                 src/mapi/vgapi/vg.pc
2101                 src/mesa/Makefile
2102                 src/mesa/gl.pc
2103                 src/mesa/drivers/dri/dri.pc
2104                 src/mesa/drivers/dri/common/Makefile
2105                 src/mesa/drivers/dri/common/xmlpool/Makefile
2106                 src/mesa/drivers/dri/i915/Makefile
2107                 src/mesa/drivers/dri/i965/Makefile
2108                 src/mesa/drivers/dri/Makefile
2109                 src/mesa/drivers/dri/nouveau/Makefile
2110                 src/mesa/drivers/dri/r200/Makefile
2111                 src/mesa/drivers/dri/radeon/Makefile
2112                 src/mesa/drivers/dri/swrast/Makefile
2113                 src/mesa/drivers/osmesa/Makefile
2114                 src/mesa/drivers/osmesa/osmesa.pc
2115                 src/mesa/drivers/x11/Makefile
2116                 src/mesa/libdricore/Makefile
2117                 src/mesa/main/tests/Makefile
2118                 src/mesa/main/tests/hash_table/Makefile
2119                 src/mesa/program/Makefile
2120                 src/mesa/x86-64/Makefile
2121                 src/mesa/x86/Makefile])
2122
2123 dnl Sort the dirs alphabetically
2124 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2125 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2126 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2127 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2128
2129 AC_OUTPUT
2130
2131 dnl
2132 dnl Output some configuration info for the user
2133 dnl
2134 echo ""
2135 echo "        prefix:          $prefix"
2136 echo "        exec_prefix:     $exec_prefix"
2137 echo "        libdir:          $libdir"
2138 echo "        includedir:      $includedir"
2139
2140 dnl API info
2141 echo ""
2142 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2143 echo "        OpenVG:          $enable_openvg"
2144
2145 dnl Driver info
2146 echo ""
2147 case "x$enable_osmesa$enable_gallium_osmesa" in
2148 xnoyes)
2149         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2150         ;;
2151 xyesno)
2152         echo "        OSMesa:          lib$OSMESA_LIB"
2153         ;;
2154 xnono)
2155         echo "        OSMesa:          no"
2156         ;;
2157 esac
2158
2159 if test "x$enable_dri" != xno; then
2160         # cleanup the drivers var
2161         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2162         if test "x$DRI_DIRS" = x; then
2163             echo "        DRI drivers:     no"
2164         else
2165             echo "        DRI drivers:     $dri_dirs"
2166         fi
2167         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2168 fi
2169
2170 case "x$enable_glx$enable_xlib_glx" in
2171 xyesyes)
2172     echo "        GLX:             Xlib-based"
2173     ;;
2174 xyesno)
2175     echo "        GLX:             DRI-based"
2176     ;;
2177 *)
2178     echo "        GLX:             $enable_glx"
2179     ;;
2180 esac
2181
2182 dnl EGL
2183 echo ""
2184 echo "        EGL:             $enable_egl"
2185 if test "$enable_egl" = yes; then
2186     echo "        EGL platforms:   $egl_platforms"
2187
2188     egl_drivers=""
2189     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2190         egl_drivers="$egl_drivers builtin:egl_glx"
2191     fi
2192     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2193         egl_drivers="$egl_drivers builtin:egl_dri2"
2194     fi
2195
2196     if test "x$enable_gallium_egl" = xyes; then
2197         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2198         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2199     else
2200         echo "        EGL drivers:    $egl_drivers"
2201     fi
2202 fi
2203
2204 echo ""
2205 if test "x$MESA_LLVM" = x1; then
2206     echo "        llvm:            yes"
2207     echo "        llvm-config:     $LLVM_CONFIG"
2208     echo "        llvm-version:    $LLVM_VERSION"
2209 else
2210     echo "        llvm:            no"
2211 fi
2212
2213 echo ""
2214 if test -n "$with_gallium_drivers"; then
2215     echo "        Gallium:         yes"
2216     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2217     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2218     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2219     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2220 else
2221     echo "        Gallium:         no"
2222 fi
2223
2224
2225 dnl Libraries
2226 echo ""
2227 echo "        Shared libs:     $enable_shared"
2228 echo "        Static libs:     $enable_static"
2229 echo "        Shared-glapi:    $enable_shared_glapi"
2230
2231 dnl Compiler options
2232 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2233 cflags=`echo $CFLAGS | \
2234     $SED 's/^ *//;s/  */ /;s/ *$//'`
2235 cxxflags=`echo $CXXFLAGS | \
2236     $SED 's/^ *//;s/  */ /;s/ *$//'`
2237 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2238 echo ""
2239 echo "        CFLAGS:          $cflags"
2240 echo "        CXXFLAGS:        $cxxflags"
2241 echo "        Macros:          $defines"
2242 echo ""
2243 if test "x$MESA_LLVM" = x1; then
2244     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2245     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2246     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2247     echo ""
2248 fi
2249 echo "        PYTHON2:         $PYTHON2"
2250
2251 echo ""
2252 echo "        Run '${MAKE-make}' to build Mesa"
2253 echo ""