configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 # Support silent build rules, requires at least automake-1.11. Disable
  50 # by either passing --disable-silent-rules to configure or passing V=1
  51 # to make
  52 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  53     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  54
  55 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  56
  57 dnl Set internal versions
  58 OSMESA_VERSION=8
  59 AC_SUBST([OSMESA_VERSION])
  60
  61 dnl Versions for external dependencies
  62 LIBDRM_REQUIRED=2.4.38
  63 LIBDRM_RADEON_REQUIRED=2.4.56
  64 LIBDRM_INTEL_REQUIRED=2.4.52
  65 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  66 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  67 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  68 DRI2PROTO_REQUIRED=2.6
  69 DRI3PROTO_REQUIRED=1.0
  70 PRESENTPROTO_REQUIRED=1.0
  71 LIBUDEV_REQUIRED=151
  72 GLPROTO_REQUIRED=1.4.14
  73 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  74 LIBVA_REQUIRED=0.35.0
  75 VDPAU_REQUIRED=0.4.1
  76 WAYLAND_REQUIRED=1.2.0
  77 XCB_REQUIRED=1.9.3
  78 XCBDRI2_REQUIRED=1.8
  79 XCBGLX_REQUIRED=1.8.1
  80 XSHMFENCE_REQUIRED=1.1
  81 XVMC_REQUIRED=1.0.6
  82
  83 dnl Check for progs
  84 AC_PROG_CPP
  85 AC_PROG_CC
  86 AC_PROG_CXX
  87 AM_PROG_CC_C_O
  88 AM_PROG_AS
  89 AX_CHECK_GNU_MAKE
  90 AC_CHECK_PROGS([PYTHON2], [python2 python])
  91 AC_PROG_SED
  92 AC_PROG_MKDIR_P
  93
  94 AC_SYS_LARGEFILE
  95
  96 LT_PREREQ([2.2])
  97 LT_INIT([disable-static])
  98
  99 AX_PROG_BISON([],
 100               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 101                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 102 AX_PROG_FLEX([],
 103              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 104                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 105
 106 AC_CHECK_PROG(INDENT, indent, indent, cat)
 107 if test "x$INDENT" != "xcat"; then
 108     # Only GNU indent is supported
 109     INDENT_VERSION=`indent --version | grep GNU`
 110     if test $? -eq 0; then
 111        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 112     else
 113        INDENT="cat"
 114     fi
 115 fi
 116
 117 AX_CHECK_PYTHON_MAKO_MODULE(0.3.4)
 118
 119 AC_PROG_INSTALL
 120
 121 dnl We need a POSIX shell for parts of the build. Assume we have one
 122 dnl in most cases.
 123 case "$host_os" in
 124 solaris*)
 125     # Solaris /bin/sh is too old/non-POSIX compliant
 126     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 127     SHELL="$POSIX_SHELL"
 128     ;;
 129 esac
 130
 131 dnl clang is mostly GCC-compatible, but its version is much lower,
 132 dnl so we have to check for it.
 133 AC_MSG_CHECKING([if compiling with clang])
 134
 135 AC_COMPILE_IFELSE(
 136 [AC_LANG_PROGRAM([], [[
 137 #ifndef __clang__
 138        not clang
 139 #endif
 140 ]])],
 141 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 142
 143 AC_MSG_RESULT([$acv_mesa_CLANG])
 144
 145 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 146 dnl versions are explictly not supported.
 147 GEN_ASM_OFFSETS=no
 148 USE_GNU99=no
 149 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 150     AC_MSG_CHECKING([whether gcc version is sufficient])
 151     major=0
 152     minor=0
 153
 154     GCC_VERSION=`$CC -dumpversion`
 155     if test $? -eq 0; then
 156         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 157         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 158     fi
 159
 160     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 161         AC_MSG_RESULT([no])
 162         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 163     else
 164         AC_MSG_RESULT([yes])
 165     fi
 166
 167     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 168         USE_GNU99=yes
 169     fi
 170     if test "x$cross_compiling" = xyes; then
 171         GEN_ASM_OFFSETS=yes
 172     fi
 173 fi
 174
 175 dnl Check for compiler builtins
 176 AX_GCC_BUILTIN([__builtin_bswap32])
 177 AX_GCC_BUILTIN([__builtin_bswap64])
 178 AX_GCC_BUILTIN([__builtin_clz])
 179 AX_GCC_BUILTIN([__builtin_clzll])
 180 AX_GCC_BUILTIN([__builtin_ctz])
 181 AX_GCC_BUILTIN([__builtin_expect])
 182 AX_GCC_BUILTIN([__builtin_ffs])
 183 AX_GCC_BUILTIN([__builtin_ffsll])
 184 AX_GCC_BUILTIN([__builtin_popcount])
 185 AX_GCC_BUILTIN([__builtin_popcountll])
 186 AX_GCC_BUILTIN([__builtin_unreachable])
 187
 188 AX_GCC_FUNC_ATTRIBUTE([flatten])
 189 AX_GCC_FUNC_ATTRIBUTE([format])
 190 AX_GCC_FUNC_ATTRIBUTE([malloc])
 191 AX_GCC_FUNC_ATTRIBUTE([packed])
 192
 193 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 194
 195 dnl Make sure the pkg-config macros are defined
 196 m4_ifndef([PKG_PROG_PKG_CONFIG],
 197     [m4_fatal([Could not locate the pkg-config autoconf macros.
 198   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 199   are in a different location, try setting the environment variable
 200   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 201 PKG_PROG_PKG_CONFIG()
 202
 203 dnl LIB_DIR - library basename
 204 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 205 AC_SUBST([LIB_DIR])
 206
 207 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 208 _SAVE_LDFLAGS="$LDFLAGS"
 209 _SAVE_CPPFLAGS="$CPPFLAGS"
 210
 211 dnl Compiler macros
 212 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 213 AC_SUBST([DEFINES])
 214 case "$host_os" in
 215 linux*|*-gnu*|gnu*)
 216     DEFINES="$DEFINES -D_GNU_SOURCE"
 217     ;;
 218 solaris*)
 219     DEFINES="$DEFINES -DSVR4"
 220     ;;
 221 cygwin*)
 222     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 223     ;;
 224 esac
 225
 226 dnl Add flags for gcc and g++
 227 if test "x$GCC" = xyes; then
 228     CFLAGS="$CFLAGS -Wall"
 229
 230     if test "x$USE_GNU99" = xyes; then
 231         CFLAGS="$CFLAGS -std=gnu99"
 232     else
 233         CFLAGS="$CFLAGS -std=c99"
 234     fi
 235
 236     # Enable -Werror=implicit-function-declaration and
 237     # -Werror=missing-prototypes, if available, or otherwise, just
 238     # -Wmissing-prototypes.  This is particularly useful to avoid
 239     # generating a loadable driver module that has undefined symbols.
 240     save_CFLAGS="$CFLAGS"
 241     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 242     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 243     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 244     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 245                    AC_MSG_RESULT([yes]),
 246                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 247                     AC_MSG_RESULT([no])]);
 248
 249     # Enable -fvisibility=hidden if using a gcc that supports it
 250     save_CFLAGS="$CFLAGS"
 251     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 252     VISIBILITY_CFLAGS="-fvisibility=hidden"
 253     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 254     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 255                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 256
 257     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 258     CFLAGS=$save_CFLAGS
 259
 260     # Work around aliasing bugs - developers should comment this out
 261     CFLAGS="$CFLAGS -fno-strict-aliasing"
 262
 263     # gcc's builtin memcmp is slower than glibc's
 264     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 265     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 266 fi
 267 if test "x$GXX" = xyes; then
 268     CXXFLAGS="$CXXFLAGS -Wall"
 269
 270     # Enable -fvisibility=hidden if using a gcc that supports it
 271     save_CXXFLAGS="$CXXFLAGS"
 272     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 273     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 274     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 275     AC_LANG_PUSH([C++])
 276     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 277                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 278     AC_LANG_POP([C++])
 279
 280     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 281     CXXFLAGS=$save_CXXFLAGS
 282
 283     # Work around aliasing bugs - developers should comment this out
 284     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 285
 286     # gcc's builtin memcmp is slower than glibc's
 287     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 288     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 289 fi
 290
 291 dnl even if the compiler appears to support it, using visibility attributes isn't
 292 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 293 case "$host_os" in
 294 cygwin*)
 295     VISIBILITY_CFLAGS=""
 296     VISIBILITY_CXXFLAGS=""
 297     ;;
 298 esac
 299
 300 AC_SUBST([VISIBILITY_CFLAGS])
 301 AC_SUBST([VISIBILITY_CXXFLAGS])
 302
 303 dnl
 304 dnl Optional flags, check for compiler support
 305 dnl
 306 SSE41_CFLAGS="-msse4.1"
 307 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 308 dnl stack, but on x86-32 such alignment is not guaranteed.
 309 case "$target_cpu" in
 310 i?86)
 311     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 312     ;;
 313 esac
 314 save_CFLAGS="$CFLAGS"
 315 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 316 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 317 #include <smmintrin.h>
 318 int main () {
 319     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 320     c = _mm_max_epu32(a, b);
 321     return 0;
 322 }]])], SSE41_SUPPORTED=1)
 323 CFLAGS="$save_CFLAGS"
 324 if test "x$SSE41_SUPPORTED" = x1; then
 325     DEFINES="$DEFINES -DUSE_SSE41"
 326 fi
 327 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 328 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 329
 330 dnl Can't have static and shared libraries, default to static if user
 331 dnl explicitly requested. If both disabled, set to static since shared
 332 dnl was explicitly requested.
 333 case "x$enable_static$enable_shared" in
 334 xyesyes)
 335     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 336     enable_shared=no
 337     ;;
 338 xnono)
 339     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 340     enable_shared=yes
 341     ;;
 342 esac
 343
 344 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 345
 346 dnl
 347 dnl other compiler options
 348 dnl
 349 AC_ARG_ENABLE([debug],
 350     [AS_HELP_STRING([--enable-debug],
 351         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 352     [enable_debug="$enableval"],
 353     [enable_debug=no]
 354 )
 355 if test "x$enable_debug" = xyes; then
 356     DEFINES="$DEFINES -DDEBUG"
 357     if test "x$GCC" = xyes; then
 358         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 359             CFLAGS="$CFLAGS -g"
 360         fi
 361         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 362             CFLAGS="$CFLAGS -O0"
 363         fi
 364     fi
 365     if test "x$GXX" = xyes; then
 366         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 367             CXXFLAGS="$CXXFLAGS -g"
 368         fi
 369         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 370             CXXFLAGS="$CXXFLAGS -O0"
 371         fi
 372     fi
 373 fi
 374
 375 dnl
 376 dnl Check if linker supports -Bsymbolic
 377 dnl
 378 save_LDFLAGS=$LDFLAGS
 379 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 380 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 381 AC_LINK_IFELSE(
 382     [AC_LANG_SOURCE([int main() { return 0;}])],
 383     [AC_MSG_RESULT([yes])
 384         BSYMBOLIC="-Wl,-Bsymbolic";],
 385     [AC_MSG_RESULT([no])
 386         BSYMBOLIC="";])
 387 LDFLAGS=$save_LDFLAGS
 388
 389 AC_SUBST([BSYMBOLIC])
 390
 391 dnl
 392 dnl Check if linker supports garbage collection
 393 dnl
 394 save_LDFLAGS=$LDFLAGS
 395 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 396 AC_MSG_CHECKING([whether ld supports --gc-sections])
 397 AC_LINK_IFELSE(
 398     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 399     [AC_MSG_RESULT([yes])
 400         GC_SECTIONS="-Wl,--gc-sections";],
 401     [AC_MSG_RESULT([no])
 402         GC_SECTIONS="";])
 403 LDFLAGS=$save_LDFLAGS
 404
 405 AC_SUBST([GC_SECTIONS])
 406
 407 dnl
 408 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 409 dnl so when these flags are passed to ld via libtool the checks will fail
 410 dnl
 411 case "$host_os" in
 412 openbsd* | darwin* )
 413     LD_NO_UNDEFINED="" ;;
 414 *)
 415     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 416 esac
 417
 418 AC_SUBST([LD_NO_UNDEFINED])
 419
 420 dnl
 421 dnl Check if linker supports version scripts
 422 dnl
 423 AC_MSG_CHECKING([if the linker supports version-scripts])
 424 save_LDFLAGS=$LDFLAGS
 425 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 426 cat > conftest.map <<EOF
 427 VERSION_1 {
 428      global:
 429          main;
 430
 431      local:
 432          *;
 433 };
 434 EOF
 435 AC_LINK_IFELSE(
 436     [AC_LANG_SOURCE([int main() { return 0;}])],
 437     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 438     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 439 LDFLAGS=$save_LDFLAGS
 440 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 441
 442 dnl
 443 dnl Check if linker supports dynamic list files
 444 dnl
 445 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 446 save_LDFLAGS=$LDFLAGS
 447 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 448 cat > conftest.dyn <<EOF
 449 {
 450         radeon_drm_winsys_create;
 451 };
 452 EOF
 453 AC_LINK_IFELSE(
 454     [AC_LANG_SOURCE([int main() { return 0;}])],
 455     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 456     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 457 LDFLAGS=$save_LDFLAGS
 458 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 459
 460 dnl
 461 dnl compatibility symlinks
 462 dnl
 463 case "$host_os" in
 464 linux* )
 465     HAVE_COMPAT_SYMLINKS=yes ;;
 466 * )
 467     HAVE_COMPAT_SYMLINKS=no ;;
 468 esac
 469
 470 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 471
 472 dnl
 473 dnl library names
 474 dnl
 475 case "$host_os" in
 476 darwin* )
 477     LIB_EXT='dylib' ;;
 478 cygwin* )
 479     LIB_EXT='dll' ;;
 480 aix* )
 481     LIB_EXT='a' ;;
 482 * )
 483     LIB_EXT='so' ;;
 484 esac
 485
 486 AC_SUBST([LIB_EXT])
 487
 488 AC_ARG_WITH([gl-lib-name],
 489   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 490     [specify GL library name @<:@default=GL@:>@])],
 491   [GL_LIB=$withval],
 492   [GL_LIB=GL])
 493 AC_ARG_WITH([osmesa-lib-name],
 494   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 495     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 496   [OSMESA_LIB=$withval],
 497   [OSMESA_LIB=OSMesa])
 498 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 499 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 500
 501 dnl
 502 dnl Mangled Mesa support
 503 dnl
 504 AC_ARG_ENABLE([mangling],
 505   [AS_HELP_STRING([--enable-mangling],
 506     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 507   [enable_mangling="${enableval}"],
 508   [enable_mangling=no]
 509 )
 510 if test "x${enable_mangling}" = "xyes" ; then
 511   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 512   GL_LIB="Mangled${GL_LIB}"
 513   OSMESA_LIB="Mangled${OSMESA_LIB}"
 514 fi
 515 AC_SUBST([GL_LIB])
 516 AC_SUBST([OSMESA_LIB])
 517
 518 dnl
 519 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 520 dnl
 521 AC_ARG_ENABLE([texture-float],
 522     [AS_HELP_STRING([--enable-texture-float],
 523         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 524     [enable_texture_float="$enableval"],
 525     [enable_texture_float=no]
 526 )
 527 if test "x$enable_texture_float" = xyes; then
 528     AC_MSG_WARN([Floating-point textures enabled.])
 529     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 530     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 531 fi
 532
 533 dnl
 534 dnl Arch/platform-specific settings
 535 dnl
 536 AC_ARG_ENABLE([asm],
 537     [AS_HELP_STRING([--disable-asm],
 538         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 539     [enable_asm="$enableval"],
 540     [enable_asm=yes]
 541 )
 542 asm_arch=""
 543 AC_MSG_CHECKING([whether to enable assembly])
 544 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 545 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 546 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 547     case "$host_cpu" in
 548     i?86 | x86_64 | amd64)
 549         enable_asm=no
 550         AC_MSG_RESULT([no, cross compiling])
 551         ;;
 552     esac
 553 fi
 554 # check for supported arches
 555 if test "x$enable_asm" = xyes; then
 556     case "$host_cpu" in
 557     i?86)
 558         case "$host_os" in
 559         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 560             asm_arch=x86
 561             ;;
 562         esac
 563         ;;
 564     x86_64|amd64)
 565         case "$host_os" in
 566         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 567             asm_arch=x86_64
 568             ;;
 569         esac
 570         ;;
 571     sparc*)
 572         case "$host_os" in
 573         linux*)
 574             asm_arch=sparc
 575             ;;
 576         esac
 577         ;;
 578     esac
 579
 580     case "$asm_arch" in
 581     x86)
 582         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 583         AC_MSG_RESULT([yes, x86])
 584         ;;
 585     x86_64|amd64)
 586         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 587         AC_MSG_RESULT([yes, x86_64])
 588         ;;
 589     sparc)
 590         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 591         AC_MSG_RESULT([yes, sparc])
 592         ;;
 593     *)
 594         AC_MSG_RESULT([no, platform not supported])
 595         ;;
 596     esac
 597 fi
 598
 599 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 600 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 601
 602 dnl Check to see if dlopen is in default libraries (like Solaris, which
 603 dnl has it in libc), or if libdl is needed to get it.
 604 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 605     [AC_CHECK_LIB([dl], [dlopen],
 606        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 607 AC_SUBST([DLOPEN_LIBS])
 608
 609 dnl Check if that library also has dladdr
 610 save_LIBS="$LIBS"
 611 LIBS="$LIBS $DLOPEN_LIBS"
 612 AC_CHECK_FUNCS([dladdr])
 613 LIBS="$save_LIBS"
 614
 615 case "$host_os" in
 616 darwin*|mingw*)
 617     ;;
 618 *)
 619     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 620                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 621                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 622     AC_SUBST([CLOCK_LIB])
 623     ;;
 624 esac
 625
 626 dnl See if posix_memalign is available
 627 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 628
 629 dnl Check for pthreads
 630 case "$host_os" in
 631 mingw*)
 632     ;;
 633 *)
 634     AX_PTHREAD
 635     ;;
 636 esac
 637 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 638 dnl to -pthread, which causes problems if we need -lpthread to appear in
 639 dnl pkgconfig files.
 640 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 641
 642 dnl SELinux awareness.
 643 AC_ARG_ENABLE([selinux],
 644     [AS_HELP_STRING([--enable-selinux],
 645         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 646     [MESA_SELINUX="$enableval"],
 647     [MESA_SELINUX=no])
 648 if test "x$enable_selinux" = "xyes"; then
 649     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 650         [AC_CHECK_HEADER([selinux/selinux.h],[],
 651                          [AC_MSG_ERROR([SELinux headers not found])])
 652          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 653                       [AC_MSG_ERROR([SELinux library not found])])
 654          SELINUX_LIBS="-lselinux"])
 655     DEFINES="$DEFINES -DMESA_SELINUX"
 656 fi
 657 AC_SUBST([SELINUX_CFLAGS])
 658 AC_SUBST([SELINUX_LIBS])
 659
 660 dnl Options for APIs
 661 AC_ARG_ENABLE([opengl],
 662     [AS_HELP_STRING([--disable-opengl],
 663         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 664     [enable_opengl="$enableval"],
 665     [enable_opengl=yes])
 666 AC_ARG_ENABLE([gles1],
 667     [AS_HELP_STRING([--enable-gles1],
 668         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 669     [enable_gles1="$enableval"],
 670     [enable_gles1=no])
 671 AC_ARG_ENABLE([gles2],
 672     [AS_HELP_STRING([--enable-gles2],
 673         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 674     [enable_gles2="$enableval"],
 675     [enable_gles2=no])
 676 AC_ARG_ENABLE([openvg],
 677     [AS_HELP_STRING([--enable-openvg],
 678         [enable support for OpenVG API @<:@default=disabled@:>@])],
 679     [enable_openvg="$enableval"],
 680     [enable_openvg=no])
 681
 682 AC_ARG_ENABLE([dri],
 683     [AS_HELP_STRING([--enable-dri],
 684         [enable DRI modules @<:@default=enabled@:>@])],
 685     [enable_dri="$enableval"],
 686     [enable_dri=yes])
 687
 688 case "$host_os" in
 689 linux*)
 690     dri3_default=yes
 691     ;;
 692 *)
 693     dri3_default=no
 694     ;;
 695 esac
 696 AC_ARG_ENABLE([dri3],
 697     [AS_HELP_STRING([--enable-dri3],
 698         [enable DRI3 @<:@default=auto@:>@])],
 699     [enable_dri3="$enableval"],
 700     [enable_dri3="$dri3_default"])
 701 AC_ARG_ENABLE([glx],
 702     [AS_HELP_STRING([--enable-glx],
 703         [enable GLX library @<:@default=enabled@:>@])],
 704     [enable_glx="$enableval"],
 705     [enable_glx=yes])
 706 AC_ARG_ENABLE([osmesa],
 707     [AS_HELP_STRING([--enable-osmesa],
 708         [enable OSMesa library @<:@default=disabled@:>@])],
 709     [enable_osmesa="$enableval"],
 710     [enable_osmesa=no])
 711 AC_ARG_ENABLE([gallium-osmesa],
 712     [AS_HELP_STRING([--enable-gallium-osmesa],
 713         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 714     [enable_gallium_osmesa="$enableval"],
 715     [enable_gallium_osmesa=no])
 716 AC_ARG_ENABLE([egl],
 717     [AS_HELP_STRING([--disable-egl],
 718         [disable EGL library @<:@default=enabled@:>@])],
 719     [enable_egl="$enableval"],
 720     [enable_egl=yes])
 721
 722 AC_ARG_ENABLE([xa],
 723     [AS_HELP_STRING([--enable-xa],
 724         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 725     [enable_xa="$enableval"],
 726     [enable_xa=no])
 727 AC_ARG_ENABLE([gbm],
 728    [AS_HELP_STRING([--enable-gbm],
 729          [enable gbm library @<:@default=auto@:>@])],
 730    [enable_gbm="$enableval"],
 731    [enable_gbm=auto])
 732 AC_ARG_ENABLE([nine],
 733     [AS_HELP_STRING([--enable-nine],
 734         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 735     [enable_nine="$enableval"],
 736     [enable_nine=no])
 737
 738 AC_ARG_ENABLE([xvmc],
 739    [AS_HELP_STRING([--enable-xvmc],
 740          [enable xvmc library @<:@default=auto@:>@])],
 741    [enable_xvmc="$enableval"],
 742    [enable_xvmc=auto])
 743 AC_ARG_ENABLE([vdpau],
 744    [AS_HELP_STRING([--enable-vdpau],
 745          [enable vdpau library @<:@default=auto@:>@])],
 746    [enable_vdpau="$enableval"],
 747    [enable_vdpau=auto])
 748 AC_ARG_ENABLE([omx],
 749    [AS_HELP_STRING([--enable-omx],
 750          [enable OpenMAX library @<:@default=disabled@:>@])],
 751    [enable_omx="$enableval"],
 752    [enable_omx=no])
 753 AC_ARG_ENABLE([va],
 754    [AS_HELP_STRING([--enable-va],
 755          [enable va library @<:@default=auto@:>@])],
 756    [enable_va="$enableval"],
 757    [enable_va=auto])
 758 AC_ARG_ENABLE([opencl],
 759    [AS_HELP_STRING([--enable-opencl],
 760          [enable OpenCL library @<:@default=disabled@:>@])],
 761    [enable_opencl="$enableval"],
 762    [enable_opencl=no])
 763 AC_ARG_ENABLE([opencl_icd],
 764    [AS_HELP_STRING([--enable-opencl-icd],
 765           [Build an OpenCL ICD library to be loaded by an ICD implementation
 766            @<:@default=disabled@:>@])],
 767     [enable_opencl_icd="$enableval"],
 768     [enable_opencl_icd=no])
 769 AC_ARG_ENABLE([xlib-glx],
 770     [AS_HELP_STRING([--enable-xlib-glx],
 771         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 772     [enable_xlib_glx="$enableval"],
 773     [enable_xlib_glx=no])
 774
 775 AC_ARG_ENABLE([r600-llvm-compiler],
 776     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 777         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 778     [enable_r600_llvm="$enableval"],
 779     [enable_r600_llvm=no])
 780
 781 AC_ARG_ENABLE([gallium-tests],
 782     [AS_HELP_STRING([--enable-gallium-tests],
 783         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 784     [enable_gallium_tests="$enableval"],
 785     [enable_gallium_tests=no])
 786
 787 # Option for Gallium drivers
 788
 789 # Keep this in sync with the --with-gallium-drivers help string default value
 790 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 791
 792 AC_ARG_WITH([gallium-drivers],
 793     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 794         [comma delimited Gallium drivers list, e.g.
 795         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 796         @<:@default=r300,r600,svga,swrast@:>@])],
 797     [with_gallium_drivers="$withval"],
 798     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 799
 800 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 801 # here so that the script doesn't choke on an unknown driver name later.
 802 case "$with_gallium_drivers" in
 803     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 804     no) with_gallium_drivers='' ;;
 805 esac
 806
 807 if test "x$enable_opengl" = xno -a \
 808         "x$enable_gles1" = xno -a \
 809         "x$enable_gles2" = xno -a \
 810         "x$enable_nine" = xno -a \
 811         "x$enable_openvg" = xno -a \
 812         "x$enable_xa" = xno -a \
 813         "x$enable_xvmc" = xno -a \
 814         "x$enable_vdpau" = xno -a \
 815         "x$enable_omx" = xno -a \
 816         "x$enable_va" = xno -a \
 817         "x$enable_opencl" = xno; then
 818     AC_MSG_ERROR([at least one API should be enabled])
 819 fi
 820
 821 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 822 if test "x$enable_opengl" = xno -a \
 823         "x$enable_gles1" = xyes; then
 824     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 825 fi
 826
 827 if test "x$enable_opengl" = xno -a \
 828         "x$enable_gles2" = xyes; then
 829     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 830 fi
 831
 832 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 833 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 834 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 835 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 836                                         "x$enable_gles1" = xyes -o \
 837                                         "x$enable_gles2" = xyes)
 838
 839 if test "x$enable_glx" = xno; then
 840     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 841     enable_xlib_glx=no
 842 fi
 843
 844 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 845     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 846 fi
 847
 848 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 849     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 850 fi
 851
 852 # Disable GLX if OpenGL is not enabled
 853 if test "x$enable_glx$enable_opengl" = xyesno; then
 854     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 855     enable_glx=no
 856 fi
 857
 858 # Disable GLX if DRI and Xlib-GLX are not enabled
 859 if test "x$enable_glx" = xyes -a \
 860         "x$enable_dri" = xno -a \
 861         "x$enable_xlib_glx" = xno; then
 862     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 863     enable_glx=no
 864 fi
 865
 866 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 867                                   "x$enable_dri" = xyes)
 868
 869 # Select which platform-dependent DRI code gets built
 870 case "$host_os" in
 871 darwin*)
 872     dri_platform='apple' ;;
 873 gnu*|mingw*|cygwin*)
 874     dri_platform='none' ;;
 875 *)
 876     dri_platform='drm' ;;
 877 esac
 878
 879 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 880 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 881 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 882 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 883 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 884
 885 AC_ARG_ENABLE([shared-glapi],
 886     [AS_HELP_STRING([--enable-shared-glapi],
 887         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 888     [enable_shared_glapi="$enableval"],
 889     [enable_shared_glapi=yes])
 890
 891 case "x$enable_opengl$enable_gles1$enable_gles2" in
 892 x*yes*yes*)
 893     if test "x$enable_shared_glapi" = xno; then
 894         AC_MSG_ERROR([shared GLAPI required when building two or more of
 895                       the following APIs - opengl, gles1 gles2])
 896     fi
 897     ;;
 898 esac
 899
 900 # Building Xlib-GLX requires shared glapi to be disabled.
 901 if test "x$enable_xlib_glx" = xyes; then
 902     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 903     enable_shared_glapi=no
 904 fi
 905
 906 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 907
 908 # Build the pipe-drivers as separate libraries/modules.
 909 # Do not touch this unless you know what you are doing.
 910 # XXX: Expose via configure option ?
 911 enable_shared_pipe_drivers=no
 912
 913 dnl
 914 dnl Driver specific build directories
 915 dnl
 916
 917 case "x$enable_glx$enable_xlib_glx" in
 918 xyesyes)
 919     NEED_WINSYS_XLIB="yes"
 920     ;;
 921 esac
 922
 923 if test "x$enable_dri" = xyes; then
 924     enable_gallium_loader="$enable_shared_pipe_drivers"
 925 fi
 926
 927 if test "x$enable_gallium_osmesa" = xyes; then
 928     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 929         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 930     fi
 931     if test "x$enable_osmesa" = xyes; then
 932         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 933     fi
 934 fi
 935
 936 AC_SUBST([MESA_LLVM])
 937
 938 # SHA1 hashing
 939 AC_ARG_WITH([sha1],
 940         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 941         [choose SHA1 implementation])])
 942 case "x$with_sha1" in
 943 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 944   ;;
 945 *)
 946         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 947 esac
 948
 949 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 950 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 951         with_sha1=libc
 952 fi
 953 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 954         AC_MSG_ERROR([sha1 in libc requested but not found])
 955 fi
 956 if test "x$with_sha1" = xlibc; then
 957         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 958                 [Use libc SHA1 functions])
 959         SHA1_LIBS=""
 960 fi
 961 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 962 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 963         with_sha1=CommonCrypto
 964 fi
 965 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
 966         AC_MSG_ERROR([CommonCrypto requested but not found])
 967 fi
 968 if test "x$with_sha1" = xCommonCrypto; then
 969         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
 970                 [Use CommonCrypto SHA1 functions])
 971         SHA1_LIBS=""
 972 fi
 973 dnl stdcall functions cannot be tested with AC_CHECK_LIB
 974 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
 975 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
 976         with_sha1=CryptoAPI
 977 fi
 978 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
 979         AC_MSG_ERROR([CryptoAPI requested but not found])
 980 fi
 981 if test "x$with_sha1" = xCryptoAPI; then
 982         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
 983                 [Use CryptoAPI SHA1 functions])
 984         SHA1_LIBS=""
 985 fi
 986 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
 987 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
 988         with_sha1=libmd
 989 fi
 990 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
 991         AC_MSG_ERROR([libmd requested but not found])
 992 fi
 993 if test "x$with_sha1" = xlibmd; then
 994         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
 995                   [Use libmd SHA1 functions])
 996         SHA1_LIBS=-lmd
 997 fi
 998 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
 999 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1000    with_sha1=libsha1
1001 fi
1002 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1003         AC_MSG_ERROR([libsha1 requested but not found])
1004 fi
1005 if test "x$with_sha1" = xlibsha1; then
1006         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1007                   [Use libsha1 for SHA1])
1008         SHA1_LIBS=-lsha1
1009 fi
1010 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1011 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1012         with_sha1=libnettle
1013 fi
1014 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1015         AC_MSG_ERROR([libnettle requested but not found])
1016 fi
1017 if test "x$with_sha1" = xlibnettle; then
1018         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1019                   [Use libnettle SHA1 functions])
1020         SHA1_LIBS=-lnettle
1021 fi
1022 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1023 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1024         with_sha1=libgcrypt
1025 fi
1026 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1027         AC_MSG_ERROR([libgcrypt requested but not found])
1028 fi
1029 if test "x$with_sha1" = xlibgcrypt; then
1030         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1031                   [Use libgcrypt SHA1 functions])
1032         SHA1_LIBS=-lgcrypt
1033 fi
1034 # We don't need all of the OpenSSL libraries, just libcrypto
1035 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1036 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1037                   [HAVE_OPENSSL_PKC=no])
1038 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1039         if test "x$with_sha1" = x; then
1040                 with_sha1=libcrypto
1041         fi
1042 else
1043         if test "x$with_sha1" = xlibcrypto; then
1044                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1045         fi
1046 fi
1047 if test "x$with_sha1" = xlibcrypto; then
1048         if test "x$HAVE_LIBCRYPTO" = xyes; then
1049                 SHA1_LIBS=-lcrypto
1050         else
1051                 SHA1_LIBS="$OPENSSL_LIBS"
1052                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1053         fi
1054 fi
1055 AC_MSG_CHECKING([for SHA1 implementation])
1056 AC_MSG_RESULT([$with_sha1])
1057 AC_SUBST(SHA1_LIBS)
1058 AC_SUBST(SHA1_CFLAGS)
1059
1060 # Allow user to configure out the shader-cache feature
1061 AC_ARG_ENABLE([shader-cache],
1062     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1063     [enable_shader_cache="$enableval"],
1064     [if test "x$with_sha1" != "x"; then
1065         enable_shader_cache=yes
1066      else
1067         enable_shader_cache=no
1068      fi])
1069 if test "x$with_sha1" = "x"; then
1070     if test "x$enable_shader_cache" = "xyes"; then
1071         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1072     fi
1073 fi
1074 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1075
1076 # Check for libdrm
1077 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1078                   [have_libdrm=yes], [have_libdrm=no])
1079 if test "x$have_libdrm" = xyes; then
1080         DEFINES="$DEFINES -DHAVE_LIBDRM"
1081 fi
1082
1083 case "$host_os" in
1084 linux*)
1085     need_pci_id=yes ;;
1086 *)
1087     need_pci_id=no ;;
1088 esac
1089
1090 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1091                   have_libudev=yes, have_libudev=no)
1092
1093 AC_ARG_ENABLE([sysfs],
1094     [AS_HELP_STRING([--enable-sysfs],
1095         [enable /sys PCI identification @<:@default=disabled@:>@])],
1096     [have_sysfs="$enableval"],
1097     [have_sysfs=no]
1098 )
1099
1100 if test "x$enable_dri" = xyes; then
1101     if test "$enable_static" = yes; then
1102         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1103     fi
1104
1105     # not a hard requirement as swrast does not depend on it
1106     if test "x$have_libdrm" = xyes; then
1107         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1108     fi
1109 fi
1110
1111 AC_ARG_ENABLE([driglx-direct],
1112     [AS_HELP_STRING([--disable-driglx-direct],
1113         [disable direct rendering in GLX and EGL for DRI \
1114             @<:@default=auto@:>@])],
1115     [driglx_direct="$enableval"],
1116     [driglx_direct="yes"])
1117
1118 dnl
1119 dnl libGL configuration per driver
1120 dnl
1121 case "x$enable_glx$enable_xlib_glx" in
1122 xyesyes)
1123     # Xlib-based GLX
1124     dri_modules="x11 xext xcb"
1125     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1126     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1127     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1128     GL_LIB_DEPS="$XLIBGL_LIBS"
1129     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1130     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1131     ;;
1132 xyesno)
1133     # DRI-based GLX
1134     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1135
1136     # find the DRI deps for libGL
1137     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1138
1139     if test x"$driglx_direct" = xyes; then
1140         if test x"$dri_platform" = xdrm ; then
1141             DEFINES="$DEFINES -DGLX_USE_DRM"
1142             if test "x$have_libdrm" != xyes; then
1143                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1144             fi
1145
1146             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1147             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1148             if test x"$enable_dri3" = xyes; then
1149                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1150                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1151             fi
1152
1153             if test x"$enable_dri" = xyes; then
1154                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1155             fi
1156
1157             if test x"$enable_dri3" = xyes; then
1158                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1159                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1160             fi
1161         fi
1162         if test x"$dri_platform" = xapple ; then
1163             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1164         fi
1165     fi
1166
1167     # add xf86vidmode if available
1168     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1169     if test "$HAVE_XF86VIDMODE" = yes ; then
1170         dri_modules="$dri_modules xxf86vm"
1171     fi
1172
1173     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1174     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1175     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1176     GL_LIB_DEPS="$DRIGL_LIBS"
1177
1178     # need DRM libs, $PTHREAD_LIBS, etc.
1179     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1180     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1181     ;;
1182 esac
1183
1184 have_pci_id=no
1185 if test "$have_libudev" = yes; then
1186     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1187     have_pci_id=yes
1188 fi
1189
1190 if test "$have_sysfs" = yes; then
1191     DEFINES="$DEFINES -DHAVE_SYSFS"
1192     have_pci_id=yes
1193 fi
1194
1195 # This is outside the case (above) so that it is invoked even for non-GLX
1196 # builds.
1197 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1198
1199 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1200 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1201 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1202 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1203
1204 AC_SUBST([X11_INCLUDES])
1205 AC_SUBST([GL_LIB_DEPS])
1206 AC_SUBST([GL_PC_REQ_PRIV])
1207 AC_SUBST([GL_PC_LIB_PRIV])
1208 AC_SUBST([GL_PC_CFLAGS])
1209 AC_SUBST([DRI_PC_REQ_PRIV])
1210 AC_SUBST([GLESv1_CM_LIB_DEPS])
1211 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1212 AC_SUBST([GLESv2_LIB_DEPS])
1213 AC_SUBST([GLESv2_PC_LIB_PRIV])
1214
1215 AC_SUBST([HAVE_XF86VIDMODE])
1216
1217 dnl
1218 dnl More GLX setup
1219 dnl
1220 case "x$enable_glx$enable_xlib_glx" in
1221 xyesyes)
1222     DEFINES="$DEFINES -DUSE_XSHM"
1223     ;;
1224 xyesno)
1225     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1226     if test "x$driglx_direct" = xyes; then
1227         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1228     fi
1229     ;;
1230 esac
1231
1232 dnl
1233 dnl TLS detection
1234 dnl
1235
1236 AC_ARG_ENABLE([glx-tls],
1237     [AS_HELP_STRING([--enable-glx-tls],
1238         [enable TLS support in GLX @<:@default=disabled@:>@])],
1239     [GLX_USE_TLS="$enableval"],
1240     [GLX_USE_TLS=no])
1241 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1242
1243 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1244       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1245
1246 dnl
1247 dnl More DRI setup
1248 dnl
1249 dnl Directory for DRI drivers
1250 AC_ARG_WITH([dri-driverdir],
1251     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1252         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1253     [DRI_DRIVER_INSTALL_DIR="$withval"],
1254     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1255 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1256 dnl Extra search path for DRI drivers
1257 AC_ARG_WITH([dri-searchpath],
1258     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1259         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1260     [DRI_DRIVER_SEARCH_DIR="$withval"],
1261     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1262 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1263 dnl Which drivers to build - default is chosen by platform
1264 AC_ARG_WITH([dri-drivers],
1265     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1266         [comma delimited classic DRI drivers list, e.g.
1267         "swrast,i965,radeon" @<:@default=auto@:>@])],
1268     [with_dri_drivers="$withval"],
1269     [with_dri_drivers=auto])
1270
1271 if test "x$with_dri_drivers" = xauto; then
1272     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1273         with_dri_drivers="yes"
1274     else
1275         with_dri_drivers="no"
1276     fi
1277 fi
1278 if test "x$with_dri_drivers" = xno; then
1279     with_dri_drivers=''
1280 fi
1281
1282 dnl If $with_dri_drivers is yes, drivers will be added through
1283 dnl platform checks. Set DEFINES and LIB_DEPS
1284 if test "x$enable_dri" = xyes; then
1285     # Platform specific settings and drivers to build
1286     case "$host_os" in
1287     linux*)
1288         DEFINES="$DEFINES -DHAVE_ALIAS"
1289         if test "x$enable_dri3" = xyes; then
1290             DEFINES="$DEFINES -DHAVE_DRI3"
1291         fi
1292
1293         if test "x$have_pci_id" != xyes; then
1294             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1295         fi
1296
1297         case "$host_cpu" in
1298         powerpc* | sparc*)
1299             # Build only the drivers for cards that exist on PowerPC/sparc
1300             if test "x$with_dri_drivers" = "xyes"; then
1301                 with_dri_drivers="r200 radeon swrast"
1302             fi
1303             ;;
1304         esac
1305         ;;
1306     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1307         DEFINES="$DEFINES -DHAVE_ALIAS"
1308         ;;
1309     gnu*)
1310         DEFINES="$DEFINES -DHAVE_ALIAS"
1311         ;;
1312     cygwin*)
1313         if test "x$with_dri_drivers" = "xyes"; then
1314             with_dri_drivers="swrast"
1315         fi
1316         ;;
1317     darwin*)
1318         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1319         if test "x$with_dri_drivers" = "xyes"; then
1320             with_dri_drivers="swrast"
1321         fi
1322         ;;
1323     esac
1324
1325     # default drivers
1326     if test "x$with_dri_drivers" = "xyes"; then
1327         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1328     fi
1329
1330     # Check for expat
1331     PKG_CHECK_MODULES([EXPAT], [expat], [],
1332         # expat version 2.0 and earlier do not provide expat.pc
1333         [AC_CHECK_HEADER([expat.h],[],
1334                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1335          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1336                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1337          EXPAT_LIBS="-lexpat"])
1338
1339     DRICOMMON_NEED_LIBDRM=no
1340     # If we are building any DRI driver other than swrast.
1341     if test -n "$with_dri_drivers"; then
1342         if test "x$with_dri_drivers" != xswrast; then
1343             # ... libdrm is required
1344             if test "x$have_libdrm" != xyes; then
1345                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1346             fi
1347             DRICOMMON_NEED_LIBDRM=yes
1348         fi
1349     fi
1350
1351     # If we're building any gallium DRI driver other than swrast
1352     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1353         if test "x$with_gallium_drivers" != xswrast; then
1354             # ... build a libdrm aware dricommon
1355             DRICOMMON_NEED_LIBDRM=yes
1356         fi
1357     fi
1358
1359     # put all the necessary libs together
1360     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1361 fi
1362
1363 AC_SUBST([DRI_LIB_DEPS])
1364
1365 DRI_DIRS=''
1366 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1367 if test -n "$with_dri_drivers"; then
1368     if test "x$enable_opengl" != xyes; then
1369         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1370     fi
1371
1372     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1373     for driver in $dri_drivers; do
1374         DRI_DIRS="$DRI_DIRS $driver"
1375         case "x$driver" in
1376         xi915)
1377             HAVE_I915_DRI=yes;
1378             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1379             ;;
1380         xi965)
1381             HAVE_I965_DRI=yes;
1382             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1383             ;;
1384         xnouveau)
1385             HAVE_NOUVEAU_DRI=yes;
1386             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1387             ;;
1388         xradeon)
1389             HAVE_RADEON_DRI=yes;
1390             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1391             ;;
1392         xr200)
1393             HAVE_R200_DRI=yes;
1394             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1395             ;;
1396         xswrast)
1397             HAVE_SWRAST_DRI=yes;
1398             ;;
1399         *)
1400             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1401             ;;
1402         esac
1403     done
1404     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1405 fi
1406
1407 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1408 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1409                                   "x$enable_osmesa" = xyes -o \
1410                                   -n "$DRI_DIRS")
1411
1412 dnl
1413 dnl OSMesa configuration
1414 dnl
1415
1416 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1417 AC_ARG_WITH([osmesa-bits],
1418     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1419         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1420     [osmesa_bits="$withval"],
1421     [osmesa_bits=8])
1422 if test "x$osmesa_bits" != x8; then
1423     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1424         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1425         osmesa_bits=8
1426     fi
1427 fi
1428 case "x$osmesa_bits" in
1429 x8)
1430     OSMESA_LIB="${OSMESA_LIB}"
1431     ;;
1432 x16|x32)
1433     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1434     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1435     ;;
1436 *)
1437     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1438     ;;
1439 esac
1440
1441 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1442     # only link libraries with osmesa if shared
1443     if test "$enable_static" = no; then
1444         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1445     else
1446         OSMESA_LIB_DEPS=""
1447     fi
1448     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1449 fi
1450
1451 AC_SUBST([OSMESA_LIB_DEPS])
1452 AC_SUBST([OSMESA_PC_REQ])
1453 AC_SUBST([OSMESA_PC_LIB_PRIV])
1454
1455 dnl
1456 dnl gbm configuration
1457 dnl
1458 if test "x$enable_gbm" = xauto; then
1459     case "$with_egl_platforms" in
1460         *drm*)
1461             enable_gbm=yes ;;
1462          *)
1463             enable_gbm=no ;;
1464     esac
1465 fi
1466 if test "x$enable_gbm" = xyes; then
1467     if test "x$need_pci_id$have_pci_id" = xyesno; then
1468         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1469     fi
1470
1471     if test "x$enable_dri" = xyes; then
1472         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1473         if test "x$enable_shared_glapi" = xno; then
1474             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1475         fi
1476     else
1477         # Strictly speaking libgbm does not require --enable-dri, although
1478         # both of its backends do. Thus one can build libgbm without any
1479         # backends if --disable-dri is set.
1480         # To avoid unnecessary complexity of checking if at least one backend
1481         # is available when building, just mandate --enable-dri.
1482         AC_MSG_ERROR([gbm requires --enable-dri])
1483     fi
1484 fi
1485 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1486 if test "x$need_pci_id$have_libudev" = xyesyes; then
1487     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1488 else
1489     GBM_PC_REQ_PRIV=""
1490 fi
1491 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1492 AC_SUBST([GBM_PC_REQ_PRIV])
1493 AC_SUBST([GBM_PC_LIB_PRIV])
1494
1495 dnl
1496 dnl EGL configuration
1497 dnl
1498 EGL_CLIENT_APIS=""
1499
1500 if test "x$enable_egl" = xyes; then
1501     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1502
1503     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1504
1505     if test "$enable_static" != yes; then
1506         if test "x$enable_dri" = xyes; then
1507             HAVE_EGL_DRIVER_DRI2=1
1508         fi
1509
1510     fi
1511 fi
1512 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1513 AC_SUBST([EGL_LIB_DEPS])
1514
1515 dnl
1516 dnl XA configuration
1517 dnl
1518 if test "x$enable_xa" = xyes; then
1519     if test "x$with_gallium_drivers" = xswrast; then
1520        AC_MSG_ERROR([
1521           Building xa requires at least one non swrast gallium driver.
1522           If you are looking to use libxatracker.so with the VMware driver,
1523           make sure to include svga in the gallium drivers list, apart from
1524           enabling XA.
1525           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1526     fi
1527     enable_gallium_loader=$enable_shared_pipe_drivers
1528 fi
1529 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1530
1531 dnl
1532 dnl OpenVG configuration
1533 dnl
1534 VG_LIB_DEPS=""
1535
1536 if test "x$enable_openvg" = xyes; then
1537     if test "x$enable_egl" = xno; then
1538         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1539     fi
1540     if test -z "$with_gallium_drivers"; then
1541         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1542     fi
1543
1544     AC_MSG_ERROR([Cannot enable OpenVG, because egl_gallium has been removed and
1545                   OpenVG has not been integrated into standard libEGL yet])
1546
1547     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1548     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1549     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1550     AC_SUBST([VG_PC_LIB_PRIV])
1551 fi
1552 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1553
1554 dnl
1555 dnl Gallium G3DVL configuration
1556 dnl
1557 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1558     if test "x$enable_xvmc" = xauto; then
1559         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1560     fi
1561
1562     if test "x$enable_vdpau" = xauto; then
1563         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1564     fi
1565
1566     if test "x$enable_omx" = xauto; then
1567         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1568     fi
1569
1570     if test "x$enable_va" = xauto; then
1571         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1572     fi
1573 fi
1574
1575 if test "x$enable_dri" = xyes -o \
1576         "x$enable_xvmc" = xyes -o \
1577         "x$enable_vdpau" = xyes -o \
1578         "x$enable_omx" = xyes -o \
1579         "x$enable_va" = xyes; then
1580     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1581     need_gallium_vl=yes
1582 fi
1583 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1584
1585 if test "x$enable_xvmc" = xyes; then
1586     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1587     enable_gallium_loader=$enable_shared_pipe_drivers
1588 fi
1589 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1590
1591 if test "x$enable_vdpau" = xyes; then
1592     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1593     enable_gallium_loader=$enable_shared_pipe_drivers
1594 fi
1595 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1596
1597 if test "x$enable_omx" = xyes; then
1598     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1599     enable_gallium_loader=$enable_shared_pipe_drivers
1600 fi
1601 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1602
1603 if test "x$enable_va" = xyes; then
1604     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1605     enable_gallium_loader=$enable_shared_pipe_drivers
1606 fi
1607 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1608
1609 dnl
1610 dnl Nine Direct3D9 configuration
1611 dnl
1612 if test "x$enable_nine" = xyes; then
1613     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1614         AC_MSG_ERROR([nine requires the gallium swrast driver])
1615     fi
1616     if test "x$with_gallium_drivers" == xswrast; then
1617         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1618     fi
1619     if test "x$enable_dri3" = xno; then
1620         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1621     fi
1622
1623     enable_gallium_loader=$enable_shared_pipe_drivers
1624 fi
1625 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1626
1627 dnl
1628 dnl OpenCL configuration
1629 dnl
1630
1631 AC_ARG_WITH([libclc-path],
1632    [AS_HELP_STRING([--with-libclc-path],
1633          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1634    [LIBCLC_PATH="$withval"],
1635    [LIBCLC_PATH=''])
1636
1637 if test -n "$LIBCLC_PATH"; then
1638    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1639                   Please review the updated build instructions for clover:
1640                   http://dri.freedesktop.org/wiki/GalliumCompute])
1641 fi
1642
1643
1644 AC_ARG_WITH([clang-libdir],
1645    [AS_HELP_STRING([--with-clang-libdir],
1646          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1647    [CLANG_LIBDIR="$withval"],
1648    [CLANG_LIBDIR=''])
1649
1650 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1651 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1652
1653 if test "x$enable_opencl" = xyes; then
1654     if test -z "$with_gallium_drivers"; then
1655         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1656     fi
1657
1658     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1659         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1660     fi
1661
1662     if test "x$have_libclc" = xno; then
1663         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1664                     Make sure the directory containing libclc.pc is specified in your
1665                     PKG_CONFIG_PATH environment variable.
1666                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1667     else
1668         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1669         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1670         AC_SUBST([LIBCLC_INCLUDEDIR])
1671         AC_SUBST([LIBCLC_LIBEXECDIR])
1672     fi
1673
1674     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1675     enable_gallium_loader=yes
1676
1677     if test "x$enable_opencl_icd" = xyes; then
1678         OPENCL_LIBNAME="MesaOpenCL"
1679     else
1680         OPENCL_LIBNAME="OpenCL"
1681     fi
1682
1683     if test "x$have_libelf" != xyes; then
1684        AC_MSG_ERROR([Clover requires libelf])
1685     fi
1686 fi
1687 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1688 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1689 AC_SUBST([OPENCL_LIBNAME])
1690
1691 dnl
1692 dnl Gallium configuration
1693 dnl
1694 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1695
1696 AC_SUBST([LLVM_BINDIR])
1697 AC_SUBST([LLVM_CFLAGS])
1698 AC_SUBST([LLVM_CPPFLAGS])
1699 AC_SUBST([LLVM_CXXFLAGS])
1700 AC_SUBST([LLVM_LIBDIR])
1701 AC_SUBST([LLVM_LIBS])
1702 AC_SUBST([LLVM_LDFLAGS])
1703 AC_SUBST([LLVM_INCLUDEDIR])
1704 AC_SUBST([LLVM_VERSION])
1705 AC_SUBST([CLANG_RESOURCE_DIR])
1706
1707 case "x$enable_opengl$enable_gles1$enable_gles2" in
1708 x*yes*)
1709     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1710     ;;
1711 esac
1712
1713 AC_SUBST([VG_LIB_DEPS])
1714 AC_SUBST([EGL_CLIENT_APIS])
1715
1716 dnl
1717 dnl EGL Platforms configuration
1718 dnl
1719 AC_ARG_WITH([egl-platforms],
1720     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1721         [comma delimited native platforms libEGL supports, e.g.
1722         "x11,drm" @<:@default=auto@:>@])],
1723     [with_egl_platforms="$withval"],
1724     [if test "x$enable_egl" = xyes; then
1725         with_egl_platforms="x11"
1726     else
1727         with_egl_platforms=""
1728     fi])
1729
1730 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1731     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1732 fi
1733
1734 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1735         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1736         WAYLAND_SCANNER='')
1737 if test "x$WAYLAND_SCANNER" = x; then
1738     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1739 fi
1740
1741 # Do per-EGL platform setups and checks
1742 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1743 for plat in $egl_platforms; do
1744         case "$plat" in
1745         wayland)
1746                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1747
1748                 if test "x$WAYLAND_SCANNER" = x; then
1749                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1750                 fi
1751                 ;;
1752
1753         x11)
1754                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1755                 ;;
1756
1757         drm)
1758                 test "x$enable_gbm" = "xno" &&
1759                         AC_MSG_ERROR([EGL platform drm needs gbm])
1760                 test "x$have_libdrm" != xyes &&
1761                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1762                 ;;
1763
1764         android|fbdev|gdi|null)
1765                 ;;
1766
1767         *)
1768                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1769                 ;;
1770         esac
1771
1772         case "$plat$need_pci_id$have_pci_id" in
1773                 waylandyesno|drmyesno)
1774                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1775         esac
1776 done
1777
1778 # libEGL wants to default to the first platform specified in
1779 # ./configure.  parse that here.
1780 if test "x$egl_platforms" != "x"; then
1781     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1782     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1783 else
1784     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1785 fi
1786
1787 if echo "$egl_platforms" | grep -q 'x11'; then
1788     NEED_WINSYS_XLIB=yes
1789 fi
1790 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1791 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1792 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1793 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1794 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1795
1796 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1797
1798 AC_SUBST([EGL_NATIVE_PLATFORM])
1799 AC_SUBST([EGL_CFLAGS])
1800
1801 # If we don't have the X11 platform, set this define so we don't try to include
1802 # the X11 headers.
1803 if ! echo "$egl_platforms" | grep -q 'x11'; then
1804     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1805     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1806 fi
1807
1808 AC_ARG_WITH([max-width],
1809     [AS_HELP_STRING([--with-max-width=N],
1810                     [Maximum framebuffer width (4096)])],
1811     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1812      AS_IF([test "${withval}" -gt "4096"],
1813            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1814 )
1815 AC_ARG_WITH([max-height],
1816     [AS_HELP_STRING([--with-max-height=N],
1817                     [Maximum framebuffer height (4096)])],
1818     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1819      AS_IF([test "${withval}" -gt "4096"],
1820            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1821 )
1822
1823 dnl
1824 dnl Gallium LLVM
1825 dnl
1826 AC_ARG_ENABLE([gallium-llvm],
1827     [AS_HELP_STRING([--enable-gallium-llvm],
1828         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1829     [enable_gallium_llvm="$enableval"],
1830     [enable_gallium_llvm=auto])
1831
1832 AC_ARG_ENABLE([llvm-shared-libs],
1833     [AS_HELP_STRING([--enable-llvm-shared-libs],
1834         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1835     [enable_llvm_shared_libs="$enableval"],
1836     [enable_llvm_shared_libs=yes])
1837
1838 AC_ARG_WITH([llvm-prefix],
1839     [AS_HELP_STRING([--with-llvm-prefix],
1840         [Prefix for LLVM installations in non-standard locations])],
1841     [llvm_prefix="$withval"],
1842     [llvm_prefix=''])
1843
1844
1845 # Call this inside ` ` to get the return value.
1846 # $1 is the llvm-config command with arguments.
1847 strip_unwanted_llvm_flags() {
1848     # Use \> (marks the end of the word)
1849     echo `$1` | sed \
1850         -e 's/-DNDEBUG\>//g' \
1851         -e 's/-D_GNU_SOURCE\>//g' \
1852         -e 's/-pedantic\>//g' \
1853         -e 's/-Wcovered-switch-default\>//g' \
1854         -e 's/-O.\>//g' \
1855         -e 's/-g\>//g' \
1856         -e 's/-Wall\>//g' \
1857         -e 's/-Wcast-qual\>//g' \
1858         -e 's/-Woverloaded-virtual\>//g' \
1859         -e 's/-fcolor-diagnostics\>//g' \
1860         -e 's/-fdata-sections\>//g' \
1861         -e 's/-ffunction-sections\>//g' \
1862         -e 's/-fno-exceptions\>//g' \
1863         -e 's/-fomit-frame-pointer\>//g' \
1864         -e 's/-fvisibility-inlines-hidden\>//g' \
1865         -e 's/-fPIC\>//g' \
1866         -e 's/-fstack-protector-strong\>//g'
1867 }
1868
1869
1870 if test -z "$with_gallium_drivers"; then
1871     enable_gallium_llvm=no
1872 fi
1873 if test "x$enable_gallium_llvm" = xauto; then
1874     case "$host_cpu" in
1875     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1876     esac
1877 fi
1878 if test "x$enable_gallium_llvm" = xyes; then
1879     if test -n "$llvm_prefix"; then
1880         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1881     else
1882         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1883     fi
1884
1885     if test "x$LLVM_CONFIG" != xno; then
1886         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1887         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1888         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1889         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1890         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1891         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1892         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1893         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1894
1895         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1896             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1897         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1898             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1899
1900         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1901         if test -z "$LLVM_VERSION_PATCH"; then
1902             LLVM_VERSION_PATCH=0
1903         fi
1904
1905         if test -n "${LLVM_VERSION_MAJOR}"; then
1906             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1907         else
1908             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1909         fi
1910
1911         LLVM_REQUIRED_VERSION_MAJOR="3"
1912         LLVM_REQUIRED_VERSION_MINOR="3"
1913         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1914             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1915         fi
1916
1917         LLVM_COMPONENTS="engine bitwriter"
1918         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1919             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1920         fi
1921
1922         if test "x$enable_opencl" = xyes; then
1923             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1924             # LLVM 3.3 >= 177971 requires IRReader
1925             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1926                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1927             fi
1928             # LLVM 3.4 requires Option
1929             if $LLVM_CONFIG --components | grep -qw 'option'; then
1930                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1931             fi
1932             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1933             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1934                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1935             fi
1936             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1937                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1938             fi
1939         fi
1940         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1941         MESA_LLVM=1
1942
1943         dnl Check for Clang internal headers
1944         if test "x$enable_opencl" = xyes; then
1945             if test -z "$CLANG_LIBDIR"; then
1946                 CLANG_LIBDIR=${LLVM_LIBDIR}
1947             fi
1948             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1949             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1950                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1951         fi
1952     else
1953         MESA_LLVM=0
1954         LLVM_VERSION_INT=0
1955     fi
1956 else
1957     MESA_LLVM=0
1958     LLVM_VERSION_INT=0
1959
1960     if test "x$enable_opencl" = xyes; then
1961         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1962     fi
1963 fi
1964
1965 dnl Directory for XVMC libs
1966 AC_ARG_WITH([xvmc-libdir],
1967     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1968         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1969     [XVMC_LIB_INSTALL_DIR="$withval"],
1970     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1971 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1972
1973 dnl
1974 dnl Gallium Tests
1975 dnl
1976 if test "x$enable_gallium_tests" = xyes; then
1977     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1978     enable_gallium_loader=yes
1979 fi
1980 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1981
1982 dnl Directory for VDPAU libs
1983 AC_ARG_WITH([vdpau-libdir],
1984     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1985         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1986     [VDPAU_LIB_INSTALL_DIR="$withval"],
1987     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1988 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1989
1990 dnl Directory for OMX libs
1991
1992 AC_ARG_WITH([omx-libdir],
1993     [AS_HELP_STRING([--with-omx-libdir=DIR],
1994         [directory for the OMX libraries])],
1995     [OMX_LIB_INSTALL_DIR="$withval"],
1996     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1997 AC_SUBST([OMX_LIB_INSTALL_DIR])
1998
1999 dnl Directory for VA libs
2000
2001 AC_ARG_WITH([va-libdir],
2002     [AS_HELP_STRING([--with-va-libdir=DIR],
2003         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2004     [VA_LIB_INSTALL_DIR="$withval"],
2005     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2006 AC_SUBST([VA_LIB_INSTALL_DIR])
2007
2008 AC_ARG_WITH([d3d-libdir],
2009     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2010         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2011     [D3D_DRIVER_INSTALL_DIR="$withval"],
2012     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2013 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2014
2015 dnl
2016 dnl Gallium helper functions
2017 dnl
2018 gallium_require_drm() {
2019     if test "x$have_libdrm" != xyes; then
2020        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2021     fi
2022 }
2023
2024 gallium_require_llvm() {
2025     if test "x$MESA_LLVM" = x0; then
2026         case "$host" in *gnux32) return;; esac
2027         case "$host_cpu" in
2028         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2029         esac
2030     fi
2031 }
2032
2033 gallium_require_drm_loader() {
2034     if test "x$enable_gallium_loader" = xyes; then
2035         if test "x$need_pci_id$have_pci_id" = xyesno; then
2036             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2037         fi
2038         enable_gallium_drm_loader=yes
2039     fi
2040     if test "x$enable_va" = xyes && test "x$7" != x; then
2041          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2042     fi
2043 }
2044
2045 require_egl_drm() {
2046     case "$with_egl_platforms" in
2047         *drm*)
2048             ;;
2049          *)
2050             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2051             ;;
2052     esac
2053     if test "x$enable_gbm" != xyes; then
2054             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2055     fi
2056 }
2057
2058 radeon_llvm_check() {
2059     if test "x$enable_gallium_llvm" != "xyes"; then
2060         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2061     fi
2062     LLVM_REQUIRED_VERSION_MAJOR="3"
2063     LLVM_REQUIRED_VERSION_MINOR="4"
2064     LLVM_REQUIRED_VERSION_PATCH="2"
2065     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2066         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2067     fi
2068     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2069         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2070                       sources with the --enable-experimental-targets=R600
2071                       configure flag])
2072     fi
2073     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2074     NEED_RADEON_LLVM=yes
2075     if test "x$have_libelf" != xyes; then
2076        AC_MSG_ERROR([$1 requires libelf when using llvm])
2077     fi
2078 }
2079
2080 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2081 if test -n "$with_gallium_drivers"; then
2082     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2083     for driver in $gallium_drivers; do
2084         case "x$driver" in
2085         xsvga)
2086             HAVE_GALLIUM_SVGA=yes
2087             gallium_require_drm "svga"
2088             gallium_require_drm_loader
2089             ;;
2090         xi915)
2091             HAVE_GALLIUM_I915=yes
2092             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2093             gallium_require_drm "Gallium i915"
2094             gallium_require_drm_loader
2095             ;;
2096         xilo)
2097             HAVE_GALLIUM_ILO=yes
2098             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2099             gallium_require_drm "Gallium i965/ilo"
2100             gallium_require_drm_loader
2101             ;;
2102         xr300)
2103             HAVE_GALLIUM_R300=yes
2104             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2105             gallium_require_drm "Gallium R300"
2106             gallium_require_drm_loader
2107             gallium_require_llvm "Gallium R300"
2108             ;;
2109         xr600)
2110             HAVE_GALLIUM_R600=yes
2111             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2112             gallium_require_drm "Gallium R600"
2113             gallium_require_drm_loader
2114             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2115                 radeon_llvm_check "r600g"
2116                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2117             fi
2118             if test "x$enable_r600_llvm" = xyes; then
2119                 USE_R600_LLVM_COMPILER=yes;
2120             fi
2121             if test "x$enable_opencl" = xyes; then
2122                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2123             fi
2124             ;;
2125         xradeonsi)
2126             HAVE_GALLIUM_RADEONSI=yes
2127             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2128             gallium_require_drm "radeonsi"
2129             gallium_require_drm_loader
2130             radeon_llvm_check "radeonsi"
2131             require_egl_drm "radeonsi"
2132             ;;
2133         xnouveau)
2134             HAVE_GALLIUM_NOUVEAU=yes
2135             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2136             gallium_require_drm "nouveau"
2137             gallium_require_drm_loader
2138             ;;
2139         xfreedreno)
2140             HAVE_GALLIUM_FREEDRENO=yes
2141             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2142             gallium_require_drm "freedreno"
2143             gallium_require_drm_loader
2144             ;;
2145         xswrast)
2146             HAVE_GALLIUM_SOFTPIPE=yes
2147             if test "x$MESA_LLVM" = x1; then
2148                 HAVE_GALLIUM_LLVMPIPE=yes
2149             fi
2150             ;;
2151         xvc4)
2152             HAVE_GALLIUM_VC4=yes
2153             gallium_require_drm "vc4"
2154             gallium_require_drm_loader
2155
2156             case "$host_cpu" in
2157                 i?86 | x86_64 | amd64)
2158                 USE_VC4_SIMULATOR=yes
2159                 ;;
2160             esac
2161             ;;
2162         *)
2163             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2164             ;;
2165         esac
2166     done
2167 fi
2168
2169 dnl Set LLVM_LIBS - This is done after the driver configuration so
2170 dnl that drivers can add additional components to LLVM_COMPONENTS.
2171 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2172 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2173 dnl this was causing the same libraries to be appear multiple times
2174 dnl in LLVM_LIBS.
2175
2176 if test "x$MESA_LLVM" != x0; then
2177
2178     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2179
2180     if test "x$enable_llvm_shared_libs" = xyes; then
2181         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2182         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2183         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2184
2185         if test "x$llvm_have_one_so" = xyes; then
2186             dnl LLVM was built using auto*, so there is only one shared object.
2187             LLVM_LIBS="-l$LLVM_SO_NAME"
2188         else
2189             dnl If LLVM was built with CMake, there will be one shared object per
2190             dnl component.
2191             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2192                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2193         Please make sure you have built llvm with the --enable-shared option
2194         and that your llvm libraries are installed in $LLVM_LIBDIR
2195         If you have installed your llvm libraries to a different directory you
2196         can use the --with-llvm-prefix= configure flag to specify this directory.
2197         NOTE: Mesa is attempting to use llvm shared libraries by default.
2198         If you do not want to build with llvm shared libraries and instead want to
2199         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2200         invocation and rebuild.])])
2201
2202            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2203            dnl install uses a shared object for each component and we have
2204            dnl already added all of these objects to LLVM_LIBS.
2205         fi
2206     else
2207         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2208         dnl We need to link to llvm system libs when using static libs
2209         dnl However, only llvm 3.5+ provides --system-libs
2210         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2211             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2212         fi
2213     fi
2214 fi
2215
2216 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2217 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2218 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2219 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2220 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2221 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2222 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2223                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2224 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2225 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2226 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2227 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2228 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2229
2230 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2231
2232 # NOTE: anything using xcb or other client side libs ends up in separate
2233 #       _CLIENT variables.  The pipe loader is built in two variants,
2234 #       one that is standalone and does not link any x client libs (for
2235 #       use by XA tracker in particular, but could be used in any case
2236 #       where communication with xserver is not desired).
2237 if test "x$enable_gallium_loader" = xyes; then
2238     if test "x$NEED_WINSYS_XLIB" = xyes; then
2239         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2240     fi
2241
2242     if test "x$enable_dri" = xyes; then
2243         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2244     fi
2245
2246     if test "x$enable_gallium_drm_loader" = xyes; then
2247         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2248         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2249                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2250         if test "x$pipe_loader_have_xcb" = xyes; then
2251             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2252             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2253         fi
2254     fi
2255
2256     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2257     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2258
2259     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2260     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2261     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2262     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2263 fi
2264
2265 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2266 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2267 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2268 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2269 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2270 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2271
2272 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2273                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2274                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2275 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2276 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2277 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2278 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2279 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2280 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2281 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2282 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2283 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2284     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2285 fi
2286
2287 AC_SUBST([ELF_LIB])
2288
2289 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2290 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2291 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2292 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2293 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2294
2295 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2296 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2297 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2298
2299 AC_SUBST([NINE_MAJOR], 1)
2300 AC_SUBST([NINE_MINOR], 0)
2301 AC_SUBST([NINE_TINY], 0)
2302 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2303
2304 AC_SUBST([VDPAU_MAJOR], 1)
2305 AC_SUBST([VDPAU_MINOR], 0)
2306
2307 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2308 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2309 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2310 AC_SUBST([VA_MINOR], $VA_MINOR)
2311
2312 AC_SUBST([XVMC_MAJOR], 1)
2313 AC_SUBST([XVMC_MINOR], 0)
2314
2315 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2316 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2317 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2318 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2319
2320 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2321 AC_SUBST([XA_MINOR], $XA_MINOR)
2322 AC_SUBST([XA_TINY], $XA_TINY)
2323 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2324
2325 dnl Restore LDFLAGS and CPPFLAGS
2326 LDFLAGS="$_SAVE_LDFLAGS"
2327 CPPFLAGS="$_SAVE_CPPFLAGS"
2328
2329 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2330 if test "x$acv_mesa_CLANG" = xyes; then
2331     CFLAGS="$CFLAGS -Qunused-arguments"
2332     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2333 fi
2334
2335 dnl Add user CFLAGS and CXXFLAGS
2336 CFLAGS="$CFLAGS $USER_CFLAGS"
2337 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2338
2339 dnl Substitute the config
2340 AC_CONFIG_FILES([Makefile
2341                 src/Makefile
2342                 src/egl/drivers/dri2/Makefile
2343                 src/egl/main/Makefile
2344                 src/egl/main/egl.pc
2345                 src/egl/wayland/wayland-drm/Makefile
2346                 src/egl/wayland/wayland-egl/Makefile
2347                 src/egl/wayland/wayland-egl/wayland-egl.pc
2348                 src/gallium/Makefile
2349                 src/gallium/auxiliary/Makefile
2350                 src/gallium/auxiliary/pipe-loader/Makefile
2351                 src/gallium/drivers/freedreno/Makefile
2352                 src/gallium/drivers/galahad/Makefile
2353                 src/gallium/drivers/i915/Makefile
2354                 src/gallium/drivers/identity/Makefile
2355                 src/gallium/drivers/ilo/Makefile
2356                 src/gallium/drivers/llvmpipe/Makefile
2357                 src/gallium/drivers/noop/Makefile
2358                 src/gallium/drivers/nouveau/Makefile
2359                 src/gallium/drivers/r300/Makefile
2360                 src/gallium/drivers/r600/Makefile
2361                 src/gallium/drivers/radeon/Makefile
2362                 src/gallium/drivers/radeonsi/Makefile
2363                 src/gallium/drivers/rbug/Makefile
2364                 src/gallium/drivers/softpipe/Makefile
2365                 src/gallium/drivers/svga/Makefile
2366                 src/gallium/drivers/trace/Makefile
2367                 src/gallium/drivers/vc4/Makefile
2368                 src/gallium/drivers/vc4/kernel/Makefile
2369                 src/gallium/state_trackers/clover/Makefile
2370                 src/gallium/state_trackers/dri/Makefile
2371                 src/gallium/state_trackers/glx/xlib/Makefile
2372                 src/gallium/state_trackers/nine/Makefile
2373                 src/gallium/state_trackers/omx/Makefile
2374                 src/gallium/state_trackers/osmesa/Makefile
2375                 src/gallium/state_trackers/va/Makefile
2376                 src/gallium/state_trackers/vdpau/Makefile
2377                 src/gallium/state_trackers/vega/Makefile
2378                 src/gallium/state_trackers/xa/Makefile
2379                 src/gallium/state_trackers/xvmc/Makefile
2380                 src/gallium/targets/d3dadapter9/Makefile
2381                 src/gallium/targets/d3dadapter9/d3d.pc
2382                 src/gallium/targets/dri/Makefile
2383                 src/gallium/targets/libgl-xlib/Makefile
2384                 src/gallium/targets/omx/Makefile
2385                 src/gallium/targets/opencl/Makefile
2386                 src/gallium/targets/osmesa/Makefile
2387                 src/gallium/targets/osmesa/osmesa.pc
2388                 src/gallium/targets/pipe-loader/Makefile
2389                 src/gallium/targets/va/Makefile
2390                 src/gallium/targets/vdpau/Makefile
2391                 src/gallium/targets/xa/Makefile
2392                 src/gallium/targets/xa/xatracker.pc
2393                 src/gallium/targets/xvmc/Makefile
2394                 src/gallium/tests/trivial/Makefile
2395                 src/gallium/tests/unit/Makefile
2396                 src/gallium/winsys/freedreno/drm/Makefile
2397                 src/gallium/winsys/i915/drm/Makefile
2398                 src/gallium/winsys/intel/drm/Makefile
2399                 src/gallium/winsys/nouveau/drm/Makefile
2400                 src/gallium/winsys/radeon/drm/Makefile
2401                 src/gallium/winsys/svga/drm/Makefile
2402                 src/gallium/winsys/sw/dri/Makefile
2403                 src/gallium/winsys/sw/fbdev/Makefile
2404                 src/gallium/winsys/sw/kms-dri/Makefile
2405                 src/gallium/winsys/sw/null/Makefile
2406                 src/gallium/winsys/sw/wayland/Makefile
2407                 src/gallium/winsys/sw/wrapper/Makefile
2408                 src/gallium/winsys/sw/xlib/Makefile
2409                 src/gallium/winsys/vc4/drm/Makefile
2410                 src/gbm/Makefile
2411                 src/gbm/main/gbm.pc
2412                 src/glsl/Makefile
2413                 src/glx/Makefile
2414                 src/glx/apple/Makefile
2415                 src/glx/tests/Makefile
2416                 src/gtest/Makefile
2417                 src/loader/Makefile
2418                 src/mapi/Makefile
2419                 src/mapi/es1api/glesv1_cm.pc
2420                 src/mapi/es2api/glesv2.pc
2421                 src/mapi/glapi/gen/Makefile
2422                 src/mesa/Makefile
2423                 src/mesa/gl.pc
2424                 src/mesa/drivers/dri/dri.pc
2425                 src/mesa/drivers/dri/common/Makefile
2426                 src/mesa/drivers/dri/common/xmlpool/Makefile
2427                 src/mesa/drivers/dri/i915/Makefile
2428                 src/mesa/drivers/dri/i965/Makefile
2429                 src/mesa/drivers/dri/Makefile
2430                 src/mesa/drivers/dri/nouveau/Makefile
2431                 src/mesa/drivers/dri/r200/Makefile
2432                 src/mesa/drivers/dri/radeon/Makefile
2433                 src/mesa/drivers/dri/swrast/Makefile
2434                 src/mesa/drivers/osmesa/Makefile
2435                 src/mesa/drivers/osmesa/osmesa.pc
2436                 src/mesa/drivers/x11/Makefile
2437                 src/mesa/main/tests/Makefile
2438                 src/util/Makefile
2439                 src/util/tests/hash_table/Makefile])
2440
2441 AC_OUTPUT
2442
2443 dnl
2444 dnl Output some configuration info for the user
2445 dnl
2446 echo ""
2447 echo "        prefix:          $prefix"
2448 echo "        exec_prefix:     $exec_prefix"
2449 echo "        libdir:          $libdir"
2450 echo "        includedir:      $includedir"
2451
2452 dnl API info
2453 echo ""
2454 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2455 echo "        OpenVG:          $enable_openvg"
2456
2457 dnl Driver info
2458 echo ""
2459 case "x$enable_osmesa$enable_gallium_osmesa" in
2460 xnoyes)
2461         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2462         ;;
2463 xyesno)
2464         echo "        OSMesa:          lib$OSMESA_LIB"
2465         ;;
2466 xnono)
2467         echo "        OSMesa:          no"
2468         ;;
2469 esac
2470
2471 echo ""
2472 if test "x$enable_dri" != xno; then
2473         echo "        DRI platform:    $dri_platform"
2474         if test -z "$DRI_DIRS"; then
2475             echo "        DRI drivers:     no"
2476         else
2477             echo "        DRI drivers:     $DRI_DIRS"
2478         fi
2479         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2480 fi
2481
2482 case "x$enable_glx$enable_xlib_glx" in
2483 xyesyes)
2484     echo "        GLX:             Xlib-based"
2485     ;;
2486 xyesno)
2487     echo "        GLX:             DRI-based"
2488     ;;
2489 *)
2490     echo "        GLX:             $enable_glx"
2491     ;;
2492 esac
2493
2494 dnl EGL
2495 echo ""
2496 echo "        EGL:             $enable_egl"
2497 if test "$enable_egl" = yes; then
2498     echo "        EGL platforms:   $egl_platforms"
2499
2500     egl_drivers=""
2501     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2502         egl_drivers="$egl_drivers builtin:egl_dri2"
2503     fi
2504
2505     echo "        EGL drivers:    $egl_drivers"
2506 fi
2507
2508 echo ""
2509 if test "x$MESA_LLVM" = x1; then
2510     echo "        llvm:            yes"
2511     echo "        llvm-config:     $LLVM_CONFIG"
2512     echo "        llvm-version:    $LLVM_VERSION"
2513 else
2514     echo "        llvm:            no"
2515 fi
2516
2517 echo ""
2518 if test -n "$with_gallium_drivers"; then
2519     echo "        Gallium:         yes"
2520 else
2521     echo "        Gallium:         no"
2522 fi
2523
2524 dnl Shader cache
2525 echo ""
2526 echo "        Shader cache:    $enable_shader_cache"
2527 if test "x$enable_shader_cache" = "xyes"; then
2528     echo "        With SHA1 from:  $with_sha1"
2529 fi
2530
2531 dnl Libraries
2532 echo ""
2533 echo "        Shared libs:     $enable_shared"
2534 echo "        Static libs:     $enable_static"
2535 echo "        Shared-glapi:    $enable_shared_glapi"
2536
2537 dnl Compiler options
2538 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2539 cflags=`echo $CFLAGS | \
2540     $SED 's/^ *//;s/  */ /;s/ *$//'`
2541 cxxflags=`echo $CXXFLAGS | \
2542     $SED 's/^ *//;s/  */ /;s/ *$//'`
2543 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2544 echo ""
2545 echo "        CFLAGS:          $cflags"
2546 echo "        CXXFLAGS:        $cxxflags"
2547 echo "        Macros:          $defines"
2548 echo ""
2549 if test "x$MESA_LLVM" = x1; then
2550     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2551     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2552     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2553     echo ""
2554 fi
2555 echo "        PYTHON2:         $PYTHON2"
2556
2557 echo ""
2558 echo "        Run '${MAKE-make}' to build Mesa"
2559 echo ""