configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.60
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.61
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126
 127 if test -z "$PYTHON2"; then
 128     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 129         AC_MSG_ERROR([Python not found - unable to generate sources])
 130     fi
 131 else
 132     if test "x$acv_mako_found" = xno; then
 133         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 134             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 135         fi
 136     fi
 137 fi
 138
 139 AC_PROG_INSTALL
 140
 141 dnl We need a POSIX shell for parts of the build. Assume we have one
 142 dnl in most cases.
 143 case "$host_os" in
 144 solaris*)
 145     # Solaris /bin/sh is too old/non-POSIX compliant
 146     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 147     SHELL="$POSIX_SHELL"
 148     ;;
 149 esac
 150
 151 dnl clang is mostly GCC-compatible, but its version is much lower,
 152 dnl so we have to check for it.
 153 AC_MSG_CHECKING([if compiling with clang])
 154
 155 AC_COMPILE_IFELSE(
 156 [AC_LANG_PROGRAM([], [[
 157 #ifndef __clang__
 158        not clang
 159 #endif
 160 ]])],
 161 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 162
 163 AC_MSG_RESULT([$acv_mesa_CLANG])
 164
 165 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 166 dnl versions are explictly not supported.
 167 GEN_ASM_OFFSETS=no
 168 USE_GNU99=no
 169 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 170     AC_MSG_CHECKING([whether gcc version is sufficient])
 171     major=0
 172     minor=0
 173
 174     GCC_VERSION=`$CC -dumpversion`
 175     if test $? -eq 0; then
 176         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 177         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 178     fi
 179
 180     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 181         AC_MSG_RESULT([no])
 182         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 183     else
 184         AC_MSG_RESULT([yes])
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 188         USE_GNU99=yes
 189     fi
 190     if test "x$cross_compiling" = xyes; then
 191         GEN_ASM_OFFSETS=yes
 192     fi
 193 fi
 194
 195 dnl Check for compiler builtins
 196 AX_GCC_BUILTIN([__builtin_bswap32])
 197 AX_GCC_BUILTIN([__builtin_bswap64])
 198 AX_GCC_BUILTIN([__builtin_clz])
 199 AX_GCC_BUILTIN([__builtin_clzll])
 200 AX_GCC_BUILTIN([__builtin_ctz])
 201 AX_GCC_BUILTIN([__builtin_expect])
 202 AX_GCC_BUILTIN([__builtin_ffs])
 203 AX_GCC_BUILTIN([__builtin_ffsll])
 204 AX_GCC_BUILTIN([__builtin_popcount])
 205 AX_GCC_BUILTIN([__builtin_popcountll])
 206 AX_GCC_BUILTIN([__builtin_unreachable])
 207
 208 AX_GCC_FUNC_ATTRIBUTE([const])
 209 AX_GCC_FUNC_ATTRIBUTE([flatten])
 210 AX_GCC_FUNC_ATTRIBUTE([format])
 211 AX_GCC_FUNC_ATTRIBUTE([malloc])
 212 AX_GCC_FUNC_ATTRIBUTE([packed])
 213 AX_GCC_FUNC_ATTRIBUTE([pure])
 214 AX_GCC_FUNC_ATTRIBUTE([unused])
 215 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 216
 217 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 218
 219 dnl Make sure the pkg-config macros are defined
 220 m4_ifndef([PKG_PROG_PKG_CONFIG],
 221     [m4_fatal([Could not locate the pkg-config autoconf macros.
 222   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 223   are in a different location, try setting the environment variable
 224   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 225 PKG_PROG_PKG_CONFIG()
 226
 227 dnl LIB_DIR - library basename
 228 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 229 AC_SUBST([LIB_DIR])
 230
 231 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 232 _SAVE_LDFLAGS="$LDFLAGS"
 233 _SAVE_CPPFLAGS="$CPPFLAGS"
 234
 235 dnl Compiler macros
 236 DEFINES=""
 237 AC_SUBST([DEFINES])
 238 case "$host_os" in
 239 linux*|*-gnu*|gnu*)
 240     DEFINES="$DEFINES -D_GNU_SOURCE"
 241     ;;
 242 solaris*)
 243     DEFINES="$DEFINES -DSVR4"
 244     ;;
 245 cygwin*)
 246     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 247     ;;
 248 esac
 249
 250 dnl Add flags for gcc and g++
 251 if test "x$GCC" = xyes; then
 252     CFLAGS="$CFLAGS -Wall"
 253
 254     if test "x$USE_GNU99" = xyes; then
 255         CFLAGS="$CFLAGS -std=gnu99"
 256     else
 257         CFLAGS="$CFLAGS -std=c99"
 258     fi
 259
 260     # Enable -Werror=implicit-function-declaration and
 261     # -Werror=missing-prototypes, if available, or otherwise, just
 262     # -Wmissing-prototypes.  This is particularly useful to avoid
 263     # generating a loadable driver module that has undefined symbols.
 264     save_CFLAGS="$CFLAGS"
 265     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 266     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 267     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 268     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 269                    AC_MSG_RESULT([yes]),
 270                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 271                     AC_MSG_RESULT([no])]);
 272
 273     # Enable -fvisibility=hidden if using a gcc that supports it
 274     save_CFLAGS="$CFLAGS"
 275     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 276     VISIBILITY_CFLAGS="-fvisibility=hidden"
 277     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 278     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 279                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 280
 281     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 282     CFLAGS=$save_CFLAGS
 283
 284     # Work around aliasing bugs - developers should comment this out
 285     CFLAGS="$CFLAGS -fno-strict-aliasing"
 286
 287     # gcc's builtin memcmp is slower than glibc's
 288     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 289     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 290
 291     # Flags to help ensure that certain portions of the code -- and only those
 292     # portions -- can be built with MSVC:
 293     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 294     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 295     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 296     #   supports most of C99)
 297     # - the rest has no compiler compiler restrictions
 298     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 299     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 300
 301     # Enable -Werror=vla if compiler supports it
 302     save_CFLAGS="$CFLAGS"
 303     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 304     CFLAGS="$CFLAGS -Werror=vla"
 305     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 306                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 307                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 308                     AC_MSG_RESULT([yes])],
 309                     AC_MSG_RESULT([no]));
 310     CFLAGS="$save_CFLAGS"
 311
 312     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 313     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 314 fi
 315 if test "x$GXX" = xyes; then
 316     CXXFLAGS="$CXXFLAGS -Wall"
 317
 318     # Enable -fvisibility=hidden if using a gcc that supports it
 319     save_CXXFLAGS="$CXXFLAGS"
 320     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 321     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 322     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 323     AC_LANG_PUSH([C++])
 324     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 325                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 326     AC_LANG_POP([C++])
 327
 328     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 329     CXXFLAGS=$save_CXXFLAGS
 330
 331     # Work around aliasing bugs - developers should comment this out
 332     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 333
 334     # gcc's builtin memcmp is slower than glibc's
 335     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 336     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 337 fi
 338
 339 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 340 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 341 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 342 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 343
 344 dnl even if the compiler appears to support it, using visibility attributes isn't
 345 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 346 case "$host_os" in
 347 cygwin*)
 348     VISIBILITY_CFLAGS=""
 349     VISIBILITY_CXXFLAGS=""
 350     ;;
 351 esac
 352
 353 AC_SUBST([VISIBILITY_CFLAGS])
 354 AC_SUBST([VISIBILITY_CXXFLAGS])
 355
 356 dnl
 357 dnl Optional flags, check for compiler support
 358 dnl
 359 SSE41_CFLAGS="-msse4.1"
 360 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 361 dnl stack, but on x86-32 such alignment is not guaranteed.
 362 case "$target_cpu" in
 363 i?86)
 364     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 365     ;;
 366 esac
 367 save_CFLAGS="$CFLAGS"
 368 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 369 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 370 #include <smmintrin.h>
 371 int main () {
 372     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 373     c = _mm_max_epu32(a, b);
 374     return 0;
 375 }]])], SSE41_SUPPORTED=1)
 376 CFLAGS="$save_CFLAGS"
 377 if test "x$SSE41_SUPPORTED" = x1; then
 378     DEFINES="$DEFINES -DUSE_SSE41"
 379 fi
 380 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 381 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 382
 383 dnl Can't have static and shared libraries, default to static if user
 384 dnl explicitly requested. If both disabled, set to static since shared
 385 dnl was explicitly requested.
 386 case "x$enable_static$enable_shared" in
 387 xyesyes)
 388     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 389     enable_shared=no
 390     ;;
 391 xnono)
 392     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 393     enable_shared=yes
 394     ;;
 395 esac
 396
 397 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 398
 399 dnl
 400 dnl other compiler options
 401 dnl
 402 AC_ARG_ENABLE([debug],
 403     [AS_HELP_STRING([--enable-debug],
 404         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 405     [enable_debug="$enableval"],
 406     [enable_debug=no]
 407 )
 408 if test "x$enable_debug" = xyes; then
 409     DEFINES="$DEFINES -DDEBUG"
 410     if test "x$GCC" = xyes; then
 411         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 412             CFLAGS="$CFLAGS -g"
 413         fi
 414         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 415             CFLAGS="$CFLAGS -O0"
 416         fi
 417     fi
 418     if test "x$GXX" = xyes; then
 419         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 420             CXXFLAGS="$CXXFLAGS -g"
 421         fi
 422         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 423             CXXFLAGS="$CXXFLAGS -O0"
 424         fi
 425     fi
 426 else
 427    DEFINES="$DEFINES -DNDEBUG"
 428 fi
 429
 430 dnl
 431 dnl Check if linker supports -Bsymbolic
 432 dnl
 433 save_LDFLAGS=$LDFLAGS
 434 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 435 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 436 AC_LINK_IFELSE(
 437     [AC_LANG_SOURCE([int main() { return 0;}])],
 438     [AC_MSG_RESULT([yes])
 439         BSYMBOLIC="-Wl,-Bsymbolic";],
 440     [AC_MSG_RESULT([no])
 441         BSYMBOLIC="";])
 442 LDFLAGS=$save_LDFLAGS
 443
 444 AC_SUBST([BSYMBOLIC])
 445
 446 dnl
 447 dnl Check if linker supports garbage collection
 448 dnl
 449 save_LDFLAGS=$LDFLAGS
 450 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 451 AC_MSG_CHECKING([whether ld supports --gc-sections])
 452 AC_LINK_IFELSE(
 453     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 454     [AC_MSG_RESULT([yes])
 455         GC_SECTIONS="-Wl,--gc-sections";],
 456     [AC_MSG_RESULT([no])
 457         GC_SECTIONS="";])
 458 LDFLAGS=$save_LDFLAGS
 459
 460 AC_SUBST([GC_SECTIONS])
 461
 462 dnl
 463 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 464 dnl so when these flags are passed to ld via libtool the checks will fail
 465 dnl
 466 case "$host_os" in
 467 openbsd* | darwin* )
 468     LD_NO_UNDEFINED="" ;;
 469 *)
 470     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 471 esac
 472
 473 AC_SUBST([LD_NO_UNDEFINED])
 474
 475 dnl
 476 dnl Check if linker supports version scripts
 477 dnl
 478 AC_MSG_CHECKING([if the linker supports version-scripts])
 479 save_LDFLAGS=$LDFLAGS
 480 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 481 cat > conftest.map <<EOF
 482 VERSION_1 {
 483      global:
 484          main;
 485
 486      local:
 487          *;
 488 };
 489 EOF
 490 AC_LINK_IFELSE(
 491     [AC_LANG_SOURCE([int main() { return 0;}])],
 492     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 493     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 494 LDFLAGS=$save_LDFLAGS
 495 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 496
 497 dnl
 498 dnl Check if linker supports dynamic list files
 499 dnl
 500 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 501 save_LDFLAGS=$LDFLAGS
 502 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 503 cat > conftest.dyn <<EOF
 504 {
 505         radeon_drm_winsys_create;
 506 };
 507 EOF
 508 AC_LINK_IFELSE(
 509     [AC_LANG_SOURCE([int main() { return 0;}])],
 510     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 511     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 512 LDFLAGS=$save_LDFLAGS
 513 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 514
 515 dnl
 516 dnl compatibility symlinks
 517 dnl
 518 case "$host_os" in
 519 linux* )
 520     HAVE_COMPAT_SYMLINKS=yes ;;
 521 * )
 522     HAVE_COMPAT_SYMLINKS=no ;;
 523 esac
 524
 525 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 526
 527 dnl
 528 dnl library names
 529 dnl
 530 case "$host_os" in
 531 darwin* )
 532     LIB_EXT='dylib' ;;
 533 cygwin* )
 534     LIB_EXT='dll' ;;
 535 aix* )
 536     LIB_EXT='a' ;;
 537 * )
 538     LIB_EXT='so' ;;
 539 esac
 540
 541 AC_SUBST([LIB_EXT])
 542
 543 AC_ARG_WITH([gl-lib-name],
 544   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 545     [specify GL library name @<:@default=GL@:>@])],
 546   [GL_LIB=$withval],
 547   [GL_LIB=GL])
 548 AC_ARG_WITH([osmesa-lib-name],
 549   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 550     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 551   [OSMESA_LIB=$withval],
 552   [OSMESA_LIB=OSMesa])
 553 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 554 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 555
 556 dnl
 557 dnl Mangled Mesa support
 558 dnl
 559 AC_ARG_ENABLE([mangling],
 560   [AS_HELP_STRING([--enable-mangling],
 561     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 562   [enable_mangling="${enableval}"],
 563   [enable_mangling=no]
 564 )
 565 if test "x${enable_mangling}" = "xyes" ; then
 566   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 567   GL_LIB="Mangled${GL_LIB}"
 568   OSMESA_LIB="Mangled${OSMESA_LIB}"
 569 fi
 570 AC_SUBST([GL_LIB])
 571 AC_SUBST([OSMESA_LIB])
 572
 573 dnl
 574 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 575 dnl
 576 AC_ARG_ENABLE([texture-float],
 577     [AS_HELP_STRING([--enable-texture-float],
 578         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 579     [enable_texture_float="$enableval"],
 580     [enable_texture_float=no]
 581 )
 582 if test "x$enable_texture_float" = xyes; then
 583     AC_MSG_WARN([Floating-point textures enabled.])
 584     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 585     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 586 fi
 587
 588 dnl
 589 dnl Arch/platform-specific settings
 590 dnl
 591 AC_ARG_ENABLE([asm],
 592     [AS_HELP_STRING([--disable-asm],
 593         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 594     [enable_asm="$enableval"],
 595     [enable_asm=yes]
 596 )
 597 asm_arch=""
 598 AC_MSG_CHECKING([whether to enable assembly])
 599 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 600 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 601 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 602     case "$host_cpu" in
 603     i?86 | x86_64 | amd64)
 604         enable_asm=no
 605         AC_MSG_RESULT([no, cross compiling])
 606         ;;
 607     esac
 608 fi
 609 # check for supported arches
 610 if test "x$enable_asm" = xyes; then
 611     case "$host_cpu" in
 612     i?86)
 613         case "$host_os" in
 614         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 615             asm_arch=x86
 616             ;;
 617         esac
 618         ;;
 619     x86_64|amd64)
 620         case "$host_os" in
 621         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 622             asm_arch=x86_64
 623             ;;
 624         esac
 625         ;;
 626     sparc*)
 627         case "$host_os" in
 628         linux*)
 629             asm_arch=sparc
 630             ;;
 631         esac
 632         ;;
 633     esac
 634
 635     case "$asm_arch" in
 636     x86)
 637         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 638         AC_MSG_RESULT([yes, x86])
 639         ;;
 640     x86_64|amd64)
 641         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 642         AC_MSG_RESULT([yes, x86_64])
 643         ;;
 644     sparc)
 645         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 646         AC_MSG_RESULT([yes, sparc])
 647         ;;
 648     *)
 649         AC_MSG_RESULT([no, platform not supported])
 650         ;;
 651     esac
 652 fi
 653
 654 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 655 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 656 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 657 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 658
 659 dnl Check to see if dlopen is in default libraries (like Solaris, which
 660 dnl has it in libc), or if libdl is needed to get it.
 661 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 662     [AC_CHECK_LIB([dl], [dlopen],
 663        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 664 AC_SUBST([DLOPEN_LIBS])
 665
 666 dnl Check if that library also has dladdr
 667 save_LIBS="$LIBS"
 668 LIBS="$LIBS $DLOPEN_LIBS"
 669 AC_CHECK_FUNCS([dladdr])
 670 LIBS="$save_LIBS"
 671
 672 case "$host_os" in
 673 darwin*)
 674     ;;
 675 *)
 676     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 677                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 678                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 679     AC_SUBST([CLOCK_LIB])
 680     ;;
 681 esac
 682
 683 dnl See if posix_memalign is available
 684 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 685
 686 dnl Check for pthreads
 687 AX_PTHREAD
 688 if test "x$ax_pthread_ok" = xno; then
 689     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 690 fi
 691 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 692 dnl to -pthread, which causes problems if we need -lpthread to appear in
 693 dnl pkgconfig files.
 694 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 695
 696 dnl SELinux awareness.
 697 AC_ARG_ENABLE([selinux],
 698     [AS_HELP_STRING([--enable-selinux],
 699         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 700     [MESA_SELINUX="$enableval"],
 701     [MESA_SELINUX=no])
 702 if test "x$enable_selinux" = "xyes"; then
 703     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 704         [AC_CHECK_HEADER([selinux/selinux.h],[],
 705                          [AC_MSG_ERROR([SELinux headers not found])])
 706          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 707                       [AC_MSG_ERROR([SELinux library not found])])
 708          SELINUX_LIBS="-lselinux"])
 709     DEFINES="$DEFINES -DMESA_SELINUX"
 710 fi
 711 AC_SUBST([SELINUX_CFLAGS])
 712 AC_SUBST([SELINUX_LIBS])
 713
 714 dnl Options for APIs
 715 AC_ARG_ENABLE([opengl],
 716     [AS_HELP_STRING([--disable-opengl],
 717         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 718     [enable_opengl="$enableval"],
 719     [enable_opengl=yes])
 720 AC_ARG_ENABLE([gles1],
 721     [AS_HELP_STRING([--disable-gles1],
 722         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 723     [enable_gles1="$enableval"],
 724     [enable_gles1=yes])
 725 AC_ARG_ENABLE([gles2],
 726     [AS_HELP_STRING([--disable-gles2],
 727         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 728     [enable_gles2="$enableval"],
 729     [enable_gles2=yes])
 730
 731 AC_ARG_ENABLE([dri],
 732     [AS_HELP_STRING([--enable-dri],
 733         [enable DRI modules @<:@default=enabled@:>@])],
 734     [enable_dri="$enableval"],
 735     [enable_dri=yes])
 736
 737 case "$host_os" in
 738 linux*)
 739     dri3_default=yes
 740     ;;
 741 *)
 742     dri3_default=no
 743     ;;
 744 esac
 745 AC_ARG_ENABLE([dri3],
 746     [AS_HELP_STRING([--enable-dri3],
 747         [enable DRI3 @<:@default=auto@:>@])],
 748     [enable_dri3="$enableval"],
 749     [enable_dri3="$dri3_default"])
 750 AC_ARG_ENABLE([glx],
 751     [AS_HELP_STRING([--enable-glx],
 752         [enable GLX library @<:@default=enabled@:>@])],
 753     [enable_glx="$enableval"],
 754     [enable_glx=yes])
 755 AC_ARG_ENABLE([osmesa],
 756     [AS_HELP_STRING([--enable-osmesa],
 757         [enable OSMesa library @<:@default=disabled@:>@])],
 758     [enable_osmesa="$enableval"],
 759     [enable_osmesa=no])
 760 AC_ARG_ENABLE([gallium-osmesa],
 761     [AS_HELP_STRING([--enable-gallium-osmesa],
 762         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 763     [enable_gallium_osmesa="$enableval"],
 764     [enable_gallium_osmesa=no])
 765 AC_ARG_ENABLE([egl],
 766     [AS_HELP_STRING([--disable-egl],
 767         [disable EGL library @<:@default=enabled@:>@])],
 768     [enable_egl="$enableval"],
 769     [enable_egl=yes])
 770
 771 AC_ARG_ENABLE([xa],
 772     [AS_HELP_STRING([--enable-xa],
 773         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 774     [enable_xa="$enableval"],
 775     [enable_xa=no])
 776 AC_ARG_ENABLE([gbm],
 777    [AS_HELP_STRING([--enable-gbm],
 778          [enable gbm library @<:@default=auto@:>@])],
 779    [enable_gbm="$enableval"],
 780    [enable_gbm=auto])
 781 AC_ARG_ENABLE([nine],
 782     [AS_HELP_STRING([--enable-nine],
 783         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 784     [enable_nine="$enableval"],
 785     [enable_nine=no])
 786
 787 AC_ARG_ENABLE([xvmc],
 788    [AS_HELP_STRING([--enable-xvmc],
 789          [enable xvmc library @<:@default=auto@:>@])],
 790    [enable_xvmc="$enableval"],
 791    [enable_xvmc=auto])
 792 AC_ARG_ENABLE([vdpau],
 793    [AS_HELP_STRING([--enable-vdpau],
 794          [enable vdpau library @<:@default=auto@:>@])],
 795    [enable_vdpau="$enableval"],
 796    [enable_vdpau=auto])
 797 AC_ARG_ENABLE([omx],
 798    [AS_HELP_STRING([--enable-omx],
 799          [enable OpenMAX library @<:@default=disabled@:>@])],
 800    [enable_omx="$enableval"],
 801    [enable_omx=no])
 802 AC_ARG_ENABLE([va],
 803    [AS_HELP_STRING([--enable-va],
 804          [enable va library @<:@default=auto@:>@])],
 805    [enable_va="$enableval"],
 806    [enable_va=auto])
 807 AC_ARG_ENABLE([opencl],
 808    [AS_HELP_STRING([--enable-opencl],
 809          [enable OpenCL library @<:@default=disabled@:>@])],
 810    [enable_opencl="$enableval"],
 811    [enable_opencl=no])
 812 AC_ARG_ENABLE([opencl_icd],
 813    [AS_HELP_STRING([--enable-opencl-icd],
 814           [Build an OpenCL ICD library to be loaded by an ICD implementation
 815            @<:@default=disabled@:>@])],
 816     [enable_opencl_icd="$enableval"],
 817     [enable_opencl_icd=no])
 818 AC_ARG_ENABLE([xlib-glx],
 819     [AS_HELP_STRING([--enable-xlib-glx],
 820         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 821     [enable_xlib_glx="$enableval"],
 822     [enable_xlib_glx=no])
 823
 824 AC_ARG_ENABLE([r600-llvm-compiler],
 825     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 826         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 827     [enable_r600_llvm="$enableval"],
 828     [enable_r600_llvm=no])
 829
 830 AC_ARG_ENABLE([gallium-tests],
 831     [AS_HELP_STRING([--enable-gallium-tests],
 832         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 833     [enable_gallium_tests="$enableval"],
 834     [enable_gallium_tests=no])
 835
 836 # Option for Gallium drivers
 837
 838 # Keep this in sync with the --with-gallium-drivers help string default value
 839 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 840
 841 AC_ARG_WITH([gallium-drivers],
 842     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 843         [comma delimited Gallium drivers list, e.g.
 844         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 845         @<:@default=r300,r600,svga,swrast@:>@])],
 846     [with_gallium_drivers="$withval"],
 847     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 848
 849 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 850 # here so that the script doesn't choke on an unknown driver name later.
 851 case "$with_gallium_drivers" in
 852     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 853     no) with_gallium_drivers='' ;;
 854 esac
 855
 856 if test "x$enable_opengl" = xno -a \
 857         "x$enable_gles1" = xno -a \
 858         "x$enable_gles2" = xno -a \
 859         "x$enable_nine" = xno -a \
 860         "x$enable_xa" = xno -a \
 861         "x$enable_xvmc" = xno -a \
 862         "x$enable_vdpau" = xno -a \
 863         "x$enable_omx" = xno -a \
 864         "x$enable_va" = xno -a \
 865         "x$enable_opencl" = xno; then
 866     AC_MSG_ERROR([at least one API should be enabled])
 867 fi
 868
 869 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 870 if test "x$enable_opengl" = xno -a \
 871         "x$enable_gles1" = xyes; then
 872     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 873 fi
 874
 875 if test "x$enable_opengl" = xno -a \
 876         "x$enable_gles2" = xyes; then
 877     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 878 fi
 879
 880 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 881 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 882 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 883 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 884                                         "x$enable_gles1" = xyes -o \
 885                                         "x$enable_gles2" = xyes)
 886
 887 if test "x$enable_glx" = xno; then
 888     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 889     enable_xlib_glx=no
 890 fi
 891
 892 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 893     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 894 fi
 895
 896 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 897     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 898 fi
 899
 900 # Disable GLX if OpenGL is not enabled
 901 if test "x$enable_glx$enable_opengl" = xyesno; then
 902     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 903     enable_glx=no
 904 fi
 905
 906 # Disable GLX if DRI and Xlib-GLX are not enabled
 907 if test "x$enable_glx" = xyes -a \
 908         "x$enable_dri" = xno -a \
 909         "x$enable_xlib_glx" = xno; then
 910     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 911     enable_glx=no
 912 fi
 913
 914 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 915                                   "x$enable_dri" = xyes)
 916
 917 # Check for libdrm
 918 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 919                   [have_libdrm=yes], [have_libdrm=no])
 920 if test "x$have_libdrm" = xyes; then
 921         DEFINES="$DEFINES -DHAVE_LIBDRM"
 922 fi
 923
 924 # Select which platform-dependent DRI code gets built
 925 case "$host_os" in
 926 darwin*)
 927     dri_platform='apple' ;;
 928 gnu*|cygwin*)
 929     dri_platform='none' ;;
 930 *)
 931     dri_platform='drm' ;;
 932 esac
 933
 934 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 935 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 936 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 937 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 938 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 939
 940 AC_ARG_ENABLE([shared-glapi],
 941     [AS_HELP_STRING([--enable-shared-glapi],
 942         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 943     [enable_shared_glapi="$enableval"],
 944     [enable_shared_glapi=yes])
 945
 946 case "x$enable_opengl$enable_gles1$enable_gles2" in
 947 x*yes*yes*)
 948     if test "x$enable_shared_glapi" = xno; then
 949         AC_MSG_ERROR([shared GLAPI required when building two or more of
 950                       the following APIs - opengl, gles1 gles2])
 951     fi
 952     ;;
 953 esac
 954
 955 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 956
 957 # Build the pipe-drivers as separate libraries/modules.
 958 # Do not touch this unless you know what you are doing.
 959 # XXX: Expose via configure option ?
 960 enable_shared_pipe_drivers=no
 961
 962 dnl
 963 dnl Driver specific build directories
 964 dnl
 965
 966 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
 967     NEED_WINSYS_XLIB="yes"
 968 fi
 969
 970 if test "x$enable_dri" = xyes; then
 971     enable_gallium_loader="$enable_shared_pipe_drivers"
 972 fi
 973
 974 if test "x$enable_gallium_osmesa" = xyes; then
 975     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 976         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 977     fi
 978     if test "x$enable_osmesa" = xyes; then
 979         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 980     fi
 981 fi
 982
 983 AC_SUBST([MESA_LLVM])
 984
 985 # SHA1 hashing
 986 AC_ARG_WITH([sha1],
 987         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 988         [choose SHA1 implementation])])
 989 case "x$with_sha1" in
 990 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 991   ;;
 992 *)
 993         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 994 esac
 995
 996 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 997 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 998         with_sha1=libc
 999 fi
1000 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1001         AC_MSG_ERROR([sha1 in libc requested but not found])
1002 fi
1003 if test "x$with_sha1" = xlibc; then
1004         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1005                 [Use libc SHA1 functions])
1006         SHA1_LIBS=""
1007 fi
1008 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1009 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1010         with_sha1=CommonCrypto
1011 fi
1012 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1013         AC_MSG_ERROR([CommonCrypto requested but not found])
1014 fi
1015 if test "x$with_sha1" = xCommonCrypto; then
1016         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1017                 [Use CommonCrypto SHA1 functions])
1018         SHA1_LIBS=""
1019 fi
1020 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1021 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1022 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1023         with_sha1=CryptoAPI
1024 fi
1025 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1026         AC_MSG_ERROR([CryptoAPI requested but not found])
1027 fi
1028 if test "x$with_sha1" = xCryptoAPI; then
1029         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1030                 [Use CryptoAPI SHA1 functions])
1031         SHA1_LIBS=""
1032 fi
1033 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1034 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1035         with_sha1=libmd
1036 fi
1037 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1038         AC_MSG_ERROR([libmd requested but not found])
1039 fi
1040 if test "x$with_sha1" = xlibmd; then
1041         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1042                   [Use libmd SHA1 functions])
1043         SHA1_LIBS=-lmd
1044 fi
1045 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1046 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1047    with_sha1=libsha1
1048 fi
1049 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1050         AC_MSG_ERROR([libsha1 requested but not found])
1051 fi
1052 if test "x$with_sha1" = xlibsha1; then
1053         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1054                   [Use libsha1 for SHA1])
1055         SHA1_LIBS=-lsha1
1056 fi
1057 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1058 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1059         with_sha1=libnettle
1060 fi
1061 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1062         AC_MSG_ERROR([libnettle requested but not found])
1063 fi
1064 if test "x$with_sha1" = xlibnettle; then
1065         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1066                   [Use libnettle SHA1 functions])
1067         SHA1_LIBS=-lnettle
1068 fi
1069 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1070 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1071         with_sha1=libgcrypt
1072 fi
1073 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1074         AC_MSG_ERROR([libgcrypt requested but not found])
1075 fi
1076 if test "x$with_sha1" = xlibgcrypt; then
1077         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1078                   [Use libgcrypt SHA1 functions])
1079         SHA1_LIBS=-lgcrypt
1080 fi
1081 # We don't need all of the OpenSSL libraries, just libcrypto
1082 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1083 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1084                   [HAVE_OPENSSL_PKC=no])
1085 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1086         if test "x$with_sha1" = x; then
1087                 with_sha1=libcrypto
1088         fi
1089 else
1090         if test "x$with_sha1" = xlibcrypto; then
1091                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1092         fi
1093 fi
1094 if test "x$with_sha1" = xlibcrypto; then
1095         if test "x$HAVE_LIBCRYPTO" = xyes; then
1096                 SHA1_LIBS=-lcrypto
1097         else
1098                 SHA1_LIBS="$OPENSSL_LIBS"
1099                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1100         fi
1101 fi
1102 AC_MSG_CHECKING([for SHA1 implementation])
1103 AC_MSG_RESULT([$with_sha1])
1104 AC_SUBST(SHA1_LIBS)
1105 AC_SUBST(SHA1_CFLAGS)
1106
1107 # Allow user to configure out the shader-cache feature
1108 AC_ARG_ENABLE([shader-cache],
1109     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1110     [enable_shader_cache="$enableval"],
1111     [if test "x$with_sha1" != "x"; then
1112         enable_shader_cache=yes
1113      else
1114         enable_shader_cache=no
1115      fi])
1116 if test "x$with_sha1" = "x"; then
1117     if test "x$enable_shader_cache" = "xyes"; then
1118         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1119     fi
1120 fi
1121 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1122
1123 case "$host_os" in
1124 linux*)
1125     need_pci_id=yes ;;
1126 *)
1127     need_pci_id=no ;;
1128 esac
1129
1130 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1131                   have_libudev=yes, have_libudev=no)
1132
1133 AC_ARG_ENABLE([sysfs],
1134     [AS_HELP_STRING([--enable-sysfs],
1135         [enable /sys PCI identification @<:@default=disabled@:>@])],
1136     [have_sysfs="$enableval"],
1137     [have_sysfs=no]
1138 )
1139
1140 if test "x$enable_dri" = xyes; then
1141     if test "$enable_static" = yes; then
1142         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1143     fi
1144
1145     # not a hard requirement as swrast does not depend on it
1146     if test "x$have_libdrm" = xyes; then
1147         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1148     fi
1149 fi
1150
1151 AC_ARG_ENABLE([driglx-direct],
1152     [AS_HELP_STRING([--disable-driglx-direct],
1153         [disable direct rendering in GLX and EGL for DRI \
1154             @<:@default=auto@:>@])],
1155     [driglx_direct="$enableval"],
1156     [driglx_direct="yes"])
1157
1158 dnl
1159 dnl libGL configuration per driver
1160 dnl
1161 case "x$enable_glx$enable_xlib_glx" in
1162 xyesyes)
1163     # Xlib-based GLX
1164     dri_modules="x11 xext xcb"
1165     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1166     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1167     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1168     GL_LIB_DEPS="$XLIBGL_LIBS"
1169     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1170     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1171     ;;
1172 xyesno)
1173     # DRI-based GLX
1174     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1175
1176     # find the DRI deps for libGL
1177     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1178
1179     if test x"$driglx_direct" = xyes; then
1180         if test x"$dri_platform" = xdrm ; then
1181             DEFINES="$DEFINES -DGLX_USE_DRM"
1182             if test "x$have_libdrm" != xyes; then
1183                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1184             fi
1185
1186             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1187             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1188             if test x"$enable_dri3" = xyes; then
1189                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1190                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1191             fi
1192
1193             if test x"$enable_dri" = xyes; then
1194                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1195             fi
1196
1197             if test x"$enable_dri3" = xyes; then
1198                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1199                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1200             fi
1201         fi
1202         if test x"$dri_platform" = xapple ; then
1203             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1204         fi
1205     fi
1206
1207     # add xf86vidmode if available
1208     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1209     if test "$HAVE_XF86VIDMODE" = yes ; then
1210         dri_modules="$dri_modules xxf86vm"
1211     fi
1212
1213     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1214     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1215     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1216     GL_LIB_DEPS="$DRIGL_LIBS"
1217
1218     # need DRM libs, $PTHREAD_LIBS, etc.
1219     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1220     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1221     ;;
1222 esac
1223
1224 have_pci_id=no
1225 if test "$have_libudev" = yes; then
1226     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1227     have_pci_id=yes
1228 fi
1229
1230 if test "$have_sysfs" = yes; then
1231     DEFINES="$DEFINES -DHAVE_SYSFS"
1232     have_pci_id=yes
1233 fi
1234
1235 # This is outside the case (above) so that it is invoked even for non-GLX
1236 # builds.
1237 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1238
1239 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1240 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1241 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1242 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1243
1244 AC_SUBST([X11_INCLUDES])
1245 AC_SUBST([GL_LIB_DEPS])
1246 AC_SUBST([GL_PC_REQ_PRIV])
1247 AC_SUBST([GL_PC_LIB_PRIV])
1248 AC_SUBST([GL_PC_CFLAGS])
1249 AC_SUBST([DRI_PC_REQ_PRIV])
1250 AC_SUBST([GLESv1_CM_LIB_DEPS])
1251 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1252 AC_SUBST([GLESv2_LIB_DEPS])
1253 AC_SUBST([GLESv2_PC_LIB_PRIV])
1254
1255 AC_SUBST([HAVE_XF86VIDMODE])
1256
1257 dnl
1258 dnl More GLX setup
1259 dnl
1260 case "x$enable_glx$enable_xlib_glx" in
1261 xyesyes)
1262     DEFINES="$DEFINES -DUSE_XSHM"
1263     ;;
1264 xyesno)
1265     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1266     if test "x$driglx_direct" = xyes; then
1267         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1268     fi
1269     ;;
1270 esac
1271
1272 dnl
1273 dnl TLS detection
1274 dnl
1275
1276 AC_ARG_ENABLE([glx-tls],
1277     [AS_HELP_STRING([--enable-glx-tls],
1278         [enable TLS support in GLX @<:@default=disabled@:>@])],
1279     [GLX_USE_TLS="$enableval"],
1280     [GLX_USE_TLS=no])
1281 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1282
1283 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1284       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1285
1286 dnl
1287 dnl More DRI setup
1288 dnl
1289 dnl Directory for DRI drivers
1290 AC_ARG_WITH([dri-driverdir],
1291     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1292         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1293     [DRI_DRIVER_INSTALL_DIR="$withval"],
1294     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1295 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1296 dnl Extra search path for DRI drivers
1297 AC_ARG_WITH([dri-searchpath],
1298     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1299         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1300     [DRI_DRIVER_SEARCH_DIR="$withval"],
1301     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1302 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1303 dnl Which drivers to build - default is chosen by platform
1304 AC_ARG_WITH([dri-drivers],
1305     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1306         [comma delimited classic DRI drivers list, e.g.
1307         "swrast,i965,radeon" @<:@default=auto@:>@])],
1308     [with_dri_drivers="$withval"],
1309     [with_dri_drivers=auto])
1310
1311 if test "x$with_dri_drivers" = xauto; then
1312     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1313         with_dri_drivers="yes"
1314     else
1315         with_dri_drivers="no"
1316     fi
1317 fi
1318 if test "x$with_dri_drivers" = xno; then
1319     with_dri_drivers=''
1320 fi
1321
1322 dnl If $with_dri_drivers is yes, drivers will be added through
1323 dnl platform checks. Set DEFINES and LIB_DEPS
1324 if test "x$enable_dri" = xyes; then
1325     # Platform specific settings and drivers to build
1326     case "$host_os" in
1327     linux*)
1328         DEFINES="$DEFINES -DHAVE_ALIAS"
1329         if test "x$enable_dri3" = xyes; then
1330             DEFINES="$DEFINES -DHAVE_DRI3"
1331         fi
1332
1333         if test "x$have_pci_id" != xyes; then
1334             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1335         fi
1336
1337         case "$host_cpu" in
1338         powerpc* | sparc*)
1339             # Build only the drivers for cards that exist on PowerPC/sparc
1340             if test "x$with_dri_drivers" = "xyes"; then
1341                 with_dri_drivers="r200 radeon swrast"
1342             fi
1343             ;;
1344         esac
1345         ;;
1346     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1347         DEFINES="$DEFINES -DHAVE_ALIAS"
1348         ;;
1349     gnu*)
1350         DEFINES="$DEFINES -DHAVE_ALIAS"
1351         ;;
1352     cygwin*)
1353         if test "x$with_dri_drivers" = "xyes"; then
1354             with_dri_drivers="swrast"
1355         fi
1356         ;;
1357     darwin*)
1358         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1359         if test "x$with_dri_drivers" = "xyes"; then
1360             with_dri_drivers="swrast"
1361         fi
1362         ;;
1363     esac
1364
1365     # default drivers
1366     if test "x$with_dri_drivers" = "xyes"; then
1367         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1368     fi
1369
1370     # Check for expat
1371     PKG_CHECK_MODULES([EXPAT], [expat], [],
1372         # expat version 2.0 and earlier do not provide expat.pc
1373         [AC_CHECK_HEADER([expat.h],[],
1374                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1375          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1376                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1377          EXPAT_LIBS="-lexpat"])
1378
1379     # put all the necessary libs together
1380     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1381 fi
1382
1383 AC_SUBST([DRI_LIB_DEPS])
1384
1385 DRI_DIRS=''
1386 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1387 if test -n "$with_dri_drivers"; then
1388     if test "x$enable_opengl" != xyes; then
1389         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1390     fi
1391
1392     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1393     for driver in $dri_drivers; do
1394         DRI_DIRS="$DRI_DIRS $driver"
1395         case "x$driver" in
1396         xi915)
1397             HAVE_I915_DRI=yes;
1398             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1399             ;;
1400         xi965)
1401             HAVE_I965_DRI=yes;
1402             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1403             ;;
1404         xnouveau)
1405             HAVE_NOUVEAU_DRI=yes;
1406             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1407             ;;
1408         xradeon)
1409             HAVE_RADEON_DRI=yes;
1410             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1411             ;;
1412         xr200)
1413             HAVE_R200_DRI=yes;
1414             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1415             ;;
1416         xswrast)
1417             HAVE_SWRAST_DRI=yes;
1418             ;;
1419         *)
1420             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1421             ;;
1422         esac
1423     done
1424     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1425 fi
1426
1427 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1428 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1429                                   "x$enable_osmesa" = xyes -o \
1430                                   -n "$DRI_DIRS")
1431
1432 dnl
1433 dnl OSMesa configuration
1434 dnl
1435
1436 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1437 AC_ARG_WITH([osmesa-bits],
1438     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1439         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1440     [osmesa_bits="$withval"],
1441     [osmesa_bits=8])
1442 if test "x$osmesa_bits" != x8; then
1443     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1444         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1445         osmesa_bits=8
1446     fi
1447 fi
1448 case "x$osmesa_bits" in
1449 x8)
1450     OSMESA_LIB="${OSMESA_LIB}"
1451     ;;
1452 x16|x32)
1453     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1454     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1455     ;;
1456 *)
1457     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1458     ;;
1459 esac
1460
1461 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1462     # only link libraries with osmesa if shared
1463     if test "$enable_static" = no; then
1464         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1465     else
1466         OSMESA_LIB_DEPS=""
1467     fi
1468     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1469 fi
1470
1471 AC_SUBST([OSMESA_LIB_DEPS])
1472 AC_SUBST([OSMESA_PC_REQ])
1473 AC_SUBST([OSMESA_PC_LIB_PRIV])
1474
1475 dnl
1476 dnl gbm configuration
1477 dnl
1478 if test "x$enable_gbm" = xauto; then
1479     case "$with_egl_platforms" in
1480         *drm*)
1481             enable_gbm=yes ;;
1482          *)
1483             enable_gbm=no ;;
1484     esac
1485 fi
1486 if test "x$enable_gbm" = xyes; then
1487     if test "x$need_pci_id$have_pci_id" = xyesno; then
1488         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1489     fi
1490
1491     if test "x$enable_dri" = xyes; then
1492         if test "x$enable_shared_glapi" = xno; then
1493             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1494         fi
1495     else
1496         # Strictly speaking libgbm does not require --enable-dri, although
1497         # both of its backends do. Thus one can build libgbm without any
1498         # backends if --disable-dri is set.
1499         # To avoid unnecessary complexity of checking if at least one backend
1500         # is available when building, just mandate --enable-dri.
1501         AC_MSG_ERROR([gbm requires --enable-dri])
1502     fi
1503 fi
1504 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1505 if test "x$need_pci_id$have_libudev" = xyesyes; then
1506     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1507 else
1508     GBM_PC_REQ_PRIV=""
1509 fi
1510 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1511 AC_SUBST([GBM_PC_REQ_PRIV])
1512 AC_SUBST([GBM_PC_LIB_PRIV])
1513
1514 dnl
1515 dnl EGL configuration
1516 dnl
1517 EGL_CLIENT_APIS=""
1518
1519 if test "x$enable_egl" = xyes; then
1520     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1521
1522     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1523
1524     if test "$enable_static" != yes; then
1525         if test "x$enable_dri" = xyes; then
1526             HAVE_EGL_DRIVER_DRI2=1
1527             if test "x$enable_shared_glapi" = xno; then
1528                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1529             fi
1530         else
1531             # Avoid building an "empty" libEGL. Drop/update this
1532             # when other backends (haiku?) come along.
1533             AC_MSG_ERROR([egl requires --enable-dri])
1534         fi
1535
1536     fi
1537 fi
1538 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1539 AC_SUBST([EGL_LIB_DEPS])
1540
1541 dnl
1542 dnl XA configuration
1543 dnl
1544 if test "x$enable_xa" = xyes; then
1545     if test "x$with_gallium_drivers" = xswrast; then
1546        AC_MSG_ERROR([
1547           Building xa requires at least one non swrast gallium driver.
1548           If you are looking to use libxatracker.so with the VMware driver,
1549           make sure to include svga in the gallium drivers list, apart from
1550           enabling XA.
1551           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1552     fi
1553     enable_gallium_loader=$enable_shared_pipe_drivers
1554 fi
1555 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1556
1557 dnl
1558 dnl Gallium G3DVL configuration
1559 dnl
1560 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1561     if test "x$enable_xvmc" = xauto; then
1562         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1563     fi
1564
1565     if test "x$enable_vdpau" = xauto; then
1566         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1567     fi
1568
1569     if test "x$enable_omx" = xauto; then
1570         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1571     fi
1572
1573     if test "x$enable_va" = xauto; then
1574         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1575     fi
1576 fi
1577
1578 if test "x$enable_dri" = xyes -o \
1579         "x$enable_xvmc" = xyes -o \
1580         "x$enable_vdpau" = xyes -o \
1581         "x$enable_omx" = xyes -o \
1582         "x$enable_va" = xyes; then
1583     need_gallium_vl=yes
1584 fi
1585 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1586
1587 if test "x$enable_xvmc" = xyes -o \
1588         "x$enable_vdpau" = xyes -o \
1589         "x$enable_omx" = xyes -o \
1590         "x$enable_va" = xyes; then
1591     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1592     need_gallium_vl_winsys=yes
1593 fi
1594 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1595
1596 if test "x$enable_xvmc" = xyes; then
1597     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1598     enable_gallium_loader=$enable_shared_pipe_drivers
1599 fi
1600 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1601
1602 if test "x$enable_vdpau" = xyes; then
1603     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1604     enable_gallium_loader=$enable_shared_pipe_drivers
1605 fi
1606 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1607
1608 if test "x$enable_omx" = xyes; then
1609     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1610     enable_gallium_loader=$enable_shared_pipe_drivers
1611 fi
1612 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1613
1614 if test "x$enable_va" = xyes; then
1615     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1616     enable_gallium_loader=$enable_shared_pipe_drivers
1617 fi
1618 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1619
1620 dnl
1621 dnl Nine Direct3D9 configuration
1622 dnl
1623 if test "x$enable_nine" = xyes; then
1624     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1625         AC_MSG_ERROR([nine requires the gallium swrast driver])
1626     fi
1627     if test "x$with_gallium_drivers" = xswrast; then
1628         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1629     fi
1630     if test "x$enable_dri3" = xno; then
1631         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1632     fi
1633
1634     enable_gallium_loader=$enable_shared_pipe_drivers
1635 fi
1636 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1637
1638 dnl
1639 dnl OpenCL configuration
1640 dnl
1641
1642 AC_ARG_WITH([clang-libdir],
1643    [AS_HELP_STRING([--with-clang-libdir],
1644          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1645    [CLANG_LIBDIR="$withval"],
1646    [CLANG_LIBDIR=''])
1647
1648 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1649 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1650
1651 if test "x$enable_opencl" = xyes; then
1652     if test -z "$with_gallium_drivers"; then
1653         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1654     fi
1655
1656     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1657         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1658     fi
1659
1660     if test "x$have_libclc" = xno; then
1661         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1662                     Make sure the directory containing libclc.pc is specified in your
1663                     PKG_CONFIG_PATH environment variable.
1664                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1665     else
1666         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1667         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1668         AC_SUBST([LIBCLC_INCLUDEDIR])
1669         AC_SUBST([LIBCLC_LIBEXECDIR])
1670     fi
1671
1672     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1673     enable_gallium_loader=yes
1674
1675     if test "x$enable_opencl_icd" = xyes; then
1676         OPENCL_LIBNAME="MesaOpenCL"
1677     else
1678         OPENCL_LIBNAME="OpenCL"
1679     fi
1680
1681     if test "x$have_libelf" != xyes; then
1682        AC_MSG_ERROR([Clover requires libelf])
1683     fi
1684 fi
1685 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1686 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1687 AC_SUBST([OPENCL_LIBNAME])
1688
1689 dnl
1690 dnl Gallium configuration
1691 dnl
1692 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1693
1694 AC_SUBST([LLVM_BINDIR])
1695 AC_SUBST([LLVM_CFLAGS])
1696 AC_SUBST([LLVM_CPPFLAGS])
1697 AC_SUBST([LLVM_CXXFLAGS])
1698 AC_SUBST([LLVM_LIBDIR])
1699 AC_SUBST([LLVM_LIBS])
1700 AC_SUBST([LLVM_LDFLAGS])
1701 AC_SUBST([LLVM_INCLUDEDIR])
1702 AC_SUBST([LLVM_VERSION])
1703 AC_SUBST([CLANG_RESOURCE_DIR])
1704
1705 case "x$enable_opengl$enable_gles1$enable_gles2" in
1706 x*yes*)
1707     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1708     ;;
1709 esac
1710
1711 AC_SUBST([VG_LIB_DEPS])
1712 AC_SUBST([EGL_CLIENT_APIS])
1713
1714 dnl
1715 dnl EGL Platforms configuration
1716 dnl
1717 AC_ARG_WITH([egl-platforms],
1718     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1719         [comma delimited native platforms libEGL supports, e.g.
1720         "x11,drm" @<:@default=auto@:>@])],
1721     [with_egl_platforms="$withval"],
1722     [if test "x$enable_egl" = xyes; then
1723         with_egl_platforms="x11"
1724     else
1725         with_egl_platforms=""
1726     fi])
1727
1728 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1729     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1730 fi
1731
1732 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1733         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1734         WAYLAND_SCANNER='')
1735 if test "x$WAYLAND_SCANNER" = x; then
1736     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1737 fi
1738
1739 # Do per-EGL platform setups and checks
1740 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1741 for plat in $egl_platforms; do
1742         case "$plat" in
1743         wayland)
1744                 test "x$have_libdrm" != xyes &&
1745                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1746
1747                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1748
1749                 if test "x$WAYLAND_SCANNER" = x; then
1750                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1751                 fi
1752                 ;;
1753
1754         x11)
1755                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1756                 ;;
1757
1758         drm)
1759                 test "x$enable_gbm" = "xno" &&
1760                         AC_MSG_ERROR([EGL platform drm needs gbm])
1761                 test "x$have_libdrm" != xyes &&
1762                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1763                 ;;
1764
1765         surfaceless)
1766                 test "x$have_libdrm" != xyes &&
1767                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1768                 ;;
1769
1770         *)
1771                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1772                 ;;
1773         esac
1774
1775         case "$plat$need_pci_id$have_pci_id" in
1776                 waylandyesno|drmyesno)
1777                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1778         esac
1779 done
1780
1781 # libEGL wants to default to the first platform specified in
1782 # ./configure.  parse that here.
1783 if test "x$egl_platforms" != "x"; then
1784     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1785     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1786 else
1787     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1788 fi
1789
1790 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1791 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1792 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1793 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1794 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1795
1796 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1797
1798 AC_SUBST([EGL_NATIVE_PLATFORM])
1799 AC_SUBST([EGL_CFLAGS])
1800
1801 # If we don't have the X11 platform, set this define so we don't try to include
1802 # the X11 headers.
1803 if ! echo "$egl_platforms" | grep -q 'x11'; then
1804     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1805     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1806 fi
1807
1808 dnl
1809 dnl Gallium LLVM
1810 dnl
1811 AC_ARG_ENABLE([gallium-llvm],
1812     [AS_HELP_STRING([--enable-gallium-llvm],
1813         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1814     [enable_gallium_llvm="$enableval"],
1815     [enable_gallium_llvm=auto])
1816
1817 AC_ARG_ENABLE([llvm-shared-libs],
1818     [AS_HELP_STRING([--enable-llvm-shared-libs],
1819         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1820     [enable_llvm_shared_libs="$enableval"],
1821     [enable_llvm_shared_libs=yes])
1822
1823 AC_ARG_WITH([llvm-prefix],
1824     [AS_HELP_STRING([--with-llvm-prefix],
1825         [Prefix for LLVM installations in non-standard locations])],
1826     [llvm_prefix="$withval"],
1827     [llvm_prefix=''])
1828
1829
1830 # Call this inside ` ` to get the return value.
1831 # $1 is the llvm-config command with arguments.
1832 strip_unwanted_llvm_flags() {
1833     # Use \> (marks the end of the word)
1834     echo `$1` | sed \
1835         -e 's/-DNDEBUG\>//g' \
1836         -e 's/-D_GNU_SOURCE\>//g' \
1837         -e 's/-pedantic\>//g' \
1838         -e 's/-Wcovered-switch-default\>//g' \
1839         -e 's/-O.\>//g' \
1840         -e 's/-g\>//g' \
1841         -e 's/-Wall\>//g' \
1842         -e 's/-Wcast-qual\>//g' \
1843         -e 's/-Woverloaded-virtual\>//g' \
1844         -e 's/-fcolor-diagnostics\>//g' \
1845         -e 's/-fdata-sections\>//g' \
1846         -e 's/-ffunction-sections\>//g' \
1847         -e 's/-fno-exceptions\>//g' \
1848         -e 's/-fomit-frame-pointer\>//g' \
1849         -e 's/-fvisibility-inlines-hidden\>//g' \
1850         -e 's/-fPIC\>//g' \
1851         -e 's/-fstack-protector-strong\>//g'
1852 }
1853
1854 llvm_check_version_for() {
1855     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1856         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1857     fi
1858 }
1859
1860
1861
1862 if test -z "$with_gallium_drivers"; then
1863     enable_gallium_llvm=no
1864 fi
1865 if test "x$enable_gallium_llvm" = xauto; then
1866     case "$host_cpu" in
1867     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1868     esac
1869 fi
1870 if test "x$enable_gallium_llvm" = xyes; then
1871     if test -n "$llvm_prefix"; then
1872         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1873     else
1874         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1875     fi
1876
1877     if test "x$LLVM_CONFIG" != xno; then
1878         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1879         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1880         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1881         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1882         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1883         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1884         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1885         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1886
1887         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1888             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1889         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1890             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1891
1892         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1893         if test -z "$LLVM_VERSION_PATCH"; then
1894             LLVM_VERSION_PATCH=0
1895         fi
1896
1897         if test -n "${LLVM_VERSION_MAJOR}"; then
1898             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1899         else
1900             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1901         fi
1902
1903         LLVM_REQUIRED_VERSION_MAJOR="3"
1904         LLVM_REQUIRED_VERSION_MINOR="3"
1905         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1906             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1907         fi
1908
1909         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1910
1911         if test "x$enable_opencl" = xyes; then
1912             llvm_check_version_for "3" "5" "0" "opencl"
1913
1914             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1915             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1916         fi
1917         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1918         MESA_LLVM=1
1919
1920         dnl Check for Clang internal headers
1921         if test "x$enable_opencl" = xyes; then
1922             if test -z "$CLANG_LIBDIR"; then
1923                 CLANG_LIBDIR=${LLVM_LIBDIR}
1924             fi
1925             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1926             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1927                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1928         fi
1929     else
1930         MESA_LLVM=0
1931         LLVM_VERSION_INT=0
1932     fi
1933 else
1934     MESA_LLVM=0
1935     LLVM_VERSION_INT=0
1936
1937     if test "x$enable_opencl" = xyes; then
1938         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1939     fi
1940 fi
1941
1942 dnl Directory for XVMC libs
1943 AC_ARG_WITH([xvmc-libdir],
1944     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1945         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1946     [XVMC_LIB_INSTALL_DIR="$withval"],
1947     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1948 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1949
1950 dnl
1951 dnl Gallium Tests
1952 dnl
1953 if test "x$enable_gallium_tests" = xyes; then
1954     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1955     enable_gallium_loader=yes
1956 fi
1957 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1958
1959 dnl Directory for VDPAU libs
1960 AC_ARG_WITH([vdpau-libdir],
1961     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1962         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1963     [VDPAU_LIB_INSTALL_DIR="$withval"],
1964     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1965 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1966
1967 dnl Directory for OMX libs
1968
1969 AC_ARG_WITH([omx-libdir],
1970     [AS_HELP_STRING([--with-omx-libdir=DIR],
1971         [directory for the OMX libraries])],
1972     [OMX_LIB_INSTALL_DIR="$withval"],
1973     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1974 AC_SUBST([OMX_LIB_INSTALL_DIR])
1975
1976 dnl Directory for VA libs
1977
1978 AC_ARG_WITH([va-libdir],
1979     [AS_HELP_STRING([--with-va-libdir=DIR],
1980         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1981     [VA_LIB_INSTALL_DIR="$withval"],
1982     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1983 AC_SUBST([VA_LIB_INSTALL_DIR])
1984
1985 AC_ARG_WITH([d3d-libdir],
1986     [AS_HELP_STRING([--with-d3d-libdir=DIR],
1987         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
1988     [D3D_DRIVER_INSTALL_DIR="$withval"],
1989     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
1990 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
1991
1992 dnl
1993 dnl Gallium helper functions
1994 dnl
1995 gallium_require_drm() {
1996     if test "x$have_libdrm" != xyes; then
1997        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1998     fi
1999 }
2000
2001 gallium_require_llvm() {
2002     if test "x$MESA_LLVM" = x0; then
2003         case "$host" in *gnux32) return;; esac
2004         case "$host_cpu" in
2005         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2006         esac
2007     fi
2008 }
2009
2010 gallium_require_drm_loader() {
2011     if test "x$enable_gallium_loader" = xyes; then
2012         if test "x$need_pci_id$have_pci_id" = xyesno; then
2013             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2014         fi
2015         enable_gallium_drm_loader=yes
2016     fi
2017     if test "x$enable_va" = xyes && test "x$7" != x; then
2018          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2019     fi
2020 }
2021
2022 require_egl_drm() {
2023     case "$with_egl_platforms" in
2024         *drm*)
2025             ;;
2026          *)
2027             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2028             ;;
2029     esac
2030     if test "x$enable_gbm" != xyes; then
2031             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2032     fi
2033 }
2034
2035 radeon_llvm_check() {
2036     if test ${LLVM_VERSION_INT} -lt 307; then
2037         amdgpu_llvm_target_name='r600'
2038     else
2039         amdgpu_llvm_target_name='amdgpu'
2040     fi
2041     if test "x$enable_gallium_llvm" != "xyes"; then
2042         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2043     fi
2044     llvm_check_version_for "3" "4" "2" $1
2045     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2046         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2047     fi
2048     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2049     NEED_RADEON_LLVM=yes
2050     if test "x$have_libelf" != xyes; then
2051        AC_MSG_ERROR([$1 requires libelf when using llvm])
2052     fi
2053 }
2054
2055 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2056 if test -n "$with_gallium_drivers"; then
2057     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2058     for driver in $gallium_drivers; do
2059         case "x$driver" in
2060         xsvga)
2061             HAVE_GALLIUM_SVGA=yes
2062             gallium_require_drm "svga"
2063             gallium_require_drm_loader
2064             ;;
2065         xi915)
2066             HAVE_GALLIUM_I915=yes
2067             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2068             gallium_require_drm "Gallium i915"
2069             gallium_require_drm_loader
2070             ;;
2071         xilo)
2072             HAVE_GALLIUM_ILO=yes
2073             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2074             gallium_require_drm "Gallium i965/ilo"
2075             gallium_require_drm_loader
2076             ;;
2077         xr300)
2078             HAVE_GALLIUM_R300=yes
2079             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2080             gallium_require_drm "Gallium R300"
2081             gallium_require_drm_loader
2082             gallium_require_llvm "Gallium R300"
2083             ;;
2084         xr600)
2085             HAVE_GALLIUM_R600=yes
2086             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2087             gallium_require_drm "Gallium R600"
2088             gallium_require_drm_loader
2089             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2090                 radeon_llvm_check "r600g"
2091                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2092             fi
2093             if test "x$enable_r600_llvm" = xyes; then
2094                 USE_R600_LLVM_COMPILER=yes;
2095             fi
2096             if test "x$enable_opencl" = xyes; then
2097                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2098             fi
2099             ;;
2100         xradeonsi)
2101             HAVE_GALLIUM_RADEONSI=yes
2102             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2103             gallium_require_drm "radeonsi"
2104             gallium_require_drm_loader
2105             radeon_llvm_check "radeonsi"
2106             require_egl_drm "radeonsi"
2107             ;;
2108         xnouveau)
2109             HAVE_GALLIUM_NOUVEAU=yes
2110             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2111             gallium_require_drm "nouveau"
2112             gallium_require_drm_loader
2113             ;;
2114         xfreedreno)
2115             HAVE_GALLIUM_FREEDRENO=yes
2116             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2117             gallium_require_drm "freedreno"
2118             gallium_require_drm_loader
2119             ;;
2120         xswrast)
2121             HAVE_GALLIUM_SOFTPIPE=yes
2122             if test "x$MESA_LLVM" = x1; then
2123                 HAVE_GALLIUM_LLVMPIPE=yes
2124             fi
2125             ;;
2126         xvc4)
2127             HAVE_GALLIUM_VC4=yes
2128             gallium_require_drm "vc4"
2129             gallium_require_drm_loader
2130
2131             case "$host_cpu" in
2132                 i?86 | x86_64 | amd64)
2133                 USE_VC4_SIMULATOR=yes
2134                 ;;
2135             esac
2136             ;;
2137         *)
2138             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2139             ;;
2140         esac
2141     done
2142 fi
2143
2144 dnl Set LLVM_LIBS - This is done after the driver configuration so
2145 dnl that drivers can add additional components to LLVM_COMPONENTS.
2146 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2147 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2148 dnl this was causing the same libraries to be appear multiple times
2149 dnl in LLVM_LIBS.
2150
2151 if test "x$MESA_LLVM" != x0; then
2152
2153     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2154
2155     if test "x$enable_llvm_shared_libs" = xyes; then
2156         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2157         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2158         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2159
2160         if test "x$llvm_have_one_so" = xyes; then
2161             dnl LLVM was built using auto*, so there is only one shared object.
2162             LLVM_LIBS="-l$LLVM_SO_NAME"
2163         else
2164             dnl If LLVM was built with CMake, there will be one shared object per
2165             dnl component.
2166             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2167                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2168         Please make sure you have built llvm with the --enable-shared option
2169         and that your llvm libraries are installed in $LLVM_LIBDIR
2170         If you have installed your llvm libraries to a different directory you
2171         can use the --with-llvm-prefix= configure flag to specify this directory.
2172         NOTE: Mesa is attempting to use llvm shared libraries by default.
2173         If you do not want to build with llvm shared libraries and instead want to
2174         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2175         invocation and rebuild.])])
2176
2177            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2178            dnl install uses a shared object for each component and we have
2179            dnl already added all of these objects to LLVM_LIBS.
2180         fi
2181     else
2182         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2183         dnl We need to link to llvm system libs when using static libs
2184         dnl However, only llvm 3.5+ provides --system-libs
2185         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2186             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2187         fi
2188     fi
2189 fi
2190
2191 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2192 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2193 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2194 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2195 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2196 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2197 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2198                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2199 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2200 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2201 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2202 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2203 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2204
2205 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2206
2207 # NOTE: anything using xcb or other client side libs ends up in separate
2208 #       _CLIENT variables.  The pipe loader is built in two variants,
2209 #       one that is standalone and does not link any x client libs (for
2210 #       use by XA tracker in particular, but could be used in any case
2211 #       where communication with xserver is not desired).
2212 if test "x$enable_gallium_loader" = xyes; then
2213     if test "x$enable_dri" = xyes; then
2214         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2215     fi
2216
2217     if test "x$enable_gallium_drm_loader" = xyes; then
2218         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2219     fi
2220
2221     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2222 fi
2223
2224 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2225 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2226 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2227 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2228 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2229 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2230
2231 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2232                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2233                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2234 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2235 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2236 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2237 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2238 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2239 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2240 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2241 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2242 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2243     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2244 fi
2245
2246 AC_SUBST([ELF_LIB])
2247
2248 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2249 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2250 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2251 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2252
2253 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2254 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2255 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2256
2257 AC_SUBST([NINE_MAJOR], 1)
2258 AC_SUBST([NINE_MINOR], 0)
2259 AC_SUBST([NINE_TINY], 0)
2260 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2261
2262 AC_SUBST([VDPAU_MAJOR], 1)
2263 AC_SUBST([VDPAU_MINOR], 0)
2264
2265 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2266 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2267 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2268 AC_SUBST([VA_MINOR], $VA_MINOR)
2269
2270 AC_SUBST([XVMC_MAJOR], 1)
2271 AC_SUBST([XVMC_MINOR], 0)
2272
2273 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2274 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2275 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2276 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2277
2278 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2279 AC_SUBST([XA_MINOR], $XA_MINOR)
2280 AC_SUBST([XA_TINY], $XA_TINY)
2281 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2282
2283 dnl Restore LDFLAGS and CPPFLAGS
2284 LDFLAGS="$_SAVE_LDFLAGS"
2285 CPPFLAGS="$_SAVE_CPPFLAGS"
2286
2287 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2288 if test "x$acv_mesa_CLANG" = xyes; then
2289     CFLAGS="$CFLAGS -Qunused-arguments"
2290     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2291 fi
2292
2293 dnl Add user CFLAGS and CXXFLAGS
2294 CFLAGS="$CFLAGS $USER_CFLAGS"
2295 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2296
2297 dnl Substitute the config
2298 AC_CONFIG_FILES([Makefile
2299                 src/Makefile
2300                 src/egl/Makefile
2301                 src/egl/main/egl.pc
2302                 src/egl/wayland/wayland-drm/Makefile
2303                 src/egl/wayland/wayland-egl/Makefile
2304                 src/egl/wayland/wayland-egl/wayland-egl.pc
2305                 src/gallium/Makefile
2306                 src/gallium/auxiliary/Makefile
2307                 src/gallium/auxiliary/pipe-loader/Makefile
2308                 src/gallium/drivers/freedreno/Makefile
2309                 src/gallium/drivers/i915/Makefile
2310                 src/gallium/drivers/ilo/Makefile
2311                 src/gallium/drivers/llvmpipe/Makefile
2312                 src/gallium/drivers/noop/Makefile
2313                 src/gallium/drivers/nouveau/Makefile
2314                 src/gallium/drivers/r300/Makefile
2315                 src/gallium/drivers/r600/Makefile
2316                 src/gallium/drivers/radeon/Makefile
2317                 src/gallium/drivers/radeonsi/Makefile
2318                 src/gallium/drivers/rbug/Makefile
2319                 src/gallium/drivers/softpipe/Makefile
2320                 src/gallium/drivers/svga/Makefile
2321                 src/gallium/drivers/trace/Makefile
2322                 src/gallium/drivers/vc4/Makefile
2323                 src/gallium/state_trackers/clover/Makefile
2324                 src/gallium/state_trackers/dri/Makefile
2325                 src/gallium/state_trackers/glx/xlib/Makefile
2326                 src/gallium/state_trackers/nine/Makefile
2327                 src/gallium/state_trackers/omx/Makefile
2328                 src/gallium/state_trackers/osmesa/Makefile
2329                 src/gallium/state_trackers/va/Makefile
2330                 src/gallium/state_trackers/vdpau/Makefile
2331                 src/gallium/state_trackers/xa/Makefile
2332                 src/gallium/state_trackers/xvmc/Makefile
2333                 src/gallium/targets/d3dadapter9/Makefile
2334                 src/gallium/targets/d3dadapter9/d3d.pc
2335                 src/gallium/targets/dri/Makefile
2336                 src/gallium/targets/libgl-xlib/Makefile
2337                 src/gallium/targets/omx/Makefile
2338                 src/gallium/targets/opencl/Makefile
2339                 src/gallium/targets/osmesa/Makefile
2340                 src/gallium/targets/osmesa/osmesa.pc
2341                 src/gallium/targets/pipe-loader/Makefile
2342                 src/gallium/targets/va/Makefile
2343                 src/gallium/targets/vdpau/Makefile
2344                 src/gallium/targets/xa/Makefile
2345                 src/gallium/targets/xa/xatracker.pc
2346                 src/gallium/targets/xvmc/Makefile
2347                 src/gallium/tests/trivial/Makefile
2348                 src/gallium/tests/unit/Makefile
2349                 src/gallium/winsys/freedreno/drm/Makefile
2350                 src/gallium/winsys/i915/drm/Makefile
2351                 src/gallium/winsys/intel/drm/Makefile
2352                 src/gallium/winsys/nouveau/drm/Makefile
2353                 src/gallium/winsys/radeon/drm/Makefile
2354                 src/gallium/winsys/svga/drm/Makefile
2355                 src/gallium/winsys/sw/dri/Makefile
2356                 src/gallium/winsys/sw/kms-dri/Makefile
2357                 src/gallium/winsys/sw/null/Makefile
2358                 src/gallium/winsys/sw/wrapper/Makefile
2359                 src/gallium/winsys/sw/xlib/Makefile
2360                 src/gallium/winsys/vc4/drm/Makefile
2361                 src/gbm/Makefile
2362                 src/gbm/main/gbm.pc
2363                 src/glsl/Makefile
2364                 src/glx/Makefile
2365                 src/glx/apple/Makefile
2366                 src/glx/tests/Makefile
2367                 src/gtest/Makefile
2368                 src/loader/Makefile
2369                 src/mapi/Makefile
2370                 src/mapi/es1api/glesv1_cm.pc
2371                 src/mapi/es2api/glesv2.pc
2372                 src/mapi/glapi/gen/Makefile
2373                 src/mesa/Makefile
2374                 src/mesa/gl.pc
2375                 src/mesa/drivers/dri/dri.pc
2376                 src/mesa/drivers/dri/common/Makefile
2377                 src/mesa/drivers/dri/common/xmlpool/Makefile
2378                 src/mesa/drivers/dri/i915/Makefile
2379                 src/mesa/drivers/dri/i965/Makefile
2380                 src/mesa/drivers/dri/Makefile
2381                 src/mesa/drivers/dri/nouveau/Makefile
2382                 src/mesa/drivers/dri/r200/Makefile
2383                 src/mesa/drivers/dri/radeon/Makefile
2384                 src/mesa/drivers/dri/swrast/Makefile
2385                 src/mesa/drivers/osmesa/Makefile
2386                 src/mesa/drivers/osmesa/osmesa.pc
2387                 src/mesa/drivers/x11/Makefile
2388                 src/mesa/main/tests/Makefile
2389                 src/util/Makefile
2390                 src/util/tests/hash_table/Makefile])
2391
2392 AC_OUTPUT
2393
2394 dnl
2395 dnl Output some configuration info for the user
2396 dnl
2397 echo ""
2398 echo "        prefix:          $prefix"
2399 echo "        exec_prefix:     $exec_prefix"
2400 echo "        libdir:          $libdir"
2401 echo "        includedir:      $includedir"
2402
2403 dnl API info
2404 echo ""
2405 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2406
2407 dnl Driver info
2408 echo ""
2409 case "x$enable_osmesa$enable_gallium_osmesa" in
2410 xnoyes)
2411         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2412         ;;
2413 xyesno)
2414         echo "        OSMesa:          lib$OSMESA_LIB"
2415         ;;
2416 xnono)
2417         echo "        OSMesa:          no"
2418         ;;
2419 esac
2420
2421 echo ""
2422 if test "x$enable_dri" != xno; then
2423         echo "        DRI platform:    $dri_platform"
2424         if test -z "$DRI_DIRS"; then
2425             echo "        DRI drivers:     no"
2426         else
2427             echo "        DRI drivers:     $DRI_DIRS"
2428         fi
2429         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2430 fi
2431
2432 case "x$enable_glx$enable_xlib_glx" in
2433 xyesyes)
2434     echo "        GLX:             Xlib-based"
2435     ;;
2436 xyesno)
2437     echo "        GLX:             DRI-based"
2438     ;;
2439 *)
2440     echo "        GLX:             $enable_glx"
2441     ;;
2442 esac
2443
2444 dnl EGL
2445 echo ""
2446 echo "        EGL:             $enable_egl"
2447 if test "$enable_egl" = yes; then
2448     echo "        EGL platforms:   $egl_platforms"
2449
2450     egl_drivers=""
2451     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2452         egl_drivers="$egl_drivers builtin:egl_dri2"
2453     fi
2454
2455     echo "        EGL drivers:    $egl_drivers"
2456 fi
2457
2458 echo ""
2459 if test "x$MESA_LLVM" = x1; then
2460     echo "        llvm:            yes"
2461     echo "        llvm-config:     $LLVM_CONFIG"
2462     echo "        llvm-version:    $LLVM_VERSION"
2463 else
2464     echo "        llvm:            no"
2465 fi
2466
2467 echo ""
2468 if test -n "$with_gallium_drivers"; then
2469     echo "        Gallium:         yes"
2470 else
2471     echo "        Gallium:         no"
2472 fi
2473
2474 dnl Shader cache
2475 echo ""
2476 echo "        Shader cache:    $enable_shader_cache"
2477 if test "x$enable_shader_cache" = "xyes"; then
2478     echo "        With SHA1 from:  $with_sha1"
2479 fi
2480
2481 dnl Libraries
2482 echo ""
2483 echo "        Shared libs:     $enable_shared"
2484 echo "        Static libs:     $enable_static"
2485 echo "        Shared-glapi:    $enable_shared_glapi"
2486
2487 dnl Compiler options
2488 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2489 cflags=`echo $CFLAGS | \
2490     $SED 's/^ *//;s/  */ /;s/ *$//'`
2491 cxxflags=`echo $CXXFLAGS | \
2492     $SED 's/^ *//;s/  */ /;s/ *$//'`
2493 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2494 echo ""
2495 echo "        CFLAGS:          $cflags"
2496 echo "        CXXFLAGS:        $cxxflags"
2497 echo "        Macros:          $defines"
2498 echo ""
2499 if test "x$MESA_LLVM" = x1; then
2500     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2501     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2502     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2503     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2504     echo ""
2505 fi
2506 echo "        PYTHON2:         $PYTHON2"
2507
2508 echo ""
2509 echo "        Run '${MAKE-make}' to build Mesa"
2510 echo ""