configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19 AM_INIT_AUTOMAKE([foreign])
  20
  21 dnl http://people.gnome.org/~walters/docs/build-api.txt
  22 dnl We don't support srcdir != builddir.
  23 echo \#buildapi-variable-no-builddir >/dev/null
  24
  25 # Support silent build rules, requires at least automake-1.11. Disable
  26 # by either passing --disable-silent-rules to configure or passing V=1
  27 # to make
  28 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  29
  30 LT_PREREQ([2.2])
  31 LT_INIT([disable-static])
  32
  33 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  34 USER_CFLAGS="$CFLAGS"
  35 USER_CXXFLAGS="$CXXFLAGS"
  36
  37 dnl Versions for external dependencies
  38 LIBDRM_REQUIRED=2.4.24
  39 LIBDRM_RADEON_REQUIRED=2.4.31
  40 LIBDRM_INTEL_REQUIRED=2.4.32
  41 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  42 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  43 DRI2PROTO_REQUIRED=2.6
  44 GLPROTO_REQUIRED=1.4.14
  45 LIBDRM_XORG_REQUIRED=2.4.24
  46 LIBKMS_XORG_REQUIRED=1.0.0
  47
  48 dnl Check for progs
  49 AC_PROG_CPP
  50 AC_PROG_CC
  51 AC_PROG_CXX
  52 AM_PROG_CC_C_O
  53 AC_CHECK_PROGS([MAKE], [gmake make])
  54 AC_CHECK_PROGS([PYTHON2], [python2 python])
  55 AC_PROG_SED
  56 AC_PROG_MKDIR_P
  57 AC_PATH_PROG([MKDEP], [makedepend])
  58
  59 if test "x$MKDEP" = "x"; then
  60     AC_MSG_ERROR([makedepend is required to build Mesa])
  61 fi
  62
  63 AC_PROG_YACC
  64 AC_PATH_PROG([YACC_INST], $YACC)
  65 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  66     if test -z "$YACC_INST"; then
  67         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  68     fi
  69 fi
  70 AC_PROG_LEX
  71
  72 AC_PATH_PROG([PERL], [perl])
  73
  74 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  75 dnl configuration in that case.
  76 AC_PROG_INSTALL
  77 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 106     AC_MSG_CHECKING([whether gcc version is sufficient])
 107     major=0
 108     minor=0
 109
 110     GCC_VERSION=`$CC -dumpversion`
 111     if test $? -eq 0; then
 112         major=`echo $GCC_VERSION | cut -d. -f1`
 113         minor=`echo $GCC_VERSION | cut -d. -f2`
 114     fi
 115
 116     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
 117         AC_MSG_RESULT([no])
 118         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 119     else
 120         AC_MSG_RESULT([yes])
 121     fi
 122 fi
 123
 124
 125 MKDEP_OPTIONS=-fdepend
 126 dnl Ask gcc where it's keeping its secret headers
 127 if test "x$GCC" = xyes; then
 128     for dir in include include-fixed; do
 129         GCC_INCLUDES=`$CC -print-file-name=$dir`
 130         if test "x$GCC_INCLUDES" != x && \
 131            test "$GCC_INCLUDES" != "$dir" && \
 132            test -d "$GCC_INCLUDES"; then
 133             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 134         fi
 135     done
 136 fi
 137 AC_SUBST([MKDEP_OPTIONS])
 138
 139 dnl Make sure the pkg-config macros are defined
 140 m4_ifndef([PKG_PROG_PKG_CONFIG],
 141     [m4_fatal([Could not locate the pkg-config autoconf macros.
 142   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 143   are in a different location, try setting the environment variable
 144   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 145 PKG_PROG_PKG_CONFIG()
 146
 147 dnl LIB_DIR - library basename
 148 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 149 AC_SUBST([LIB_DIR])
 150
 151 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 152 _SAVE_LDFLAGS="$LDFLAGS"
 153 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 154 AC_SUBST([EXTRA_LIB_PATH])
 155
 156 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 157 _SAVE_CPPFLAGS="$CPPFLAGS"
 158 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 159 AC_SUBST([X11_INCLUDES])
 160
 161 dnl Compiler macros
 162 DEFINES=""
 163 AC_SUBST([DEFINES])
 164 case "$host_os" in
 165 linux*|*-gnu*|gnu*)
 166     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 167     ;;
 168 solaris*)
 169     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 170     ;;
 171 cygwin*)
 172     DEFINES="$DEFINES -DPTHREADS"
 173     ;;
 174 esac
 175
 176 dnl Add flags for gcc and g++
 177 if test "x$GCC" = xyes; then
 178     CFLAGS="$CFLAGS -Wall -std=c99"
 179
 180     # Enable -Werror=implicit-function-declaration and
 181     # -Werror=missing-prototypes, if available, or otherwise, just
 182     # -Wmissing-prototypes.  This is particularly useful to avoid
 183     # generating a loadable driver module that has undefined symbols.
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 186     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 187     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 189                    AC_MSG_RESULT([yes]),
 190                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 191                     AC_MSG_RESULT([no])]);
 192
 193     # Enable -fvisibility=hidden if using a gcc that supports it
 194     save_CFLAGS="$CFLAGS"
 195     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 196     VISIBILITY_CFLAGS="-fvisibility=hidden"
 197     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 199                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 200
 201     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 202     CFLAGS=$save_CFLAGS
 203
 204     # Work around aliasing bugs - developers should comment this out
 205     CFLAGS="$CFLAGS -fno-strict-aliasing"
 206
 207     # gcc's builtin memcmp is slower than glibc's
 208     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 209     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 210 fi
 211 if test "x$GXX" = xyes; then
 212     CXXFLAGS="$CXXFLAGS -Wall"
 213
 214     # Enable -fvisibility=hidden if using a gcc that supports it
 215     save_CXXFLAGS="$CXXFLAGS"
 216     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 217     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 218     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 219     AC_LANG_PUSH([C++])
 220     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 221                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 222     AC_LANG_POP([C++])
 223
 224     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 225     CXXFLAGS=$save_CXXFLAGS
 226
 227     # Work around aliasing bugs - developers should comment this out
 228     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 229
 230     # gcc's builtin memcmp is slower than glibc's
 231     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 232     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 233 fi
 234
 235 dnl even if the compiler appears to support it, using visibility attributes isn't
 236 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 237 case "$host_os" in
 238 cygwin*)
 239     VISIBILITY_CFLAGS=""
 240     VISIBILITY_CXXFLAGS=""
 241     ;;
 242 esac
 243
 244 AC_SUBST([VISIBILITY_CFLAGS])
 245 AC_SUBST([VISIBILITY_CXXFLAGS])
 246
 247 dnl These should be unnecessary, but let the user set them if they want
 248 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 249     Default is to use CFLAGS.])
 250 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 251     compiler. Default is to use CFLAGS.])
 252 AC_SUBST([OPT_FLAGS])
 253 AC_SUBST([ARCH_FLAGS])
 254
 255 dnl
 256 dnl Hacks to enable 32 or 64 bit build
 257 dnl
 258 AC_ARG_ENABLE([32-bit],
 259     [AS_HELP_STRING([--enable-32-bit],
 260         [build 32-bit libraries @<:@default=auto@:>@])],
 261     [enable_32bit="$enableval"],
 262     [enable_32bit=auto]
 263 )
 264 if test "x$enable_32bit" = xyes; then
 265     if test "x$GCC" = xyes; then
 266         CFLAGS="$CFLAGS -m32"
 267         ARCH_FLAGS="$ARCH_FLAGS -m32"
 268     fi
 269     if test "x$GXX" = xyes; then
 270         CXXFLAGS="$CXXFLAGS -m32"
 271     fi
 272 fi
 273 AC_ARG_ENABLE([64-bit],
 274     [AS_HELP_STRING([--enable-64-bit],
 275         [build 64-bit libraries @<:@default=auto@:>@])],
 276     [enable_64bit="$enableval"],
 277     [enable_64bit=auto]
 278 )
 279 if test "x$enable_64bit" = xyes; then
 280     if test "x$GCC" = xyes; then
 281         CFLAGS="$CFLAGS -m64"
 282     fi
 283     if test "x$GXX" = xyes; then
 284         CXXFLAGS="$CXXFLAGS -m64"
 285     fi
 286 fi
 287
 288 dnl Can't have static and shared libraries, default to static if user
 289 dnl explicitly requested. If both disabled, set to static since shared
 290 dnl was explicitly requested.
 291 case "x$enable_static$enable_shared" in
 292 xyesyes )
 293     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 294     enable_shared=no
 295     ;;
 296 xnono )
 297     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 298     enable_static=yes
 299     ;;
 300 esac
 301
 302 dnl
 303 dnl mklib options
 304 dnl
 305 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 306 if test "$enable_static" = yes; then
 307     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 308 fi
 309 AC_SUBST([MKLIB_OPTIONS])
 310
 311 dnl
 312 dnl other compiler options
 313 dnl
 314 AC_ARG_ENABLE([debug],
 315     [AS_HELP_STRING([--enable-debug],
 316         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 317     [enable_debug="$enableval"],
 318     [enable_debug=no]
 319 )
 320 if test "x$enable_debug" = xyes; then
 321     DEFINES="$DEFINES -DDEBUG"
 322     if test "x$GCC" = xyes; then
 323         CFLAGS="$CFLAGS -g"
 324     fi
 325     if test "x$GXX" = xyes; then
 326         CXXFLAGS="$CXXFLAGS -g"
 327     fi
 328 fi
 329
 330 dnl
 331 dnl library names
 332 dnl
 333 LIB_PREFIX_GLOB='lib'
 334 LIB_VERSION_SEPARATOR='.'
 335 if test "$enable_static" = yes; then
 336     LIB_EXTENSION='a'
 337 else
 338     case "$host_os" in
 339     darwin* )
 340         LIB_EXTENSION='dylib' ;;
 341     cygwin* )
 342         dnl prefix can be 'cyg' or 'lib'
 343         LIB_PREFIX_GLOB='???'
 344         LIB_VERSION_SEPARATOR='-'
 345         LIB_EXTENSION='dll' ;;
 346     aix* )
 347         LIB_EXTENSION='a' ;;
 348     * )
 349         LIB_EXTENSION='so' ;;
 350     esac
 351 fi
 352
 353 dnl
 354 dnl Mangled Mesa support
 355 dnl
 356 AC_ARG_ENABLE([mangling],
 357   [AS_HELP_STRING([--enable-mangling],
 358     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 359   [enable_mangling="${enableval}"],
 360   [enable_mangling=no]
 361 )
 362 GL_LIB="GL"
 363 GLU_LIB="GLU"
 364 OSMESA_LIB="OSMesa"
 365 if test "x${enable_mangling}" = "xyes" ; then
 366   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 367   GL_LIB="MangledGL"
 368   GLU_LIB="MangledGLU"
 369   OSMESA_LIB="MangledOSMesa"
 370 fi
 371 AC_SUBST([GL_LIB])
 372 AC_SUBST([GLU_LIB])
 373 AC_SUBST([OSMESA_LIB])
 374 AM_CONDITIONAL(HAVE_MANGLED_GL, test $GL_LIB = MangledGL)
 375
 376 dnl
 377 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 378 dnl
 379 AC_ARG_ENABLE([texture-float],
 380     [AS_HELP_STRING([--enable-texture-float],
 381         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 382     [enable_texture_float="$enableval"],
 383     [enable_texture_float=no]
 384 )
 385 if test "x$enable_texture_float" = xyes; then
 386     AC_MSG_WARN([Floating-point textures enabled.])
 387     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 388     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 389 fi
 390
 391 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 392 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 393 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 394 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 395 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 396 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 397 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 398 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 399
 400 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409
 410 AC_SUBST([GL_LIB_NAME])
 411 AC_SUBST([GLU_LIB_NAME])
 412 AC_SUBST([OSMESA_LIB_NAME])
 413 AC_SUBST([EGL_LIB_NAME])
 414 AC_SUBST([GLESv1_CM_LIB_NAME])
 415 AC_SUBST([GLESv2_LIB_NAME])
 416 AC_SUBST([VG_LIB_NAME])
 417 AC_SUBST([GLAPI_LIB_NAME])
 418
 419 AC_SUBST([GL_LIB_GLOB])
 420 AC_SUBST([GLU_LIB_GLOB])
 421 AC_SUBST([OSMESA_LIB_GLOB])
 422 AC_SUBST([EGL_LIB_GLOB])
 423 AC_SUBST([GLESv1_CM_LIB_GLOB])
 424 AC_SUBST([GLESv2_LIB_GLOB])
 425 AC_SUBST([VG_LIB_GLOB])
 426 AC_SUBST([GLAPI_LIB_GLOB])
 427
 428 dnl
 429 dnl Arch/platform-specific settings
 430 dnl
 431 AC_ARG_ENABLE([asm],
 432     [AS_HELP_STRING([--disable-asm],
 433         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 434     [enable_asm="$enableval"],
 435     [enable_asm=yes]
 436 )
 437 asm_arch=""
 438 ASM_FLAGS=""
 439 MESA_ASM_SOURCES=""
 440 GLAPI_ASM_SOURCES=""
 441 AC_MSG_CHECKING([whether to enable assembly])
 442 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 443 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 444 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 445     case "$host_cpu" in
 446     i?86 | x86_64)
 447         enable_asm=no
 448         AC_MSG_RESULT([no, cross compiling])
 449         ;;
 450     esac
 451 fi
 452 # check for supported arches
 453 if test "x$enable_asm" = xyes; then
 454     case "$host_cpu" in
 455     i?86)
 456         case "$host_os" in
 457         linux* | *freebsd* | dragonfly* | *netbsd*)
 458             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 459             ;;
 460         esac
 461         ;;
 462     x86_64)
 463         case "$host_os" in
 464         linux* | *freebsd* | dragonfly* | *netbsd*)
 465             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 466             ;;
 467         esac
 468         ;;
 469     powerpc)
 470         case "$host_os" in
 471         linux*)
 472             asm_arch=ppc
 473             ;;
 474         esac
 475         ;;
 476     sparc*)
 477         case "$host_os" in
 478         linux*)
 479             asm_arch=sparc
 480             ;;
 481         esac
 482         ;;
 483     esac
 484
 485     case "$asm_arch" in
 486     x86)
 487         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 488         MESA_ASM_SOURCES='$(X86_SOURCES)'
 489         GLAPI_ASM_SOURCES='$(X86_API)'
 490         AC_MSG_RESULT([yes, x86])
 491         ;;
 492     x86_64)
 493         ASM_FLAGS="-DUSE_X86_64_ASM"
 494         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 495         GLAPI_ASM_SOURCES='$(X86-64_API)'
 496         AC_MSG_RESULT([yes, x86_64])
 497         ;;
 498     sparc)
 499         ASM_FLAGS="-DUSE_SPARC_ASM"
 500         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 501         GLAPI_ASM_SOURCES='$(SPARC_API)'
 502         AC_MSG_RESULT([yes, sparc])
 503         ;;
 504     *)
 505         AC_MSG_RESULT([no, platform not supported])
 506         ;;
 507     esac
 508 fi
 509 AC_SUBST([ASM_FLAGS])
 510 AC_SUBST([MESA_ASM_SOURCES])
 511 AC_SUBST([GLAPI_ASM_SOURCES])
 512
 513 dnl PIC code macro
 514 MESA_PIC_FLAGS
 515
 516 dnl Check to see if dlopen is in default libraries (like Solaris, which
 517 dnl has it in libc), or if libdl is needed to get it.
 518 AC_CHECK_FUNC([dlopen], [],
 519     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 520 AC_SUBST([DLOPEN_LIBS])
 521
 522 dnl See if posix_memalign is available
 523 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 524
 525 dnl SELinux awareness.
 526 AC_ARG_ENABLE([selinux],
 527     [AS_HELP_STRING([--enable-selinux],
 528         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 529     [MESA_SELINUX="$enableval"],
 530     [MESA_SELINUX=no])
 531 if test "x$enable_selinux" = "xyes"; then
 532     AC_CHECK_HEADER([selinux/selinux.h],[],
 533                     [AC_MSG_ERROR([SELinux headers not found])])
 534     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 535                  [AC_MSG_ERROR([SELinux library not found])])
 536     SELINUX_LIBS="-lselinux"
 537     DEFINES="$DEFINES -DMESA_SELINUX"
 538 fi
 539
 540 dnl Options for APIs
 541 AC_ARG_ENABLE([opengl],
 542     [AS_HELP_STRING([--disable-opengl],
 543         [disable support for standard OpenGL API @<:@default=no@:>@])],
 544     [enable_opengl="$enableval"],
 545     [enable_opengl=yes])
 546 AC_ARG_ENABLE([gles1],
 547     [AS_HELP_STRING([--enable-gles1],
 548         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 549     [enable_gles1="$enableval"],
 550     [enable_gles1=no])
 551 AC_ARG_ENABLE([gles2],
 552     [AS_HELP_STRING([--enable-gles2],
 553         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 554     [enable_gles2="$enableval"],
 555     [enable_gles2=no])
 556 AC_ARG_ENABLE([openvg],
 557     [AS_HELP_STRING([--enable-openvg],
 558         [enable support for OpenVG API @<:@default=no@:>@])],
 559     [enable_openvg="$enableval"],
 560     [enable_openvg=no])
 561
 562 AC_ARG_ENABLE([dri],
 563     [AS_HELP_STRING([--enable-dri],
 564         [enable DRI modules @<:@default=auto@:>@])],
 565     [enable_dri="$enableval"],
 566     [enable_dri=auto])
 567 AC_ARG_ENABLE([glx],
 568     [AS_HELP_STRING([--enable-glx],
 569         [enable GLX library @<:@default=auto@:>@])],
 570     [enable_glx="$enableval"],
 571     [enable_glx=auto])
 572 AC_ARG_ENABLE([osmesa],
 573     [AS_HELP_STRING([--enable-osmesa],
 574         [enable OSMesa library @<:@default=auto@:>@])],
 575     [enable_osmesa="$enableval"],
 576     [enable_osmesa=auto])
 577 AC_ARG_ENABLE([egl],
 578     [AS_HELP_STRING([--disable-egl],
 579         [disable EGL library @<:@default=enabled@:>@])],
 580     [enable_egl="$enableval"],
 581     [enable_egl=yes])
 582
 583 AC_ARG_ENABLE([xorg],
 584     [AS_HELP_STRING([--enable-xorg],
 585         [enable support for X.Org DDX API @<:@default=no@:>@])],
 586     [enable_xorg="$enableval"],
 587     [enable_xorg=no])
 588 AC_ARG_ENABLE([xa],
 589     [AS_HELP_STRING([--enable-xa],
 590         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 591     [enable_xa="$enableval"],
 592     [enable_xa=no])
 593 AC_ARG_ENABLE([d3d1x],
 594     [AS_HELP_STRING([--enable-d3d1x],
 595         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 596     [enable_d3d1x="$enableval"],
 597     [enable_d3d1x=no])
 598 AC_ARG_ENABLE([gbm],
 599    [AS_HELP_STRING([--enable-gbm],
 600          [enable gbm library @<:@default=auto@:>@])],
 601    [enable_gbm="$enableval"],
 602    [enable_gbm=auto])
 603
 604 AC_ARG_ENABLE([xvmc],
 605    [AS_HELP_STRING([--enable-xvmc],
 606          [enable xvmc library @<:@default=auto@:>@])],
 607    [enable_xvmc="$enableval"],
 608    [enable_xvmc=auto])
 609 AC_ARG_ENABLE([vdpau],
 610    [AS_HELP_STRING([--enable-vdpau],
 611          [enable vdpau library @<:@default=auto@:>@])],
 612    [enable_vdpau="$enableval"],
 613    [enable_vdpau=auto])
 614 AC_ARG_ENABLE([va],
 615    [AS_HELP_STRING([--enable-va],
 616          [enable va library @<:@default=auto@:>@])],
 617    [enable_va="$enableval"],
 618    [enable_va=auto])
 619
 620 AC_ARG_ENABLE([xlib_glx],
 621     [AS_HELP_STRING([--enable-xlib-glx],
 622         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 623     [enable_xlib_glx="$enableval"],
 624     [enable_xlib_glx=auto])
 625 AC_ARG_ENABLE([gallium_egl],
 626     [AS_HELP_STRING([--enable-gallium-egl],
 627         [enable optional EGL state tracker (not required
 628          for EGL support in Gallium with OpenGL and OpenGL ES)
 629          @<:@default=disable@:>@])],
 630     [enable_gallium_egl="$enableval"],
 631     [enable_gallium_egl=no])
 632 AC_ARG_ENABLE([gallium_gbm],
 633     [AS_HELP_STRING([--enable-gallium-gbm],
 634         [enable optional gbm state tracker (not required for
 635          gbm support in Gallium)
 636          @<:@default=auto@:>@])],
 637     [enable_gallium_gbm="$enableval"],
 638     [enable_gallium_gbm=auto])
 639
 640 # Option for Gallium drivers
 641 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 642
 643 AC_ARG_WITH([gallium-drivers],
 644     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 645         [comma delimited Gallium drivers list, e.g.
 646         "i915,nouveau,r300,r600,svga,swrast"
 647         @<:@default=r300,r600,swrast@:>@])],
 648     [with_gallium_drivers="$withval"],
 649     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 650
 651 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 652 # here so that the script doesn't choke on an unknown driver name later.
 653 case "$with_gallium_drivers" in
 654     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 655     no) with_gallium_drivers='' ;;
 656 esac
 657
 658 if test "x$enable_opengl" = xno -a \
 659         "x$enable_gles1" = xno -a \
 660         "x$enable_gles2" = xno -a \
 661         "x$enable_openvg" = xno -a \
 662         "x$enable_xorg" = xno -a \
 663         "x$enable_xa" = xno -a \
 664         "x$enable_d3d1x" = xno -a \
 665         "x$enable_xvmc" = xno -a \
 666         "x$enable_vdpau" = xno -a \
 667         "x$enable_va" = xno; then
 668     AC_MSG_ERROR([at least one API should be enabled])
 669 fi
 670
 671 API_DEFINES=""
 672 if test "x$enable_opengl" = xno; then
 673     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 674 else
 675     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 676 fi
 677 if test "x$enable_gles1" = xyes; then
 678     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 679 fi
 680 if test "x$enable_gles2" = xyes; then
 681     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 682 fi
 683 AC_SUBST([API_DEFINES])
 684
 685 AC_ARG_ENABLE([shared-glapi],
 686     [AS_HELP_STRING([--enable-shared-glapi],
 687         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 688     [enable_shared_glapi="$enableval"],
 689     [enable_shared_glapi=no])
 690
 691 SHARED_GLAPI="0"
 692 if test "x$enable_shared_glapi" = xyes; then
 693     SHARED_GLAPI="1"
 694     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 695     # the remap table)
 696     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 697     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 698 fi
 699 AC_SUBST([SHARED_GLAPI])
 700 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 701
 702 dnl
 703 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 704 dnl More later: fbdev, ...
 705 dnl
 706 default_driver="xlib"
 707
 708 case "$host_os" in
 709 linux*)
 710     case "$host_cpu" in
 711     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 712     esac
 713     ;;
 714 *freebsd* | dragonfly* | *netbsd*)
 715     case "$host_cpu" in
 716     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 717     esac
 718     ;;
 719 esac
 720
 721 if test "x$enable_opengl" = xno; then
 722     default_driver="no"
 723 fi
 724
 725 AC_ARG_WITH([driver],
 726     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 727     [mesa_driver="$withval"],
 728     [mesa_driver=auto])
 729 dnl Check for valid option
 730 case "x$mesa_driver" in
 731 xxlib|xdri|xosmesa|xno)
 732     if test "x$enable_dri" != xauto -o \
 733             "x$enable_glx" != xauto -o \
 734             "x$enable_osmesa" != xauto -o \
 735             "x$enable_xlib_glx" != xauto; then
 736         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 737     fi
 738     ;;
 739 xauto)
 740     mesa_driver="$default_driver"
 741     ;;
 742 *)
 743     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 744     ;;
 745 esac
 746
 747 # map $mesa_driver to APIs
 748 if test "x$enable_dri" = xauto; then
 749     case "x$mesa_driver" in
 750     xdri) enable_dri=yes ;;
 751     *)    enable_dri=no ;;
 752     esac
 753 fi
 754
 755 if test "x$enable_glx" = xauto; then
 756     case "x$mesa_driver" in
 757     xdri|xxlib) enable_glx=yes ;;
 758     *)          enable_glx=no ;;
 759     esac
 760 fi
 761
 762 if test "x$enable_osmesa" = xauto; then
 763     case "x$mesa_driver" in
 764     xxlib|xosmesa) enable_osmesa=yes ;;
 765     *)             enable_osmesa=no ;;
 766     esac
 767 fi
 768
 769 if test "x$enable_xlib_glx" = xauto; then
 770     case "x$mesa_driver" in
 771     xxlib) enable_xlib_glx=yes ;;
 772     *)     enable_xlib_glx=no ;;
 773     esac
 774 fi
 775
 776 if test "x$enable_glx" = xno; then
 777     enable_xlib_glx=no
 778 fi
 779
 780 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 781
 782 dnl
 783 dnl Driver specific build directories
 784 dnl
 785
 786 dnl this variable will be prepended to SRC_DIRS and is not exported
 787 CORE_DIRS=""
 788
 789 SRC_DIRS="gtest"
 790 GLU_DIRS="sgi"
 791 GALLIUM_DIRS="auxiliary drivers state_trackers"
 792 GALLIUM_TARGET_DIRS=""
 793 GALLIUM_WINSYS_DIRS="sw"
 794 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 795 GALLIUM_STATE_TRACKERS_DIRS=""
 796
 797 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 798 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 799 x*yes*)
 800     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 801     ;;
 802 esac
 803
 804 # build glapi if OpenGL is enabled
 805 if test "x$enable_opengl" = xyes; then
 806     CORE_DIRS="$CORE_DIRS mapi/glapi"
 807 fi
 808
 809 # build es1api if OpenGL ES 1.x is enabled
 810 if test "x$enable_gles1" = xyes; then
 811     CORE_DIRS="$CORE_DIRS mapi/es1api"
 812 fi
 813
 814 # build es2api if OpenGL ES 2.x is enabled
 815 if test "x$enable_gles2" = xyes; then
 816     CORE_DIRS="$CORE_DIRS mapi/es2api"
 817 fi
 818
 819 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 820 case "x$enable_opengl$enable_gles1$enable_gles2" in
 821 x*yes*)
 822     CORE_DIRS="$CORE_DIRS glsl mesa"
 823     ;;
 824 esac
 825
 826 case "x$enable_glx$enable_xlib_glx" in
 827 xyesyes)
 828     DRIVER_DIRS="$DRIVER_DIRS x11"
 829     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 830     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 831     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 832     HAVE_WINSYS_XLIB="yes"
 833     ;;
 834 xyesno)
 835     # DRI-based GLX
 836     SRC_DIRS="$SRC_DIRS glx"
 837     ;;
 838 esac
 839
 840 if test "x$enable_dri" = xyes; then
 841     DRIVER_DIRS="$DRIVER_DIRS dri"
 842
 843     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 844     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 845     HAVE_ST_DRI="yes"
 846 fi
 847
 848 if test "x$enable_osmesa" = xyes; then
 849     # the empty space matters for osmesa... (see src/mesa/Makefile)
 850     if test -n "$DRIVER_DIRS"; then
 851         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 852     else
 853         DRIVER_DIRS="osmesa"
 854     fi
 855 fi
 856
 857 AC_SUBST([SRC_DIRS])
 858 AC_SUBST([GLU_DIRS])
 859 AC_SUBST([DRIVER_DIRS])
 860 AC_SUBST([GALLIUM_DIRS])
 861 AC_SUBST([GALLIUM_TARGET_DIRS])
 862 AC_SUBST([GALLIUM_WINSYS_DIRS])
 863 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 864 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 865 AC_SUBST([MESA_LLVM])
 866
 867 # Check for libdrm
 868 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 869                   [have_libdrm=yes], [have_libdrm=no])
 870
 871 if test "x$enable_dri" = xyes; then
 872     # DRI must be shared, I think
 873     if test "$enable_static" = yes; then
 874         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 875     fi
 876
 877     # not a hard requirement as swrast does not depend on it
 878     if test "x$have_libdrm" = xyes; then
 879         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 880     fi
 881 fi
 882
 883 dnl
 884 dnl Find out if X is available. The variable have_x is set if libX11 is
 885 dnl found to mimic AC_PATH_XTRA.
 886 dnl
 887 if test -n "$PKG_CONFIG"; then
 888     AC_MSG_CHECKING([pkg-config files for X11 are available])
 889     PKG_CHECK_EXISTS([x11],[
 890         x11_pkgconfig=yes
 891         have_x=yes
 892         ],[
 893         x11_pkgconfig=no
 894     ])
 895     AC_MSG_RESULT([$x11_pkgconfig])
 896 else
 897     x11_pkgconfig=no
 898 fi
 899 dnl Use the autoconf macro if no pkg-config files
 900 if test "$x11_pkgconfig" = yes; then
 901     PKG_CHECK_MODULES([X11], [x11])
 902 else
 903     AC_PATH_XTRA
 904     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 905     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 906     AC_SUBST([X11_CFLAGS])
 907     AC_SUBST([X11_LIBS])
 908 fi
 909
 910 dnl Try to tell the user that the --x-* options are only used when
 911 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 912 m4_divert_once([HELP_BEGIN],
 913 [These options are only used when the X libraries cannot be found by the
 914 pkg-config utility.])
 915
 916 dnl We need X for xlib and dri, so bomb now if it's not found
 917 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 918     AC_MSG_ERROR([X11 development libraries needed for GLX])
 919 fi
 920
 921 if test "x$enable_glx" = xyes; then
 922     DEFINES="$DEFINES -DUSE_XCB"
 923 fi
 924
 925 dnl Direct rendering or just indirect rendering
 926 case "$host_os" in
 927 gnu*)
 928     dnl Disable by default on GNU/Hurd
 929     driglx_direct_default="no"
 930     ;;
 931 cygwin*)
 932     dnl Disable by default on cygwin
 933     driglx_direct_default="no"
 934     ;;
 935 *)
 936     driglx_direct_default="yes"
 937     ;;
 938 esac
 939 AC_ARG_ENABLE([driglx-direct],
 940     [AS_HELP_STRING([--disable-driglx-direct],
 941         [enable direct rendering in GLX and EGL for DRI \
 942             @<:@default=auto@:>@])],
 943     [driglx_direct="$enableval"],
 944     [driglx_direct="$driglx_direct_default"])
 945
 946 dnl
 947 dnl libGL configuration per driver
 948 dnl
 949 case "x$enable_glx$enable_xlib_glx" in
 950 xyesyes)
 951     # Xlib-based GLX
 952     if test "$x11_pkgconfig" = yes; then
 953         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 954         GL_PC_REQ_PRIV="x11 xext"
 955         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 956         GL_LIB_DEPS="$XLIBGL_LIBS"
 957     else
 958         # should check these...
 959         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 960         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 961         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 962         GL_PC_CFLAGS="$X11_INCLUDES"
 963     fi
 964     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 965     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 966     ;;
 967 xyesno)
 968     # DRI-based GLX
 969     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 970     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 971     if test x"$driglx_direct" = xyes; then
 972         if test "x$have_libdrm" != xyes; then
 973             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 974         fi
 975         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 976         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 977     fi
 978
 979     # find the DRI deps for libGL
 980     if test "$x11_pkgconfig" = yes; then
 981         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 982
 983         # add xf86vidmode if available
 984         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 985         if test "$HAVE_XF86VIDMODE" = yes ; then
 986             dri_modules="$dri_modules xxf86vm"
 987         fi
 988
 989         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 990         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 991         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 992         GL_LIB_DEPS="$DRIGL_LIBS"
 993     else
 994         # should check these...
 995         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 996         if test "x$HAVE_XF86VIDMODE" == xyes; then
 997            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 998         else
 999            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1000         fi
1001         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1002         GL_PC_CFLAGS="$X11_INCLUDES"
1003
1004         # XCB can only be used from pkg-config
1005         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1006         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1007         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1008         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1009     fi
1010
1011     # Check to see if the xcb-glx library is new enough to support
1012     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1013     # is released.
1014     save_CPPFLAGS="$CPPFLAGS"
1015     save_LDFLAGS="$LDFLAGS"
1016     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1017     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1018     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1019         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1020         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1021     CPPFLAGS="$save_CPPFLAGS"
1022     LDFLAGS="$save_LDFLAGS"
1023
1024     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1025         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1026     fi
1027
1028     # need DRM libs, -lpthread, etc.
1029     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1030     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1031     ;;
1032 esac
1033
1034 # This is outside the case (above) so that it is invoked even for non-GLX
1035 # builds.
1036 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1037     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1038 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1039
1040 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1041 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1042 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1043 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1044
1045 AC_SUBST([GL_LIB_DEPS])
1046 AC_SUBST([GL_PC_REQ_PRIV])
1047 AC_SUBST([GL_PC_LIB_PRIV])
1048 AC_SUBST([GL_PC_CFLAGS])
1049 AC_SUBST([DRI_PC_REQ_PRIV])
1050 AC_SUBST([GLESv1_CM_LIB_DEPS])
1051 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1052 AC_SUBST([GLESv2_LIB_DEPS])
1053 AC_SUBST([GLESv2_PC_LIB_PRIV])
1054
1055 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1056 AC_SUBST([GLAPI_LIB_DEPS])
1057
1058
1059 dnl Setup default DRI CFLAGS
1060 DRI_CFLAGS='$(CFLAGS)'
1061 DRI_CXXFLAGS='$(CXXFLAGS)'
1062 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1063 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1064
1065 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1066     DRICORE_GLSL_LIBS='$(TOP)/$(LIB_DIR)/libglsl.so'
1067     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1068     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -lglsl'
1069     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore -lglsl'
1070     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1071     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1072     MESA_MODULES='$(DRICORE_LIBS) $(DRICORE_GLSL_LIBS)'
1073 fi
1074 AC_SUBST([DRICORE_LIBS])
1075 AC_SUBST([DRICORE_GLSL_LIBS])
1076 AC_SUBST([DRICORE_LIB_DEPS])
1077 AC_SUBST([DRI_CXXFLAGS])
1078 AC_SUBST([DRI_CFLAGS])
1079 AC_SUBST([MESA_MODULES])
1080
1081 AC_SUBST([HAVE_XF86VIDMODE])
1082
1083 dnl
1084 dnl More GLX setup
1085 dnl
1086 case "x$enable_glx$enable_xlib_glx" in
1087 xyesyes)
1088     DEFINES="$DEFINES -DUSE_XSHM"
1089     ;;
1090 xyesno)
1091     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1092     if test "x$driglx_direct" = xyes; then
1093         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1094     fi
1095     ;;
1096 esac
1097
1098 dnl
1099 dnl TLS detection
1100 dnl
1101
1102 AC_ARG_ENABLE([glx-tls],
1103     [AS_HELP_STRING([--enable-glx-tls],
1104         [enable TLS support in GLX @<:@default=disabled@:>@])],
1105     [GLX_USE_TLS="$enableval"],
1106     [GLX_USE_TLS=no])
1107 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1108
1109 AS_IF([test "x$GLX_USE_TLS" = xyes],
1110       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1111
1112 dnl
1113 dnl More DRI setup
1114 dnl
1115 dnl Directory for DRI drivers
1116 AC_ARG_WITH([dri-driverdir],
1117     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1118         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1119     [DRI_DRIVER_INSTALL_DIR="$withval"],
1120     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1121 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1122 dnl Extra search path for DRI drivers
1123 AC_ARG_WITH([dri-searchpath],
1124     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1125         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1126     [DRI_DRIVER_SEARCH_DIR="$withval"],
1127     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1128 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1129 dnl Which drivers to build - default is chosen by platform
1130 AC_ARG_WITH([dri-drivers],
1131     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1132         [comma delimited DRI drivers list, e.g.
1133         "swrast,i965,radeon" @<:@default=auto@:>@])],
1134     [with_dri_drivers="$withval"],
1135     [with_dri_drivers=yes])
1136 if test "x$with_dri_drivers" = x; then
1137     with_dri_drivers=no
1138 fi
1139
1140 dnl If $with_dri_drivers is yes, directories will be added through
1141 dnl platform checks
1142 DRI_DIRS=""
1143 case "$with_dri_drivers" in
1144 no) ;;
1145 yes)
1146     # classic DRI drivers require FEATURE_GL to build
1147     if test "x$enable_opengl" = xyes; then
1148         DRI_DIRS="yes"
1149     fi
1150     ;;
1151 *)
1152     # verify the requested driver directories exist
1153     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1154     for driver in $dri_drivers; do
1155         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1156             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1157     done
1158     DRI_DIRS="$dri_drivers"
1159     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1160         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1161     fi
1162     ;;
1163 esac
1164
1165 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1166 if test "x$enable_dri" = xyes; then
1167     # Platform specific settings and drivers to build
1168     case "$host_os" in
1169     linux*)
1170         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1171         DEFINES="$DEFINES -DHAVE_ALIAS"
1172
1173         case "$host_cpu" in
1174         x86_64)
1175             if test "x$DRI_DIRS" = "xyes"; then
1176                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1177             fi
1178             ;;
1179         powerpc*)
1180             # Build only the drivers for cards that exist on PowerPC.
1181             if test "x$DRI_DIRS" = "xyes"; then
1182                 DRI_DIRS="r200 radeon swrast"
1183             fi
1184             ;;
1185         sparc*)
1186             # Build only the drivers for cards that exist on sparc
1187             if test "x$DRI_DIRS" = "xyes"; then
1188                 DRI_DIRS="r200 radeon swrast"
1189             fi
1190             ;;
1191         esac
1192         ;;
1193     freebsd* | dragonfly* | *netbsd*)
1194         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1195         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1196
1197         if test "x$DRI_DIRS" = "xyes"; then
1198             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1199         fi
1200         ;;
1201     gnu*)
1202         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1203         DEFINES="$DEFINES -DHAVE_ALIAS"
1204         ;;
1205     solaris*)
1206         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1207         ;;
1208     cygwin*)
1209         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1210         if test "x$DRI_DIRS" = "xyes"; then
1211             DRI_DIRS="swrast"
1212         fi
1213         ;;
1214     esac
1215
1216     # default drivers
1217     if test "x$DRI_DIRS" = "xyes"; then
1218         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1219     fi
1220
1221     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1222
1223     # Check for expat
1224     if test "x$enable_dri" = xyes; then
1225         EXPAT_INCLUDES=""
1226         EXPAT_LIB=-lexpat
1227         AC_ARG_WITH([expat],
1228             [AS_HELP_STRING([--with-expat=DIR],
1229                 [expat install directory])],[
1230             EXPAT_INCLUDES="-I$withval/include"
1231             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1232             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1233             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1234             ])
1235         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1236         save_LIBS="$LIBS"
1237         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1238             [AC_MSG_ERROR([Expat required for DRI.])])
1239         LIBS="$save_LIBS"
1240     fi
1241
1242     # if we are building any dri driver other than swrast ...
1243     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1244         # ... libdrm is required
1245         if test "x$have_libdrm" != xyes; then
1246             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1247         fi
1248         # ... and build dricommon
1249         HAVE_COMMON_DRI=yes
1250     fi
1251
1252     # put all the necessary libs together
1253     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1254 fi
1255 AC_SUBST([DRI_DIRS])
1256 AC_SUBST([EXPAT_INCLUDES])
1257 AC_SUBST([DRI_LIB_DEPS])
1258
1259 case $DRI_DIRS in
1260 *i915*|*i965*)
1261     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1262
1263     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1264         case $d in
1265         i915)
1266             HAVE_I915_DRI=yes;
1267             ;;
1268         i965)
1269             HAVE_I965_DRI=yes;
1270             ;;
1271         esac
1272     done
1273
1274     ;;
1275 esac
1276
1277 case $DRI_DIRS in
1278 *nouveau*)
1279     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1280     HAVE_NOUVEAU_DRI=yes;
1281     ;;
1282 esac
1283
1284 case $DRI_DIRS in
1285 *radeon*|*r200*)
1286     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1287
1288     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1289         case $d in
1290         radeon)
1291             HAVE_RADEON_DRI=yes;
1292             ;;
1293         r200)
1294             HAVE_R200_DRI=yes;
1295             ;;
1296         esac
1297     done
1298
1299     ;;
1300 esac
1301
1302 case $DRI_DIRS in
1303 *swrast*)
1304     HAVE_SWRAST_DRI=yes;
1305     ;;
1306 esac
1307
1308 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1309 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1310 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1311 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1312 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1313 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1314 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1315
1316 dnl
1317 dnl OSMesa configuration
1318 dnl
1319
1320 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1321 AC_ARG_WITH([osmesa-bits],
1322     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1323         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1324     [osmesa_bits="$withval"],
1325     [osmesa_bits=8])
1326 if test "x$osmesa_bits" != x8; then
1327     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1328         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1329         osmesa_bits=8
1330     fi
1331 fi
1332 case "x$osmesa_bits" in
1333 x8)
1334     OSMESA_LIB="${OSMESA_LIB}"
1335     ;;
1336 x16|x32)
1337     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1338     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1339     ;;
1340 *)
1341     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1342     ;;
1343 esac
1344
1345 if test "x$enable_osmesa" = xyes; then
1346     # only link libraries with osmesa if shared
1347     if test "$enable_static" = no; then
1348         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1349     else
1350         OSMESA_LIB_DEPS=""
1351     fi
1352     OSMESA_MESA_DEPS=""
1353     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1354 fi
1355 AC_SUBST([OSMESA_LIB_DEPS])
1356 AC_SUBST([OSMESA_MESA_DEPS])
1357 AC_SUBST([OSMESA_PC_REQ])
1358 AC_SUBST([OSMESA_PC_LIB_PRIV])
1359
1360 dnl
1361 dnl gbm configuration
1362 dnl
1363 if test "x$enable_gbm" = xauto; then
1364     case "$with_egl_platforms" in
1365         *drm*)
1366             enable_gbm=yes ;;
1367          *)
1368             enable_gbm=no ;;
1369     esac
1370 fi
1371 if test "x$enable_gbm" = xyes; then
1372     SRC_DIRS="$SRC_DIRS gbm"
1373
1374     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1375                       AC_MSG_ERROR([gbm needs udev]))
1376
1377     if test "x$enable_dri" = xyes; then
1378         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1379         if test "$SHARED_GLAPI" -eq 0; then
1380             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1381         fi
1382     fi
1383 fi
1384 GBM_PC_REQ_PRIV="libudev"
1385 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1386 AC_SUBST([GBM_PC_REQ_PRIV])
1387 AC_SUBST([GBM_PC_LIB_PRIV])
1388
1389 dnl
1390 dnl EGL configuration
1391 dnl
1392 EGL_CLIENT_APIS=""
1393
1394 if test "x$enable_egl" = xyes; then
1395     SRC_DIRS="$SRC_DIRS egl"
1396     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1397
1398     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1399
1400     if test "$enable_static" != yes; then
1401         # build egl_glx when libGL is built
1402         if test "x$enable_glx" = xyes; then
1403             HAVE_EGL_DRIVER_GLX=1
1404         fi
1405
1406         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1407                           [have_libudev=yes],[have_libudev=no])
1408         if test "$have_libudev" = yes; then
1409             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1410         fi
1411         if test "x$enable_dri" = xyes; then
1412             # build egl_dri2 when xcb-dri2 is available
1413             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1414                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1415             if test "$have_xcb_dri2" = yes; then
1416                 HAVE_EGL_DRIVER_DRI2=1
1417                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1418                 save_LIBS="$LIBS"
1419                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1420                           [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1421                 LIBS="$save_LIBS"
1422             fi
1423         fi
1424
1425     fi
1426 fi
1427 AC_SUBST([EGL_LIB_DEPS])
1428
1429 dnl
1430 dnl EGL Gallium configuration
1431 dnl
1432 if test "x$enable_gallium_egl" = xyes; then
1433     if test "x$with_gallium_drivers" = x; then
1434         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1435     fi
1436     if test "x$enable_egl" = xno; then
1437         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1438     fi
1439     if test "x$have_libdrm" != xyes; then
1440         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1441     fi
1442
1443     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1444     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1445     HAVE_ST_EGL="yes"
1446 fi
1447
1448 dnl
1449 dnl gbm Gallium configuration
1450 dnl
1451 if test "x$enable_gallium_gbm" = xauto; then
1452     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1453         yesyesyes*drm*)
1454             enable_gallium_gbm=yes ;;
1455          *)
1456             enable_gallium_gbm=no ;;
1457     esac
1458 fi
1459 if test "x$enable_gallium_gbm" = xyes; then
1460     if test "x$with_gallium_drivers" = x; then
1461         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1462     fi
1463     if test "x$enable_gbm" = xno; then
1464         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1465     fi
1466     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1467     if test "x$enable_dri" = xno; then
1468         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1469     fi
1470
1471     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1472     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1473     HAVE_ST_GBM="yes"
1474 fi
1475
1476 dnl
1477 dnl X.Org DDX configuration
1478 dnl
1479 if test "x$enable_xorg" = xyes; then
1480     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1481     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1482     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1483     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1484         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1485         HAVE_XEXTPROTO_71="no")
1486     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1487     HAVE_ST_XORG=yes
1488 fi
1489
1490 dnl
1491 dnl XA configuration
1492 dnl
1493 if test "x$enable_xa" = xyes; then
1494 AC_PROG_AWK
1495 AC_PROG_GREP
1496 AC_CHECK_PROG(NM, nm, "nm")
1497 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1498 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1499 enable_xa=no
1500 fi
1501 fi
1502 if test "x$enable_xa" = xyes; then
1503     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1504     HAVE_ST_XA=yes
1505     AC_SUBST(AWK)
1506     AC_SUBST(GREP)
1507     AC_SUBST(NM)
1508 fi
1509
1510 dnl
1511 dnl OpenVG configuration
1512 dnl
1513 VG_LIB_DEPS=""
1514
1515 if test "x$enable_openvg" = xyes; then
1516     if test "x$enable_egl" = xno; then
1517         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1518     fi
1519     if test "x$with_gallium_drivers" = x; then
1520         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1521     fi
1522     if test "x$enable_gallium_egl" = xno; then
1523         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1524     fi
1525
1526     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1527     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1528     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1529     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1530     HAVE_ST_VEGA=yes
1531 fi
1532
1533 dnl
1534 dnl D3D1X configuration
1535 dnl
1536
1537 if test "x$enable_d3d1x" = xyes; then
1538     if test "x$with_gallium_drivers" = x; then
1539         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1540     fi
1541
1542     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1543     HAVE_ST_D3D1X=yes
1544 fi
1545
1546 dnl
1547 dnl Gallium G3DVL configuration
1548 dnl
1549 AC_ARG_ENABLE([gallium-g3dvl],
1550     [AS_HELP_STRING([--enable-gallium-g3dvl],
1551         [build gallium g3dvl @<:@default=disabled@:>@])],
1552     [enable_gallium_g3dvl="$enableval"],
1553     [enable_gallium_g3dvl=no])
1554 if test "x$enable_gallium_g3dvl" = xyes; then
1555     if test "x$with_gallium_drivers" = x; then
1556         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1557     fi
1558
1559     if test "x$enable_xvmc" = xauto; then
1560         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1561     fi
1562
1563     if test "x$enable_vdpau" = xauto; then
1564         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1565     fi
1566
1567     if test "x$enable_va" = xauto; then
1568         #don't enable vaapi state tracker even if package exists
1569         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1570         enable_va=no
1571     fi
1572 fi
1573
1574 if test "x$enable_xvmc" = xyes; then
1575     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1576     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1577     HAVE_ST_XVMC="yes"
1578 fi
1579
1580 if test "x$enable_vdpau" = xyes; then
1581     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1582     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1583     HAVE_ST_VDPAU="yes"
1584 fi
1585
1586 if test "x$enable_va" = xyes; then
1587     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1588     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1589     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1590     HAVE_ST_VA="yes"
1591 fi
1592
1593 dnl
1594 dnl GLU configuration
1595 dnl
1596 AC_ARG_ENABLE([glu],
1597     [AS_HELP_STRING([--disable-glu],
1598         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1599     [enable_glu="$enableval"],
1600     [enable_glu=yes])
1601
1602 if test "x$enable_glu" = xyes; then
1603     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1604         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1605         enable_glu=no
1606     fi
1607 fi
1608
1609 if test "x$enable_glu" = xyes; then
1610     SRC_DIRS="$SRC_DIRS glu"
1611
1612     if test "x$enable_glx" = xno; then
1613         # Link libGLU to libOSMesa instead of libGL
1614         GLU_LIB_DEPS=""
1615         GLU_PC_REQ="osmesa"
1616         if test "$enable_static" = no; then
1617             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1618         else
1619             GLU_MESA_DEPS=""
1620         fi
1621     else
1622         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1623         GLU_PC_REQ="gl"
1624         GLU_PC_LIB_PRIV="-lm"
1625         if test "$enable_static" = no; then
1626             GLU_LIB_DEPS="-lm"
1627             GLU_MESA_DEPS='-l$(GL_LIB)'
1628         else
1629             GLU_LIB_DEPS=""
1630             GLU_MESA_DEPS=""
1631         fi
1632     fi
1633 fi
1634 if test "$enable_static" = no; then
1635     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1636 fi
1637 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1638 AC_SUBST([GLU_LIB_DEPS])
1639 AC_SUBST([GLU_MESA_DEPS])
1640 AC_SUBST([GLU_PC_REQ])
1641 AC_SUBST([GLU_PC_REQ_PRIV])
1642 AC_SUBST([GLU_PC_LIB_PRIV])
1643 AC_SUBST([GLU_PC_CFLAGS])
1644
1645 AC_SUBST([PROGRAM_DIRS])
1646
1647 dnl
1648 dnl Gallium configuration
1649 dnl
1650 if test "x$with_gallium_drivers" != x; then
1651     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1652 fi
1653
1654 AC_SUBST([LLVM_BINDIR])
1655 AC_SUBST([LLVM_CFLAGS])
1656 AC_SUBST([LLVM_CXXFLAGS])
1657 AC_SUBST([LLVM_LIBS])
1658 AC_SUBST([LLVM_LDFLAGS])
1659 AC_SUBST([LLVM_INCLUDEDIR])
1660 AC_SUBST([LLVM_VERSION])
1661
1662 case "x$enable_opengl$enable_gles1$enable_gles2" in
1663 x*yes*)
1664     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1665     ;;
1666 esac
1667
1668 AC_SUBST([VG_LIB_DEPS])
1669 AC_SUBST([EGL_CLIENT_APIS])
1670
1671 AC_ARG_WITH([egl-platforms],
1672     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1673         [comma delimited native platforms libEGL supports, e.g.
1674         "x11,drm" @<:@default=auto@:>@])],
1675     [with_egl_platforms="$withval"],
1676     [if test "x$enable_egl" = xyes; then
1677         with_egl_platforms="x11"
1678     else
1679         with_egl_platforms=""
1680     fi])
1681
1682 EGL_PLATFORMS=""
1683
1684 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1685     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1686 fi
1687
1688 # verify the requested driver directories exist
1689 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1690 for plat in $egl_platforms; do
1691         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1692             AC_MSG_ERROR([EGL platform '$plat' does not exist])
1693         if test "$plat" = "fbdev"; then
1694                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1695         fi
1696         if test "$plat" = "null"; then
1697                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1698         fi
1699         if test "$plat" = "wayland"; then
1700                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1701                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1702                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1703
1704                 m4_ifdef([WAYLAND_SCANNER_RULES],
1705                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1706         fi
1707         if test "$plat" = "drm" && test "x$enable_gbm" = "xno"; then
1708                 AC_MSG_ERROR([EGL platform drm needs gbm])
1709         fi
1710         case "$plat$have_libudev" in
1711                 waylandno|drmno)
1712                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1713         esac
1714 done
1715
1716 # libEGL wants to default to the first platform specified in
1717 # ./configure.  parse that here.
1718 if test "x$egl_platforms" != "x"; then
1719     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1720     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1721 else
1722     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1723 fi
1724
1725 EGL_PLATFORMS="$egl_platforms"
1726
1727 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1728 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1729 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1730 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1731 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1732
1733 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1734 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1735
1736 AC_SUBST([EGL_NATIVE_PLATFORM])
1737 AC_SUBST([EGL_PLATFORMS])
1738 AC_SUBST([EGL_CFLAGS])
1739
1740 AC_ARG_WITH([egl-driver-dir],
1741     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1742                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1743     [EGL_DRIVER_INSTALL_DIR="$withval"],
1744     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1745 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1746
1747 AC_ARG_WITH([xorg-driver-dir],
1748     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1749                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1750     [XORG_DRIVER_INSTALL_DIR="$withval"],
1751     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1752 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1753
1754 AC_ARG_WITH([max-width],
1755     [AS_HELP_STRING([--with-max-width=N],
1756                     [Maximum framebuffer width (4096)])],
1757     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1758      AS_IF([test "${withval}" -gt "4096"],
1759            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1760 )
1761 AC_ARG_WITH([max-height],
1762     [AS_HELP_STRING([--with-max-height=N],
1763                     [Maximum framebuffer height (4096)])],
1764     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1765      AS_IF([test "${withval}" -gt "4096"],
1766            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1767 )
1768
1769 dnl
1770 dnl Gallium LLVM
1771 dnl
1772 AC_ARG_ENABLE([gallium-llvm],
1773     [AS_HELP_STRING([--enable-gallium-llvm],
1774         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1775     [enable_gallium_llvm="$enableval"],
1776     [enable_gallium_llvm=auto])
1777
1778 AC_ARG_WITH([llvm-shared-libs],
1779     [AS_HELP_STRING([--with-llvm-shared-libs],
1780         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1781     [with_llvm_shared_libs=yes],
1782     [with_llvm_shared_libs=no])
1783
1784 if test "x$with_gallium_drivers" = x; then
1785     enable_gallium_llvm=no
1786 fi
1787 if test "x$enable_gallium_llvm" = xauto; then
1788     case "$host_cpu" in
1789     i*86|x86_64) enable_gallium_llvm=yes;;
1790     esac
1791 fi
1792 if test "x$enable_gallium_llvm" = xyes; then
1793     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1794
1795     if test "x$LLVM_CONFIG" != xno; then
1796         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1797         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g'`
1798         if test "x$with_llvm_shared_libs" = xyes; then
1799             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1800             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1801         else
1802             LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1803         fi
1804         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1805         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1806         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1807         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1808         DEFINES="$DEFINES -D__STDC_CONSTANT_MACROS"
1809         MESA_LLVM=1
1810     else
1811         MESA_LLVM=0
1812     fi
1813 else
1814     MESA_LLVM=0
1815 fi
1816
1817 dnl Directory for XVMC libs
1818 AC_ARG_WITH([xvmc-libdir],
1819     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1820         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1821     [XVMC_LIB_INSTALL_DIR="$withval"],
1822     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1823 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1824
1825 dnl Directory for VDPAU libs
1826 AC_ARG_WITH([vdpau-libdir],
1827     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1828         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1829     [VDPAU_LIB_INSTALL_DIR="$withval"],
1830     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1831 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1832
1833 dnl Directory for VA libs
1834 AC_ARG_WITH([va-libdir],
1835     [AS_HELP_STRING([--with-va-libdir=DIR],
1836         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1837     [VA_LIB_INSTALL_DIR="$withval"],
1838     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1839 AC_SUBST([VA_LIB_INSTALL_DIR])
1840
1841 dnl
1842 dnl Gallium helper functions
1843 dnl
1844 gallium_check_st() {
1845     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1846          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1847          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1848          if test "x$have_libdrm" != xyes; then
1849             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1850          fi
1851          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1852     fi
1853     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1854          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1855     fi
1856     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1857          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1858     fi
1859     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1860          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1861     fi
1862     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1863          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1864     fi
1865     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1866          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1867     fi
1868     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1869          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1870     fi
1871 }
1872
1873 gallium_require_llvm() {
1874     if test "x$MESA_LLVM" = x0; then
1875         case "$host_cpu" in
1876         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1877         esac
1878     fi
1879 }
1880
1881 dnl Gallium drivers
1882 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1883 if test "x$with_gallium_drivers" != x; then
1884     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1885     for driver in $gallium_drivers; do
1886         case "x$driver" in
1887         xsvga)
1888             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1889             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1890             ;;
1891         xi915)
1892             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1893             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1894             if test "x$MESA_LLVM" = x1; then
1895                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1896             fi
1897             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1898             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1899             ;;
1900         xr300)
1901             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1902             gallium_require_llvm "Gallium R300"
1903             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1904             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1905             ;;
1906         xr600)
1907             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1908             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1909             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1910             ;;
1911         xradeonsi)
1912             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1913             if test "x$LLVM_VERSION" != "x3.1"; then
1914                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1915             fi
1916             NEED_RADEON_GALLIUM=yes;
1917             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
1918             ;;
1919         xnouveau)
1920             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1921             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1922             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1923             ;;
1924         xswrast)
1925             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1926             if test "x$MESA_LLVM" = x1; then
1927                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1928             fi
1929
1930             if test "x$HAVE_ST_DRI" = xyes; then
1931                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1932             fi
1933             if test "x$HAVE_ST_VDPAU" = xyes; then
1934                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1935             fi
1936             if test "x$HAVE_ST_XVMC" = xyes; then
1937                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1938             fi
1939             if test "x$HAVE_ST_VA" = xyes; then
1940                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1941             fi
1942             if test "x$HAVE_ST_VDPAU" = xyes ||
1943                test "x$HAVE_ST_XVMC" = xyes ||
1944                test "x$HAVE_ST_VA" = xyes; then
1945                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1946                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1947                fi
1948             fi
1949             ;;
1950         *)
1951             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1952             ;;
1953         esac
1954     done
1955 fi
1956
1957 dnl Tell Automake which drivers to build
1958 for driver in $GALLIUM_DRIVERS_DIRS; do
1959     case "x$driver" in
1960         xgalahad)
1961             HAVE_GALAHAD_GALLIUM=yes;
1962             ;;
1963         xidentity)
1964             HAVE_IDENTITY_GALLIUM=yes;
1965             ;;
1966         xnoop)
1967             HAVE_NOOP_GALLIUM=yes;
1968             ;;
1969         *)
1970             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1971             ;;
1972     esac
1973 done
1974
1975 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1976 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1977 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1978 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1979 AC_SUBST([GALLIUM_MAKE_DIRS])
1980
1981 dnl prepend CORE_DIRS to SRC_DIRS
1982 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1983
1984 dnl Restore LDFLAGS and CPPFLAGS
1985 LDFLAGS="$_SAVE_LDFLAGS"
1986 CPPFLAGS="$_SAVE_CPPFLAGS"
1987
1988 dnl Add user CFLAGS and CXXFLAGS
1989 CFLAGS="$CFLAGS $USER_CFLAGS"
1990 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1991
1992 dnl Substitute the config
1993 AC_CONFIG_FILES([configs/autoconf
1994                 src/gallium/drivers/Makefile
1995                 src/gallium/drivers/r300/Makefile
1996                 src/gbm/Makefile
1997                 src/gbm/main/gbm.pc
1998                 src/egl/drivers/Makefile
1999                 src/egl/drivers/dri2/Makefile
2000                 src/egl/drivers/glx/Makefile
2001                 src/egl/main/Makefile
2002                 src/egl/main/egl.pc
2003                 src/egl/wayland/Makefile
2004                 src/egl/wayland/wayland-egl/Makefile
2005                 src/egl/wayland/wayland-egl/wayland-egl.pc
2006                 src/egl/wayland/wayland-drm/Makefile
2007                 src/glx/Makefile
2008                 src/mapi/shared-glapi/Makefile
2009                 src/gtest/Makefile
2010                 src/mesa/drivers/dri/dri.pc
2011                 src/mesa/drivers/dri/Makefile
2012                 src/mesa/drivers/dri/common/Makefile
2013                 src/mesa/drivers/dri/i915/Makefile
2014                 src/mesa/drivers/dri/i965/Makefile
2015                 src/mesa/drivers/dri/nouveau/Makefile
2016                 src/mesa/drivers/dri/r200/Makefile
2017                 src/mesa/drivers/dri/radeon/Makefile
2018                 src/mesa/drivers/dri/swrast/Makefile
2019                 tests/Makefile
2020                 tests/glx/Makefile])
2021
2022 dnl Replace the configs/current symlink
2023 AC_CONFIG_COMMANDS([configs],[
2024 if test -f configs/current || test -L configs/current; then
2025     rm -f configs/current
2026 fi
2027 ln -s autoconf configs/current
2028 ])
2029
2030 dnl Sort the dirs alphabetically
2031 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2032 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2033 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2034 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2035 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2036
2037 AC_OUTPUT
2038
2039 dnl
2040 dnl Output some configuration info for the user
2041 dnl
2042 echo ""
2043 echo "        prefix:          $prefix"
2044 echo "        exec_prefix:     $exec_prefix"
2045 echo "        libdir:          $libdir"
2046 echo "        includedir:      $includedir"
2047
2048 dnl API info
2049 echo ""
2050 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2051 echo "        OpenVG:          $enable_openvg"
2052
2053 dnl Driver info
2054 echo ""
2055 if test "x$enable_osmesa" != xno; then
2056         echo "        OSMesa:          lib$OSMESA_LIB"
2057 else
2058         echo "        OSMesa:          no"
2059 fi
2060
2061 if test "x$enable_dri" != xno; then
2062         # cleanup the drivers var
2063         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2064         if test "x$DRI_DIRS" = x; then
2065             echo "        DRI drivers:     no"
2066         else
2067             echo "        DRI drivers:     $dri_dirs"
2068         fi
2069         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2070 fi
2071
2072 case "x$enable_glx$enable_xlib_glx" in
2073 xyesyes)
2074     echo "        GLX:             Xlib-based"
2075     ;;
2076 xyesno)
2077     echo "        GLX:             DRI-based"
2078     ;;
2079 *)
2080     echo "        GLX:             $enable_glx"
2081     ;;
2082 esac
2083
2084 echo ""
2085 echo "        GLU:             $enable_glu"
2086
2087 dnl EGL
2088 echo ""
2089 echo "        EGL:             $enable_egl"
2090 if test "$enable_egl" = yes; then
2091     echo "        EGL platforms:   $EGL_PLATFORMS"
2092
2093     egl_drivers=""
2094     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2095         egl_drivers="$egl_drivers builtin:egl_glx"
2096     fi
2097     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2098         egl_drivers="$egl_drivers builtin:egl_dri2"
2099     fi
2100
2101     if test "x$HAVE_ST_EGL" = xyes; then
2102         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2103         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2104     else
2105         echo "        EGL drivers:    $egl_drivers"
2106     fi
2107 fi
2108
2109 echo ""
2110 if test "x$MESA_LLVM" = x1; then
2111     echo "        llvm:            yes"
2112     echo "        llvm-config:     $LLVM_CONFIG"
2113     echo "        llvm-version:    $LLVM_VERSION"
2114 else
2115     echo "        llvm:            no"
2116 fi
2117
2118 echo ""
2119 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2120     echo "        Gallium:         yes"
2121     echo "        Gallium dirs:    $GALLIUM_DIRS"
2122     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2123     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2124     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2125     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2126 else
2127     echo "        Gallium:         no"
2128 fi
2129
2130
2131 dnl Libraries
2132 echo ""
2133 echo "        Shared libs:     $enable_shared"
2134 echo "        Static libs:     $enable_static"
2135
2136 dnl Compiler options
2137 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2138 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2139     $SED 's/^ *//;s/  */ /;s/ *$//'`
2140 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2141     $SED 's/^ *//;s/  */ /;s/ *$//'`
2142 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2143 echo ""
2144 echo "        CFLAGS:          $cflags"
2145 echo "        CXXFLAGS:        $cxxflags"
2146 echo "        Macros:          $defines"
2147 echo ""
2148 echo "        PYTHON2:         $PYTHON2"
2149
2150 echo ""
2151 echo "        Run '${MAKE-make}' to build Mesa"
2152 echo ""