configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports garbage collection
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 323 AC_MSG_CHECKING([whether ld supports --gc-sections])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         GC_SECTIONS="-Wl,--gc-sections";],
 328     [AC_MSG_RESULT([no])
 329         GC_SECTIONS="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([GC_SECTIONS])
 333
 334 dnl
 335 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 336 dnl so when these flags are passed to ld via libtool the checks will fail
 337 dnl
 338 case "$host_os" in
 339 openbsd*)
 340     LD_NO_UNDEFINED="" ;;
 341 *)
 342     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 343 esac
 344
 345 AC_SUBST([LD_NO_UNDEFINED])
 346
 347 dnl
 348 dnl compatibility symlinks
 349 dnl
 350 case "$host_os" in
 351 linux* )
 352     HAVE_COMPAT_SYMLINKS=yes ;;
 353 * )
 354     HAVE_COMPAT_SYMLINKS=no ;;
 355 esac
 356
 357 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 358
 359 dnl
 360 dnl library names
 361 dnl
 362 case "$host_os" in
 363 darwin* )
 364     LIB_EXT='dylib' ;;
 365 cygwin* )
 366     LIB_EXT='dll' ;;
 367 aix* )
 368     LIB_EXT='a' ;;
 369 * )
 370     LIB_EXT='so' ;;
 371 esac
 372
 373 AC_SUBST([LIB_EXT])
 374
 375 AC_ARG_WITH([gl-lib-name],
 376   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 377     [specify GL library name @<:@default=GL@:>@])],
 378   [GL_LIB=$withval],
 379   [GL_LIB=GL])
 380 AC_ARG_WITH([osmesa-lib-name],
 381   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 382     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 383   [OSMESA_LIB=$withval],
 384   [OSMESA_LIB=OSMesa])
 385 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 386 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 387
 388 dnl
 389 dnl Mangled Mesa support
 390 dnl
 391 AC_ARG_ENABLE([mangling],
 392   [AS_HELP_STRING([--enable-mangling],
 393     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 394   [enable_mangling="${enableval}"],
 395   [enable_mangling=no]
 396 )
 397 if test "x${enable_mangling}" = "xyes" ; then
 398   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 399   GL_LIB="Mangled${GL_LIB}"
 400   OSMESA_LIB="Mangled${OSMESA_LIB}"
 401 fi
 402 AC_SUBST([GL_LIB])
 403 AC_SUBST([OSMESA_LIB])
 404
 405 dnl
 406 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 407 dnl
 408 AC_ARG_ENABLE([texture-float],
 409     [AS_HELP_STRING([--enable-texture-float],
 410         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 411     [enable_texture_float="$enableval"],
 412     [enable_texture_float=no]
 413 )
 414 if test "x$enable_texture_float" = xyes; then
 415     AC_MSG_WARN([Floating-point textures enabled.])
 416     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 417     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 418 fi
 419
 420 dnl
 421 dnl Arch/platform-specific settings
 422 dnl
 423 AC_ARG_ENABLE([asm],
 424     [AS_HELP_STRING([--disable-asm],
 425         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 426     [enable_asm="$enableval"],
 427     [enable_asm=yes]
 428 )
 429 asm_arch=""
 430 AC_MSG_CHECKING([whether to enable assembly])
 431 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 432 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 433 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 434     case "$host_cpu" in
 435     i?86 | x86_64 | amd64)
 436         enable_asm=no
 437         AC_MSG_RESULT([no, cross compiling])
 438         ;;
 439     esac
 440 fi
 441 # check for supported arches
 442 if test "x$enable_asm" = xyes; then
 443     case "$host_cpu" in
 444     i?86)
 445         case "$host_os" in
 446         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 447             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 448             ;;
 449         gnu*)
 450             asm_arch=x86
 451             ;;
 452         esac
 453         ;;
 454     x86_64|amd64)
 455         case "$host_os" in
 456         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 457             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 458             ;;
 459         esac
 460         ;;
 461     sparc*)
 462         case "$host_os" in
 463         linux*)
 464             asm_arch=sparc
 465             ;;
 466         esac
 467         ;;
 468     esac
 469
 470     case "$asm_arch" in
 471     x86)
 472         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 473         AC_MSG_RESULT([yes, x86])
 474         ;;
 475     x86_64|amd64)
 476         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 477         AC_MSG_RESULT([yes, x86_64])
 478         ;;
 479     sparc)
 480         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 481         AC_MSG_RESULT([yes, sparc])
 482         ;;
 483     *)
 484         AC_MSG_RESULT([no, platform not supported])
 485         ;;
 486     esac
 487 fi
 488
 489 dnl Check to see if dlopen is in default libraries (like Solaris, which
 490 dnl has it in libc), or if libdl is needed to get it.
 491 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 492     [AC_CHECK_LIB([dl], [dlopen],
 493        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 494 AC_SUBST([DLOPEN_LIBS])
 495
 496 dnl Check if that library also has dladdr
 497 save_LDFLAGS="$LDFLAGS"
 498 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 499 AC_CHECK_FUNCS([dladdr])
 500 LDFLAGS="$save_LDFLAGS"
 501
 502 case "$host_os" in
 503 darwin*|mingw*)
 504     ;;
 505 *)
 506     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 507                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 508                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 509     AC_SUBST([CLOCK_LIB])
 510     ;;
 511 esac
 512
 513 dnl See if posix_memalign is available
 514 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 515
 516 dnl Check for pthreads
 517 AX_PTHREAD
 518 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 519 dnl to -pthread, which causes problems if we need -lpthread to appear in
 520 dnl pkgconfig files.
 521 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 522
 523 dnl SELinux awareness.
 524 AC_ARG_ENABLE([selinux],
 525     [AS_HELP_STRING([--enable-selinux],
 526         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 527     [MESA_SELINUX="$enableval"],
 528     [MESA_SELINUX=no])
 529 if test "x$enable_selinux" = "xyes"; then
 530     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 531         [AC_CHECK_HEADER([selinux/selinux.h],[],
 532                          [AC_MSG_ERROR([SELinux headers not found])])
 533          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 534                       [AC_MSG_ERROR([SELinux library not found])])
 535          SELINUX_LIBS="-lselinux"])
 536     DEFINES="$DEFINES -DMESA_SELINUX"
 537 fi
 538 AC_SUBST([SELINUX_CFLAGS])
 539 AC_SUBST([SELINUX_LIBS])
 540
 541 dnl Options for APIs
 542 AC_ARG_ENABLE([opengl],
 543     [AS_HELP_STRING([--disable-opengl],
 544         [disable support for standard OpenGL API @<:@default=no@:>@])],
 545     [enable_opengl="$enableval"],
 546     [enable_opengl=yes])
 547 AC_ARG_ENABLE([gles1],
 548     [AS_HELP_STRING([--enable-gles1],
 549         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 550     [enable_gles1="$enableval"],
 551     [enable_gles1=no])
 552 AC_ARG_ENABLE([gles2],
 553     [AS_HELP_STRING([--enable-gles2],
 554         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 555     [enable_gles2="$enableval"],
 556     [enable_gles2=no])
 557 AC_ARG_ENABLE([openvg],
 558     [AS_HELP_STRING([--enable-openvg],
 559         [enable support for OpenVG API @<:@default=no@:>@])],
 560     [enable_openvg="$enableval"],
 561     [enable_openvg=no])
 562
 563 AC_ARG_ENABLE([dri],
 564     [AS_HELP_STRING([--enable-dri],
 565         [enable DRI modules @<:@default=enabled@:>@])],
 566     [enable_dri="$enableval"],
 567     [enable_dri=yes])
 568
 569 case "$host_os" in
 570 linux*)
 571     dri3_default=yes
 572     ;;
 573 *)
 574     dri3_default=no
 575     ;;
 576 esac
 577 AC_ARG_ENABLE([dri3],
 578     [AS_HELP_STRING([--enable-dri3],
 579         [enable DRI3 @<:@default=auto@:>@])],
 580     [enable_dri3="$enableval"],
 581     [enable_dri3="$dri3_default"])
 582 AC_ARG_ENABLE([glx],
 583     [AS_HELP_STRING([--enable-glx],
 584         [enable GLX library @<:@default=enabled@:>@])],
 585     [enable_glx="$enableval"],
 586     [enable_glx=yes])
 587 AC_ARG_ENABLE([osmesa],
 588     [AS_HELP_STRING([--enable-osmesa],
 589         [enable OSMesa library @<:@default=disabled@:>@])],
 590     [enable_osmesa="$enableval"],
 591     [enable_osmesa=no])
 592 AC_ARG_ENABLE([gallium-osmesa],
 593     [AS_HELP_STRING([--enable-gallium-osmesa],
 594         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 595     [enable_gallium_osmesa="$enableval"],
 596     [enable_gallium_osmesa=no])
 597 AC_ARG_ENABLE([egl],
 598     [AS_HELP_STRING([--disable-egl],
 599         [disable EGL library @<:@default=enabled@:>@])],
 600     [enable_egl="$enableval"],
 601     [enable_egl=yes])
 602
 603 AC_ARG_ENABLE([xa],
 604     [AS_HELP_STRING([--enable-xa],
 605         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 606     [enable_xa="$enableval"],
 607     [enable_xa=no])
 608 AC_ARG_ENABLE([gbm],
 609    [AS_HELP_STRING([--enable-gbm],
 610          [enable gbm library @<:@default=auto@:>@])],
 611    [enable_gbm="$enableval"],
 612    [enable_gbm=auto])
 613
 614 AC_ARG_ENABLE([xvmc],
 615    [AS_HELP_STRING([--enable-xvmc],
 616          [enable xvmc library @<:@default=auto@:>@])],
 617    [enable_xvmc="$enableval"],
 618    [enable_xvmc=no])
 619 AC_ARG_ENABLE([vdpau],
 620    [AS_HELP_STRING([--enable-vdpau],
 621          [enable vdpau library @<:@default=auto@:>@])],
 622    [enable_vdpau="$enableval"],
 623    [enable_vdpau=auto])
 624 AC_ARG_ENABLE([omx],
 625    [AS_HELP_STRING([--enable-omx],
 626          [enable OpenMAX library @<:@default=no@:>@])],
 627    [enable_omx="$enableval"],
 628    [enable_omx=no])
 629 AC_ARG_ENABLE([opencl],
 630    [AS_HELP_STRING([--enable-opencl],
 631          [enable OpenCL library @<:@default=no@:>@])],
 632    [enable_opencl="$enableval"],
 633    [enable_opencl=no])
 634 AC_ARG_ENABLE([opencl_icd],
 635    [AS_HELP_STRING([--enable-opencl-icd],
 636           [Build an OpenCL ICD library to be loaded by an ICD implementation
 637            @<:@default=no@:>@])],
 638     [enable_opencl_icd="$enableval"],
 639     [enable_opencl_icd=no])
 640 AC_ARG_ENABLE([xlib-glx],
 641     [AS_HELP_STRING([--enable-xlib-glx],
 642         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 643     [enable_xlib_glx="$enableval"],
 644     [enable_xlib_glx=no])
 645 AC_ARG_ENABLE([gallium-egl],
 646     [AS_HELP_STRING([--enable-gallium-egl],
 647         [enable optional EGL state tracker (not required
 648          for EGL support in Gallium with OpenGL and OpenGL ES)
 649          @<:@default=disable@:>@])],
 650     [enable_gallium_egl="$enableval"],
 651     [enable_gallium_egl=no])
 652 AC_ARG_ENABLE([gallium-gbm],
 653     [AS_HELP_STRING([--enable-gallium-gbm],
 654         [enable optional gbm state tracker (not required for
 655          gbm support in Gallium)
 656          @<:@default=auto@:>@])],
 657     [enable_gallium_gbm="$enableval"],
 658     [enable_gallium_gbm=auto])
 659
 660 AC_ARG_ENABLE([r600-llvm-compiler],
 661     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 662         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 663     [enable_r600_llvm="$enableval"],
 664     [enable_r600_llvm=no])
 665
 666 AC_ARG_ENABLE([gallium-tests],
 667     [AS_HELP_STRING([--enable-gallium-tests],
 668         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 669     [enable_gallium_tests="$enableval"],
 670     [enable_gallium_tests=no])
 671
 672 # Option for Gallium drivers
 673
 674 # Keep this in sync with the --with-gallium-drivers help string default value
 675 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 676
 677 AC_ARG_WITH([gallium-drivers],
 678     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 679         [comma delimited Gallium drivers list, e.g.
 680         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 681         @<:@default=r300,r600,svga,swrast@:>@])],
 682     [with_gallium_drivers="$withval"],
 683     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 684
 685 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 686 # here so that the script doesn't choke on an unknown driver name later.
 687 case "$with_gallium_drivers" in
 688     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 689     no) with_gallium_drivers='' ;;
 690 esac
 691
 692 if test "x$enable_opengl" = xno -a \
 693         "x$enable_gles1" = xno -a \
 694         "x$enable_gles2" = xno -a \
 695         "x$enable_openvg" = xno -a \
 696         "x$enable_xa" = xno -a \
 697         "x$enable_xvmc" = xno -a \
 698         "x$enable_vdpau" = xno -a \
 699         "x$enable_omx" = xno -a \
 700         "x$enable_opencl" = xno; then
 701     AC_MSG_ERROR([at least one API should be enabled])
 702 fi
 703
 704 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 705 if test "x$enable_opengl" = xno -a \
 706         "x$enable_gles1" = xyes; then
 707     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 708 fi
 709
 710 if test "x$enable_opengl" = xno -a \
 711         "x$enable_gles2" = xyes; then
 712     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 713 fi
 714
 715 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 716 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 717 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 718 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 719                                         "x$enable_gles1" = xyes -o \
 720                                         "x$enable_gles2" = xyes)
 721
 722 if test "x$enable_glx" = xno; then
 723     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 724     enable_xlib_glx=no
 725 fi
 726
 727 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 728     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 729 fi
 730
 731 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 732     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 733 fi
 734
 735 # Disable GLX if OpenGL is not enabled
 736 if test "x$enable_glx$enable_opengl" = xyesno; then
 737     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 738     enable_glx=no
 739 fi
 740
 741 # Disable GLX if DRI and Xlib-GLX are not enabled
 742 if test "x$enable_glx" = xyes -a \
 743         "x$enable_dri" = xno -a \
 744         "x$enable_xlib_glx" = xno; then
 745     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 746     enable_glx=no
 747 fi
 748
 749 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 750                                   "x$enable_dri" = xyes)
 751 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 752 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 753
 754 AC_ARG_ENABLE([shared-glapi],
 755     [AS_HELP_STRING([--enable-shared-glapi],
 756         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 757     [enable_shared_glapi="$enableval"],
 758     [enable_shared_glapi=yes])
 759
 760 case "x$enable_opengl$enable_gles1$enable_gles2" in
 761 x*yes*yes*)
 762     if test "x$enable_shared_glapi" = xno; then
 763         AC_MSG_ERROR([shared GLAPI required when building two or more of
 764                       the following APIs - opengl, gles1 gles2])
 765     fi
 766     ;;
 767 esac
 768
 769 # Building Xlib-GLX requires shared glapi to be disabled.
 770 if test "x$enable_xlib_glx" = xyes; then
 771     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 772     enable_shared_glapi=no
 773 fi
 774
 775 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 776
 777 dnl
 778 dnl Driver specific build directories
 779 dnl
 780 GALLIUM_TARGET_DIRS=""
 781 GALLIUM_WINSYS_DIRS="sw"
 782 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 783 GALLIUM_STATE_TRACKERS_DIRS=""
 784
 785 case "x$enable_glx$enable_xlib_glx" in
 786 xyesyes)
 787     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 788     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 789     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 790     NEED_WINSYS_XLIB="yes"
 791     ;;
 792 esac
 793
 794 if test "x$enable_dri" = xyes; then
 795     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 796     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 797 fi
 798
 799 if test "x$enable_gallium_osmesa" = xyes; then
 800     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 801         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 802     fi
 803     if test "x$enable_osmesa" = xyes; then
 804         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 805     fi
 806     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 807     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 808 fi
 809
 810 AC_SUBST([MESA_LLVM])
 811
 812 # Check for libdrm
 813 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 814                   [have_libdrm=yes], [have_libdrm=no])
 815 if test "x$have_libdrm" = xyes; then
 816         DEFINES="$DEFINES -DHAVE_LIBDRM"
 817 fi
 818
 819 case "$host_os" in
 820 linux*)
 821     need_libudev=yes ;;
 822 *)
 823     need_libudev=no ;;
 824 esac
 825
 826 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 827                   have_libudev=yes, have_libudev=no)
 828
 829 if test "x$enable_dri" = xyes; then
 830     if test "$enable_static" = yes; then
 831         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 832     fi
 833
 834     # not a hard requirement as swrast does not depend on it
 835     if test "x$have_libdrm" = xyes; then
 836         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 837     fi
 838 fi
 839
 840 dnl Direct rendering or just indirect rendering
 841 case "$host_os" in
 842 gnu*)
 843     dnl Disable by default on GNU/Hurd
 844     driglx_direct_default="no"
 845     ;;
 846 cygwin*)
 847     dnl Disable by default on cygwin
 848     driglx_direct_default="no"
 849     ;;
 850 *)
 851     driglx_direct_default="yes"
 852     ;;
 853 esac
 854 AC_ARG_ENABLE([driglx-direct],
 855     [AS_HELP_STRING([--disable-driglx-direct],
 856         [disable direct rendering in GLX and EGL for DRI \
 857             @<:@default=auto@:>@])],
 858     [driglx_direct="$enableval"],
 859     [driglx_direct="$driglx_direct_default"])
 860
 861 dnl
 862 dnl libGL configuration per driver
 863 dnl
 864 case "x$enable_glx$enable_xlib_glx" in
 865 xyesyes)
 866     # Xlib-based GLX
 867     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 868     GL_PC_REQ_PRIV="x11 xext"
 869     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 870     GL_LIB_DEPS="$XLIBGL_LIBS"
 871     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 872     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 873     ;;
 874 xyesno)
 875     # DRI-based GLX
 876     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 877     if test x"$driglx_direct" = xyes; then
 878         if test "x$have_libdrm" != xyes; then
 879             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 880         fi
 881         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 882         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 883         if test x"$enable_dri3" = xyes; then
 884             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 885             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 886         fi
 887     fi
 888
 889     # find the DRI deps for libGL
 890     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 891
 892     if test x"$enable_dri3" = xyes; then
 893         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 894     fi
 895
 896     # add xf86vidmode if available
 897     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 898     if test "$HAVE_XF86VIDMODE" = yes ; then
 899         dri_modules="$dri_modules xxf86vm"
 900     fi
 901
 902     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 903     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 904     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 905     GL_LIB_DEPS="$DRIGL_LIBS"
 906
 907     # need DRM libs, $PTHREAD_LIBS, etc.
 908     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 909     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 910     ;;
 911 esac
 912
 913 if test "$have_libudev" = yes; then
 914     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 915 fi
 916
 917 # This is outside the case (above) so that it is invoked even for non-GLX
 918 # builds.
 919 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 920
 921 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 922 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 923 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 924 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 925
 926 AC_SUBST([X11_INCLUDES])
 927 AC_SUBST([GL_LIB_DEPS])
 928 AC_SUBST([GL_PC_REQ_PRIV])
 929 AC_SUBST([GL_PC_LIB_PRIV])
 930 AC_SUBST([GL_PC_CFLAGS])
 931 AC_SUBST([DRI_PC_REQ_PRIV])
 932 AC_SUBST([GLESv1_CM_LIB_DEPS])
 933 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 934 AC_SUBST([GLESv2_LIB_DEPS])
 935 AC_SUBST([GLESv2_PC_LIB_PRIV])
 936
 937 AC_SUBST([HAVE_XF86VIDMODE])
 938
 939 dnl
 940 dnl More GLX setup
 941 dnl
 942 case "x$enable_glx$enable_xlib_glx" in
 943 xyesyes)
 944     DEFINES="$DEFINES -DUSE_XSHM"
 945     ;;
 946 xyesno)
 947     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 948     if test "x$driglx_direct" = xyes; then
 949         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 950     fi
 951     ;;
 952 esac
 953
 954 dnl
 955 dnl TLS detection
 956 dnl
 957
 958 AC_ARG_ENABLE([glx-tls],
 959     [AS_HELP_STRING([--enable-glx-tls],
 960         [enable TLS support in GLX @<:@default=disabled@:>@])],
 961     [GLX_USE_TLS="$enableval"],
 962     [GLX_USE_TLS=no])
 963 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 964
 965 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 966       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 967
 968 dnl
 969 dnl More DRI setup
 970 dnl
 971 dnl Directory for DRI drivers
 972 AC_ARG_WITH([dri-driverdir],
 973     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 974         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 975     [DRI_DRIVER_INSTALL_DIR="$withval"],
 976     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 977 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 978 dnl Extra search path for DRI drivers
 979 AC_ARG_WITH([dri-searchpath],
 980     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 981         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 982     [DRI_DRIVER_SEARCH_DIR="$withval"],
 983     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 984 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 985 dnl Which drivers to build - default is chosen by platform
 986 AC_ARG_WITH([dri-drivers],
 987     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 988         [comma delimited classic DRI drivers list, e.g.
 989         "swrast,i965,radeon" @<:@default=auto@:>@])],
 990     [with_dri_drivers="$withval"],
 991     [with_dri_drivers=auto])
 992
 993 if test "x$with_dri_drivers" = xauto; then
 994     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 995         with_dri_drivers="yes"
 996     else
 997         with_dri_drivers="no"
 998     fi
 999 fi
1000 if test "x$with_dri_drivers" = xno; then
1001     with_dri_drivers=''
1002 fi
1003
1004 dnl If $with_dri_drivers is yes, drivers will be added through
1005 dnl platform checks. Set DEFINES and LIB_DEPS
1006 if test "x$enable_dri" = xyes; then
1007     # Platform specific settings and drivers to build
1008     case "$host_os" in
1009     linux*)
1010         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1011         DEFINES="$DEFINES -DHAVE_ALIAS"
1012         if test "x$enable_dri3" = xyes; then
1013             DEFINES="$DEFINES -DHAVE_DRI3"
1014         fi
1015
1016         if test "x$have_libudev" != xyes; then
1017             AC_MSG_ERROR([libudev-dev required for building DRI])
1018         fi
1019
1020         case "$host_cpu" in
1021         powerpc* | sparc*)
1022             # Build only the drivers for cards that exist on PowerPC/sparc
1023             if test "x$with_dri_drivers" = "xyes"; then
1024                 with_dri_drivers="r200 radeon swrast"
1025             fi
1026             ;;
1027         esac
1028         ;;
1029     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1030         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1031         DEFINES="$DEFINES -DHAVE_ALIAS"
1032         ;;
1033     gnu*)
1034         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1035         DEFINES="$DEFINES -DHAVE_ALIAS"
1036         ;;
1037     solaris*)
1038         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1039         ;;
1040     cygwin*)
1041         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1042         if test "x$with_dri_drivers" = "xyes"; then
1043             with_dri_drivers="swrast"
1044         fi
1045         ;;
1046     esac
1047
1048     # default drivers
1049     if test "x$with_dri_drivers" = "xyes"; then
1050         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1051     fi
1052
1053     # Check for expat
1054     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1055     if test "x$have_expat" = "xyes"; then
1056        PKG_CHECK_MODULES([EXPAT], [expat], [],
1057                          AC_MSG_ERROR([Expat required for DRI.]))
1058     else
1059        # expat version 2.0 and earlier do not provide expat.pc
1060        EXPAT_LIBS=-lexpat
1061     fi
1062
1063     # If we are building any DRI driver other than swrast.
1064     if test -n "$with_dri_drivers"; then
1065         if test "x$with_dri_drivers" != xswrast; then
1066             # ... libdrm is required
1067             if test "x$have_libdrm" != xyes; then
1068                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1069             fi
1070             DRICOMMON_NEED_LIBDRM=yes
1071         else
1072             DRICOMMON_NEED_LIBDRM=no
1073         fi
1074     fi
1075
1076     # put all the necessary libs together
1077     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1078 fi
1079
1080 AC_SUBST([DRI_LIB_DEPS])
1081
1082 DRI_DIRS=''
1083 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1084 if test -n "$with_dri_drivers"; then
1085     if test "x$enable_opengl" != xyes; then
1086         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1087     fi
1088
1089     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1090     for driver in $dri_drivers; do
1091         DRI_DIRS="$DRI_DIRS $driver"
1092         case "x$driver" in
1093         xi915)
1094             HAVE_I915_DRI=yes;
1095             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1096             ;;
1097         xi965)
1098             HAVE_I965_DRI=yes;
1099             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1100             ;;
1101         xnouveau)
1102             HAVE_NOUVEAU_DRI=yes;
1103             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1104             ;;
1105         xradeon)
1106             HAVE_RADEON_DRI=yes;
1107             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1108             ;;
1109         xr200)
1110             HAVE_R200_DRI=yes;
1111             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1112             ;;
1113         xswrast)
1114             HAVE_SWRAST_DRI=yes;
1115             ;;
1116         *)
1117             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1118             ;;
1119         esac
1120     done
1121     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1122 fi
1123
1124 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1125 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1126                                   "x$enable_osmesa" = xyes -o \
1127                                   -n "$DRI_DIRS")
1128
1129 dnl
1130 dnl OSMesa configuration
1131 dnl
1132
1133 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1134 AC_ARG_WITH([osmesa-bits],
1135     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1136         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1137     [osmesa_bits="$withval"],
1138     [osmesa_bits=8])
1139 if test "x$osmesa_bits" != x8; then
1140     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1141         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1142         osmesa_bits=8
1143     fi
1144 fi
1145 case "x$osmesa_bits" in
1146 x8)
1147     OSMESA_LIB="${OSMESA_LIB}"
1148     ;;
1149 x16|x32)
1150     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1151     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1152     ;;
1153 *)
1154     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1155     ;;
1156 esac
1157
1158 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1159     # only link libraries with osmesa if shared
1160     if test "$enable_static" = no; then
1161         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1162     else
1163         OSMESA_LIB_DEPS=""
1164     fi
1165     OSMESA_MESA_DEPS=""
1166     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1167 fi
1168
1169 AC_SUBST([OSMESA_LIB_DEPS])
1170 AC_SUBST([OSMESA_MESA_DEPS])
1171 AC_SUBST([OSMESA_PC_REQ])
1172 AC_SUBST([OSMESA_PC_LIB_PRIV])
1173
1174 dnl
1175 dnl gbm configuration
1176 dnl
1177 if test "x$enable_gbm" = xauto; then
1178     case "$with_egl_platforms" in
1179         *drm*)
1180             enable_gbm=yes ;;
1181          *)
1182             enable_gbm=no ;;
1183     esac
1184 fi
1185 if test "x$enable_gbm" = xyes; then
1186     if test "x$need_libudev$have_libudev" = xyesno; then
1187         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1188     fi
1189
1190     if test "x$enable_dri" = xyes; then
1191         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1192         if test "x$enable_shared_glapi" = xno; then
1193             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1194         fi
1195     else
1196         # Strictly speaking libgbm does not require --enable-dri, although
1197         # both of its backends do. Thus one can build libgbm without any
1198         # backends if --disable-dri is set.
1199         # To avoid unnecessary complexity of checking if at least one backend
1200         # is available when building, just mandate --enable-dri.
1201         AC_MSG_ERROR([gbm requires --enable-dri])
1202     fi
1203 fi
1204 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1205 if test "x$need_libudev" = xyes; then
1206     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1207 else
1208     GBM_PC_REQ_PRIV=""
1209 fi
1210 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1211 AC_SUBST([GBM_PC_REQ_PRIV])
1212 AC_SUBST([GBM_PC_LIB_PRIV])
1213
1214 dnl
1215 dnl EGL configuration
1216 dnl
1217 EGL_CLIENT_APIS=""
1218
1219 if test "x$enable_egl" = xyes; then
1220     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1221
1222     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1223
1224     if test "$enable_static" != yes; then
1225         if test "x$enable_dri" = xyes; then
1226             HAVE_EGL_DRIVER_DRI2=1
1227         fi
1228
1229     fi
1230 fi
1231 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1232 AC_SUBST([EGL_LIB_DEPS])
1233
1234 dnl
1235 dnl EGL Gallium configuration
1236 dnl
1237 if test "x$enable_gallium_egl" = xyes; then
1238     if test -z "$with_gallium_drivers"; then
1239         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1240     fi
1241     if test "x$enable_egl" = xno; then
1242         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1243     fi
1244     if test "x$have_libdrm" != xyes; then
1245         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1246     fi
1247
1248     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1249     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1250 fi
1251 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1252
1253 dnl
1254 dnl gbm Gallium configuration
1255 dnl
1256 if test "x$enable_gallium_gbm" = xauto; then
1257     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1258         yesyesyes*drm*)
1259             enable_gallium_gbm=yes ;;
1260          *)
1261             enable_gallium_gbm=no ;;
1262     esac
1263 fi
1264 if test "x$enable_gallium_gbm" = xyes; then
1265     if test -z "$with_gallium_drivers"; then
1266         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1267     fi
1268     if test "x$enable_gbm" = xno; then
1269         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1270     fi
1271     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1272     if test "x$enable_dri" = xno; then
1273         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1274     fi
1275
1276     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1277     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1278     enable_gallium_loader=yes
1279 fi
1280 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1281
1282 dnl
1283 dnl XA configuration
1284 dnl
1285 if test "x$enable_xa" = xyes; then
1286     if test "x$with_gallium_drivers" = xswrast; then
1287        AC_MSG_ERROR([
1288           Building xa requires at least one non swrast gallium driver.
1289           If you are looking to use libxatracker.so with vmware's virtual gpu,
1290           make sure to include svga in the gallium drivers list, apart from
1291           enabling XA.
1292           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1293     fi
1294     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1295     enable_gallium_loader=yes
1296 fi
1297 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1298
1299 dnl
1300 dnl OpenVG configuration
1301 dnl
1302 VG_LIB_DEPS=""
1303
1304 if test "x$enable_openvg" = xyes; then
1305     if test "x$enable_egl" = xno; then
1306         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1307     fi
1308     if test -z "$with_gallium_drivers"; then
1309         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1310     fi
1311     if test "x$enable_gallium_egl" = xno; then
1312         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1313     fi
1314
1315     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1316     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1317     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1318     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1319     AC_SUBST([VG_PC_LIB_PRIV])
1320 fi
1321 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1322
1323 dnl
1324 dnl Gallium G3DVL configuration
1325 dnl
1326 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1327     if test "x$enable_xvmc" = xauto; then
1328         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1329     fi
1330
1331     if test "x$enable_vdpau" = xauto; then
1332         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1333     fi
1334
1335     if test "x$enable_omx" = xauto; then
1336         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1337     fi
1338 fi
1339
1340 if test "x$enable_xvmc" = xyes; then
1341     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1342     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1343 fi
1344 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1345
1346 if test "x$enable_vdpau" = xyes; then
1347     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1348                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1349     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1350 fi
1351 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1352
1353 if test "x$enable_omx" = xyes; then
1354     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1355     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1356 fi
1357 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1358
1359 dnl
1360 dnl OpenCL configuration
1361 dnl
1362
1363 AC_ARG_WITH([libclc-path],
1364    [AS_HELP_STRING([--with-libclc-path],
1365          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1366    [LIBCLC_PATH="$withval"],
1367    [LIBCLC_PATH=''])
1368
1369 if test -n "$LIBCLC_PATH"; then
1370    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1371                   Please review the updated build instructions for clover:
1372                   http://dri.freedesktop.org/wiki/GalliumCompute])
1373 fi
1374
1375
1376 AC_ARG_WITH([clang-libdir],
1377    [AS_HELP_STRING([--with-clang-libdir],
1378          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1379    [CLANG_LIBDIR="$withval"],
1380    [CLANG_LIBDIR=''])
1381
1382 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1383
1384 if test "x$enable_opencl" = xyes; then
1385     if test -z "$with_gallium_drivers"; then
1386         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1387     fi
1388
1389     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1390         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1391     fi
1392
1393     if test "x$have_libclc" = xno; then
1394         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1395                     Make sure the directory containing libclc.pc is specified in your
1396                     PKG_CONFIG_PATH environment variable.
1397                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1398     else
1399         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1400         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1401         AC_SUBST([LIBCLC_INCLUDEDIR])
1402         AC_SUBST([LIBCLC_LIBEXECDIR])
1403     fi
1404
1405     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1406     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1407     enable_gallium_loader=yes
1408
1409     if test "x$enable_opencl_icd" = xyes; then
1410         OPENCL_LIBNAME="MesaOpenCL"
1411     else
1412         OPENCL_LIBNAME="OpenCL"
1413     fi
1414 fi
1415 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1416 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1417 AC_SUBST([OPENCL_LIBNAME])
1418
1419 dnl
1420 dnl Gallium configuration
1421 dnl
1422 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1423
1424 AC_SUBST([LLVM_BINDIR])
1425 AC_SUBST([LLVM_CFLAGS])
1426 AC_SUBST([LLVM_CPPFLAGS])
1427 AC_SUBST([LLVM_CXXFLAGS])
1428 AC_SUBST([LLVM_LIBDIR])
1429 AC_SUBST([LLVM_LIBS])
1430 AC_SUBST([LLVM_LDFLAGS])
1431 AC_SUBST([LLVM_INCLUDEDIR])
1432 AC_SUBST([LLVM_VERSION])
1433 AC_SUBST([CLANG_RESOURCE_DIR])
1434
1435 case "x$enable_opengl$enable_gles1$enable_gles2" in
1436 x*yes*)
1437     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1438     ;;
1439 esac
1440
1441 AC_SUBST([VG_LIB_DEPS])
1442 AC_SUBST([EGL_CLIENT_APIS])
1443
1444 dnl
1445 dnl EGL Platforms configuration
1446 dnl
1447 AC_ARG_WITH([egl-platforms],
1448     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1449         [comma delimited native platforms libEGL supports, e.g.
1450         "x11,drm" @<:@default=auto@:>@])],
1451     [with_egl_platforms="$withval"],
1452     [if test "x$enable_egl" = xyes; then
1453         with_egl_platforms="x11"
1454     else
1455         with_egl_platforms=""
1456     fi])
1457
1458 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1459     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1460 fi
1461
1462 # Do per-EGL platform setups and checks
1463 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1464 for plat in $egl_platforms; do
1465         case "$plat" in
1466         wayland)
1467                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1468                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1469
1470                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1471                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1472                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1473                 ;;
1474
1475         x11)
1476                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1477                 ;;
1478
1479         drm)
1480                 test "x$enable_gbm" = "xno" &&
1481                         AC_MSG_ERROR([EGL platform drm needs gbm])
1482                 test "x$have_libdrm" != xyes &&
1483                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1484                 ;;
1485
1486         android|fbdev|gdi|null)
1487                 ;;
1488
1489         *)
1490                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1491                 ;;
1492         esac
1493
1494         case "$plat$need_libudev$have_libudev" in
1495                 waylandyesno|drmyesno)
1496                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1497         esac
1498 done
1499
1500 # libEGL wants to default to the first platform specified in
1501 # ./configure.  parse that here.
1502 if test "x$egl_platforms" != "x"; then
1503     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1504     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1505 else
1506     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1507 fi
1508
1509 if echo "$egl_platforms" | grep -q 'x11'; then
1510     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1511     NEED_WINSYS_XLIB=yes
1512 fi
1513 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1514 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1515 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1516 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1517 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1518
1519 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1520
1521 AC_SUBST([EGL_NATIVE_PLATFORM])
1522 AC_SUBST([EGL_CFLAGS])
1523
1524 # If we don't have the X11 platform, set this define so we don't try to include
1525 # the X11 headers.
1526 if ! echo "$egl_platforms" | grep -q 'x11'; then
1527     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1528     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1529 fi
1530
1531 AC_ARG_WITH([egl-driver-dir],
1532     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1533                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1534     [EGL_DRIVER_INSTALL_DIR="$withval"],
1535     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1536 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1537
1538 AC_ARG_WITH([max-width],
1539     [AS_HELP_STRING([--with-max-width=N],
1540                     [Maximum framebuffer width (4096)])],
1541     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1542      AS_IF([test "${withval}" -gt "4096"],
1543            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1544 )
1545 AC_ARG_WITH([max-height],
1546     [AS_HELP_STRING([--with-max-height=N],
1547                     [Maximum framebuffer height (4096)])],
1548     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1549      AS_IF([test "${withval}" -gt "4096"],
1550            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1551 )
1552
1553 dnl
1554 dnl Gallium LLVM
1555 dnl
1556 AC_ARG_ENABLE([gallium-llvm],
1557     [AS_HELP_STRING([--enable-gallium-llvm],
1558         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1559     [enable_gallium_llvm="$enableval"],
1560     [enable_gallium_llvm=auto])
1561
1562 AC_ARG_ENABLE([llvm-shared-libs],
1563     [AS_HELP_STRING([--enable-llvm-shared-libs],
1564         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1565     [enable_llvm_shared_libs="$enableval"],
1566     [enable_llvm_shared_libs=yes])
1567
1568 AC_ARG_WITH([llvm-prefix],
1569     [AS_HELP_STRING([--with-llvm-prefix],
1570         [Prefix for LLVM installations in non-standard locations])],
1571     [llvm_prefix="$withval"],
1572     [llvm_prefix=''])
1573
1574
1575 # Call this inside ` ` to get the return value.
1576 # $1 is the llvm-config command with arguments.
1577 strip_unwanted_llvm_flags() {
1578     # Use \> (marks the end of the word)
1579     echo `$1` | sed \
1580         -e 's/-DNDEBUG\>//g' \
1581         -e 's/-pedantic\>//g' \
1582         -e 's/-Wcovered-switch-default\>//g' \
1583         -e 's/-O.\>//g' \
1584         -e 's/-g\>//g' \
1585         -e 's/-Wall\>//g' \
1586         -e 's/-Wcast-qual\>//g' \
1587         -e 's/-Woverloaded-virtual\>//g' \
1588         -e 's/-fcolor-diagnostics\>//g' \
1589         -e 's/-fdata-sections\>//g' \
1590         -e 's/-ffunction-sections\>//g' \
1591         -e 's/-fno-exceptions\>//g' \
1592         -e 's/-fomit-frame-pointer\>//g' \
1593         -e 's/-fvisibility-inlines-hidden\>//g' \
1594         -e 's/-fPIC\>//g'
1595 }
1596
1597
1598 if test -z "$with_gallium_drivers"; then
1599     enable_gallium_llvm=no
1600 fi
1601 if test "x$enable_gallium_llvm" = xauto; then
1602     case "$host_cpu" in
1603     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1604     esac
1605 fi
1606 if test "x$enable_gallium_llvm" = xyes; then
1607     if test -n "$llvm_prefix"; then
1608         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1609     else
1610         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1611     fi
1612
1613     if test "x$LLVM_CONFIG" != xno; then
1614         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1615         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1616         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1617         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1618         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1619         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1620         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1621         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1622
1623         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1624             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1625         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1626             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1627
1628         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1629         dnl llvm-config.h
1630         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1631             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1632             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1633
1634         if test -n "${LLVM_VERSION_MAJOR}"; then
1635             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1636         else
1637             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1638         fi
1639
1640         LLVM_REQUIRED_VERSION_MAJOR="3"
1641         LLVM_REQUIRED_VERSION_MINOR="1"
1642         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1643             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1644         fi
1645
1646         LLVM_COMPONENTS="engine bitwriter"
1647         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1648             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1649         fi
1650
1651         if test "x$enable_opencl" = xyes; then
1652             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1653             # LLVM 3.3 >= 177971 requires IRReader
1654             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1655                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1656             fi
1657             # LLVM 3.4 requires Option
1658             if $LLVM_CONFIG --components | grep -qw 'option'; then
1659                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1660             fi
1661         fi
1662         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1663         MESA_LLVM=1
1664
1665         dnl Check for Clang internal headers
1666         if test "x$enable_opencl" = xyes; then
1667             if test -z "$CLANG_LIBDIR"; then
1668                 CLANG_LIBDIR=${LLVM_LIBDIR}
1669             fi
1670             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1671             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1672                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1673         fi
1674     else
1675         MESA_LLVM=0
1676         LLVM_VERSION_INT=0
1677     fi
1678 else
1679     MESA_LLVM=0
1680     LLVM_VERSION_INT=0
1681 fi
1682
1683 dnl Directory for XVMC libs
1684 AC_ARG_WITH([xvmc-libdir],
1685     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1686         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1687     [XVMC_LIB_INSTALL_DIR="$withval"],
1688     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1689 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1690
1691 dnl
1692 dnl Gallium Tests
1693 dnl
1694 if test "x$enable_gallium_tests" = xyes; then
1695     enable_gallium_loader=yes
1696 fi
1697 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1698
1699 if test "x$enable_gallium_loader" = xyes; then
1700     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1701 fi
1702 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1703
1704 dnl Directory for VDPAU libs
1705 AC_ARG_WITH([vdpau-libdir],
1706     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1707         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1708     [VDPAU_LIB_INSTALL_DIR="$withval"],
1709     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1710 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1711
1712 OMX_LIB_INSTALL_DIR_DEFAULT=''
1713 if test "x$enable_omx" = xyes; then
1714     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1715 fi
1716
1717 AC_ARG_WITH([omx-libdir],
1718     [AS_HELP_STRING([--with-omx-libdir=DIR],
1719         [directory for the OMX libraries])],
1720     [OMX_LIB_INSTALL_DIR="$withval"],
1721     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1722 AC_SUBST([OMX_LIB_INSTALL_DIR])
1723
1724 dnl Directory for OpenCL libs
1725 AC_ARG_WITH([opencl-libdir],
1726     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1727         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1728     [OPENCL_LIB_INSTALL_DIR="$withval"],
1729     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1730 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1731
1732 dnl
1733 dnl Gallium helper functions
1734 dnl
1735 gallium_check_st() {
1736     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1737          if test "x$have_libdrm" != xyes; then
1738             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1739          fi
1740          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1741     fi
1742     if test "x$enable_dri" = xyes && test -n "$2"; then
1743          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1744     fi
1745     if test "x$enable_xa" = xyes && test -n "$3"; then
1746          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1747     fi
1748     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1749          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1750     fi
1751     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1752          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1753     fi
1754     if test "x$enable_omx" = xyes && test "x$6" != x; then
1755          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1756     fi
1757 }
1758
1759 gallium_require_llvm() {
1760     if test "x$MESA_LLVM" = x0; then
1761         case "$host_cpu" in
1762         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1763         esac
1764     fi
1765 }
1766
1767 gallium_require_drm_loader() {
1768     if test "x$enable_gallium_loader" = xyes; then
1769         if test "x$need_libudev$have_libudev" = xyesno; then
1770             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1771         fi
1772         if test "x$have_libdrm" != xyes; then
1773             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1774         fi
1775         enable_gallium_drm_loader=yes
1776     fi
1777 }
1778
1779 require_egl_drm() {
1780     case "$with_egl_platforms" in
1781         *drm*)
1782             ;;
1783          *)
1784             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1785             ;;
1786     esac
1787     if test "x$enable_gbm" != xyes; then
1788             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1789     fi
1790 }
1791
1792 radeon_llvm_check() {
1793     if test "x$enable_gallium_llvm" != "xyes"; then
1794         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1795     fi
1796     LLVM_REQUIRED_VERSION_MAJOR="3"
1797     LLVM_REQUIRED_VERSION_MINOR="3"
1798     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1799         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1800     fi
1801     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1802         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1803                       sources with the --enable-experimental-targets=R600
1804                       configure flag])
1805     fi
1806     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1807     NEED_RADEON_LLVM=yes
1808     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1809                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1810 }
1811
1812 dnl Gallium drivers
1813 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1814         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1815     NEED_NONNULL_WINSYS=yes
1816 fi
1817 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1818
1819 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1820 if test -n "$with_gallium_drivers"; then
1821     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1822     for driver in $gallium_drivers; do
1823         case "x$driver" in
1824         xsvga)
1825             HAVE_GALLIUM_SVGA=yes
1826             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1827             gallium_require_drm_loader
1828             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1829             ;;
1830         xi915)
1831             HAVE_GALLIUM_I915=yes
1832             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1833             gallium_require_drm_loader
1834             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1835             if test "x$MESA_LLVM" = x1; then
1836                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1837             fi
1838             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1839             gallium_check_st "i915/drm" "dri-i915"
1840             DRICOMMON_NEED_LIBDRM=yes
1841             ;;
1842         xilo)
1843             HAVE_GALLIUM_ILO=yes
1844             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1845             gallium_require_drm_loader
1846             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1847             gallium_check_st "intel/drm" "dri-ilo"
1848             DRICOMMON_NEED_LIBDRM=yes
1849             ;;
1850         xr300)
1851             HAVE_GALLIUM_R300=yes
1852             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1853             gallium_require_drm_loader
1854             gallium_require_llvm "Gallium R300"
1855             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1856             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1857             DRICOMMON_NEED_LIBDRM=yes
1858             ;;
1859         xr600)
1860             HAVE_GALLIUM_R600=yes
1861             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1862             gallium_require_drm_loader
1863             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1864             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1865                 radeon_llvm_check "r600g"
1866                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1867             fi
1868             if test "x$enable_r600_llvm" = xyes; then
1869                 USE_R600_LLVM_COMPILER=yes;
1870             fi
1871             if test "x$enable_opencl" = xyes; then
1872                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1873             fi
1874             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1875             DRICOMMON_NEED_LIBDRM=yes
1876             ;;
1877         xradeonsi)
1878             HAVE_GALLIUM_RADEONSI=yes
1879             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1880             gallium_require_drm_loader
1881             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1882             radeon_llvm_check "radeonsi"
1883             require_egl_drm "radeonsi"
1884             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1885             DRICOMMON_NEED_LIBDRM=yes
1886             ;;
1887         xnouveau)
1888             HAVE_GALLIUM_NOUVEAU=yes
1889             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1890             gallium_require_drm_loader
1891             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1892             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1893             DRICOMMON_NEED_LIBDRM=yes
1894             ;;
1895         xfreedreno)
1896             HAVE_GALLIUM_FREEDRENO=yes
1897             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1898             gallium_require_drm_loader
1899             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1900             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1901             DRICOMMON_NEED_LIBDRM=yes
1902             ;;
1903         xswrast)
1904             HAVE_GALLIUM_SOFTPIPE=yes
1905             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1906             if test "x$MESA_LLVM" = x1; then
1907                 HAVE_GALLIUM_LLVMPIPE=yes
1908                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1909             fi
1910
1911             if test "x$enable_dri" = xyes; then
1912                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1913             fi
1914             ;;
1915         *)
1916             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1917             ;;
1918         esac
1919     done
1920 fi
1921
1922 dnl Set LLVM_LIBS - This is done after the driver configuration so
1923 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1924 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1925 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1926 dnl this was causing the same libraries to be appear multiple times
1927 dnl in LLVM_LIBS.
1928
1929 if test "x$MESA_LLVM" != x0; then
1930
1931     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1932
1933     if test "x$enable_llvm_shared_libs" = xyes; then
1934         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1935         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1936         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1937
1938         if test "x$llvm_have_one_so" = xyes; then
1939             dnl LLVM was built using auto*, so there is only one shared object.
1940             LLVM_LIBS="-l$LLVM_SO_NAME"
1941         else
1942             dnl If LLVM was built with CMake, there will be one shared object per
1943             dnl component.
1944             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1945                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1946         Please make sure you have built llvm with the --enable-shared option
1947         and that your llvm libraries are installed in $LLVM_LIBDIR
1948         If you have installed your llvm libraries to a different directory you
1949         can use the --with-llvm-prefix= configure flag to specify this directory.
1950         NOTE: Mesa is attempting to use llvm shared libraries by default.
1951         If you do not want to build with llvm shared libraries and instead want to
1952         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1953         invocation and rebuild.])])
1954
1955            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1956            dnl install uses a shared object for each compoenent and we have
1957            dnl already added all of these objects to LLVM_LIBS.
1958         fi
1959     else
1960         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
1961     fi
1962 fi
1963
1964 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1965 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1966 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1967 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1968 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1969 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1970 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
1971                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
1972 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1973 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1974 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1975 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1976
1977 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1978                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1979                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1980 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1981                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1982                                                   && test "x$MESA_LLVM" = x1)
1983
1984 # NOTE: anything using xcb or other client side libs ends up in separate
1985 #       _CLIENT variables.  The pipe loader is built in two variants,
1986 #       one that is standalone and does not link any x client libs (for
1987 #       use by XA tracker in particular, but could be used in any case
1988 #       where communication with xserver is not desired).
1989 if test "x$enable_gallium_loader" = xyes; then
1990     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1991
1992     if test "x$NEED_WINSYS_XLIB" = xyes; then
1993         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1994     fi
1995
1996     if test "x$enable_dri" = xyes; then
1997         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
1998     fi
1999
2000     if test "x$enable_gallium_drm_loader" = xyes; then
2001         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2002         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2003                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2004         if test "x$pipe_loader_have_xcb" = xyes; then
2005             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2006             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2007         fi
2008     fi
2009
2010     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2011     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2012
2013     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2014     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2015     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2016     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2017 fi
2018
2019 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2020 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2021 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2022 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2023 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2024 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2025
2026 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2027                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2028                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2029                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2030 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2031                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2032 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2033 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2034 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2035 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2036 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2037 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2038 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2039
2040 AC_SUBST([ELF_LIB])
2041
2042 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2043 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2044 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2045 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2046 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2047
2048 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2049 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2050 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2051
2052 AC_SUBST([VDPAU_MAJOR], 1)
2053 AC_SUBST([VDPAU_MINOR], 0)
2054
2055 AC_SUBST([XVMC_MAJOR], 1)
2056 AC_SUBST([XVMC_MINOR], 0)
2057
2058 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2059 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2060 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2061 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2062
2063 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2064 AC_SUBST([XA_MINOR], $XA_MINOR)
2065 AC_SUBST([XA_TINY], $XA_TINY)
2066 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2067
2068 dnl Restore LDFLAGS and CPPFLAGS
2069 LDFLAGS="$_SAVE_LDFLAGS"
2070 CPPFLAGS="$_SAVE_CPPFLAGS"
2071
2072 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2073 if test "x$acv_mesa_CLANG" = xyes; then
2074     CFLAGS="$CFLAGS -Qunused-arguments"
2075     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2076 fi
2077
2078 dnl Add user CFLAGS and CXXFLAGS
2079 CFLAGS="$CFLAGS $USER_CFLAGS"
2080 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2081
2082 dnl Substitute the config
2083 AC_CONFIG_FILES([Makefile
2084                 src/Makefile
2085                 src/egl/drivers/dri2/Makefile
2086                 src/egl/main/Makefile
2087                 src/egl/main/egl.pc
2088                 src/egl/wayland/Makefile
2089                 src/egl/wayland/wayland-drm/Makefile
2090                 src/egl/wayland/wayland-egl/Makefile
2091                 src/egl/wayland/wayland-egl/wayland-egl.pc
2092                 src/gallium/auxiliary/Makefile
2093                 src/gallium/auxiliary/pipe-loader/Makefile
2094                 src/gallium/drivers/Makefile
2095                 src/gallium/drivers/freedreno/Makefile
2096                 src/gallium/drivers/galahad/Makefile
2097                 src/gallium/drivers/i915/Makefile
2098                 src/gallium/drivers/identity/Makefile
2099                 src/gallium/drivers/ilo/Makefile
2100                 src/gallium/drivers/llvmpipe/Makefile
2101                 src/gallium/drivers/noop/Makefile
2102                 src/gallium/drivers/nouveau/Makefile
2103                 src/gallium/drivers/r300/Makefile
2104                 src/gallium/drivers/r600/Makefile
2105                 src/gallium/drivers/radeon/Makefile
2106                 src/gallium/drivers/radeonsi/Makefile
2107                 src/gallium/drivers/rbug/Makefile
2108                 src/gallium/drivers/softpipe/Makefile
2109                 src/gallium/drivers/svga/Makefile
2110                 src/gallium/drivers/trace/Makefile
2111                 src/gallium/state_trackers/Makefile
2112                 src/gallium/state_trackers/clover/Makefile
2113                 src/gallium/state_trackers/dri/Makefile
2114                 src/gallium/state_trackers/dri/drm/Makefile
2115                 src/gallium/state_trackers/dri/sw/Makefile
2116                 src/gallium/state_trackers/egl/Makefile
2117                 src/gallium/state_trackers/gbm/Makefile
2118                 src/gallium/state_trackers/glx/xlib/Makefile
2119                 src/gallium/state_trackers/omx/Makefile
2120                 src/gallium/state_trackers/osmesa/Makefile
2121                 src/gallium/state_trackers/vdpau/Makefile
2122                 src/gallium/state_trackers/vega/Makefile
2123                 src/gallium/state_trackers/xa/Makefile
2124                 src/gallium/state_trackers/xvmc/Makefile
2125                 src/gallium/targets/Makefile
2126                 src/gallium/targets/dri-freedreno/Makefile
2127                 src/gallium/targets/dri-i915/Makefile
2128                 src/gallium/targets/dri-ilo/Makefile
2129                 src/gallium/targets/dri-nouveau/Makefile
2130                 src/gallium/targets/dri-swrast/Makefile
2131                 src/gallium/targets/dri-vmwgfx/Makefile
2132                 src/gallium/targets/egl-static/Makefile
2133                 src/gallium/targets/gbm/Makefile
2134                 src/gallium/targets/opencl/Makefile
2135                 src/gallium/targets/xa/Makefile
2136                 src/gallium/targets/xa/xatracker.pc
2137                 src/gallium/targets/omx-nouveau/Makefile
2138                 src/gallium/targets/osmesa/Makefile
2139                 src/gallium/targets/osmesa/osmesa.pc
2140                 src/gallium/targets/pipe-loader/Makefile
2141                 src/gallium/targets/radeonsi/dri/Makefile
2142                 src/gallium/targets/radeonsi/omx/Makefile
2143                 src/gallium/targets/radeonsi/vdpau/Makefile
2144                 src/gallium/targets/r300/dri/Makefile
2145                 src/gallium/targets/r600/dri/Makefile
2146                 src/gallium/targets/r600/omx/Makefile
2147                 src/gallium/targets/r600/vdpau/Makefile
2148                 src/gallium/targets/r600/xvmc/Makefile
2149                 src/gallium/targets/libgl-xlib/Makefile
2150                 src/gallium/targets/vdpau-nouveau/Makefile
2151                 src/gallium/targets/xvmc-nouveau/Makefile
2152                 src/gallium/tests/trivial/Makefile
2153                 src/gallium/tests/unit/Makefile
2154                 src/gallium/winsys/Makefile
2155                 src/gallium/winsys/freedreno/drm/Makefile
2156                 src/gallium/winsys/i915/drm/Makefile
2157                 src/gallium/winsys/i915/sw/Makefile
2158                 src/gallium/winsys/intel/drm/Makefile
2159                 src/gallium/winsys/nouveau/drm/Makefile
2160                 src/gallium/winsys/radeon/drm/Makefile
2161                 src/gallium/winsys/svga/drm/Makefile
2162                 src/gallium/winsys/sw/dri/Makefile
2163                 src/gallium/winsys/sw/fbdev/Makefile
2164                 src/gallium/winsys/sw/null/Makefile
2165                 src/gallium/winsys/sw/wayland/Makefile
2166                 src/gallium/winsys/sw/wrapper/Makefile
2167                 src/gallium/winsys/sw/xlib/Makefile
2168                 src/gbm/Makefile
2169                 src/gbm/main/gbm.pc
2170                 src/glsl/Makefile
2171                 src/glx/Makefile
2172                 src/glx/tests/Makefile
2173                 src/gtest/Makefile
2174                 src/loader/Makefile
2175                 src/mapi/Makefile
2176                 src/mapi/es1api/Makefile
2177                 src/mapi/es1api/glesv1_cm.pc
2178                 src/mapi/es2api/Makefile
2179                 src/mapi/es2api/glesv2.pc
2180                 src/mapi/glapi/Makefile
2181                 src/mapi/glapi/gen/Makefile
2182                 src/mapi/glapi/tests/Makefile
2183                 src/mapi/shared-glapi/Makefile
2184                 src/mapi/shared-glapi/tests/Makefile
2185                 src/mapi/vgapi/Makefile
2186                 src/mapi/vgapi/vg.pc
2187                 src/mesa/Makefile
2188                 src/mesa/gl.pc
2189                 src/mesa/drivers/dri/dri.pc
2190                 src/mesa/drivers/dri/common/Makefile
2191                 src/mesa/drivers/dri/common/xmlpool/Makefile
2192                 src/mesa/drivers/dri/i915/Makefile
2193                 src/mesa/drivers/dri/i965/Makefile
2194                 src/mesa/drivers/dri/Makefile
2195                 src/mesa/drivers/dri/nouveau/Makefile
2196                 src/mesa/drivers/dri/r200/Makefile
2197                 src/mesa/drivers/dri/radeon/Makefile
2198                 src/mesa/drivers/dri/swrast/Makefile
2199                 src/mesa/drivers/osmesa/Makefile
2200                 src/mesa/drivers/osmesa/osmesa.pc
2201                 src/mesa/drivers/x11/Makefile
2202                 src/mesa/main/tests/Makefile
2203                 src/mesa/main/tests/hash_table/Makefile])
2204
2205 dnl Sort the dirs alphabetically
2206 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2207 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2208 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2209 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2210
2211 AC_OUTPUT
2212
2213 dnl
2214 dnl Output some configuration info for the user
2215 dnl
2216 echo ""
2217 echo "        prefix:          $prefix"
2218 echo "        exec_prefix:     $exec_prefix"
2219 echo "        libdir:          $libdir"
2220 echo "        includedir:      $includedir"
2221
2222 dnl API info
2223 echo ""
2224 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2225 echo "        OpenVG:          $enable_openvg"
2226
2227 dnl Driver info
2228 echo ""
2229 case "x$enable_osmesa$enable_gallium_osmesa" in
2230 xnoyes)
2231         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2232         ;;
2233 xyesno)
2234         echo "        OSMesa:          lib$OSMESA_LIB"
2235         ;;
2236 xnono)
2237         echo "        OSMesa:          no"
2238         ;;
2239 esac
2240
2241 if test "x$enable_dri" != xno; then
2242         if test -z "$DRI_DIRS"; then
2243             echo "        DRI drivers:     no"
2244         else
2245             echo "        DRI drivers:     $DRI_DIRS"
2246         fi
2247         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2248 fi
2249
2250 case "x$enable_glx$enable_xlib_glx" in
2251 xyesyes)
2252     echo "        GLX:             Xlib-based"
2253     ;;
2254 xyesno)
2255     echo "        GLX:             DRI-based"
2256     ;;
2257 *)
2258     echo "        GLX:             $enable_glx"
2259     ;;
2260 esac
2261
2262 dnl EGL
2263 echo ""
2264 echo "        EGL:             $enable_egl"
2265 if test "$enable_egl" = yes; then
2266     echo "        EGL platforms:   $egl_platforms"
2267
2268     egl_drivers=""
2269     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2270         egl_drivers="$egl_drivers builtin:egl_dri2"
2271     fi
2272
2273     if test "x$enable_gallium_egl" = xyes; then
2274         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2275         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2276     else
2277         echo "        EGL drivers:    $egl_drivers"
2278     fi
2279 fi
2280
2281 echo ""
2282 if test "x$MESA_LLVM" = x1; then
2283     echo "        llvm:            yes"
2284     echo "        llvm-config:     $LLVM_CONFIG"
2285     echo "        llvm-version:    $LLVM_VERSION"
2286 else
2287     echo "        llvm:            no"
2288 fi
2289
2290 echo ""
2291 if test -n "$with_gallium_drivers"; then
2292     echo "        Gallium:         yes"
2293     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2294     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2295     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2296     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2297 else
2298     echo "        Gallium:         no"
2299 fi
2300
2301
2302 dnl Libraries
2303 echo ""
2304 echo "        Shared libs:     $enable_shared"
2305 echo "        Static libs:     $enable_static"
2306 echo "        Shared-glapi:    $enable_shared_glapi"
2307
2308 dnl Compiler options
2309 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2310 cflags=`echo $CFLAGS | \
2311     $SED 's/^ *//;s/  */ /;s/ *$//'`
2312 cxxflags=`echo $CXXFLAGS | \
2313     $SED 's/^ *//;s/  */ /;s/ *$//'`
2314 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2315 echo ""
2316 echo "        CFLAGS:          $cflags"
2317 echo "        CXXFLAGS:        $cxxflags"
2318 echo "        Macros:          $defines"
2319 echo ""
2320 if test "x$MESA_LLVM" = x1; then
2321     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2322     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2323     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2324     echo ""
2325 fi
2326 echo "        PYTHON2:         $PYTHON2"
2327
2328 echo ""
2329 echo "        Run '${MAKE-make}' to build Mesa"
2330 echo ""