configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.38
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.60
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126
 127 if test -z "$PYTHON2"; then
 128     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 129         AC_MSG_ERROR([Python not found - unable to generate sources])
 130     fi
 131 else
 132     if test "x$acv_mako_found" = xno; then
 133         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 134             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 135         fi
 136     fi
 137 fi
 138
 139 AC_PROG_INSTALL
 140
 141 dnl We need a POSIX shell for parts of the build. Assume we have one
 142 dnl in most cases.
 143 case "$host_os" in
 144 solaris*)
 145     # Solaris /bin/sh is too old/non-POSIX compliant
 146     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 147     SHELL="$POSIX_SHELL"
 148     ;;
 149 esac
 150
 151 dnl clang is mostly GCC-compatible, but its version is much lower,
 152 dnl so we have to check for it.
 153 AC_MSG_CHECKING([if compiling with clang])
 154
 155 AC_COMPILE_IFELSE(
 156 [AC_LANG_PROGRAM([], [[
 157 #ifndef __clang__
 158        not clang
 159 #endif
 160 ]])],
 161 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 162
 163 AC_MSG_RESULT([$acv_mesa_CLANG])
 164
 165 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 166 dnl versions are explictly not supported.
 167 GEN_ASM_OFFSETS=no
 168 USE_GNU99=no
 169 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 170     AC_MSG_CHECKING([whether gcc version is sufficient])
 171     major=0
 172     minor=0
 173
 174     GCC_VERSION=`$CC -dumpversion`
 175     if test $? -eq 0; then
 176         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 177         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 178     fi
 179
 180     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 181         AC_MSG_RESULT([no])
 182         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 183     else
 184         AC_MSG_RESULT([yes])
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 188         USE_GNU99=yes
 189     fi
 190     if test "x$cross_compiling" = xyes; then
 191         GEN_ASM_OFFSETS=yes
 192     fi
 193 fi
 194
 195 dnl Check for compiler builtins
 196 AX_GCC_BUILTIN([__builtin_bswap32])
 197 AX_GCC_BUILTIN([__builtin_bswap64])
 198 AX_GCC_BUILTIN([__builtin_clz])
 199 AX_GCC_BUILTIN([__builtin_clzll])
 200 AX_GCC_BUILTIN([__builtin_ctz])
 201 AX_GCC_BUILTIN([__builtin_expect])
 202 AX_GCC_BUILTIN([__builtin_ffs])
 203 AX_GCC_BUILTIN([__builtin_ffsll])
 204 AX_GCC_BUILTIN([__builtin_popcount])
 205 AX_GCC_BUILTIN([__builtin_popcountll])
 206 AX_GCC_BUILTIN([__builtin_unreachable])
 207
 208 AX_GCC_FUNC_ATTRIBUTE([flatten])
 209 AX_GCC_FUNC_ATTRIBUTE([format])
 210 AX_GCC_FUNC_ATTRIBUTE([malloc])
 211 AX_GCC_FUNC_ATTRIBUTE([packed])
 212 AX_GCC_FUNC_ATTRIBUTE([unused])
 213
 214 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 215
 216 dnl Make sure the pkg-config macros are defined
 217 m4_ifndef([PKG_PROG_PKG_CONFIG],
 218     [m4_fatal([Could not locate the pkg-config autoconf macros.
 219   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 220   are in a different location, try setting the environment variable
 221   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 222 PKG_PROG_PKG_CONFIG()
 223
 224 dnl LIB_DIR - library basename
 225 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 226 AC_SUBST([LIB_DIR])
 227
 228 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 229 _SAVE_LDFLAGS="$LDFLAGS"
 230 _SAVE_CPPFLAGS="$CPPFLAGS"
 231
 232 dnl Compiler macros
 233 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 234 AC_SUBST([DEFINES])
 235 case "$host_os" in
 236 linux*|*-gnu*|gnu*)
 237     DEFINES="$DEFINES -D_GNU_SOURCE"
 238     ;;
 239 solaris*)
 240     DEFINES="$DEFINES -DSVR4"
 241     ;;
 242 cygwin*)
 243     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 244     ;;
 245 esac
 246
 247 dnl Add flags for gcc and g++
 248 if test "x$GCC" = xyes; then
 249     CFLAGS="$CFLAGS -Wall"
 250
 251     if test "x$USE_GNU99" = xyes; then
 252         CFLAGS="$CFLAGS -std=gnu99"
 253     else
 254         CFLAGS="$CFLAGS -std=c99"
 255     fi
 256
 257     # Enable -Werror=implicit-function-declaration and
 258     # -Werror=missing-prototypes, if available, or otherwise, just
 259     # -Wmissing-prototypes.  This is particularly useful to avoid
 260     # generating a loadable driver module that has undefined symbols.
 261     save_CFLAGS="$CFLAGS"
 262     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 263     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 264     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 265     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 266                    AC_MSG_RESULT([yes]),
 267                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 268                     AC_MSG_RESULT([no])]);
 269
 270     # Enable -fvisibility=hidden if using a gcc that supports it
 271     save_CFLAGS="$CFLAGS"
 272     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 273     VISIBILITY_CFLAGS="-fvisibility=hidden"
 274     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 275     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 276                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 277
 278     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 279     CFLAGS=$save_CFLAGS
 280
 281     # Work around aliasing bugs - developers should comment this out
 282     CFLAGS="$CFLAGS -fno-strict-aliasing"
 283
 284     # gcc's builtin memcmp is slower than glibc's
 285     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 286     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 287
 288     # Flags to help ensure that certain portions of the code -- and only those
 289     # portions -- can be built with MSVC:
 290     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 291     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 292     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 293     #   supports most of C99)
 294     # - the rest has no compiler compiler restrictions
 295     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 296     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 297
 298     # Enable -Werror=vla if compiler supports it
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 301     CFLAGS="$CFLAGS -Werror=vla"
 302     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 303                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 304                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 305                     AC_MSG_RESULT([yes])],
 306                     AC_MSG_RESULT([no]));
 307     CFLAGS="$save_CFLAGS"
 308
 309     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 310     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 311 fi
 312 if test "x$GXX" = xyes; then
 313     CXXFLAGS="$CXXFLAGS -Wall"
 314
 315     # Enable -fvisibility=hidden if using a gcc that supports it
 316     save_CXXFLAGS="$CXXFLAGS"
 317     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 318     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 319     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 320     AC_LANG_PUSH([C++])
 321     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 322                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 323     AC_LANG_POP([C++])
 324
 325     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 326     CXXFLAGS=$save_CXXFLAGS
 327
 328     # Work around aliasing bugs - developers should comment this out
 329     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 330
 331     # gcc's builtin memcmp is slower than glibc's
 332     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 333     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 334 fi
 335
 336 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 337 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 338 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 339 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 340
 341 dnl even if the compiler appears to support it, using visibility attributes isn't
 342 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 343 case "$host_os" in
 344 cygwin*)
 345     VISIBILITY_CFLAGS=""
 346     VISIBILITY_CXXFLAGS=""
 347     ;;
 348 esac
 349
 350 AC_SUBST([VISIBILITY_CFLAGS])
 351 AC_SUBST([VISIBILITY_CXXFLAGS])
 352
 353 dnl
 354 dnl Optional flags, check for compiler support
 355 dnl
 356 SSE41_CFLAGS="-msse4.1"
 357 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 358 dnl stack, but on x86-32 such alignment is not guaranteed.
 359 case "$target_cpu" in
 360 i?86)
 361     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 362     ;;
 363 esac
 364 save_CFLAGS="$CFLAGS"
 365 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 366 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 367 #include <smmintrin.h>
 368 int main () {
 369     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 370     c = _mm_max_epu32(a, b);
 371     return 0;
 372 }]])], SSE41_SUPPORTED=1)
 373 CFLAGS="$save_CFLAGS"
 374 if test "x$SSE41_SUPPORTED" = x1; then
 375     DEFINES="$DEFINES -DUSE_SSE41"
 376 fi
 377 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 378 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 379
 380 dnl Can't have static and shared libraries, default to static if user
 381 dnl explicitly requested. If both disabled, set to static since shared
 382 dnl was explicitly requested.
 383 case "x$enable_static$enable_shared" in
 384 xyesyes)
 385     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 386     enable_shared=no
 387     ;;
 388 xnono)
 389     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 390     enable_shared=yes
 391     ;;
 392 esac
 393
 394 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 395
 396 dnl
 397 dnl other compiler options
 398 dnl
 399 AC_ARG_ENABLE([debug],
 400     [AS_HELP_STRING([--enable-debug],
 401         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 402     [enable_debug="$enableval"],
 403     [enable_debug=no]
 404 )
 405 if test "x$enable_debug" = xyes; then
 406     DEFINES="$DEFINES -DDEBUG"
 407     if test "x$GCC" = xyes; then
 408         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 409             CFLAGS="$CFLAGS -g"
 410         fi
 411         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 412             CFLAGS="$CFLAGS -O0"
 413         fi
 414     fi
 415     if test "x$GXX" = xyes; then
 416         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 417             CXXFLAGS="$CXXFLAGS -g"
 418         fi
 419         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 420             CXXFLAGS="$CXXFLAGS -O0"
 421         fi
 422     fi
 423 else
 424    DEFINES="$DEFINES -DNDEBUG"
 425 fi
 426
 427 dnl
 428 dnl Check if linker supports -Bsymbolic
 429 dnl
 430 save_LDFLAGS=$LDFLAGS
 431 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 432 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 433 AC_LINK_IFELSE(
 434     [AC_LANG_SOURCE([int main() { return 0;}])],
 435     [AC_MSG_RESULT([yes])
 436         BSYMBOLIC="-Wl,-Bsymbolic";],
 437     [AC_MSG_RESULT([no])
 438         BSYMBOLIC="";])
 439 LDFLAGS=$save_LDFLAGS
 440
 441 AC_SUBST([BSYMBOLIC])
 442
 443 dnl
 444 dnl Check if linker supports garbage collection
 445 dnl
 446 save_LDFLAGS=$LDFLAGS
 447 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 448 AC_MSG_CHECKING([whether ld supports --gc-sections])
 449 AC_LINK_IFELSE(
 450     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 451     [AC_MSG_RESULT([yes])
 452         GC_SECTIONS="-Wl,--gc-sections";],
 453     [AC_MSG_RESULT([no])
 454         GC_SECTIONS="";])
 455 LDFLAGS=$save_LDFLAGS
 456
 457 AC_SUBST([GC_SECTIONS])
 458
 459 dnl
 460 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 461 dnl so when these flags are passed to ld via libtool the checks will fail
 462 dnl
 463 case "$host_os" in
 464 openbsd* | darwin* )
 465     LD_NO_UNDEFINED="" ;;
 466 *)
 467     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 468 esac
 469
 470 AC_SUBST([LD_NO_UNDEFINED])
 471
 472 dnl
 473 dnl Check if linker supports version scripts
 474 dnl
 475 AC_MSG_CHECKING([if the linker supports version-scripts])
 476 save_LDFLAGS=$LDFLAGS
 477 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 478 cat > conftest.map <<EOF
 479 VERSION_1 {
 480      global:
 481          main;
 482
 483      local:
 484          *;
 485 };
 486 EOF
 487 AC_LINK_IFELSE(
 488     [AC_LANG_SOURCE([int main() { return 0;}])],
 489     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 490     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 491 LDFLAGS=$save_LDFLAGS
 492 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 493
 494 dnl
 495 dnl Check if linker supports dynamic list files
 496 dnl
 497 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 498 save_LDFLAGS=$LDFLAGS
 499 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 500 cat > conftest.dyn <<EOF
 501 {
 502         radeon_drm_winsys_create;
 503 };
 504 EOF
 505 AC_LINK_IFELSE(
 506     [AC_LANG_SOURCE([int main() { return 0;}])],
 507     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 508     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 509 LDFLAGS=$save_LDFLAGS
 510 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 511
 512 dnl
 513 dnl compatibility symlinks
 514 dnl
 515 case "$host_os" in
 516 linux* )
 517     HAVE_COMPAT_SYMLINKS=yes ;;
 518 * )
 519     HAVE_COMPAT_SYMLINKS=no ;;
 520 esac
 521
 522 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 523
 524 dnl
 525 dnl library names
 526 dnl
 527 case "$host_os" in
 528 darwin* )
 529     LIB_EXT='dylib' ;;
 530 cygwin* )
 531     LIB_EXT='dll' ;;
 532 aix* )
 533     LIB_EXT='a' ;;
 534 * )
 535     LIB_EXT='so' ;;
 536 esac
 537
 538 AC_SUBST([LIB_EXT])
 539
 540 AC_ARG_WITH([gl-lib-name],
 541   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 542     [specify GL library name @<:@default=GL@:>@])],
 543   [GL_LIB=$withval],
 544   [GL_LIB=GL])
 545 AC_ARG_WITH([osmesa-lib-name],
 546   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 547     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 548   [OSMESA_LIB=$withval],
 549   [OSMESA_LIB=OSMesa])
 550 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 551 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 552
 553 dnl
 554 dnl Mangled Mesa support
 555 dnl
 556 AC_ARG_ENABLE([mangling],
 557   [AS_HELP_STRING([--enable-mangling],
 558     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 559   [enable_mangling="${enableval}"],
 560   [enable_mangling=no]
 561 )
 562 if test "x${enable_mangling}" = "xyes" ; then
 563   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 564   GL_LIB="Mangled${GL_LIB}"
 565   OSMESA_LIB="Mangled${OSMESA_LIB}"
 566 fi
 567 AC_SUBST([GL_LIB])
 568 AC_SUBST([OSMESA_LIB])
 569
 570 dnl
 571 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 572 dnl
 573 AC_ARG_ENABLE([texture-float],
 574     [AS_HELP_STRING([--enable-texture-float],
 575         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 576     [enable_texture_float="$enableval"],
 577     [enable_texture_float=no]
 578 )
 579 if test "x$enable_texture_float" = xyes; then
 580     AC_MSG_WARN([Floating-point textures enabled.])
 581     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 582     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 583 fi
 584
 585 dnl
 586 dnl Arch/platform-specific settings
 587 dnl
 588 AC_ARG_ENABLE([asm],
 589     [AS_HELP_STRING([--disable-asm],
 590         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 591     [enable_asm="$enableval"],
 592     [enable_asm=yes]
 593 )
 594 asm_arch=""
 595 AC_MSG_CHECKING([whether to enable assembly])
 596 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 597 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 598 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 599     case "$host_cpu" in
 600     i?86 | x86_64 | amd64)
 601         enable_asm=no
 602         AC_MSG_RESULT([no, cross compiling])
 603         ;;
 604     esac
 605 fi
 606 # check for supported arches
 607 if test "x$enable_asm" = xyes; then
 608     case "$host_cpu" in
 609     i?86)
 610         case "$host_os" in
 611         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 612             asm_arch=x86
 613             ;;
 614         esac
 615         ;;
 616     x86_64|amd64)
 617         case "$host_os" in
 618         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 619             asm_arch=x86_64
 620             ;;
 621         esac
 622         ;;
 623     sparc*)
 624         case "$host_os" in
 625         linux*)
 626             asm_arch=sparc
 627             ;;
 628         esac
 629         ;;
 630     esac
 631
 632     case "$asm_arch" in
 633     x86)
 634         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 635         AC_MSG_RESULT([yes, x86])
 636         ;;
 637     x86_64|amd64)
 638         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 639         AC_MSG_RESULT([yes, x86_64])
 640         ;;
 641     sparc)
 642         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 643         AC_MSG_RESULT([yes, sparc])
 644         ;;
 645     *)
 646         AC_MSG_RESULT([no, platform not supported])
 647         ;;
 648     esac
 649 fi
 650
 651 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 652 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 653
 654 dnl Check to see if dlopen is in default libraries (like Solaris, which
 655 dnl has it in libc), or if libdl is needed to get it.
 656 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 657     [AC_CHECK_LIB([dl], [dlopen],
 658        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 659 AC_SUBST([DLOPEN_LIBS])
 660
 661 dnl Check if that library also has dladdr
 662 save_LIBS="$LIBS"
 663 LIBS="$LIBS $DLOPEN_LIBS"
 664 AC_CHECK_FUNCS([dladdr])
 665 LIBS="$save_LIBS"
 666
 667 case "$host_os" in
 668 darwin*)
 669     ;;
 670 *)
 671     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 672                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 673                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 674     AC_SUBST([CLOCK_LIB])
 675     ;;
 676 esac
 677
 678 dnl See if posix_memalign is available
 679 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 680
 681 dnl Check for pthreads
 682 AX_PTHREAD
 683 if test "x$ax_pthread_ok" = xno; then
 684     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 685 fi
 686 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 687 dnl to -pthread, which causes problems if we need -lpthread to appear in
 688 dnl pkgconfig files.
 689 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 690
 691 dnl SELinux awareness.
 692 AC_ARG_ENABLE([selinux],
 693     [AS_HELP_STRING([--enable-selinux],
 694         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 695     [MESA_SELINUX="$enableval"],
 696     [MESA_SELINUX=no])
 697 if test "x$enable_selinux" = "xyes"; then
 698     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 699         [AC_CHECK_HEADER([selinux/selinux.h],[],
 700                          [AC_MSG_ERROR([SELinux headers not found])])
 701          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 702                       [AC_MSG_ERROR([SELinux library not found])])
 703          SELINUX_LIBS="-lselinux"])
 704     DEFINES="$DEFINES -DMESA_SELINUX"
 705 fi
 706 AC_SUBST([SELINUX_CFLAGS])
 707 AC_SUBST([SELINUX_LIBS])
 708
 709 dnl Options for APIs
 710 AC_ARG_ENABLE([opengl],
 711     [AS_HELP_STRING([--disable-opengl],
 712         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 713     [enable_opengl="$enableval"],
 714     [enable_opengl=yes])
 715 AC_ARG_ENABLE([gles1],
 716     [AS_HELP_STRING([--enable-gles1],
 717         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 718     [enable_gles1="$enableval"],
 719     [enable_gles1=no])
 720 AC_ARG_ENABLE([gles2],
 721     [AS_HELP_STRING([--enable-gles2],
 722         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 723     [enable_gles2="$enableval"],
 724     [enable_gles2=no])
 725
 726 AC_ARG_ENABLE([dri],
 727     [AS_HELP_STRING([--enable-dri],
 728         [enable DRI modules @<:@default=enabled@:>@])],
 729     [enable_dri="$enableval"],
 730     [enable_dri=yes])
 731
 732 case "$host_os" in
 733 linux*)
 734     dri3_default=yes
 735     ;;
 736 *)
 737     dri3_default=no
 738     ;;
 739 esac
 740 AC_ARG_ENABLE([dri3],
 741     [AS_HELP_STRING([--enable-dri3],
 742         [enable DRI3 @<:@default=auto@:>@])],
 743     [enable_dri3="$enableval"],
 744     [enable_dri3="$dri3_default"])
 745 AC_ARG_ENABLE([glx],
 746     [AS_HELP_STRING([--enable-glx],
 747         [enable GLX library @<:@default=enabled@:>@])],
 748     [enable_glx="$enableval"],
 749     [enable_glx=yes])
 750 AC_ARG_ENABLE([osmesa],
 751     [AS_HELP_STRING([--enable-osmesa],
 752         [enable OSMesa library @<:@default=disabled@:>@])],
 753     [enable_osmesa="$enableval"],
 754     [enable_osmesa=no])
 755 AC_ARG_ENABLE([gallium-osmesa],
 756     [AS_HELP_STRING([--enable-gallium-osmesa],
 757         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 758     [enable_gallium_osmesa="$enableval"],
 759     [enable_gallium_osmesa=no])
 760 AC_ARG_ENABLE([egl],
 761     [AS_HELP_STRING([--disable-egl],
 762         [disable EGL library @<:@default=enabled@:>@])],
 763     [enable_egl="$enableval"],
 764     [enable_egl=yes])
 765
 766 AC_ARG_ENABLE([xa],
 767     [AS_HELP_STRING([--enable-xa],
 768         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 769     [enable_xa="$enableval"],
 770     [enable_xa=no])
 771 AC_ARG_ENABLE([gbm],
 772    [AS_HELP_STRING([--enable-gbm],
 773          [enable gbm library @<:@default=auto@:>@])],
 774    [enable_gbm="$enableval"],
 775    [enable_gbm=auto])
 776 AC_ARG_ENABLE([nine],
 777     [AS_HELP_STRING([--enable-nine],
 778         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 779     [enable_nine="$enableval"],
 780     [enable_nine=no])
 781
 782 AC_ARG_ENABLE([xvmc],
 783    [AS_HELP_STRING([--enable-xvmc],
 784          [enable xvmc library @<:@default=auto@:>@])],
 785    [enable_xvmc="$enableval"],
 786    [enable_xvmc=auto])
 787 AC_ARG_ENABLE([vdpau],
 788    [AS_HELP_STRING([--enable-vdpau],
 789          [enable vdpau library @<:@default=auto@:>@])],
 790    [enable_vdpau="$enableval"],
 791    [enable_vdpau=auto])
 792 AC_ARG_ENABLE([omx],
 793    [AS_HELP_STRING([--enable-omx],
 794          [enable OpenMAX library @<:@default=disabled@:>@])],
 795    [enable_omx="$enableval"],
 796    [enable_omx=no])
 797 AC_ARG_ENABLE([va],
 798    [AS_HELP_STRING([--enable-va],
 799          [enable va library @<:@default=auto@:>@])],
 800    [enable_va="$enableval"],
 801    [enable_va=auto])
 802 AC_ARG_ENABLE([opencl],
 803    [AS_HELP_STRING([--enable-opencl],
 804          [enable OpenCL library @<:@default=disabled@:>@])],
 805    [enable_opencl="$enableval"],
 806    [enable_opencl=no])
 807 AC_ARG_ENABLE([opencl_icd],
 808    [AS_HELP_STRING([--enable-opencl-icd],
 809           [Build an OpenCL ICD library to be loaded by an ICD implementation
 810            @<:@default=disabled@:>@])],
 811     [enable_opencl_icd="$enableval"],
 812     [enable_opencl_icd=no])
 813 AC_ARG_ENABLE([xlib-glx],
 814     [AS_HELP_STRING([--enable-xlib-glx],
 815         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 816     [enable_xlib_glx="$enableval"],
 817     [enable_xlib_glx=no])
 818
 819 AC_ARG_ENABLE([r600-llvm-compiler],
 820     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 821         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 822     [enable_r600_llvm="$enableval"],
 823     [enable_r600_llvm=no])
 824
 825 AC_ARG_ENABLE([gallium-tests],
 826     [AS_HELP_STRING([--enable-gallium-tests],
 827         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 828     [enable_gallium_tests="$enableval"],
 829     [enable_gallium_tests=no])
 830
 831 # Option for Gallium drivers
 832
 833 # Keep this in sync with the --with-gallium-drivers help string default value
 834 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 835
 836 AC_ARG_WITH([gallium-drivers],
 837     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 838         [comma delimited Gallium drivers list, e.g.
 839         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 840         @<:@default=r300,r600,svga,swrast@:>@])],
 841     [with_gallium_drivers="$withval"],
 842     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 843
 844 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 845 # here so that the script doesn't choke on an unknown driver name later.
 846 case "$with_gallium_drivers" in
 847     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 848     no) with_gallium_drivers='' ;;
 849 esac
 850
 851 if test "x$enable_opengl" = xno -a \
 852         "x$enable_gles1" = xno -a \
 853         "x$enable_gles2" = xno -a \
 854         "x$enable_nine" = xno -a \
 855         "x$enable_xa" = xno -a \
 856         "x$enable_xvmc" = xno -a \
 857         "x$enable_vdpau" = xno -a \
 858         "x$enable_omx" = xno -a \
 859         "x$enable_va" = xno -a \
 860         "x$enable_opencl" = xno; then
 861     AC_MSG_ERROR([at least one API should be enabled])
 862 fi
 863
 864 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 865 if test "x$enable_opengl" = xno -a \
 866         "x$enable_gles1" = xyes; then
 867     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 868 fi
 869
 870 if test "x$enable_opengl" = xno -a \
 871         "x$enable_gles2" = xyes; then
 872     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 873 fi
 874
 875 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 876 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 877 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 878 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 879                                         "x$enable_gles1" = xyes -o \
 880                                         "x$enable_gles2" = xyes)
 881
 882 if test "x$enable_glx" = xno; then
 883     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 884     enable_xlib_glx=no
 885 fi
 886
 887 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 888     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 889 fi
 890
 891 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 892     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 893 fi
 894
 895 # Disable GLX if OpenGL is not enabled
 896 if test "x$enable_glx$enable_opengl" = xyesno; then
 897     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 898     enable_glx=no
 899 fi
 900
 901 # Disable GLX if DRI and Xlib-GLX are not enabled
 902 if test "x$enable_glx" = xyes -a \
 903         "x$enable_dri" = xno -a \
 904         "x$enable_xlib_glx" = xno; then
 905     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 906     enable_glx=no
 907 fi
 908
 909 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 910                                   "x$enable_dri" = xyes)
 911
 912 # Select which platform-dependent DRI code gets built
 913 case "$host_os" in
 914 darwin*)
 915     dri_platform='apple' ;;
 916 gnu*|cygwin*)
 917     dri_platform='none' ;;
 918 *)
 919     dri_platform='drm' ;;
 920 esac
 921
 922 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 923 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 924 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 925 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 926 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 927
 928 AC_ARG_ENABLE([shared-glapi],
 929     [AS_HELP_STRING([--enable-shared-glapi],
 930         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 931     [enable_shared_glapi="$enableval"],
 932     [enable_shared_glapi=yes])
 933
 934 case "x$enable_opengl$enable_gles1$enable_gles2" in
 935 x*yes*yes*)
 936     if test "x$enable_shared_glapi" = xno; then
 937         AC_MSG_ERROR([shared GLAPI required when building two or more of
 938                       the following APIs - opengl, gles1 gles2])
 939     fi
 940     ;;
 941 esac
 942
 943 # Building Xlib-GLX requires shared glapi to be disabled.
 944 if test "x$enable_xlib_glx" = xyes; then
 945     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 946     enable_shared_glapi=no
 947 fi
 948
 949 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 950
 951 # Build the pipe-drivers as separate libraries/modules.
 952 # Do not touch this unless you know what you are doing.
 953 # XXX: Expose via configure option ?
 954 enable_shared_pipe_drivers=no
 955
 956 dnl
 957 dnl Driver specific build directories
 958 dnl
 959
 960 case "x$enable_glx$enable_xlib_glx" in
 961 xyesyes)
 962     NEED_WINSYS_XLIB="yes"
 963     ;;
 964 esac
 965
 966 if test "x$enable_dri" = xyes; then
 967     enable_gallium_loader="$enable_shared_pipe_drivers"
 968 fi
 969
 970 if test "x$enable_gallium_osmesa" = xyes; then
 971     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 972         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 973     fi
 974     if test "x$enable_osmesa" = xyes; then
 975         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 976     fi
 977 fi
 978
 979 AC_SUBST([MESA_LLVM])
 980
 981 # SHA1 hashing
 982 AC_ARG_WITH([sha1],
 983         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 984         [choose SHA1 implementation])])
 985 case "x$with_sha1" in
 986 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 987   ;;
 988 *)
 989         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 990 esac
 991
 992 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 993 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 994         with_sha1=libc
 995 fi
 996 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 997         AC_MSG_ERROR([sha1 in libc requested but not found])
 998 fi
 999 if test "x$with_sha1" = xlibc; then
1000         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1001                 [Use libc SHA1 functions])
1002         SHA1_LIBS=""
1003 fi
1004 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1005 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1006         with_sha1=CommonCrypto
1007 fi
1008 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1009         AC_MSG_ERROR([CommonCrypto requested but not found])
1010 fi
1011 if test "x$with_sha1" = xCommonCrypto; then
1012         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1013                 [Use CommonCrypto SHA1 functions])
1014         SHA1_LIBS=""
1015 fi
1016 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1017 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1018 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1019         with_sha1=CryptoAPI
1020 fi
1021 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1022         AC_MSG_ERROR([CryptoAPI requested but not found])
1023 fi
1024 if test "x$with_sha1" = xCryptoAPI; then
1025         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1026                 [Use CryptoAPI SHA1 functions])
1027         SHA1_LIBS=""
1028 fi
1029 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1030 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1031         with_sha1=libmd
1032 fi
1033 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1034         AC_MSG_ERROR([libmd requested but not found])
1035 fi
1036 if test "x$with_sha1" = xlibmd; then
1037         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1038                   [Use libmd SHA1 functions])
1039         SHA1_LIBS=-lmd
1040 fi
1041 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1042 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1043    with_sha1=libsha1
1044 fi
1045 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1046         AC_MSG_ERROR([libsha1 requested but not found])
1047 fi
1048 if test "x$with_sha1" = xlibsha1; then
1049         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1050                   [Use libsha1 for SHA1])
1051         SHA1_LIBS=-lsha1
1052 fi
1053 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1054 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1055         with_sha1=libnettle
1056 fi
1057 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1058         AC_MSG_ERROR([libnettle requested but not found])
1059 fi
1060 if test "x$with_sha1" = xlibnettle; then
1061         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1062                   [Use libnettle SHA1 functions])
1063         SHA1_LIBS=-lnettle
1064 fi
1065 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1066 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1067         with_sha1=libgcrypt
1068 fi
1069 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1070         AC_MSG_ERROR([libgcrypt requested but not found])
1071 fi
1072 if test "x$with_sha1" = xlibgcrypt; then
1073         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1074                   [Use libgcrypt SHA1 functions])
1075         SHA1_LIBS=-lgcrypt
1076 fi
1077 # We don't need all of the OpenSSL libraries, just libcrypto
1078 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1079 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1080                   [HAVE_OPENSSL_PKC=no])
1081 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1082         if test "x$with_sha1" = x; then
1083                 with_sha1=libcrypto
1084         fi
1085 else
1086         if test "x$with_sha1" = xlibcrypto; then
1087                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1088         fi
1089 fi
1090 if test "x$with_sha1" = xlibcrypto; then
1091         if test "x$HAVE_LIBCRYPTO" = xyes; then
1092                 SHA1_LIBS=-lcrypto
1093         else
1094                 SHA1_LIBS="$OPENSSL_LIBS"
1095                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1096         fi
1097 fi
1098 AC_MSG_CHECKING([for SHA1 implementation])
1099 AC_MSG_RESULT([$with_sha1])
1100 AC_SUBST(SHA1_LIBS)
1101 AC_SUBST(SHA1_CFLAGS)
1102
1103 # Allow user to configure out the shader-cache feature
1104 AC_ARG_ENABLE([shader-cache],
1105     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1106     [enable_shader_cache="$enableval"],
1107     [if test "x$with_sha1" != "x"; then
1108         enable_shader_cache=yes
1109      else
1110         enable_shader_cache=no
1111      fi])
1112 if test "x$with_sha1" = "x"; then
1113     if test "x$enable_shader_cache" = "xyes"; then
1114         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1115     fi
1116 fi
1117 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1118
1119 # Check for libdrm
1120 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1121                   [have_libdrm=yes], [have_libdrm=no])
1122 if test "x$have_libdrm" = xyes; then
1123         DEFINES="$DEFINES -DHAVE_LIBDRM"
1124 fi
1125
1126 case "$host_os" in
1127 linux*)
1128     need_pci_id=yes ;;
1129 *)
1130     need_pci_id=no ;;
1131 esac
1132
1133 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1134                   have_libudev=yes, have_libudev=no)
1135
1136 AC_ARG_ENABLE([sysfs],
1137     [AS_HELP_STRING([--enable-sysfs],
1138         [enable /sys PCI identification @<:@default=disabled@:>@])],
1139     [have_sysfs="$enableval"],
1140     [have_sysfs=no]
1141 )
1142
1143 if test "x$enable_dri" = xyes; then
1144     if test "$enable_static" = yes; then
1145         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1146     fi
1147
1148     # not a hard requirement as swrast does not depend on it
1149     if test "x$have_libdrm" = xyes; then
1150         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1151     fi
1152 fi
1153
1154 AC_ARG_ENABLE([driglx-direct],
1155     [AS_HELP_STRING([--disable-driglx-direct],
1156         [disable direct rendering in GLX and EGL for DRI \
1157             @<:@default=auto@:>@])],
1158     [driglx_direct="$enableval"],
1159     [driglx_direct="yes"])
1160
1161 dnl
1162 dnl libGL configuration per driver
1163 dnl
1164 case "x$enable_glx$enable_xlib_glx" in
1165 xyesyes)
1166     # Xlib-based GLX
1167     dri_modules="x11 xext xcb"
1168     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1169     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1170     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1171     GL_LIB_DEPS="$XLIBGL_LIBS"
1172     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1173     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1174     ;;
1175 xyesno)
1176     # DRI-based GLX
1177     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1178
1179     # find the DRI deps for libGL
1180     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1181
1182     if test x"$driglx_direct" = xyes; then
1183         if test x"$dri_platform" = xdrm ; then
1184             DEFINES="$DEFINES -DGLX_USE_DRM"
1185             if test "x$have_libdrm" != xyes; then
1186                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1187             fi
1188
1189             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1190             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1191             if test x"$enable_dri3" = xyes; then
1192                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1193                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1194             fi
1195
1196             if test x"$enable_dri" = xyes; then
1197                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1198             fi
1199
1200             if test x"$enable_dri3" = xyes; then
1201                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1202                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1203             fi
1204         fi
1205         if test x"$dri_platform" = xapple ; then
1206             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1207         fi
1208     fi
1209
1210     # add xf86vidmode if available
1211     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1212     if test "$HAVE_XF86VIDMODE" = yes ; then
1213         dri_modules="$dri_modules xxf86vm"
1214     fi
1215
1216     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1217     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1218     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1219     GL_LIB_DEPS="$DRIGL_LIBS"
1220
1221     # need DRM libs, $PTHREAD_LIBS, etc.
1222     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1223     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1224     ;;
1225 esac
1226
1227 have_pci_id=no
1228 if test "$have_libudev" = yes; then
1229     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1230     have_pci_id=yes
1231 fi
1232
1233 if test "$have_sysfs" = yes; then
1234     DEFINES="$DEFINES -DHAVE_SYSFS"
1235     have_pci_id=yes
1236 fi
1237
1238 # This is outside the case (above) so that it is invoked even for non-GLX
1239 # builds.
1240 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1241
1242 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1243 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1244 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1245 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1246
1247 AC_SUBST([X11_INCLUDES])
1248 AC_SUBST([GL_LIB_DEPS])
1249 AC_SUBST([GL_PC_REQ_PRIV])
1250 AC_SUBST([GL_PC_LIB_PRIV])
1251 AC_SUBST([GL_PC_CFLAGS])
1252 AC_SUBST([DRI_PC_REQ_PRIV])
1253 AC_SUBST([GLESv1_CM_LIB_DEPS])
1254 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1255 AC_SUBST([GLESv2_LIB_DEPS])
1256 AC_SUBST([GLESv2_PC_LIB_PRIV])
1257
1258 AC_SUBST([HAVE_XF86VIDMODE])
1259
1260 dnl
1261 dnl More GLX setup
1262 dnl
1263 case "x$enable_glx$enable_xlib_glx" in
1264 xyesyes)
1265     DEFINES="$DEFINES -DUSE_XSHM"
1266     ;;
1267 xyesno)
1268     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1269     if test "x$driglx_direct" = xyes; then
1270         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1271     fi
1272     ;;
1273 esac
1274
1275 dnl
1276 dnl TLS detection
1277 dnl
1278
1279 AC_ARG_ENABLE([glx-tls],
1280     [AS_HELP_STRING([--enable-glx-tls],
1281         [enable TLS support in GLX @<:@default=disabled@:>@])],
1282     [GLX_USE_TLS="$enableval"],
1283     [GLX_USE_TLS=no])
1284 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1285
1286 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1287       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1288
1289 dnl
1290 dnl More DRI setup
1291 dnl
1292 dnl Directory for DRI drivers
1293 AC_ARG_WITH([dri-driverdir],
1294     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1295         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1296     [DRI_DRIVER_INSTALL_DIR="$withval"],
1297     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1298 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1299 dnl Extra search path for DRI drivers
1300 AC_ARG_WITH([dri-searchpath],
1301     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1302         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1303     [DRI_DRIVER_SEARCH_DIR="$withval"],
1304     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1305 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1306 dnl Which drivers to build - default is chosen by platform
1307 AC_ARG_WITH([dri-drivers],
1308     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1309         [comma delimited classic DRI drivers list, e.g.
1310         "swrast,i965,radeon" @<:@default=auto@:>@])],
1311     [with_dri_drivers="$withval"],
1312     [with_dri_drivers=auto])
1313
1314 if test "x$with_dri_drivers" = xauto; then
1315     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1316         with_dri_drivers="yes"
1317     else
1318         with_dri_drivers="no"
1319     fi
1320 fi
1321 if test "x$with_dri_drivers" = xno; then
1322     with_dri_drivers=''
1323 fi
1324
1325 dnl If $with_dri_drivers is yes, drivers will be added through
1326 dnl platform checks. Set DEFINES and LIB_DEPS
1327 if test "x$enable_dri" = xyes; then
1328     # Platform specific settings and drivers to build
1329     case "$host_os" in
1330     linux*)
1331         DEFINES="$DEFINES -DHAVE_ALIAS"
1332         if test "x$enable_dri3" = xyes; then
1333             DEFINES="$DEFINES -DHAVE_DRI3"
1334         fi
1335
1336         if test "x$have_pci_id" != xyes; then
1337             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1338         fi
1339
1340         case "$host_cpu" in
1341         powerpc* | sparc*)
1342             # Build only the drivers for cards that exist on PowerPC/sparc
1343             if test "x$with_dri_drivers" = "xyes"; then
1344                 with_dri_drivers="r200 radeon swrast"
1345             fi
1346             ;;
1347         esac
1348         ;;
1349     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1350         DEFINES="$DEFINES -DHAVE_ALIAS"
1351         ;;
1352     gnu*)
1353         DEFINES="$DEFINES -DHAVE_ALIAS"
1354         ;;
1355     cygwin*)
1356         if test "x$with_dri_drivers" = "xyes"; then
1357             with_dri_drivers="swrast"
1358         fi
1359         ;;
1360     darwin*)
1361         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1362         if test "x$with_dri_drivers" = "xyes"; then
1363             with_dri_drivers="swrast"
1364         fi
1365         ;;
1366     esac
1367
1368     # default drivers
1369     if test "x$with_dri_drivers" = "xyes"; then
1370         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1371     fi
1372
1373     # Check for expat
1374     PKG_CHECK_MODULES([EXPAT], [expat], [],
1375         # expat version 2.0 and earlier do not provide expat.pc
1376         [AC_CHECK_HEADER([expat.h],[],
1377                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1378          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1379                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1380          EXPAT_LIBS="-lexpat"])
1381
1382     DRICOMMON_NEED_LIBDRM=no
1383     # If we are building any DRI driver other than swrast.
1384     if test -n "$with_dri_drivers"; then
1385         if test "x$with_dri_drivers" != xswrast; then
1386             # ... libdrm is required
1387             if test "x$have_libdrm" != xyes; then
1388                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1389             fi
1390             DRICOMMON_NEED_LIBDRM=yes
1391         fi
1392     fi
1393
1394     # If we're building any gallium DRI driver other than swrast
1395     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1396         if test "x$with_gallium_drivers" != xswrast; then
1397             # ... build a libdrm aware dricommon
1398             DRICOMMON_NEED_LIBDRM=yes
1399         fi
1400     fi
1401
1402     # put all the necessary libs together
1403     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1404 fi
1405
1406 AC_SUBST([DRI_LIB_DEPS])
1407
1408 DRI_DIRS=''
1409 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1410 if test -n "$with_dri_drivers"; then
1411     if test "x$enable_opengl" != xyes; then
1412         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1413     fi
1414
1415     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1416     for driver in $dri_drivers; do
1417         DRI_DIRS="$DRI_DIRS $driver"
1418         case "x$driver" in
1419         xi915)
1420             HAVE_I915_DRI=yes;
1421             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1422             ;;
1423         xi965)
1424             HAVE_I965_DRI=yes;
1425             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1426             ;;
1427         xnouveau)
1428             HAVE_NOUVEAU_DRI=yes;
1429             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1430             ;;
1431         xradeon)
1432             HAVE_RADEON_DRI=yes;
1433             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1434             ;;
1435         xr200)
1436             HAVE_R200_DRI=yes;
1437             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1438             ;;
1439         xswrast)
1440             HAVE_SWRAST_DRI=yes;
1441             ;;
1442         *)
1443             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1444             ;;
1445         esac
1446     done
1447     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1448 fi
1449
1450 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1451 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1452                                   "x$enable_osmesa" = xyes -o \
1453                                   -n "$DRI_DIRS")
1454
1455 dnl
1456 dnl OSMesa configuration
1457 dnl
1458
1459 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1460 AC_ARG_WITH([osmesa-bits],
1461     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1462         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1463     [osmesa_bits="$withval"],
1464     [osmesa_bits=8])
1465 if test "x$osmesa_bits" != x8; then
1466     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1467         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1468         osmesa_bits=8
1469     fi
1470 fi
1471 case "x$osmesa_bits" in
1472 x8)
1473     OSMESA_LIB="${OSMESA_LIB}"
1474     ;;
1475 x16|x32)
1476     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1477     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1478     ;;
1479 *)
1480     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1481     ;;
1482 esac
1483
1484 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1485     # only link libraries with osmesa if shared
1486     if test "$enable_static" = no; then
1487         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1488     else
1489         OSMESA_LIB_DEPS=""
1490     fi
1491     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1492 fi
1493
1494 AC_SUBST([OSMESA_LIB_DEPS])
1495 AC_SUBST([OSMESA_PC_REQ])
1496 AC_SUBST([OSMESA_PC_LIB_PRIV])
1497
1498 dnl
1499 dnl gbm configuration
1500 dnl
1501 if test "x$enable_gbm" = xauto; then
1502     case "$with_egl_platforms" in
1503         *drm*)
1504             enable_gbm=yes ;;
1505          *)
1506             enable_gbm=no ;;
1507     esac
1508 fi
1509 if test "x$enable_gbm" = xyes; then
1510     if test "x$need_pci_id$have_pci_id" = xyesno; then
1511         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1512     fi
1513
1514     if test "x$enable_dri" = xyes; then
1515         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1516         if test "x$enable_shared_glapi" = xno; then
1517             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1518         fi
1519     else
1520         # Strictly speaking libgbm does not require --enable-dri, although
1521         # both of its backends do. Thus one can build libgbm without any
1522         # backends if --disable-dri is set.
1523         # To avoid unnecessary complexity of checking if at least one backend
1524         # is available when building, just mandate --enable-dri.
1525         AC_MSG_ERROR([gbm requires --enable-dri])
1526     fi
1527 fi
1528 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1529 if test "x$need_pci_id$have_libudev" = xyesyes; then
1530     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1531 else
1532     GBM_PC_REQ_PRIV=""
1533 fi
1534 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1535 AC_SUBST([GBM_PC_REQ_PRIV])
1536 AC_SUBST([GBM_PC_LIB_PRIV])
1537
1538 dnl
1539 dnl EGL configuration
1540 dnl
1541 EGL_CLIENT_APIS=""
1542
1543 if test "x$enable_egl" = xyes; then
1544     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1545
1546     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1547
1548     if test "$enable_static" != yes; then
1549         if test "x$enable_dri" = xyes; then
1550             HAVE_EGL_DRIVER_DRI2=1
1551         fi
1552
1553     fi
1554 fi
1555 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1556 AC_SUBST([EGL_LIB_DEPS])
1557
1558 dnl
1559 dnl XA configuration
1560 dnl
1561 if test "x$enable_xa" = xyes; then
1562     if test "x$with_gallium_drivers" = xswrast; then
1563        AC_MSG_ERROR([
1564           Building xa requires at least one non swrast gallium driver.
1565           If you are looking to use libxatracker.so with the VMware driver,
1566           make sure to include svga in the gallium drivers list, apart from
1567           enabling XA.
1568           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1569     fi
1570     enable_gallium_loader=$enable_shared_pipe_drivers
1571 fi
1572 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1573
1574 dnl
1575 dnl Gallium G3DVL configuration
1576 dnl
1577 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1578     if test "x$enable_xvmc" = xauto; then
1579         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1580     fi
1581
1582     if test "x$enable_vdpau" = xauto; then
1583         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1584     fi
1585
1586     if test "x$enable_omx" = xauto; then
1587         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1588     fi
1589
1590     if test "x$enable_va" = xauto; then
1591         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1592     fi
1593 fi
1594
1595 if test "x$enable_dri" = xyes -o \
1596         "x$enable_xvmc" = xyes -o \
1597         "x$enable_vdpau" = xyes -o \
1598         "x$enable_omx" = xyes -o \
1599         "x$enable_va" = xyes; then
1600     need_gallium_vl=yes
1601 fi
1602 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1603
1604 if test "x$enable_xvmc" = xyes -o \
1605         "x$enable_vdpau" = xyes -o \
1606         "x$enable_omx" = xyes -o \
1607         "x$enable_va" = xyes; then
1608     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1609     need_gallium_vl_winsys=yes
1610 fi
1611 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1612
1613 if test "x$enable_xvmc" = xyes; then
1614     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1615     enable_gallium_loader=$enable_shared_pipe_drivers
1616 fi
1617 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1618
1619 if test "x$enable_vdpau" = xyes; then
1620     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1621     enable_gallium_loader=$enable_shared_pipe_drivers
1622 fi
1623 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1624
1625 if test "x$enable_omx" = xyes; then
1626     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1627     enable_gallium_loader=$enable_shared_pipe_drivers
1628 fi
1629 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1630
1631 if test "x$enable_va" = xyes; then
1632     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1633     enable_gallium_loader=$enable_shared_pipe_drivers
1634 fi
1635 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1636
1637 dnl
1638 dnl Nine Direct3D9 configuration
1639 dnl
1640 if test "x$enable_nine" = xyes; then
1641     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1642         AC_MSG_ERROR([nine requires the gallium swrast driver])
1643     fi
1644     if test "x$with_gallium_drivers" == xswrast; then
1645         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1646     fi
1647     if test "x$enable_dri3" = xno; then
1648         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1649     fi
1650
1651     enable_gallium_loader=$enable_shared_pipe_drivers
1652 fi
1653 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1654
1655 dnl
1656 dnl OpenCL configuration
1657 dnl
1658
1659 AC_ARG_WITH([libclc-path],
1660    [AS_HELP_STRING([--with-libclc-path],
1661          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1662    [LIBCLC_PATH="$withval"],
1663    [LIBCLC_PATH=''])
1664
1665 if test -n "$LIBCLC_PATH"; then
1666    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1667                   Please review the updated build instructions for clover:
1668                   http://dri.freedesktop.org/wiki/GalliumCompute])
1669 fi
1670
1671
1672 AC_ARG_WITH([clang-libdir],
1673    [AS_HELP_STRING([--with-clang-libdir],
1674          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1675    [CLANG_LIBDIR="$withval"],
1676    [CLANG_LIBDIR=''])
1677
1678 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1679 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1680
1681 if test "x$enable_opencl" = xyes; then
1682     if test -z "$with_gallium_drivers"; then
1683         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1684     fi
1685
1686     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1687         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1688     fi
1689
1690     if test "x$have_libclc" = xno; then
1691         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1692                     Make sure the directory containing libclc.pc is specified in your
1693                     PKG_CONFIG_PATH environment variable.
1694                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1695     else
1696         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1697         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1698         AC_SUBST([LIBCLC_INCLUDEDIR])
1699         AC_SUBST([LIBCLC_LIBEXECDIR])
1700     fi
1701
1702     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1703     enable_gallium_loader=yes
1704
1705     if test "x$enable_opencl_icd" = xyes; then
1706         OPENCL_LIBNAME="MesaOpenCL"
1707     else
1708         OPENCL_LIBNAME="OpenCL"
1709     fi
1710
1711     if test "x$have_libelf" != xyes; then
1712        AC_MSG_ERROR([Clover requires libelf])
1713     fi
1714 fi
1715 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1716 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1717 AC_SUBST([OPENCL_LIBNAME])
1718
1719 dnl
1720 dnl Gallium configuration
1721 dnl
1722 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1723
1724 AC_SUBST([LLVM_BINDIR])
1725 AC_SUBST([LLVM_CFLAGS])
1726 AC_SUBST([LLVM_CPPFLAGS])
1727 AC_SUBST([LLVM_CXXFLAGS])
1728 AC_SUBST([LLVM_LIBDIR])
1729 AC_SUBST([LLVM_LIBS])
1730 AC_SUBST([LLVM_LDFLAGS])
1731 AC_SUBST([LLVM_INCLUDEDIR])
1732 AC_SUBST([LLVM_VERSION])
1733 AC_SUBST([CLANG_RESOURCE_DIR])
1734
1735 case "x$enable_opengl$enable_gles1$enable_gles2" in
1736 x*yes*)
1737     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1738     ;;
1739 esac
1740
1741 AC_SUBST([VG_LIB_DEPS])
1742 AC_SUBST([EGL_CLIENT_APIS])
1743
1744 dnl
1745 dnl EGL Platforms configuration
1746 dnl
1747 AC_ARG_WITH([egl-platforms],
1748     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1749         [comma delimited native platforms libEGL supports, e.g.
1750         "x11,drm" @<:@default=auto@:>@])],
1751     [with_egl_platforms="$withval"],
1752     [if test "x$enable_egl" = xyes; then
1753         with_egl_platforms="x11"
1754     else
1755         with_egl_platforms=""
1756     fi])
1757
1758 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1759     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1760 fi
1761
1762 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1763         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1764         WAYLAND_SCANNER='')
1765 if test "x$WAYLAND_SCANNER" = x; then
1766     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1767 fi
1768
1769 # Do per-EGL platform setups and checks
1770 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1771 for plat in $egl_platforms; do
1772         case "$plat" in
1773         wayland)
1774                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1775
1776                 if test "x$WAYLAND_SCANNER" = x; then
1777                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1778                 fi
1779                 ;;
1780
1781         x11)
1782                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1783                 ;;
1784
1785         drm)
1786                 test "x$enable_gbm" = "xno" &&
1787                         AC_MSG_ERROR([EGL platform drm needs gbm])
1788                 test "x$have_libdrm" != xyes &&
1789                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1790                 ;;
1791
1792         android|gdi|null)
1793                 ;;
1794
1795         *)
1796                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1797                 ;;
1798         esac
1799
1800         case "$plat$need_pci_id$have_pci_id" in
1801                 waylandyesno|drmyesno)
1802                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1803         esac
1804 done
1805
1806 # libEGL wants to default to the first platform specified in
1807 # ./configure.  parse that here.
1808 if test "x$egl_platforms" != "x"; then
1809     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1810     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1811 else
1812     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1813 fi
1814
1815 if echo "$egl_platforms" | grep -q 'x11'; then
1816     NEED_WINSYS_XLIB=yes
1817 fi
1818 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1819 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1820 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1821 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1822
1823 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1824
1825 AC_SUBST([EGL_NATIVE_PLATFORM])
1826 AC_SUBST([EGL_CFLAGS])
1827
1828 # If we don't have the X11 platform, set this define so we don't try to include
1829 # the X11 headers.
1830 if ! echo "$egl_platforms" | grep -q 'x11'; then
1831     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1832     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1833 fi
1834
1835 dnl
1836 dnl Gallium LLVM
1837 dnl
1838 AC_ARG_ENABLE([gallium-llvm],
1839     [AS_HELP_STRING([--enable-gallium-llvm],
1840         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1841     [enable_gallium_llvm="$enableval"],
1842     [enable_gallium_llvm=auto])
1843
1844 AC_ARG_ENABLE([llvm-shared-libs],
1845     [AS_HELP_STRING([--enable-llvm-shared-libs],
1846         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1847     [enable_llvm_shared_libs="$enableval"],
1848     [enable_llvm_shared_libs=yes])
1849
1850 AC_ARG_WITH([llvm-prefix],
1851     [AS_HELP_STRING([--with-llvm-prefix],
1852         [Prefix for LLVM installations in non-standard locations])],
1853     [llvm_prefix="$withval"],
1854     [llvm_prefix=''])
1855
1856
1857 # Call this inside ` ` to get the return value.
1858 # $1 is the llvm-config command with arguments.
1859 strip_unwanted_llvm_flags() {
1860     # Use \> (marks the end of the word)
1861     echo `$1` | sed \
1862         -e 's/-DNDEBUG\>//g' \
1863         -e 's/-D_GNU_SOURCE\>//g' \
1864         -e 's/-pedantic\>//g' \
1865         -e 's/-Wcovered-switch-default\>//g' \
1866         -e 's/-O.\>//g' \
1867         -e 's/-g\>//g' \
1868         -e 's/-Wall\>//g' \
1869         -e 's/-Wcast-qual\>//g' \
1870         -e 's/-Woverloaded-virtual\>//g' \
1871         -e 's/-fcolor-diagnostics\>//g' \
1872         -e 's/-fdata-sections\>//g' \
1873         -e 's/-ffunction-sections\>//g' \
1874         -e 's/-fno-exceptions\>//g' \
1875         -e 's/-fomit-frame-pointer\>//g' \
1876         -e 's/-fvisibility-inlines-hidden\>//g' \
1877         -e 's/-fPIC\>//g' \
1878         -e 's/-fstack-protector-strong\>//g'
1879 }
1880
1881
1882 if test -z "$with_gallium_drivers"; then
1883     enable_gallium_llvm=no
1884 fi
1885 if test "x$enable_gallium_llvm" = xauto; then
1886     case "$host_cpu" in
1887     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1888     esac
1889 fi
1890 if test "x$enable_gallium_llvm" = xyes; then
1891     if test -n "$llvm_prefix"; then
1892         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1893     else
1894         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1895     fi
1896
1897     if test "x$LLVM_CONFIG" != xno; then
1898         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1899         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1900         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1901         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1902         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1903         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1904         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1905         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1906
1907         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1908             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1909         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1910             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1911
1912         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1913         if test -z "$LLVM_VERSION_PATCH"; then
1914             LLVM_VERSION_PATCH=0
1915         fi
1916
1917         if test -n "${LLVM_VERSION_MAJOR}"; then
1918             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1919         else
1920             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1921         fi
1922
1923         LLVM_REQUIRED_VERSION_MAJOR="3"
1924         LLVM_REQUIRED_VERSION_MINOR="3"
1925         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1926             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1927         fi
1928
1929         LLVM_COMPONENTS="engine bitwriter"
1930         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1931             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1932         fi
1933
1934         if test "x$enable_opencl" = xyes; then
1935             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1936             # LLVM 3.3 >= 177971 requires IRReader
1937             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1938                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1939             fi
1940             # LLVM 3.4 requires Option
1941             if $LLVM_CONFIG --components | grep -qw 'option'; then
1942                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1943             fi
1944             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1945             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1946                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1947             fi
1948             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1949                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1950             fi
1951         fi
1952         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1953         MESA_LLVM=1
1954
1955         dnl Check for Clang internal headers
1956         if test "x$enable_opencl" = xyes; then
1957             if test -z "$CLANG_LIBDIR"; then
1958                 CLANG_LIBDIR=${LLVM_LIBDIR}
1959             fi
1960             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1961             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1962                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1963         fi
1964     else
1965         MESA_LLVM=0
1966         LLVM_VERSION_INT=0
1967     fi
1968 else
1969     MESA_LLVM=0
1970     LLVM_VERSION_INT=0
1971
1972     if test "x$enable_opencl" = xyes; then
1973         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1974     fi
1975 fi
1976
1977 dnl Directory for XVMC libs
1978 AC_ARG_WITH([xvmc-libdir],
1979     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1980         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1981     [XVMC_LIB_INSTALL_DIR="$withval"],
1982     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1983 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1984
1985 dnl
1986 dnl Gallium Tests
1987 dnl
1988 if test "x$enable_gallium_tests" = xyes; then
1989     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1990     enable_gallium_loader=yes
1991 fi
1992 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1993
1994 dnl Directory for VDPAU libs
1995 AC_ARG_WITH([vdpau-libdir],
1996     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1997         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1998     [VDPAU_LIB_INSTALL_DIR="$withval"],
1999     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2000 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2001
2002 dnl Directory for OMX libs
2003
2004 AC_ARG_WITH([omx-libdir],
2005     [AS_HELP_STRING([--with-omx-libdir=DIR],
2006         [directory for the OMX libraries])],
2007     [OMX_LIB_INSTALL_DIR="$withval"],
2008     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2009 AC_SUBST([OMX_LIB_INSTALL_DIR])
2010
2011 dnl Directory for VA libs
2012
2013 AC_ARG_WITH([va-libdir],
2014     [AS_HELP_STRING([--with-va-libdir=DIR],
2015         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2016     [VA_LIB_INSTALL_DIR="$withval"],
2017     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2018 AC_SUBST([VA_LIB_INSTALL_DIR])
2019
2020 AC_ARG_WITH([d3d-libdir],
2021     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2022         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2023     [D3D_DRIVER_INSTALL_DIR="$withval"],
2024     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2025 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2026
2027 dnl
2028 dnl Gallium helper functions
2029 dnl
2030 gallium_require_drm() {
2031     if test "x$have_libdrm" != xyes; then
2032        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2033     fi
2034 }
2035
2036 gallium_require_llvm() {
2037     if test "x$MESA_LLVM" = x0; then
2038         case "$host" in *gnux32) return;; esac
2039         case "$host_cpu" in
2040         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2041         esac
2042     fi
2043 }
2044
2045 gallium_require_drm_loader() {
2046     if test "x$enable_gallium_loader" = xyes; then
2047         if test "x$need_pci_id$have_pci_id" = xyesno; then
2048             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2049         fi
2050         enable_gallium_drm_loader=yes
2051     fi
2052     if test "x$enable_va" = xyes && test "x$7" != x; then
2053          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2054     fi
2055 }
2056
2057 require_egl_drm() {
2058     case "$with_egl_platforms" in
2059         *drm*)
2060             ;;
2061          *)
2062             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2063             ;;
2064     esac
2065     if test "x$enable_gbm" != xyes; then
2066             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2067     fi
2068 }
2069
2070 radeon_llvm_check() {
2071     if test "x$enable_gallium_llvm" != "xyes"; then
2072         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2073     fi
2074     LLVM_REQUIRED_VERSION_MAJOR="3"
2075     LLVM_REQUIRED_VERSION_MINOR="4"
2076     LLVM_REQUIRED_VERSION_PATCH="2"
2077     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2078         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2079     fi
2080     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2081         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2082                       sources with the --enable-experimental-targets=R600
2083                       configure flag])
2084     fi
2085     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2086     NEED_RADEON_LLVM=yes
2087     if test "x$have_libelf" != xyes; then
2088        AC_MSG_ERROR([$1 requires libelf when using llvm])
2089     fi
2090 }
2091
2092 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2093 if test -n "$with_gallium_drivers"; then
2094     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2095     for driver in $gallium_drivers; do
2096         case "x$driver" in
2097         xsvga)
2098             HAVE_GALLIUM_SVGA=yes
2099             gallium_require_drm "svga"
2100             gallium_require_drm_loader
2101             ;;
2102         xi915)
2103             HAVE_GALLIUM_I915=yes
2104             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2105             gallium_require_drm "Gallium i915"
2106             gallium_require_drm_loader
2107             ;;
2108         xilo)
2109             HAVE_GALLIUM_ILO=yes
2110             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2111             gallium_require_drm "Gallium i965/ilo"
2112             gallium_require_drm_loader
2113             ;;
2114         xr300)
2115             HAVE_GALLIUM_R300=yes
2116             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2117             gallium_require_drm "Gallium R300"
2118             gallium_require_drm_loader
2119             gallium_require_llvm "Gallium R300"
2120             ;;
2121         xr600)
2122             HAVE_GALLIUM_R600=yes
2123             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2124             gallium_require_drm "Gallium R600"
2125             gallium_require_drm_loader
2126             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2127                 radeon_llvm_check "r600g"
2128                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2129             fi
2130             if test "x$enable_r600_llvm" = xyes; then
2131                 USE_R600_LLVM_COMPILER=yes;
2132             fi
2133             if test "x$enable_opencl" = xyes; then
2134                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2135             fi
2136             ;;
2137         xradeonsi)
2138             HAVE_GALLIUM_RADEONSI=yes
2139             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2140             gallium_require_drm "radeonsi"
2141             gallium_require_drm_loader
2142             radeon_llvm_check "radeonsi"
2143             require_egl_drm "radeonsi"
2144             ;;
2145         xnouveau)
2146             HAVE_GALLIUM_NOUVEAU=yes
2147             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2148             gallium_require_drm "nouveau"
2149             gallium_require_drm_loader
2150             ;;
2151         xfreedreno)
2152             HAVE_GALLIUM_FREEDRENO=yes
2153             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2154             gallium_require_drm "freedreno"
2155             gallium_require_drm_loader
2156             ;;
2157         xswrast)
2158             HAVE_GALLIUM_SOFTPIPE=yes
2159             if test "x$MESA_LLVM" = x1; then
2160                 HAVE_GALLIUM_LLVMPIPE=yes
2161             fi
2162             ;;
2163         xvc4)
2164             HAVE_GALLIUM_VC4=yes
2165             gallium_require_drm "vc4"
2166             gallium_require_drm_loader
2167
2168             case "$host_cpu" in
2169                 i?86 | x86_64 | amd64)
2170                 USE_VC4_SIMULATOR=yes
2171                 ;;
2172             esac
2173             ;;
2174         *)
2175             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2176             ;;
2177         esac
2178     done
2179 fi
2180
2181 dnl Set LLVM_LIBS - This is done after the driver configuration so
2182 dnl that drivers can add additional components to LLVM_COMPONENTS.
2183 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2184 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2185 dnl this was causing the same libraries to be appear multiple times
2186 dnl in LLVM_LIBS.
2187
2188 if test "x$MESA_LLVM" != x0; then
2189
2190     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2191
2192     if test "x$enable_llvm_shared_libs" = xyes; then
2193         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2194         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2195         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2196
2197         if test "x$llvm_have_one_so" = xyes; then
2198             dnl LLVM was built using auto*, so there is only one shared object.
2199             LLVM_LIBS="-l$LLVM_SO_NAME"
2200         else
2201             dnl If LLVM was built with CMake, there will be one shared object per
2202             dnl component.
2203             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2204                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2205         Please make sure you have built llvm with the --enable-shared option
2206         and that your llvm libraries are installed in $LLVM_LIBDIR
2207         If you have installed your llvm libraries to a different directory you
2208         can use the --with-llvm-prefix= configure flag to specify this directory.
2209         NOTE: Mesa is attempting to use llvm shared libraries by default.
2210         If you do not want to build with llvm shared libraries and instead want to
2211         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2212         invocation and rebuild.])])
2213
2214            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2215            dnl install uses a shared object for each component and we have
2216            dnl already added all of these objects to LLVM_LIBS.
2217         fi
2218     else
2219         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2220         dnl We need to link to llvm system libs when using static libs
2221         dnl However, only llvm 3.5+ provides --system-libs
2222         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2223             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2224         fi
2225     fi
2226 fi
2227
2228 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2229 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2230 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2231 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2232 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2233 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2234 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2235                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2236 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2237 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2238 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2239 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2240 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2241
2242 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2243
2244 # NOTE: anything using xcb or other client side libs ends up in separate
2245 #       _CLIENT variables.  The pipe loader is built in two variants,
2246 #       one that is standalone and does not link any x client libs (for
2247 #       use by XA tracker in particular, but could be used in any case
2248 #       where communication with xserver is not desired).
2249 if test "x$enable_gallium_loader" = xyes; then
2250     if test "x$NEED_WINSYS_XLIB" = xyes; then
2251         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2252     fi
2253
2254     if test "x$enable_dri" = xyes; then
2255         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2256     fi
2257
2258     if test "x$enable_gallium_drm_loader" = xyes; then
2259         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2260         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2261                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2262         if test "x$pipe_loader_have_xcb" = xyes; then
2263             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2264             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2265         fi
2266     fi
2267
2268     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2269     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2270
2271     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2272     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2273     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2274     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2275 fi
2276
2277 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2278 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2279 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2280 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2281 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2282 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2283
2284 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2285                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2286                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2287 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2288 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2289 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2290 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2291 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2292 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2293 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2294 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2295 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2296     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2297 fi
2298
2299 AC_SUBST([ELF_LIB])
2300
2301 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2302 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2303 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2304 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2305 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2306
2307 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2308 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2309 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2310
2311 AC_SUBST([NINE_MAJOR], 1)
2312 AC_SUBST([NINE_MINOR], 0)
2313 AC_SUBST([NINE_TINY], 0)
2314 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2315
2316 AC_SUBST([VDPAU_MAJOR], 1)
2317 AC_SUBST([VDPAU_MINOR], 0)
2318
2319 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2320 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2321 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2322 AC_SUBST([VA_MINOR], $VA_MINOR)
2323
2324 AC_SUBST([XVMC_MAJOR], 1)
2325 AC_SUBST([XVMC_MINOR], 0)
2326
2327 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2328 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2329 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2330 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2331
2332 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2333 AC_SUBST([XA_MINOR], $XA_MINOR)
2334 AC_SUBST([XA_TINY], $XA_TINY)
2335 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2336
2337 dnl Restore LDFLAGS and CPPFLAGS
2338 LDFLAGS="$_SAVE_LDFLAGS"
2339 CPPFLAGS="$_SAVE_CPPFLAGS"
2340
2341 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2342 if test "x$acv_mesa_CLANG" = xyes; then
2343     CFLAGS="$CFLAGS -Qunused-arguments"
2344     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2345 fi
2346
2347 dnl Add user CFLAGS and CXXFLAGS
2348 CFLAGS="$CFLAGS $USER_CFLAGS"
2349 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2350
2351 dnl Substitute the config
2352 AC_CONFIG_FILES([Makefile
2353                 src/Makefile
2354                 src/egl/drivers/dri2/Makefile
2355                 src/egl/main/Makefile
2356                 src/egl/main/egl.pc
2357                 src/egl/wayland/wayland-drm/Makefile
2358                 src/egl/wayland/wayland-egl/Makefile
2359                 src/egl/wayland/wayland-egl/wayland-egl.pc
2360                 src/gallium/Makefile
2361                 src/gallium/auxiliary/Makefile
2362                 src/gallium/auxiliary/pipe-loader/Makefile
2363                 src/gallium/drivers/freedreno/Makefile
2364                 src/gallium/drivers/i915/Makefile
2365                 src/gallium/drivers/ilo/Makefile
2366                 src/gallium/drivers/llvmpipe/Makefile
2367                 src/gallium/drivers/noop/Makefile
2368                 src/gallium/drivers/nouveau/Makefile
2369                 src/gallium/drivers/r300/Makefile
2370                 src/gallium/drivers/r600/Makefile
2371                 src/gallium/drivers/radeon/Makefile
2372                 src/gallium/drivers/radeonsi/Makefile
2373                 src/gallium/drivers/rbug/Makefile
2374                 src/gallium/drivers/softpipe/Makefile
2375                 src/gallium/drivers/svga/Makefile
2376                 src/gallium/drivers/trace/Makefile
2377                 src/gallium/drivers/vc4/Makefile
2378                 src/gallium/drivers/vc4/kernel/Makefile
2379                 src/gallium/state_trackers/clover/Makefile
2380                 src/gallium/state_trackers/dri/Makefile
2381                 src/gallium/state_trackers/glx/xlib/Makefile
2382                 src/gallium/state_trackers/nine/Makefile
2383                 src/gallium/state_trackers/omx/Makefile
2384                 src/gallium/state_trackers/osmesa/Makefile
2385                 src/gallium/state_trackers/va/Makefile
2386                 src/gallium/state_trackers/vdpau/Makefile
2387                 src/gallium/state_trackers/xa/Makefile
2388                 src/gallium/state_trackers/xvmc/Makefile
2389                 src/gallium/targets/d3dadapter9/Makefile
2390                 src/gallium/targets/d3dadapter9/d3d.pc
2391                 src/gallium/targets/dri/Makefile
2392                 src/gallium/targets/libgl-xlib/Makefile
2393                 src/gallium/targets/omx/Makefile
2394                 src/gallium/targets/opencl/Makefile
2395                 src/gallium/targets/osmesa/Makefile
2396                 src/gallium/targets/osmesa/osmesa.pc
2397                 src/gallium/targets/pipe-loader/Makefile
2398                 src/gallium/targets/va/Makefile
2399                 src/gallium/targets/vdpau/Makefile
2400                 src/gallium/targets/xa/Makefile
2401                 src/gallium/targets/xa/xatracker.pc
2402                 src/gallium/targets/xvmc/Makefile
2403                 src/gallium/tests/trivial/Makefile
2404                 src/gallium/tests/unit/Makefile
2405                 src/gallium/winsys/freedreno/drm/Makefile
2406                 src/gallium/winsys/i915/drm/Makefile
2407                 src/gallium/winsys/intel/drm/Makefile
2408                 src/gallium/winsys/nouveau/drm/Makefile
2409                 src/gallium/winsys/radeon/drm/Makefile
2410                 src/gallium/winsys/svga/drm/Makefile
2411                 src/gallium/winsys/sw/dri/Makefile
2412                 src/gallium/winsys/sw/kms-dri/Makefile
2413                 src/gallium/winsys/sw/null/Makefile
2414                 src/gallium/winsys/sw/wrapper/Makefile
2415                 src/gallium/winsys/sw/xlib/Makefile
2416                 src/gallium/winsys/vc4/drm/Makefile
2417                 src/gbm/Makefile
2418                 src/gbm/main/gbm.pc
2419                 src/glsl/Makefile
2420                 src/glx/Makefile
2421                 src/glx/apple/Makefile
2422                 src/glx/tests/Makefile
2423                 src/gtest/Makefile
2424                 src/loader/Makefile
2425                 src/mapi/Makefile
2426                 src/mapi/es1api/glesv1_cm.pc
2427                 src/mapi/es2api/glesv2.pc
2428                 src/mapi/glapi/gen/Makefile
2429                 src/mesa/Makefile
2430                 src/mesa/gl.pc
2431                 src/mesa/drivers/dri/dri.pc
2432                 src/mesa/drivers/dri/common/Makefile
2433                 src/mesa/drivers/dri/common/xmlpool/Makefile
2434                 src/mesa/drivers/dri/i915/Makefile
2435                 src/mesa/drivers/dri/i965/Makefile
2436                 src/mesa/drivers/dri/Makefile
2437                 src/mesa/drivers/dri/nouveau/Makefile
2438                 src/mesa/drivers/dri/r200/Makefile
2439                 src/mesa/drivers/dri/radeon/Makefile
2440                 src/mesa/drivers/dri/swrast/Makefile
2441                 src/mesa/drivers/osmesa/Makefile
2442                 src/mesa/drivers/osmesa/osmesa.pc
2443                 src/mesa/drivers/x11/Makefile
2444                 src/mesa/main/tests/Makefile
2445                 src/util/Makefile
2446                 src/util/tests/hash_table/Makefile])
2447
2448 AC_OUTPUT
2449
2450 dnl
2451 dnl Output some configuration info for the user
2452 dnl
2453 echo ""
2454 echo "        prefix:          $prefix"
2455 echo "        exec_prefix:     $exec_prefix"
2456 echo "        libdir:          $libdir"
2457 echo "        includedir:      $includedir"
2458
2459 dnl API info
2460 echo ""
2461 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2462
2463 dnl Driver info
2464 echo ""
2465 case "x$enable_osmesa$enable_gallium_osmesa" in
2466 xnoyes)
2467         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2468         ;;
2469 xyesno)
2470         echo "        OSMesa:          lib$OSMESA_LIB"
2471         ;;
2472 xnono)
2473         echo "        OSMesa:          no"
2474         ;;
2475 esac
2476
2477 echo ""
2478 if test "x$enable_dri" != xno; then
2479         echo "        DRI platform:    $dri_platform"
2480         if test -z "$DRI_DIRS"; then
2481             echo "        DRI drivers:     no"
2482         else
2483             echo "        DRI drivers:     $DRI_DIRS"
2484         fi
2485         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2486 fi
2487
2488 case "x$enable_glx$enable_xlib_glx" in
2489 xyesyes)
2490     echo "        GLX:             Xlib-based"
2491     ;;
2492 xyesno)
2493     echo "        GLX:             DRI-based"
2494     ;;
2495 *)
2496     echo "        GLX:             $enable_glx"
2497     ;;
2498 esac
2499
2500 dnl EGL
2501 echo ""
2502 echo "        EGL:             $enable_egl"
2503 if test "$enable_egl" = yes; then
2504     echo "        EGL platforms:   $egl_platforms"
2505
2506     egl_drivers=""
2507     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2508         egl_drivers="$egl_drivers builtin:egl_dri2"
2509     fi
2510
2511     echo "        EGL drivers:    $egl_drivers"
2512 fi
2513
2514 echo ""
2515 if test "x$MESA_LLVM" = x1; then
2516     echo "        llvm:            yes"
2517     echo "        llvm-config:     $LLVM_CONFIG"
2518     echo "        llvm-version:    $LLVM_VERSION"
2519 else
2520     echo "        llvm:            no"
2521 fi
2522
2523 echo ""
2524 if test -n "$with_gallium_drivers"; then
2525     echo "        Gallium:         yes"
2526 else
2527     echo "        Gallium:         no"
2528 fi
2529
2530 dnl Shader cache
2531 echo ""
2532 echo "        Shader cache:    $enable_shader_cache"
2533 if test "x$enable_shader_cache" = "xyes"; then
2534     echo "        With SHA1 from:  $with_sha1"
2535 fi
2536
2537 dnl Libraries
2538 echo ""
2539 echo "        Shared libs:     $enable_shared"
2540 echo "        Static libs:     $enable_static"
2541 echo "        Shared-glapi:    $enable_shared_glapi"
2542
2543 dnl Compiler options
2544 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2545 cflags=`echo $CFLAGS | \
2546     $SED 's/^ *//;s/  */ /;s/ *$//'`
2547 cxxflags=`echo $CXXFLAGS | \
2548     $SED 's/^ *//;s/  */ /;s/ *$//'`
2549 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2550 echo ""
2551 echo "        CFLAGS:          $cflags"
2552 echo "        CXXFLAGS:        $cxxflags"
2553 echo "        Macros:          $defines"
2554 echo ""
2555 if test "x$MESA_LLVM" = x1; then
2556     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2557     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2558     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2559     echo ""
2560 fi
2561 echo "        PYTHON2:         $PYTHON2"
2562
2563 echo ""
2564 echo "        Run '${MAKE-make}' to build Mesa"
2565 echo ""