configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.68
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 LIBUDEV_REQUIRED=151
  83 GLPROTO_REQUIRED=1.4.14
  84 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  85 LIBVA_REQUIRED=0.38.0
  86 VDPAU_REQUIRED=1.1
  87 WAYLAND_REQUIRED=1.2.0
  88 XCB_REQUIRED=1.9.3
  89 XCBDRI2_REQUIRED=1.8
  90 XCBGLX_REQUIRED=1.8.1
  91 XSHMFENCE_REQUIRED=1.1
  92 XVMC_REQUIRED=1.0.6
  93 PYTHON_MAKO_REQUIRED=0.8.0
  94 LIBSENSORS_REQUIRED=4.0.0
  95
  96 dnl Check for progs
  97 AC_PROG_CPP
  98 AC_PROG_CC
  99 AC_PROG_CXX
 100 AM_PROG_CC_C_O
 101 AM_PROG_AS
 102 AX_CHECK_GNU_MAKE
 103 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 104 AC_PROG_SED
 105 AC_PROG_MKDIR_P
 106
 107 AC_SYS_LARGEFILE
 108
 109 LT_PREREQ([2.2])
 110 LT_INIT([disable-static])
 111
 112 AC_CHECK_PROG(RM, rm, [rm -f])
 113 AC_CHECK_PROG(XXD, xxd, [xxd])
 114
 115 AX_PROG_BISON([],
 116               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 117                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 118 AX_PROG_FLEX([],
 119              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 120                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 121
 122 AC_CHECK_PROG(INDENT, indent, indent, cat)
 123 if test "x$INDENT" != "xcat"; then
 124     # Only GNU indent is supported
 125     INDENT_VERSION=`indent --version | grep GNU`
 126     if test $? -eq 0; then
 127        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 128     else
 129        INDENT="cat"
 130     fi
 131 fi
 132
 133 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 134
 135 if test -z "$PYTHON2"; then
 136     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 137         AC_MSG_ERROR([Python not found - unable to generate sources])
 138     fi
 139 else
 140     if test "x$acv_mako_found" = xno; then
 141         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 142             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 143         fi
 144     fi
 145 fi
 146
 147 AC_PROG_INSTALL
 148
 149 dnl We need a POSIX shell for parts of the build. Assume we have one
 150 dnl in most cases.
 151 case "$host_os" in
 152 solaris*)
 153     # Solaris /bin/sh is too old/non-POSIX compliant
 154     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 155     SHELL="$POSIX_SHELL"
 156     ;;
 157 esac
 158
 159 dnl clang is mostly GCC-compatible, but its version is much lower,
 160 dnl so we have to check for it.
 161 AC_MSG_CHECKING([if compiling with clang])
 162
 163 AC_COMPILE_IFELSE(
 164 [AC_LANG_PROGRAM([], [[
 165 #ifndef __clang__
 166        not clang
 167 #endif
 168 ]])],
 169 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 170
 171 AC_MSG_RESULT([$acv_mesa_CLANG])
 172
 173 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 174 dnl versions are explictly not supported.
 175 GEN_ASM_OFFSETS=no
 176 USE_GNU99=no
 177 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 178     AC_MSG_CHECKING([whether gcc version is sufficient])
 179     major=0
 180     minor=0
 181
 182     GCC_VERSION=`$CC -dumpversion`
 183     if test $? -eq 0; then
 184         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 185         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 186     fi
 187
 188     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 189         AC_MSG_RESULT([no])
 190         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 191     else
 192         AC_MSG_RESULT([yes])
 193     fi
 194
 195     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 196         USE_GNU99=yes
 197     fi
 198     if test "x$cross_compiling" = xyes; then
 199         GEN_ASM_OFFSETS=yes
 200     fi
 201 fi
 202
 203 dnl We don't support building Mesa with Sun C compiler
 204 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 205 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 206 if test "x$SUNCC" = xyes; then
 207     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 208 fi
 209
 210 dnl Check for compiler builtins
 211 AX_GCC_BUILTIN([__builtin_bswap32])
 212 AX_GCC_BUILTIN([__builtin_bswap64])
 213 AX_GCC_BUILTIN([__builtin_clz])
 214 AX_GCC_BUILTIN([__builtin_clzll])
 215 AX_GCC_BUILTIN([__builtin_ctz])
 216 AX_GCC_BUILTIN([__builtin_expect])
 217 AX_GCC_BUILTIN([__builtin_ffs])
 218 AX_GCC_BUILTIN([__builtin_ffsll])
 219 AX_GCC_BUILTIN([__builtin_popcount])
 220 AX_GCC_BUILTIN([__builtin_popcountll])
 221 AX_GCC_BUILTIN([__builtin_unreachable])
 222
 223 AX_GCC_FUNC_ATTRIBUTE([const])
 224 AX_GCC_FUNC_ATTRIBUTE([flatten])
 225 AX_GCC_FUNC_ATTRIBUTE([format])
 226 AX_GCC_FUNC_ATTRIBUTE([malloc])
 227 AX_GCC_FUNC_ATTRIBUTE([packed])
 228 AX_GCC_FUNC_ATTRIBUTE([pure])
 229 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 230 AX_GCC_FUNC_ATTRIBUTE([unused])
 231 AX_GCC_FUNC_ATTRIBUTE([visibility])
 232 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 233 AX_GCC_FUNC_ATTRIBUTE([weak])
 234
 235 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 236
 237 dnl Make sure the pkg-config macros are defined
 238 m4_ifndef([PKG_PROG_PKG_CONFIG],
 239     [m4_fatal([Could not locate the pkg-config autoconf macros.
 240   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 241   are in a different location, try setting the environment variable
 242   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 243 PKG_PROG_PKG_CONFIG()
 244
 245 dnl LIB_DIR - library basename
 246 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 247 AC_SUBST([LIB_DIR])
 248
 249 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 250 _SAVE_LDFLAGS="$LDFLAGS"
 251 _SAVE_CPPFLAGS="$CPPFLAGS"
 252
 253 dnl Compiler macros
 254 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 255 AC_SUBST([DEFINES])
 256 android=no
 257 case "$host_os" in
 258 *-android)
 259     android=yes
 260     ;;
 261 linux*|*-gnu*|gnu*|cygwin*)
 262     DEFINES="$DEFINES -D_GNU_SOURCE"
 263     ;;
 264 solaris*)
 265     DEFINES="$DEFINES -DSVR4"
 266     ;;
 267 esac
 268
 269 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 270
 271 dnl Add flags for gcc and g++
 272 if test "x$GCC" = xyes; then
 273     CFLAGS="$CFLAGS -Wall"
 274
 275     if test "x$USE_GNU99" = xyes; then
 276         CFLAGS="$CFLAGS -std=gnu99"
 277     else
 278         CFLAGS="$CFLAGS -std=c99"
 279     fi
 280
 281     # Enable -Werror=implicit-function-declaration and
 282     # -Werror=missing-prototypes, if available, or otherwise, just
 283     # -Wmissing-prototypes.  This is particularly useful to avoid
 284     # generating a loadable driver module that has undefined symbols.
 285     save_CFLAGS="$CFLAGS"
 286     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 287     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 288     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 289     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 290                    AC_MSG_RESULT([yes]),
 291                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 292                     AC_MSG_RESULT([no])]);
 293
 294     # Enable -fvisibility=hidden if using a gcc that supports it
 295     save_CFLAGS="$CFLAGS"
 296     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 297     VISIBILITY_CFLAGS="-fvisibility=hidden"
 298     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 299     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 300                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 301
 302     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 303     CFLAGS=$save_CFLAGS
 304
 305     # We don't want floating-point math functions to set errno or trap
 306     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 307
 308     # Flags to help ensure that certain portions of the code -- and only those
 309     # portions -- can be built with MSVC:
 310     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 311     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 312     #   supports most of C99)
 313     # - the rest has no compiler compiler restrictions
 314     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 315     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 316
 317     # Enable -Werror=vla if compiler supports it
 318     save_CFLAGS="$CFLAGS"
 319     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 320     CFLAGS="$CFLAGS -Werror=vla"
 321     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 322                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 323                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 324                     AC_MSG_RESULT([yes])],
 325                     AC_MSG_RESULT([no]));
 326     CFLAGS="$save_CFLAGS"
 327 fi
 328 if test "x$GXX" = xyes; then
 329     CXXFLAGS="$CXXFLAGS -Wall"
 330
 331     # Enable -fvisibility=hidden if using a gcc that supports it
 332     save_CXXFLAGS="$CXXFLAGS"
 333     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 334     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 335     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 336     AC_LANG_PUSH([C++])
 337     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 338                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 339     AC_LANG_POP([C++])
 340
 341     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 342     CXXFLAGS=$save_CXXFLAGS
 343
 344     # We don't want floating-point math functions to set errno or trap
 345     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 346 fi
 347
 348 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 349 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 350
 351 dnl even if the compiler appears to support it, using visibility attributes isn't
 352 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 353 case "$host_os" in
 354 cygwin*)
 355     VISIBILITY_CFLAGS=""
 356     VISIBILITY_CXXFLAGS=""
 357     ;;
 358 esac
 359
 360 AC_SUBST([VISIBILITY_CFLAGS])
 361 AC_SUBST([VISIBILITY_CXXFLAGS])
 362
 363 dnl
 364 dnl Optional flags, check for compiler support
 365 dnl
 366 SSE41_CFLAGS="-msse4.1"
 367 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 368 dnl stack, but on x86-32 such alignment is not guaranteed.
 369 case "$target_cpu" in
 370 i?86)
 371     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 372     ;;
 373 esac
 374 save_CFLAGS="$CFLAGS"
 375 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 376 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 377 #include <smmintrin.h>
 378 int param;
 379 int main () {
 380     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 381     c = _mm_max_epu32(a, b);
 382     return _mm_cvtsi128_si32(c);
 383 }]])], SSE41_SUPPORTED=1)
 384 CFLAGS="$save_CFLAGS"
 385 if test "x$SSE41_SUPPORTED" = x1; then
 386     DEFINES="$DEFINES -DUSE_SSE41"
 387 fi
 388 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 389 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 390
 391 dnl Check for new-style atomic builtins
 392 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 393 int main() {
 394     int n;
 395     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 396 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 397 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 398     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 399 fi
 400 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 401
 402 dnl Check for Endianness
 403 AC_C_BIGENDIAN(
 404    little_endian=no,
 405    little_endian=yes,
 406    little_endian=no,
 407    little_endian=no
 408 )
 409
 410 dnl Check for POWER8 Architecture
 411 PWR8_CFLAGS="-mpower8-vector"
 412 have_pwr8_intrinsics=no
 413 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 414 save_CFLAGS=$CFLAGS
 415 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 416 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 417 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 418 #error "Need GCC >= 4.8 for sane POWER8 support"
 419 #endif
 420 #include <altivec.h>
 421 int main () {
 422     vector unsigned char r;
 423     vector unsigned int v = vec_splat_u32 (1);
 424     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 425     return 0;
 426 }]])], have_pwr8_intrinsics=yes)
 427 CFLAGS=$save_CFLAGS
 428
 429 AC_ARG_ENABLE(pwr8,
 430    [AC_HELP_STRING([--disable-pwr8-inst],
 431                    [disable POWER8-specific instructions])],
 432    [enable_pwr8=$enableval], [enable_pwr8=auto])
 433
 434 if test "x$enable_pwr8" = xno ; then
 435    have_pwr8_intrinsics=disabled
 436 fi
 437
 438 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 439    DEFINES="$DEFINES -D_ARCH_PWR8"
 440    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 441    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 442 else
 443    PWR8_CFLAGS=
 444 fi
 445
 446 AC_MSG_RESULT($have_pwr8_intrinsics)
 447 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 448    AC_MSG_ERROR([POWER8 compiler support not detected])
 449 fi
 450
 451 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 452    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 453 fi
 454
 455 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 456
 457 dnl Can't have static and shared libraries, default to static if user
 458 dnl explicitly requested. If both disabled, set to static since shared
 459 dnl was explicitly requested.
 460 case "x$enable_static$enable_shared" in
 461 xyesyes)
 462     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 463     enable_shared=no
 464     ;;
 465 xnono)
 466     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 467     enable_shared=yes
 468     ;;
 469 esac
 470
 471 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 472
 473 dnl
 474 dnl other compiler options
 475 dnl
 476 AC_ARG_ENABLE([debug],
 477     [AS_HELP_STRING([--enable-debug],
 478         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 479     [enable_debug="$enableval"],
 480     [enable_debug=no]
 481 )
 482
 483 AC_ARG_ENABLE([profile],
 484     [AS_HELP_STRING([--enable-profile],
 485         [enable profiling of code @<:@default=disabled@:>@])],
 486     [enable_profile="$enableval"],
 487     [enable_profile=no]
 488 )
 489
 490 if test "x$enable_profile" = xyes; then
 491     DEFINES="$DEFINES -DPROFILE"
 492     if test "x$GCC" = xyes; then
 493         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 494     fi
 495     if test "x$GXX" = xyes; then
 496         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 497     fi
 498 fi
 499
 500 if test "x$enable_debug" = xyes; then
 501     DEFINES="$DEFINES -DDEBUG"
 502     if test "x$enable_profile" = xyes; then
 503         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 504     fi
 505     if test "x$GCC" = xyes; then
 506         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 507             CFLAGS="$CFLAGS -g"
 508         fi
 509         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 510             CFLAGS="$CFLAGS -O0"
 511         fi
 512     fi
 513     if test "x$GXX" = xyes; then
 514         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 515             CXXFLAGS="$CXXFLAGS -g"
 516         fi
 517         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 518             CXXFLAGS="$CXXFLAGS -O0"
 519         fi
 520     fi
 521 else
 522    DEFINES="$DEFINES -DNDEBUG"
 523 fi
 524
 525 DEFAULT_GL_LIB_NAME=GL
 526
 527 dnl
 528 dnl Check if linker supports -Bsymbolic
 529 dnl
 530 save_LDFLAGS=$LDFLAGS
 531 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 532 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 533 AC_LINK_IFELSE(
 534     [AC_LANG_SOURCE([int main() { return 0;}])],
 535     [AC_MSG_RESULT([yes])
 536         BSYMBOLIC="-Wl,-Bsymbolic";],
 537     [AC_MSG_RESULT([no])
 538         BSYMBOLIC="";])
 539 LDFLAGS=$save_LDFLAGS
 540
 541 AC_SUBST([BSYMBOLIC])
 542
 543 dnl
 544 dnl Check if linker supports garbage collection
 545 dnl
 546 save_LDFLAGS=$LDFLAGS
 547 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 548 AC_MSG_CHECKING([whether ld supports --gc-sections])
 549 AC_LINK_IFELSE(
 550     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 551     [AC_MSG_RESULT([yes])
 552         GC_SECTIONS="-Wl,--gc-sections";],
 553     [AC_MSG_RESULT([no])
 554         GC_SECTIONS="";])
 555 LDFLAGS=$save_LDFLAGS
 556
 557 AC_SUBST([GC_SECTIONS])
 558
 559 dnl
 560 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 561 dnl so when these flags are passed to ld via libtool the checks will fail
 562 dnl
 563 case "$host_os" in
 564 openbsd* | darwin* )
 565     LD_NO_UNDEFINED="" ;;
 566 *)
 567     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 568 esac
 569
 570 AC_SUBST([LD_NO_UNDEFINED])
 571
 572 dnl
 573 dnl Check if linker supports version scripts
 574 dnl
 575 AC_MSG_CHECKING([if the linker supports version-scripts])
 576 save_LDFLAGS=$LDFLAGS
 577 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 578 cat > conftest.map <<EOF
 579 VERSION_1 {
 580      global:
 581          main;
 582
 583      local:
 584          *;
 585 };
 586 EOF
 587 AC_LINK_IFELSE(
 588     [AC_LANG_SOURCE([int main() { return 0;}])],
 589     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 590     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 591 LDFLAGS=$save_LDFLAGS
 592 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 593
 594 dnl
 595 dnl Check if linker supports dynamic list files
 596 dnl
 597 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 598 save_LDFLAGS=$LDFLAGS
 599 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 600 cat > conftest.dyn <<EOF
 601 {
 602         radeon_drm_winsys_create;
 603 };
 604 EOF
 605 AC_LINK_IFELSE(
 606     [AC_LANG_SOURCE([int main() { return 0;}])],
 607     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 608     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 609 LDFLAGS=$save_LDFLAGS
 610 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 611
 612 dnl
 613 dnl compatibility symlinks
 614 dnl
 615 case "$host_os" in
 616 linux* )
 617     HAVE_COMPAT_SYMLINKS=yes ;;
 618 * )
 619     HAVE_COMPAT_SYMLINKS=no ;;
 620 esac
 621
 622 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 623
 624 DEFAULT_GL_LIB_NAME=GL
 625
 626 dnl
 627 dnl Libglvnd configuration
 628 dnl
 629 AC_ARG_ENABLE([libglvnd],
 630     [AS_HELP_STRING([--enable-libglvnd],
 631         [Build for libglvnd @<:@default=disabled@:>@])],
 632     [enable_libglvnd="$enableval"],
 633     [enable_libglvnd=no])
 634 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 635 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 636 if test "x$enable_libglvnd" = xyes ; then
 637     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 638     DEFAULT_GL_LIB_NAME=GLX_mesa
 639 fi
 640
 641 dnl
 642 dnl library names
 643 dnl
 644 dnl Unfortunately we need to do a few things that libtool can't help us with,
 645 dnl so we need some knowledge of shared library filenames:
 646 dnl
 647 dnl LIB_EXT is the extension used when creating symlinks for alternate
 648 dnl filenames for a shared library which will be dynamically loaded
 649 dnl
 650 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 651 dnl the file for a shared library we wish to link with
 652 dnl
 653 case "$host_os" in
 654 darwin* )
 655     LIB_EXT='dylib'
 656     IMP_LIB_EXT=$LIB_EXT
 657     ;;
 658 cygwin* )
 659     LIB_EXT='dll'
 660     IMP_LIB_EXT='dll.a'
 661     ;;
 662 aix* )
 663     LIB_EXT='a'
 664     IMP_LIB_EXT=$LIB_EXT
 665     ;;
 666 * )
 667     LIB_EXT='so'
 668     IMP_LIB_EXT=$LIB_EXT
 669     ;;
 670 esac
 671
 672 AC_SUBST([LIB_EXT])
 673
 674 AC_ARG_WITH([gl-lib-name],
 675   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 676     [specify GL library name @<:@default=GL@:>@])],
 677   [GL_LIB=$withval],
 678   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 679 AC_ARG_WITH([osmesa-lib-name],
 680   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 681     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 682   [OSMESA_LIB=$withval],
 683   [OSMESA_LIB=OSMesa])
 684 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 685 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 686
 687 dnl
 688 dnl Mangled Mesa support
 689 dnl
 690 AC_ARG_ENABLE([mangling],
 691   [AS_HELP_STRING([--enable-mangling],
 692     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 693   [enable_mangling="${enableval}"],
 694   [enable_mangling=no]
 695 )
 696 if test "x${enable_mangling}" = "xyes" ; then
 697   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 698   GL_LIB="Mangled${GL_LIB}"
 699   OSMESA_LIB="Mangled${OSMESA_LIB}"
 700 fi
 701 AC_SUBST([GL_LIB])
 702 AC_SUBST([OSMESA_LIB])
 703
 704 dnl
 705 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 706 dnl
 707 AC_ARG_ENABLE([texture-float],
 708     [AS_HELP_STRING([--enable-texture-float],
 709         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 710     [enable_texture_float="$enableval"],
 711     [enable_texture_float=no]
 712 )
 713 if test "x$enable_texture_float" = xyes; then
 714     AC_MSG_WARN([Floating-point textures enabled.])
 715     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 716     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 717 fi
 718
 719 dnl
 720 dnl Arch/platform-specific settings
 721 dnl
 722 AC_ARG_ENABLE([asm],
 723     [AS_HELP_STRING([--disable-asm],
 724         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 725     [enable_asm="$enableval"],
 726     [enable_asm=yes]
 727 )
 728 asm_arch=""
 729 AC_MSG_CHECKING([whether to enable assembly])
 730 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 731 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 732 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 733     case "$host_cpu" in
 734     i?86 | x86_64 | amd64)
 735         if test "x$host_cpu" != "x$target_cpu"; then
 736             enable_asm=no
 737             AC_MSG_RESULT([no, cross compiling])
 738         fi
 739         ;;
 740     esac
 741 fi
 742 # check for supported arches
 743 if test "x$enable_asm" = xyes; then
 744     case "$host_cpu" in
 745     i?86)
 746         case "$host_os" in
 747         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 748             asm_arch=x86
 749             ;;
 750         esac
 751         ;;
 752     x86_64|amd64)
 753         case "$host_os" in
 754         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 755             asm_arch=x86_64
 756             ;;
 757         esac
 758         ;;
 759     sparc*)
 760         case "$host_os" in
 761         linux*)
 762             asm_arch=sparc
 763             ;;
 764         esac
 765         ;;
 766     esac
 767
 768     case "$asm_arch" in
 769     x86)
 770         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 771         AC_MSG_RESULT([yes, x86])
 772         ;;
 773     x86_64|amd64)
 774         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 775         AC_MSG_RESULT([yes, x86_64])
 776         ;;
 777     sparc)
 778         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 779         AC_MSG_RESULT([yes, sparc])
 780         ;;
 781     *)
 782         AC_MSG_RESULT([no, platform not supported])
 783         ;;
 784     esac
 785 fi
 786
 787 AC_HEADER_MAJOR
 788 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 789 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 790 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 791 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 792
 793 dnl Check to see if dlopen is in default libraries (like Solaris, which
 794 dnl has it in libc), or if libdl is needed to get it.
 795 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 796     [AC_CHECK_LIB([dl], [dlopen],
 797        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 798 AC_SUBST([DLOPEN_LIBS])
 799
 800 dnl Check if that library also has dladdr
 801 save_LIBS="$LIBS"
 802 LIBS="$LIBS $DLOPEN_LIBS"
 803 AC_CHECK_FUNCS([dladdr])
 804 LIBS="$save_LIBS"
 805
 806 case "$host_os" in
 807 darwin*)
 808     ;;
 809 *)
 810     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 811                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 812                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 813     AC_SUBST([CLOCK_LIB])
 814     ;;
 815 esac
 816
 817 dnl See if posix_memalign is available
 818 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 819
 820 dnl Check for pthreads
 821 AX_PTHREAD
 822 if test "x$ax_pthread_ok" = xno; then
 823     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 824 fi
 825 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 826 dnl to -pthread, which causes problems if we need -lpthread to appear in
 827 dnl pkgconfig files.
 828 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 829
 830 dnl pthread-stubs is mandatory on targets where it exists
 831 case "$host_os" in
 832 cygwin* )
 833     pthread_stubs_possible="no"
 834     ;;
 835 * )
 836     pthread_stubs_possible="yes"
 837     ;;
 838 esac
 839
 840 if test "x$pthread_stubs_possible" = xyes; then
 841     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 842     AC_SUBST(PTHREADSTUBS_CFLAGS)
 843     AC_SUBST(PTHREADSTUBS_LIBS)
 844 fi
 845
 846 dnl SELinux awareness.
 847 AC_ARG_ENABLE([selinux],
 848     [AS_HELP_STRING([--enable-selinux],
 849         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 850     [MESA_SELINUX="$enableval"],
 851     [MESA_SELINUX=no])
 852 if test "x$enable_selinux" = "xyes"; then
 853     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 854         [AC_CHECK_HEADER([selinux/selinux.h],[],
 855                          [AC_MSG_ERROR([SELinux headers not found])])
 856          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 857                       [AC_MSG_ERROR([SELinux library not found])])
 858          SELINUX_LIBS="-lselinux"])
 859     DEFINES="$DEFINES -DMESA_SELINUX"
 860 fi
 861 AC_SUBST([SELINUX_CFLAGS])
 862 AC_SUBST([SELINUX_LIBS])
 863
 864 dnl Options for APIs
 865 AC_ARG_ENABLE([opengl],
 866     [AS_HELP_STRING([--disable-opengl],
 867         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 868     [enable_opengl="$enableval"],
 869     [enable_opengl=yes])
 870 AC_ARG_ENABLE([gles1],
 871     [AS_HELP_STRING([--disable-gles1],
 872         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 873     [enable_gles1="$enableval"],
 874     [enable_gles1=yes])
 875 AC_ARG_ENABLE([gles2],
 876     [AS_HELP_STRING([--disable-gles2],
 877         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 878     [enable_gles2="$enableval"],
 879     [enable_gles2=yes])
 880
 881 AC_ARG_ENABLE([dri],
 882     [AS_HELP_STRING([--enable-dri],
 883         [enable DRI modules @<:@default=enabled@:>@])],
 884     [enable_dri="$enableval"],
 885     [enable_dri=yes])
 886
 887 AC_ARG_ENABLE([gallium-extra-hud],
 888     [AS_HELP_STRING([--enable-gallium-extra-hud],
 889         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
 890     [enable_gallium_extra_hud="$enableval"],
 891     [enable_gallium_extra_hud=no])
 892 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
 893 if test "x$enable_gallium_extra_hud" = xyes ; then
 894     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
 895 fi
 896
 897 #TODO: no pkgconfig .pc available for libsensors.
 898 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
 899 AC_ARG_ENABLE([lmsensors],
 900     [AS_HELP_STRING([--enable-lmsensors],
 901         [enable HUD lmsensor support @<:@default=disabled@:>@])],
 902     [enable_lmsensors="$enableval"],
 903     [enable_lmsensors=no])
 904 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
 905 if test "x$enable_lmsensors" = xyes ; then
 906     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
 907     LIBSENSORS_LDFLAGS="-lsensors"
 908 else
 909     LIBSENSORS_LDFLAGS=""
 910 fi
 911 AC_SUBST(LIBSENSORS_LDFLAGS)
 912
 913 case "$host_os" in
 914 linux*)
 915     dri3_default=yes
 916     ;;
 917 *)
 918     dri3_default=no
 919     ;;
 920 esac
 921
 922 if test "x$enable_dri" = xno; then
 923     dri3_default=no
 924 fi
 925
 926 AC_ARG_ENABLE([dri3],
 927     [AS_HELP_STRING([--enable-dri3],
 928         [enable DRI3 @<:@default=auto@:>@])],
 929     [enable_dri3="$enableval"],
 930     [enable_dri3="$dri3_default"])
 931 AC_ARG_ENABLE([glx],
 932     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 933         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 934     [enable_glx="$enableval"],
 935     [enable_glx=yes])
 936 AC_ARG_ENABLE([osmesa],
 937     [AS_HELP_STRING([--enable-osmesa],
 938         [enable OSMesa library @<:@default=disabled@:>@])],
 939     [enable_osmesa="$enableval"],
 940     [enable_osmesa=no])
 941 AC_ARG_ENABLE([gallium-osmesa],
 942     [AS_HELP_STRING([--enable-gallium-osmesa],
 943         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 944     [enable_gallium_osmesa="$enableval"],
 945     [enable_gallium_osmesa=no])
 946 AC_ARG_ENABLE([egl],
 947     [AS_HELP_STRING([--disable-egl],
 948         [disable EGL library @<:@default=enabled@:>@])],
 949     [enable_egl="$enableval"],
 950     [enable_egl=yes])
 951
 952 AC_ARG_ENABLE([xa],
 953     [AS_HELP_STRING([--enable-xa],
 954         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 955     [enable_xa="$enableval"],
 956     [enable_xa=no])
 957 AC_ARG_ENABLE([gbm],
 958    [AS_HELP_STRING([--enable-gbm],
 959          [enable gbm library @<:@default=auto@:>@])],
 960    [enable_gbm="$enableval"],
 961    [enable_gbm=auto])
 962 AC_ARG_ENABLE([nine],
 963     [AS_HELP_STRING([--enable-nine],
 964         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 965     [enable_nine="$enableval"],
 966     [enable_nine=no])
 967
 968 AC_ARG_ENABLE([xvmc],
 969    [AS_HELP_STRING([--enable-xvmc],
 970          [enable xvmc library @<:@default=auto@:>@])],
 971    [enable_xvmc="$enableval"],
 972    [enable_xvmc=auto])
 973 AC_ARG_ENABLE([vdpau],
 974    [AS_HELP_STRING([--enable-vdpau],
 975          [enable vdpau library @<:@default=auto@:>@])],
 976    [enable_vdpau="$enableval"],
 977    [enable_vdpau=auto])
 978 AC_ARG_ENABLE([omx],
 979    [AS_HELP_STRING([--enable-omx],
 980          [enable OpenMAX library @<:@default=disabled@:>@])],
 981    [enable_omx="$enableval"],
 982    [enable_omx=no])
 983 AC_ARG_ENABLE([va],
 984    [AS_HELP_STRING([--enable-va],
 985          [enable va library @<:@default=auto@:>@])],
 986    [enable_va="$enableval"],
 987    [enable_va=auto])
 988 AC_ARG_ENABLE([opencl],
 989    [AS_HELP_STRING([--enable-opencl],
 990          [enable OpenCL library @<:@default=disabled@:>@])],
 991    [enable_opencl="$enableval"],
 992    [enable_opencl=no])
 993 AC_ARG_ENABLE([opencl_icd],
 994    [AS_HELP_STRING([--enable-opencl-icd],
 995           [Build an OpenCL ICD library to be loaded by an ICD implementation
 996            @<:@default=disabled@:>@])],
 997     [enable_opencl_icd="$enableval"],
 998     [enable_opencl_icd=no])
 999
1000 AC_ARG_ENABLE([gallium-tests],
1001     [AS_HELP_STRING([--enable-gallium-tests],
1002         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1003     [enable_gallium_tests="$enableval"],
1004     [enable_gallium_tests=no])
1005
1006 # Option for Gallium drivers
1007
1008 # Keep this in sync with the --with-gallium-drivers help string default value
1009 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1010
1011 AC_ARG_WITH([gallium-drivers],
1012     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1013         [comma delimited Gallium drivers list, e.g.
1014         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1015         @<:@default=r300,r600,svga,swrast@:>@])],
1016     [with_gallium_drivers="$withval"],
1017     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1018
1019 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1020 # here so that the script doesn't choke on an unknown driver name later.
1021 case "$with_gallium_drivers" in
1022     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1023     no) with_gallium_drivers='' ;;
1024 esac
1025
1026 if test "x$enable_opengl" = xno -a \
1027         "x$enable_gles1" = xno -a \
1028         "x$enable_gles2" = xno -a \
1029         "x$enable_nine" = xno -a \
1030         "x$enable_xa" = xno -a \
1031         "x$enable_xvmc" = xno -a \
1032         "x$enable_vdpau" = xno -a \
1033         "x$enable_omx" = xno -a \
1034         "x$enable_va" = xno -a \
1035         "x$enable_opencl" = xno; then
1036     AC_MSG_ERROR([at least one API should be enabled])
1037 fi
1038
1039 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1040 if test "x$enable_opengl" = xno -a \
1041         "x$enable_gles1" = xyes; then
1042     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1043 fi
1044
1045 if test "x$enable_opengl" = xno -a \
1046         "x$enable_gles2" = xyes; then
1047     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1048 fi
1049
1050 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1051 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1052 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1053 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1054                                         "x$enable_gles1" = xyes -o \
1055                                         "x$enable_gles2" = xyes)
1056
1057 # Validate GLX options
1058 if test "x$enable_glx" = xyes; then
1059     if test "x$enable_dri" = xyes; then
1060         enable_glx=dri
1061     elif test -n "$with_gallium_drivers"; then
1062         enable_glx=gallium-xlib
1063     else
1064         enable_glx=xlib
1065     fi
1066 fi
1067 case "x$enable_glx" in
1068 xdri | xxlib | xgallium-xlib)
1069     # GLX requires OpenGL
1070     if test "x$enable_opengl" = xno; then
1071         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1072     fi
1073
1074     # Check individual dependencies
1075     case "x$enable_glx" in
1076     xdri)
1077         if test "x$enable_dri" = xno; then
1078             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1079         fi
1080         ;;
1081     xxlib)
1082         if test "x$enable_dri" = xyes; then
1083             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1084         fi
1085         ;;
1086     xgallium-xlib )
1087         if test "x$enable_dri" = xyes; then
1088             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1089         fi
1090         if test -z "$with_gallium_drivers"; then
1091             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1092         fi
1093         ;;
1094     esac
1095     ;;
1096 xno)
1097     ;;
1098 *)
1099     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1100     ;;
1101 esac
1102
1103 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1104 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1105 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1106 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1107
1108 dnl
1109 dnl Libglvnd configuration
1110 dnl
1111 AC_ARG_ENABLE([libglvnd],
1112     [AS_HELP_STRING([--enable-libglvnd],
1113         [Build for libglvnd @<:@default=disabled@:>@])],
1114     [enable_libglvnd="$enableval"],
1115     [enable_libglvnd=no])
1116 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1117 if test "x$enable_libglvnd" = xyes ; then
1118     dnl XXX: update once we can handle more than libGL/glx.
1119     dnl Namely: we should error out if neither of the glvnd enabled libraries
1120     dnl are built
1121     case "x$enable_glx" in
1122     xno)
1123         AC_MSG_ERROR([cannot build libglvnd without GLX])
1124         ;;
1125     xxlib | xgallium-xlib )
1126         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1127         ;;
1128     xdri)
1129         ;;
1130     esac
1131
1132     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1133     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1134     DEFAULT_GL_LIB_NAME=GLX_mesa
1135 fi
1136
1137 # Check for libdrm
1138 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1139                   [have_libdrm=yes], [have_libdrm=no])
1140 if test "x$have_libdrm" = xyes; then
1141         DEFINES="$DEFINES -DHAVE_LIBDRM"
1142 fi
1143
1144 # Select which platform-dependent DRI code gets built
1145 case "$host_os" in
1146 darwin*)
1147     dri_platform='apple' ;;
1148 cygwin*)
1149     dri_platform='windows' ;;
1150 gnu*)
1151     dri_platform='none' ;;
1152 *)
1153     dri_platform='drm' ;;
1154 esac
1155
1156 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1157     have_drisw_kms='yes'
1158 fi
1159
1160 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1161 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1162 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1163 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1164 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1165 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1166 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1167 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1168 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1169
1170 AC_ARG_ENABLE([shared-glapi],
1171     [AS_HELP_STRING([--enable-shared-glapi],
1172         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1173     [enable_shared_glapi="$enableval"],
1174     [enable_shared_glapi=yes])
1175
1176 case "x$enable_opengl$enable_gles1$enable_gles2" in
1177 x*yes*yes*)
1178     if test "x$enable_shared_glapi" = xno; then
1179         AC_MSG_ERROR([shared GLAPI required when building two or more of
1180                       the following APIs - opengl, gles1 gles2])
1181     fi
1182     ;;
1183 esac
1184
1185 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1186
1187 # Build the pipe-drivers as separate libraries/modules.
1188 # Do not touch this unless you know what you are doing.
1189 # XXX: Expose via configure option ?
1190 enable_shared_pipe_drivers=no
1191
1192 dnl
1193 dnl Driver specific build directories
1194 dnl
1195
1196 if test "x$enable_gallium_osmesa" = xyes; then
1197     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1198         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1199     fi
1200     if test "x$enable_osmesa" = xyes; then
1201         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1202     fi
1203 fi
1204
1205 AC_SUBST([MESA_LLVM])
1206
1207 # SHA1 hashing
1208 AC_ARG_WITH([sha1],
1209         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1210         [choose SHA1 implementation])])
1211 case "x$with_sha1" in
1212 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1213   ;;
1214 *)
1215         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1216 esac
1217
1218 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1219 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1220         with_sha1=libc
1221 fi
1222 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1223         AC_MSG_ERROR([sha1 in libc requested but not found])
1224 fi
1225 if test "x$with_sha1" = xlibc; then
1226         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1227                 [Use libc SHA1 functions])
1228         SHA1_LIBS=""
1229 fi
1230 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1231 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1232         with_sha1=CommonCrypto
1233 fi
1234 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1235         AC_MSG_ERROR([CommonCrypto requested but not found])
1236 fi
1237 if test "x$with_sha1" = xCommonCrypto; then
1238         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1239                 [Use CommonCrypto SHA1 functions])
1240         SHA1_LIBS=""
1241 fi
1242 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1243 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1244 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1245         with_sha1=CryptoAPI
1246 fi
1247 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1248         AC_MSG_ERROR([CryptoAPI requested but not found])
1249 fi
1250 if test "x$with_sha1" = xCryptoAPI; then
1251         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1252                 [Use CryptoAPI SHA1 functions])
1253         SHA1_LIBS=""
1254 fi
1255 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1256 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1257         with_sha1=libmd
1258 fi
1259 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1260         AC_MSG_ERROR([libmd requested but not found])
1261 fi
1262 if test "x$with_sha1" = xlibmd; then
1263         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1264                   [Use libmd SHA1 functions])
1265         SHA1_LIBS=-lmd
1266 fi
1267 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1268 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1269    with_sha1=libsha1
1270 fi
1271 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1272         AC_MSG_ERROR([libsha1 requested but not found])
1273 fi
1274 if test "x$with_sha1" = xlibsha1; then
1275         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1276                   [Use libsha1 for SHA1])
1277         SHA1_LIBS=-lsha1
1278 fi
1279 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1280 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1281         with_sha1=libnettle
1282 fi
1283 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1284         AC_MSG_ERROR([libnettle requested but not found])
1285 fi
1286 if test "x$with_sha1" = xlibnettle; then
1287         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1288                   [Use libnettle SHA1 functions])
1289         SHA1_LIBS=-lnettle
1290 fi
1291 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1292 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1293         with_sha1=libgcrypt
1294 fi
1295 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1296         AC_MSG_ERROR([libgcrypt requested but not found])
1297 fi
1298 if test "x$with_sha1" = xlibgcrypt; then
1299         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1300                   [Use libgcrypt SHA1 functions])
1301         SHA1_LIBS=-lgcrypt
1302 fi
1303 # We don't need all of the OpenSSL libraries, just libcrypto
1304 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1305 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1306                   [HAVE_OPENSSL_PKC=no])
1307 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1308         if test "x$with_sha1" = x; then
1309                 with_sha1=libcrypto
1310         fi
1311 else
1312         if test "x$with_sha1" = xlibcrypto; then
1313                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1314         fi
1315 fi
1316 if test "x$with_sha1" = xlibcrypto; then
1317         if test "x$HAVE_LIBCRYPTO" = xyes; then
1318                 SHA1_LIBS=-lcrypto
1319         else
1320                 SHA1_LIBS="$OPENSSL_LIBS"
1321                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1322         fi
1323 fi
1324 AC_MSG_CHECKING([for SHA1 implementation])
1325 AC_MSG_RESULT([$with_sha1])
1326 AC_SUBST(SHA1_LIBS)
1327 AC_SUBST(SHA1_CFLAGS)
1328
1329 # Enable a define for SHA1
1330 if test "x$with_sha1" != "x"; then
1331         DEFINES="$DEFINES -DHAVE_SHA1"
1332 fi
1333
1334 # Allow user to configure out the shader-cache feature
1335 AC_ARG_ENABLE([shader-cache],
1336     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1337     [enable_shader_cache="$enableval"],
1338     [if test "x$with_sha1" != "x"; then
1339         enable_shader_cache=yes
1340      else
1341         enable_shader_cache=no
1342      fi])
1343 if test "x$with_sha1" = "x"; then
1344     if test "x$enable_shader_cache" = "xyes"; then
1345         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1346     fi
1347 fi
1348 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1349 if test "x$enable_shader_cache" = "xyes"; then
1350    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1351 fi
1352
1353 case "$host_os" in
1354 linux*)
1355     need_pci_id=yes ;;
1356 *)
1357     need_pci_id=no ;;
1358 esac
1359
1360 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1361                   have_libudev=yes, have_libudev=no)
1362
1363 AC_ARG_ENABLE([sysfs],
1364     [AS_HELP_STRING([--enable-sysfs],
1365         [enable /sys PCI identification @<:@default=disabled@:>@])],
1366     [have_sysfs="$enableval"],
1367     [have_sysfs=no]
1368 )
1369
1370 if test "x$enable_dri" = xyes; then
1371     if test "$enable_static" = yes; then
1372         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1373     fi
1374
1375     # not a hard requirement as swrast does not depend on it
1376     if test "x$have_libdrm" = xyes; then
1377         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1378     fi
1379 fi
1380
1381 AC_ARG_ENABLE([driglx-direct],
1382     [AS_HELP_STRING([--disable-driglx-direct],
1383         [disable direct rendering in GLX and EGL for DRI \
1384             @<:@default=auto@:>@])],
1385     [driglx_direct="$enableval"],
1386     [driglx_direct="yes"])
1387
1388 dnl
1389 dnl libGL configuration per driver
1390 dnl
1391 case "x$enable_glx" in
1392 xxlib | xgallium-xlib)
1393     # Xlib-based GLX
1394     dri_modules="x11 xext xcb"
1395     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1396     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1397     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1398     GL_LIB_DEPS="$XLIBGL_LIBS"
1399     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1400     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1401     ;;
1402 xdri)
1403     # DRI-based GLX
1404     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1405
1406     # find the DRI deps for libGL
1407     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1408
1409     if test x"$driglx_direct" = xyes; then
1410         if test x"$dri_platform" = xdrm ; then
1411             DEFINES="$DEFINES -DGLX_USE_DRM"
1412             if test "x$have_libdrm" != xyes; then
1413                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1414             fi
1415
1416             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1417             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1418             if test x"$enable_dri3" = xyes; then
1419                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1420                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1421             fi
1422
1423             if test x"$enable_dri" = xyes; then
1424                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1425             fi
1426
1427             if test x"$enable_dri3" = xyes; then
1428                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1429                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1430                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1431             fi
1432         fi
1433         if test x"$dri_platform" = xapple ; then
1434             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1435         fi
1436         if test x"$dri_platform" = xwindows ; then
1437             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1438         fi
1439     fi
1440
1441     # add xf86vidmode if available
1442     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1443     if test "$HAVE_XF86VIDMODE" = yes ; then
1444         dri_modules="$dri_modules xxf86vm"
1445     fi
1446
1447     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1448     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1449     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1450     GL_LIB_DEPS="$DRIGL_LIBS"
1451
1452     # need DRM libs, $PTHREAD_LIBS, etc.
1453     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1454     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1455     ;;
1456 esac
1457
1458 have_pci_id=no
1459 if test "$have_libudev" = yes; then
1460     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1461     have_pci_id=yes
1462 fi
1463
1464 if test "$have_sysfs" = yes; then
1465     DEFINES="$DEFINES -DHAVE_SYSFS"
1466     have_pci_id=yes
1467 fi
1468
1469 if test "$have_libdrm" = yes; then
1470     have_pci_id=yes
1471 fi
1472
1473 # This is outside the case (above) so that it is invoked even for non-GLX
1474 # builds.
1475 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1476
1477 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1478 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1479 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1480 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1481
1482 AC_SUBST([X11_INCLUDES])
1483 AC_SUBST([GL_LIB_DEPS])
1484 AC_SUBST([GL_PC_REQ_PRIV])
1485 AC_SUBST([GL_PC_LIB_PRIV])
1486 AC_SUBST([GL_PC_CFLAGS])
1487 AC_SUBST([DRI_PC_REQ_PRIV])
1488 AC_SUBST([GLESv1_CM_LIB_DEPS])
1489 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1490 AC_SUBST([GLESv2_LIB_DEPS])
1491 AC_SUBST([GLESv2_PC_LIB_PRIV])
1492
1493 AC_SUBST([HAVE_XF86VIDMODE])
1494
1495 dnl
1496 dnl More GLX setup
1497 dnl
1498 case "x$enable_glx" in
1499 xxlib | xgallium-xlib)
1500     DEFINES="$DEFINES -DUSE_XSHM"
1501     ;;
1502 xdri)
1503     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1504     if test "x$driglx_direct" = xyes; then
1505         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1506     fi
1507     ;;
1508 esac
1509
1510 dnl
1511 dnl TLS detection
1512 dnl
1513
1514 AC_ARG_ENABLE([glx-tls],
1515     [AS_HELP_STRING([--enable-glx-tls],
1516         [enable TLS support in GLX @<:@default=disabled@:>@])],
1517     [GLX_USE_TLS="$enableval"],
1518     [GLX_USE_TLS=no])
1519 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1520
1521 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1522       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1523
1524 dnl Read-only text section on x86 hardened platforms
1525 AC_ARG_ENABLE([glx-read-only-text],
1526     [AS_HELP_STRING([--enable-glx-read-only-text],
1527         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1528     [enable_glx_read_only_text="$enableval"],
1529     [enable_glx_read_only_text=no])
1530 if test "x$enable_glx_read_only_text" = xyes; then
1531     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1532 fi
1533
1534 dnl
1535 dnl More DRI setup
1536 dnl
1537 dnl Directory for DRI drivers
1538 AC_ARG_WITH([dri-driverdir],
1539     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1540         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1541     [DRI_DRIVER_INSTALL_DIR="$withval"],
1542     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1543 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1544 dnl Extra search path for DRI drivers
1545 AC_ARG_WITH([dri-searchpath],
1546     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1547         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1548     [DRI_DRIVER_SEARCH_DIR="$withval"],
1549     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1550 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1551 dnl Which drivers to build - default is chosen by platform
1552 AC_ARG_WITH([dri-drivers],
1553     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1554         [comma delimited classic DRI drivers list, e.g.
1555         "swrast,i965,radeon" @<:@default=auto@:>@])],
1556     [with_dri_drivers="$withval"],
1557     [with_dri_drivers=auto])
1558
1559 if test "x$with_dri_drivers" = xauto; then
1560     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1561         with_dri_drivers="yes"
1562     else
1563         with_dri_drivers="no"
1564     fi
1565 fi
1566 if test "x$with_dri_drivers" = xno; then
1567     with_dri_drivers=''
1568 fi
1569
1570 dnl If $with_dri_drivers is yes, drivers will be added through
1571 dnl platform checks. Set DEFINES and LIB_DEPS
1572 if test "x$enable_dri" = xyes; then
1573     # Platform specific settings and drivers to build
1574     case "$host_os" in
1575     linux*)
1576         DEFINES="$DEFINES -DHAVE_ALIAS"
1577         if test "x$enable_dri3" = xyes; then
1578             DEFINES="$DEFINES -DHAVE_DRI3"
1579         fi
1580
1581         if test "x$have_pci_id" != xyes; then
1582             AC_MSG_ERROR([libudev-dev, sysfs or libdrm >= $LIBDRM_REQUIRED required for building DRI])
1583         fi
1584
1585         case "$host_cpu" in
1586         powerpc* | sparc*)
1587             # Build only the drivers for cards that exist on PowerPC/sparc
1588             if test "x$with_dri_drivers" = "xyes"; then
1589                 with_dri_drivers="r200 radeon swrast"
1590             fi
1591             ;;
1592         esac
1593         ;;
1594     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1595         DEFINES="$DEFINES -DHAVE_ALIAS"
1596         ;;
1597     gnu*)
1598         DEFINES="$DEFINES -DHAVE_ALIAS"
1599         ;;
1600     cygwin*)
1601         if test "x$with_dri_drivers" = "xyes"; then
1602             with_dri_drivers="swrast"
1603         fi
1604         ;;
1605     darwin*)
1606         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1607         if test "x$with_dri_drivers" = "xyes"; then
1608             with_dri_drivers="swrast"
1609         fi
1610         ;;
1611     esac
1612
1613     # default drivers
1614     if test "x$with_dri_drivers" = "xyes"; then
1615         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1616     fi
1617
1618     # Check for expat
1619     PKG_CHECK_MODULES([EXPAT], [expat], [],
1620         # expat version 2.0 and earlier do not provide expat.pc
1621         [AC_CHECK_HEADER([expat.h],[],
1622                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1623          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1624                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1625          EXPAT_LIBS="-lexpat"])
1626
1627     # put all the necessary libs together
1628     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1629 fi
1630
1631 AC_SUBST([DRI_LIB_DEPS])
1632
1633 DRI_DIRS=''
1634 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1635 if test -n "$with_dri_drivers"; then
1636     if test "x$enable_opengl" != xyes; then
1637         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1638     fi
1639
1640     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1641     for driver in $dri_drivers; do
1642         DRI_DIRS="$DRI_DIRS $driver"
1643         case "x$driver" in
1644         xi915)
1645             HAVE_I915_DRI=yes;
1646             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1647             ;;
1648         xi965)
1649             HAVE_I965_DRI=yes;
1650             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1651             ;;
1652         xnouveau)
1653             HAVE_NOUVEAU_DRI=yes;
1654             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1655             ;;
1656         xradeon)
1657             HAVE_RADEON_DRI=yes;
1658             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1659             ;;
1660         xr200)
1661             HAVE_R200_DRI=yes;
1662             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1663             ;;
1664         xswrast)
1665             HAVE_SWRAST_DRI=yes;
1666             ;;
1667         *)
1668             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1669             ;;
1670         esac
1671     done
1672     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1673 fi
1674
1675
1676 #
1677 # Vulkan driver configuration
1678 #
1679
1680 AC_ARG_WITH([vulkan-drivers],
1681     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1682         [comma delimited Vulkan drivers list, e.g.
1683         "intel"
1684         @<:@default=no@:>@])],
1685     [with_vulkan_drivers="$withval"],
1686     [with_vulkan_drivers="no"])
1687
1688 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1689 # here so that the script doesn't choke on an unknown driver name later.
1690 case "x$with_vulkan_drivers" in
1691     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1692     xno) with_vulkan_drivers='' ;;
1693 esac
1694
1695 AC_ARG_WITH([vulkan-icddir],
1696     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1697         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1698     [VULKAN_ICD_INSTALL_DIR="$withval"],
1699     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1700 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1701
1702 AC_ARG_ENABLE([vulkan-icd-full-driver-path],
1703    [AS_HELP_STRING([--disable-vulkan-icd-full-driver-path],
1704                    [create Vulkan ICD files with just a .so name and no path])],
1705    [vulkan_icd_driver_path="$enableval"],
1706    [vulkan_icd_driver_path="yes"])
1707 AM_CONDITIONAL(VULKAN_ICD_DRIVER_PATH, test "x$vulkan_icd_driver_path" = xyes)
1708
1709 if test -n "$with_vulkan_drivers"; then
1710     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1711     for driver in $VULKAN_DRIVERS; do
1712         case "x$driver" in
1713         xintel)
1714             if test "x$HAVE_I965_DRI" != xyes; then
1715                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1716             fi
1717             if test "x$with_sha1" == "x"; then
1718                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1719             fi
1720             HAVE_INTEL_VULKAN=yes;
1721
1722             ;;
1723         xradeon)
1724             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1725             HAVE_RADEON_VULKAN=yes;
1726             if test "x$with_sha1" == "x"; then
1727                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1728             fi
1729             ;;
1730         *)
1731             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1732             ;;
1733         esac
1734     done
1735     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1736 fi
1737
1738
1739 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1740 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1741                                   "x$enable_osmesa" = xyes -o \
1742                                   -n "$DRI_DIRS")
1743
1744 dnl
1745 dnl OSMesa configuration
1746 dnl
1747
1748 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1749 AC_ARG_WITH([osmesa-bits],
1750     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1751         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1752     [osmesa_bits="$withval"],
1753     [osmesa_bits=8])
1754 if test "x$osmesa_bits" != x8; then
1755     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1756         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1757         osmesa_bits=8
1758     fi
1759 fi
1760 case "x$osmesa_bits" in
1761 x8)
1762     OSMESA_LIB="${OSMESA_LIB}"
1763     ;;
1764 x16|x32)
1765     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1766     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1767     ;;
1768 *)
1769     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1770     ;;
1771 esac
1772
1773 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1774     # only link libraries with osmesa if shared
1775     if test "$enable_static" = no; then
1776         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1777     else
1778         OSMESA_LIB_DEPS=""
1779     fi
1780     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1781 fi
1782
1783 AC_SUBST([OSMESA_LIB_DEPS])
1784 AC_SUBST([OSMESA_PC_REQ])
1785 AC_SUBST([OSMESA_PC_LIB_PRIV])
1786
1787 dnl
1788 dnl gbm configuration
1789 dnl
1790 if test "x$enable_gbm" = xauto; then
1791     case "$with_egl_platforms" in
1792         *drm*)
1793             enable_gbm=yes ;;
1794          *)
1795             enable_gbm=no ;;
1796     esac
1797 fi
1798 if test "x$enable_gbm" = xyes; then
1799     if test "x$need_pci_id$have_pci_id" = xyesno; then
1800         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED, sysfs or libdrm >= $LIBDRM_REQUIRED])
1801     fi
1802
1803     if test "x$enable_dri" = xyes; then
1804         if test "x$enable_shared_glapi" = xno; then
1805             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1806         fi
1807     else
1808         # Strictly speaking libgbm does not require --enable-dri, although
1809         # both of its backends do. Thus one can build libgbm without any
1810         # backends if --disable-dri is set.
1811         # To avoid unnecessary complexity of checking if at least one backend
1812         # is available when building, just mandate --enable-dri.
1813         AC_MSG_ERROR([gbm requires --enable-dri])
1814     fi
1815 fi
1816 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1817 if test "x$need_pci_id$have_libudev" = xyesyes; then
1818     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1819 else
1820     GBM_PC_REQ_PRIV=""
1821 fi
1822 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1823 AC_SUBST([GBM_PC_REQ_PRIV])
1824 AC_SUBST([GBM_PC_LIB_PRIV])
1825
1826 dnl
1827 dnl EGL configuration
1828 dnl
1829 EGL_CLIENT_APIS=""
1830
1831 if test "x$enable_egl" = xyes; then
1832     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1833
1834     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1835
1836     if test "$enable_static" != yes; then
1837         if test "x$enable_dri" = xyes; then
1838             HAVE_EGL_DRIVER_DRI2=1
1839             if test "x$enable_shared_glapi" = xno; then
1840                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1841             fi
1842             if test "x$enable_dri3" = xyes; then
1843                 HAVE_EGL_DRIVER_DRI3=1
1844                 if test "x$enable_shared_glapi" = xno; then
1845                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1846                 fi
1847             fi
1848         else
1849             # Avoid building an "empty" libEGL. Drop/update this
1850             # when other backends (haiku?) come along.
1851             AC_MSG_ERROR([egl requires --enable-dri])
1852         fi
1853
1854     fi
1855 fi
1856 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1857 AC_SUBST([EGL_LIB_DEPS])
1858
1859 gallium_st="mesa"
1860
1861 dnl
1862 dnl XA configuration
1863 dnl
1864 if test "x$enable_xa" = xyes; then
1865     if test "x$with_gallium_drivers" = xswrast; then
1866        AC_MSG_ERROR([
1867           Building xa requires at least one non swrast gallium driver.
1868           If you are looking to use libxatracker.so with the VMware driver,
1869           make sure to include svga in the gallium drivers list, apart from
1870           enabling XA.
1871           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1872     fi
1873     gallium_st="$gallium_st xa"
1874 fi
1875 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1876
1877 dnl
1878 dnl Gallium G3DVL configuration
1879 dnl
1880 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1881     if test "x$enable_xvmc" = xauto; then
1882         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1883     fi
1884
1885     if test "x$enable_vdpau" = xauto; then
1886         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1887     fi
1888
1889     if test "x$enable_omx" = xauto; then
1890         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1891     fi
1892
1893     if test "x$enable_va" = xauto; then
1894         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1895     fi
1896 fi
1897
1898 if test "x$enable_dri" = xyes -o \
1899         "x$enable_xvmc" = xyes -o \
1900         "x$enable_vdpau" = xyes -o \
1901         "x$enable_omx" = xyes -o \
1902         "x$enable_va" = xyes; then
1903     need_gallium_vl=yes
1904 fi
1905 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1906
1907 if test "x$enable_xvmc" = xyes -o \
1908         "x$enable_vdpau" = xyes -o \
1909         "x$enable_omx" = xyes -o \
1910         "x$enable_va" = xyes; then
1911     if test x"$enable_dri3" = xyes; then
1912         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1913                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1914     else
1915         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1916     fi
1917     need_gallium_vl_winsys=yes
1918 fi
1919 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1920
1921 if test "x$enable_xvmc" = xyes; then
1922     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1923     gallium_st="$gallium_st xvmc"
1924 fi
1925 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1926
1927 if test "x$enable_vdpau" = xyes; then
1928     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1929     gallium_st="$gallium_st vdpau"
1930     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1931 fi
1932 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1933
1934 if test "x$enable_omx" = xyes; then
1935     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1936     gallium_st="$gallium_st omx"
1937 fi
1938 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1939
1940 if test "x$enable_va" = xyes; then
1941     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1942     gallium_st="$gallium_st va"
1943 fi
1944 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1945
1946 dnl
1947 dnl Nine Direct3D9 configuration
1948 dnl
1949 if test "x$enable_nine" = xyes; then
1950     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1951         AC_MSG_ERROR([nine requires the gallium swrast driver])
1952     fi
1953     if test "x$with_gallium_drivers" = xswrast; then
1954         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1955     fi
1956     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1957         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1958     fi
1959
1960     if test "x$enable_dri3" = xno; then
1961         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1962     fi
1963
1964     gallium_st="$gallium_st nine"
1965 fi
1966 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1967
1968 dnl
1969 dnl OpenCL configuration
1970 dnl
1971
1972 AC_ARG_WITH([clang-libdir],
1973    [AS_HELP_STRING([--with-clang-libdir],
1974          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1975    [CLANG_LIBDIR="$withval"],
1976    [CLANG_LIBDIR=''])
1977
1978 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1979 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1980
1981 if test "x$have_libelf" = xno; then
1982    LIBELF_LIBS=''
1983    LIBELF_CFLAGS=''
1984    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1985    AC_SUBST([LIBELF_LIBS])
1986    AC_SUBST([LIBELF_CFLAGS])
1987 fi
1988
1989 if test "x$enable_opencl" = xyes; then
1990     if test -z "$with_gallium_drivers"; then
1991         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1992     fi
1993
1994     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1995         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1996     fi
1997
1998     if test "x$have_libclc" = xno; then
1999         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2000                     Make sure the directory containing libclc.pc is specified in your
2001                     PKG_CONFIG_PATH environment variable.
2002                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2003     else
2004         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2005         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2006         AC_SUBST([LIBCLC_INCLUDEDIR])
2007         AC_SUBST([LIBCLC_LIBEXECDIR])
2008     fi
2009
2010     gallium_st="$gallium_st clover"
2011
2012     if test "x$enable_opencl_icd" = xyes; then
2013         OPENCL_LIBNAME="MesaOpenCL"
2014     else
2015         OPENCL_LIBNAME="OpenCL"
2016     fi
2017
2018     if test "x$have_libelf" != xyes; then
2019        AC_MSG_ERROR([Clover requires libelf])
2020     fi
2021 fi
2022 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2023 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2024 AC_SUBST([OPENCL_LIBNAME])
2025
2026 dnl
2027 dnl Gallium configuration
2028 dnl
2029 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2030
2031 AC_SUBST([LLVM_BINDIR])
2032 AC_SUBST([LLVM_CFLAGS])
2033 AC_SUBST([LLVM_CPPFLAGS])
2034 AC_SUBST([LLVM_CXXFLAGS])
2035 AC_SUBST([LLVM_LIBDIR])
2036 AC_SUBST([LLVM_LIBS])
2037 AC_SUBST([LLVM_LDFLAGS])
2038 AC_SUBST([LLVM_INCLUDEDIR])
2039 AC_SUBST([LLVM_VERSION])
2040 AC_SUBST([CLANG_RESOURCE_DIR])
2041
2042 case "x$enable_opengl$enable_gles1$enable_gles2" in
2043 x*yes*)
2044     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2045     ;;
2046 esac
2047
2048 AC_SUBST([VG_LIB_DEPS])
2049 AC_SUBST([EGL_CLIENT_APIS])
2050
2051 dnl
2052 dnl EGL Platforms configuration
2053 dnl
2054 AC_ARG_WITH([egl-platforms],
2055     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2056         [comma delimited native platforms libEGL supports, e.g.
2057         "x11,drm" @<:@default=auto@:>@])],
2058     [with_egl_platforms="$withval"],
2059     [if test "x$enable_egl" = xyes; then
2060         with_egl_platforms="x11"
2061     else
2062         with_egl_platforms=""
2063     fi])
2064
2065 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2066     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2067 fi
2068
2069 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2070         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2071         WAYLAND_SCANNER='')
2072 if test "x$WAYLAND_SCANNER" = x; then
2073     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2074 fi
2075
2076 # Do per-EGL platform setups and checks
2077 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2078 for plat in $egl_platforms; do
2079         case "$plat" in
2080         wayland)
2081                 test "x$have_libdrm" != xyes &&
2082                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
2083
2084                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2085
2086                 if test "x$WAYLAND_SCANNER" = x; then
2087                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2088                 fi
2089                 ;;
2090
2091         x11)
2092                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2093                 ;;
2094
2095         drm)
2096                 test "x$enable_gbm" = "xno" &&
2097                         AC_MSG_ERROR([EGL platform drm needs gbm])
2098                 test "x$have_libdrm" != xyes &&
2099                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
2100                 ;;
2101
2102         surfaceless)
2103                 test "x$have_libdrm" != xyes &&
2104                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
2105                 ;;
2106
2107         android)
2108                 ;;
2109
2110         *)
2111                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2112                 ;;
2113         esac
2114
2115         case "$plat$need_pci_id$have_pci_id" in
2116                 waylandyesno|drmyesno)
2117                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED, sysfs or libdrm >= $LIBDRM_REQUIRED]) ;;
2118         esac
2119 done
2120
2121 # libEGL wants to default to the first platform specified in
2122 # ./configure.  parse that here.
2123 if test "x$egl_platforms" != "x"; then
2124     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2125     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2126 else
2127     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2128 fi
2129
2130 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2131 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2132 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2133 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2134 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2135
2136 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2137
2138 AC_SUBST([EGL_NATIVE_PLATFORM])
2139 AC_SUBST([EGL_CFLAGS])
2140
2141 # If we don't have the X11 platform, set this define so we don't try to include
2142 # the X11 headers.
2143 if ! echo "$egl_platforms" | grep -q 'x11'; then
2144     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2145     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2146 fi
2147
2148 dnl
2149 dnl Gallium LLVM
2150 dnl
2151 AC_ARG_ENABLE([gallium-llvm],
2152     [AS_HELP_STRING([--enable-gallium-llvm],
2153         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2154     [enable_gallium_llvm="$enableval"],
2155     [enable_gallium_llvm=auto])
2156
2157 AC_ARG_ENABLE([llvm-shared-libs],
2158     [AS_HELP_STRING([--enable-llvm-shared-libs],
2159         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2160     [enable_llvm_shared_libs="$enableval"],
2161     [enable_llvm_shared_libs=yes])
2162
2163 AC_ARG_WITH([llvm-prefix],
2164     [AS_HELP_STRING([--with-llvm-prefix],
2165         [Prefix for LLVM installations in non-standard locations])],
2166     [llvm_prefix="$withval"],
2167     [llvm_prefix=''])
2168
2169
2170 # Call this inside ` ` to get the return value.
2171 # $1 is the llvm-config command with arguments.
2172 strip_unwanted_llvm_flags() {
2173     # Use \> (marks the end of the word)
2174     echo `$1` | sed \
2175         -e 's/-march=\S*//g' \
2176         -e 's/-mtune=\S*//g' \
2177         -e 's/-mcpu=\S*//g' \
2178         -e 's/-DNDEBUG\>//g' \
2179         -e 's/-D_GNU_SOURCE\>//g' \
2180         -e 's/-pedantic\>//g' \
2181         -e 's/-Wcovered-switch-default\>//g' \
2182         -e 's/-O.\>//g' \
2183         -e 's/-g\>//g' \
2184         -e 's/-Wall\>//g' \
2185         -e 's/-Wcast-qual\>//g' \
2186         -e 's/-Woverloaded-virtual\>//g' \
2187         -e 's/-fcolor-diagnostics\>//g' \
2188         -e 's/-fdata-sections\>//g' \
2189         -e 's/-ffunction-sections\>//g' \
2190         -e 's/-fno-exceptions\>//g' \
2191         -e 's/-fomit-frame-pointer\>//g' \
2192         -e 's/-fvisibility-inlines-hidden\>//g' \
2193         -e 's/-fPIC\>//g' \
2194         -e 's/-fstack-protector-strong\>//g'
2195 }
2196
2197 llvm_check_version_for() {
2198     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2199         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2200     fi
2201 }
2202
2203
2204
2205 if test -z "$with_gallium_drivers"; then
2206     enable_gallium_llvm=no
2207 fi
2208 if test "x$enable_gallium_llvm" = xauto; then
2209     case "$host_cpu" in
2210     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2211     esac
2212 fi
2213 if test "x$enable_gallium_llvm" = xyes || test "x$HAVE_RADEON_VULKAN" = xyes; then
2214     if test -n "$llvm_prefix"; then
2215         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2216     else
2217         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2218     fi
2219
2220     if test "x$LLVM_CONFIG" != xno; then
2221         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2222         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2223         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2224         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2225         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2226         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2227         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2228         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2229
2230         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2231             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2232         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2233             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2234
2235         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2236         if test -z "$LLVM_VERSION_PATCH"; then
2237             LLVM_VERSION_PATCH=0
2238         fi
2239
2240         if test -n "${LLVM_VERSION_MAJOR}"; then
2241             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2242         else
2243             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2244         fi
2245
2246         LLVM_REQUIRED_VERSION_MAJOR="3"
2247         LLVM_REQUIRED_VERSION_MINOR="3"
2248         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2249             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2250         fi
2251
2252         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2253
2254         if $LLVM_CONFIG --components | grep -q inteljitevents ; then
2255             LLVM_COMPONENTS="${LLVM_COMPONENTS} inteljitevents"
2256         fi
2257
2258         if test "x$enable_opencl" = xyes; then
2259             llvm_check_version_for "3" "6" "0" "opencl"
2260
2261             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2262             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2263         fi
2264         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2265         MESA_LLVM=1
2266
2267         dnl Check for Clang internal headers
2268         if test "x$enable_opencl" = xyes; then
2269             if test -z "$CLANG_LIBDIR"; then
2270                 CLANG_LIBDIR=${LLVM_LIBDIR}
2271             fi
2272             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2273             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2274                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2275         fi
2276     else
2277         MESA_LLVM=0
2278         LLVM_VERSION_INT=0
2279     fi
2280 else
2281     MESA_LLVM=0
2282     LLVM_VERSION_INT=0
2283
2284     if test "x$enable_opencl" = xyes; then
2285         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2286     fi
2287 fi
2288
2289 dnl Directory for XVMC libs
2290 AC_ARG_WITH([xvmc-libdir],
2291     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2292         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2293     [XVMC_LIB_INSTALL_DIR="$withval"],
2294     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2295 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2296
2297 dnl
2298 dnl Gallium Tests
2299 dnl
2300 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2301
2302 dnl Directory for VDPAU libs
2303 AC_ARG_WITH([vdpau-libdir],
2304     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2305         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2306     [VDPAU_LIB_INSTALL_DIR="$withval"],
2307     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2308 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2309
2310 dnl Directory for OMX libs
2311
2312 AC_ARG_WITH([omx-libdir],
2313     [AS_HELP_STRING([--with-omx-libdir=DIR],
2314         [directory for the OMX libraries])],
2315     [OMX_LIB_INSTALL_DIR="$withval"],
2316     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2317 AC_SUBST([OMX_LIB_INSTALL_DIR])
2318
2319 dnl Directory for VA libs
2320
2321 AC_ARG_WITH([va-libdir],
2322     [AS_HELP_STRING([--with-va-libdir=DIR],
2323         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2324     [VA_LIB_INSTALL_DIR="$withval"],
2325     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2326 AC_SUBST([VA_LIB_INSTALL_DIR])
2327
2328 AC_ARG_WITH([d3d-libdir],
2329     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2330         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2331     [D3D_DRIVER_INSTALL_DIR="$withval"],
2332     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2333 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2334
2335 dnl
2336 dnl Gallium helper functions
2337 dnl
2338 gallium_require_drm() {
2339     if test "x$have_libdrm" != xyes; then
2340        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2341     fi
2342 }
2343
2344 gallium_require_llvm() {
2345     if test "x$MESA_LLVM" = x0; then
2346         case "$host" in *gnux32) return;; esac
2347         case "$host_cpu" in
2348         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2349         esac
2350     fi
2351 }
2352
2353 gallium_require_drm_loader() {
2354     if test "x$need_pci_id$have_pci_id" = xyesno; then
2355         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED, sysfs or libdrm >= $LIBDRM_REQUIRED])
2356     fi
2357 }
2358
2359 dnl This is for Glamor. Skip this if OpenGL is disabled.
2360 require_egl_drm() {
2361     if test "x$enable_opengl" = xno; then
2362         return 0
2363     fi
2364
2365     case "$with_egl_platforms" in
2366         *drm*)
2367             ;;
2368          *)
2369             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2370             ;;
2371     esac
2372     if test "x$enable_gbm" != xyes; then
2373             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2374     fi
2375 }
2376
2377 radeon_llvm_check() {
2378     if test ${LLVM_VERSION_INT} -lt 307; then
2379         amdgpu_llvm_target_name='r600'
2380     else
2381         amdgpu_llvm_target_name='amdgpu'
2382     fi
2383     llvm_check_version_for $2 $3 $4 $1
2384     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2385         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2386     fi
2387     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2388     NEED_RADEON_LLVM=yes
2389     if test "x$have_libelf" != xyes; then
2390        AC_MSG_ERROR([$1 requires libelf when using llvm])
2391     fi
2392 }
2393
2394 radeon_gallium_llvm_check() {
2395     if test "x$enable_gallium_llvm" != "xyes"; then
2396         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2397     fi
2398     radeon_llvm_check $*
2399 }
2400
2401 swr_llvm_check() {
2402     gallium_require_llvm $1
2403     if test ${LLVM_VERSION_INT} -lt 306; then
2404         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2405     fi
2406     if test "x$enable_gallium_llvm" != "xyes"; then
2407         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2408     fi
2409 }
2410
2411 swr_require_cxx_feature_flags() {
2412     feature_name="$1"
2413     preprocessor_test="$2"
2414     option_list="$3"
2415     output_var="$4"
2416
2417     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2418     AC_LANG_PUSH([C++])
2419     save_CXXFLAGS="$CXXFLAGS"
2420     save_IFS="$IFS"
2421     IFS=","
2422     found=0
2423     for opts in $option_list
2424     do
2425         unset IFS
2426         CXXFLAGS="$opts $save_CXXFLAGS"
2427         AC_COMPILE_IFELSE(
2428             [AC_LANG_PROGRAM(
2429                 [   #if !($preprocessor_test)
2430                     #error
2431                     #endif
2432                 ])],
2433             [found=1; break],
2434             [])
2435         IFS=","
2436     done
2437     IFS="$save_IFS"
2438     CXXFLAGS="$save_CXXFLAGS"
2439     AC_LANG_POP([C++])
2440     if test $found -eq 1; then
2441         AC_MSG_RESULT([$opts])
2442         eval "$output_var=\$opts"
2443         return 0
2444     fi
2445     AC_MSG_RESULT([no])
2446     AC_MSG_ERROR([swr requires $feature_name support])
2447     return 1
2448 }
2449
2450 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2451 if test -n "$with_gallium_drivers"; then
2452     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2453     for driver in $gallium_drivers; do
2454         case "x$driver" in
2455         xsvga)
2456             HAVE_GALLIUM_SVGA=yes
2457             gallium_require_drm "svga"
2458             gallium_require_drm_loader
2459             ;;
2460         xi915)
2461             HAVE_GALLIUM_I915=yes
2462             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2463             gallium_require_drm "Gallium i915"
2464             gallium_require_drm_loader
2465             ;;
2466         xilo)
2467             HAVE_GALLIUM_ILO=yes
2468             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2469             gallium_require_drm "Gallium i965/ilo"
2470             gallium_require_drm_loader
2471             ;;
2472         xr300)
2473             HAVE_GALLIUM_R300=yes
2474             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2475             gallium_require_drm "Gallium R300"
2476             gallium_require_drm_loader
2477             gallium_require_llvm "Gallium R300"
2478             ;;
2479         xr600)
2480             HAVE_GALLIUM_R600=yes
2481             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2482             gallium_require_drm "Gallium R600"
2483             gallium_require_drm_loader
2484             if test "x$enable_opencl" = xyes; then
2485                 radeon_gallium_llvm_check "r600g" "3" "6" "0"
2486                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2487             fi
2488             ;;
2489         xradeonsi)
2490             HAVE_GALLIUM_RADEONSI=yes
2491             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2492             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2493             gallium_require_drm "radeonsi"
2494             gallium_require_drm_loader
2495             radeon_gallium_llvm_check "radeonsi" "3" "6" "0"
2496             require_egl_drm "radeonsi"
2497             ;;
2498         xnouveau)
2499             HAVE_GALLIUM_NOUVEAU=yes
2500             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2501             gallium_require_drm "nouveau"
2502             gallium_require_drm_loader
2503             ;;
2504         xfreedreno)
2505             HAVE_GALLIUM_FREEDRENO=yes
2506             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2507             gallium_require_drm "freedreno"
2508             gallium_require_drm_loader
2509             ;;
2510         xswrast)
2511             HAVE_GALLIUM_SOFTPIPE=yes
2512             if test "x$MESA_LLVM" = x1; then
2513                 HAVE_GALLIUM_LLVMPIPE=yes
2514             fi
2515             ;;
2516         xswr)
2517             swr_llvm_check "swr"
2518
2519             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2520                 ",-std=c++11" \
2521                 SWR_CXX11_CXXFLAGS
2522             AC_SUBST([SWR_CXX11_CXXFLAGS])
2523
2524             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2525                 ",-mavx,-march=core-avx" \
2526                 SWR_AVX_CXXFLAGS
2527             AC_SUBST([SWR_AVX_CXXFLAGS])
2528
2529             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2530                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2531                 SWR_AVX2_CXXFLAGS
2532             AC_SUBST([SWR_AVX2_CXXFLAGS])
2533
2534             HAVE_GALLIUM_SWR=yes
2535             ;;
2536         xvc4)
2537             HAVE_GALLIUM_VC4=yes
2538             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2539             gallium_require_drm "vc4"
2540             gallium_require_drm_loader
2541
2542             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2543                               [USE_VC4_SIMULATOR=yes;
2544                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2545                               [USE_VC4_SIMULATOR=no])
2546             ;;
2547         xvirgl)
2548             HAVE_GALLIUM_VIRGL=yes
2549             gallium_require_drm "virgl"
2550             gallium_require_drm_loader
2551             require_egl_drm "virgl"
2552             ;;
2553         *)
2554             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2555             ;;
2556         esac
2557     done
2558 fi
2559
2560 if test "x$HAVE_RADEON_VULKAN" = "xyes"; then
2561     radeon_llvm_check "radv" "3" "9" "0"
2562 fi
2563
2564 dnl Set LLVM_LIBS - This is done after the driver configuration so
2565 dnl that drivers can add additional components to LLVM_COMPONENTS.
2566 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2567 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2568 dnl this was causing the same libraries to be appear multiple times
2569 dnl in LLVM_LIBS.
2570
2571 if test "x$MESA_LLVM" != x0; then
2572
2573     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2574        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2575     fi
2576     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2577
2578     dnl llvm-config may not give the right answer when llvm is a built as a
2579     dnl single shared library, so we must work the library name out for
2580     dnl ourselves.
2581     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2582     if test "x$enable_llvm_shared_libs" = xyes; then
2583         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2584         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2585         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2586
2587         if test "x$llvm_have_one_so" = xyes; then
2588             dnl LLVM was built using auto*, so there is only one shared object.
2589             LLVM_LIBS="-l$LLVM_SO_NAME"
2590         else
2591             dnl If LLVM was built with CMake, there will be one shared object per
2592             dnl component.
2593             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2594                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2595         Please make sure you have built llvm with the --enable-shared option
2596         and that your llvm libraries are installed in $LLVM_LIBDIR
2597         If you have installed your llvm libraries to a different directory you
2598         can use the --with-llvm-prefix= configure flag to specify this directory.
2599         NOTE: Mesa is attempting to use llvm shared libraries by default.
2600         If you do not want to build with llvm shared libraries and instead want to
2601         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2602         invocation and rebuild.])])
2603
2604            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2605            dnl install uses a shared object for each component and we have
2606            dnl already added all of these objects to LLVM_LIBS.
2607         fi
2608     else
2609         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2610         dnl We need to link to llvm system libs when using static libs
2611         dnl However, only llvm 3.5+ provides --system-libs
2612         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2613             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2614         fi
2615     fi
2616 fi
2617
2618 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2619 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2621 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2622 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2623 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2624 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2625                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2626 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2627 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2628 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2629 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2630 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2631 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2632                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2633                                          "x$HAVE_GALLIUM_SWR" = xyes)
2634 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2635 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2636
2637 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2638
2639 if test "x$enable_dri" = xyes; then
2640     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2641 fi
2642
2643 if test "x$have_drisw_kms" = xyes; then
2644     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2645 fi
2646 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2647
2648 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2649 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2650 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2651 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2652 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2653 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2654
2655 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2656 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2657
2658 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2659                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2660                                       "x$HAVE_RADEON_VULKAN" = xyes)
2661
2662 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2663                                         "x$HAVE_I965_DRI" = xyes)
2664
2665 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2666                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2667                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2668 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2669 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2670 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2671 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2672 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2673 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2674     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2675 fi
2676
2677 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2678 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2679 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2680 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2681                                         "x$enable_gallium_osmesa" = xyes)
2682
2683 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2684 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2685 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2686
2687 AC_SUBST([NINE_MAJOR], 1)
2688 AC_SUBST([NINE_MINOR], 0)
2689 AC_SUBST([NINE_TINY], 0)
2690 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2691
2692 AC_SUBST([VDPAU_MAJOR], 1)
2693 AC_SUBST([VDPAU_MINOR], 0)
2694
2695 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2696 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2697 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2698 AC_SUBST([VA_MINOR], $VA_MINOR)
2699
2700 AC_SUBST([XVMC_MAJOR], 1)
2701 AC_SUBST([XVMC_MINOR], 0)
2702
2703 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2704 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2705 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2706 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2707
2708 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2709 AC_SUBST([XA_MINOR], $XA_MINOR)
2710 AC_SUBST([XA_TINY], $XA_TINY)
2711 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2712
2713 AC_SUBST([TIMESTAMP_CMD], '`test $(SOURCE_DATE_EPOCH) && echo $(SOURCE_DATE_EPOCH) || date +%s`')
2714
2715 AC_ARG_ENABLE(valgrind,
2716               [AS_HELP_STRING([--enable-valgrind],
2717                              [Build mesa with valgrind support (default: auto)])],
2718                              [VALGRIND=$enableval], [VALGRIND=auto])
2719 if test "x$VALGRIND" != xno; then
2720         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2721 fi
2722 AC_MSG_CHECKING([whether to enable Valgrind support])
2723 if test "x$VALGRIND" = xauto; then
2724         VALGRIND="$have_valgrind"
2725 fi
2726
2727 if test "x$VALGRIND" = "xyes"; then
2728         if ! test "x$have_valgrind" = xyes; then
2729                 AC_MSG_ERROR([Valgrind support required but not present])
2730         fi
2731         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2732 fi
2733
2734 AC_MSG_RESULT([$VALGRIND])
2735
2736 dnl Restore LDFLAGS and CPPFLAGS
2737 LDFLAGS="$_SAVE_LDFLAGS"
2738 CPPFLAGS="$_SAVE_CPPFLAGS"
2739
2740 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2741 if test "x$acv_mesa_CLANG" = xyes; then
2742     CFLAGS="$CFLAGS -Qunused-arguments"
2743     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2744 fi
2745
2746 dnl Add user CFLAGS and CXXFLAGS
2747 CFLAGS="$CFLAGS $USER_CFLAGS"
2748 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2749
2750 dnl Substitute the config
2751 AC_CONFIG_FILES([Makefile
2752                 src/Makefile
2753                 src/amd/Makefile
2754                 src/amd/common/Makefile
2755                 src/amd/vulkan/Makefile
2756                 src/compiler/Makefile
2757                 src/egl/Makefile
2758                 src/egl/main/egl.pc
2759                 src/egl/wayland/wayland-drm/Makefile
2760                 src/egl/wayland/wayland-egl/Makefile
2761                 src/egl/wayland/wayland-egl/wayland-egl.pc
2762                 src/gallium/Makefile
2763                 src/gallium/auxiliary/Makefile
2764                 src/gallium/auxiliary/pipe-loader/Makefile
2765                 src/gallium/drivers/freedreno/Makefile
2766                 src/gallium/drivers/ddebug/Makefile
2767                 src/gallium/drivers/i915/Makefile
2768                 src/gallium/drivers/ilo/Makefile
2769                 src/gallium/drivers/llvmpipe/Makefile
2770                 src/gallium/drivers/noop/Makefile
2771                 src/gallium/drivers/nouveau/Makefile
2772                 src/gallium/drivers/r300/Makefile
2773                 src/gallium/drivers/r600/Makefile
2774                 src/gallium/drivers/radeon/Makefile
2775                 src/gallium/drivers/radeonsi/Makefile
2776                 src/gallium/drivers/rbug/Makefile
2777                 src/gallium/drivers/softpipe/Makefile
2778                 src/gallium/drivers/svga/Makefile
2779                 src/gallium/drivers/swr/Makefile
2780                 src/gallium/drivers/trace/Makefile
2781                 src/gallium/drivers/vc4/Makefile
2782                 src/gallium/drivers/virgl/Makefile
2783                 src/gallium/state_trackers/clover/Makefile
2784                 src/gallium/state_trackers/dri/Makefile
2785                 src/gallium/state_trackers/glx/xlib/Makefile
2786                 src/gallium/state_trackers/nine/Makefile
2787                 src/gallium/state_trackers/omx/Makefile
2788                 src/gallium/state_trackers/osmesa/Makefile
2789                 src/gallium/state_trackers/va/Makefile
2790                 src/gallium/state_trackers/vdpau/Makefile
2791                 src/gallium/state_trackers/xa/Makefile
2792                 src/gallium/state_trackers/xvmc/Makefile
2793                 src/gallium/targets/d3dadapter9/Makefile
2794                 src/gallium/targets/d3dadapter9/d3d.pc
2795                 src/gallium/targets/dri/Makefile
2796                 src/gallium/targets/libgl-xlib/Makefile
2797                 src/gallium/targets/omx/Makefile
2798                 src/gallium/targets/opencl/Makefile
2799                 src/gallium/targets/opencl/mesa.icd
2800                 src/gallium/targets/osmesa/Makefile
2801                 src/gallium/targets/osmesa/osmesa.pc
2802                 src/gallium/targets/pipe-loader/Makefile
2803                 src/gallium/targets/va/Makefile
2804                 src/gallium/targets/vdpau/Makefile
2805                 src/gallium/targets/xa/Makefile
2806                 src/gallium/targets/xa/xatracker.pc
2807                 src/gallium/targets/xvmc/Makefile
2808                 src/gallium/tests/trivial/Makefile
2809                 src/gallium/tests/unit/Makefile
2810                 src/gallium/winsys/freedreno/drm/Makefile
2811                 src/gallium/winsys/i915/drm/Makefile
2812                 src/gallium/winsys/intel/drm/Makefile
2813                 src/gallium/winsys/nouveau/drm/Makefile
2814                 src/gallium/winsys/radeon/drm/Makefile
2815                 src/gallium/winsys/amdgpu/drm/Makefile
2816                 src/gallium/winsys/svga/drm/Makefile
2817                 src/gallium/winsys/sw/dri/Makefile
2818                 src/gallium/winsys/sw/kms-dri/Makefile
2819                 src/gallium/winsys/sw/null/Makefile
2820                 src/gallium/winsys/sw/wrapper/Makefile
2821                 src/gallium/winsys/sw/xlib/Makefile
2822                 src/gallium/winsys/vc4/drm/Makefile
2823                 src/gallium/winsys/virgl/drm/Makefile
2824                 src/gallium/winsys/virgl/vtest/Makefile
2825                 src/gbm/Makefile
2826                 src/gbm/main/gbm.pc
2827                 src/glx/Makefile
2828                 src/glx/apple/Makefile
2829                 src/glx/tests/Makefile
2830                 src/glx/windows/Makefile
2831                 src/glx/windows/windowsdriproto.pc
2832                 src/gtest/Makefile
2833                 src/intel/Makefile
2834                 src/intel/tools/Makefile
2835                 src/intel/vulkan/Makefile
2836                 src/loader/Makefile
2837                 src/mapi/Makefile
2838                 src/mapi/es1api/glesv1_cm.pc
2839                 src/mapi/es2api/glesv2.pc
2840                 src/mapi/glapi/gen/Makefile
2841                 src/mesa/Makefile
2842                 src/mesa/gl.pc
2843                 src/mesa/drivers/dri/dri.pc
2844                 src/mesa/drivers/dri/common/Makefile
2845                 src/mesa/drivers/dri/common/xmlpool/Makefile
2846                 src/mesa/drivers/dri/i915/Makefile
2847                 src/mesa/drivers/dri/i965/Makefile
2848                 src/mesa/drivers/dri/Makefile
2849                 src/mesa/drivers/dri/nouveau/Makefile
2850                 src/mesa/drivers/dri/r200/Makefile
2851                 src/mesa/drivers/dri/radeon/Makefile
2852                 src/mesa/drivers/dri/swrast/Makefile
2853                 src/mesa/drivers/osmesa/Makefile
2854                 src/mesa/drivers/osmesa/osmesa.pc
2855                 src/mesa/drivers/x11/Makefile
2856                 src/mesa/main/tests/Makefile
2857                 src/util/Makefile
2858                 src/util/tests/hash_table/Makefile])
2859
2860 AC_OUTPUT
2861
2862 # Fix up dependencies in *.Plo files, where we changed the extension of a
2863 # source file
2864 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2865
2866
2867 dnl
2868 dnl Output some configuration info for the user
2869 dnl
2870 echo ""
2871 echo "        prefix:          $prefix"
2872 echo "        exec_prefix:     $exec_prefix"
2873 echo "        libdir:          $libdir"
2874 echo "        includedir:      $includedir"
2875
2876 dnl API info
2877 echo ""
2878 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2879
2880 dnl Driver info
2881 echo ""
2882 case "x$enable_osmesa$enable_gallium_osmesa" in
2883 xnoyes)
2884         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2885         ;;
2886 xyesno)
2887         echo "        OSMesa:          lib$OSMESA_LIB"
2888         ;;
2889 xnono)
2890         echo "        OSMesa:          no"
2891         ;;
2892 esac
2893
2894 echo ""
2895 if test "x$enable_dri" != xno; then
2896         echo "        DRI platform:    $dri_platform"
2897         if test -z "$DRI_DIRS"; then
2898             echo "        DRI drivers:     no"
2899         else
2900             echo "        DRI drivers:     $DRI_DIRS"
2901         fi
2902         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2903 fi
2904
2905 case "x$enable_glx" in
2906 xdri)
2907     echo "        GLX:             DRI-based"
2908     ;;
2909 xxlib)
2910     echo "        GLX:             Xlib-based"
2911     ;;
2912 xgallium-xlib)
2913     echo "        GLX:             Xlib-based (Gallium)"
2914     ;;
2915 *)
2916     echo "        GLX:             $enable_glx"
2917     ;;
2918 esac
2919
2920 dnl EGL
2921 echo ""
2922 echo "        EGL:             $enable_egl"
2923 if test "$enable_egl" = yes; then
2924     echo "        EGL platforms:   $egl_platforms"
2925
2926     egl_drivers=""
2927     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2928         egl_drivers="$egl_drivers builtin:egl_dri2"
2929     fi
2930     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2931         egl_drivers="$egl_drivers builtin:egl_dri3"
2932     fi
2933
2934     echo "        EGL drivers:    $egl_drivers"
2935 fi
2936
2937 # Vulkan
2938 echo ""
2939 if test "x$VULKAN_DRIVERS" != x; then
2940     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2941     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2942 else
2943     echo "        Vulkan drivers:  no"
2944 fi
2945
2946 echo ""
2947 if test "x$MESA_LLVM" = x1; then
2948     echo "        llvm:            yes"
2949     echo "        llvm-config:     $LLVM_CONFIG"
2950     echo "        llvm-version:    $LLVM_VERSION"
2951 else
2952     echo "        llvm:            no"
2953 fi
2954
2955 echo ""
2956 if test -n "$with_gallium_drivers"; then
2957     echo "        Gallium drivers: $gallium_drivers"
2958     echo "        Gallium st:      $gallium_st"
2959 else
2960     echo "        Gallium:         no"
2961 fi
2962
2963 echo ""
2964 if test "x$enable_gallium_extra_hud" != xyes; then
2965     echo "        HUD extra stats: no"
2966 else
2967     echo "        HUD extra stats: yes"
2968 fi
2969
2970 if test "x$enable_lmsensors" != xyes; then
2971     echo "        HUD lmsensors:   no"
2972 else
2973     echo "        HUD lmsensors:   yes"
2974 fi
2975
2976 dnl Shader cache
2977 echo ""
2978 echo "        Shader cache:    $enable_shader_cache"
2979 if test "x$enable_shader_cache" = "xyes"; then
2980     echo "        With SHA1 from:  $with_sha1"
2981 fi
2982
2983 dnl Libraries
2984 echo ""
2985 echo "        Shared libs:     $enable_shared"
2986 echo "        Static libs:     $enable_static"
2987 echo "        Shared-glapi:    $enable_shared_glapi"
2988
2989 dnl Compiler options
2990 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2991 cflags=`echo $CFLAGS | \
2992     $SED 's/^ *//;s/  */ /;s/ *$//'`
2993 cxxflags=`echo $CXXFLAGS | \
2994     $SED 's/^ *//;s/  */ /;s/ *$//'`
2995 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2996 echo ""
2997 echo "        CFLAGS:          $cflags"
2998 echo "        CXXFLAGS:        $cxxflags"
2999 echo "        Macros:          $defines"
3000 echo ""
3001 if test "x$MESA_LLVM" = x1; then
3002     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3003     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3004     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3005     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3006     echo ""
3007 fi
3008 echo "        PYTHON2:         $PYTHON2"
3009
3010 echo ""
3011 echo "        Run '${MAKE-make}' to build Mesa"
3012 echo ""