configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.38
  32 LIBDRM_INTEL_REQUIRED=2.4.37
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  35 DRI2PROTO_REQUIRED=2.6
  36 GLPROTO_REQUIRED=1.4.14
  37 LIBDRM_XORG_REQUIRED=2.4.24
  38 LIBKMS_XORG_REQUIRED=1.0.0
  39
  40 dnl Check for progs
  41 AC_PROG_CPP
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AM_PROG_AS
  46 AC_CHECK_PROGS([MAKE], [gmake make])
  47 AC_CHECK_PROGS([PYTHON2], [python2 python])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50 AC_PATH_PROG([MKDEP], [makedepend])
  51
  52 if test "x$MKDEP" = "x"; then
  53     AC_MSG_ERROR([makedepend is required to build Mesa])
  54 fi
  55
  56 AC_PROG_YACC
  57 AC_PATH_PROG([YACC_INST], $YACC)
  58 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  59     if test -z "$YACC_INST"; then
  60         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  61     fi
  62 fi
  63 AC_PROG_LEX
  64
  65 AC_PATH_PROG([PERL], [perl])
  66
  67 AC_CHECK_PROG(INDENT, indent, indent, cat)
  68 if test "x$INDENT" != "xcat"; then
  69     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  70 fi
  71
  72 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  73 dnl configuration in that case.
  74 AC_PROG_INSTALL
  75 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122
 123 MKDEP_OPTIONS=-fdepend
 124 dnl Ask gcc where it's keeping its secret headers
 125 if test "x$GCC" = xyes; then
 126     for dir in include include-fixed; do
 127         GCC_INCLUDES=`$CC -print-file-name=$dir`
 128         if test "x$GCC_INCLUDES" != x && \
 129            test "$GCC_INCLUDES" != "$dir" && \
 130            test -d "$GCC_INCLUDES"; then
 131             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 132         fi
 133     done
 134 fi
 135 AC_SUBST([MKDEP_OPTIONS])
 136
 137 dnl Make sure the pkg-config macros are defined
 138 m4_ifndef([PKG_PROG_PKG_CONFIG],
 139     [m4_fatal([Could not locate the pkg-config autoconf macros.
 140   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 141   are in a different location, try setting the environment variable
 142   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 143 PKG_PROG_PKG_CONFIG()
 144
 145 dnl LIB_DIR - library basename
 146 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 147 AC_SUBST([LIB_DIR])
 148
 149 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 150 _SAVE_LDFLAGS="$LDFLAGS"
 151 _SAVE_CPPFLAGS="$CPPFLAGS"
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DPTHREADS"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     CFLAGS="$CFLAGS -Wall -std=c99"
 171
 172     # Enable -Werror=implicit-function-declaration and
 173     # -Werror=missing-prototypes, if available, or otherwise, just
 174     # -Wmissing-prototypes.  This is particularly useful to avoid
 175     # generating a loadable driver module that has undefined symbols.
 176     save_CFLAGS="$CFLAGS"
 177     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 178     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 179     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 180     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 181                    AC_MSG_RESULT([yes]),
 182                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 183                     AC_MSG_RESULT([no])]);
 184
 185     # Enable -fvisibility=hidden if using a gcc that supports it
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 188     VISIBILITY_CFLAGS="-fvisibility=hidden"
 189     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 191                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 192
 193     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 194     CFLAGS=$save_CFLAGS
 195
 196     # Work around aliasing bugs - developers should comment this out
 197     CFLAGS="$CFLAGS -fno-strict-aliasing"
 198
 199     # gcc's builtin memcmp is slower than glibc's
 200     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 201     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 202 fi
 203 if test "x$GXX" = xyes; then
 204     CXXFLAGS="$CXXFLAGS -Wall"
 205
 206     # Enable -fvisibility=hidden if using a gcc that supports it
 207     save_CXXFLAGS="$CXXFLAGS"
 208     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 209     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 210     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 211     AC_LANG_PUSH([C++])
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 213                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 214     AC_LANG_POP([C++])
 215
 216     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 217     CXXFLAGS=$save_CXXFLAGS
 218
 219     # Work around aliasing bugs - developers should comment this out
 220     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 221
 222     # gcc's builtin memcmp is slower than glibc's
 223     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 224     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 225 fi
 226
 227 dnl even if the compiler appears to support it, using visibility attributes isn't
 228 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 229 case "$host_os" in
 230 cygwin*)
 231     VISIBILITY_CFLAGS=""
 232     VISIBILITY_CXXFLAGS=""
 233     ;;
 234 esac
 235
 236 AC_SUBST([VISIBILITY_CFLAGS])
 237 AC_SUBST([VISIBILITY_CXXFLAGS])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 dnl
 287 dnl mklib options
 288 dnl
 289 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 290 if test "$enable_static" = yes; then
 291     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 292 fi
 293 AC_SUBST([MKLIB_OPTIONS])
 294
 295 dnl
 296 dnl other compiler options
 297 dnl
 298 AC_ARG_ENABLE([debug],
 299     [AS_HELP_STRING([--enable-debug],
 300         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 301     [enable_debug="$enableval"],
 302     [enable_debug=no]
 303 )
 304 if test "x$enable_debug" = xyes; then
 305     DEFINES="$DEFINES -DDEBUG"
 306     if test "x$GCC" = xyes; then
 307         CFLAGS="$CFLAGS -g"
 308     fi
 309     if test "x$GXX" = xyes; then
 310         CXXFLAGS="$CXXFLAGS -g"
 311     fi
 312 fi
 313
 314 dnl
 315 dnl library names
 316 dnl
 317 LIB_PREFIX_GLOB='lib'
 318 LIB_VERSION_SEPARATOR='.'
 319 if test "$enable_static" = yes; then
 320     LIB_EXTENSION='a'
 321 else
 322     case "$host_os" in
 323     darwin* )
 324         LIB_EXTENSION='dylib' ;;
 325     cygwin* )
 326         dnl prefix can be 'cyg' or 'lib'
 327         LIB_PREFIX_GLOB='???'
 328         LIB_VERSION_SEPARATOR='-'
 329         LIB_EXTENSION='dll' ;;
 330     aix* )
 331         LIB_EXTENSION='a' ;;
 332     * )
 333         LIB_EXTENSION='so' ;;
 334     esac
 335 fi
 336 AC_ARG_WITH([gl-lib-name],
 337   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 338     [specify GL library name @<:@default=GL@:>@])],
 339   [GL_LIB=$withval],
 340   [GL_LIB=GL])
 341 AC_ARG_WITH([glu-lib-name],
 342   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 343     [specify GLU library name @<:@default=GLU@:>@])],
 344   [GLU_LIB=$withval],
 345   [GLU_LIB=GLU])
 346 AC_ARG_WITH([osmesa-lib-name],
 347   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 348     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 349   [OSMESA_LIB=$withval],
 350   [OSMESA_LIB=OSMesa])
 351 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 352 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 353 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 354
 355 dnl
 356 dnl Mangled Mesa support
 357 dnl
 358 AC_ARG_ENABLE([mangling],
 359   [AS_HELP_STRING([--enable-mangling],
 360     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 361   [enable_mangling="${enableval}"],
 362   [enable_mangling=no]
 363 )
 364 if test "x${enable_mangling}" = "xyes" ; then
 365   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 366   GL_LIB="Mangled${GL_LIB}"
 367   GLU_LIB="Mangled${GLU_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([GLU_LIB])
 372 AC_SUBST([OSMESA_LIB])
 373
 374 dnl
 375 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 376 dnl
 377 AC_ARG_ENABLE([texture-float],
 378     [AS_HELP_STRING([--enable-texture-float],
 379         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 380     [enable_texture_float="$enableval"],
 381     [enable_texture_float=no]
 382 )
 383 if test "x$enable_texture_float" = xyes; then
 384     AC_MSG_WARN([Floating-point textures enabled.])
 385     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 386     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 387 fi
 388
 389 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 390 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 391 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 392 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 393 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 394 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 395 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 396 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 397
 398 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406
 407 AC_SUBST([GL_LIB_NAME])
 408 AC_SUBST([GLU_LIB_NAME])
 409 AC_SUBST([OSMESA_LIB_NAME])
 410 AC_SUBST([EGL_LIB_NAME])
 411 AC_SUBST([GLESv1_CM_LIB_NAME])
 412 AC_SUBST([GLESv2_LIB_NAME])
 413 AC_SUBST([VG_LIB_NAME])
 414 AC_SUBST([GLAPI_LIB_NAME])
 415
 416 AC_SUBST([GL_LIB_GLOB])
 417 AC_SUBST([GLU_LIB_GLOB])
 418 AC_SUBST([EGL_LIB_GLOB])
 419 AC_SUBST([GLESv1_CM_LIB_GLOB])
 420 AC_SUBST([GLESv2_LIB_GLOB])
 421 AC_SUBST([VG_LIB_GLOB])
 422 AC_SUBST([GLAPI_LIB_GLOB])
 423
 424 dnl
 425 dnl Arch/platform-specific settings
 426 dnl
 427 AC_ARG_ENABLE([asm],
 428     [AS_HELP_STRING([--disable-asm],
 429         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 430     [enable_asm="$enableval"],
 431     [enable_asm=yes]
 432 )
 433 asm_arch=""
 434 MESA_ASM_FILES=""
 435 AC_MSG_CHECKING([whether to enable assembly])
 436 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 437 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 438 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 439     case "$host_cpu" in
 440     i?86 | x86_64)
 441         enable_asm=no
 442         AC_MSG_RESULT([no, cross compiling])
 443         ;;
 444     esac
 445 fi
 446 # check for supported arches
 447 if test "x$enable_asm" = xyes; then
 448     case "$host_cpu" in
 449     i?86)
 450         case "$host_os" in
 451         linux* | *freebsd* | dragonfly* | *netbsd*)
 452             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 453             ;;
 454         esac
 455         ;;
 456     x86_64)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd*)
 459             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 460             ;;
 461         esac
 462         ;;
 463     sparc*)
 464         case "$host_os" in
 465         linux*)
 466             asm_arch=sparc
 467             ;;
 468         esac
 469         ;;
 470     esac
 471
 472     case "$asm_arch" in
 473     x86)
 474         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 475         MESA_ASM_FILES='$(X86_FILES)'
 476         AC_MSG_RESULT([yes, x86])
 477         ;;
 478     x86_64)
 479         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 480         MESA_ASM_FILES='$(X86_64_FILES)'
 481         AC_MSG_RESULT([yes, x86_64])
 482         ;;
 483     sparc)
 484         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 485         MESA_ASM_FILES='$(SPARC_FILES)'
 486         AC_MSG_RESULT([yes, sparc])
 487         ;;
 488     *)
 489         AC_MSG_RESULT([no, platform not supported])
 490         ;;
 491     esac
 492 fi
 493 AC_SUBST([MESA_ASM_FILES])
 494
 495 dnl PIC code macro
 496 MESA_PIC_FLAGS
 497
 498 dnl Check to see if dlopen is in default libraries (like Solaris, which
 499 dnl has it in libc), or if libdl is needed to get it.
 500 AC_CHECK_FUNC([dlopen], [],
 501     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 502 AC_SUBST([DLOPEN_LIBS])
 503
 504 dnl See if posix_memalign is available
 505 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 506
 507 dnl SELinux awareness.
 508 AC_ARG_ENABLE([selinux],
 509     [AS_HELP_STRING([--enable-selinux],
 510         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 511     [MESA_SELINUX="$enableval"],
 512     [MESA_SELINUX=no])
 513 if test "x$enable_selinux" = "xyes"; then
 514     AC_CHECK_HEADER([selinux/selinux.h],[],
 515                     [AC_MSG_ERROR([SELinux headers not found])])
 516     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 517                  [AC_MSG_ERROR([SELinux library not found])])
 518     SELINUX_LIBS="-lselinux"
 519     DEFINES="$DEFINES -DMESA_SELINUX"
 520 fi
 521
 522 dnl Options for APIs
 523 AC_ARG_ENABLE([opengl],
 524     [AS_HELP_STRING([--disable-opengl],
 525         [disable support for standard OpenGL API @<:@default=no@:>@])],
 526     [enable_opengl="$enableval"],
 527     [enable_opengl=yes])
 528 AC_ARG_ENABLE([gles1],
 529     [AS_HELP_STRING([--enable-gles1],
 530         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 531     [enable_gles1="$enableval"],
 532     [enable_gles1=no])
 533 AC_ARG_ENABLE([gles2],
 534     [AS_HELP_STRING([--enable-gles2],
 535         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 536     [enable_gles2="$enableval"],
 537     [enable_gles2=no])
 538 AC_ARG_ENABLE([openvg],
 539     [AS_HELP_STRING([--enable-openvg],
 540         [enable support for OpenVG API @<:@default=no@:>@])],
 541     [enable_openvg="$enableval"],
 542     [enable_openvg=no])
 543
 544 AC_ARG_ENABLE([dri],
 545     [AS_HELP_STRING([--enable-dri],
 546         [enable DRI modules @<:@default=auto@:>@])],
 547     [enable_dri="$enableval"],
 548     [enable_dri=auto])
 549 AC_ARG_ENABLE([glx],
 550     [AS_HELP_STRING([--enable-glx],
 551         [enable GLX library @<:@default=auto@:>@])],
 552     [enable_glx="$enableval"],
 553     [enable_glx=auto])
 554 AC_ARG_ENABLE([osmesa],
 555     [AS_HELP_STRING([--enable-osmesa],
 556         [enable OSMesa library @<:@default=auto@:>@])],
 557     [enable_osmesa="$enableval"],
 558     [enable_osmesa=auto])
 559 AC_ARG_ENABLE([egl],
 560     [AS_HELP_STRING([--disable-egl],
 561         [disable EGL library @<:@default=enabled@:>@])],
 562     [enable_egl="$enableval"],
 563     [enable_egl=yes])
 564
 565 AC_ARG_ENABLE([xorg],
 566     [AS_HELP_STRING([--enable-xorg],
 567         [enable support for X.Org DDX API @<:@default=no@:>@])],
 568     [enable_xorg="$enableval"],
 569     [enable_xorg=no])
 570 AC_ARG_ENABLE([xa],
 571     [AS_HELP_STRING([--enable-xa],
 572         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 573     [enable_xa="$enableval"],
 574     [enable_xa=no])
 575 AC_ARG_ENABLE([d3d1x],
 576     [AS_HELP_STRING([--enable-d3d1x],
 577         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 578     [enable_d3d1x="$enableval"],
 579     [enable_d3d1x=no])
 580 AC_ARG_ENABLE([gbm],
 581    [AS_HELP_STRING([--enable-gbm],
 582          [enable gbm library @<:@default=auto@:>@])],
 583    [enable_gbm="$enableval"],
 584    [enable_gbm=auto])
 585
 586 AC_ARG_ENABLE([xvmc],
 587    [AS_HELP_STRING([--enable-xvmc],
 588          [enable xvmc library @<:@default=auto@:>@])],
 589    [enable_xvmc="$enableval"],
 590    [enable_xvmc=auto])
 591 AC_ARG_ENABLE([vdpau],
 592    [AS_HELP_STRING([--enable-vdpau],
 593          [enable vdpau library @<:@default=auto@:>@])],
 594    [enable_vdpau="$enableval"],
 595    [enable_vdpau=auto])
 596 AC_ARG_ENABLE([va],
 597    [AS_HELP_STRING([--enable-va],
 598          [enable va library @<:@default=auto@:>@])],
 599    [enable_va="$enableval"],
 600    [enable_va=auto])
 601 AC_ARG_ENABLE([opencl],
 602    [AS_HELP_STRING([--enable-opencl],
 603          [enable OpenCL library @<:@default=no@:>@])],
 604    [enable_opencl="$enableval"],
 605    [enable_opencl=no])
 606 AC_ARG_ENABLE([xlib_glx],
 607     [AS_HELP_STRING([--enable-xlib-glx],
 608         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 609     [enable_xlib_glx="$enableval"],
 610     [enable_xlib_glx=auto])
 611 AC_ARG_ENABLE([gallium_egl],
 612     [AS_HELP_STRING([--enable-gallium-egl],
 613         [enable optional EGL state tracker (not required
 614          for EGL support in Gallium with OpenGL and OpenGL ES)
 615          @<:@default=disable@:>@])],
 616     [enable_gallium_egl="$enableval"],
 617     [enable_gallium_egl=no])
 618 AC_ARG_ENABLE([gallium_gbm],
 619     [AS_HELP_STRING([--enable-gallium-gbm],
 620         [enable optional gbm state tracker (not required for
 621          gbm support in Gallium)
 622          @<:@default=auto@:>@])],
 623     [enable_gallium_gbm="$enableval"],
 624     [enable_gallium_gbm=auto])
 625
 626 AC_ARG_ENABLE([r600-llvm-compiler],
 627     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 628         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 629     [enable_r600_llvm="$enableval"],
 630     [enable_r600_llvm=no])
 631
 632 AC_ARG_ENABLE([gallium_tests],
 633     [AS_HELP_STRING([--enable-gallium-tests],
 634         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 635     [enable_gallium_tests="$enableval"],
 636     [enable_gallium_tests=no])
 637
 638 # Option for Gallium drivers
 639 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 640
 641 AC_ARG_WITH([gallium-drivers],
 642     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 643         [comma delimited Gallium drivers list, e.g.
 644         "i915,nouveau,r300,r600,svga,swrast"
 645         @<:@default=r300,r600,swrast@:>@])],
 646     [with_gallium_drivers="$withval"],
 647     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 648
 649 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 650 # here so that the script doesn't choke on an unknown driver name later.
 651 case "$with_gallium_drivers" in
 652     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 653     no) with_gallium_drivers='' ;;
 654 esac
 655
 656 if test "x$enable_opengl" = xno -a \
 657         "x$enable_gles1" = xno -a \
 658         "x$enable_gles2" = xno -a \
 659         "x$enable_openvg" = xno -a \
 660         "x$enable_xorg" = xno -a \
 661         "x$enable_xa" = xno -a \
 662         "x$enable_d3d1x" = xno -a \
 663         "x$enable_xvmc" = xno -a \
 664         "x$enable_vdpau" = xno -a \
 665         "x$enable_va" = xno -a \
 666         "x$enable_opencl" = xno; then
 667     AC_MSG_ERROR([at least one API should be enabled])
 668 fi
 669
 670 API_DEFINES=""
 671 if test "x$enable_opengl" = xno; then
 672     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 673 else
 674     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 675 fi
 676 if test "x$enable_gles1" = xyes; then
 677     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 678 fi
 679 if test "x$enable_gles2" = xyes; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 681 fi
 682 AC_SUBST([API_DEFINES])
 683
 684 AC_ARG_ENABLE([shared-glapi],
 685     [AS_HELP_STRING([--enable-shared-glapi],
 686         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 687     [enable_shared_glapi="$enableval"],
 688     [enable_shared_glapi=yes])
 689
 690 SHARED_GLAPI="0"
 691 if test "x$enable_shared_glapi" = xyes; then
 692     SHARED_GLAPI="1"
 693     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 694     # the remap table)
 695     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 696     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 697 fi
 698 AC_SUBST([SHARED_GLAPI])
 699 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 700
 701 dnl Driver configuration. Options are xlib, dri and osmesa.
 702 default_driver="xlib"
 703
 704 case "$host_os" in
 705 linux*)
 706     default_driver="dri"
 707     ;;
 708 *freebsd* | dragonfly* | *netbsd*)
 709     case "$host_cpu" in
 710     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 711     esac
 712     ;;
 713 esac
 714
 715 if test "x$enable_opengl" = xno; then
 716     default_driver="no"
 717 fi
 718
 719 # map $default_driver to APIs
 720 if test "x$enable_dri" = xauto; then
 721     case "x$default_driver" in
 722     xdri) enable_dri=yes ;;
 723     *)    enable_dri=no ;;
 724     esac
 725 fi
 726
 727 if test "x$enable_glx" = xauto; then
 728     case "x$default_driver" in
 729     xdri|xxlib) enable_glx=yes ;;
 730     *)          enable_glx=no ;;
 731     esac
 732 fi
 733
 734 if test "x$enable_osmesa" = xauto; then
 735     case "x$default_driver" in
 736     xxlib|xosmesa) enable_osmesa=yes ;;
 737     *)             enable_osmesa=no ;;
 738     esac
 739 fi
 740
 741 if test "x$enable_xlib_glx" = xauto; then
 742     case "x$default_driver" in
 743     xxlib) enable_xlib_glx=yes ;;
 744     *)     enable_xlib_glx=no ;;
 745     esac
 746 fi
 747
 748 if test "x$enable_glx" = xno; then
 749     enable_xlib_glx=no
 750 fi
 751
 752 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 753
 754 dnl
 755 dnl Driver specific build directories
 756 dnl
 757
 758 dnl this variable will be prepended to SRC_DIRS and is not exported
 759 CORE_DIRS=""
 760
 761 SRC_DIRS="gtest"
 762 GLU_DIRS="sgi"
 763 GALLIUM_DIRS="auxiliary drivers state_trackers"
 764 GALLIUM_TARGET_DIRS=""
 765 GALLIUM_WINSYS_DIRS="sw"
 766 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 767 GALLIUM_STATE_TRACKERS_DIRS=""
 768
 769 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 770 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 771 x*yes*)
 772     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 773     ;;
 774 esac
 775
 776 # build glapi if OpenGL is enabled
 777 if test "x$enable_opengl" = xyes; then
 778     CORE_DIRS="$CORE_DIRS mapi/glapi"
 779 fi
 780
 781 # build es1api if OpenGL ES 1.x is enabled
 782 if test "x$enable_gles1" = xyes; then
 783     CORE_DIRS="$CORE_DIRS mapi/es1api"
 784 fi
 785
 786 # build es2api if OpenGL ES 2.x is enabled
 787 if test "x$enable_gles2" = xyes; then
 788     CORE_DIRS="$CORE_DIRS mapi/es2api"
 789 fi
 790
 791 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 792 case "x$enable_opengl$enable_gles1$enable_gles2" in
 793 x*yes*)
 794     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 795     ;;
 796 esac
 797
 798 case "x$enable_glx$enable_xlib_glx" in
 799 xyesyes)
 800     DRIVER_DIRS="$DRIVER_DIRS x11"
 801     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 802     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 803     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 804     HAVE_WINSYS_XLIB="yes"
 805     ;;
 806 xyesno)
 807     # DRI-based GLX
 808     SRC_DIRS="$SRC_DIRS glx"
 809     ;;
 810 esac
 811
 812 if test "x$enable_dri" = xyes; then
 813     DRIVER_DIRS="$DRIVER_DIRS dri"
 814
 815     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 816     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 817     HAVE_ST_DRI="yes"
 818 fi
 819
 820 if test "x$enable_osmesa" = xyes; then
 821     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 822 fi
 823
 824 AC_SUBST([SRC_DIRS])
 825 AC_SUBST([GLU_DIRS])
 826 AC_SUBST([DRIVER_DIRS])
 827 AC_SUBST([GALLIUM_DIRS])
 828 AC_SUBST([GALLIUM_TARGET_DIRS])
 829 AC_SUBST([GALLIUM_WINSYS_DIRS])
 830 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 831 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 832 AC_SUBST([MESA_LLVM])
 833
 834 # Check for libdrm
 835 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 836                   [have_libdrm=yes], [have_libdrm=no])
 837
 838 if test "x$enable_dri" = xyes; then
 839     # DRI must be shared, I think
 840     if test "$enable_static" = yes; then
 841         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 842     fi
 843
 844     # not a hard requirement as swrast does not depend on it
 845     if test "x$have_libdrm" = xyes; then
 846         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 847     fi
 848 fi
 849
 850 dnl Find out if X is available.
 851 PKG_CHECK_MODULES([X11], [x11])
 852
 853 dnl Try to tell the user that the --x-* options are only used when
 854 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 855 m4_divert_once([HELP_BEGIN],
 856 [These options are only used when the X libraries cannot be found by the
 857 pkg-config utility.])
 858
 859 dnl We need X for xlib and dri, so bomb now if it's not found
 860 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 861     AC_MSG_ERROR([X11 development libraries needed for GLX])
 862 fi
 863
 864 if test "x$enable_glx" = xyes; then
 865     DEFINES="$DEFINES -DUSE_XCB"
 866 fi
 867
 868 dnl Direct rendering or just indirect rendering
 869 case "$host_os" in
 870 gnu*)
 871     dnl Disable by default on GNU/Hurd
 872     driglx_direct_default="no"
 873     ;;
 874 cygwin*)
 875     dnl Disable by default on cygwin
 876     driglx_direct_default="no"
 877     ;;
 878 *)
 879     driglx_direct_default="yes"
 880     ;;
 881 esac
 882 AC_ARG_ENABLE([driglx-direct],
 883     [AS_HELP_STRING([--disable-driglx-direct],
 884         [enable direct rendering in GLX and EGL for DRI \
 885             @<:@default=auto@:>@])],
 886     [driglx_direct="$enableval"],
 887     [driglx_direct="$driglx_direct_default"])
 888
 889 dnl
 890 dnl libGL configuration per driver
 891 dnl
 892 case "x$enable_glx$enable_xlib_glx" in
 893 xyesyes)
 894     # Xlib-based GLX
 895     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 896     GL_PC_REQ_PRIV="x11 xext"
 897     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 898     GL_LIB_DEPS="$XLIBGL_LIBS"
 899     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 900     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 901     ;;
 902 xyesno)
 903     # DRI-based GLX
 904     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 905     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 906     if test x"$driglx_direct" = xyes; then
 907         if test "x$have_libdrm" != xyes; then
 908             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 909         fi
 910         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 911         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 912     fi
 913
 914     # find the DRI deps for libGL
 915     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 916
 917     # add xf86vidmode if available
 918     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 919     if test "$HAVE_XF86VIDMODE" = yes ; then
 920         dri_modules="$dri_modules xxf86vm"
 921     fi
 922
 923     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 924     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 925     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 926     GL_LIB_DEPS="$DRIGL_LIBS"
 927
 928     # need DRM libs, -lpthread, etc.
 929     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 930     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 931     ;;
 932 esac
 933
 934 # This is outside the case (above) so that it is invoked even for non-GLX
 935 # builds.
 936 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 937
 938 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 939 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 940 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 941 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 942
 943 AC_SUBST([GL_LIB_DEPS])
 944 AC_SUBST([GL_PC_REQ_PRIV])
 945 AC_SUBST([GL_PC_LIB_PRIV])
 946 AC_SUBST([GL_PC_CFLAGS])
 947 AC_SUBST([DRI_PC_REQ_PRIV])
 948 AC_SUBST([GLESv1_CM_LIB_DEPS])
 949 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 950 AC_SUBST([GLESv2_LIB_DEPS])
 951 AC_SUBST([GLESv2_PC_LIB_PRIV])
 952
 953 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
 954 AC_SUBST([GLAPI_LIB_DEPS])
 955
 956
 957 dnl dri libraries are linking with mesa
 958 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.la'
 959 GALLIUM_DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
 960
 961 dnl ... or dricore?
 962 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
 963     DRI_LIB_DEPS="\$(TOP)/src/mesa/libdricore/libdricore${VERSION}.la"
 964     GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
 965     HAVE_DRICORE=yes
 966 fi
 967 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
 968
 969 AC_SUBST([HAVE_XF86VIDMODE])
 970
 971 dnl
 972 dnl More GLX setup
 973 dnl
 974 case "x$enable_glx$enable_xlib_glx" in
 975 xyesyes)
 976     DEFINES="$DEFINES -DUSE_XSHM"
 977     ;;
 978 xyesno)
 979     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 980     if test "x$driglx_direct" = xyes; then
 981         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 982     fi
 983     ;;
 984 esac
 985
 986 dnl
 987 dnl TLS detection
 988 dnl
 989
 990 AC_ARG_ENABLE([glx-tls],
 991     [AS_HELP_STRING([--enable-glx-tls],
 992         [enable TLS support in GLX @<:@default=disabled@:>@])],
 993     [GLX_USE_TLS="$enableval"],
 994     [GLX_USE_TLS=no])
 995 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 996
 997 AS_IF([test "x$GLX_USE_TLS" = xyes],
 998       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 999
1000 dnl
1001 dnl More DRI setup
1002 dnl
1003 dnl Directory for DRI drivers
1004 AC_ARG_WITH([dri-driverdir],
1005     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1006         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1007     [DRI_DRIVER_INSTALL_DIR="$withval"],
1008     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1009 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1010 dnl Extra search path for DRI drivers
1011 AC_ARG_WITH([dri-searchpath],
1012     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1013         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1014     [DRI_DRIVER_SEARCH_DIR="$withval"],
1015     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1016 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1017 dnl Which drivers to build - default is chosen by platform
1018 AC_ARG_WITH([dri-drivers],
1019     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1020         [comma delimited DRI drivers list, e.g.
1021         "swrast,i965,radeon" @<:@default=auto@:>@])],
1022     [with_dri_drivers="$withval"],
1023     [with_dri_drivers=yes])
1024 if test "x$with_dri_drivers" = x; then
1025     with_dri_drivers=no
1026 fi
1027
1028 dnl If $with_dri_drivers is yes, directories will be added through
1029 dnl platform checks
1030 DRI_DIRS=""
1031 case "$with_dri_drivers" in
1032 no) ;;
1033 yes)
1034     # classic DRI drivers require FEATURE_GL to build
1035     if test "x$enable_opengl" = xyes; then
1036         DRI_DIRS="yes"
1037     fi
1038     ;;
1039 *)
1040     # verify the requested driver directories exist
1041     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1042     for driver in $dri_drivers; do
1043         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1044             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1045     done
1046     DRI_DIRS="$dri_drivers"
1047     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1048         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1049     fi
1050     ;;
1051 esac
1052
1053 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1054 if test "x$enable_dri" = xyes; then
1055     # Platform specific settings and drivers to build
1056     case "$host_os" in
1057     linux*)
1058         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1059         DEFINES="$DEFINES -DHAVE_ALIAS"
1060
1061         case "$host_cpu" in
1062         x86_64)
1063             if test "x$DRI_DIRS" = "xyes"; then
1064                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1065             fi
1066             ;;
1067         powerpc*)
1068             # Build only the drivers for cards that exist on PowerPC.
1069             if test "x$DRI_DIRS" = "xyes"; then
1070                 DRI_DIRS="r200 radeon swrast"
1071             fi
1072             ;;
1073         sparc*)
1074             # Build only the drivers for cards that exist on sparc
1075             if test "x$DRI_DIRS" = "xyes"; then
1076                 DRI_DIRS="r200 radeon swrast"
1077             fi
1078             ;;
1079         esac
1080         ;;
1081     freebsd* | dragonfly* | *netbsd*)
1082         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1083         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1084
1085         if test "x$DRI_DIRS" = "xyes"; then
1086             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1087         fi
1088         ;;
1089     gnu*)
1090         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1091         DEFINES="$DEFINES -DHAVE_ALIAS"
1092         ;;
1093     solaris*)
1094         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1095         ;;
1096     cygwin*)
1097         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1098         if test "x$DRI_DIRS" = "xyes"; then
1099             DRI_DIRS="swrast"
1100         fi
1101         ;;
1102     esac
1103
1104     # default drivers
1105     if test "x$DRI_DIRS" = "xyes"; then
1106         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1107     fi
1108
1109     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1110
1111     # Check for expat
1112     if test "x$enable_dri" = xyes; then
1113         EXPAT_INCLUDES=""
1114         EXPAT_LIB=-lexpat
1115         AC_ARG_WITH([expat],
1116             [AS_HELP_STRING([--with-expat=DIR],
1117                 [expat install directory])],[
1118             EXPAT_INCLUDES="-I$withval/include"
1119             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1120             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1121             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1122             ])
1123         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1124         save_LIBS="$LIBS"
1125         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1126             [AC_MSG_ERROR([Expat required for DRI.])])
1127         LIBS="$save_LIBS"
1128     fi
1129
1130     # if we are building any dri driver other than swrast ...
1131     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1132         # ... libdrm is required
1133         if test "x$have_libdrm" != xyes; then
1134             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1135         fi
1136         # ... and build dricommon
1137         HAVE_COMMON_DRI=yes
1138     fi
1139
1140     # put all the necessary libs together
1141     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1142     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1143 fi
1144 AC_SUBST([DRI_DIRS])
1145 AC_SUBST([EXPAT_INCLUDES])
1146 AC_SUBST([DRI_LIB_DEPS])
1147 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1148
1149 case $DRI_DIRS in
1150 *i915*|*i965*)
1151     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1152
1153     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1154         case $d in
1155         i915)
1156             HAVE_I915_DRI=yes;
1157             ;;
1158         i965)
1159             HAVE_I965_DRI=yes;
1160             ;;
1161         esac
1162     done
1163
1164     ;;
1165 esac
1166
1167 case $DRI_DIRS in
1168 *nouveau*)
1169     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1170     HAVE_NOUVEAU_DRI=yes;
1171     ;;
1172 esac
1173
1174 case $DRI_DIRS in
1175 *radeon*|*r200*)
1176     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1177
1178     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1179         case $d in
1180         radeon)
1181             HAVE_RADEON_DRI=yes;
1182             ;;
1183         r200)
1184             HAVE_R200_DRI=yes;
1185             ;;
1186         esac
1187     done
1188
1189     ;;
1190 esac
1191
1192 case $DRI_DIRS in
1193 *swrast*)
1194     HAVE_SWRAST_DRI=yes;
1195     ;;
1196 esac
1197
1198 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1199 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1200 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1201 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1202 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1203 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1204 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1205
1206 dnl
1207 dnl OSMesa configuration
1208 dnl
1209
1210 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1211 AC_ARG_WITH([osmesa-bits],
1212     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1213         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1214     [osmesa_bits="$withval"],
1215     [osmesa_bits=8])
1216 if test "x$osmesa_bits" != x8; then
1217     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1218         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1219         osmesa_bits=8
1220     fi
1221 fi
1222 case "x$osmesa_bits" in
1223 x8)
1224     OSMESA_LIB="${OSMESA_LIB}"
1225     ;;
1226 x16|x32)
1227     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1228     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1229     ;;
1230 *)
1231     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1232     ;;
1233 esac
1234
1235 if test "x$enable_osmesa" = xyes; then
1236     # only link libraries with osmesa if shared
1237     if test "$enable_static" = no; then
1238         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1239     else
1240         OSMESA_LIB_DEPS=""
1241     fi
1242     OSMESA_MESA_DEPS=""
1243     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1244 fi
1245
1246 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1247
1248 AC_SUBST([OSMESA_LIB_DEPS])
1249 AC_SUBST([OSMESA_MESA_DEPS])
1250 AC_SUBST([OSMESA_PC_REQ])
1251 AC_SUBST([OSMESA_PC_LIB_PRIV])
1252 AC_SUBST([OSMESA_VERSION])
1253
1254 dnl
1255 dnl gbm configuration
1256 dnl
1257 if test "x$enable_gbm" = xauto; then
1258     case "$with_egl_platforms" in
1259         *drm*)
1260             enable_gbm=yes ;;
1261          *)
1262             enable_gbm=no ;;
1263     esac
1264 fi
1265 if test "x$enable_gbm" = xyes; then
1266     SRC_DIRS="$SRC_DIRS gbm"
1267
1268     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1269                       AC_MSG_ERROR([gbm needs udev]))
1270
1271     if test "x$enable_dri" = xyes; then
1272         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1273         if test "$SHARED_GLAPI" -eq 0; then
1274             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1275         fi
1276     fi
1277 fi
1278 GBM_PC_REQ_PRIV="libudev"
1279 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1280 AC_SUBST([GBM_PC_REQ_PRIV])
1281 AC_SUBST([GBM_PC_LIB_PRIV])
1282
1283 dnl
1284 dnl EGL configuration
1285 dnl
1286 EGL_CLIENT_APIS=""
1287
1288 if test "x$enable_egl" = xyes; then
1289     SRC_DIRS="$SRC_DIRS egl"
1290     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1291
1292     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1293
1294     if test "$enable_static" != yes; then
1295         # build egl_glx when libGL is built
1296         if test "x$enable_glx" = xyes; then
1297             HAVE_EGL_DRIVER_GLX=1
1298         fi
1299
1300         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1301                           [have_libudev=yes],[have_libudev=no])
1302         if test "$have_libudev" = yes; then
1303             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1304         fi
1305
1306         if test "x$enable_dri" = xyes; then
1307             HAVE_EGL_DRIVER_DRI2=1
1308         fi
1309
1310     fi
1311 fi
1312 AC_SUBST([EGL_LIB_DEPS])
1313
1314 dnl
1315 dnl EGL Gallium configuration
1316 dnl
1317 if test "x$enable_gallium_egl" = xyes; then
1318     if test "x$with_gallium_drivers" = x; then
1319         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1320     fi
1321     if test "x$enable_egl" = xno; then
1322         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1323     fi
1324     if test "x$have_libdrm" != xyes; then
1325         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1326     fi
1327
1328     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1329     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1330     HAVE_ST_EGL="yes"
1331 fi
1332
1333 dnl
1334 dnl gbm Gallium configuration
1335 dnl
1336 if test "x$enable_gallium_gbm" = xauto; then
1337     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1338         yesyesyes*drm*)
1339             enable_gallium_gbm=yes ;;
1340          *)
1341             enable_gallium_gbm=no ;;
1342     esac
1343 fi
1344 if test "x$enable_gallium_gbm" = xyes; then
1345     if test "x$with_gallium_drivers" = x; then
1346         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1347     fi
1348     if test "x$enable_gbm" = xno; then
1349         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1350     fi
1351     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1352     if test "x$enable_dri" = xno; then
1353         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1354     fi
1355
1356     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1357     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1358     HAVE_ST_GBM="yes"
1359     enable_gallium_loader=yes
1360 fi
1361
1362 dnl
1363 dnl X.Org DDX configuration
1364 dnl
1365 if test "x$enable_xorg" = xyes; then
1366     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1367     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1368     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1369     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1370         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1371         HAVE_XEXTPROTO_71="no")
1372     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1373     HAVE_ST_XORG=yes
1374 fi
1375
1376 dnl
1377 dnl XA configuration
1378 dnl
1379 if test "x$enable_xa" = xyes; then
1380 AC_PROG_AWK
1381 AC_PROG_GREP
1382 AC_CHECK_PROG(NM, nm, "nm")
1383 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1384 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1385 enable_xa=no
1386 fi
1387 fi
1388 if test "x$enable_xa" = xyes; then
1389     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1390     HAVE_ST_XA=yes
1391     AC_SUBST(AWK)
1392     AC_SUBST(GREP)
1393     AC_SUBST(NM)
1394 fi
1395
1396 dnl
1397 dnl OpenVG configuration
1398 dnl
1399 VG_LIB_DEPS=""
1400
1401 if test "x$enable_openvg" = xyes; then
1402     if test "x$enable_egl" = xno; then
1403         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1404     fi
1405     if test "x$with_gallium_drivers" = x; then
1406         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1407     fi
1408     if test "x$enable_gallium_egl" = xno; then
1409         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1410     fi
1411
1412     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1413     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1414     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1415     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1416     HAVE_ST_VEGA=yes
1417 fi
1418
1419 dnl
1420 dnl D3D1X configuration
1421 dnl
1422
1423 if test "x$enable_d3d1x" = xyes; then
1424     if test "x$with_gallium_drivers" = x; then
1425         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1426     fi
1427
1428     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1429     HAVE_ST_D3D1X=yes
1430 fi
1431
1432 dnl
1433 dnl Gallium G3DVL configuration
1434 dnl
1435 AC_ARG_ENABLE([gallium-g3dvl],
1436     [AS_HELP_STRING([--enable-gallium-g3dvl],
1437         [build gallium g3dvl @<:@default=disabled@:>@])],
1438     [enable_gallium_g3dvl="$enableval"],
1439     [enable_gallium_g3dvl=no])
1440 if test "x$enable_gallium_g3dvl" = xyes; then
1441     if test "x$with_gallium_drivers" = x; then
1442         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1443     fi
1444
1445     if test "x$enable_xvmc" = xauto; then
1446         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1447     fi
1448
1449     if test "x$enable_vdpau" = xauto; then
1450         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1451     fi
1452
1453     if test "x$enable_va" = xauto; then
1454         #don't enable vaapi state tracker even if package exists
1455         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1456         enable_va=no
1457     fi
1458 fi
1459
1460 if test "x$enable_xvmc" = xyes; then
1461     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1462     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1463     HAVE_ST_XVMC="yes"
1464 fi
1465
1466 if test "x$enable_vdpau" = xyes; then
1467     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1468     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1469     HAVE_ST_VDPAU="yes"
1470 fi
1471
1472 if test "x$enable_va" = xyes; then
1473     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1474     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1475     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1476     HAVE_ST_VA="yes"
1477 fi
1478
1479 dnl
1480 dnl OpenCL configuration
1481 dnl
1482
1483 AC_ARG_WITH([libclc-path],
1484    [AS_HELP_STRING([--with-libclc-path],
1485          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1486    [LIBCLC_PATH="$withval"],
1487    [LIBCLC_PATH=""])
1488
1489 AC_ARG_WITH([clang-libdir],
1490    [AS_HELP_STRING([--with-clang-libdir],
1491          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1492    [CLANG_LIBDIR="$withval"],
1493    [CLANG_LIBDIR=""])
1494
1495 AC_SUBST([LIBCLC_PATH])
1496
1497 if test "x$enable_opencl" = xyes; then
1498     if test "x$with_gallium_drivers" = x; then
1499         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1500     fi
1501
1502     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1503         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1504     fi
1505
1506     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1507     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1508     enable_gallium_loader=yes
1509 fi
1510
1511 dnl
1512 dnl GLU configuration
1513 dnl
1514 AC_ARG_ENABLE([glu],
1515     [AS_HELP_STRING([--disable-glu],
1516         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1517     [enable_glu="$enableval"],
1518     [enable_glu=yes])
1519
1520 if test "x$enable_glu" = xyes; then
1521     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1522         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1523         enable_glu=no
1524     fi
1525 fi
1526
1527 if test "x$enable_glu" = xyes; then
1528     SRC_DIRS="$SRC_DIRS glu"
1529
1530     if test "x$enable_glx" = xno; then
1531         # Link libGLU to libOSMesa instead of libGL
1532         GLU_LIB_DEPS=""
1533         GLU_PC_REQ="osmesa"
1534         if test "$enable_static" = no; then
1535             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1536         else
1537             GLU_MESA_DEPS=""
1538         fi
1539     else
1540         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1541         GLU_PC_REQ="gl"
1542         GLU_PC_LIB_PRIV="-lm"
1543         if test "$enable_static" = no; then
1544             GLU_LIB_DEPS="-lm"
1545             GLU_MESA_DEPS='-l$(GL_LIB)'
1546         else
1547             GLU_LIB_DEPS=""
1548             GLU_MESA_DEPS=""
1549         fi
1550     fi
1551 fi
1552 if test "$enable_static" = no; then
1553     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1554 fi
1555 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1556 AC_SUBST([GLU_LIB_DEPS])
1557 AC_SUBST([GLU_MESA_DEPS])
1558 AC_SUBST([GLU_PC_REQ])
1559 AC_SUBST([GLU_PC_REQ_PRIV])
1560 AC_SUBST([GLU_PC_LIB_PRIV])
1561 AC_SUBST([GLU_PC_CFLAGS])
1562
1563 AC_SUBST([PROGRAM_DIRS])
1564
1565 dnl
1566 dnl Gallium configuration
1567 dnl
1568 if test "x$with_gallium_drivers" != x; then
1569     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1570 fi
1571
1572 AC_SUBST([LLVM_BINDIR])
1573 AC_SUBST([LLVM_CFLAGS])
1574 AC_SUBST([LLVM_CPPFLAGS])
1575 AC_SUBST([LLVM_CXXFLAGS])
1576 AC_SUBST([LLVM_LIBDIR])
1577 AC_SUBST([LLVM_LIBS])
1578 AC_SUBST([LLVM_LDFLAGS])
1579 AC_SUBST([LLVM_INCLUDEDIR])
1580 AC_SUBST([LLVM_VERSION])
1581 AC_SUBST([CLANG_RESOURCE_DIR])
1582
1583 case "x$enable_opengl$enable_gles1$enable_gles2" in
1584 x*yes*)
1585     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1586     ;;
1587 esac
1588
1589 AC_SUBST([VG_LIB_DEPS])
1590 AC_SUBST([EGL_CLIENT_APIS])
1591
1592 dnl
1593 dnl EGL Platforms configuration
1594 dnl
1595 AC_ARG_WITH([egl-platforms],
1596     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1597         [comma delimited native platforms libEGL supports, e.g.
1598         "x11,drm" @<:@default=auto@:>@])],
1599     [with_egl_platforms="$withval"],
1600     [if test "x$enable_egl" = xyes; then
1601         with_egl_platforms="x11"
1602     else
1603         with_egl_platforms=""
1604     fi])
1605
1606 EGL_PLATFORMS=""
1607
1608 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1609     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1610 fi
1611
1612 # Do per-EGL platform setups and checks
1613 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1614 for plat in $egl_platforms; do
1615         case "$plat" in
1616         fbdev|null)
1617                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1618                 ;;
1619
1620         wayland)
1621                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1622                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1623                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1624
1625                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1626                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1627                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1628                 ;;
1629
1630         x11)
1631                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1632                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1633                 save_LIBS="$LIBS"
1634                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1635                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1636                 LIBS="$save_LIBS"
1637                 ;;
1638
1639         drm)
1640                 test "x$enable_gbm" = "xno" &&
1641                         AC_MSG_ERROR([EGL platform drm needs gbm])
1642                 ;;
1643
1644         android|gdi)
1645                 ;;
1646
1647         *)
1648                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1649                 ;;
1650         esac
1651
1652         case "$plat$have_libudev" in
1653                 waylandno|drmno)
1654                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1655         esac
1656 done
1657
1658 # libEGL wants to default to the first platform specified in
1659 # ./configure.  parse that here.
1660 if test "x$egl_platforms" != "x"; then
1661     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1662     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1663 else
1664     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1665 fi
1666
1667 EGL_PLATFORMS="$egl_platforms"
1668
1669 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1670 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1671 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1672 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1673 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1674
1675 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1676 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1677
1678 AC_SUBST([EGL_NATIVE_PLATFORM])
1679 AC_SUBST([EGL_PLATFORMS])
1680 AC_SUBST([EGL_CFLAGS])
1681
1682 AC_ARG_WITH([egl-driver-dir],
1683     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1684                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1685     [EGL_DRIVER_INSTALL_DIR="$withval"],
1686     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1687 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1688
1689 AC_ARG_WITH([xorg-driver-dir],
1690     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1691                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1692     [XORG_DRIVER_INSTALL_DIR="$withval"],
1693     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1694 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1695
1696 AC_ARG_WITH([max-width],
1697     [AS_HELP_STRING([--with-max-width=N],
1698                     [Maximum framebuffer width (4096)])],
1699     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1700      AS_IF([test "${withval}" -gt "4096"],
1701            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1702 )
1703 AC_ARG_WITH([max-height],
1704     [AS_HELP_STRING([--with-max-height=N],
1705                     [Maximum framebuffer height (4096)])],
1706     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1707      AS_IF([test "${withval}" -gt "4096"],
1708            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1709 )
1710
1711 dnl
1712 dnl Gallium LLVM
1713 dnl
1714 AC_ARG_ENABLE([gallium-llvm],
1715     [AS_HELP_STRING([--enable-gallium-llvm],
1716         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1717     [enable_gallium_llvm="$enableval"],
1718     [enable_gallium_llvm=auto])
1719
1720 AC_ARG_WITH([llvm-shared-libs],
1721     [AS_HELP_STRING([--with-llvm-shared-libs],
1722         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1723     [with_llvm_shared_libs=yes],
1724     [with_llvm_shared_libs=no])
1725
1726 AC_ARG_WITH([llvm-prefix],
1727     [AS_HELP_STRING([--with-llvm-prefix],
1728         [Prefix for LLVM installations in non-standard locations])],
1729     [llvm_prefix="$withval"],
1730     [llvm_prefix=""])
1731
1732
1733 if test "x$with_gallium_drivers" = x; then
1734     enable_gallium_llvm=no
1735 fi
1736 if test "x$enable_gallium_llvm" = xauto; then
1737     case "$host_cpu" in
1738     i*86|x86_64) enable_gallium_llvm=yes;;
1739     esac
1740 fi
1741 if test "x$enable_gallium_llvm" = xyes; then
1742     if test "x$llvm_prefix" != x; then
1743         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1744     else
1745         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1746     fi
1747
1748     if test "x$LLVM_CONFIG" != xno; then
1749         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1750         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1751         if test "x$with_llvm_shared_libs" = xyes; then
1752             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1753             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1754         else
1755             LLVM_COMPONENTS="engine bitwriter"
1756             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1757                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1758             fi
1759             if test "x$enable_opencl" = xyes; then
1760                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1761             fi
1762             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1763         fi
1764         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1765         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1766         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1767         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1768         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1769         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1770         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1771         MESA_LLVM=1
1772
1773         dnl Check for Clang interanl headers
1774         if test "x$enable_opencl" = xyes; then
1775             if test "x$CLANG_LIBDIR" = x; then
1776                 CLANG_LIBDIR=${LLVM_LIBDIR}
1777             fi
1778             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1779             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1780                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1781         fi
1782     else
1783         MESA_LLVM=0
1784     fi
1785 else
1786     MESA_LLVM=0
1787 fi
1788
1789 dnl Directory for XVMC libs
1790 AC_ARG_WITH([xvmc-libdir],
1791     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1792         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1793     [XVMC_LIB_INSTALL_DIR="$withval"],
1794     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1795 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1796
1797 dnl
1798 dnl Gallium Tests
1799 dnl
1800 if test "x$enable_gallium_tests" = xyes; then
1801     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1802     enable_gallium_loader=yes
1803 fi
1804
1805 dnl Directory for VDPAU libs
1806 AC_ARG_WITH([vdpau-libdir],
1807     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1808         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1809     [VDPAU_LIB_INSTALL_DIR="$withval"],
1810     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1811 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1812
1813 dnl Directory for VA libs
1814 AC_ARG_WITH([va-libdir],
1815     [AS_HELP_STRING([--with-va-libdir=DIR],
1816         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1817     [VA_LIB_INSTALL_DIR="$withval"],
1818     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1819 AC_SUBST([VA_LIB_INSTALL_DIR])
1820
1821 dnl Directory for OpenCL libs
1822 AC_ARG_WITH([opencl-libdir],
1823     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1824         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1825     [OPENCL_LIB_INSTALL_DIR="$withval"],
1826     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1827 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1828
1829 dnl
1830 dnl Gallium helper functions
1831 dnl
1832 gallium_check_st() {
1833     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1834          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1835          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1836          if test "x$have_libdrm" != xyes; then
1837             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1838          fi
1839          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1840     fi
1841     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1842          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1843     fi
1844     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1845          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1846     fi
1847     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1848          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1849     fi
1850     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1851          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1852     fi
1853     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1854          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1855     fi
1856     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1857          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1858     fi
1859 }
1860
1861 gallium_require_llvm() {
1862     if test "x$MESA_LLVM" = x0; then
1863         case "$host_cpu" in
1864         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1865         esac
1866     fi
1867 }
1868
1869 gallium_require_drm_loader() {
1870     if test "x$enable_gallium_loader" = xyes; then
1871         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1872                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1873         if test "x$have_libdrm" != xyes; then
1874             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1875         fi
1876         enable_gallium_drm_loader=yes
1877     fi
1878 }
1879
1880 dnl Gallium drivers
1881 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1882 if test "x$with_gallium_drivers" != x; then
1883     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1884     for driver in $gallium_drivers; do
1885         case "x$driver" in
1886         xsvga)
1887             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1888             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1889             ;;
1890         xi915)
1891             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1892             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1893             if test "x$MESA_LLVM" = x1; then
1894                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1895             fi
1896             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1897             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1898             ;;
1899         xr300)
1900             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1901             gallium_require_llvm "Gallium R300"
1902             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1903             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1904             ;;
1905         xr600)
1906             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1907             gallium_require_drm_loader
1908             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1909             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1910                 if test "x$LLVM_VERSION" != "x3.1"; then
1911                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1912                 fi
1913                 NEED_RADEON_GALLIUM=yes;
1914             fi
1915             if test "x$enable_r600_llvm" = xyes; then
1916                 USE_R600_LLVM_COMPILER=yes;
1917             fi
1918             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1919                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1920             fi
1921             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1922             ;;
1923         xradeonsi)
1924             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1925             gallium_require_drm_loader
1926             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1927             if test "x$LLVM_VERSION" != "x3.1"; then
1928                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1929             fi
1930             NEED_RADEON_GALLIUM=yes;
1931             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1932             ;;
1933         xnouveau)
1934             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1935             gallium_require_drm_loader
1936             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1937             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1938             ;;
1939         xswrast)
1940             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1941             if test "x$MESA_LLVM" = x1; then
1942                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1943             fi
1944
1945             if test "x$HAVE_ST_DRI" = xyes; then
1946                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1947             fi
1948             if test "x$HAVE_ST_VDPAU" = xyes; then
1949                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1950             fi
1951             if test "x$HAVE_ST_XVMC" = xyes; then
1952                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1953             fi
1954             if test "x$HAVE_ST_VA" = xyes; then
1955                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1956             fi
1957             if test "x$HAVE_ST_VDPAU" = xyes ||
1958                test "x$HAVE_ST_XVMC" = xyes ||
1959                test "x$HAVE_ST_VA" = xyes; then
1960                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1961                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1962                fi
1963             fi
1964             ;;
1965         *)
1966             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1967             ;;
1968         esac
1969     done
1970 fi
1971
1972 if test "x$enable_gallium_loader" = xyes; then
1973     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1974     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1975     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1976     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1977
1978     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1979         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1980         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1981     fi
1982
1983     if test "x$enable_gallium_drm_loader" = xyes; then
1984         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1985         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1986                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1987         if test "x$pipe_loader_have_xcb" = xyes; then
1988             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1989             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1990         fi
1991     fi
1992
1993     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1994     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1995 fi
1996
1997 dnl Tell Automake which drivers to build
1998 for driver in $GALLIUM_DRIVERS_DIRS; do
1999     case "x$driver" in
2000         xgalahad)
2001             HAVE_GALAHAD_GALLIUM=yes;
2002             ;;
2003         xidentity)
2004             HAVE_IDENTITY_GALLIUM=yes;
2005             ;;
2006         xnoop)
2007             HAVE_NOOP_GALLIUM=yes;
2008             ;;
2009         *)
2010             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2011             ;;
2012     esac
2013 done
2014
2015 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2016 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2017 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2018 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2019 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2020 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2021 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2022 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2023 AC_SUBST([GALLIUM_MAKE_DIRS])
2024
2025 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2026 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2027
2028 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2029 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2030 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2031
2032 dnl prepend CORE_DIRS to SRC_DIRS
2033 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2034
2035 dnl Restore LDFLAGS and CPPFLAGS
2036 LDFLAGS="$_SAVE_LDFLAGS"
2037 CPPFLAGS="$_SAVE_CPPFLAGS"
2038
2039 dnl Add user CFLAGS and CXXFLAGS
2040 CFLAGS="$CFLAGS $USER_CFLAGS"
2041 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2042
2043 dnl Substitute the config
2044 AC_CONFIG_FILES([configs/current
2045                 Makefile
2046                 src/Makefile
2047                 src/gallium/Makefile
2048                 src/gallium/auxiliary/pipe-loader/Makefile
2049                 src/gallium/state_trackers/clover/Makefile
2050                 src/gallium/drivers/Makefile
2051                 src/gallium/drivers/r300/Makefile
2052                 src/gallium/drivers/r600/Makefile
2053                 src/gallium/targets/opencl/Makefile
2054                 src/gbm/Makefile
2055                 src/gbm/main/gbm.pc
2056                 src/egl/drivers/Makefile
2057                 src/egl/drivers/dri2/Makefile
2058                 src/egl/drivers/glx/Makefile
2059                 src/egl/Makefile
2060                 src/egl/main/Makefile
2061                 src/egl/main/egl.pc
2062                 src/egl/wayland/Makefile
2063                 src/egl/wayland/wayland-egl/Makefile
2064                 src/egl/wayland/wayland-egl/wayland-egl.pc
2065                 src/egl/wayland/wayland-drm/Makefile
2066                 src/glsl/Makefile
2067                 src/glsl/glcpp/Makefile
2068                 src/glsl/tests/Makefile
2069                 src/glx/Makefile
2070                 src/glx/tests/Makefile
2071                 src/mapi/glapi/Makefile
2072                 src/mapi/glapi/gen/Makefile
2073                 src/mapi/shared-glapi/Makefile
2074                 src/mapi/glapi/tests/Makefile
2075                 src/mapi/shared-glapi/tests/Makefile
2076                 src/gtest/Makefile
2077                 src/mesa/Makefile
2078                 src/mesa/libdricore/Makefile
2079                 src/mesa/main/tests/Makefile
2080                 src/mesa/x86/Makefile
2081                 src/mesa/x86-64/Makefile
2082                 src/mesa/drivers/Makefile
2083                 src/mesa/drivers/dri/dri.pc
2084                 src/mesa/drivers/dri/Makefile
2085                 src/mesa/drivers/dri/common/Makefile
2086                 src/mesa/drivers/dri/i915/Makefile
2087                 src/mesa/drivers/dri/i965/Makefile
2088                 src/mesa/drivers/dri/nouveau/Makefile
2089                 src/mesa/drivers/dri/r200/Makefile
2090                 src/mesa/drivers/dri/radeon/Makefile
2091                 src/mesa/drivers/dri/swrast/Makefile
2092                 src/mesa/drivers/osmesa/Makefile
2093                 src/mesa/drivers/x11/Makefile
2094                 src/mesa/gl.pc
2095                 src/mesa/drivers/osmesa/osmesa.pc])
2096
2097 dnl Sort the dirs alphabetically
2098 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2099 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2100 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2101 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2102 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2103
2104 AC_OUTPUT
2105
2106 dnl
2107 dnl Output some configuration info for the user
2108 dnl
2109 echo ""
2110 echo "        prefix:          $prefix"
2111 echo "        exec_prefix:     $exec_prefix"
2112 echo "        libdir:          $libdir"
2113 echo "        includedir:      $includedir"
2114
2115 dnl API info
2116 echo ""
2117 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2118 echo "        OpenVG:          $enable_openvg"
2119
2120 dnl Driver info
2121 echo ""
2122 if test "x$enable_osmesa" != xno; then
2123         echo "        OSMesa:          lib$OSMESA_LIB"
2124 else
2125         echo "        OSMesa:          no"
2126 fi
2127
2128 if test "x$enable_dri" != xno; then
2129         # cleanup the drivers var
2130         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2131         if test "x$DRI_DIRS" = x; then
2132             echo "        DRI drivers:     no"
2133         else
2134             echo "        DRI drivers:     $dri_dirs"
2135         fi
2136         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2137 fi
2138
2139 case "x$enable_glx$enable_xlib_glx" in
2140 xyesyes)
2141     echo "        GLX:             Xlib-based"
2142     ;;
2143 xyesno)
2144     echo "        GLX:             DRI-based"
2145     ;;
2146 *)
2147     echo "        GLX:             $enable_glx"
2148     ;;
2149 esac
2150
2151 echo ""
2152 echo "        GLU:             $enable_glu"
2153
2154 dnl EGL
2155 echo ""
2156 echo "        EGL:             $enable_egl"
2157 if test "$enable_egl" = yes; then
2158     echo "        EGL platforms:   $EGL_PLATFORMS"
2159
2160     egl_drivers=""
2161     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2162         egl_drivers="$egl_drivers builtin:egl_glx"
2163     fi
2164     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2165         egl_drivers="$egl_drivers builtin:egl_dri2"
2166     fi
2167
2168     if test "x$HAVE_ST_EGL" = xyes; then
2169         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2170         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2171     else
2172         echo "        EGL drivers:    $egl_drivers"
2173     fi
2174 fi
2175
2176 echo ""
2177 if test "x$MESA_LLVM" = x1; then
2178     echo "        llvm:            yes"
2179     echo "        llvm-config:     $LLVM_CONFIG"
2180     echo "        llvm-version:    $LLVM_VERSION"
2181 else
2182     echo "        llvm:            no"
2183 fi
2184
2185 echo ""
2186 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2187     echo "        Gallium:         yes"
2188     echo "        Gallium dirs:    $GALLIUM_DIRS"
2189     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2190     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2191     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2192     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2193 else
2194     echo "        Gallium:         no"
2195 fi
2196
2197
2198 dnl Libraries
2199 echo ""
2200 echo "        Shared libs:     $enable_shared"
2201 echo "        Static libs:     $enable_static"
2202
2203 dnl Compiler options
2204 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2205 cflags=`echo $CFLAGS $PIC_FLAGS | \
2206     $SED 's/^ *//;s/  */ /;s/ *$//'`
2207 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2208     $SED 's/^ *//;s/  */ /;s/ *$//'`
2209 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2210 echo ""
2211 echo "        CFLAGS:          $cflags"
2212 echo "        CXXFLAGS:        $cxxflags"
2213 echo "        Macros:          $defines"
2214 echo ""
2215 echo "        PYTHON2:         $PYTHON2"
2216
2217 echo ""
2218 echo "        Run '${MAKE-make}' to build Mesa"
2219 echo ""