configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 dnl http://people.gnome.org/~walters/docs/build-api.txt
  18 dnl We don't support srcdir != builddir.
  19 echo \#buildapi-variable-no-builddir >/dev/null
  20
  21 # Support silent build rules, requires at least automake-1.11. Disable
  22 # by either passing --disable-silent-rules to configure or passing V=1
  23 # to make
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  25     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  26
  27 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  28
  29 dnl Set internal versions
  30 OSMESA_VERSION=8
  31 AC_SUBST([OSMESA_VERSION])
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.46
  36 LIBDRM_INTEL_REQUIRED=2.4.38
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  39 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AX_PYTHON_MODULE([libxml2], [needed])
  54 AC_PROG_SED
  55 AC_PROG_MKDIR_P
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([disable-static])
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 GEN_ASM_OFFSETS=no
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120
 121     if test "x$cross_compiling" = xyes; then
 122         GEN_ASM_OFFSETS=yes
 123     fi
 124 fi
 125 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 126
 127 dnl Make sure the pkg-config macros are defined
 128 m4_ifndef([PKG_PROG_PKG_CONFIG],
 129     [m4_fatal([Could not locate the pkg-config autoconf macros.
 130   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 131   are in a different location, try setting the environment variable
 132   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 133 PKG_PROG_PKG_CONFIG()
 134
 135 dnl LIB_DIR - library basename
 136 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 137 AC_SUBST([LIB_DIR])
 138
 139 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 140 _SAVE_LDFLAGS="$LDFLAGS"
 141 _SAVE_CPPFLAGS="$CPPFLAGS"
 142
 143 dnl Compiler macros
 144 DEFINES=""
 145 AC_SUBST([DEFINES])
 146 case "$host_os" in
 147 linux*|*-gnu*|gnu*)
 148     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 149     ;;
 150 solaris*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 152     ;;
 153 cygwin*)
 154     DEFINES="$DEFINES -DHAVE_PTHREAD"
 155     ;;
 156 esac
 157
 158 dnl Add flags for gcc and g++
 159 if test "x$GCC" = xyes; then
 160     case "$host_os" in
 161     cygwin*)
 162         CFLAGS="$CFLAGS -Wall -std=gnu99"
 163         ;;
 164     *)
 165         CFLAGS="$CFLAGS -Wall -std=c99"
 166         ;;
 167     esac
 168
 169     # Enable -Werror=implicit-function-declaration and
 170     # -Werror=missing-prototypes, if available, or otherwise, just
 171     # -Wmissing-prototypes.  This is particularly useful to avoid
 172     # generating a loadable driver module that has undefined symbols.
 173     save_CFLAGS="$CFLAGS"
 174     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 175     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 176     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 177     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 178                    AC_MSG_RESULT([yes]),
 179                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 180                     AC_MSG_RESULT([no])]);
 181
 182     # Enable -fvisibility=hidden if using a gcc that supports it
 183     save_CFLAGS="$CFLAGS"
 184     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 185     VISIBILITY_CFLAGS="-fvisibility=hidden"
 186     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 188                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 189
 190     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 191     CFLAGS=$save_CFLAGS
 192
 193     # Work around aliasing bugs - developers should comment this out
 194     CFLAGS="$CFLAGS -fno-strict-aliasing"
 195
 196     # gcc's builtin memcmp is slower than glibc's
 197     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 198     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 199 fi
 200 if test "x$GXX" = xyes; then
 201     CXXFLAGS="$CXXFLAGS -Wall"
 202
 203     # Enable -fvisibility=hidden if using a gcc that supports it
 204     save_CXXFLAGS="$CXXFLAGS"
 205     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 206     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 207     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 208     AC_LANG_PUSH([C++])
 209     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 210                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 211     AC_LANG_POP([C++])
 212
 213     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 214     CXXFLAGS=$save_CXXFLAGS
 215
 216     # Work around aliasing bugs - developers should comment this out
 217     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 218
 219     # gcc's builtin memcmp is slower than glibc's
 220     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 221     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 222 fi
 223
 224 dnl even if the compiler appears to support it, using visibility attributes isn't
 225 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 226 case "$host_os" in
 227 cygwin*)
 228     VISIBILITY_CFLAGS=""
 229     VISIBILITY_CXXFLAGS=""
 230     ;;
 231 esac
 232
 233 AC_SUBST([VISIBILITY_CFLAGS])
 234 AC_SUBST([VISIBILITY_CXXFLAGS])
 235
 236 dnl
 237 dnl Hacks to enable 32 or 64 bit build
 238 dnl
 239 AC_ARG_ENABLE([32-bit],
 240     [AS_HELP_STRING([--enable-32-bit],
 241         [build 32-bit libraries @<:@default=auto@:>@])],
 242     [enable_32bit="$enableval"],
 243     [enable_32bit=auto]
 244 )
 245 if test "x$enable_32bit" = xyes; then
 246     if test "x$GCC" = xyes; then
 247         CFLAGS="$CFLAGS -m32"
 248         CCASFLAGS="$CCASFLAGS -m32"
 249     fi
 250     if test "x$GXX" = xyes; then
 251         CXXFLAGS="$CXXFLAGS -m32"
 252     fi
 253 fi
 254 AC_ARG_ENABLE([64-bit],
 255     [AS_HELP_STRING([--enable-64-bit],
 256         [build 64-bit libraries @<:@default=auto@:>@])],
 257     [enable_64bit="$enableval"],
 258     [enable_64bit=auto]
 259 )
 260 if test "x$enable_64bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m64"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m64"
 266     fi
 267 fi
 268
 269 dnl Can't have static and shared libraries, default to static if user
 270 dnl explicitly requested. If both disabled, set to static since shared
 271 dnl was explicitly requested.
 272 case "x$enable_static$enable_shared" in
 273 xyesyes )
 274     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 275     enable_shared=no
 276     ;;
 277 xnono )
 278     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 279     enable_static=yes
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 284
 285 dnl
 286 dnl other compiler options
 287 dnl
 288 AC_ARG_ENABLE([debug],
 289     [AS_HELP_STRING([--enable-debug],
 290         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 291     [enable_debug="$enableval"],
 292     [enable_debug=no]
 293 )
 294 if test "x$enable_debug" = xyes; then
 295     DEFINES="$DEFINES -DDEBUG"
 296     if test "x$GCC" = xyes; then
 297         CFLAGS="$CFLAGS -g -O0"
 298     fi
 299     if test "x$GXX" = xyes; then
 300         CXXFLAGS="$CXXFLAGS -g -O0"
 301     fi
 302 fi
 303
 304 dnl
 305 dnl library names
 306 dnl
 307 LIB_PREFIX_GLOB='lib'
 308 LIB_VERSION_SEPARATOR='.'
 309 if test "$enable_static" = yes; then
 310     LIB_EXTENSION='a'
 311 else
 312     case "$host_os" in
 313     darwin* )
 314         LIB_EXTENSION='dylib' ;;
 315     cygwin* )
 316         dnl prefix can be 'cyg' or 'lib'
 317         LIB_PREFIX_GLOB='???'
 318         LIB_VERSION_SEPARATOR='-'
 319         LIB_EXTENSION='dll' ;;
 320     aix* )
 321         LIB_EXTENSION='a' ;;
 322     * )
 323         LIB_EXTENSION='so' ;;
 324     esac
 325 fi
 326 AC_ARG_WITH([gl-lib-name],
 327   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 328     [specify GL library name @<:@default=GL@:>@])],
 329   [GL_LIB=$withval],
 330   [GL_LIB=GL])
 331 AC_ARG_WITH([osmesa-lib-name],
 332   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 333     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 334   [OSMESA_LIB=$withval],
 335   [OSMESA_LIB=OSMesa])
 336 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 337 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 338
 339 dnl
 340 dnl Mangled Mesa support
 341 dnl
 342 AC_ARG_ENABLE([mangling],
 343   [AS_HELP_STRING([--enable-mangling],
 344     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 345   [enable_mangling="${enableval}"],
 346   [enable_mangling=no]
 347 )
 348 if test "x${enable_mangling}" = "xyes" ; then
 349   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 350   GL_LIB="Mangled${GL_LIB}"
 351   OSMESA_LIB="Mangled${OSMESA_LIB}"
 352 fi
 353 AC_SUBST([GL_LIB])
 354 AC_SUBST([OSMESA_LIB])
 355
 356 dnl
 357 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 358 dnl
 359 AC_ARG_ENABLE([texture-float],
 360     [AS_HELP_STRING([--enable-texture-float],
 361         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 362     [enable_texture_float="$enableval"],
 363     [enable_texture_float=no]
 364 )
 365 if test "x$enable_texture_float" = xyes; then
 366     AC_MSG_WARN([Floating-point textures enabled.])
 367     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 368     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 369 fi
 370
 371 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 372 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 373 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 374 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 375 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 376 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 377 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 378
 379 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 380 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 381 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 382 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386
 387 AC_SUBST([GL_LIB_NAME])
 388 AC_SUBST([OSMESA_LIB_NAME])
 389 AC_SUBST([EGL_LIB_NAME])
 390 AC_SUBST([GLESv1_CM_LIB_NAME])
 391 AC_SUBST([GLESv2_LIB_NAME])
 392 AC_SUBST([VG_LIB_NAME])
 393 AC_SUBST([GLAPI_LIB_NAME])
 394
 395 AC_SUBST([GL_LIB_GLOB])
 396 AC_SUBST([EGL_LIB_GLOB])
 397 AC_SUBST([GLESv1_CM_LIB_GLOB])
 398 AC_SUBST([GLESv2_LIB_GLOB])
 399 AC_SUBST([VG_LIB_GLOB])
 400 AC_SUBST([GLAPI_LIB_GLOB])
 401
 402 dnl
 403 dnl Arch/platform-specific settings
 404 dnl
 405 AC_ARG_ENABLE([asm],
 406     [AS_HELP_STRING([--disable-asm],
 407         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 408     [enable_asm="$enableval"],
 409     [enable_asm=yes]
 410 )
 411 asm_arch=""
 412 AC_MSG_CHECKING([whether to enable assembly])
 413 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 414 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 415 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 416     case "$host_cpu" in
 417     i?86 | x86_64 | amd64)
 418         enable_asm=no
 419         AC_MSG_RESULT([no, cross compiling])
 420         ;;
 421     esac
 422 fi
 423 # check for supported arches
 424 if test "x$enable_asm" = xyes; then
 425     case "$host_cpu" in
 426     i?86)
 427         case "$host_os" in
 428         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 429             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 430             ;;
 431         gnu*)
 432             asm_arch=x86
 433             ;;
 434         esac
 435         ;;
 436     x86_64|amd64)
 437         case "$host_os" in
 438         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 439             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 440             ;;
 441         esac
 442         ;;
 443     sparc*)
 444         case "$host_os" in
 445         linux*)
 446             asm_arch=sparc
 447             ;;
 448         esac
 449         ;;
 450     esac
 451
 452     case "$asm_arch" in
 453     x86)
 454         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 455         AC_MSG_RESULT([yes, x86])
 456         ;;
 457     x86_64|amd64)
 458         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 459         AC_MSG_RESULT([yes, x86_64])
 460         ;;
 461     sparc)
 462         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 463         AC_MSG_RESULT([yes, sparc])
 464         ;;
 465     *)
 466         AC_MSG_RESULT([no, platform not supported])
 467         ;;
 468     esac
 469 fi
 470
 471 dnl Check to see if dlopen is in default libraries (like Solaris, which
 472 dnl has it in libc), or if libdl is needed to get it.
 473 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 474     [AC_CHECK_LIB([dl], [dlopen],
 475        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 476 AC_SUBST([DLOPEN_LIBS])
 477
 478 case "$host_os" in
 479 darwin*|mingw*)
 480     ;;
 481 *)
 482     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 483                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 484                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 485     AC_SUBST([CLOCK_LIB])
 486     ;;
 487 esac
 488
 489 dnl See if posix_memalign is available
 490 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 491
 492 dnl Check for pthreads
 493 AX_PTHREAD
 494 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 495 dnl to -pthread, which causes problems if we need -lpthread to appear in
 496 dnl pkgconfig files.
 497 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 498
 499 dnl SELinux awareness.
 500 AC_ARG_ENABLE([selinux],
 501     [AS_HELP_STRING([--enable-selinux],
 502         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 503     [MESA_SELINUX="$enableval"],
 504     [MESA_SELINUX=no])
 505 if test "x$enable_selinux" = "xyes"; then
 506     AC_CHECK_HEADER([selinux/selinux.h],[],
 507                     [AC_MSG_ERROR([SELinux headers not found])])
 508     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 509                  [AC_MSG_ERROR([SELinux library not found])])
 510     SELINUX_LIBS="-lselinux"
 511     DEFINES="$DEFINES -DMESA_SELINUX"
 512 fi
 513 AC_SUBST([SELINUX_LIBS])
 514
 515 dnl Options for APIs
 516 AC_ARG_ENABLE([opengl],
 517     [AS_HELP_STRING([--disable-opengl],
 518         [disable support for standard OpenGL API @<:@default=no@:>@])],
 519     [enable_opengl="$enableval"],
 520     [enable_opengl=yes])
 521 AC_ARG_ENABLE([gles1],
 522     [AS_HELP_STRING([--enable-gles1],
 523         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 524     [enable_gles1="$enableval"],
 525     [enable_gles1=no])
 526 AC_ARG_ENABLE([gles2],
 527     [AS_HELP_STRING([--enable-gles2],
 528         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 529     [enable_gles2="$enableval"],
 530     [enable_gles2=no])
 531 AC_ARG_ENABLE([openvg],
 532     [AS_HELP_STRING([--enable-openvg],
 533         [enable support for OpenVG API @<:@default=no@:>@])],
 534     [enable_openvg="$enableval"],
 535     [enable_openvg=no])
 536
 537 AC_ARG_ENABLE([dri],
 538     [AS_HELP_STRING([--enable-dri],
 539         [enable DRI modules @<:@default=enabled@:>@])],
 540     [enable_dri="$enableval"],
 541     [enable_dri=yes])
 542 AC_ARG_ENABLE([glx],
 543     [AS_HELP_STRING([--enable-glx],
 544         [enable GLX library @<:@default=enabled@:>@])],
 545     [enable_glx="$enableval"],
 546     [enable_glx=yes])
 547 AC_ARG_ENABLE([osmesa],
 548     [AS_HELP_STRING([--enable-osmesa],
 549         [enable OSMesa library @<:@default=disabled@:>@])],
 550     [enable_osmesa="$enableval"],
 551     [enable_osmesa=no])
 552 AC_ARG_ENABLE([gallium-osmesa],
 553     [AS_HELP_STRING([--enable-gallium-osmesa],
 554         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 555     [enable_gallium_osmesa="$enableval"],
 556     [enable_gallium_osmesa=no])
 557 AC_ARG_ENABLE([egl],
 558     [AS_HELP_STRING([--disable-egl],
 559         [disable EGL library @<:@default=enabled@:>@])],
 560     [enable_egl="$enableval"],
 561     [enable_egl=yes])
 562
 563 AC_ARG_ENABLE([xorg],
 564     [AS_HELP_STRING([--enable-xorg],
 565         [enable support for X.Org DDX API @<:@default=no@:>@])],
 566     [enable_xorg="$enableval"],
 567     [enable_xorg=no])
 568 AC_ARG_ENABLE([xa],
 569     [AS_HELP_STRING([--enable-xa],
 570         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 571     [enable_xa="$enableval"],
 572     [enable_xa=no])
 573 AC_ARG_ENABLE([gbm],
 574    [AS_HELP_STRING([--enable-gbm],
 575          [enable gbm library @<:@default=auto@:>@])],
 576    [enable_gbm="$enableval"],
 577    [enable_gbm=auto])
 578
 579 AC_ARG_ENABLE([xvmc],
 580    [AS_HELP_STRING([--enable-xvmc],
 581          [enable xvmc library @<:@default=auto@:>@])],
 582    [enable_xvmc="$enableval"],
 583    [enable_xvmc=auto])
 584 AC_ARG_ENABLE([vdpau],
 585    [AS_HELP_STRING([--enable-vdpau],
 586          [enable vdpau library @<:@default=auto@:>@])],
 587    [enable_vdpau="$enableval"],
 588    [enable_vdpau=auto])
 589 AC_ARG_ENABLE([opencl],
 590    [AS_HELP_STRING([--enable-opencl],
 591          [enable OpenCL library NOTE: Enabling this option will also enable
 592           --with-llvm-shared-libs
 593           @<:@default=no@:>@])],
 594    [],
 595    [enable_opencl=no])
 596 AC_ARG_ENABLE([opencl_icd],
 597    [AS_HELP_STRING([--enable-opencl-icd],
 598           [Build an OpenCL ICD library to be loaded by an ICD implementation
 599            @<:@default=no@:>@])],
 600     [enable_opencl_icd="$enableval"],
 601     [enable_opencl_icd=no])
 602 AC_ARG_ENABLE([xlib-glx],
 603     [AS_HELP_STRING([--enable-xlib-glx],
 604         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 605     [enable_xlib_glx="$enableval"],
 606     [enable_xlib_glx=no])
 607 AC_ARG_ENABLE([gallium-egl],
 608     [AS_HELP_STRING([--enable-gallium-egl],
 609         [enable optional EGL state tracker (not required
 610          for EGL support in Gallium with OpenGL and OpenGL ES)
 611          @<:@default=disable@:>@])],
 612     [enable_gallium_egl="$enableval"],
 613     [enable_gallium_egl=no])
 614 AC_ARG_ENABLE([gallium-gbm],
 615     [AS_HELP_STRING([--enable-gallium-gbm],
 616         [enable optional gbm state tracker (not required for
 617          gbm support in Gallium)
 618          @<:@default=auto@:>@])],
 619     [enable_gallium_gbm="$enableval"],
 620     [enable_gallium_gbm=auto])
 621
 622 AC_ARG_ENABLE([r600-llvm-compiler],
 623     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 624         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 625     [enable_r600_llvm="$enableval"],
 626     [enable_r600_llvm=no])
 627
 628 AC_ARG_ENABLE([gallium-tests],
 629     [AS_HELP_STRING([--enable-gallium-tests],
 630         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 631     [enable_gallium_tests="$enableval"],
 632     [enable_gallium_tests=no])
 633
 634 # Option for Gallium drivers
 635
 636 # Keep this in sync with the --with-gallium-drivers help string default value
 637 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 638
 639 AC_ARG_WITH([gallium-drivers],
 640     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 641         [comma delimited Gallium drivers list, e.g.
 642         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 643         @<:@default=r300,r600,svga,swrast@:>@])],
 644     [with_gallium_drivers="$withval"],
 645     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 646
 647 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 648 # here so that the script doesn't choke on an unknown driver name later.
 649 case "$with_gallium_drivers" in
 650     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 651     no) with_gallium_drivers='' ;;
 652 esac
 653
 654 if test "x$enable_opengl" = xno -a \
 655         "x$enable_gles1" = xno -a \
 656         "x$enable_gles2" = xno -a \
 657         "x$enable_openvg" = xno -a \
 658         "x$enable_xorg" = xno -a \
 659         "x$enable_xa" = xno -a \
 660         "x$enable_xvmc" = xno -a \
 661         "x$enable_vdpau" = xno -a \
 662         "x$enable_opencl" = xno; then
 663     AC_MSG_ERROR([at least one API should be enabled])
 664 fi
 665
 666 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 667 if test "x$enable_opengl" = xno -a \
 668         "x$enable_gles1" = xyes; then
 669     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 670 fi
 671
 672 if test "x$enable_opengl" = xno -a \
 673         "x$enable_gles2" = xyes; then
 674     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 675 fi
 676
 677 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 678 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 679 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 680 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 681                                         "x$enable_gles1" = xyes -o \
 682                                         "x$enable_gles2" = xyes)
 683
 684 if test "x$enable_glx" = xno; then
 685     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 686     enable_xlib_glx=no
 687 fi
 688
 689 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 690     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 691 fi
 692
 693 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 694     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 695 fi
 696
 697 # Disable GLX if OpenGL is not enabled
 698 if test "x$enable_glx$enable_opengl" = xyesno; then
 699     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 700     enable_glx=no
 701 fi
 702
 703 # Disable GLX if DRI and Xlib-GLX are not enabled
 704 if test "x$enable_glx" = xyes -a \
 705         "x$enable_dri" = xno -a \
 706         "x$enable_xlib_glx" = xno; then
 707     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 708     enable_glx=no
 709 fi
 710
 711 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 712                                   "x$enable_dri" = xyes)
 713 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 714
 715 AC_ARG_ENABLE([shared-glapi],
 716     [AS_HELP_STRING([--enable-shared-glapi],
 717         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 718     [enable_shared_glapi="$enableval"],
 719     [enable_shared_glapi="$enable_dri"])
 720
 721 # Shared GLAPI is only useful for DRI
 722 if test "x$enable_dri" = xno; then
 723     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 724     enable_shared_glapi=no
 725 fi
 726
 727 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 728
 729 dnl
 730 dnl Driver specific build directories
 731 dnl
 732 GALLIUM_TARGET_DIRS=""
 733 GALLIUM_WINSYS_DIRS="sw"
 734 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 735 GALLIUM_STATE_TRACKERS_DIRS=""
 736
 737 case "x$enable_glx$enable_xlib_glx" in
 738 xyesyes)
 739     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 740     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 741     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 742     NEED_WINSYS_XLIB="yes"
 743     ;;
 744 esac
 745
 746 if test "x$enable_dri" = xyes; then
 747     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 748     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 749 fi
 750
 751 if test "x$enable_gallium_osmesa" = xyes; then
 752     if test -z "$with_gallium_drivers"; then
 753         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 754     fi
 755     if test "x$enable_osmesa" = xyes; then
 756         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 757     fi
 758     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 759     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 760 fi
 761
 762 AC_SUBST([MESA_LLVM])
 763
 764 # Check for libdrm
 765 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 766                   [have_libdrm=yes], [have_libdrm=no])
 767
 768 if test "x$enable_dri" = xyes; then
 769     # DRI must be shared, I think
 770     if test "$enable_static" = yes; then
 771         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 772     fi
 773
 774     # not a hard requirement as swrast does not depend on it
 775     if test "x$have_libdrm" = xyes; then
 776         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 777     fi
 778 fi
 779
 780 dnl Direct rendering or just indirect rendering
 781 case "$host_os" in
 782 gnu*)
 783     dnl Disable by default on GNU/Hurd
 784     driglx_direct_default="no"
 785     ;;
 786 cygwin*)
 787     dnl Disable by default on cygwin
 788     driglx_direct_default="no"
 789     ;;
 790 *)
 791     driglx_direct_default="yes"
 792     ;;
 793 esac
 794 AC_ARG_ENABLE([driglx-direct],
 795     [AS_HELP_STRING([--disable-driglx-direct],
 796         [disable direct rendering in GLX and EGL for DRI \
 797             @<:@default=auto@:>@])],
 798     [driglx_direct="$enableval"],
 799     [driglx_direct="$driglx_direct_default"])
 800
 801 dnl
 802 dnl libGL configuration per driver
 803 dnl
 804 case "x$enable_glx$enable_xlib_glx" in
 805 xyesyes)
 806     # Xlib-based GLX
 807     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 808     GL_PC_REQ_PRIV="x11 xext"
 809     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 810     GL_LIB_DEPS="$XLIBGL_LIBS"
 811     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 812     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 813     ;;
 814 xyesno)
 815     # DRI-based GLX
 816     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 817     if test x"$driglx_direct" = xyes; then
 818         if test "x$have_libdrm" != xyes; then
 819             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 820         fi
 821         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 822         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 823     fi
 824
 825     # find the DRI deps for libGL
 826     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 827
 828     # add xf86vidmode if available
 829     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 830     if test "$HAVE_XF86VIDMODE" = yes ; then
 831         dri_modules="$dri_modules xxf86vm"
 832     fi
 833
 834     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 835     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 836     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 837     GL_LIB_DEPS="$DRIGL_LIBS"
 838
 839     # need DRM libs, $PTHREAD_LIBS, etc.
 840     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 841     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 842     ;;
 843 esac
 844
 845 # This is outside the case (above) so that it is invoked even for non-GLX
 846 # builds.
 847 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 848
 849 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 850 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 851 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 852 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 853
 854 AC_SUBST([X11_INCLUDES])
 855 AC_SUBST([GL_LIB_DEPS])
 856 AC_SUBST([GL_PC_REQ_PRIV])
 857 AC_SUBST([GL_PC_LIB_PRIV])
 858 AC_SUBST([GL_PC_CFLAGS])
 859 AC_SUBST([DRI_PC_REQ_PRIV])
 860 AC_SUBST([GLESv1_CM_LIB_DEPS])
 861 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 862 AC_SUBST([GLESv2_LIB_DEPS])
 863 AC_SUBST([GLESv2_PC_LIB_PRIV])
 864
 865 AC_SUBST([HAVE_XF86VIDMODE])
 866
 867 dnl
 868 dnl More GLX setup
 869 dnl
 870 case "x$enable_glx$enable_xlib_glx" in
 871 xyesyes)
 872     DEFINES="$DEFINES -DUSE_XSHM"
 873     ;;
 874 xyesno)
 875     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 876     if test "x$driglx_direct" = xyes; then
 877         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 878     fi
 879     ;;
 880 esac
 881
 882 dnl
 883 dnl TLS detection
 884 dnl
 885
 886 AC_ARG_ENABLE([glx-tls],
 887     [AS_HELP_STRING([--enable-glx-tls],
 888         [enable TLS support in GLX @<:@default=disabled@:>@])],
 889     [GLX_USE_TLS="$enableval"],
 890     [GLX_USE_TLS=no])
 891 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 892
 893 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 894       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 895
 896 dnl
 897 dnl More DRI setup
 898 dnl
 899 dnl Directory for DRI drivers
 900 AC_ARG_WITH([dri-driverdir],
 901     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 902         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 903     [DRI_DRIVER_INSTALL_DIR="$withval"],
 904     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 905 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 906 dnl Extra search path for DRI drivers
 907 AC_ARG_WITH([dri-searchpath],
 908     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 909         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 910     [DRI_DRIVER_SEARCH_DIR="$withval"],
 911     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 912 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 913 dnl Which drivers to build - default is chosen by platform
 914 AC_ARG_WITH([dri-drivers],
 915     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 916         [comma delimited DRI drivers list, e.g.
 917         "swrast,i965,radeon" @<:@default=auto@:>@])],
 918     [with_dri_drivers="$withval"],
 919     [with_dri_drivers=yes])
 920 if test "x$with_dri_drivers" = x; then
 921     with_dri_drivers=no
 922 fi
 923
 924 dnl If $with_dri_drivers is yes, directories will be added through
 925 dnl platform checks
 926 DRI_DIRS=""
 927 case "$with_dri_drivers" in
 928 no) ;;
 929 yes)
 930     # classic DRI drivers
 931     if test "x$enable_opengl" = xyes; then
 932         DRI_DIRS="yes"
 933     fi
 934     ;;
 935 *)
 936     # verify the requested driver directories exist
 937     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 938     for driver in $dri_drivers; do
 939         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 940             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 941     done
 942     DRI_DIRS="$dri_drivers"
 943     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 944         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 945     fi
 946     ;;
 947 esac
 948
 949 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 950 if test "x$enable_dri" = xyes; then
 951     # Platform specific settings and drivers to build
 952     case "$host_os" in
 953     linux*)
 954         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 955         DEFINES="$DEFINES -DHAVE_ALIAS"
 956
 957         case "$host_cpu" in
 958         x86_64|amd64)
 959             if test "x$DRI_DIRS" = "xyes"; then
 960                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 961             fi
 962             ;;
 963         powerpc*)
 964             # Build only the drivers for cards that exist on PowerPC.
 965             if test "x$DRI_DIRS" = "xyes"; then
 966                 DRI_DIRS="r200 radeon swrast"
 967             fi
 968             ;;
 969         sparc*)
 970             # Build only the drivers for cards that exist on sparc
 971             if test "x$DRI_DIRS" = "xyes"; then
 972                 DRI_DIRS="r200 radeon swrast"
 973             fi
 974             ;;
 975         esac
 976         ;;
 977     freebsd* | dragonfly* | *netbsd* | openbsd*)
 978         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 979         DEFINES="$DEFINES -DHAVE_ALIAS"
 980
 981         if test "x$DRI_DIRS" = "xyes"; then
 982             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 983         fi
 984         ;;
 985     gnu*)
 986         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 987         DEFINES="$DEFINES -DHAVE_ALIAS"
 988         ;;
 989     solaris*)
 990         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 991         ;;
 992     cygwin*)
 993         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 994         if test "x$DRI_DIRS" = "xyes"; then
 995             DRI_DIRS="swrast"
 996         fi
 997         ;;
 998     esac
 999
1000     # default drivers
1001     if test "x$DRI_DIRS" = "xyes"; then
1002         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1003     fi
1004
1005     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1006
1007     # Check for expat
1008     EXPAT_INCLUDES=""
1009     EXPAT_LIB=-lexpat
1010     AC_ARG_WITH([expat],
1011         [AS_HELP_STRING([--with-expat=DIR],
1012             [expat install directory])],[
1013         EXPAT_INCLUDES="-I$withval/include"
1014         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1015         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1016         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1017         ])
1018     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1019     save_LIBS="$LIBS"
1020     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1021         [AC_MSG_ERROR([Expat required for DRI.])])
1022     LIBS="$save_LIBS"
1023
1024     # If we are building any DRI driver other than swrast.
1025     if test -n "$DRI_DIRS"; then
1026         if test x"$DRI_DIRS" != xswrast; then
1027             # ... libdrm is required
1028             if test "x$have_libdrm" != xyes; then
1029                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1030             fi
1031             DRICOMMON_NEED_LIBDRM=yes
1032         else
1033             DRICOMMON_NEED_LIBDRM=no
1034         fi
1035     fi
1036
1037     # put all the necessary libs together
1038     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1039     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1040
1041     DRI_DRIVER_LDFLAGS="-module -avoid-version -shared -Wl,-Bsymbolic"
1042 fi
1043
1044 enable_dricore=no
1045
1046 # megadriver wants to use libmesa.la, while non-megadrivers want to
1047 # automatically get libdricore.  Some day hopefully we'll transition
1048 # everything to megadriver.
1049 MEGADRIVER_DRI_LIB_DEPS=$DRI_LIB_DEPS
1050 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la $DRI_LIB_DEPS"
1051
1052 AM_CONDITIONAL(NEED_LIBDRICORE, test "x$enable_dricore" = xyes)
1053 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1054 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1055                                   "x$enable_osmesa" = xyes -o \
1056                                   -n "$DRI_DIRS")
1057 AC_SUBST([EXPAT_INCLUDES])
1058 AC_SUBST([DRI_LIB_DEPS])
1059 AC_SUBST([DRI_DRIVER_LDFLAGS])
1060 AC_SUBST([MEGADRIVER_DRI_LIB_DEPS])
1061 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1062
1063 case $DRI_DIRS in
1064 *i915*|*i965*)
1065     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1066
1067     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1068         case $d in
1069         i915)
1070             HAVE_I915_DRI=yes;
1071             ;;
1072         i965)
1073             HAVE_I965_DRI=yes;
1074             ;;
1075         esac
1076     done
1077
1078     ;;
1079 esac
1080
1081 case $DRI_DIRS in
1082 *nouveau*)
1083     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1084     HAVE_NOUVEAU_DRI=yes;
1085     ;;
1086 esac
1087
1088 case $DRI_DIRS in
1089 *radeon*|*r200*)
1090     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1091
1092     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1093         case $d in
1094         radeon)
1095             HAVE_RADEON_DRI=yes;
1096             ;;
1097         r200)
1098             HAVE_R200_DRI=yes;
1099             ;;
1100         esac
1101     done
1102
1103     ;;
1104 esac
1105
1106 case $DRI_DIRS in
1107 *swrast*)
1108     HAVE_SWRAST_DRI=yes;
1109     ;;
1110 esac
1111
1112 dnl
1113 dnl OSMesa configuration
1114 dnl
1115
1116 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1117 AC_ARG_WITH([osmesa-bits],
1118     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1119         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1120     [osmesa_bits="$withval"],
1121     [osmesa_bits=8])
1122 if test "x$osmesa_bits" != x8; then
1123     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1124         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1125         osmesa_bits=8
1126     fi
1127 fi
1128 case "x$osmesa_bits" in
1129 x8)
1130     OSMESA_LIB="${OSMESA_LIB}"
1131     ;;
1132 x16|x32)
1133     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1134     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1135     ;;
1136 *)
1137     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1138     ;;
1139 esac
1140
1141 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1142     # only link libraries with osmesa if shared
1143     if test "$enable_static" = no; then
1144         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1145     else
1146         OSMESA_LIB_DEPS=""
1147     fi
1148     OSMESA_MESA_DEPS=""
1149     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1150 fi
1151
1152 AC_SUBST([OSMESA_LIB_DEPS])
1153 AC_SUBST([OSMESA_MESA_DEPS])
1154 AC_SUBST([OSMESA_PC_REQ])
1155 AC_SUBST([OSMESA_PC_LIB_PRIV])
1156
1157 dnl
1158 dnl gbm configuration
1159 dnl
1160 if test "x$enable_gbm" = xauto; then
1161     case "$with_egl_platforms" in
1162         *drm*)
1163             enable_gbm=yes ;;
1164          *)
1165             enable_gbm=no ;;
1166     esac
1167 fi
1168 if test "x$enable_gbm" = xyes; then
1169     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1170                       AC_MSG_ERROR([gbm needs udev]))
1171
1172     if test "x$enable_dri" = xyes; then
1173         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1174         if test "x$enable_shared_glapi" = xno; then
1175             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1176         fi
1177     fi
1178 fi
1179 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1180 GBM_PC_REQ_PRIV="libudev"
1181 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1182 AC_SUBST([GBM_PC_REQ_PRIV])
1183 AC_SUBST([GBM_PC_LIB_PRIV])
1184
1185 dnl
1186 dnl EGL configuration
1187 dnl
1188 EGL_CLIENT_APIS=""
1189
1190 if test "x$enable_egl" = xyes; then
1191     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1192
1193     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1194
1195     if test "$enable_static" != yes; then
1196         # build egl_glx when libGL is built
1197         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1198                           [have_libudev=yes],[have_libudev=no])
1199         if test "$have_libudev" = yes; then
1200             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1201         fi
1202
1203         if test "x$enable_dri" = xyes; then
1204             HAVE_EGL_DRIVER_DRI2=1
1205         fi
1206
1207     fi
1208 fi
1209 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1210 AC_SUBST([EGL_LIB_DEPS])
1211
1212 dnl
1213 dnl EGL Gallium configuration
1214 dnl
1215 if test "x$enable_gallium_egl" = xyes; then
1216     if test "x$with_gallium_drivers" = x; then
1217         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1218     fi
1219     if test "x$enable_egl" = xno; then
1220         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1221     fi
1222     if test "x$have_libdrm" != xyes; then
1223         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1224     fi
1225
1226     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1227     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1228 fi
1229 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1230
1231 dnl
1232 dnl gbm Gallium configuration
1233 dnl
1234 if test "x$enable_gallium_gbm" = xauto; then
1235     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1236         yesyesyes*drm*)
1237             enable_gallium_gbm=yes ;;
1238          *)
1239             enable_gallium_gbm=no ;;
1240     esac
1241 fi
1242 if test "x$enable_gallium_gbm" = xyes; then
1243     if test "x$with_gallium_drivers" = x; then
1244         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1245     fi
1246     if test "x$enable_gbm" = xno; then
1247         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1248     fi
1249     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1250     if test "x$enable_dri" = xno; then
1251         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1252     fi
1253
1254     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1255     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1256     enable_gallium_loader=yes
1257 fi
1258 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1259
1260 dnl
1261 dnl X.Org DDX configuration
1262 dnl
1263 if test "x$enable_xorg" = xyes; then
1264     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1265     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1266     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1267     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1268         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1269         HAVE_XEXTPROTO_71="no")
1270     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1271 fi
1272 AM_CONDITIONAL(HAVE_ST_XORG, test "x$enable_xorg" = xyes)
1273
1274 dnl
1275 dnl XA configuration
1276 dnl
1277 if test "x$enable_xa" = xyes; then
1278     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1279 fi
1280 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1281
1282 dnl
1283 dnl OpenVG configuration
1284 dnl
1285 VG_LIB_DEPS=""
1286
1287 if test "x$enable_openvg" = xyes; then
1288     if test "x$enable_egl" = xno; then
1289         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1290     fi
1291     if test "x$with_gallium_drivers" = x; then
1292         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1293     fi
1294     if test "x$enable_gallium_egl" = xno; then
1295         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1296     fi
1297
1298     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1299     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1300     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1301     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1302     AC_SUBST([VG_PC_LIB_PRIV])
1303 fi
1304 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1305
1306 dnl
1307 dnl Gallium G3DVL configuration
1308 dnl
1309 if test -n "$with_gallium_drivers"; then
1310     if test "x$enable_xvmc" = xauto; then
1311         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1312     fi
1313
1314     if test "x$enable_vdpau" = xauto; then
1315         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1316     fi
1317 fi
1318
1319 if test "x$enable_xvmc" = xyes; then
1320     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1321     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1322 fi
1323 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1324
1325 if test "x$enable_vdpau" = xyes; then
1326     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1327     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1328 fi
1329 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1330
1331 dnl
1332 dnl OpenCL configuration
1333 dnl
1334
1335 AC_ARG_WITH([libclc-path],
1336    [AS_HELP_STRING([--with-libclc-path],
1337          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1338    [LIBCLC_PATH="$withval"],
1339    [LIBCLC_PATH=""])
1340
1341 if test "x$LIBCLC_PATH" != x; then
1342    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1343                   Please review the updated build instructions for clover:
1344                   http://dri.freedesktop.org/wiki/GalliumCompute])
1345 fi
1346
1347
1348 AC_ARG_WITH([clang-libdir],
1349    [AS_HELP_STRING([--with-clang-libdir],
1350          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1351    [CLANG_LIBDIR="$withval"],
1352    [CLANG_LIBDIR=""])
1353
1354 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1355
1356 if test "x$enable_opencl" = xyes; then
1357     if test "x$with_gallium_drivers" = x; then
1358         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1359     fi
1360
1361     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1362         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1363     fi
1364
1365     if test "x$have_libclc" = xno; then
1366         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1367                     Make sure the directory containing libclc.pc is specified in your
1368                     PKG_CONFIG_PATH environment variable.
1369                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1370     else
1371         LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1372         LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1373         AC_SUBST([LIBCLC_INCLUDEDIR])
1374         AC_SUBST([LIBCLC_LIBEXECDIR])
1375     fi
1376
1377     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1378     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1379     enable_gallium_loader=yes
1380
1381     if test "x$enable_opencl_icd" = xyes; then
1382         OPENCL_LIBNAME="MesaOpenCL"
1383     else
1384         OPENCL_LIBNAME="OpenCL"
1385     fi
1386 fi
1387 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1388 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1389 AC_SUBST([OPENCL_LIBNAME])
1390
1391 dnl
1392 dnl Gallium configuration
1393 dnl
1394 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1395
1396 AC_SUBST([LLVM_BINDIR])
1397 AC_SUBST([LLVM_CFLAGS])
1398 AC_SUBST([LLVM_CPPFLAGS])
1399 AC_SUBST([LLVM_CXXFLAGS])
1400 AC_SUBST([LLVM_LIBDIR])
1401 AC_SUBST([LLVM_LIBS])
1402 AC_SUBST([LLVM_LDFLAGS])
1403 AC_SUBST([LLVM_INCLUDEDIR])
1404 AC_SUBST([LLVM_VERSION])
1405 AC_SUBST([CLANG_RESOURCE_DIR])
1406
1407 case "x$enable_opengl$enable_gles1$enable_gles2" in
1408 x*yes*)
1409     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1410     ;;
1411 esac
1412
1413 AC_SUBST([VG_LIB_DEPS])
1414 AC_SUBST([EGL_CLIENT_APIS])
1415
1416 dnl
1417 dnl EGL Platforms configuration
1418 dnl
1419 AC_ARG_WITH([egl-platforms],
1420     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1421         [comma delimited native platforms libEGL supports, e.g.
1422         "x11,drm" @<:@default=auto@:>@])],
1423     [with_egl_platforms="$withval"],
1424     [if test "x$enable_egl" = xyes; then
1425         with_egl_platforms="x11"
1426     else
1427         with_egl_platforms=""
1428     fi])
1429
1430 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1431     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1432 fi
1433
1434 # Do per-EGL platform setups and checks
1435 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1436 for plat in $egl_platforms; do
1437         case "$plat" in
1438         wayland)
1439                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1440                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1441
1442                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1443                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1444                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1445                 ;;
1446
1447         x11)
1448                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1449
1450                 if test "x$enable_glx" = xyes; then
1451                         HAVE_EGL_DRIVER_GLX=1
1452                 fi
1453                 ;;
1454
1455         drm)
1456                 test "x$enable_gbm" = "xno" &&
1457                         AC_MSG_ERROR([EGL platform drm needs gbm])
1458                 ;;
1459
1460         android|fbdev|gdi|null)
1461                 ;;
1462
1463         *)
1464                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1465                 ;;
1466         esac
1467
1468         case "$plat$have_libudev" in
1469                 waylandno|drmno)
1470                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1471         esac
1472 done
1473
1474 # libEGL wants to default to the first platform specified in
1475 # ./configure.  parse that here.
1476 if test "x$egl_platforms" != "x"; then
1477     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1478     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1479 else
1480     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1481 fi
1482
1483 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1484     NEED_WINSYS_XLIB=yes
1485 fi
1486 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1487 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1488 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1489 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1490 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1491
1492 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1493 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1494
1495 AC_SUBST([EGL_NATIVE_PLATFORM])
1496 AC_SUBST([EGL_CFLAGS])
1497
1498 # If we don't have the X11 platform, set this define so we don't try to include
1499 # the X11 headers.
1500 if ! echo "$egl_platforms" | grep -q 'x11'; then
1501     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1502     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1503 fi
1504
1505 AC_ARG_WITH([egl-driver-dir],
1506     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1507                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1508     [EGL_DRIVER_INSTALL_DIR="$withval"],
1509     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1510 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1511
1512 AC_ARG_WITH([xorg-driver-dir],
1513     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1514                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1515     [XORG_DRIVER_INSTALL_DIR="$withval"],
1516     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1517 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1518
1519 AC_ARG_WITH([max-width],
1520     [AS_HELP_STRING([--with-max-width=N],
1521                     [Maximum framebuffer width (4096)])],
1522     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1523      AS_IF([test "${withval}" -gt "4096"],
1524            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1525 )
1526 AC_ARG_WITH([max-height],
1527     [AS_HELP_STRING([--with-max-height=N],
1528                     [Maximum framebuffer height (4096)])],
1529     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1530      AS_IF([test "${withval}" -gt "4096"],
1531            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1532 )
1533
1534 dnl
1535 dnl Gallium LLVM
1536 dnl
1537 AC_ARG_ENABLE([gallium-llvm],
1538     [AS_HELP_STRING([--enable-gallium-llvm],
1539         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1540     [enable_gallium_llvm="$enableval"],
1541     [enable_gallium_llvm=auto])
1542
1543 AC_ARG_WITH([llvm-shared-libs],
1544     [AS_HELP_STRING([--with-llvm-shared-libs],
1545         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1546     [],
1547     [with_llvm_shared_libs=no])
1548 AS_IF([test x$enable_opencl = xyes],
1549     [
1550         if test "x$with_llvm_shared_libs" != xyes; then
1551             AC_MSG_ERROR([OpenCL requires LLVM shared libraries])
1552         fi
1553     ])
1554
1555 AC_ARG_WITH([llvm-prefix],
1556     [AS_HELP_STRING([--with-llvm-prefix],
1557         [Prefix for LLVM installations in non-standard locations])],
1558     [llvm_prefix="$withval"],
1559     [llvm_prefix=""])
1560
1561
1562 # Call this inside ` ` to get the return value.
1563 # $1 is the llvm-config command with arguments.
1564 strip_unwanted_llvm_flags() {
1565     # Use \> (marks the end of the word)
1566     echo `$1` | sed \
1567         -e 's/-DNDEBUG\>//g' \
1568         -e 's/-pedantic\>//g' \
1569         -e 's/-Wcovered-switch-default\>//g' \
1570         -e 's/-O.\>//g' \
1571         -e 's/-g\>//g' \
1572         -e 's/-Wall\>//g' \
1573         -e 's/-fomit-frame-pointer\>//g'
1574 }
1575
1576
1577 if test "x$with_gallium_drivers" = x; then
1578     enable_gallium_llvm=no
1579 fi
1580 if test "x$enable_gallium_llvm" = xauto; then
1581     case "$host_cpu" in
1582     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1583     esac
1584 fi
1585 if test "x$enable_gallium_llvm" = xyes; then
1586     if test "x$llvm_prefix" != x; then
1587         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1588     else
1589         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1590     fi
1591
1592     if test "x$LLVM_CONFIG" != xno; then
1593         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1594         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1595         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1596         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1597         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1598         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1599         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1600         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1601
1602         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1603             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1604         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1605             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1606
1607         if test "x${LLVM_VERSION_MAJOR}" != x; then
1608             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1609         else
1610             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1611         fi
1612
1613         LLVM_COMPONENTS="engine bitwriter"
1614         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1615             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1616         fi
1617
1618         if test "x$enable_opencl" = xyes; then
1619             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1620             # LLVM 3.3 >= 177971 requires IRReader
1621             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1622                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1623             fi
1624             # LLVM 3.4 requires Option
1625             if $LLVM_CONFIG --components | grep -qw 'option'; then
1626                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1627             fi
1628         fi
1629         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1630         MESA_LLVM=1
1631
1632         dnl Check for Clang internal headers
1633         if test "x$enable_opencl" = xyes; then
1634             if test "x$CLANG_LIBDIR" = x; then
1635                 CLANG_LIBDIR=${LLVM_LIBDIR}
1636             fi
1637             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1638             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1639                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1640         fi
1641     else
1642         MESA_LLVM=0
1643         LLVM_VERSION_INT=0
1644     fi
1645 else
1646     MESA_LLVM=0
1647     LLVM_VERSION_INT=0
1648 fi
1649
1650 dnl Directory for XVMC libs
1651 AC_ARG_WITH([xvmc-libdir],
1652     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1653         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1654     [XVMC_LIB_INSTALL_DIR="$withval"],
1655     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1656 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1657
1658 dnl
1659 dnl Gallium Tests
1660 dnl
1661 if test "x$enable_gallium_tests" = xyes; then
1662     enable_gallium_loader=yes
1663 fi
1664 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1665
1666 if test "x$enable_gallium_loader" = xyes; then
1667     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1668 fi
1669 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1670
1671 dnl Directory for VDPAU libs
1672 AC_ARG_WITH([vdpau-libdir],
1673     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1674         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1675     [VDPAU_LIB_INSTALL_DIR="$withval"],
1676     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1677 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1678
1679 dnl Directory for OpenCL libs
1680 AC_ARG_WITH([opencl-libdir],
1681     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1682         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1683     [OPENCL_LIB_INSTALL_DIR="$withval"],
1684     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1685 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1686
1687 dnl
1688 dnl Gallium helper functions
1689 dnl
1690 gallium_check_st() {
1691     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1692          if test "x$have_libdrm" != xyes; then
1693             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1694          fi
1695          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1696     fi
1697     if test "x$enable_dri" = xyes && test "x$2" != x; then
1698          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1699     fi
1700     if test "x$enable_xorg" = xyes && test "x$3" != x; then
1701          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1702     fi
1703     if test "x$enable_xa" = xyes && test "x$4" != x; then
1704          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1705     fi
1706     if test "x$enable_xvmc" = xyes && test "x$5" != x; then
1707          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1708     fi
1709     if test "x$enable_vdpau" = xyes && test "x$6" != x; then
1710          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1711     fi
1712 }
1713
1714 gallium_require_llvm() {
1715     if test "x$MESA_LLVM" = x0; then
1716         case "$host_cpu" in
1717         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1718         esac
1719     fi
1720 }
1721
1722 gallium_require_drm_loader() {
1723     if test "x$enable_gallium_loader" = xyes; then
1724         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1725                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1726         if test "x$have_libdrm" != xyes; then
1727             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1728         fi
1729         enable_gallium_drm_loader=yes
1730     fi
1731 }
1732
1733 radeon_llvm_check() {
1734     LLVM_REQUIRED_VERSION_MAJOR="3"
1735     LLVM_REQUIRED_VERSION_MINOR="3"
1736     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1737         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1738     fi
1739     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1740         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1741                       sources with the --enable-experimental-targets=R600
1742                       configure flag])
1743     fi
1744     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1745     NEED_RADEON_LLVM=yes
1746     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1747                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1748 }
1749
1750 dnl Gallium drivers
1751 if test "x$enable_dri" = xyes -o "x$enable_xorg" = xyes -o \
1752         "x$enable_xa" = xyes -o "x$enable_xvmc" = xyes -o \
1753         "x$enable_vdpau" = xyes; then
1754     NEED_NONNULL_WINSYS=yes
1755 fi
1756 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1757
1758 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1759 if test "x$with_gallium_drivers" != x; then
1760     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1761     for driver in $gallium_drivers; do
1762         case "x$driver" in
1763         xsvga)
1764             HAVE_GALLIUM_SVGA=yes
1765             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1766             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1767             ;;
1768         xi915)
1769             HAVE_GALLIUM_I915=yes
1770             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1771             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1772             if test "x$MESA_LLVM" = x1; then
1773                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1774             fi
1775             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1776             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1777             DRICOMMON_NEED_LIBDRM=yes
1778             ;;
1779         xilo)
1780             HAVE_GALLIUM_ILO=yes
1781             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1782             gallium_require_drm_loader
1783             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1784             gallium_check_st "intel/drm" "dri-ilo"
1785             DRICOMMON_NEED_LIBDRM=yes
1786             ;;
1787         xr300)
1788             HAVE_GALLIUM_R300=yes
1789             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1790             gallium_require_llvm "Gallium R300"
1791             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1792             gallium_check_st "radeon/drm" "r300/dri" "" "" "r300/xvmc" "r300/vdpau"
1793             DRICOMMON_NEED_LIBDRM=yes
1794             ;;
1795         xr600)
1796             HAVE_GALLIUM_R600=yes
1797             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1798             gallium_require_drm_loader
1799             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1800             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1801                 radeon_llvm_check
1802                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1803             fi
1804             if test "x$enable_r600_llvm" = xyes; then
1805                 USE_R600_LLVM_COMPILER=yes;
1806             fi
1807             if test "x$enable_opencl" = xyes; then
1808                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1809             fi
1810             gallium_check_st "radeon/drm" "r600/dri" "r600/xorg" "" "r600/xvmc" "r600/vdpau"
1811             DRICOMMON_NEED_LIBDRM=yes
1812             ;;
1813         xradeonsi)
1814             HAVE_GALLIUM_RADEONSI=yes
1815             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1816             gallium_require_drm_loader
1817             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1818             radeon_llvm_check
1819             gallium_check_st "radeon/drm" "radeonsi/dri" "radeonsi/xorg" "" "" "radeonsi/vdpau" ""
1820             DRICOMMON_NEED_LIBDRM=yes
1821             ;;
1822         xnouveau)
1823             HAVE_GALLIUM_NOUVEAU=yes
1824             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1825             gallium_require_drm_loader
1826             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1827             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1828             DRICOMMON_NEED_LIBDRM=yes
1829             ;;
1830         xfreedreno)
1831             HAVE_GALLIUM_FREEDRENO=yes
1832             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1833             gallium_require_drm_loader
1834             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1835             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1836             DRICOMMON_NEED_LIBDRM=yes
1837             ;;
1838         xswrast)
1839             HAVE_GALLIUM_SOFTPIPE=yes
1840             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1841             if test "x$MESA_LLVM" = x1; then
1842                 HAVE_GALLIUM_LLVMPIPE=yes
1843                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1844             fi
1845
1846             if test "x$enable_dri" = xyes; then
1847                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1848             fi
1849             if test "x$enable_vdpau" = xyes; then
1850                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1851             fi
1852             if test "x$enable_xvmc" = xyes; then
1853                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1854             fi
1855             if test "x$enable_vdpau" = xyes -o "x$enable_xvmc" = xyes; then
1856                 NEED_WINSYS_XLIB=yes
1857                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1858             fi
1859             ;;
1860         *)
1861             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1862             ;;
1863         esac
1864     done
1865 fi
1866
1867 dnl Set LLVM_LIBS - This is done after the driver configuration so
1868 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1869 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1870 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1871 dnl this was causing the same libraries to be appear multiple times
1872 dnl in LLVM_LIBS.
1873
1874 if test "x$MESA_LLVM" != x0; then
1875
1876     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1877
1878     if test "x$with_llvm_shared_libs" = xyes; then
1879         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1880         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1881         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1882
1883         if test "x$llvm_have_one_so" = xyes; then
1884             dnl LLVM was built using auto*, so there is only one shared object.
1885             LLVM_LIBS="-l$LLVM_SO_NAME"
1886         else
1887             dnl If LLVM was built with CMake, there will be one shared object per
1888             dnl component.
1889             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1890                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1891         Please make sure you have built llvm with the --enable-shared option
1892         and that your llvm libraries are installed in $LLVM_LIBDIR
1893         If you have installed your llvm libraries to a different directory you
1894         can use the --with-llvm-prefix= configure flag to specify this directory.
1895         NOTE: Mesa is attempting to use llvm shared libraries because you have
1896         passed one of the following options to configure:
1897                 --with-llvm-shared-libs
1898                 --enable-opencl
1899         If you do not want to build with llvm shared libraries and instead want to
1900         use llvm static libraries then remove these options from your configure
1901         invocation and reconfigure.])])
1902
1903            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1904            dnl install uses a shared object for each compoenent and we have
1905            dnl already added all of these objects to LLVM_LIBS.
1906         fi
1907     fi
1908 fi
1909
1910 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1911 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1912 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1913 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1914 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1915 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1916 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1917 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1918 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1919 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1920
1921 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1922                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1923                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1924 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1925                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1926                                                   && test "x$MESA_LLVM" = x1)
1927
1928 if test "x$enable_gallium_loader" = xyes; then
1929     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1930
1931     if test "x$enable_gallium_drm_loader" = xyes; then
1932         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1933         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1934                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1935         if test "x$pipe_loader_have_xcb" = xyes; then
1936             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1937             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1938         fi
1939     fi
1940
1941     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1942     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1943 fi
1944
1945 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1946 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1947 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1948 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1949 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1950 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1951
1952 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1953                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1954                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1955                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1956 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1957                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1958 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1959 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1960 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1961 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1962 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1963 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1964 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1965
1966 AC_SUBST([ELF_LIB])
1967
1968 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1969 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1970                                      "x$enable_xlib_glx" = xyes -o \
1971                                      "x$enable_osmesa" = xyes -o \
1972                                      -n "$DRI_DIRS" -o \
1973                                      "x$enable_gallium_osmesa" = xyes)
1974 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1975 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1976 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1977
1978 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1979 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1980 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1981
1982 AC_SUBST([VDPAU_MAJOR], 1)
1983 AC_SUBST([VDPAU_MINOR], 0)
1984
1985 AC_SUBST([XVMC_MAJOR], 1)
1986 AC_SUBST([XVMC_MINOR], 0)
1987
1988 AC_SUBST([XA_MAJOR], 2)
1989 AC_SUBST([XA_MINOR], 0)
1990 AC_SUBST([XA_TINY], 0)
1991 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1992
1993 dnl Restore LDFLAGS and CPPFLAGS
1994 LDFLAGS="$_SAVE_LDFLAGS"
1995 CPPFLAGS="$_SAVE_CPPFLAGS"
1996
1997 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1998 if test "x$acv_mesa_CLANG" = xyes; then
1999     CFLAGS="$CFLAGS -Qunused-arguments"
2000     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2001 fi
2002
2003 dnl Add user CFLAGS and CXXFLAGS
2004 CFLAGS="$CFLAGS $USER_CFLAGS"
2005 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2006
2007 dnl Substitute the config
2008 AC_CONFIG_FILES([Makefile
2009                 src/Makefile
2010                 src/egl/Makefile
2011                 src/egl/drivers/Makefile
2012                 src/egl/drivers/dri2/Makefile
2013                 src/egl/drivers/glx/Makefile
2014                 src/egl/main/Makefile
2015                 src/egl/main/egl.pc
2016                 src/egl/wayland/Makefile
2017                 src/egl/wayland/wayland-drm/Makefile
2018                 src/egl/wayland/wayland-egl/Makefile
2019                 src/egl/wayland/wayland-egl/wayland-egl.pc
2020                 src/gallium/auxiliary/Makefile
2021                 src/gallium/auxiliary/pipe-loader/Makefile
2022                 src/gallium/drivers/Makefile
2023                 src/gallium/drivers/freedreno/Makefile
2024                 src/gallium/drivers/freedreno/a2xx/Makefile
2025                 src/gallium/drivers/freedreno/a3xx/Makefile
2026                 src/gallium/drivers/galahad/Makefile
2027                 src/gallium/drivers/i915/Makefile
2028                 src/gallium/drivers/identity/Makefile
2029                 src/gallium/drivers/ilo/Makefile
2030                 src/gallium/drivers/llvmpipe/Makefile
2031                 src/gallium/drivers/noop/Makefile
2032                 src/gallium/drivers/nouveau/Makefile
2033                 src/gallium/drivers/r300/Makefile
2034                 src/gallium/drivers/r600/Makefile
2035                 src/gallium/drivers/radeon/Makefile
2036                 src/gallium/drivers/radeonsi/Makefile
2037                 src/gallium/drivers/rbug/Makefile
2038                 src/gallium/drivers/softpipe/Makefile
2039                 src/gallium/drivers/svga/Makefile
2040                 src/gallium/drivers/trace/Makefile
2041                 src/gallium/state_trackers/Makefile
2042                 src/gallium/state_trackers/clover/Makefile
2043                 src/gallium/state_trackers/dri/Makefile
2044                 src/gallium/state_trackers/dri/drm/Makefile
2045                 src/gallium/state_trackers/dri/sw/Makefile
2046                 src/gallium/state_trackers/egl/Makefile
2047                 src/gallium/state_trackers/gbm/Makefile
2048                 src/gallium/state_trackers/glx/xlib/Makefile
2049                 src/gallium/state_trackers/osmesa/Makefile
2050                 src/gallium/state_trackers/vdpau/Makefile
2051                 src/gallium/state_trackers/vega/Makefile
2052                 src/gallium/state_trackers/xa/Makefile
2053                 src/gallium/state_trackers/xorg/Makefile
2054                 src/gallium/state_trackers/xvmc/Makefile
2055                 src/gallium/targets/Makefile
2056                 src/gallium/targets/dri-freedreno/Makefile
2057                 src/gallium/targets/dri-i915/Makefile
2058                 src/gallium/targets/dri-ilo/Makefile
2059                 src/gallium/targets/dri-nouveau/Makefile
2060                 src/gallium/targets/dri-swrast/Makefile
2061                 src/gallium/targets/dri-vmwgfx/Makefile
2062                 src/gallium/targets/egl-static/Makefile
2063                 src/gallium/targets/gbm/Makefile
2064                 src/gallium/targets/opencl/Makefile
2065                 src/gallium/targets/osmesa/Makefile
2066                 src/gallium/targets/osmesa/osmesa.pc
2067                 src/gallium/targets/pipe-loader/Makefile
2068                 src/gallium/targets/radeonsi/dri/Makefile
2069                 src/gallium/targets/radeonsi/vdpau/Makefile
2070                 src/gallium/targets/radeonsi/xorg/Makefile
2071                 src/gallium/targets/r300/dri/Makefile
2072                 src/gallium/targets/r300/vdpau/Makefile
2073                 src/gallium/targets/r300/xvmc/Makefile
2074                 src/gallium/targets/r600/dri/Makefile
2075                 src/gallium/targets/r600/vdpau/Makefile
2076                 src/gallium/targets/r600/xorg/Makefile
2077                 src/gallium/targets/r600/xvmc/Makefile
2078                 src/gallium/targets/libgl-xlib/Makefile
2079                 src/gallium/targets/vdpau-nouveau/Makefile
2080                 src/gallium/targets/vdpau-softpipe/Makefile
2081                 src/gallium/targets/xa-vmwgfx/Makefile
2082                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2083                 src/gallium/targets/xorg-i915/Makefile
2084                 src/gallium/targets/xorg-nouveau/Makefile
2085                 src/gallium/targets/xvmc-nouveau/Makefile
2086                 src/gallium/targets/xvmc-softpipe/Makefile
2087                 src/gallium/tests/trivial/Makefile
2088                 src/gallium/tests/unit/Makefile
2089                 src/gallium/winsys/Makefile
2090                 src/gallium/winsys/freedreno/drm/Makefile
2091                 src/gallium/winsys/i915/drm/Makefile
2092                 src/gallium/winsys/i915/sw/Makefile
2093                 src/gallium/winsys/intel/drm/Makefile
2094                 src/gallium/winsys/nouveau/drm/Makefile
2095                 src/gallium/winsys/radeon/drm/Makefile
2096                 src/gallium/winsys/svga/drm/Makefile
2097                 src/gallium/winsys/sw/dri/Makefile
2098                 src/gallium/winsys/sw/fbdev/Makefile
2099                 src/gallium/winsys/sw/null/Makefile
2100                 src/gallium/winsys/sw/wayland/Makefile
2101                 src/gallium/winsys/sw/wrapper/Makefile
2102                 src/gallium/winsys/sw/xlib/Makefile
2103                 src/gbm/Makefile
2104                 src/gbm/main/gbm.pc
2105                 src/glsl/Makefile
2106                 src/glx/Makefile
2107                 src/glx/tests/Makefile
2108                 src/gtest/Makefile
2109                 src/mapi/Makefile
2110                 src/mapi/es1api/Makefile
2111                 src/mapi/es1api/glesv1_cm.pc
2112                 src/mapi/es2api/Makefile
2113                 src/mapi/es2api/glesv2.pc
2114                 src/mapi/glapi/Makefile
2115                 src/mapi/glapi/gen/Makefile
2116                 src/mapi/glapi/tests/Makefile
2117                 src/mapi/shared-glapi/Makefile
2118                 src/mapi/shared-glapi/tests/Makefile
2119                 src/mapi/vgapi/Makefile
2120                 src/mapi/vgapi/vg.pc
2121                 src/mesa/Makefile
2122                 src/mesa/gl.pc
2123                 src/mesa/drivers/dri/dri.pc
2124                 src/mesa/drivers/dri/common/Makefile
2125                 src/mesa/drivers/dri/common/xmlpool/Makefile
2126                 src/mesa/drivers/dri/i915/Makefile
2127                 src/mesa/drivers/dri/i965/Makefile
2128                 src/mesa/drivers/dri/Makefile
2129                 src/mesa/drivers/dri/nouveau/Makefile
2130                 src/mesa/drivers/dri/r200/Makefile
2131                 src/mesa/drivers/dri/radeon/Makefile
2132                 src/mesa/drivers/dri/swrast/Makefile
2133                 src/mesa/drivers/osmesa/Makefile
2134                 src/mesa/drivers/osmesa/osmesa.pc
2135                 src/mesa/drivers/x11/Makefile
2136                 src/mesa/libdricore/Makefile
2137                 src/mesa/main/tests/Makefile
2138                 src/mesa/main/tests/hash_table/Makefile
2139                 src/mesa/program/Makefile
2140                 src/mesa/x86-64/Makefile
2141                 src/mesa/x86/Makefile])
2142
2143 dnl Sort the dirs alphabetically
2144 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2145 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2146 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2147 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2148
2149 AC_OUTPUT
2150
2151 dnl
2152 dnl Output some configuration info for the user
2153 dnl
2154 echo ""
2155 echo "        prefix:          $prefix"
2156 echo "        exec_prefix:     $exec_prefix"
2157 echo "        libdir:          $libdir"
2158 echo "        includedir:      $includedir"
2159
2160 dnl API info
2161 echo ""
2162 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2163 echo "        OpenVG:          $enable_openvg"
2164
2165 dnl Driver info
2166 echo ""
2167 case "x$enable_osmesa$enable_gallium_osmesa" in
2168 xnoyes)
2169         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2170         ;;
2171 xyesno)
2172         echo "        OSMesa:          lib$OSMESA_LIB"
2173         ;;
2174 xnono)
2175         echo "        OSMesa:          no"
2176         ;;
2177 esac
2178
2179 if test "x$enable_dri" != xno; then
2180         # cleanup the drivers var
2181         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2182         if test "x$DRI_DIRS" = x; then
2183             echo "        DRI drivers:     no"
2184         else
2185             echo "        DRI drivers:     $dri_dirs"
2186         fi
2187         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2188 fi
2189
2190 case "x$enable_glx$enable_xlib_glx" in
2191 xyesyes)
2192     echo "        GLX:             Xlib-based"
2193     ;;
2194 xyesno)
2195     echo "        GLX:             DRI-based"
2196     ;;
2197 *)
2198     echo "        GLX:             $enable_glx"
2199     ;;
2200 esac
2201
2202 dnl EGL
2203 echo ""
2204 echo "        EGL:             $enable_egl"
2205 if test "$enable_egl" = yes; then
2206     echo "        EGL platforms:   $egl_platforms"
2207
2208     egl_drivers=""
2209     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2210         egl_drivers="$egl_drivers builtin:egl_glx"
2211     fi
2212     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2213         egl_drivers="$egl_drivers builtin:egl_dri2"
2214     fi
2215
2216     if test "x$enable_gallium_egl" = xyes; then
2217         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2218         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2219     else
2220         echo "        EGL drivers:    $egl_drivers"
2221     fi
2222 fi
2223
2224 echo ""
2225 if test "x$MESA_LLVM" = x1; then
2226     echo "        llvm:            yes"
2227     echo "        llvm-config:     $LLVM_CONFIG"
2228     echo "        llvm-version:    $LLVM_VERSION"
2229 else
2230     echo "        llvm:            no"
2231 fi
2232
2233 echo ""
2234 if test -n "$with_gallium_drivers"; then
2235     echo "        Gallium:         yes"
2236     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2237     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2238     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2239     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2240 else
2241     echo "        Gallium:         no"
2242 fi
2243
2244
2245 dnl Libraries
2246 echo ""
2247 echo "        Shared libs:     $enable_shared"
2248 echo "        Static libs:     $enable_static"
2249 echo "        Shared-glapi:    $enable_shared_glapi"
2250
2251 dnl Compiler options
2252 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2253 cflags=`echo $CFLAGS | \
2254     $SED 's/^ *//;s/  */ /;s/ *$//'`
2255 cxxflags=`echo $CXXFLAGS | \
2256     $SED 's/^ *//;s/  */ /;s/ *$//'`
2257 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2258 echo ""
2259 echo "        CFLAGS:          $cflags"
2260 echo "        CXXFLAGS:        $cxxflags"
2261 echo "        Macros:          $defines"
2262 echo ""
2263 if test "x$MESA_LLVM" = x1; then
2264     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2265     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2266     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2267     echo ""
2268 fi
2269 echo "        PYTHON2:         $PYTHON2"
2270
2271 echo ""
2272 echo "        Run '${MAKE-make}' to build Mesa"
2273 echo ""