configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports garbage collection
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 323 AC_MSG_CHECKING([whether ld supports --gc-sections])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         GC_SECTIONS="-Wl,--gc-sections";],
 328     [AC_MSG_RESULT([no])
 329         GC_SECTIONS="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([GC_SECTIONS])
 333
 334 dnl
 335 dnl compatibility symlinks
 336 dnl
 337 case "$host_os" in
 338 linux* )
 339     HAVE_COMPAT_SYMLINKS=yes ;;
 340 * )
 341     HAVE_COMPAT_SYMLINKS=no ;;
 342 esac
 343
 344 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 345
 346 dnl
 347 dnl library names
 348 dnl
 349 case "$host_os" in
 350 darwin* )
 351     LIB_EXT='dylib' ;;
 352 cygwin* )
 353     LIB_EXT='dll' ;;
 354 aix* )
 355     LIB_EXT='a' ;;
 356 * )
 357     LIB_EXT='so' ;;
 358 esac
 359
 360 AC_SUBST([LIB_EXT])
 361
 362 AC_ARG_WITH([gl-lib-name],
 363   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 364     [specify GL library name @<:@default=GL@:>@])],
 365   [GL_LIB=$withval],
 366   [GL_LIB=GL])
 367 AC_ARG_WITH([osmesa-lib-name],
 368   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 369     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 370   [OSMESA_LIB=$withval],
 371   [OSMESA_LIB=OSMesa])
 372 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 373 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 374
 375 dnl
 376 dnl Mangled Mesa support
 377 dnl
 378 AC_ARG_ENABLE([mangling],
 379   [AS_HELP_STRING([--enable-mangling],
 380     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 381   [enable_mangling="${enableval}"],
 382   [enable_mangling=no]
 383 )
 384 if test "x${enable_mangling}" = "xyes" ; then
 385   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 386   GL_LIB="Mangled${GL_LIB}"
 387   OSMESA_LIB="Mangled${OSMESA_LIB}"
 388 fi
 389 AC_SUBST([GL_LIB])
 390 AC_SUBST([OSMESA_LIB])
 391
 392 dnl
 393 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 394 dnl
 395 AC_ARG_ENABLE([texture-float],
 396     [AS_HELP_STRING([--enable-texture-float],
 397         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 398     [enable_texture_float="$enableval"],
 399     [enable_texture_float=no]
 400 )
 401 if test "x$enable_texture_float" = xyes; then
 402     AC_MSG_WARN([Floating-point textures enabled.])
 403     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 404     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 405 fi
 406
 407 dnl
 408 dnl Arch/platform-specific settings
 409 dnl
 410 AC_ARG_ENABLE([asm],
 411     [AS_HELP_STRING([--disable-asm],
 412         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 413     [enable_asm="$enableval"],
 414     [enable_asm=yes]
 415 )
 416 asm_arch=""
 417 AC_MSG_CHECKING([whether to enable assembly])
 418 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 419 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 420 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 421     case "$host_cpu" in
 422     i?86 | x86_64 | amd64)
 423         enable_asm=no
 424         AC_MSG_RESULT([no, cross compiling])
 425         ;;
 426     esac
 427 fi
 428 # check for supported arches
 429 if test "x$enable_asm" = xyes; then
 430     case "$host_cpu" in
 431     i?86)
 432         case "$host_os" in
 433         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 434             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 435             ;;
 436         gnu*)
 437             asm_arch=x86
 438             ;;
 439         esac
 440         ;;
 441     x86_64|amd64)
 442         case "$host_os" in
 443         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 444             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 445             ;;
 446         esac
 447         ;;
 448     sparc*)
 449         case "$host_os" in
 450         linux*)
 451             asm_arch=sparc
 452             ;;
 453         esac
 454         ;;
 455     esac
 456
 457     case "$asm_arch" in
 458     x86)
 459         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 460         AC_MSG_RESULT([yes, x86])
 461         ;;
 462     x86_64|amd64)
 463         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 464         AC_MSG_RESULT([yes, x86_64])
 465         ;;
 466     sparc)
 467         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 468         AC_MSG_RESULT([yes, sparc])
 469         ;;
 470     *)
 471         AC_MSG_RESULT([no, platform not supported])
 472         ;;
 473     esac
 474 fi
 475
 476 dnl Check to see if dlopen is in default libraries (like Solaris, which
 477 dnl has it in libc), or if libdl is needed to get it.
 478 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 479     [AC_CHECK_LIB([dl], [dlopen],
 480        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 481 AC_SUBST([DLOPEN_LIBS])
 482
 483 dnl Check if that library also has dladdr
 484 save_LDFLAGS="$LDFLAGS"
 485 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 486 AC_CHECK_FUNCS([dladdr])
 487 LDFLAGS="$save_LDFLAGS"
 488
 489 case "$host_os" in
 490 darwin*|mingw*)
 491     ;;
 492 *)
 493     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 494                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 495                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 496     AC_SUBST([CLOCK_LIB])
 497     ;;
 498 esac
 499
 500 dnl See if posix_memalign is available
 501 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 502
 503 dnl Check for pthreads
 504 AX_PTHREAD
 505 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 506 dnl to -pthread, which causes problems if we need -lpthread to appear in
 507 dnl pkgconfig files.
 508 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 509
 510 dnl SELinux awareness.
 511 AC_ARG_ENABLE([selinux],
 512     [AS_HELP_STRING([--enable-selinux],
 513         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 514     [MESA_SELINUX="$enableval"],
 515     [MESA_SELINUX=no])
 516 if test "x$enable_selinux" = "xyes"; then
 517     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 518         [AC_CHECK_HEADER([selinux/selinux.h],[],
 519                          [AC_MSG_ERROR([SELinux headers not found])])
 520          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 521                       [AC_MSG_ERROR([SELinux library not found])])
 522          SELINUX_LIBS="-lselinux"])
 523     DEFINES="$DEFINES -DMESA_SELINUX"
 524 fi
 525 AC_SUBST([SELINUX_CFLAGS])
 526 AC_SUBST([SELINUX_LIBS])
 527
 528 dnl Options for APIs
 529 AC_ARG_ENABLE([opengl],
 530     [AS_HELP_STRING([--disable-opengl],
 531         [disable support for standard OpenGL API @<:@default=no@:>@])],
 532     [enable_opengl="$enableval"],
 533     [enable_opengl=yes])
 534 AC_ARG_ENABLE([gles1],
 535     [AS_HELP_STRING([--enable-gles1],
 536         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 537     [enable_gles1="$enableval"],
 538     [enable_gles1=no])
 539 AC_ARG_ENABLE([gles2],
 540     [AS_HELP_STRING([--enable-gles2],
 541         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 542     [enable_gles2="$enableval"],
 543     [enable_gles2=no])
 544 AC_ARG_ENABLE([openvg],
 545     [AS_HELP_STRING([--enable-openvg],
 546         [enable support for OpenVG API @<:@default=no@:>@])],
 547     [enable_openvg="$enableval"],
 548     [enable_openvg=no])
 549
 550 AC_ARG_ENABLE([dri],
 551     [AS_HELP_STRING([--enable-dri],
 552         [enable DRI modules @<:@default=enabled@:>@])],
 553     [enable_dri="$enableval"],
 554     [enable_dri=yes])
 555
 556 case "$host_os" in
 557 linux*)
 558     dri3_default=yes
 559     ;;
 560 *)
 561     dri3_default=no
 562     ;;
 563 esac
 564 AC_ARG_ENABLE([dri3],
 565     [AS_HELP_STRING([--enable-dri3],
 566         [enable DRI3 @<:@default=auto@:>@])],
 567     [enable_dri3="$enableval"],
 568     [enable_dri3="$dri3_default"])
 569 AC_ARG_ENABLE([glx],
 570     [AS_HELP_STRING([--enable-glx],
 571         [enable GLX library @<:@default=enabled@:>@])],
 572     [enable_glx="$enableval"],
 573     [enable_glx=yes])
 574 AC_ARG_ENABLE([osmesa],
 575     [AS_HELP_STRING([--enable-osmesa],
 576         [enable OSMesa library @<:@default=disabled@:>@])],
 577     [enable_osmesa="$enableval"],
 578     [enable_osmesa=no])
 579 AC_ARG_ENABLE([gallium-osmesa],
 580     [AS_HELP_STRING([--enable-gallium-osmesa],
 581         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 582     [enable_gallium_osmesa="$enableval"],
 583     [enable_gallium_osmesa=no])
 584 AC_ARG_ENABLE([egl],
 585     [AS_HELP_STRING([--disable-egl],
 586         [disable EGL library @<:@default=enabled@:>@])],
 587     [enable_egl="$enableval"],
 588     [enable_egl=yes])
 589
 590 AC_ARG_ENABLE([xa],
 591     [AS_HELP_STRING([--enable-xa],
 592         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 593     [enable_xa="$enableval"],
 594     [enable_xa=no])
 595 AC_ARG_ENABLE([gbm],
 596    [AS_HELP_STRING([--enable-gbm],
 597          [enable gbm library @<:@default=auto@:>@])],
 598    [enable_gbm="$enableval"],
 599    [enable_gbm=auto])
 600
 601 AC_ARG_ENABLE([xvmc],
 602    [AS_HELP_STRING([--enable-xvmc],
 603          [enable xvmc library @<:@default=auto@:>@])],
 604    [enable_xvmc="$enableval"],
 605    [enable_xvmc=no])
 606 AC_ARG_ENABLE([vdpau],
 607    [AS_HELP_STRING([--enable-vdpau],
 608          [enable vdpau library @<:@default=auto@:>@])],
 609    [enable_vdpau="$enableval"],
 610    [enable_vdpau=auto])
 611 AC_ARG_ENABLE([omx],
 612    [AS_HELP_STRING([--enable-omx],
 613          [enable OpenMAX library @<:@default=no@:>@])],
 614    [enable_omx="$enableval"],
 615    [enable_omx=no])
 616 AC_ARG_ENABLE([opencl],
 617    [AS_HELP_STRING([--enable-opencl],
 618          [enable OpenCL library @<:@default=no@:>@])],
 619    [enable_opencl="$enableval"],
 620    [enable_opencl=no])
 621 AC_ARG_ENABLE([opencl_icd],
 622    [AS_HELP_STRING([--enable-opencl-icd],
 623           [Build an OpenCL ICD library to be loaded by an ICD implementation
 624            @<:@default=no@:>@])],
 625     [enable_opencl_icd="$enableval"],
 626     [enable_opencl_icd=no])
 627 AC_ARG_ENABLE([xlib-glx],
 628     [AS_HELP_STRING([--enable-xlib-glx],
 629         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 630     [enable_xlib_glx="$enableval"],
 631     [enable_xlib_glx=no])
 632 AC_ARG_ENABLE([gallium-egl],
 633     [AS_HELP_STRING([--enable-gallium-egl],
 634         [enable optional EGL state tracker (not required
 635          for EGL support in Gallium with OpenGL and OpenGL ES)
 636          @<:@default=disable@:>@])],
 637     [enable_gallium_egl="$enableval"],
 638     [enable_gallium_egl=no])
 639 AC_ARG_ENABLE([gallium-gbm],
 640     [AS_HELP_STRING([--enable-gallium-gbm],
 641         [enable optional gbm state tracker (not required for
 642          gbm support in Gallium)
 643          @<:@default=auto@:>@])],
 644     [enable_gallium_gbm="$enableval"],
 645     [enable_gallium_gbm=auto])
 646
 647 AC_ARG_ENABLE([r600-llvm-compiler],
 648     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 649         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 650     [enable_r600_llvm="$enableval"],
 651     [enable_r600_llvm=no])
 652
 653 AC_ARG_ENABLE([gallium-tests],
 654     [AS_HELP_STRING([--enable-gallium-tests],
 655         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 656     [enable_gallium_tests="$enableval"],
 657     [enable_gallium_tests=no])
 658
 659 # Option for Gallium drivers
 660
 661 # Keep this in sync with the --with-gallium-drivers help string default value
 662 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 663
 664 AC_ARG_WITH([gallium-drivers],
 665     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 666         [comma delimited Gallium drivers list, e.g.
 667         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 668         @<:@default=r300,r600,svga,swrast@:>@])],
 669     [with_gallium_drivers="$withval"],
 670     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 671
 672 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 673 # here so that the script doesn't choke on an unknown driver name later.
 674 case "$with_gallium_drivers" in
 675     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 676     no) with_gallium_drivers='' ;;
 677 esac
 678
 679 if test "x$enable_opengl" = xno -a \
 680         "x$enable_gles1" = xno -a \
 681         "x$enable_gles2" = xno -a \
 682         "x$enable_openvg" = xno -a \
 683         "x$enable_xa" = xno -a \
 684         "x$enable_xvmc" = xno -a \
 685         "x$enable_vdpau" = xno -a \
 686         "x$enable_omx" = xno -a \
 687         "x$enable_opencl" = xno; then
 688     AC_MSG_ERROR([at least one API should be enabled])
 689 fi
 690
 691 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 692 if test "x$enable_opengl" = xno -a \
 693         "x$enable_gles1" = xyes; then
 694     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 695 fi
 696
 697 if test "x$enable_opengl" = xno -a \
 698         "x$enable_gles2" = xyes; then
 699     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 700 fi
 701
 702 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 703 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 704 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 705 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 706                                         "x$enable_gles1" = xyes -o \
 707                                         "x$enable_gles2" = xyes)
 708
 709 if test "x$enable_glx" = xno; then
 710     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 711     enable_xlib_glx=no
 712 fi
 713
 714 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 715     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 716 fi
 717
 718 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 719     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 720 fi
 721
 722 # Disable GLX if OpenGL is not enabled
 723 if test "x$enable_glx$enable_opengl" = xyesno; then
 724     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 725     enable_glx=no
 726 fi
 727
 728 # Disable GLX if DRI and Xlib-GLX are not enabled
 729 if test "x$enable_glx" = xyes -a \
 730         "x$enable_dri" = xno -a \
 731         "x$enable_xlib_glx" = xno; then
 732     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 733     enable_glx=no
 734 fi
 735
 736 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 737                                   "x$enable_dri" = xyes)
 738 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 739 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 740
 741 AC_ARG_ENABLE([shared-glapi],
 742     [AS_HELP_STRING([--enable-shared-glapi],
 743         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 744     [enable_shared_glapi="$enableval"],
 745     [enable_shared_glapi=yes])
 746
 747 case "x$enable_opengl$enable_gles1$enable_gles2" in
 748 x*yes*yes*)
 749     if test "x$enable_shared_glapi" = xno; then
 750         AC_MSG_ERROR([shared GLAPI required when building two or more of
 751                       the following APIs - opengl, gles1 gles2])
 752     fi
 753     ;;
 754 esac
 755
 756 # Building Xlib-GLX requires shared glapi to be disabled.
 757 if test "x$enable_xlib_glx" = xyes; then
 758     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 759     enable_shared_glapi=no
 760 fi
 761
 762 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 763
 764 dnl
 765 dnl Driver specific build directories
 766 dnl
 767 GALLIUM_TARGET_DIRS=""
 768 GALLIUM_WINSYS_DIRS="sw"
 769 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 770 GALLIUM_STATE_TRACKERS_DIRS=""
 771
 772 case "x$enable_glx$enable_xlib_glx" in
 773 xyesyes)
 774     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 775     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 776     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 777     NEED_WINSYS_XLIB="yes"
 778     ;;
 779 esac
 780
 781 if test "x$enable_dri" = xyes; then
 782     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 783     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 784 fi
 785
 786 if test "x$enable_gallium_osmesa" = xyes; then
 787     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 788         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 789     fi
 790     if test "x$enable_osmesa" = xyes; then
 791         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 792     fi
 793     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 794     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 795 fi
 796
 797 AC_SUBST([MESA_LLVM])
 798
 799 # Check for libdrm
 800 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 801                   [have_libdrm=yes], [have_libdrm=no])
 802 if test "x$have_libdrm" = xyes; then
 803         DEFINES="$DEFINES -DHAVE_LIBDRM"
 804 fi
 805
 806 case "$host_os" in
 807 linux*)
 808     need_libudev=yes ;;
 809 *)
 810     need_libudev=no ;;
 811 esac
 812
 813 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 814                   have_libudev=yes, have_libudev=no)
 815
 816 if test "x$enable_dri" = xyes; then
 817     if test "$enable_static" = yes; then
 818         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 819     fi
 820
 821     # not a hard requirement as swrast does not depend on it
 822     if test "x$have_libdrm" = xyes; then
 823         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 824     fi
 825 fi
 826
 827 dnl Direct rendering or just indirect rendering
 828 case "$host_os" in
 829 gnu*)
 830     dnl Disable by default on GNU/Hurd
 831     driglx_direct_default="no"
 832     ;;
 833 cygwin*)
 834     dnl Disable by default on cygwin
 835     driglx_direct_default="no"
 836     ;;
 837 *)
 838     driglx_direct_default="yes"
 839     ;;
 840 esac
 841 AC_ARG_ENABLE([driglx-direct],
 842     [AS_HELP_STRING([--disable-driglx-direct],
 843         [disable direct rendering in GLX and EGL for DRI \
 844             @<:@default=auto@:>@])],
 845     [driglx_direct="$enableval"],
 846     [driglx_direct="$driglx_direct_default"])
 847
 848 dnl
 849 dnl libGL configuration per driver
 850 dnl
 851 case "x$enable_glx$enable_xlib_glx" in
 852 xyesyes)
 853     # Xlib-based GLX
 854     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 855     GL_PC_REQ_PRIV="x11 xext"
 856     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 857     GL_LIB_DEPS="$XLIBGL_LIBS"
 858     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 859     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 860     ;;
 861 xyesno)
 862     # DRI-based GLX
 863     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 864     if test x"$driglx_direct" = xyes; then
 865         if test "x$have_libdrm" != xyes; then
 866             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 867         fi
 868         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 869         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 870         if test x"$enable_dri3" = xyes; then
 871             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 872             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 873         fi
 874     fi
 875
 876     # find the DRI deps for libGL
 877     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 878
 879     if test x"$enable_dri3" = xyes; then
 880         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 881     fi
 882
 883     # add xf86vidmode if available
 884     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 885     if test "$HAVE_XF86VIDMODE" = yes ; then
 886         dri_modules="$dri_modules xxf86vm"
 887     fi
 888
 889     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 890     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 891     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 892     GL_LIB_DEPS="$DRIGL_LIBS"
 893
 894     # need DRM libs, $PTHREAD_LIBS, etc.
 895     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 897     ;;
 898 esac
 899
 900 if test "$have_libudev" = yes; then
 901     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 902 fi
 903
 904 # This is outside the case (above) so that it is invoked even for non-GLX
 905 # builds.
 906 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 907
 908 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 909 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 910 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 911 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 912
 913 AC_SUBST([X11_INCLUDES])
 914 AC_SUBST([GL_LIB_DEPS])
 915 AC_SUBST([GL_PC_REQ_PRIV])
 916 AC_SUBST([GL_PC_LIB_PRIV])
 917 AC_SUBST([GL_PC_CFLAGS])
 918 AC_SUBST([DRI_PC_REQ_PRIV])
 919 AC_SUBST([GLESv1_CM_LIB_DEPS])
 920 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 921 AC_SUBST([GLESv2_LIB_DEPS])
 922 AC_SUBST([GLESv2_PC_LIB_PRIV])
 923
 924 AC_SUBST([HAVE_XF86VIDMODE])
 925
 926 dnl
 927 dnl More GLX setup
 928 dnl
 929 case "x$enable_glx$enable_xlib_glx" in
 930 xyesyes)
 931     DEFINES="$DEFINES -DUSE_XSHM"
 932     ;;
 933 xyesno)
 934     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 935     if test "x$driglx_direct" = xyes; then
 936         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 937     fi
 938     ;;
 939 esac
 940
 941 dnl
 942 dnl TLS detection
 943 dnl
 944
 945 AC_ARG_ENABLE([glx-tls],
 946     [AS_HELP_STRING([--enable-glx-tls],
 947         [enable TLS support in GLX @<:@default=disabled@:>@])],
 948     [GLX_USE_TLS="$enableval"],
 949     [GLX_USE_TLS=no])
 950 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 951
 952 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 953       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 954
 955 dnl
 956 dnl More DRI setup
 957 dnl
 958 dnl Directory for DRI drivers
 959 AC_ARG_WITH([dri-driverdir],
 960     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 961         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 962     [DRI_DRIVER_INSTALL_DIR="$withval"],
 963     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 964 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 965 dnl Extra search path for DRI drivers
 966 AC_ARG_WITH([dri-searchpath],
 967     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 968         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 969     [DRI_DRIVER_SEARCH_DIR="$withval"],
 970     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 971 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 972 dnl Which drivers to build - default is chosen by platform
 973 AC_ARG_WITH([dri-drivers],
 974     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 975         [comma delimited classic DRI drivers list, e.g.
 976         "swrast,i965,radeon" @<:@default=auto@:>@])],
 977     [with_dri_drivers="$withval"],
 978     [with_dri_drivers=auto])
 979
 980 if test "x$with_dri_drivers" = xauto; then
 981     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 982         with_dri_drivers="yes"
 983     else
 984         with_dri_drivers="no"
 985     fi
 986 fi
 987 if test "x$with_dri_drivers" = xno; then
 988     with_dri_drivers=''
 989 fi
 990
 991 dnl If $with_dri_drivers is yes, drivers will be added through
 992 dnl platform checks. Set DEFINES and LIB_DEPS
 993 if test "x$enable_dri" = xyes; then
 994     # Platform specific settings and drivers to build
 995     case "$host_os" in
 996     linux*)
 997         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 998         DEFINES="$DEFINES -DHAVE_ALIAS"
 999         if test "x$enable_dri3" = xyes; then
1000             DEFINES="$DEFINES -DHAVE_DRI3"
1001         fi
1002
1003         if test "x$have_libudev" != xyes; then
1004             AC_MSG_ERROR([libudev-dev required for building DRI])
1005         fi
1006
1007         case "$host_cpu" in
1008         powerpc* | sparc*)
1009             # Build only the drivers for cards that exist on PowerPC/sparc
1010             if test "x$with_dri_drivers" = "xyes"; then
1011                 with_dri_drivers="r200 radeon swrast"
1012             fi
1013             ;;
1014         esac
1015         ;;
1016     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1017         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1018         DEFINES="$DEFINES -DHAVE_ALIAS"
1019         ;;
1020     gnu*)
1021         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1022         DEFINES="$DEFINES -DHAVE_ALIAS"
1023         ;;
1024     solaris*)
1025         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1026         ;;
1027     cygwin*)
1028         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1029         if test "x$with_dri_drivers" = "xyes"; then
1030             with_dri_drivers="swrast"
1031         fi
1032         ;;
1033     esac
1034
1035     # default drivers
1036     if test "x$with_dri_drivers" = "xyes"; then
1037         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1038     fi
1039
1040     # Check for expat
1041     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1042     if test "x$have_expat" = "xyes"; then
1043        PKG_CHECK_MODULES([EXPAT], [expat], [],
1044                          AC_MSG_ERROR([Expat required for DRI.]))
1045     else
1046        # expat version 2.0 and earlier do not provide expat.pc
1047        EXPAT_LIBS=-lexpat
1048     fi
1049
1050     # If we are building any DRI driver other than swrast.
1051     if test -n "$with_dri_drivers"; then
1052         if test "x$with_dri_drivers" != xswrast; then
1053             # ... libdrm is required
1054             if test "x$have_libdrm" != xyes; then
1055                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1056             fi
1057             DRICOMMON_NEED_LIBDRM=yes
1058         else
1059             DRICOMMON_NEED_LIBDRM=no
1060         fi
1061     fi
1062
1063     # put all the necessary libs together
1064     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1065 fi
1066
1067 AC_SUBST([DRI_LIB_DEPS])
1068
1069 DRI_DIRS=''
1070 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1071 if test -n "$with_dri_drivers"; then
1072     if test "x$enable_opengl" != xyes; then
1073         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1074     fi
1075
1076     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1077     for driver in $dri_drivers; do
1078         DRI_DIRS="$DRI_DIRS $driver"
1079         case "x$driver" in
1080         xi915)
1081             HAVE_I915_DRI=yes;
1082             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1083             ;;
1084         xi965)
1085             HAVE_I965_DRI=yes;
1086             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1087             ;;
1088         xnouveau)
1089             HAVE_NOUVEAU_DRI=yes;
1090             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1091             ;;
1092         xradeon)
1093             HAVE_RADEON_DRI=yes;
1094             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1095             ;;
1096         xr200)
1097             HAVE_R200_DRI=yes;
1098             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1099             ;;
1100         xswrast)
1101             HAVE_SWRAST_DRI=yes;
1102             ;;
1103         *)
1104             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1105             ;;
1106         esac
1107     done
1108     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1109 fi
1110
1111 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1112 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1113                                   "x$enable_osmesa" = xyes -o \
1114                                   -n "$DRI_DIRS")
1115
1116 dnl
1117 dnl OSMesa configuration
1118 dnl
1119
1120 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1121 AC_ARG_WITH([osmesa-bits],
1122     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1123         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1124     [osmesa_bits="$withval"],
1125     [osmesa_bits=8])
1126 if test "x$osmesa_bits" != x8; then
1127     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1128         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1129         osmesa_bits=8
1130     fi
1131 fi
1132 case "x$osmesa_bits" in
1133 x8)
1134     OSMESA_LIB="${OSMESA_LIB}"
1135     ;;
1136 x16|x32)
1137     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1138     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1139     ;;
1140 *)
1141     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1142     ;;
1143 esac
1144
1145 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1146     # only link libraries with osmesa if shared
1147     if test "$enable_static" = no; then
1148         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1149     else
1150         OSMESA_LIB_DEPS=""
1151     fi
1152     OSMESA_MESA_DEPS=""
1153     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1154 fi
1155
1156 AC_SUBST([OSMESA_LIB_DEPS])
1157 AC_SUBST([OSMESA_MESA_DEPS])
1158 AC_SUBST([OSMESA_PC_REQ])
1159 AC_SUBST([OSMESA_PC_LIB_PRIV])
1160
1161 dnl
1162 dnl gbm configuration
1163 dnl
1164 if test "x$enable_gbm" = xauto; then
1165     case "$with_egl_platforms" in
1166         *drm*)
1167             enable_gbm=yes ;;
1168          *)
1169             enable_gbm=no ;;
1170     esac
1171 fi
1172 if test "x$enable_gbm" = xyes; then
1173     if test "x$need_libudev$have_libudev" = xyesno; then
1174         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1175     fi
1176
1177     if test "x$enable_dri" = xyes; then
1178         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1179         if test "x$enable_shared_glapi" = xno; then
1180             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1181         fi
1182     fi
1183 fi
1184 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1185 if test "x$need_libudev" = xyes; then
1186     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1187 else
1188     GBM_PC_REQ_PRIV=""
1189 fi
1190 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1191 AC_SUBST([GBM_PC_REQ_PRIV])
1192 AC_SUBST([GBM_PC_LIB_PRIV])
1193
1194 dnl
1195 dnl EGL configuration
1196 dnl
1197 EGL_CLIENT_APIS=""
1198
1199 if test "x$enable_egl" = xyes; then
1200     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1201
1202     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1203
1204     if test "$enable_static" != yes; then
1205         if test "x$enable_dri" = xyes; then
1206             HAVE_EGL_DRIVER_DRI2=1
1207         fi
1208
1209     fi
1210 fi
1211 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1212 AC_SUBST([EGL_LIB_DEPS])
1213
1214 dnl
1215 dnl EGL Gallium configuration
1216 dnl
1217 if test "x$enable_gallium_egl" = xyes; then
1218     if test -z "$with_gallium_drivers"; then
1219         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1220     fi
1221     if test "x$enable_egl" = xno; then
1222         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1223     fi
1224     if test "x$have_libdrm" != xyes; then
1225         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1226     fi
1227
1228     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1229     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1230 fi
1231 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1232
1233 dnl
1234 dnl gbm Gallium configuration
1235 dnl
1236 if test "x$enable_gallium_gbm" = xauto; then
1237     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1238         yesyesyes*drm*)
1239             enable_gallium_gbm=yes ;;
1240          *)
1241             enable_gallium_gbm=no ;;
1242     esac
1243 fi
1244 if test "x$enable_gallium_gbm" = xyes; then
1245     if test -z "$with_gallium_drivers"; then
1246         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1247     fi
1248     if test "x$enable_gbm" = xno; then
1249         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1250     fi
1251     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1252     if test "x$enable_dri" = xno; then
1253         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1254     fi
1255
1256     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1257     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1258     enable_gallium_loader=yes
1259 fi
1260 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1261
1262 dnl
1263 dnl XA configuration
1264 dnl
1265 if test "x$enable_xa" = xyes; then
1266     if test "x$with_gallium_drivers" = xswrast; then
1267        AC_MSG_ERROR([
1268           Building xa requires at least one non swrast gallium driver.
1269           If you are looking to use libxatracker.so with vmware's virtual gpu,
1270           make sure to include svga in the gallium drivers list, apart from
1271           enabling XA.
1272           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1273     fi
1274     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1275     enable_gallium_loader=yes
1276 fi
1277 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1278
1279 dnl
1280 dnl OpenVG configuration
1281 dnl
1282 VG_LIB_DEPS=""
1283
1284 if test "x$enable_openvg" = xyes; then
1285     if test "x$enable_egl" = xno; then
1286         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1287     fi
1288     if test -z "$with_gallium_drivers"; then
1289         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1290     fi
1291     if test "x$enable_gallium_egl" = xno; then
1292         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1293     fi
1294
1295     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1296     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1297     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1298     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1299     AC_SUBST([VG_PC_LIB_PRIV])
1300 fi
1301 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1302
1303 dnl
1304 dnl Gallium G3DVL configuration
1305 dnl
1306 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1307     if test "x$enable_xvmc" = xauto; then
1308         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1309     fi
1310
1311     if test "x$enable_vdpau" = xauto; then
1312         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1313     fi
1314
1315     if test "x$enable_omx" = xauto; then
1316         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1317     fi
1318 fi
1319
1320 if test "x$enable_xvmc" = xyes; then
1321     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1322     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1323 fi
1324 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1325
1326 if test "x$enable_vdpau" = xyes; then
1327     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1328                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1329     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1330 fi
1331 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1332
1333 if test "x$enable_omx" = xyes; then
1334     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1335     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1336 fi
1337 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1338
1339 dnl
1340 dnl OpenCL configuration
1341 dnl
1342
1343 AC_ARG_WITH([libclc-path],
1344    [AS_HELP_STRING([--with-libclc-path],
1345          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1346    [LIBCLC_PATH="$withval"],
1347    [LIBCLC_PATH=''])
1348
1349 if test -n "$LIBCLC_PATH"; then
1350    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1351                   Please review the updated build instructions for clover:
1352                   http://dri.freedesktop.org/wiki/GalliumCompute])
1353 fi
1354
1355
1356 AC_ARG_WITH([clang-libdir],
1357    [AS_HELP_STRING([--with-clang-libdir],
1358          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1359    [CLANG_LIBDIR="$withval"],
1360    [CLANG_LIBDIR=''])
1361
1362 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1363
1364 if test "x$enable_opencl" = xyes; then
1365     if test -z "$with_gallium_drivers"; then
1366         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1367     fi
1368
1369     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1370         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1371     fi
1372
1373     if test "x$have_libclc" = xno; then
1374         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1375                     Make sure the directory containing libclc.pc is specified in your
1376                     PKG_CONFIG_PATH environment variable.
1377                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1378     else
1379         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1380         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1381         AC_SUBST([LIBCLC_INCLUDEDIR])
1382         AC_SUBST([LIBCLC_LIBEXECDIR])
1383     fi
1384
1385     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1386     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1387     enable_gallium_loader=yes
1388
1389     if test "x$enable_opencl_icd" = xyes; then
1390         OPENCL_LIBNAME="MesaOpenCL"
1391     else
1392         OPENCL_LIBNAME="OpenCL"
1393     fi
1394 fi
1395 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1396 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1397 AC_SUBST([OPENCL_LIBNAME])
1398
1399 dnl
1400 dnl Gallium configuration
1401 dnl
1402 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1403
1404 AC_SUBST([LLVM_BINDIR])
1405 AC_SUBST([LLVM_CFLAGS])
1406 AC_SUBST([LLVM_CPPFLAGS])
1407 AC_SUBST([LLVM_CXXFLAGS])
1408 AC_SUBST([LLVM_LIBDIR])
1409 AC_SUBST([LLVM_LIBS])
1410 AC_SUBST([LLVM_LDFLAGS])
1411 AC_SUBST([LLVM_INCLUDEDIR])
1412 AC_SUBST([LLVM_VERSION])
1413 AC_SUBST([CLANG_RESOURCE_DIR])
1414
1415 case "x$enable_opengl$enable_gles1$enable_gles2" in
1416 x*yes*)
1417     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1418     ;;
1419 esac
1420
1421 AC_SUBST([VG_LIB_DEPS])
1422 AC_SUBST([EGL_CLIENT_APIS])
1423
1424 dnl
1425 dnl EGL Platforms configuration
1426 dnl
1427 AC_ARG_WITH([egl-platforms],
1428     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1429         [comma delimited native platforms libEGL supports, e.g.
1430         "x11,drm" @<:@default=auto@:>@])],
1431     [with_egl_platforms="$withval"],
1432     [if test "x$enable_egl" = xyes; then
1433         with_egl_platforms="x11"
1434     else
1435         with_egl_platforms=""
1436     fi])
1437
1438 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1439     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1440 fi
1441
1442 # Do per-EGL platform setups and checks
1443 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1444 for plat in $egl_platforms; do
1445         case "$plat" in
1446         wayland)
1447                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1448                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1449
1450                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1451                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1452                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1453                 ;;
1454
1455         x11)
1456                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1457                 ;;
1458
1459         drm)
1460                 test "x$enable_gbm" = "xno" &&
1461                         AC_MSG_ERROR([EGL platform drm needs gbm])
1462                 test "x$have_libdrm" != xyes &&
1463                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1464                 ;;
1465
1466         android|fbdev|gdi|null)
1467                 ;;
1468
1469         *)
1470                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1471                 ;;
1472         esac
1473
1474         case "$plat$need_libudev$have_libudev" in
1475                 waylandyesno|drmyesno)
1476                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1477         esac
1478 done
1479
1480 # libEGL wants to default to the first platform specified in
1481 # ./configure.  parse that here.
1482 if test "x$egl_platforms" != "x"; then
1483     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1484     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1485 else
1486     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1487 fi
1488
1489 if echo "$egl_platforms" | grep -q 'x11'; then
1490     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1491     NEED_WINSYS_XLIB=yes
1492 fi
1493 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1494 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1495 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1496 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1497 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1498
1499 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1500
1501 AC_SUBST([EGL_NATIVE_PLATFORM])
1502 AC_SUBST([EGL_CFLAGS])
1503
1504 # If we don't have the X11 platform, set this define so we don't try to include
1505 # the X11 headers.
1506 if ! echo "$egl_platforms" | grep -q 'x11'; then
1507     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1508     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1509 fi
1510
1511 AC_ARG_WITH([egl-driver-dir],
1512     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1513                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1514     [EGL_DRIVER_INSTALL_DIR="$withval"],
1515     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1516 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1517
1518 AC_ARG_WITH([max-width],
1519     [AS_HELP_STRING([--with-max-width=N],
1520                     [Maximum framebuffer width (4096)])],
1521     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1522      AS_IF([test "${withval}" -gt "4096"],
1523            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1524 )
1525 AC_ARG_WITH([max-height],
1526     [AS_HELP_STRING([--with-max-height=N],
1527                     [Maximum framebuffer height (4096)])],
1528     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1529      AS_IF([test "${withval}" -gt "4096"],
1530            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1531 )
1532
1533 dnl
1534 dnl Gallium LLVM
1535 dnl
1536 AC_ARG_ENABLE([gallium-llvm],
1537     [AS_HELP_STRING([--enable-gallium-llvm],
1538         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1539     [enable_gallium_llvm="$enableval"],
1540     [enable_gallium_llvm=auto])
1541
1542 AC_ARG_ENABLE([llvm-shared-libs],
1543     [AS_HELP_STRING([--enable-llvm-shared-libs],
1544         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1545     [enable_llvm_shared_libs="$enableval"],
1546     [enable_llvm_shared_libs=yes])
1547
1548 AC_ARG_WITH([llvm-prefix],
1549     [AS_HELP_STRING([--with-llvm-prefix],
1550         [Prefix for LLVM installations in non-standard locations])],
1551     [llvm_prefix="$withval"],
1552     [llvm_prefix=''])
1553
1554
1555 # Call this inside ` ` to get the return value.
1556 # $1 is the llvm-config command with arguments.
1557 strip_unwanted_llvm_flags() {
1558     # Use \> (marks the end of the word)
1559     echo `$1` | sed \
1560         -e 's/-DNDEBUG\>//g' \
1561         -e 's/-pedantic\>//g' \
1562         -e 's/-Wcovered-switch-default\>//g' \
1563         -e 's/-O.\>//g' \
1564         -e 's/-g\>//g' \
1565         -e 's/-Wall\>//g' \
1566         -e 's/-Wcast-qual\>//g' \
1567         -e 's/-Woverloaded-virtual\>//g' \
1568         -e 's/-fcolor-diagnostics\>//g' \
1569         -e 's/-fdata-sections\>//g' \
1570         -e 's/-ffunction-sections\>//g' \
1571         -e 's/-fno-exceptions\>//g' \
1572         -e 's/-fomit-frame-pointer\>//g' \
1573         -e 's/-fvisibility-inlines-hidden\>//g' \
1574         -e 's/-fPIC\>//g'
1575 }
1576
1577
1578 if test -z "$with_gallium_drivers"; then
1579     enable_gallium_llvm=no
1580 fi
1581 if test "x$enable_gallium_llvm" = xauto; then
1582     case "$host_cpu" in
1583     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1584     esac
1585 fi
1586 if test "x$enable_gallium_llvm" = xyes; then
1587     if test -n "$llvm_prefix"; then
1588         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1589     else
1590         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1591     fi
1592
1593     if test "x$LLVM_CONFIG" != xno; then
1594         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1595         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1596         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1597         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1598         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1599         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1600         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1601         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1602
1603         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1604             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1605         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1606             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1607
1608         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1609         dnl llvm-config.h
1610         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1611             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1612             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1613
1614         if test -n "${LLVM_VERSION_MAJOR}"; then
1615             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1616         else
1617             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1618         fi
1619
1620         LLVM_COMPONENTS="engine bitwriter"
1621         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1622             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1623         fi
1624
1625         if test "x$enable_opencl" = xyes; then
1626             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1627             # LLVM 3.3 >= 177971 requires IRReader
1628             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1629                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1630             fi
1631             # LLVM 3.4 requires Option
1632             if $LLVM_CONFIG --components | grep -qw 'option'; then
1633                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1634             fi
1635         fi
1636         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1637         MESA_LLVM=1
1638
1639         dnl Check for Clang internal headers
1640         if test "x$enable_opencl" = xyes; then
1641             if test -z "$CLANG_LIBDIR"; then
1642                 CLANG_LIBDIR=${LLVM_LIBDIR}
1643             fi
1644             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1645             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1646                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1647         fi
1648     else
1649         MESA_LLVM=0
1650         LLVM_VERSION_INT=0
1651     fi
1652 else
1653     MESA_LLVM=0
1654     LLVM_VERSION_INT=0
1655 fi
1656
1657 dnl Directory for XVMC libs
1658 AC_ARG_WITH([xvmc-libdir],
1659     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1660         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1661     [XVMC_LIB_INSTALL_DIR="$withval"],
1662     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1663 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1664
1665 dnl
1666 dnl Gallium Tests
1667 dnl
1668 if test "x$enable_gallium_tests" = xyes; then
1669     enable_gallium_loader=yes
1670 fi
1671 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1672
1673 if test "x$enable_gallium_loader" = xyes; then
1674     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1675 fi
1676 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1677
1678 dnl Directory for VDPAU libs
1679 AC_ARG_WITH([vdpau-libdir],
1680     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1681         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1682     [VDPAU_LIB_INSTALL_DIR="$withval"],
1683     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1684 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1685
1686 OMX_LIB_INSTALL_DIR_DEFAULT=''
1687 if test "x$enable_omx" = xyes; then
1688     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1689 fi
1690
1691 AC_ARG_WITH([omx-libdir],
1692     [AS_HELP_STRING([--with-omx-libdir=DIR],
1693         [directory for the OMX libraries])],
1694     [OMX_LIB_INSTALL_DIR="$withval"],
1695     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1696 AC_SUBST([OMX_LIB_INSTALL_DIR])
1697
1698 dnl Directory for OpenCL libs
1699 AC_ARG_WITH([opencl-libdir],
1700     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1701         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1702     [OPENCL_LIB_INSTALL_DIR="$withval"],
1703     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1704 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1705
1706 dnl
1707 dnl Gallium helper functions
1708 dnl
1709 gallium_check_st() {
1710     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1711          if test "x$have_libdrm" != xyes; then
1712             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1713          fi
1714          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1715     fi
1716     if test "x$enable_dri" = xyes && test -n "$2"; then
1717          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1718     fi
1719     if test "x$enable_xa" = xyes && test -n "$3"; then
1720          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1721     fi
1722     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1723          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1724     fi
1725     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1726          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1727     fi
1728     if test "x$enable_omx" = xyes && test "x$6" != x; then
1729          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1730     fi
1731 }
1732
1733 gallium_require_llvm() {
1734     if test "x$MESA_LLVM" = x0; then
1735         case "$host_cpu" in
1736         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1737         esac
1738     fi
1739 }
1740
1741 gallium_require_drm_loader() {
1742     if test "x$enable_gallium_loader" = xyes; then
1743         if test "x$need_libudev$have_libudev" = xyesno; then
1744             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1745         fi
1746         if test "x$have_libdrm" != xyes; then
1747             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1748         fi
1749         enable_gallium_drm_loader=yes
1750     fi
1751 }
1752
1753 require_egl_drm() {
1754     case "$with_egl_platforms" in
1755         *drm*)
1756             ;;
1757          *)
1758             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1759             ;;
1760     esac
1761     if test "x$enable_gbm" != xyes; then
1762             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1763     fi
1764 }
1765
1766 radeon_llvm_check() {
1767     if test "x$enable_gallium_llvm" != "xyes"; then
1768         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1769     fi
1770     LLVM_REQUIRED_VERSION_MAJOR="3"
1771     LLVM_REQUIRED_VERSION_MINOR="3"
1772     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1773         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1774     fi
1775     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1776         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1777                       sources with the --enable-experimental-targets=R600
1778                       configure flag])
1779     fi
1780     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1781     NEED_RADEON_LLVM=yes
1782     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1783                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1784 }
1785
1786 dnl Gallium drivers
1787 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1788         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1789     NEED_NONNULL_WINSYS=yes
1790 fi
1791 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1792
1793 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1794 if test -n "$with_gallium_drivers"; then
1795     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1796     for driver in $gallium_drivers; do
1797         case "x$driver" in
1798         xsvga)
1799             HAVE_GALLIUM_SVGA=yes
1800             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1801             gallium_require_drm_loader
1802             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1803             ;;
1804         xi915)
1805             HAVE_GALLIUM_I915=yes
1806             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1807             gallium_require_drm_loader
1808             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1809             if test "x$MESA_LLVM" = x1; then
1810                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1811             fi
1812             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1813             gallium_check_st "i915/drm" "dri-i915"
1814             DRICOMMON_NEED_LIBDRM=yes
1815             ;;
1816         xilo)
1817             HAVE_GALLIUM_ILO=yes
1818             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1819             gallium_require_drm_loader
1820             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1821             gallium_check_st "intel/drm" "dri-ilo"
1822             DRICOMMON_NEED_LIBDRM=yes
1823             ;;
1824         xr300)
1825             HAVE_GALLIUM_R300=yes
1826             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1827             gallium_require_drm_loader
1828             gallium_require_llvm "Gallium R300"
1829             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1830             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1831             DRICOMMON_NEED_LIBDRM=yes
1832             ;;
1833         xr600)
1834             HAVE_GALLIUM_R600=yes
1835             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1836             gallium_require_drm_loader
1837             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1838             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1839                 radeon_llvm_check "r600g"
1840                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1841             fi
1842             if test "x$enable_r600_llvm" = xyes; then
1843                 USE_R600_LLVM_COMPILER=yes;
1844             fi
1845             if test "x$enable_opencl" = xyes; then
1846                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1847             fi
1848             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1849             DRICOMMON_NEED_LIBDRM=yes
1850             ;;
1851         xradeonsi)
1852             HAVE_GALLIUM_RADEONSI=yes
1853             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1854             gallium_require_drm_loader
1855             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1856             radeon_llvm_check "radeonsi"
1857             require_egl_drm "radeonsi"
1858             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1859             DRICOMMON_NEED_LIBDRM=yes
1860             ;;
1861         xnouveau)
1862             HAVE_GALLIUM_NOUVEAU=yes
1863             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1864             gallium_require_drm_loader
1865             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1866             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1867             DRICOMMON_NEED_LIBDRM=yes
1868             ;;
1869         xfreedreno)
1870             HAVE_GALLIUM_FREEDRENO=yes
1871             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1872             gallium_require_drm_loader
1873             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1874             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1875             DRICOMMON_NEED_LIBDRM=yes
1876             ;;
1877         xswrast)
1878             HAVE_GALLIUM_SOFTPIPE=yes
1879             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1880             if test "x$MESA_LLVM" = x1; then
1881                 HAVE_GALLIUM_LLVMPIPE=yes
1882                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1883             fi
1884
1885             if test "x$enable_dri" = xyes; then
1886                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1887             fi
1888             ;;
1889         *)
1890             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1891             ;;
1892         esac
1893     done
1894 fi
1895
1896 dnl Set LLVM_LIBS - This is done after the driver configuration so
1897 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1898 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1899 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1900 dnl this was causing the same libraries to be appear multiple times
1901 dnl in LLVM_LIBS.
1902
1903 if test "x$MESA_LLVM" != x0; then
1904
1905     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1906
1907     if test "x$enable_llvm_shared_libs" = xyes; then
1908         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1909         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1910         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1911
1912         if test "x$llvm_have_one_so" = xyes; then
1913             dnl LLVM was built using auto*, so there is only one shared object.
1914             LLVM_LIBS="-l$LLVM_SO_NAME"
1915         else
1916             dnl If LLVM was built with CMake, there will be one shared object per
1917             dnl component.
1918             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1919                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1920         Please make sure you have built llvm with the --enable-shared option
1921         and that your llvm libraries are installed in $LLVM_LIBDIR
1922         If you have installed your llvm libraries to a different directory you
1923         can use the --with-llvm-prefix= configure flag to specify this directory.
1924         NOTE: Mesa is attempting to use llvm shared libraries by default.
1925         If you do not want to build with llvm shared libraries and instead want to
1926         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1927         invocation and rebuild.])])
1928
1929            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1930            dnl install uses a shared object for each compoenent and we have
1931            dnl already added all of these objects to LLVM_LIBS.
1932         fi
1933     else
1934         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
1935     fi
1936 fi
1937
1938 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1939 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1940 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1941 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1942 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1943 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1944 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1945 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1946 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1947 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1948
1949 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1950                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1951                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1952 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1953                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1954                                                   && test "x$MESA_LLVM" = x1)
1955
1956 # NOTE: anything using xcb or other client side libs ends up in separate
1957 #       _CLIENT variables.  The pipe loader is built in two variants,
1958 #       one that is standalone and does not link any x client libs (for
1959 #       use by XA tracker in particular, but could be used in any case
1960 #       where communication with xserver is not desired).
1961 if test "x$enable_gallium_loader" = xyes; then
1962     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1963
1964     if test "x$NEED_WINSYS_XLIB" = xyes; then
1965         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1966     fi
1967
1968     if test "x$enable_dri" = xyes; then
1969         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
1970     fi
1971
1972     if test "x$enable_gallium_drm_loader" = xyes; then
1973         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1974         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1975                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1976         if test "x$pipe_loader_have_xcb" = xyes; then
1977             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1978             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1979         fi
1980     fi
1981
1982     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1983     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1984
1985     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1986     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1987     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1988     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1989 fi
1990
1991 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1992 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1993 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1994 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1995 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1996 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1997
1998 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1999                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2000                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2001                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2002 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2003                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2004 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2005 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2006 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2007 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2008 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2009 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2010 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2011
2012 AC_SUBST([ELF_LIB])
2013
2014 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2015 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2016 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2017 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2018 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2019
2020 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2021 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2022 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2023
2024 AC_SUBST([VDPAU_MAJOR], 1)
2025 AC_SUBST([VDPAU_MINOR], 0)
2026
2027 AC_SUBST([XVMC_MAJOR], 1)
2028 AC_SUBST([XVMC_MINOR], 0)
2029
2030 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2031 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2032 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2033 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2034
2035 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2036 AC_SUBST([XA_MINOR], $XA_MINOR)
2037 AC_SUBST([XA_TINY], $XA_TINY)
2038 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2039
2040 dnl Restore LDFLAGS and CPPFLAGS
2041 LDFLAGS="$_SAVE_LDFLAGS"
2042 CPPFLAGS="$_SAVE_CPPFLAGS"
2043
2044 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2045 if test "x$acv_mesa_CLANG" = xyes; then
2046     CFLAGS="$CFLAGS -Qunused-arguments"
2047     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2048 fi
2049
2050 dnl Add user CFLAGS and CXXFLAGS
2051 CFLAGS="$CFLAGS $USER_CFLAGS"
2052 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2053
2054 dnl Substitute the config
2055 AC_CONFIG_FILES([Makefile
2056                 src/Makefile
2057                 src/egl/drivers/dri2/Makefile
2058                 src/egl/main/Makefile
2059                 src/egl/main/egl.pc
2060                 src/egl/wayland/Makefile
2061                 src/egl/wayland/wayland-drm/Makefile
2062                 src/egl/wayland/wayland-egl/Makefile
2063                 src/egl/wayland/wayland-egl/wayland-egl.pc
2064                 src/gallium/auxiliary/Makefile
2065                 src/gallium/auxiliary/pipe-loader/Makefile
2066                 src/gallium/drivers/Makefile
2067                 src/gallium/drivers/freedreno/Makefile
2068                 src/gallium/drivers/galahad/Makefile
2069                 src/gallium/drivers/i915/Makefile
2070                 src/gallium/drivers/identity/Makefile
2071                 src/gallium/drivers/ilo/Makefile
2072                 src/gallium/drivers/llvmpipe/Makefile
2073                 src/gallium/drivers/noop/Makefile
2074                 src/gallium/drivers/nouveau/Makefile
2075                 src/gallium/drivers/r300/Makefile
2076                 src/gallium/drivers/r600/Makefile
2077                 src/gallium/drivers/radeon/Makefile
2078                 src/gallium/drivers/radeonsi/Makefile
2079                 src/gallium/drivers/rbug/Makefile
2080                 src/gallium/drivers/softpipe/Makefile
2081                 src/gallium/drivers/svga/Makefile
2082                 src/gallium/drivers/trace/Makefile
2083                 src/gallium/state_trackers/Makefile
2084                 src/gallium/state_trackers/clover/Makefile
2085                 src/gallium/state_trackers/dri/Makefile
2086                 src/gallium/state_trackers/dri/drm/Makefile
2087                 src/gallium/state_trackers/dri/sw/Makefile
2088                 src/gallium/state_trackers/egl/Makefile
2089                 src/gallium/state_trackers/gbm/Makefile
2090                 src/gallium/state_trackers/glx/xlib/Makefile
2091                 src/gallium/state_trackers/omx/Makefile
2092                 src/gallium/state_trackers/osmesa/Makefile
2093                 src/gallium/state_trackers/vdpau/Makefile
2094                 src/gallium/state_trackers/vega/Makefile
2095                 src/gallium/state_trackers/xa/Makefile
2096                 src/gallium/state_trackers/xvmc/Makefile
2097                 src/gallium/targets/Makefile
2098                 src/gallium/targets/dri-freedreno/Makefile
2099                 src/gallium/targets/dri-i915/Makefile
2100                 src/gallium/targets/dri-ilo/Makefile
2101                 src/gallium/targets/dri-nouveau/Makefile
2102                 src/gallium/targets/dri-swrast/Makefile
2103                 src/gallium/targets/dri-vmwgfx/Makefile
2104                 src/gallium/targets/egl-static/Makefile
2105                 src/gallium/targets/gbm/Makefile
2106                 src/gallium/targets/opencl/Makefile
2107                 src/gallium/targets/xa/Makefile
2108                 src/gallium/targets/xa/xatracker.pc
2109                 src/gallium/targets/omx-nouveau/Makefile
2110                 src/gallium/targets/osmesa/Makefile
2111                 src/gallium/targets/osmesa/osmesa.pc
2112                 src/gallium/targets/pipe-loader/Makefile
2113                 src/gallium/targets/radeonsi/dri/Makefile
2114                 src/gallium/targets/radeonsi/omx/Makefile
2115                 src/gallium/targets/radeonsi/vdpau/Makefile
2116                 src/gallium/targets/r300/dri/Makefile
2117                 src/gallium/targets/r600/dri/Makefile
2118                 src/gallium/targets/r600/omx/Makefile
2119                 src/gallium/targets/r600/vdpau/Makefile
2120                 src/gallium/targets/r600/xvmc/Makefile
2121                 src/gallium/targets/libgl-xlib/Makefile
2122                 src/gallium/targets/vdpau-nouveau/Makefile
2123                 src/gallium/targets/xvmc-nouveau/Makefile
2124                 src/gallium/tests/trivial/Makefile
2125                 src/gallium/tests/unit/Makefile
2126                 src/gallium/winsys/Makefile
2127                 src/gallium/winsys/freedreno/drm/Makefile
2128                 src/gallium/winsys/i915/drm/Makefile
2129                 src/gallium/winsys/i915/sw/Makefile
2130                 src/gallium/winsys/intel/drm/Makefile
2131                 src/gallium/winsys/nouveau/drm/Makefile
2132                 src/gallium/winsys/radeon/drm/Makefile
2133                 src/gallium/winsys/svga/drm/Makefile
2134                 src/gallium/winsys/sw/dri/Makefile
2135                 src/gallium/winsys/sw/fbdev/Makefile
2136                 src/gallium/winsys/sw/null/Makefile
2137                 src/gallium/winsys/sw/wayland/Makefile
2138                 src/gallium/winsys/sw/wrapper/Makefile
2139                 src/gallium/winsys/sw/xlib/Makefile
2140                 src/gbm/Makefile
2141                 src/gbm/main/gbm.pc
2142                 src/glsl/Makefile
2143                 src/glx/Makefile
2144                 src/glx/tests/Makefile
2145                 src/gtest/Makefile
2146                 src/loader/Makefile
2147                 src/mapi/Makefile
2148                 src/mapi/es1api/Makefile
2149                 src/mapi/es1api/glesv1_cm.pc
2150                 src/mapi/es2api/Makefile
2151                 src/mapi/es2api/glesv2.pc
2152                 src/mapi/glapi/Makefile
2153                 src/mapi/glapi/gen/Makefile
2154                 src/mapi/glapi/tests/Makefile
2155                 src/mapi/shared-glapi/Makefile
2156                 src/mapi/shared-glapi/tests/Makefile
2157                 src/mapi/vgapi/Makefile
2158                 src/mapi/vgapi/vg.pc
2159                 src/mesa/Makefile
2160                 src/mesa/gl.pc
2161                 src/mesa/drivers/dri/dri.pc
2162                 src/mesa/drivers/dri/common/Makefile
2163                 src/mesa/drivers/dri/common/xmlpool/Makefile
2164                 src/mesa/drivers/dri/i915/Makefile
2165                 src/mesa/drivers/dri/i965/Makefile
2166                 src/mesa/drivers/dri/Makefile
2167                 src/mesa/drivers/dri/nouveau/Makefile
2168                 src/mesa/drivers/dri/r200/Makefile
2169                 src/mesa/drivers/dri/radeon/Makefile
2170                 src/mesa/drivers/dri/swrast/Makefile
2171                 src/mesa/drivers/osmesa/Makefile
2172                 src/mesa/drivers/osmesa/osmesa.pc
2173                 src/mesa/drivers/x11/Makefile
2174                 src/mesa/main/tests/Makefile
2175                 src/mesa/main/tests/hash_table/Makefile])
2176
2177 dnl Sort the dirs alphabetically
2178 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2179 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2180 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2181 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2182
2183 AC_OUTPUT
2184
2185 dnl
2186 dnl Output some configuration info for the user
2187 dnl
2188 echo ""
2189 echo "        prefix:          $prefix"
2190 echo "        exec_prefix:     $exec_prefix"
2191 echo "        libdir:          $libdir"
2192 echo "        includedir:      $includedir"
2193
2194 dnl API info
2195 echo ""
2196 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2197 echo "        OpenVG:          $enable_openvg"
2198
2199 dnl Driver info
2200 echo ""
2201 case "x$enable_osmesa$enable_gallium_osmesa" in
2202 xnoyes)
2203         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2204         ;;
2205 xyesno)
2206         echo "        OSMesa:          lib$OSMESA_LIB"
2207         ;;
2208 xnono)
2209         echo "        OSMesa:          no"
2210         ;;
2211 esac
2212
2213 if test "x$enable_dri" != xno; then
2214         if test -z "$DRI_DIRS"; then
2215             echo "        DRI drivers:     no"
2216         else
2217             echo "        DRI drivers:     $DRI_DIRS"
2218         fi
2219         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2220 fi
2221
2222 case "x$enable_glx$enable_xlib_glx" in
2223 xyesyes)
2224     echo "        GLX:             Xlib-based"
2225     ;;
2226 xyesno)
2227     echo "        GLX:             DRI-based"
2228     ;;
2229 *)
2230     echo "        GLX:             $enable_glx"
2231     ;;
2232 esac
2233
2234 dnl EGL
2235 echo ""
2236 echo "        EGL:             $enable_egl"
2237 if test "$enable_egl" = yes; then
2238     echo "        EGL platforms:   $egl_platforms"
2239
2240     egl_drivers=""
2241     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2242         egl_drivers="$egl_drivers builtin:egl_dri2"
2243     fi
2244
2245     if test "x$enable_gallium_egl" = xyes; then
2246         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2247         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2248     else
2249         echo "        EGL drivers:    $egl_drivers"
2250     fi
2251 fi
2252
2253 echo ""
2254 if test "x$MESA_LLVM" = x1; then
2255     echo "        llvm:            yes"
2256     echo "        llvm-config:     $LLVM_CONFIG"
2257     echo "        llvm-version:    $LLVM_VERSION"
2258 else
2259     echo "        llvm:            no"
2260 fi
2261
2262 echo ""
2263 if test -n "$with_gallium_drivers"; then
2264     echo "        Gallium:         yes"
2265     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2266     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2267     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2268     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2269 else
2270     echo "        Gallium:         no"
2271 fi
2272
2273
2274 dnl Libraries
2275 echo ""
2276 echo "        Shared libs:     $enable_shared"
2277 echo "        Static libs:     $enable_static"
2278 echo "        Shared-glapi:    $enable_shared_glapi"
2279
2280 dnl Compiler options
2281 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2282 cflags=`echo $CFLAGS | \
2283     $SED 's/^ *//;s/  */ /;s/ *$//'`
2284 cxxflags=`echo $CXXFLAGS | \
2285     $SED 's/^ *//;s/  */ /;s/ *$//'`
2286 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2287 echo ""
2288 echo "        CFLAGS:          $cflags"
2289 echo "        CXXFLAGS:        $cxxflags"
2290 echo "        Macros:          $defines"
2291 echo ""
2292 if test "x$MESA_LLVM" = x1; then
2293     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2294     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2295     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2296     echo ""
2297 fi
2298 echo "        PYTHON2:         $PYTHON2"
2299
2300 echo ""
2301 echo "        Run '${MAKE-make}' to build Mesa"
2302 echo ""