configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports -Bsymbolic
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 323 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         BSYMBOLIC="-Wl,-Bsymbolic";],
 328     [AC_MSG_RESULT([no])
 329         BSYMBOLIC="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([BSYMBOLIC])
 333
 334 dnl
 335 dnl Check if linker supports garbage collection
 336 dnl
 337 save_LDFLAGS=$LDFLAGS
 338 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 339 AC_MSG_CHECKING([whether ld supports --gc-sections])
 340 AC_LINK_IFELSE(
 341     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 342     [AC_MSG_RESULT([yes])
 343         GC_SECTIONS="-Wl,--gc-sections";],
 344     [AC_MSG_RESULT([no])
 345         GC_SECTIONS="";])
 346 LDFLAGS=$save_LDFLAGS
 347
 348 AC_SUBST([GC_SECTIONS])
 349
 350 dnl
 351 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 352 dnl so when these flags are passed to ld via libtool the checks will fail
 353 dnl
 354 case "$host_os" in
 355 openbsd* | darwin* )
 356     LD_NO_UNDEFINED="" ;;
 357 *)
 358     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 359 esac
 360
 361 AC_SUBST([LD_NO_UNDEFINED])
 362
 363 dnl
 364 dnl Check if linker supports version scripts
 365 dnl
 366 AC_MSG_CHECKING([if the linker supports version-scripts])
 367 save_LDFLAGS=$LDFLAGS
 368 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 369 cat > conftest.map <<EOF
 370 VERSION_1 {
 371      global:
 372          main;
 373
 374      local:
 375          *;
 376 };
 377 EOF
 378 AC_LINK_IFELSE(
 379     [AC_LANG_SOURCE([int main() { return 0;}])],
 380     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 381     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 382 LDFLAGS=$save_LDFLAGS
 383 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 384
 385 dnl
 386 dnl compatibility symlinks
 387 dnl
 388 case "$host_os" in
 389 linux* )
 390     HAVE_COMPAT_SYMLINKS=yes ;;
 391 * )
 392     HAVE_COMPAT_SYMLINKS=no ;;
 393 esac
 394
 395 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 396
 397 dnl
 398 dnl library names
 399 dnl
 400 case "$host_os" in
 401 darwin* )
 402     LIB_EXT='dylib' ;;
 403 cygwin* )
 404     LIB_EXT='dll' ;;
 405 aix* )
 406     LIB_EXT='a' ;;
 407 * )
 408     LIB_EXT='so' ;;
 409 esac
 410
 411 AC_SUBST([LIB_EXT])
 412
 413 AC_ARG_WITH([gl-lib-name],
 414   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 415     [specify GL library name @<:@default=GL@:>@])],
 416   [GL_LIB=$withval],
 417   [GL_LIB=GL])
 418 AC_ARG_WITH([osmesa-lib-name],
 419   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 420     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 421   [OSMESA_LIB=$withval],
 422   [OSMESA_LIB=OSMesa])
 423 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 424 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 425
 426 dnl
 427 dnl Mangled Mesa support
 428 dnl
 429 AC_ARG_ENABLE([mangling],
 430   [AS_HELP_STRING([--enable-mangling],
 431     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 432   [enable_mangling="${enableval}"],
 433   [enable_mangling=no]
 434 )
 435 if test "x${enable_mangling}" = "xyes" ; then
 436   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 437   GL_LIB="Mangled${GL_LIB}"
 438   OSMESA_LIB="Mangled${OSMESA_LIB}"
 439 fi
 440 AC_SUBST([GL_LIB])
 441 AC_SUBST([OSMESA_LIB])
 442
 443 dnl
 444 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 445 dnl
 446 AC_ARG_ENABLE([texture-float],
 447     [AS_HELP_STRING([--enable-texture-float],
 448         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 449     [enable_texture_float="$enableval"],
 450     [enable_texture_float=no]
 451 )
 452 if test "x$enable_texture_float" = xyes; then
 453     AC_MSG_WARN([Floating-point textures enabled.])
 454     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 455     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 456 fi
 457
 458 dnl
 459 dnl Arch/platform-specific settings
 460 dnl
 461 AC_ARG_ENABLE([asm],
 462     [AS_HELP_STRING([--disable-asm],
 463         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 464     [enable_asm="$enableval"],
 465     [enable_asm=yes]
 466 )
 467 asm_arch=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64 | amd64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         gnu*)
 488             asm_arch=x86
 489             ;;
 490         esac
 491         ;;
 492     x86_64|amd64)
 493         case "$host_os" in
 494         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 495             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 496             ;;
 497         esac
 498         ;;
 499     sparc*)
 500         case "$host_os" in
 501         linux*)
 502             asm_arch=sparc
 503             ;;
 504         esac
 505         ;;
 506     esac
 507
 508     case "$asm_arch" in
 509     x86)
 510         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 511         AC_MSG_RESULT([yes, x86])
 512         ;;
 513     x86_64|amd64)
 514         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 515         AC_MSG_RESULT([yes, x86_64])
 516         ;;
 517     sparc)
 518         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 530     [AC_CHECK_LIB([dl], [dlopen],
 531        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 532 AC_SUBST([DLOPEN_LIBS])
 533
 534 dnl Check if that library also has dladdr
 535 save_LDFLAGS="$LDFLAGS"
 536 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 537 AC_CHECK_FUNCS([dladdr])
 538 LDFLAGS="$save_LDFLAGS"
 539
 540 case "$host_os" in
 541 darwin*|mingw*)
 542     ;;
 543 *)
 544     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 545                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 546                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 547     AC_SUBST([CLOCK_LIB])
 548     ;;
 549 esac
 550
 551 dnl See if posix_memalign is available
 552 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 553
 554 dnl Check for pthreads
 555 case "$host_os" in
 556 mingw*)
 557     ;;
 558 *)
 559     AX_PTHREAD
 560     ;;
 561 esac
 562 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 563 dnl to -pthread, which causes problems if we need -lpthread to appear in
 564 dnl pkgconfig files.
 565 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 566
 567 dnl SELinux awareness.
 568 AC_ARG_ENABLE([selinux],
 569     [AS_HELP_STRING([--enable-selinux],
 570         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 571     [MESA_SELINUX="$enableval"],
 572     [MESA_SELINUX=no])
 573 if test "x$enable_selinux" = "xyes"; then
 574     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 575         [AC_CHECK_HEADER([selinux/selinux.h],[],
 576                          [AC_MSG_ERROR([SELinux headers not found])])
 577          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 578                       [AC_MSG_ERROR([SELinux library not found])])
 579          SELINUX_LIBS="-lselinux"])
 580     DEFINES="$DEFINES -DMESA_SELINUX"
 581 fi
 582 AC_SUBST([SELINUX_CFLAGS])
 583 AC_SUBST([SELINUX_LIBS])
 584
 585 dnl Options for APIs
 586 AC_ARG_ENABLE([opengl],
 587     [AS_HELP_STRING([--disable-opengl],
 588         [disable support for standard OpenGL API @<:@default=no@:>@])],
 589     [enable_opengl="$enableval"],
 590     [enable_opengl=yes])
 591 AC_ARG_ENABLE([gles1],
 592     [AS_HELP_STRING([--enable-gles1],
 593         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 594     [enable_gles1="$enableval"],
 595     [enable_gles1=no])
 596 AC_ARG_ENABLE([gles2],
 597     [AS_HELP_STRING([--enable-gles2],
 598         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 599     [enable_gles2="$enableval"],
 600     [enable_gles2=no])
 601 AC_ARG_ENABLE([openvg],
 602     [AS_HELP_STRING([--enable-openvg],
 603         [enable support for OpenVG API @<:@default=no@:>@])],
 604     [enable_openvg="$enableval"],
 605     [enable_openvg=no])
 606
 607 AC_ARG_ENABLE([dri],
 608     [AS_HELP_STRING([--enable-dri],
 609         [enable DRI modules @<:@default=enabled@:>@])],
 610     [enable_dri="$enableval"],
 611     [enable_dri=yes])
 612
 613 case "$host_os" in
 614 linux*)
 615     dri3_default=yes
 616     ;;
 617 *)
 618     dri3_default=no
 619     ;;
 620 esac
 621 AC_ARG_ENABLE([dri3],
 622     [AS_HELP_STRING([--enable-dri3],
 623         [enable DRI3 @<:@default=auto@:>@])],
 624     [enable_dri3="$enableval"],
 625     [enable_dri3="$dri3_default"])
 626 AC_ARG_ENABLE([glx],
 627     [AS_HELP_STRING([--enable-glx],
 628         [enable GLX library @<:@default=enabled@:>@])],
 629     [enable_glx="$enableval"],
 630     [enable_glx=yes])
 631 AC_ARG_ENABLE([osmesa],
 632     [AS_HELP_STRING([--enable-osmesa],
 633         [enable OSMesa library @<:@default=disabled@:>@])],
 634     [enable_osmesa="$enableval"],
 635     [enable_osmesa=no])
 636 AC_ARG_ENABLE([gallium-osmesa],
 637     [AS_HELP_STRING([--enable-gallium-osmesa],
 638         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 639     [enable_gallium_osmesa="$enableval"],
 640     [enable_gallium_osmesa=no])
 641 AC_ARG_ENABLE([egl],
 642     [AS_HELP_STRING([--disable-egl],
 643         [disable EGL library @<:@default=enabled@:>@])],
 644     [enable_egl="$enableval"],
 645     [enable_egl=yes])
 646
 647 AC_ARG_ENABLE([xa],
 648     [AS_HELP_STRING([--enable-xa],
 649         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 650     [enable_xa="$enableval"],
 651     [enable_xa=no])
 652 AC_ARG_ENABLE([gbm],
 653    [AS_HELP_STRING([--enable-gbm],
 654          [enable gbm library @<:@default=auto@:>@])],
 655    [enable_gbm="$enableval"],
 656    [enable_gbm=auto])
 657
 658 AC_ARG_ENABLE([xvmc],
 659    [AS_HELP_STRING([--enable-xvmc],
 660          [enable xvmc library @<:@default=auto@:>@])],
 661    [enable_xvmc="$enableval"],
 662    [enable_xvmc=no])
 663 AC_ARG_ENABLE([vdpau],
 664    [AS_HELP_STRING([--enable-vdpau],
 665          [enable vdpau library @<:@default=auto@:>@])],
 666    [enable_vdpau="$enableval"],
 667    [enable_vdpau=auto])
 668 AC_ARG_ENABLE([omx],
 669    [AS_HELP_STRING([--enable-omx],
 670          [enable OpenMAX library @<:@default=no@:>@])],
 671    [enable_omx="$enableval"],
 672    [enable_omx=no])
 673 AC_ARG_ENABLE([opencl],
 674    [AS_HELP_STRING([--enable-opencl],
 675          [enable OpenCL library @<:@default=no@:>@])],
 676    [enable_opencl="$enableval"],
 677    [enable_opencl=no])
 678 AC_ARG_ENABLE([opencl_icd],
 679    [AS_HELP_STRING([--enable-opencl-icd],
 680           [Build an OpenCL ICD library to be loaded by an ICD implementation
 681            @<:@default=no@:>@])],
 682     [enable_opencl_icd="$enableval"],
 683     [enable_opencl_icd=no])
 684 AC_ARG_ENABLE([xlib-glx],
 685     [AS_HELP_STRING([--enable-xlib-glx],
 686         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 687     [enable_xlib_glx="$enableval"],
 688     [enable_xlib_glx=no])
 689 AC_ARG_ENABLE([gallium-egl],
 690     [AS_HELP_STRING([--enable-gallium-egl],
 691         [enable optional EGL state tracker (not required
 692          for EGL support in Gallium with OpenGL and OpenGL ES)
 693          @<:@default=disable@:>@])],
 694     [enable_gallium_egl="$enableval"],
 695     [enable_gallium_egl=no])
 696 AC_ARG_ENABLE([gallium-gbm],
 697     [AS_HELP_STRING([--enable-gallium-gbm],
 698         [enable optional gbm state tracker (not required for
 699          gbm support in Gallium)
 700          @<:@default=auto@:>@])],
 701     [enable_gallium_gbm="$enableval"],
 702     [enable_gallium_gbm=auto])
 703
 704 AC_ARG_ENABLE([r600-llvm-compiler],
 705     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 706         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 707     [enable_r600_llvm="$enableval"],
 708     [enable_r600_llvm=no])
 709
 710 AC_ARG_ENABLE([gallium-tests],
 711     [AS_HELP_STRING([--enable-gallium-tests],
 712         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 713     [enable_gallium_tests="$enableval"],
 714     [enable_gallium_tests=no])
 715
 716 # Option for Gallium drivers
 717
 718 # Keep this in sync with the --with-gallium-drivers help string default value
 719 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 720
 721 AC_ARG_WITH([gallium-drivers],
 722     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 723         [comma delimited Gallium drivers list, e.g.
 724         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 725         @<:@default=r300,r600,svga,swrast@:>@])],
 726     [with_gallium_drivers="$withval"],
 727     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 728
 729 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 730 # here so that the script doesn't choke on an unknown driver name later.
 731 case "$with_gallium_drivers" in
 732     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 733     no) with_gallium_drivers='' ;;
 734 esac
 735
 736 if test "x$enable_opengl" = xno -a \
 737         "x$enable_gles1" = xno -a \
 738         "x$enable_gles2" = xno -a \
 739         "x$enable_openvg" = xno -a \
 740         "x$enable_xa" = xno -a \
 741         "x$enable_xvmc" = xno -a \
 742         "x$enable_vdpau" = xno -a \
 743         "x$enable_omx" = xno -a \
 744         "x$enable_opencl" = xno; then
 745     AC_MSG_ERROR([at least one API should be enabled])
 746 fi
 747
 748 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 749 if test "x$enable_opengl" = xno -a \
 750         "x$enable_gles1" = xyes; then
 751     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 752 fi
 753
 754 if test "x$enable_opengl" = xno -a \
 755         "x$enable_gles2" = xyes; then
 756     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 757 fi
 758
 759 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 760 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 761 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 762 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 763                                         "x$enable_gles1" = xyes -o \
 764                                         "x$enable_gles2" = xyes)
 765
 766 if test "x$enable_glx" = xno; then
 767     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 768     enable_xlib_glx=no
 769 fi
 770
 771 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 772     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 773 fi
 774
 775 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 776     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 777 fi
 778
 779 # Disable GLX if OpenGL is not enabled
 780 if test "x$enable_glx$enable_opengl" = xyesno; then
 781     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 782     enable_glx=no
 783 fi
 784
 785 # Disable GLX if DRI and Xlib-GLX are not enabled
 786 if test "x$enable_glx" = xyes -a \
 787         "x$enable_dri" = xno -a \
 788         "x$enable_xlib_glx" = xno; then
 789     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 790     enable_glx=no
 791 fi
 792
 793 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 794                                   "x$enable_dri" = xyes)
 795
 796 # Select which platform-dependent DRI code gets built
 797 case "$host_os" in
 798 darwin*)
 799     dri_platform='apple' ;;
 800 gnu*|mingw*|cygwin*)
 801     dri_platform='none' ;;
 802 *)
 803     dri_platform='drm' ;;
 804 esac
 805
 806 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 807 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 808 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 809 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 810 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 811
 812 AC_ARG_ENABLE([shared-glapi],
 813     [AS_HELP_STRING([--enable-shared-glapi],
 814         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 815     [enable_shared_glapi="$enableval"],
 816     [enable_shared_glapi=yes])
 817
 818 case "x$enable_opengl$enable_gles1$enable_gles2" in
 819 x*yes*yes*)
 820     if test "x$enable_shared_glapi" = xno; then
 821         AC_MSG_ERROR([shared GLAPI required when building two or more of
 822                       the following APIs - opengl, gles1 gles2])
 823     fi
 824     ;;
 825 esac
 826
 827 # Building Xlib-GLX requires shared glapi to be disabled.
 828 if test "x$enable_xlib_glx" = xyes; then
 829     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 830     enable_shared_glapi=no
 831 fi
 832
 833 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 834
 835 dnl
 836 dnl Driver specific build directories
 837 dnl
 838 GALLIUM_TARGET_DIRS=""
 839 GALLIUM_WINSYS_DIRS="sw"
 840 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 841 GALLIUM_STATE_TRACKERS_DIRS=""
 842
 843 case "x$enable_glx$enable_xlib_glx" in
 844 xyesyes)
 845     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 846     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 847     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 848     NEED_WINSYS_XLIB="yes"
 849     ;;
 850 esac
 851
 852 if test "x$enable_dri" = xyes; then
 853     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 854     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 855 fi
 856
 857 if test "x$enable_gallium_osmesa" = xyes; then
 858     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 859         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 860     fi
 861     if test "x$enable_osmesa" = xyes; then
 862         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 863     fi
 864     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 865     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 866 fi
 867
 868 AC_SUBST([MESA_LLVM])
 869
 870 # Check for libdrm
 871 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 872                   [have_libdrm=yes], [have_libdrm=no])
 873 if test "x$have_libdrm" = xyes; then
 874         DEFINES="$DEFINES -DHAVE_LIBDRM"
 875 fi
 876
 877 case "$host_os" in
 878 linux*)
 879     need_pci_id=yes ;;
 880 *)
 881     need_pci_id=no ;;
 882 esac
 883
 884 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 885                   have_libudev=yes, have_libudev=no)
 886
 887 AC_ARG_ENABLE([sysfs],
 888     [AS_HELP_STRING([--enable-sysfs],
 889         [enable /sys PCI identification @<:@default=disabled@:>@])],
 890     [have_sysfs="$enableval"],
 891     [have_sysfs=no]
 892 )
 893
 894 if test "x$enable_dri" = xyes; then
 895     if test "$enable_static" = yes; then
 896         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 897     fi
 898
 899     # not a hard requirement as swrast does not depend on it
 900     if test "x$have_libdrm" = xyes; then
 901         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 902     fi
 903 fi
 904
 905 dnl Direct rendering or just indirect rendering
 906 case "$host_os" in
 907 gnu*)
 908     dnl Disable by default on GNU/Hurd
 909     driglx_direct_default="no"
 910     ;;
 911 cygwin*)
 912     dnl Disable by default on cygwin
 913     driglx_direct_default="no"
 914     ;;
 915 *)
 916     driglx_direct_default="yes"
 917     ;;
 918 esac
 919 AC_ARG_ENABLE([driglx-direct],
 920     [AS_HELP_STRING([--disable-driglx-direct],
 921         [disable direct rendering in GLX and EGL for DRI \
 922             @<:@default=auto@:>@])],
 923     [driglx_direct="$enableval"],
 924     [driglx_direct="$driglx_direct_default"])
 925
 926 dnl
 927 dnl libGL configuration per driver
 928 dnl
 929 case "x$enable_glx$enable_xlib_glx" in
 930 xyesyes)
 931     # Xlib-based GLX
 932     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 933     GL_PC_REQ_PRIV="x11 xext"
 934     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 935     GL_LIB_DEPS="$XLIBGL_LIBS"
 936     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 937     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 938     ;;
 939 xyesno)
 940     # DRI-based GLX
 941     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 942
 943     # find the DRI deps for libGL
 944     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 945
 946     if test x"$driglx_direct" = xyes; then
 947         if test x"$dri_platform" = xdrm ; then
 948             DEFINES="$DEFINES -DGLX_USE_DRM"
 949             if test "x$have_libdrm" != xyes; then
 950                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 951             fi
 952
 953             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 954             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 955             if test x"$enable_dri3" = xyes; then
 956                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 957                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 958             fi
 959
 960             if test x"$enable_dri" = xyes; then
 961                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 962             fi
 963
 964             if test x"$enable_dri3" = xyes; then
 965                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 966             fi
 967         fi
 968         if test x"$dri_platform" = xapple ; then
 969             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 970         fi
 971     fi
 972
 973     # add xf86vidmode if available
 974     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 975     if test "$HAVE_XF86VIDMODE" = yes ; then
 976         dri_modules="$dri_modules xxf86vm"
 977     fi
 978
 979     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 980     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 981     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 982     GL_LIB_DEPS="$DRIGL_LIBS"
 983
 984     # need DRM libs, $PTHREAD_LIBS, etc.
 985     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 986     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 987     ;;
 988 esac
 989
 990 have_pci_id=no
 991 if test "$have_libudev" = yes; then
 992     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 993     have_pci_id=yes
 994 fi
 995
 996 if test "$have_sysfs" = yes; then
 997     DEFINES="$DEFINES -DHAVE_SYSFS"
 998     have_pci_id=yes
 999 fi
1000
1001 # This is outside the case (above) so that it is invoked even for non-GLX
1002 # builds.
1003 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1004
1005 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1006 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1007 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1008 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1009
1010 AC_SUBST([X11_INCLUDES])
1011 AC_SUBST([GL_LIB_DEPS])
1012 AC_SUBST([GL_PC_REQ_PRIV])
1013 AC_SUBST([GL_PC_LIB_PRIV])
1014 AC_SUBST([GL_PC_CFLAGS])
1015 AC_SUBST([DRI_PC_REQ_PRIV])
1016 AC_SUBST([GLESv1_CM_LIB_DEPS])
1017 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1018 AC_SUBST([GLESv2_LIB_DEPS])
1019 AC_SUBST([GLESv2_PC_LIB_PRIV])
1020
1021 AC_SUBST([HAVE_XF86VIDMODE])
1022
1023 dnl
1024 dnl More GLX setup
1025 dnl
1026 case "x$enable_glx$enable_xlib_glx" in
1027 xyesyes)
1028     DEFINES="$DEFINES -DUSE_XSHM"
1029     ;;
1030 xyesno)
1031     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1032     if test "x$driglx_direct" = xyes; then
1033         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1034     fi
1035     ;;
1036 esac
1037
1038 dnl
1039 dnl TLS detection
1040 dnl
1041
1042 AC_ARG_ENABLE([glx-tls],
1043     [AS_HELP_STRING([--enable-glx-tls],
1044         [enable TLS support in GLX @<:@default=disabled@:>@])],
1045     [GLX_USE_TLS="$enableval"],
1046     [GLX_USE_TLS=no])
1047 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1048
1049 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1050       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1051
1052 dnl
1053 dnl More DRI setup
1054 dnl
1055 dnl Directory for DRI drivers
1056 AC_ARG_WITH([dri-driverdir],
1057     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1058         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1059     [DRI_DRIVER_INSTALL_DIR="$withval"],
1060     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1061 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1062 dnl Extra search path for DRI drivers
1063 AC_ARG_WITH([dri-searchpath],
1064     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1065         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1066     [DRI_DRIVER_SEARCH_DIR="$withval"],
1067     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1068 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1069 dnl Which drivers to build - default is chosen by platform
1070 AC_ARG_WITH([dri-drivers],
1071     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1072         [comma delimited classic DRI drivers list, e.g.
1073         "swrast,i965,radeon" @<:@default=auto@:>@])],
1074     [with_dri_drivers="$withval"],
1075     [with_dri_drivers=auto])
1076
1077 if test "x$with_dri_drivers" = xauto; then
1078     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1079         with_dri_drivers="yes"
1080     else
1081         with_dri_drivers="no"
1082     fi
1083 fi
1084 if test "x$with_dri_drivers" = xno; then
1085     with_dri_drivers=''
1086 fi
1087
1088 dnl If $with_dri_drivers is yes, drivers will be added through
1089 dnl platform checks. Set DEFINES and LIB_DEPS
1090 if test "x$enable_dri" = xyes; then
1091     # Platform specific settings and drivers to build
1092     case "$host_os" in
1093     linux*)
1094         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1095         DEFINES="$DEFINES -DHAVE_ALIAS"
1096         if test "x$enable_dri3" = xyes; then
1097             DEFINES="$DEFINES -DHAVE_DRI3"
1098         fi
1099
1100         if test "x$have_pci_id" != xyes; then
1101             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1102         fi
1103
1104         case "$host_cpu" in
1105         powerpc* | sparc*)
1106             # Build only the drivers for cards that exist on PowerPC/sparc
1107             if test "x$with_dri_drivers" = "xyes"; then
1108                 with_dri_drivers="r200 radeon swrast"
1109             fi
1110             ;;
1111         esac
1112         ;;
1113     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1114         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1115         DEFINES="$DEFINES -DHAVE_ALIAS"
1116         ;;
1117     gnu*)
1118         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1119         DEFINES="$DEFINES -DHAVE_ALIAS"
1120         ;;
1121     solaris*)
1122         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1123         ;;
1124     cygwin*)
1125         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1126         if test "x$with_dri_drivers" = "xyes"; then
1127             with_dri_drivers="swrast"
1128         fi
1129         ;;
1130     darwin*)
1131         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DGLX_ALIAS_UNSUPPORTED"
1132         if test "x$with_dri_drivers" = "xyes"; then
1133             with_dri_drivers="swrast"
1134         fi
1135         ;;
1136     esac
1137
1138     # default drivers
1139     if test "x$with_dri_drivers" = "xyes"; then
1140         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1141     fi
1142
1143     # Check for expat
1144     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1145     if test "x$have_expat" = "xyes"; then
1146        PKG_CHECK_MODULES([EXPAT], [expat], [],
1147                          AC_MSG_ERROR([Expat required for DRI.]))
1148     else
1149        # expat version 2.0 and earlier do not provide expat.pc
1150        EXPAT_LIBS=-lexpat
1151     fi
1152
1153     # If we are building any DRI driver other than swrast.
1154     if test -n "$with_dri_drivers"; then
1155         if test "x$with_dri_drivers" != xswrast; then
1156             # ... libdrm is required
1157             if test "x$have_libdrm" != xyes; then
1158                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1159             fi
1160             DRICOMMON_NEED_LIBDRM=yes
1161         else
1162             DRICOMMON_NEED_LIBDRM=no
1163         fi
1164     fi
1165
1166     # put all the necessary libs together
1167     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1168 fi
1169
1170 AC_SUBST([DRI_LIB_DEPS])
1171
1172 DRI_DIRS=''
1173 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1174 if test -n "$with_dri_drivers"; then
1175     if test "x$enable_opengl" != xyes; then
1176         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1177     fi
1178
1179     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1180     for driver in $dri_drivers; do
1181         DRI_DIRS="$DRI_DIRS $driver"
1182         case "x$driver" in
1183         xi915)
1184             HAVE_I915_DRI=yes;
1185             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1186             ;;
1187         xi965)
1188             HAVE_I965_DRI=yes;
1189             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1190             ;;
1191         xnouveau)
1192             HAVE_NOUVEAU_DRI=yes;
1193             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1194             ;;
1195         xradeon)
1196             HAVE_RADEON_DRI=yes;
1197             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1198             ;;
1199         xr200)
1200             HAVE_R200_DRI=yes;
1201             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1202             ;;
1203         xswrast)
1204             HAVE_SWRAST_DRI=yes;
1205             ;;
1206         *)
1207             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1208             ;;
1209         esac
1210     done
1211     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1212 fi
1213
1214 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1215 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1216                                   "x$enable_osmesa" = xyes -o \
1217                                   -n "$DRI_DIRS")
1218
1219 dnl
1220 dnl OSMesa configuration
1221 dnl
1222
1223 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1224 AC_ARG_WITH([osmesa-bits],
1225     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1226         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1227     [osmesa_bits="$withval"],
1228     [osmesa_bits=8])
1229 if test "x$osmesa_bits" != x8; then
1230     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1231         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1232         osmesa_bits=8
1233     fi
1234 fi
1235 case "x$osmesa_bits" in
1236 x8)
1237     OSMESA_LIB="${OSMESA_LIB}"
1238     ;;
1239 x16|x32)
1240     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1241     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1242     ;;
1243 *)
1244     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1245     ;;
1246 esac
1247
1248 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1249     # only link libraries with osmesa if shared
1250     if test "$enable_static" = no; then
1251         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1252     else
1253         OSMESA_LIB_DEPS=""
1254     fi
1255     OSMESA_MESA_DEPS=""
1256     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1257 fi
1258
1259 AC_SUBST([OSMESA_LIB_DEPS])
1260 AC_SUBST([OSMESA_MESA_DEPS])
1261 AC_SUBST([OSMESA_PC_REQ])
1262 AC_SUBST([OSMESA_PC_LIB_PRIV])
1263
1264 dnl
1265 dnl gbm configuration
1266 dnl
1267 if test "x$enable_gbm" = xauto; then
1268     case "$with_egl_platforms" in
1269         *drm*)
1270             enable_gbm=yes ;;
1271          *)
1272             enable_gbm=no ;;
1273     esac
1274 fi
1275 if test "x$enable_gbm" = xyes; then
1276     if test "x$need_pci_id$have_pci_id" = xyesno; then
1277         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1278     fi
1279
1280     if test "x$enable_dri" = xyes; then
1281         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1282         if test "x$enable_shared_glapi" = xno; then
1283             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1284         fi
1285     else
1286         # Strictly speaking libgbm does not require --enable-dri, although
1287         # both of its backends do. Thus one can build libgbm without any
1288         # backends if --disable-dri is set.
1289         # To avoid unnecessary complexity of checking if at least one backend
1290         # is available when building, just mandate --enable-dri.
1291         AC_MSG_ERROR([gbm requires --enable-dri])
1292     fi
1293 fi
1294 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1295 if test "x$need_pci_id$have_libudev" = xyesyes; then
1296     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1297 else
1298     GBM_PC_REQ_PRIV=""
1299 fi
1300 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1301 AC_SUBST([GBM_PC_REQ_PRIV])
1302 AC_SUBST([GBM_PC_LIB_PRIV])
1303
1304 dnl
1305 dnl EGL configuration
1306 dnl
1307 EGL_CLIENT_APIS=""
1308
1309 if test "x$enable_egl" = xyes; then
1310     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1311
1312     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1313
1314     if test "$enable_static" != yes; then
1315         if test "x$enable_dri" = xyes; then
1316             HAVE_EGL_DRIVER_DRI2=1
1317         fi
1318
1319     fi
1320 fi
1321 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1322 AC_SUBST([EGL_LIB_DEPS])
1323
1324 dnl
1325 dnl EGL Gallium configuration
1326 dnl
1327 if test "x$enable_gallium_egl" = xyes; then
1328     if test -z "$with_gallium_drivers"; then
1329         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1330     fi
1331     if test "x$enable_egl" = xno; then
1332         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1333     fi
1334     if test "x$have_libdrm" != xyes; then
1335         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1336     fi
1337
1338     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1339     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1340 fi
1341 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1342
1343 dnl
1344 dnl gbm Gallium configuration
1345 dnl
1346 if test "x$enable_gallium_gbm" = xauto; then
1347     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1348         yesyesyes*drm*)
1349             enable_gallium_gbm=yes ;;
1350          *)
1351             enable_gallium_gbm=no ;;
1352     esac
1353 fi
1354 if test "x$enable_gallium_gbm" = xyes; then
1355     if test -z "$with_gallium_drivers"; then
1356         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1357     fi
1358     if test "x$enable_gbm" = xno; then
1359         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1360     fi
1361     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1362     if test "x$enable_dri" = xno; then
1363         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1364     fi
1365
1366     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1367     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1368     enable_gallium_loader=yes
1369 fi
1370 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1371
1372 dnl
1373 dnl XA configuration
1374 dnl
1375 if test "x$enable_xa" = xyes; then
1376     if test "x$with_gallium_drivers" = xswrast; then
1377        AC_MSG_ERROR([
1378           Building xa requires at least one non swrast gallium driver.
1379           If you are looking to use libxatracker.so with vmware's virtual gpu,
1380           make sure to include svga in the gallium drivers list, apart from
1381           enabling XA.
1382           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1383     fi
1384     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1385     enable_gallium_loader=yes
1386 fi
1387 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1388
1389 dnl
1390 dnl OpenVG configuration
1391 dnl
1392 VG_LIB_DEPS=""
1393
1394 if test "x$enable_openvg" = xyes; then
1395     if test "x$enable_egl" = xno; then
1396         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1397     fi
1398     if test -z "$with_gallium_drivers"; then
1399         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1400     fi
1401     if test "x$enable_gallium_egl" = xno; then
1402         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1403     fi
1404
1405     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1406     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1407     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1408     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1409     AC_SUBST([VG_PC_LIB_PRIV])
1410 fi
1411 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1412
1413 dnl
1414 dnl Gallium G3DVL configuration
1415 dnl
1416 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1417     if test "x$enable_xvmc" = xauto; then
1418         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1419     fi
1420
1421     if test "x$enable_vdpau" = xauto; then
1422         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1423     fi
1424
1425     if test "x$enable_omx" = xauto; then
1426         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1427     fi
1428 fi
1429
1430 if test "x$enable_xvmc" = xyes; then
1431     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1432     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1433 fi
1434 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1435
1436 if test "x$enable_vdpau" = xyes; then
1437     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1438                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1439     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1440 fi
1441 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1442
1443 if test "x$enable_omx" = xyes; then
1444     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1445     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1446 fi
1447 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1448
1449 dnl
1450 dnl OpenCL configuration
1451 dnl
1452
1453 AC_ARG_WITH([libclc-path],
1454    [AS_HELP_STRING([--with-libclc-path],
1455          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1456    [LIBCLC_PATH="$withval"],
1457    [LIBCLC_PATH=''])
1458
1459 if test -n "$LIBCLC_PATH"; then
1460    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1461                   Please review the updated build instructions for clover:
1462                   http://dri.freedesktop.org/wiki/GalliumCompute])
1463 fi
1464
1465
1466 AC_ARG_WITH([clang-libdir],
1467    [AS_HELP_STRING([--with-clang-libdir],
1468          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1469    [CLANG_LIBDIR="$withval"],
1470    [CLANG_LIBDIR=''])
1471
1472 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1473
1474 if test "x$enable_opencl" = xyes; then
1475     if test -z "$with_gallium_drivers"; then
1476         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1477     fi
1478
1479     if test "x$enable_gallium_llvm" != xyes; then
1480         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1481     fi
1482
1483     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1484         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1485     fi
1486
1487     if test "x$have_libclc" = xno; then
1488         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1489                     Make sure the directory containing libclc.pc is specified in your
1490                     PKG_CONFIG_PATH environment variable.
1491                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1492     else
1493         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1494         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1495         AC_SUBST([LIBCLC_INCLUDEDIR])
1496         AC_SUBST([LIBCLC_LIBEXECDIR])
1497     fi
1498
1499     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1500     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1501     enable_gallium_loader=yes
1502
1503     if test "x$enable_opencl_icd" = xyes; then
1504         OPENCL_LIBNAME="MesaOpenCL"
1505     else
1506         OPENCL_LIBNAME="OpenCL"
1507     fi
1508 fi
1509 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1510 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1511 AC_SUBST([OPENCL_LIBNAME])
1512
1513 dnl
1514 dnl Gallium configuration
1515 dnl
1516 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1517
1518 AC_SUBST([LLVM_BINDIR])
1519 AC_SUBST([LLVM_CFLAGS])
1520 AC_SUBST([LLVM_CPPFLAGS])
1521 AC_SUBST([LLVM_CXXFLAGS])
1522 AC_SUBST([LLVM_LIBDIR])
1523 AC_SUBST([LLVM_LIBS])
1524 AC_SUBST([LLVM_LDFLAGS])
1525 AC_SUBST([LLVM_INCLUDEDIR])
1526 AC_SUBST([LLVM_VERSION])
1527 AC_SUBST([CLANG_RESOURCE_DIR])
1528
1529 case "x$enable_opengl$enable_gles1$enable_gles2" in
1530 x*yes*)
1531     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1532     ;;
1533 esac
1534
1535 AC_SUBST([VG_LIB_DEPS])
1536 AC_SUBST([EGL_CLIENT_APIS])
1537
1538 dnl
1539 dnl EGL Platforms configuration
1540 dnl
1541 AC_ARG_WITH([egl-platforms],
1542     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1543         [comma delimited native platforms libEGL supports, e.g.
1544         "x11,drm" @<:@default=auto@:>@])],
1545     [with_egl_platforms="$withval"],
1546     [if test "x$enable_egl" = xyes; then
1547         with_egl_platforms="x11"
1548     else
1549         with_egl_platforms=""
1550     fi])
1551
1552 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1553     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1554 fi
1555
1556 # Do per-EGL platform setups and checks
1557 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1558 for plat in $egl_platforms; do
1559         case "$plat" in
1560         wayland)
1561                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1562                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1563
1564                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1565                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1566                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1567                 ;;
1568
1569         x11)
1570                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1571                 ;;
1572
1573         drm)
1574                 test "x$enable_gbm" = "xno" &&
1575                         AC_MSG_ERROR([EGL platform drm needs gbm])
1576                 test "x$have_libdrm" != xyes &&
1577                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1578                 ;;
1579
1580         android|fbdev|gdi|null)
1581                 ;;
1582
1583         *)
1584                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1585                 ;;
1586         esac
1587
1588         case "$plat$need_pci_id$have_pci_id" in
1589                 waylandyesno|drmyesno)
1590                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1591         esac
1592 done
1593
1594 # libEGL wants to default to the first platform specified in
1595 # ./configure.  parse that here.
1596 if test "x$egl_platforms" != "x"; then
1597     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1598     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1599 else
1600     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1601 fi
1602
1603 if echo "$egl_platforms" | grep -q 'x11'; then
1604     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1605     NEED_WINSYS_XLIB=yes
1606 fi
1607 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1608 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1609 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1610 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1611 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1612
1613 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1614
1615 AC_SUBST([EGL_NATIVE_PLATFORM])
1616 AC_SUBST([EGL_CFLAGS])
1617
1618 # If we don't have the X11 platform, set this define so we don't try to include
1619 # the X11 headers.
1620 if ! echo "$egl_platforms" | grep -q 'x11'; then
1621     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1622     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1623 fi
1624
1625 AC_ARG_WITH([egl-driver-dir],
1626     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1627                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1628     [EGL_DRIVER_INSTALL_DIR="$withval"],
1629     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1630 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1631
1632 AC_ARG_WITH([max-width],
1633     [AS_HELP_STRING([--with-max-width=N],
1634                     [Maximum framebuffer width (4096)])],
1635     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1636      AS_IF([test "${withval}" -gt "4096"],
1637            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1638 )
1639 AC_ARG_WITH([max-height],
1640     [AS_HELP_STRING([--with-max-height=N],
1641                     [Maximum framebuffer height (4096)])],
1642     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1643      AS_IF([test "${withval}" -gt "4096"],
1644            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1645 )
1646
1647 dnl
1648 dnl Gallium LLVM
1649 dnl
1650 AC_ARG_ENABLE([gallium-llvm],
1651     [AS_HELP_STRING([--enable-gallium-llvm],
1652         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1653     [enable_gallium_llvm="$enableval"],
1654     [enable_gallium_llvm=auto])
1655
1656 AC_ARG_ENABLE([llvm-shared-libs],
1657     [AS_HELP_STRING([--enable-llvm-shared-libs],
1658         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1659     [enable_llvm_shared_libs="$enableval"],
1660     [enable_llvm_shared_libs=yes])
1661
1662 AC_ARG_WITH([llvm-prefix],
1663     [AS_HELP_STRING([--with-llvm-prefix],
1664         [Prefix for LLVM installations in non-standard locations])],
1665     [llvm_prefix="$withval"],
1666     [llvm_prefix=''])
1667
1668
1669 # Call this inside ` ` to get the return value.
1670 # $1 is the llvm-config command with arguments.
1671 strip_unwanted_llvm_flags() {
1672     # Use \> (marks the end of the word)
1673     echo `$1` | sed \
1674         -e 's/-DNDEBUG\>//g' \
1675         -e 's/-pedantic\>//g' \
1676         -e 's/-Wcovered-switch-default\>//g' \
1677         -e 's/-O.\>//g' \
1678         -e 's/-g\>//g' \
1679         -e 's/-Wall\>//g' \
1680         -e 's/-Wcast-qual\>//g' \
1681         -e 's/-Woverloaded-virtual\>//g' \
1682         -e 's/-fcolor-diagnostics\>//g' \
1683         -e 's/-fdata-sections\>//g' \
1684         -e 's/-ffunction-sections\>//g' \
1685         -e 's/-fno-exceptions\>//g' \
1686         -e 's/-fomit-frame-pointer\>//g' \
1687         -e 's/-fvisibility-inlines-hidden\>//g' \
1688         -e 's/-fPIC\>//g' \
1689         -e 's/-fstack-protector-strong\>//g'
1690 }
1691
1692
1693 if test -z "$with_gallium_drivers"; then
1694     enable_gallium_llvm=no
1695 fi
1696 if test "x$enable_gallium_llvm" = xauto; then
1697     case "$host_cpu" in
1698     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1699     esac
1700 fi
1701 if test "x$enable_gallium_llvm" = xyes; then
1702     if test -n "$llvm_prefix"; then
1703         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1704     else
1705         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1706     fi
1707
1708     if test "x$LLVM_CONFIG" != xno; then
1709         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1710         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1711         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1712         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1713         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1714         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1715         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1716         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1717
1718         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1719             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1720         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1721             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1722
1723         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1724         dnl llvm-config.h
1725         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1726             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1727             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1728
1729         if test -n "${LLVM_VERSION_MAJOR}"; then
1730             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1731         else
1732             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1733         fi
1734
1735         LLVM_REQUIRED_VERSION_MAJOR="3"
1736         LLVM_REQUIRED_VERSION_MINOR="1"
1737         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1738             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1739         fi
1740
1741         LLVM_COMPONENTS="engine bitwriter"
1742         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1743             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1744         fi
1745
1746         if test "x$enable_opencl" = xyes; then
1747             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1748             # LLVM 3.3 >= 177971 requires IRReader
1749             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1750                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1751             fi
1752             # LLVM 3.4 requires Option
1753             if $LLVM_CONFIG --components | grep -qw 'option'; then
1754                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1755             fi
1756             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1757             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1758                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1759             fi
1760             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1761                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1762             fi
1763         fi
1764         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1765         MESA_LLVM=1
1766
1767         dnl Check for Clang internal headers
1768         if test "x$enable_opencl" = xyes; then
1769             if test -z "$CLANG_LIBDIR"; then
1770                 CLANG_LIBDIR=${LLVM_LIBDIR}
1771             fi
1772             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1773             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1774                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1775         fi
1776     else
1777         MESA_LLVM=0
1778         LLVM_VERSION_INT=0
1779     fi
1780 else
1781     MESA_LLVM=0
1782     LLVM_VERSION_INT=0
1783 fi
1784
1785 dnl Directory for XVMC libs
1786 AC_ARG_WITH([xvmc-libdir],
1787     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1788         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1789     [XVMC_LIB_INSTALL_DIR="$withval"],
1790     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1791 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1792
1793 dnl
1794 dnl Gallium Tests
1795 dnl
1796 if test "x$enable_gallium_tests" = xyes; then
1797     enable_gallium_loader=yes
1798 fi
1799 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1800
1801 if test "x$enable_gallium_loader" = xyes; then
1802     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1803 fi
1804 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1805
1806 dnl Directory for VDPAU libs
1807 AC_ARG_WITH([vdpau-libdir],
1808     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1809         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1810     [VDPAU_LIB_INSTALL_DIR="$withval"],
1811     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1812 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1813
1814 OMX_LIB_INSTALL_DIR_DEFAULT=''
1815 if test "x$enable_omx" = xyes; then
1816     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1817 fi
1818
1819 AC_ARG_WITH([omx-libdir],
1820     [AS_HELP_STRING([--with-omx-libdir=DIR],
1821         [directory for the OMX libraries])],
1822     [OMX_LIB_INSTALL_DIR="$withval"],
1823     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1824 AC_SUBST([OMX_LIB_INSTALL_DIR])
1825
1826 dnl Directory for OpenCL libs
1827 AC_ARG_WITH([opencl-libdir],
1828     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1829         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1830     [OPENCL_LIB_INSTALL_DIR="$withval"],
1831     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1832 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1833
1834 dnl
1835 dnl Gallium helper functions
1836 dnl
1837 gallium_check_st() {
1838     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1839          if test "x$have_libdrm" != xyes; then
1840             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1841          fi
1842          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1843     fi
1844     if test "x$enable_dri" = xyes && test -n "$2"; then
1845          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1846     fi
1847     if test "x$enable_xa" = xyes && test -n "$3"; then
1848          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1849     fi
1850     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1851          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1852     fi
1853     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1854          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1855     fi
1856     if test "x$enable_omx" = xyes && test "x$6" != x; then
1857          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1858     fi
1859 }
1860
1861 gallium_require_llvm() {
1862     if test "x$MESA_LLVM" = x0; then
1863         case "$host_cpu" in
1864         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1865         esac
1866     fi
1867 }
1868
1869 gallium_require_drm_loader() {
1870     if test "x$enable_gallium_loader" = xyes; then
1871         if test "x$need_pci_id$have_pci_id" = xyesno; then
1872             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1873         fi
1874         if test "x$have_libdrm" != xyes; then
1875             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1876         fi
1877         enable_gallium_drm_loader=yes
1878     fi
1879 }
1880
1881 require_egl_drm() {
1882     case "$with_egl_platforms" in
1883         *drm*)
1884             ;;
1885          *)
1886             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1887             ;;
1888     esac
1889     if test "x$enable_gbm" != xyes; then
1890             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1891     fi
1892 }
1893
1894 radeon_llvm_check() {
1895     if test "x$enable_gallium_llvm" != "xyes"; then
1896         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1897     fi
1898     LLVM_REQUIRED_VERSION_MAJOR="3"
1899     LLVM_REQUIRED_VERSION_MINOR="3"
1900     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1901         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1902     fi
1903     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1904         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1905                       sources with the --enable-experimental-targets=R600
1906                       configure flag])
1907     fi
1908     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1909     NEED_RADEON_LLVM=yes
1910     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1911                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1912 }
1913
1914 dnl Gallium drivers
1915 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1916         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1917     NEED_NONNULL_WINSYS=yes
1918 fi
1919 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1920
1921 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1922 if test -n "$with_gallium_drivers"; then
1923     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1924     for driver in $gallium_drivers; do
1925         case "x$driver" in
1926         xsvga)
1927             HAVE_GALLIUM_SVGA=yes
1928             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1929             gallium_require_drm_loader
1930             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1931             ;;
1932         xi915)
1933             HAVE_GALLIUM_I915=yes
1934             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1935             gallium_require_drm_loader
1936             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1937             if test "x$MESA_LLVM" = x1; then
1938                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1939             fi
1940             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1941             gallium_check_st "i915/drm" "dri-i915"
1942             DRICOMMON_NEED_LIBDRM=yes
1943             ;;
1944         xilo)
1945             HAVE_GALLIUM_ILO=yes
1946             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1947             gallium_require_drm_loader
1948             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1949             gallium_check_st "intel/drm" "dri-ilo"
1950             DRICOMMON_NEED_LIBDRM=yes
1951             ;;
1952         xr300)
1953             HAVE_GALLIUM_R300=yes
1954             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1955             gallium_require_drm_loader
1956             gallium_require_llvm "Gallium R300"
1957             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1958             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1959             DRICOMMON_NEED_LIBDRM=yes
1960             ;;
1961         xr600)
1962             HAVE_GALLIUM_R600=yes
1963             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1964             gallium_require_drm_loader
1965             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1966             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1967                 radeon_llvm_check "r600g"
1968                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1969             fi
1970             if test "x$enable_r600_llvm" = xyes; then
1971                 USE_R600_LLVM_COMPILER=yes;
1972             fi
1973             if test "x$enable_opencl" = xyes; then
1974                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1975             fi
1976             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1977             DRICOMMON_NEED_LIBDRM=yes
1978             ;;
1979         xradeonsi)
1980             HAVE_GALLIUM_RADEONSI=yes
1981             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1982             gallium_require_drm_loader
1983             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1984             radeon_llvm_check "radeonsi"
1985             require_egl_drm "radeonsi"
1986             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1987             DRICOMMON_NEED_LIBDRM=yes
1988             ;;
1989         xnouveau)
1990             HAVE_GALLIUM_NOUVEAU=yes
1991             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1992             gallium_require_drm_loader
1993             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1994             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1995             DRICOMMON_NEED_LIBDRM=yes
1996             ;;
1997         xfreedreno)
1998             HAVE_GALLIUM_FREEDRENO=yes
1999             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2000             gallium_require_drm_loader
2001             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
2002             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
2003             DRICOMMON_NEED_LIBDRM=yes
2004             ;;
2005         xswrast)
2006             HAVE_GALLIUM_SOFTPIPE=yes
2007             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2008             if test "x$MESA_LLVM" = x1; then
2009                 HAVE_GALLIUM_LLVMPIPE=yes
2010                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2011             fi
2012
2013             if test "x$enable_dri" = xyes; then
2014                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2015             fi
2016             ;;
2017         *)
2018             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2019             ;;
2020         esac
2021     done
2022 fi
2023
2024 dnl Set LLVM_LIBS - This is done after the driver configuration so
2025 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2026 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2027 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2028 dnl this was causing the same libraries to be appear multiple times
2029 dnl in LLVM_LIBS.
2030
2031 if test "x$MESA_LLVM" != x0; then
2032
2033     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2034
2035     if test "x$enable_llvm_shared_libs" = xyes; then
2036         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2037         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2038         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2039
2040         if test "x$llvm_have_one_so" = xyes; then
2041             dnl LLVM was built using auto*, so there is only one shared object.
2042             LLVM_LIBS="-l$LLVM_SO_NAME"
2043         else
2044             dnl If LLVM was built with CMake, there will be one shared object per
2045             dnl component.
2046             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2047                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2048         Please make sure you have built llvm with the --enable-shared option
2049         and that your llvm libraries are installed in $LLVM_LIBDIR
2050         If you have installed your llvm libraries to a different directory you
2051         can use the --with-llvm-prefix= configure flag to specify this directory.
2052         NOTE: Mesa is attempting to use llvm shared libraries by default.
2053         If you do not want to build with llvm shared libraries and instead want to
2054         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2055         invocation and rebuild.])])
2056
2057            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2058            dnl install uses a shared object for each compoenent and we have
2059            dnl already added all of these objects to LLVM_LIBS.
2060         fi
2061     else
2062         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2063     fi
2064 fi
2065
2066 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2067 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2068 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2069 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2070 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2071 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2072 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2073                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2074 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2075 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2076 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2077 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2078
2079 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2080                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
2081                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2082 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2083                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2084                                                   && test "x$MESA_LLVM" = x1)
2085
2086 # NOTE: anything using xcb or other client side libs ends up in separate
2087 #       _CLIENT variables.  The pipe loader is built in two variants,
2088 #       one that is standalone and does not link any x client libs (for
2089 #       use by XA tracker in particular, but could be used in any case
2090 #       where communication with xserver is not desired).
2091 if test "x$enable_gallium_loader" = xyes; then
2092     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2093
2094     if test "x$NEED_WINSYS_XLIB" = xyes; then
2095         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2096     fi
2097
2098     if test "x$enable_dri" = xyes; then
2099         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2100     fi
2101
2102     if test "x$enable_gallium_drm_loader" = xyes; then
2103         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2104         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2105                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2106         if test "x$pipe_loader_have_xcb" = xyes; then
2107             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2108             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2109         fi
2110     fi
2111
2112     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2113     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2114
2115     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2116     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2117     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2118     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2119 fi
2120
2121 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2122 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2123 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2124 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2125 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2126 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2127
2128 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2129                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2130                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2131                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2132 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2133                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2134 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2135 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2136 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2137 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2138 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2139 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2140 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2141
2142 AC_SUBST([ELF_LIB])
2143
2144 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2145 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2146 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2147 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2148 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2149
2150 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2151 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2152 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2153
2154 AC_SUBST([VDPAU_MAJOR], 1)
2155 AC_SUBST([VDPAU_MINOR], 0)
2156
2157 AC_SUBST([XVMC_MAJOR], 1)
2158 AC_SUBST([XVMC_MINOR], 0)
2159
2160 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2161 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2162 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2163 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2164
2165 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2166 AC_SUBST([XA_MINOR], $XA_MINOR)
2167 AC_SUBST([XA_TINY], $XA_TINY)
2168 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2169
2170 dnl Restore LDFLAGS and CPPFLAGS
2171 LDFLAGS="$_SAVE_LDFLAGS"
2172 CPPFLAGS="$_SAVE_CPPFLAGS"
2173
2174 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2175 if test "x$acv_mesa_CLANG" = xyes; then
2176     CFLAGS="$CFLAGS -Qunused-arguments"
2177     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2178 fi
2179
2180 dnl Add user CFLAGS and CXXFLAGS
2181 CFLAGS="$CFLAGS $USER_CFLAGS"
2182 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2183
2184 dnl Substitute the config
2185 AC_CONFIG_FILES([Makefile
2186                 src/Makefile
2187                 src/egl/drivers/dri2/Makefile
2188                 src/egl/main/Makefile
2189                 src/egl/main/egl.pc
2190                 src/egl/wayland/Makefile
2191                 src/egl/wayland/wayland-drm/Makefile
2192                 src/egl/wayland/wayland-egl/Makefile
2193                 src/egl/wayland/wayland-egl/wayland-egl.pc
2194                 src/gallium/auxiliary/Makefile
2195                 src/gallium/auxiliary/pipe-loader/Makefile
2196                 src/gallium/drivers/Makefile
2197                 src/gallium/drivers/freedreno/Makefile
2198                 src/gallium/drivers/galahad/Makefile
2199                 src/gallium/drivers/i915/Makefile
2200                 src/gallium/drivers/identity/Makefile
2201                 src/gallium/drivers/ilo/Makefile
2202                 src/gallium/drivers/llvmpipe/Makefile
2203                 src/gallium/drivers/noop/Makefile
2204                 src/gallium/drivers/nouveau/Makefile
2205                 src/gallium/drivers/r300/Makefile
2206                 src/gallium/drivers/r600/Makefile
2207                 src/gallium/drivers/radeon/Makefile
2208                 src/gallium/drivers/radeonsi/Makefile
2209                 src/gallium/drivers/rbug/Makefile
2210                 src/gallium/drivers/softpipe/Makefile
2211                 src/gallium/drivers/svga/Makefile
2212                 src/gallium/drivers/trace/Makefile
2213                 src/gallium/state_trackers/Makefile
2214                 src/gallium/state_trackers/clover/Makefile
2215                 src/gallium/state_trackers/dri/Makefile
2216                 src/gallium/state_trackers/dri/drm/Makefile
2217                 src/gallium/state_trackers/dri/sw/Makefile
2218                 src/gallium/state_trackers/egl/Makefile
2219                 src/gallium/state_trackers/gbm/Makefile
2220                 src/gallium/state_trackers/glx/xlib/Makefile
2221                 src/gallium/state_trackers/omx/Makefile
2222                 src/gallium/state_trackers/osmesa/Makefile
2223                 src/gallium/state_trackers/vdpau/Makefile
2224                 src/gallium/state_trackers/vega/Makefile
2225                 src/gallium/state_trackers/xa/Makefile
2226                 src/gallium/state_trackers/xvmc/Makefile
2227                 src/gallium/targets/Makefile
2228                 src/gallium/targets/dri-freedreno/Makefile
2229                 src/gallium/targets/dri-i915/Makefile
2230                 src/gallium/targets/dri-ilo/Makefile
2231                 src/gallium/targets/dri-nouveau/Makefile
2232                 src/gallium/targets/dri-swrast/Makefile
2233                 src/gallium/targets/dri-vmwgfx/Makefile
2234                 src/gallium/targets/egl-static/Makefile
2235                 src/gallium/targets/gbm/Makefile
2236                 src/gallium/targets/opencl/Makefile
2237                 src/gallium/targets/xa/Makefile
2238                 src/gallium/targets/xa/xatracker.pc
2239                 src/gallium/targets/omx-nouveau/Makefile
2240                 src/gallium/targets/osmesa/Makefile
2241                 src/gallium/targets/osmesa/osmesa.pc
2242                 src/gallium/targets/pipe-loader/Makefile
2243                 src/gallium/targets/radeonsi/dri/Makefile
2244                 src/gallium/targets/radeonsi/omx/Makefile
2245                 src/gallium/targets/radeonsi/vdpau/Makefile
2246                 src/gallium/targets/r300/dri/Makefile
2247                 src/gallium/targets/r600/dri/Makefile
2248                 src/gallium/targets/r600/omx/Makefile
2249                 src/gallium/targets/r600/vdpau/Makefile
2250                 src/gallium/targets/r600/xvmc/Makefile
2251                 src/gallium/targets/libgl-xlib/Makefile
2252                 src/gallium/targets/vdpau-nouveau/Makefile
2253                 src/gallium/targets/xvmc-nouveau/Makefile
2254                 src/gallium/tests/trivial/Makefile
2255                 src/gallium/tests/unit/Makefile
2256                 src/gallium/winsys/Makefile
2257                 src/gallium/winsys/freedreno/drm/Makefile
2258                 src/gallium/winsys/i915/drm/Makefile
2259                 src/gallium/winsys/i915/sw/Makefile
2260                 src/gallium/winsys/intel/drm/Makefile
2261                 src/gallium/winsys/nouveau/drm/Makefile
2262                 src/gallium/winsys/radeon/drm/Makefile
2263                 src/gallium/winsys/svga/drm/Makefile
2264                 src/gallium/winsys/sw/dri/Makefile
2265                 src/gallium/winsys/sw/fbdev/Makefile
2266                 src/gallium/winsys/sw/null/Makefile
2267                 src/gallium/winsys/sw/wayland/Makefile
2268                 src/gallium/winsys/sw/wrapper/Makefile
2269                 src/gallium/winsys/sw/xlib/Makefile
2270                 src/gbm/Makefile
2271                 src/gbm/main/gbm.pc
2272                 src/glsl/Makefile
2273                 src/glx/Makefile
2274                 src/glx/apple/Makefile
2275                 src/glx/tests/Makefile
2276                 src/gtest/Makefile
2277                 src/loader/Makefile
2278                 src/mapi/Makefile
2279                 src/mapi/es1api/Makefile
2280                 src/mapi/es1api/glesv1_cm.pc
2281                 src/mapi/es2api/Makefile
2282                 src/mapi/es2api/glesv2.pc
2283                 src/mapi/glapi/Makefile
2284                 src/mapi/glapi/gen/Makefile
2285                 src/mapi/glapi/tests/Makefile
2286                 src/mapi/shared-glapi/Makefile
2287                 src/mapi/shared-glapi/tests/Makefile
2288                 src/mapi/vgapi/Makefile
2289                 src/mapi/vgapi/vg.pc
2290                 src/mesa/Makefile
2291                 src/mesa/gl.pc
2292                 src/mesa/drivers/dri/dri.pc
2293                 src/mesa/drivers/dri/common/Makefile
2294                 src/mesa/drivers/dri/common/xmlpool/Makefile
2295                 src/mesa/drivers/dri/i915/Makefile
2296                 src/mesa/drivers/dri/i965/Makefile
2297                 src/mesa/drivers/dri/Makefile
2298                 src/mesa/drivers/dri/nouveau/Makefile
2299                 src/mesa/drivers/dri/r200/Makefile
2300                 src/mesa/drivers/dri/radeon/Makefile
2301                 src/mesa/drivers/dri/swrast/Makefile
2302                 src/mesa/drivers/osmesa/Makefile
2303                 src/mesa/drivers/osmesa/osmesa.pc
2304                 src/mesa/drivers/x11/Makefile
2305                 src/mesa/main/tests/Makefile
2306                 src/mesa/main/tests/hash_table/Makefile])
2307
2308 dnl Sort the dirs alphabetically
2309 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2310 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2311 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2312 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2313
2314 AC_OUTPUT
2315
2316 dnl
2317 dnl Output some configuration info for the user
2318 dnl
2319 echo ""
2320 echo "        prefix:          $prefix"
2321 echo "        exec_prefix:     $exec_prefix"
2322 echo "        libdir:          $libdir"
2323 echo "        includedir:      $includedir"
2324
2325 dnl API info
2326 echo ""
2327 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2328 echo "        OpenVG:          $enable_openvg"
2329
2330 dnl Driver info
2331 echo ""
2332 case "x$enable_osmesa$enable_gallium_osmesa" in
2333 xnoyes)
2334         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2335         ;;
2336 xyesno)
2337         echo "        OSMesa:          lib$OSMESA_LIB"
2338         ;;
2339 xnono)
2340         echo "        OSMesa:          no"
2341         ;;
2342 esac
2343
2344 echo ""
2345 if test "x$enable_dri" != xno; then
2346         echo "        DRI platform:    $dri_platform"
2347         if test -z "$DRI_DIRS"; then
2348             echo "        DRI drivers:     no"
2349         else
2350             echo "        DRI drivers:     $DRI_DIRS"
2351         fi
2352         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2353 fi
2354
2355 case "x$enable_glx$enable_xlib_glx" in
2356 xyesyes)
2357     echo "        GLX:             Xlib-based"
2358     ;;
2359 xyesno)
2360     echo "        GLX:             DRI-based"
2361     ;;
2362 *)
2363     echo "        GLX:             $enable_glx"
2364     ;;
2365 esac
2366
2367 dnl EGL
2368 echo ""
2369 echo "        EGL:             $enable_egl"
2370 if test "$enable_egl" = yes; then
2371     echo "        EGL platforms:   $egl_platforms"
2372
2373     egl_drivers=""
2374     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2375         egl_drivers="$egl_drivers builtin:egl_dri2"
2376     fi
2377
2378     if test "x$enable_gallium_egl" = xyes; then
2379         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2380         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2381     else
2382         echo "        EGL drivers:    $egl_drivers"
2383     fi
2384 fi
2385
2386 echo ""
2387 if test "x$MESA_LLVM" = x1; then
2388     echo "        llvm:            yes"
2389     echo "        llvm-config:     $LLVM_CONFIG"
2390     echo "        llvm-version:    $LLVM_VERSION"
2391 else
2392     echo "        llvm:            no"
2393 fi
2394
2395 echo ""
2396 if test -n "$with_gallium_drivers"; then
2397     echo "        Gallium:         yes"
2398     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2399     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2400     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2401     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2402 else
2403     echo "        Gallium:         no"
2404 fi
2405
2406
2407 dnl Libraries
2408 echo ""
2409 echo "        Shared libs:     $enable_shared"
2410 echo "        Static libs:     $enable_static"
2411 echo "        Shared-glapi:    $enable_shared_glapi"
2412
2413 dnl Compiler options
2414 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2415 cflags=`echo $CFLAGS | \
2416     $SED 's/^ *//;s/  */ /;s/ *$//'`
2417 cxxflags=`echo $CXXFLAGS | \
2418     $SED 's/^ *//;s/  */ /;s/ *$//'`
2419 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2420 echo ""
2421 echo "        CFLAGS:          $cflags"
2422 echo "        CXXFLAGS:        $cxxflags"
2423 echo "        Macros:          $defines"
2424 echo ""
2425 if test "x$MESA_LLVM" = x1; then
2426     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2427     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2428     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2429     echo ""
2430 fi
2431 echo "        PYTHON2:         $PYTHON2"
2432
2433 echo ""
2434 echo "        Run '${MAKE-make}' to build Mesa"
2435 echo ""