src/compiler/glsl/glsl_lexer.ll

   1 %{
   2 /*
   3  * Copyright © 2008, 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include <ctype.h>
  25 #include <limits.h>
  26 #include "util/strtod.h"
  27 #include "ast.h"
  28 #include "glsl_parser_extras.h"
  29 #include "glsl_parser.h"
  30
  31 static int classify_identifier(struct _mesa_glsl_parse_state *, const char *);
  32
  33 #ifdef _MSC_VER
  34 #define YY_NO_UNISTD_H
  35 #endif
  36
  37 #define YY_USER_ACTION                                          \
  38    do {                                                         \
  39       yylloc->first_column = yycolumn + 1;                      \
  40       yylloc->first_line = yylloc->last_line = yylineno + 1;    \
  41       yycolumn += yyleng;                                       \
  42       yylloc->last_column = yycolumn + 1;                       \
  43    } while(0);
  44
  45 #define YY_USER_INIT yylineno = 0; yycolumn = 0; yylloc->source = 0;
  46
  47 /* A macro for handling reserved words and keywords across language versions.
  48  *
  49  * Certain words start out as identifiers, become reserved words in
  50  * later language revisions, and finally become language keywords.
  51  * This may happen at different times in desktop GLSL and GLSL ES.
  52  *
  53  * For example, consider the following lexer rule:
  54  * samplerBuffer       KEYWORD(130, 0, 140, 0, SAMPLERBUFFER)
  55  *
  56  * This means that "samplerBuffer" will be treated as:
  57  * - a keyword (SAMPLERBUFFER token)         ...in GLSL >= 1.40
  58  * - a reserved word - error                 ...in GLSL >= 1.30
  59  * - an identifier                           ...in GLSL <  1.30 or GLSL ES
  60  */
  61 #define KEYWORD(reserved_glsl, reserved_glsl_es,                        \
  62                 allowed_glsl, allowed_glsl_es, token)                   \
  63    KEYWORD_WITH_ALT(reserved_glsl, reserved_glsl_es,                    \
  64                     allowed_glsl, allowed_glsl_es, false, token)
  65
  66 /**
  67  * Like the KEYWORD macro, but the word is also treated as a keyword
  68  * if the given boolean expression is true.
  69  */
  70 #define KEYWORD_WITH_ALT(reserved_glsl, reserved_glsl_es,               \
  71                          allowed_glsl, allowed_glsl_es,                 \
  72                          alt_expr, token)                               \
  73    do {                                                                 \
  74       if (yyextra->is_version(allowed_glsl, allowed_glsl_es)            \
  75           || (alt_expr)) {                                              \
  76          return token;                                                  \
  77       } else if (yyextra->is_version(reserved_glsl,                     \
  78                                      reserved_glsl_es)) {               \
  79          _mesa_glsl_error(yylloc, yyextra,                              \
  80                           "illegal use of reserved word `%s'", yytext); \
  81          return ERROR_TOK;                                              \
  82       } else {                                                          \
  83          void *mem_ctx = yyextra->linalloc;                                     \
  84          yylval->identifier = linear_strdup(mem_ctx, yytext);           \
  85          return classify_identifier(yyextra, yytext);                   \
  86       }                                                                 \
  87    } while (0)
  88
  89 /**
  90  * A macro for handling keywords that have been present in GLSL since
  91  * its origin, but were changed into reserved words in GLSL 3.00 ES.
  92  */
  93 #define DEPRECATED_ES_KEYWORD(token)                                    \
  94    do {                                                                 \
  95       if (yyextra->is_version(0, 300)) {                                \
  96          _mesa_glsl_error(yylloc, yyextra,                              \
  97                           "illegal use of reserved word `%s'", yytext); \
  98          return ERROR_TOK;                                              \
  99       } else {                                                          \
 100          return token;                                                  \
 101       }                                                                 \
 102    } while (0)
 103
 104 static int
 105 literal_integer(char *text, int len, struct _mesa_glsl_parse_state *state,
 106                 YYSTYPE *lval, YYLTYPE *lloc, int base)
 107 {
 108    bool is_uint = (text[len - 1] == 'u' ||
 109                    text[len - 1] == 'U');
 110    const char *digits = text;
 111
 112    /* Skip "0x" */
 113    if (base == 16)
 114       digits += 2;
 115
 116    unsigned long long value = strtoull(digits, NULL, base);
 117
 118    lval->n = (int)value;
 119
 120    if (value > UINT_MAX) {
 121       /* Note that signed 0xffffffff is valid, not out of range! */
 122       if (state->is_version(130, 300)) {
 123          _mesa_glsl_error(lloc, state,
 124                           "literal value `%s' out of range", text);
 125       } else {
 126          _mesa_glsl_warning(lloc, state,
 127                             "literal value `%s' out of range", text);
 128       }
 129    } else if (base == 10 && !is_uint && (unsigned)value > (unsigned)INT_MAX + 1) {
 130       /* Tries to catch unintentionally providing a negative value.
 131        * Note that -2147483648 is parsed as -(2147483648), so we don't
 132        * want to warn for INT_MAX.
 133        */
 134       _mesa_glsl_warning(lloc, state,
 135                          "signed literal value `%s' is interpreted as %d",
 136                          text, lval->n);
 137    }
 138    return is_uint ? UINTCONSTANT : INTCONSTANT;
 139 }
 140
 141 #define LITERAL_INTEGER(base) \
 142    literal_integer(yytext, yyleng, yyextra, yylval, yylloc, base)
 143
 144 %}
 145
 146 %option bison-bridge bison-locations reentrant noyywrap
 147 %option nounput noyy_top_state
 148 %option never-interactive
 149 %option prefix="_mesa_glsl_lexer_"
 150 %option extra-type="struct _mesa_glsl_parse_state *"
 151 %option warn nodefault
 152
 153         /* Note: When adding any start conditions to this list, you must also
 154          * update the "Internal compiler error" catch-all rule near the end of
 155          * this file. */
 156 %x PP PRAGMA
 157
 158 DEC_INT         [1-9][0-9]*
 159 HEX_INT         0[xX][0-9a-fA-F]+
 160 OCT_INT         0[0-7]*
 161 INT             ({DEC_INT}|{HEX_INT}|{OCT_INT})
 162 SPC             [ \t]*
 163 SPCP            [ \t]+
 164 HASH            ^{SPC}#{SPC}
 165 %%
 166
 167 [ \r\t]+                ;
 168
 169     /* Preprocessor tokens. */
 170 ^[ \t]*#[ \t]*$                 ;
 171 ^[ \t]*#[ \t]*version           { BEGIN PP; return VERSION_TOK; }
 172 ^[ \t]*#[ \t]*extension         { BEGIN PP; return EXTENSION; }
 173 {HASH}line{SPCP}{INT}{SPCP}{INT}{SPC}$ {
 174                                    /* Eat characters until the first digit is
 175                                     * encountered
 176                                     */
 177                                    char *ptr = yytext;
 178                                    while (!isdigit(*ptr))
 179                                       ptr++;
 180
 181                                    /* Subtract one from the line number because
 182                                     * yylineno is zero-based instead of
 183                                     * one-based.
 184                                     */
 185                                    yylineno = strtol(ptr, &ptr, 0) - 1;
 186
 187                                    /* From GLSL 3.30 and GLSL ES on, after processing the
 188                                     * line directive (including its new-line), the implementation
 189                                     * will behave as if it is compiling at the line number passed
 190                                     * as argument. It was line number + 1 in older specifications.
 191                                     */
 192                                    if (yyextra->is_version(330, 100))
 193                                       yylineno--;
 194
 195                                    yylloc->source = strtol(ptr, NULL, 0);
 196                                 }
 197 {HASH}line{SPCP}{INT}{SPC}$     {
 198                                    /* Eat characters until the first digit is
 199                                     * encountered
 200                                     */
 201                                    char *ptr = yytext;
 202                                    while (!isdigit(*ptr))
 203                                       ptr++;
 204
 205                                    /* Subtract one from the line number because
 206                                     * yylineno is zero-based instead of
 207                                     * one-based.
 208                                     */
 209                                    yylineno = strtol(ptr, &ptr, 0) - 1;
 210
 211                                    /* From GLSL 3.30 and GLSL ES on, after processing the
 212                                     * line directive (including its new-line), the implementation
 213                                     * will behave as if it is compiling at the line number passed
 214                                     * as argument. It was line number + 1 in older specifications.
 215                                     */
 216                                    if (yyextra->is_version(330, 100))
 217                                       yylineno--;
 218                                 }
 219 ^{SPC}#{SPC}pragma{SPCP}debug{SPC}\({SPC}on{SPC}\) {
 220                                   BEGIN PP;
 221                                   return PRAGMA_DEBUG_ON;
 222                                 }
 223 ^{SPC}#{SPC}pragma{SPCP}debug{SPC}\({SPC}off{SPC}\) {
 224                                   BEGIN PP;
 225                                   return PRAGMA_DEBUG_OFF;
 226                                 }
 227 ^{SPC}#{SPC}pragma{SPCP}optimize{SPC}\({SPC}on{SPC}\) {
 228                                   BEGIN PP;
 229                                   return PRAGMA_OPTIMIZE_ON;
 230                                 }
 231 ^{SPC}#{SPC}pragma{SPCP}optimize{SPC}\({SPC}off{SPC}\) {
 232                                   BEGIN PP;
 233                                   return PRAGMA_OPTIMIZE_OFF;
 234                                 }
 235 ^{SPC}#{SPC}pragma{SPCP}STDGL{SPCP}invariant{SPC}\({SPC}all{SPC}\) {
 236                                   BEGIN PP;
 237                                   return PRAGMA_INVARIANT_ALL;
 238                                 }
 239 ^{SPC}#{SPC}pragma{SPCP}        { BEGIN PRAGMA; }
 240
 241 <PRAGMA>\n                      { BEGIN 0; yylineno++; yycolumn = 0; }
 242 <PRAGMA>.                       { }
 243
 244 <PP>\/\/[^\n]*                  { }
 245 <PP>[ \t\r]*                    { }
 246 <PP>:                           return COLON;
 247 <PP>[_a-zA-Z][_a-zA-Z0-9]*      {
 248                                    void *mem_ctx = yyextra->linalloc;
 249                                    yylval->identifier = linear_strdup(mem_ctx, yytext);
 250                                    return IDENTIFIER;
 251                                 }
 252 <PP>[1-9][0-9]*                 {
 253                                     yylval->n = strtol(yytext, NULL, 10);
 254                                     return INTCONSTANT;
 255                                 }
 256 <PP>0                           {
 257                                     yylval->n = 0;
 258                                     return INTCONSTANT;
 259                                 }
 260 <PP>\n                          { BEGIN 0; yylineno++; yycolumn = 0; return EOL; }
 261 <PP>.                           { return yytext[0]; }
 262
 263 \n              { yylineno++; yycolumn = 0; }
 264
 265 attribute       DEPRECATED_ES_KEYWORD(ATTRIBUTE);
 266 const           return CONST_TOK;
 267 bool            return BOOL_TOK;
 268 float           return FLOAT_TOK;
 269 int             return INT_TOK;
 270 uint            KEYWORD(130, 300, 130, 300, UINT_TOK);
 271
 272 break           return BREAK;
 273 continue        return CONTINUE;
 274 do              return DO;
 275 while           return WHILE;
 276 else            return ELSE;
 277 for             return FOR;
 278 if              return IF;
 279 discard         return DISCARD;
 280 return          return RETURN;
 281
 282 bvec2           return BVEC2;
 283 bvec3           return BVEC3;
 284 bvec4           return BVEC4;
 285 ivec2           return IVEC2;
 286 ivec3           return IVEC3;
 287 ivec4           return IVEC4;
 288 uvec2           KEYWORD(130, 300, 130, 300, UVEC2);
 289 uvec3           KEYWORD(130, 300, 130, 300, UVEC3);
 290 uvec4           KEYWORD(130, 300, 130, 300, UVEC4);
 291 vec2            return VEC2;
 292 vec3            return VEC3;
 293 vec4            return VEC4;
 294 mat2            return MAT2X2;
 295 mat3            return MAT3X3;
 296 mat4            return MAT4X4;
 297 mat2x2          KEYWORD(120, 300, 120, 300, MAT2X2);
 298 mat2x3          KEYWORD(120, 300, 120, 300, MAT2X3);
 299 mat2x4          KEYWORD(120, 300, 120, 300, MAT2X4);
 300 mat3x2          KEYWORD(120, 300, 120, 300, MAT3X2);
 301 mat3x3          KEYWORD(120, 300, 120, 300, MAT3X3);
 302 mat3x4          KEYWORD(120, 300, 120, 300, MAT3X4);
 303 mat4x2          KEYWORD(120, 300, 120, 300, MAT4X2);
 304 mat4x3          KEYWORD(120, 300, 120, 300, MAT4X3);
 305 mat4x4          KEYWORD(120, 300, 120, 300, MAT4X4);
 306
 307 in              return IN_TOK;
 308 out             return OUT_TOK;
 309 inout           return INOUT_TOK;
 310 uniform         return UNIFORM;
 311 buffer          KEYWORD_WITH_ALT(0, 0, 430, 310, yyextra->ARB_shader_storage_buffer_object_enable, BUFFER);
 312 varying         DEPRECATED_ES_KEYWORD(VARYING);
 313 centroid        KEYWORD(120, 300, 120, 300, CENTROID);
 314 invariant       KEYWORD(120, 100, 120, 100, INVARIANT);
 315 flat            KEYWORD(130, 100, 130, 300, FLAT);
 316 smooth          KEYWORD(130, 300, 130, 300, SMOOTH);
 317 noperspective   KEYWORD(130, 300, 130, 0, NOPERSPECTIVE);
 318 patch           KEYWORD_WITH_ALT(0, 300, 400, 320, yyextra->has_tessellation_shader(), PATCH);
 319
 320 sampler1D       DEPRECATED_ES_KEYWORD(SAMPLER1D);
 321 sampler2D       return SAMPLER2D;
 322 sampler3D       return SAMPLER3D;
 323 samplerCube     return SAMPLERCUBE;
 324 sampler1DArray  KEYWORD(130, 300, 130, 0, SAMPLER1DARRAY);
 325 sampler2DArray  KEYWORD(130, 300, 130, 300, SAMPLER2DARRAY);
 326 sampler1DShadow DEPRECATED_ES_KEYWORD(SAMPLER1DSHADOW);
 327 sampler2DShadow return SAMPLER2DSHADOW;
 328 samplerCubeShadow       KEYWORD(130, 300, 130, 300, SAMPLERCUBESHADOW);
 329 sampler1DArrayShadow    KEYWORD(130, 300, 130, 0, SAMPLER1DARRAYSHADOW);
 330 sampler2DArrayShadow    KEYWORD(130, 300, 130, 300, SAMPLER2DARRAYSHADOW);
 331 isampler1D              KEYWORD(130, 300, 130, 0, ISAMPLER1D);
 332 isampler2D              KEYWORD(130, 300, 130, 300, ISAMPLER2D);
 333 isampler3D              KEYWORD(130, 300, 130, 300, ISAMPLER3D);
 334 isamplerCube            KEYWORD(130, 300, 130, 300, ISAMPLERCUBE);
 335 isampler1DArray         KEYWORD(130, 300, 130, 0, ISAMPLER1DARRAY);
 336 isampler2DArray         KEYWORD(130, 300, 130, 300, ISAMPLER2DARRAY);
 337 usampler1D              KEYWORD(130, 300, 130, 0, USAMPLER1D);
 338 usampler2D              KEYWORD(130, 300, 130, 300, USAMPLER2D);
 339 usampler3D              KEYWORD(130, 300, 130, 300, USAMPLER3D);
 340 usamplerCube            KEYWORD(130, 300, 130, 300, USAMPLERCUBE);
 341 usampler1DArray         KEYWORD(130, 300, 130, 0, USAMPLER1DARRAY);
 342 usampler2DArray         KEYWORD(130, 300, 130, 300, USAMPLER2DARRAY);
 343
 344    /* additional keywords in ARB_texture_multisample, included in GLSL 1.50 */
 345    /* these are reserved but not defined in GLSL 3.00 */
 346    /* [iu]sampler2DMS are defined in GLSL ES 3.10 */
 347 sampler2DMS        KEYWORD_WITH_ALT(150, 300, 150, 310, yyextra->ARB_texture_multisample_enable, SAMPLER2DMS);
 348 isampler2DMS       KEYWORD_WITH_ALT(150, 300, 150, 310, yyextra->ARB_texture_multisample_enable, ISAMPLER2DMS);
 349 usampler2DMS       KEYWORD_WITH_ALT(150, 300, 150, 310, yyextra->ARB_texture_multisample_enable, USAMPLER2DMS);
 350 sampler2DMSArray   KEYWORD_WITH_ALT(150, 300, 150, 320, yyextra->ARB_texture_multisample_enable || yyextra->OES_texture_storage_multisample_2d_array_enable, SAMPLER2DMSARRAY);
 351 isampler2DMSArray  KEYWORD_WITH_ALT(150, 300, 150, 320, yyextra->ARB_texture_multisample_enable || yyextra->OES_texture_storage_multisample_2d_array_enable, ISAMPLER2DMSARRAY);
 352 usampler2DMSArray  KEYWORD_WITH_ALT(150, 300, 150, 320, yyextra->ARB_texture_multisample_enable || yyextra->OES_texture_storage_multisample_2d_array_enable, USAMPLER2DMSARRAY);
 353
 354    /* keywords available with ARB_texture_cube_map_array_enable extension on desktop GLSL */
 355 samplerCubeArray   KEYWORD_WITH_ALT(400, 310, 400, 320, yyextra->ARB_texture_cube_map_array_enable || yyextra->OES_texture_cube_map_array_enable || yyextra->EXT_texture_cube_map_array_enable, SAMPLERCUBEARRAY);
 356 isamplerCubeArray KEYWORD_WITH_ALT(400, 310, 400, 320, yyextra->ARB_texture_cube_map_array_enable || yyextra->OES_texture_cube_map_array_enable || yyextra->EXT_texture_cube_map_array_enable, ISAMPLERCUBEARRAY);
 357 usamplerCubeArray KEYWORD_WITH_ALT(400, 310, 400, 320, yyextra->ARB_texture_cube_map_array_enable || yyextra->OES_texture_cube_map_array_enable || yyextra->EXT_texture_cube_map_array_enable, USAMPLERCUBEARRAY);
 358 samplerCubeArrayShadow   KEYWORD_WITH_ALT(400, 310, 400, 320, yyextra->ARB_texture_cube_map_array_enable || yyextra->OES_texture_cube_map_array_enable || yyextra->EXT_texture_cube_map_array_enable, SAMPLERCUBEARRAYSHADOW);
 359
 360 samplerExternalOES              {
 361                           if (yyextra->OES_EGL_image_external_enable)
 362                              return SAMPLEREXTERNALOES;
 363                           else
 364                              return IDENTIFIER;
 365                 }
 366
 367    /* keywords available with ARB_gpu_shader5 */
 368 precise         KEYWORD_WITH_ALT(400, 310, 400, 320, yyextra->ARB_gpu_shader5_enable || yyextra->EXT_gpu_shader5_enable || yyextra->OES_gpu_shader5_enable, PRECISE);
 369
 370    /* keywords available with ARB_shader_image_load_store */
 371 image1D         KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IMAGE1D);
 372 image2D         KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, IMAGE2D);
 373 image3D         KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, IMAGE3D);
 374 image2DRect     KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IMAGE2DRECT);
 375 imageCube       KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, IMAGECUBE);
 376 imageBuffer     KEYWORD_WITH_ALT(130, 300, 420, 320, yyextra->ARB_shader_image_load_store_enable || yyextra->EXT_texture_buffer_enable || yyextra->OES_texture_buffer_enable, IMAGEBUFFER);
 377 image1DArray    KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IMAGE1DARRAY);
 378 image2DArray    KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, IMAGE2DARRAY);
 379 imageCubeArray  KEYWORD_WITH_ALT(130, 300, 420, 320, yyextra->ARB_shader_image_load_store_enable || yyextra->OES_texture_cube_map_array_enable || yyextra->EXT_texture_cube_map_array_enable, IMAGECUBEARRAY);
 380 image2DMS       KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IMAGE2DMS);
 381 image2DMSArray  KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IMAGE2DMSARRAY);
 382 iimage1D        KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IIMAGE1D);
 383 iimage2D        KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, IIMAGE2D);
 384 iimage3D        KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, IIMAGE3D);
 385 iimage2DRect    KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IIMAGE2DRECT);
 386 iimageCube      KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, IIMAGECUBE);
 387 iimageBuffer    KEYWORD_WITH_ALT(130, 300, 420, 320, yyextra->ARB_shader_image_load_store_enable || yyextra->EXT_texture_buffer_enable || yyextra->OES_texture_buffer_enable, IIMAGEBUFFER);
 388 iimage1DArray   KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IIMAGE1DARRAY);
 389 iimage2DArray   KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, IIMAGE2DARRAY);
 390 iimageCubeArray KEYWORD_WITH_ALT(130, 300, 420, 320, yyextra->ARB_shader_image_load_store_enable || yyextra->OES_texture_cube_map_array_enable || yyextra->EXT_texture_cube_map_array_enable, IIMAGECUBEARRAY);
 391 iimage2DMS      KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IIMAGE2DMS);
 392 iimage2DMSArray KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, IIMAGE2DMSARRAY);
 393 uimage1D        KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, UIMAGE1D);
 394 uimage2D        KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, UIMAGE2D);
 395 uimage3D        KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, UIMAGE3D);
 396 uimage2DRect    KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, UIMAGE2DRECT);
 397 uimageCube      KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, UIMAGECUBE);
 398 uimageBuffer    KEYWORD_WITH_ALT(130, 300, 420, 320, yyextra->ARB_shader_image_load_store_enable || yyextra->EXT_texture_buffer_enable || yyextra->OES_texture_buffer_enable, UIMAGEBUFFER);
 399 uimage1DArray   KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, UIMAGE1DARRAY);
 400 uimage2DArray   KEYWORD_WITH_ALT(130, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable, UIMAGE2DARRAY);
 401 uimageCubeArray KEYWORD_WITH_ALT(130, 300, 420, 320, yyextra->ARB_shader_image_load_store_enable || yyextra->OES_texture_cube_map_array_enable || yyextra->EXT_texture_cube_map_array_enable, UIMAGECUBEARRAY);
 402 uimage2DMS      KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, UIMAGE2DMS);
 403 uimage2DMSArray KEYWORD_WITH_ALT(130, 300, 420, 0, yyextra->ARB_shader_image_load_store_enable, UIMAGE2DMSARRAY);
 404 image1DShadow           KEYWORD(130, 300, 0, 0, IMAGE1DSHADOW);
 405 image2DShadow           KEYWORD(130, 300, 0, 0, IMAGE2DSHADOW);
 406 image1DArrayShadow      KEYWORD(130, 300, 0, 0, IMAGE1DARRAYSHADOW);
 407 image2DArrayShadow      KEYWORD(130, 300, 0, 0, IMAGE2DARRAYSHADOW);
 408
 409 coherent       KEYWORD_WITH_ALT(420, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable || yyextra->ARB_shader_storage_buffer_object_enable, COHERENT);
 410 volatile       KEYWORD_WITH_ALT(110, 100, 420, 310, yyextra->ARB_shader_image_load_store_enable || yyextra->ARB_shader_storage_buffer_object_enable, VOLATILE);
 411 restrict       KEYWORD_WITH_ALT(420, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable || yyextra->ARB_shader_storage_buffer_object_enable, RESTRICT);
 412 readonly       KEYWORD_WITH_ALT(420, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable || yyextra->ARB_shader_storage_buffer_object_enable, READONLY);
 413 writeonly      KEYWORD_WITH_ALT(420, 300, 420, 310, yyextra->ARB_shader_image_load_store_enable || yyextra->ARB_shader_storage_buffer_object_enable, WRITEONLY);
 414
 415 atomic_uint     KEYWORD_WITH_ALT(420, 300, 420, 310, yyextra->ARB_shader_atomic_counters_enable, ATOMIC_UINT);
 416
 417 shared          KEYWORD_WITH_ALT(430, 310, 430, 310, yyextra->ARB_compute_shader_enable, SHARED);
 418
 419 struct          return STRUCT;
 420 void            return VOID_TOK;
 421
 422 layout          {
 423                   if ((yyextra->is_version(140, 300))
 424                       || yyextra->AMD_conservative_depth_enable
 425                       || yyextra->ARB_conservative_depth_enable
 426                       || yyextra->ARB_explicit_attrib_location_enable
 427                       || yyextra->ARB_explicit_uniform_location_enable
 428                       || yyextra->has_separate_shader_objects()
 429                       || yyextra->ARB_uniform_buffer_object_enable
 430                       || yyextra->ARB_fragment_coord_conventions_enable
 431                       || yyextra->ARB_shading_language_420pack_enable
 432                       || yyextra->ARB_compute_shader_enable
 433                       || yyextra->ARB_tessellation_shader_enable) {
 434                       return LAYOUT_TOK;
 435                    } else {
 436                       void *mem_ctx = yyextra->linalloc;
 437                       yylval->identifier = linear_strdup(mem_ctx, yytext);
 438                       return classify_identifier(yyextra, yytext);
 439                    }
 440                 }
 441
 442 \+\+            return INC_OP;
 443 --              return DEC_OP;
 444 \<=             return LE_OP;
 445 >=              return GE_OP;
 446 ==              return EQ_OP;
 447 !=              return NE_OP;
 448 &&              return AND_OP;
 449 \|\|            return OR_OP;
 450 "^^"            return XOR_OP;
 451 "<<"            return LEFT_OP;
 452 ">>"            return RIGHT_OP;
 453
 454 \*=             return MUL_ASSIGN;
 455 \/=             return DIV_ASSIGN;
 456 \+=             return ADD_ASSIGN;
 457 \%=             return MOD_ASSIGN;
 458 \<\<=           return LEFT_ASSIGN;
 459 >>=             return RIGHT_ASSIGN;
 460 &=              return AND_ASSIGN;
 461 "^="            return XOR_ASSIGN;
 462 \|=             return OR_ASSIGN;
 463 -=              return SUB_ASSIGN;
 464
 465 [1-9][0-9]*[uU]?        {
 466                             return LITERAL_INTEGER(10);
 467                         }
 468 0[xX][0-9a-fA-F]+[uU]?  {
 469                             return LITERAL_INTEGER(16);
 470                         }
 471 0[0-7]*[uU]?            {
 472                             return LITERAL_INTEGER(8);
 473                         }
 474
 475 [0-9]+\.[0-9]+([eE][+-]?[0-9]+)?[fF]?   |
 476 \.[0-9]+([eE][+-]?[0-9]+)?[fF]?         |
 477 [0-9]+\.([eE][+-]?[0-9]+)?[fF]?         |
 478 [0-9]+[eE][+-]?[0-9]+[fF]?              {
 479                             struct _mesa_glsl_parse_state *state = yyextra;
 480                             char suffix = yytext[strlen(yytext) - 1];
 481                             if (!state->is_version(120, 300) &&
 482                                 (suffix == 'f' || suffix == 'F')) {
 483                                 _mesa_glsl_warning(yylloc, state,
 484                                                    "Float suffixes are invalid in GLSL 1.10");
 485                             }
 486                             yylval->real = _mesa_strtof(yytext, NULL);
 487                             return FLOATCONSTANT;
 488                         }
 489
 490 [0-9]+\.[0-9]+([eE][+-]?[0-9]+)?(lf|LF) |
 491 \.[0-9]+([eE][+-]?[0-9]+)?(lf|LF)       |
 492 [0-9]+\.([eE][+-]?[0-9]+)?(lf|LF)       |
 493 [0-9]+[eE][+-]?[0-9]+(lf|LF)            {
 494                             if (!yyextra->is_version(400, 0) &&
 495                                 !yyextra->ARB_gpu_shader_fp64_enable)
 496                                 return ERROR_TOK;
 497                             yylval->dreal = _mesa_strtod(yytext, NULL);
 498                             return DOUBLECONSTANT;
 499                         }
 500
 501 true                    {
 502                             yylval->n = 1;
 503                             return BOOLCONSTANT;
 504                         }
 505 false                   {
 506                             yylval->n = 0;
 507                             return BOOLCONSTANT;
 508                         }
 509
 510
 511     /* Reserved words in GLSL 1.10. */
 512 asm             KEYWORD(110, 100, 0, 0, ASM);
 513 class           KEYWORD(110, 100, 0, 0, CLASS);
 514 union           KEYWORD(110, 100, 0, 0, UNION);
 515 enum            KEYWORD(110, 100, 0, 0, ENUM);
 516 typedef         KEYWORD(110, 100, 0, 0, TYPEDEF);
 517 template        KEYWORD(110, 100, 0, 0, TEMPLATE);
 518 this            KEYWORD(110, 100, 0, 0, THIS);
 519 packed          KEYWORD_WITH_ALT(110, 100, 140, 300, yyextra->ARB_uniform_buffer_object_enable, PACKED_TOK);
 520 goto            KEYWORD(110, 100, 0, 0, GOTO);
 521 switch          KEYWORD(110, 100, 130, 300, SWITCH);
 522 default         KEYWORD(110, 100, 130, 300, DEFAULT);
 523 inline          KEYWORD(110, 100, 0, 0, INLINE_TOK);
 524 noinline        KEYWORD(110, 100, 0, 0, NOINLINE);
 525 public          KEYWORD(110, 100, 0, 0, PUBLIC_TOK);
 526 static          KEYWORD(110, 100, 0, 0, STATIC);
 527 extern          KEYWORD(110, 100, 0, 0, EXTERN);
 528 external        KEYWORD(110, 100, 0, 0, EXTERNAL);
 529 interface       KEYWORD(110, 100, 0, 0, INTERFACE);
 530 long            KEYWORD(110, 100, 0, 0, LONG_TOK);
 531 short           KEYWORD(110, 100, 0, 0, SHORT_TOK);
 532 double          KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DOUBLE_TOK);
 533 half            KEYWORD(110, 100, 0, 0, HALF);
 534 fixed           KEYWORD(110, 100, 0, 0, FIXED_TOK);
 535 unsigned        KEYWORD(110, 100, 0, 0, UNSIGNED);
 536 input           KEYWORD(110, 100, 0, 0, INPUT_TOK);
 537 output          KEYWORD(110, 100, 0, 0, OUTPUT);
 538 hvec2           KEYWORD(110, 100, 0, 0, HVEC2);
 539 hvec3           KEYWORD(110, 100, 0, 0, HVEC3);
 540 hvec4           KEYWORD(110, 100, 0, 0, HVEC4);
 541 dvec2           KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DVEC2);
 542 dvec3           KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DVEC3);
 543 dvec4           KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DVEC4);
 544 dmat2           KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT2X2);
 545 dmat3           KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT3X3);
 546 dmat4           KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT4X4);
 547 dmat2x2         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT2X2);
 548 dmat2x3         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT2X3);
 549 dmat2x4         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT2X4);
 550 dmat3x2         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT3X2);
 551 dmat3x3         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT3X3);
 552 dmat3x4         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT3X4);
 553 dmat4x2         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT4X2);
 554 dmat4x3         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT4X3);
 555 dmat4x4         KEYWORD_WITH_ALT(110, 100, 400, 0, yyextra->ARB_gpu_shader_fp64_enable, DMAT4X4);
 556 fvec2           KEYWORD(110, 100, 0, 0, FVEC2);
 557 fvec3           KEYWORD(110, 100, 0, 0, FVEC3);
 558 fvec4           KEYWORD(110, 100, 0, 0, FVEC4);
 559 sampler2DRect           DEPRECATED_ES_KEYWORD(SAMPLER2DRECT);
 560 sampler3DRect           KEYWORD(110, 100, 0, 0, SAMPLER3DRECT);
 561 sampler2DRectShadow     DEPRECATED_ES_KEYWORD(SAMPLER2DRECTSHADOW);
 562 sizeof          KEYWORD(110, 100, 0, 0, SIZEOF);
 563 cast            KEYWORD(110, 100, 0, 0, CAST);
 564 namespace       KEYWORD(110, 100, 0, 0, NAMESPACE);
 565 using           KEYWORD(110, 100, 0, 0, USING);
 566
 567     /* Additional reserved words in GLSL 1.20. */
 568 lowp            KEYWORD(120, 100, 130, 100, LOWP);
 569 mediump         KEYWORD(120, 100, 130, 100, MEDIUMP);
 570 highp           KEYWORD(120, 100, 130, 100, HIGHP);
 571 precision       KEYWORD(120, 100, 130, 100, PRECISION);
 572
 573     /* Additional reserved words in GLSL 1.30. */
 574 case            KEYWORD(130, 300, 130, 300, CASE);
 575 common          KEYWORD(130, 300, 0, 0, COMMON);
 576 partition       KEYWORD(130, 300, 0, 0, PARTITION);
 577 active          KEYWORD(130, 300, 0, 0, ACTIVE);
 578 superp          KEYWORD(130, 100, 0, 0, SUPERP);
 579 samplerBuffer   KEYWORD_WITH_ALT(130, 300, 140, 320, yyextra->EXT_texture_buffer_enable || yyextra->OES_texture_buffer_enable, SAMPLERBUFFER);
 580 filter          KEYWORD(130, 300, 0, 0, FILTER);
 581 row_major       KEYWORD_WITH_ALT(130, 0, 140, 0, yyextra->ARB_uniform_buffer_object_enable && !yyextra->es_shader, ROW_MAJOR);
 582
 583     /* Additional reserved words in GLSL 1.40 */
 584 isampler2DRect  KEYWORD(140, 300, 140, 0, ISAMPLER2DRECT);
 585 usampler2DRect  KEYWORD(140, 300, 140, 0, USAMPLER2DRECT);
 586 isamplerBuffer  KEYWORD_WITH_ALT(140, 300, 140, 320, yyextra->EXT_texture_buffer_enable || yyextra->OES_texture_buffer_enable, ISAMPLERBUFFER);
 587 usamplerBuffer  KEYWORD_WITH_ALT(140, 300, 140, 320, yyextra->EXT_texture_buffer_enable || yyextra->OES_texture_buffer_enable, USAMPLERBUFFER);
 588
 589     /* Additional reserved words in GLSL ES 3.00 */
 590 resource        KEYWORD(420, 300, 0, 0, RESOURCE);
 591 sample          KEYWORD_WITH_ALT(400, 300, 400, 320, yyextra->ARB_gpu_shader5_enable || yyextra->OES_shader_multisample_interpolation_enable, SAMPLE);
 592 subroutine      KEYWORD_WITH_ALT(400, 300, 400, 0, yyextra->ARB_shader_subroutine_enable, SUBROUTINE);
 593
 594     /* Additional words for ARB_gpu_shader_int64 */
 595 int64_t         KEYWORD_WITH_ALT(0, 0, 0, 0, yyextra->ARB_gpu_shader_int64_enable, INT64);
 596 i64vec2         KEYWORD_WITH_ALT(0, 0, 0, 0, yyextra->ARB_gpu_shader_int64_enable, I64VEC2);
 597 i64vec3         KEYWORD_WITH_ALT(0, 0, 0, 0, yyextra->ARB_gpu_shader_int64_enable, I64VEC3);
 598 i64vec4         KEYWORD_WITH_ALT(0, 0, 0, 0, yyextra->ARB_gpu_shader_int64_enable, I64VEC4);
 599
 600 uint64_t        KEYWORD_WITH_ALT(0, 0, 0, 0, yyextra->ARB_gpu_shader_int64_enable, UINT64);
 601 u64vec2         KEYWORD_WITH_ALT(0, 0, 0, 0, yyextra->ARB_gpu_shader_int64_enable, U64VEC2);
 602 u64vec3         KEYWORD_WITH_ALT(0, 0, 0, 0, yyextra->ARB_gpu_shader_int64_enable, U64VEC3);
 603 u64vec4         KEYWORD_WITH_ALT(0, 0, 0, 0, yyextra->ARB_gpu_shader_int64_enable, U64VEC4);
 604
 605 [_a-zA-Z][_a-zA-Z0-9]*  {
 606                             struct _mesa_glsl_parse_state *state = yyextra;
 607                             void *ctx = state->linalloc;
 608                             if (state->es_shader && strlen(yytext) > 1024) {
 609                                _mesa_glsl_error(yylloc, state,
 610                                                 "Identifier `%s' exceeds 1024 characters",
 611                                                 yytext);
 612                             } else {
 613                               yylval->identifier = linear_strdup(ctx, yytext);
 614                             }
 615                             return classify_identifier(state, yytext);
 616                         }
 617
 618 \.                      { struct _mesa_glsl_parse_state *state = yyextra;
 619                           state->is_field = true;
 620                           return DOT_TOK; }
 621
 622 .                       { return yytext[0]; }
 623
 624 %%
 625
 626 int
 627 classify_identifier(struct _mesa_glsl_parse_state *state, const char *name)
 628 {
 629    if (state->is_field) {
 630       state->is_field = false;
 631       return FIELD_SELECTION;
 632    }
 633    if (state->symbols->get_variable(name) || state->symbols->get_function(name))
 634       return IDENTIFIER;
 635    else if (state->symbols->get_type(name))
 636       return TYPE_IDENTIFIER;
 637    else
 638       return NEW_IDENTIFIER;
 639 }
 640
 641 void
 642 _mesa_glsl_lexer_ctor(struct _mesa_glsl_parse_state *state, const char *string)
 643 {
 644    yylex_init_extra(state, & state->scanner);
 645    yy_scan_string(string, state->scanner);
 646 }
 647
 648 void
 649 _mesa_glsl_lexer_dtor(struct _mesa_glsl_parse_state *state)
 650 {
 651    yylex_destroy(state->scanner);
 652 }