src/mesa/program/program_parse.y

   1 %{
   2 /*
   3  * Copyright © 2009 Intel Corporation
   4  *
   5  * Permission is hereby granted, free of charge, to any person obtaining a
   6  * copy of this software and associated documentation files (the "Software"),
   7  * to deal in the Software without restriction, including without limitation
   8  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
   9  * and/or sell copies of the Software, and to permit persons to whom the
  10  * Software is furnished to do so, subject to the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the next
  13  * paragraph) shall be included in all copies or substantial portions of the
  14  * Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  19  * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  */
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <string.h>
  27
  28 #include "main/mtypes.h"
  29 #include "main/imports.h"
  30 #include "program/program.h"
  31 #include "program/prog_parameter.h"
  32 #include "program/prog_parameter_layout.h"
  33 #include "program/prog_statevars.h"
  34 #include "program/prog_instruction.h"
  35
  36 #include "program/symbol_table.h"
  37 #include "program/program_parser.h"
  38
  39 extern void *yy_scan_string(char *);
  40 extern void yy_delete_buffer(void *);
  41
  42 static struct asm_symbol *declare_variable(struct asm_parser_state *state,
  43     char *name, enum asm_type t, struct YYLTYPE *locp);
  44
  45 static int add_state_reference(struct gl_program_parameter_list *param_list,
  46     const gl_state_index tokens[STATE_LENGTH]);
  47
  48 static int initialize_symbol_from_state(struct gl_program *prog,
  49     struct asm_symbol *param_var, const gl_state_index tokens[STATE_LENGTH]);
  50
  51 static int initialize_symbol_from_param(struct gl_program *prog,
  52     struct asm_symbol *param_var, const gl_state_index tokens[STATE_LENGTH]);
  53
  54 static int initialize_symbol_from_const(struct gl_program *prog,
  55     struct asm_symbol *param_var, const struct asm_vector *vec,
  56     GLboolean allowSwizzle);
  57
  58 static int yyparse(struct asm_parser_state *state);
  59
  60 static char *make_error_string(const char *fmt, ...);
  61
  62 static void yyerror(struct YYLTYPE *locp, struct asm_parser_state *state,
  63     const char *s);
  64
  65 static int validate_inputs(struct YYLTYPE *locp,
  66     struct asm_parser_state *state);
  67
  68 static void init_dst_reg(struct prog_dst_register *r);
  69
  70 static void set_dst_reg(struct prog_dst_register *r,
  71                         gl_register_file file, GLint index);
  72
  73 static void init_src_reg(struct asm_src_register *r);
  74
  75 static void set_src_reg(struct asm_src_register *r,
  76                         gl_register_file file, GLint index);
  77
  78 static void set_src_reg_swz(struct asm_src_register *r,
  79                             gl_register_file file, GLint index, GLuint swizzle);
  80
  81 static void asm_instruction_set_operands(struct asm_instruction *inst,
  82     const struct prog_dst_register *dst, const struct asm_src_register *src0,
  83     const struct asm_src_register *src1, const struct asm_src_register *src2);
  84
  85 static struct asm_instruction *asm_instruction_ctor(gl_inst_opcode op,
  86     const struct prog_dst_register *dst, const struct asm_src_register *src0,
  87     const struct asm_src_register *src1, const struct asm_src_register *src2);
  88
  89 static struct asm_instruction *asm_instruction_copy_ctor(
  90     const struct prog_instruction *base, const struct prog_dst_register *dst,
  91     const struct asm_src_register *src0, const struct asm_src_register *src1,
  92     const struct asm_src_register *src2);
  93
  94 #ifndef FALSE
  95 #define FALSE 0
  96 #define TRUE (!FALSE)
  97 #endif
  98
  99 #define YYLLOC_DEFAULT(Current, Rhs, N)                                 \
 100    do {                                                                 \
 101       if (YYID(N)) {                                                    \
 102          (Current).first_line = YYRHSLOC(Rhs, 1).first_line;            \
 103          (Current).first_column = YYRHSLOC(Rhs, 1).first_column;        \
 104          (Current).position = YYRHSLOC(Rhs, 1).position;                \
 105          (Current).last_line = YYRHSLOC(Rhs, N).last_line;              \
 106          (Current).last_column = YYRHSLOC(Rhs, N).last_column;          \
 107       } else {                                                          \
 108          (Current).first_line = YYRHSLOC(Rhs, 0).last_line;             \
 109          (Current).last_line = (Current).first_line;                    \
 110          (Current).first_column = YYRHSLOC(Rhs, 0).last_column;         \
 111          (Current).last_column = (Current).first_column;                \
 112          (Current).position = YYRHSLOC(Rhs, 0).position                 \
 113             + (Current).first_column;                                   \
 114       }                                                                 \
 115    } while(YYID(0))
 116
 117 #define YYLEX_PARAM state->scanner
 118 %}
 119
 120 %pure-parser
 121 %locations
 122 %parse-param { struct asm_parser_state *state }
 123 %error-verbose
 124 %lex-param { void *scanner }
 125
 126 %union {
 127    struct asm_instruction *inst;
 128    struct asm_symbol *sym;
 129    struct asm_symbol temp_sym;
 130    struct asm_swizzle_mask swiz_mask;
 131    struct asm_src_register src_reg;
 132    struct prog_dst_register dst_reg;
 133    struct prog_instruction temp_inst;
 134    char *string;
 135    unsigned result;
 136    unsigned attrib;
 137    int integer;
 138    float real;
 139    gl_state_index state[STATE_LENGTH];
 140    int negate;
 141    struct asm_vector vector;
 142    gl_inst_opcode opcode;
 143
 144    struct {
 145       unsigned swz;
 146       unsigned rgba_valid:1;
 147       unsigned xyzw_valid:1;
 148       unsigned negate:1;
 149    } ext_swizzle;
 150 }
 151
 152 %token ARBvp_10 ARBfp_10
 153
 154 /* Tokens for assembler pseudo-ops */
 155 %token <integer> ADDRESS
 156 %token ALIAS ATTRIB
 157 %token OPTION OUTPUT
 158 %token PARAM
 159 %token <integer> TEMP
 160 %token END
 161
 162  /* Tokens for instructions */
 163 %token <temp_inst> BIN_OP BINSC_OP SAMPLE_OP SCALAR_OP TRI_OP VECTOR_OP
 164 %token <temp_inst> ARL KIL SWZ TXD_OP
 165
 166 %token <integer> INTEGER
 167 %token <real> REAL
 168
 169 %token AMBIENT ATTENUATION
 170 %token BACK
 171 %token CLIP COLOR
 172 %token DEPTH DIFFUSE DIRECTION
 173 %token EMISSION ENV EYE
 174 %token FOG FOGCOORD FRAGMENT FRONT
 175 %token HALF
 176 %token INVERSE INVTRANS
 177 %token LIGHT LIGHTMODEL LIGHTPROD LOCAL
 178 %token MATERIAL MAT_PROGRAM MATRIX MATRIXINDEX MODELVIEW MVP
 179 %token NORMAL
 180 %token OBJECT
 181 %token PALETTE PARAMS PLANE POINT_TOK POINTSIZE POSITION PRIMARY PROGRAM PROJECTION
 182 %token RANGE RESULT ROW
 183 %token SCENECOLOR SECONDARY SHININESS SIZE_TOK SPECULAR SPOT STATE
 184 %token TEXCOORD TEXENV TEXGEN TEXGEN_Q TEXGEN_R TEXGEN_S TEXGEN_T TEXTURE TRANSPOSE
 185 %token TEXTURE_UNIT TEX_1D TEX_2D TEX_3D TEX_CUBE TEX_RECT
 186 %token TEX_SHADOW1D TEX_SHADOW2D TEX_SHADOWRECT
 187 %token TEX_ARRAY1D TEX_ARRAY2D TEX_ARRAYSHADOW1D TEX_ARRAYSHADOW2D
 188 %token VERTEX VTXATTRIB
 189 %token WEIGHT
 190
 191 %token <string> IDENTIFIER USED_IDENTIFIER
 192 %type <string> string
 193 %token <swiz_mask> MASK4 MASK3 MASK2 MASK1 SWIZZLE
 194 %token DOT_DOT
 195 %token DOT
 196
 197 %type <inst> instruction ALU_instruction TexInstruction
 198 %type <inst> ARL_instruction VECTORop_instruction
 199 %type <inst> SCALARop_instruction BINSCop_instruction BINop_instruction
 200 %type <inst> TRIop_instruction TXD_instruction SWZ_instruction SAMPLE_instruction
 201 %type <inst> KIL_instruction
 202
 203 %type <dst_reg> dstReg maskedDstReg maskedAddrReg
 204 %type <src_reg> srcReg scalarUse scalarSrcReg swizzleSrcReg
 205 %type <swiz_mask> scalarSuffix swizzleSuffix extendedSwizzle
 206 %type <ext_swizzle> extSwizComp extSwizSel
 207 %type <swiz_mask> optionalMask
 208
 209 %type <sym> progParamArray
 210 %type <integer> addrRegRelOffset addrRegPosOffset addrRegNegOffset
 211 %type <src_reg> progParamArrayMem progParamArrayAbs progParamArrayRel
 212 %type <sym> addrReg
 213 %type <swiz_mask> addrComponent addrWriteMask
 214
 215 %type <dst_reg> ccMaskRule ccTest ccMaskRule2 ccTest2 optionalCcMask
 216
 217 %type <result> resultBinding resultColBinding
 218 %type <integer> optFaceType optColorType
 219 %type <integer> optResultFaceType optResultColorType
 220
 221 %type <integer> optTexImageUnitNum texImageUnitNum
 222 %type <integer> optTexCoordUnitNum texCoordUnitNum
 223 %type <integer> optLegacyTexUnitNum legacyTexUnitNum
 224 %type <integer> texImageUnit texTarget
 225 %type <integer> vtxAttribNum
 226
 227 %type <attrib> attribBinding vtxAttribItem fragAttribItem
 228
 229 %type <temp_sym> paramSingleInit paramSingleItemDecl
 230 %type <integer> optArraySize
 231
 232 %type <state> stateSingleItem stateMultipleItem
 233 %type <state> stateMaterialItem
 234 %type <state> stateLightItem stateLightModelItem stateLightProdItem
 235 %type <state> stateTexGenItem stateFogItem stateClipPlaneItem statePointItem
 236 %type <state> stateMatrixItem stateMatrixRow stateMatrixRows
 237 %type <state> stateTexEnvItem stateDepthItem
 238
 239 %type <state> stateLModProperty
 240 %type <state> stateMatrixName optMatrixRows
 241
 242 %type <integer> stateMatProperty
 243 %type <integer> stateLightProperty stateSpotProperty
 244 %type <integer> stateLightNumber stateLProdProperty
 245 %type <integer> stateTexGenType stateTexGenCoord
 246 %type <integer> stateTexEnvProperty
 247 %type <integer> stateFogProperty
 248 %type <integer> stateClipPlaneNum
 249 %type <integer> statePointProperty
 250
 251 %type <integer> stateOptMatModifier stateMatModifier stateMatrixRowNum
 252 %type <integer> stateOptModMatNum stateModMatNum statePaletteMatNum
 253 %type <integer> stateProgramMatNum
 254
 255 %type <integer> ambDiffSpecProperty
 256
 257 %type <state> programSingleItem progEnvParam progLocalParam
 258 %type <state> programMultipleItem progEnvParams progLocalParams
 259
 260 %type <temp_sym> paramMultipleInit paramMultInitList paramMultipleItem
 261 %type <temp_sym> paramSingleItemUse
 262
 263 %type <integer> progEnvParamNum progLocalParamNum
 264 %type <state> progEnvParamNums progLocalParamNums
 265
 266 %type <vector> paramConstDecl paramConstUse
 267 %type <vector> paramConstScalarDecl paramConstScalarUse paramConstVector
 268 %type <real> signedFloatConstant
 269 %type <negate> optionalSign
 270
 271 %{
 272 extern int yylex(YYSTYPE *yylval_param, YYLTYPE *yylloc_param,
 273     void *yyscanner);
 274 %}
 275
 276 %%
 277
 278 program: language optionSequence statementSequence END
 279         ;
 280
 281 language: ARBvp_10
 282         {
 283            if (state->prog->Target != GL_VERTEX_PROGRAM_ARB) {
 284               yyerror(& @1, state, "invalid fragment program header");
 285
 286            }
 287            state->mode = ARB_vertex;
 288         }
 289         | ARBfp_10
 290         {
 291            if (state->prog->Target != GL_FRAGMENT_PROGRAM_ARB) {
 292               yyerror(& @1, state, "invalid vertex program header");
 293            }
 294            state->mode = ARB_fragment;
 295
 296            state->option.TexRect =
 297               (state->ctx->Extensions.NV_texture_rectangle != GL_FALSE);
 298         }
 299         ;
 300
 301 optionSequence: optionSequence option
 302         |
 303         ;
 304
 305 option: OPTION string ';'
 306         {
 307            int valid = 0;
 308
 309            if (state->mode == ARB_vertex) {
 310               valid = _mesa_ARBvp_parse_option(state, $2);
 311            } else if (state->mode == ARB_fragment) {
 312               valid = _mesa_ARBfp_parse_option(state, $2);
 313            }
 314
 315
 316            free($2);
 317
 318            if (!valid) {
 319               const char *const err_str = (state->mode == ARB_vertex)
 320                  ? "invalid ARB vertex program option"
 321                  : "invalid ARB fragment program option";
 322
 323               yyerror(& @2, state, err_str);
 324               YYERROR;
 325            }
 326         }
 327         ;
 328
 329 statementSequence: statementSequence statement
 330         |
 331         ;
 332
 333 statement: instruction ';'
 334         {
 335            if ($1 != NULL) {
 336               if (state->inst_tail == NULL) {
 337                  state->inst_head = $1;
 338               } else {
 339                  state->inst_tail->next = $1;
 340               }
 341
 342               state->inst_tail = $1;
 343               $1->next = NULL;
 344
 345               state->prog->NumInstructions++;
 346            }
 347         }
 348         | namingStatement ';'
 349         ;
 350
 351 instruction: ALU_instruction
 352         {
 353            $$ = $1;
 354            state->prog->NumAluInstructions++;
 355         }
 356         | TexInstruction
 357         {
 358            $$ = $1;
 359            state->prog->NumTexInstructions++;
 360         }
 361         ;
 362
 363 ALU_instruction: ARL_instruction
 364         | VECTORop_instruction
 365         | SCALARop_instruction
 366         | BINSCop_instruction
 367         | BINop_instruction
 368         | TRIop_instruction
 369         | SWZ_instruction
 370         ;
 371
 372 TexInstruction: SAMPLE_instruction
 373         | KIL_instruction
 374         | TXD_instruction
 375         ;
 376
 377 ARL_instruction: ARL maskedAddrReg ',' scalarSrcReg
 378         {
 379            $$ = asm_instruction_ctor(OPCODE_ARL, & $2, & $4, NULL, NULL);
 380         }
 381         ;
 382
 383 VECTORop_instruction: VECTOR_OP maskedDstReg ',' swizzleSrcReg
 384         {
 385            if ($1.Opcode == OPCODE_DDY)
 386               state->fragment.UsesDFdy = 1;
 387            $$ = asm_instruction_copy_ctor(& $1, & $2, & $4, NULL, NULL);
 388         }
 389         ;
 390
 391 SCALARop_instruction: SCALAR_OP maskedDstReg ',' scalarSrcReg
 392         {
 393            $$ = asm_instruction_copy_ctor(& $1, & $2, & $4, NULL, NULL);
 394         }
 395         ;
 396
 397 BINSCop_instruction: BINSC_OP maskedDstReg ',' scalarSrcReg ',' scalarSrcReg
 398         {
 399            $$ = asm_instruction_copy_ctor(& $1, & $2, & $4, & $6, NULL);
 400         }
 401         ;
 402
 403
 404 BINop_instruction: BIN_OP maskedDstReg ',' swizzleSrcReg ',' swizzleSrcReg
 405         {
 406            $$ = asm_instruction_copy_ctor(& $1, & $2, & $4, & $6, NULL);
 407         }
 408         ;
 409
 410 TRIop_instruction: TRI_OP maskedDstReg ','
 411                    swizzleSrcReg ',' swizzleSrcReg ',' swizzleSrcReg
 412         {
 413            $$ = asm_instruction_copy_ctor(& $1, & $2, & $4, & $6, & $8);
 414         }
 415         ;
 416
 417 SAMPLE_instruction: SAMPLE_OP maskedDstReg ',' swizzleSrcReg ',' texImageUnit ',' texTarget
 418         {
 419            $$ = asm_instruction_copy_ctor(& $1, & $2, & $4, NULL, NULL);
 420            if ($$ != NULL) {
 421               const GLbitfield tex_mask = (1U << $6);
 422               GLbitfield shadow_tex = 0;
 423               GLbitfield target_mask = 0;
 424
 425
 426               $$->Base.TexSrcUnit = $6;
 427
 428               if ($8 < 0) {
 429                  shadow_tex = tex_mask;
 430
 431                  $$->Base.TexSrcTarget = -$8;
 432                  $$->Base.TexShadow = 1;
 433               } else {
 434                  $$->Base.TexSrcTarget = $8;
 435               }
 436
 437               target_mask = (1U << $$->Base.TexSrcTarget);
 438
 439               /* If this texture unit was previously accessed and that access
 440                * had a different texture target, generate an error.
 441                *
 442                * If this texture unit was previously accessed and that access
 443                * had a different shadow mode, generate an error.
 444                */
 445               if ((state->prog->TexturesUsed[$6] != 0)
 446                   && ((state->prog->TexturesUsed[$6] != target_mask)
 447                       || ((state->prog->ShadowSamplers & tex_mask)
 448                           != shadow_tex))) {
 449                  yyerror(& @8, state,
 450                          "multiple targets used on one texture image unit");
 451                  YYERROR;
 452               }
 453
 454
 455               state->prog->TexturesUsed[$6] |= target_mask;
 456               state->prog->ShadowSamplers |= shadow_tex;
 457            }
 458         }
 459         ;
 460
 461 KIL_instruction: KIL swizzleSrcReg
 462         {
 463            $$ = asm_instruction_ctor(OPCODE_KIL, NULL, & $2, NULL, NULL);
 464            state->fragment.UsesKill = 1;
 465         }
 466         | KIL ccTest
 467         {
 468            $$ = asm_instruction_ctor(OPCODE_KIL_NV, NULL, NULL, NULL, NULL);
 469            $$->Base.DstReg.CondMask = $2.CondMask;
 470            $$->Base.DstReg.CondSwizzle = $2.CondSwizzle;
 471            state->fragment.UsesKill = 1;
 472         }
 473         ;
 474
 475 TXD_instruction: TXD_OP maskedDstReg ',' swizzleSrcReg ',' swizzleSrcReg ',' swizzleSrcReg ',' texImageUnit ',' texTarget
 476         {
 477            $$ = asm_instruction_copy_ctor(& $1, & $2, & $4, & $6, & $8);
 478            if ($$ != NULL) {
 479               const GLbitfield tex_mask = (1U << $10);
 480               GLbitfield shadow_tex = 0;
 481               GLbitfield target_mask = 0;
 482
 483
 484               $$->Base.TexSrcUnit = $10;
 485
 486               if ($12 < 0) {
 487                  shadow_tex = tex_mask;
 488
 489                  $$->Base.TexSrcTarget = -$12;
 490                  $$->Base.TexShadow = 1;
 491               } else {
 492                  $$->Base.TexSrcTarget = $12;
 493               }
 494
 495               target_mask = (1U << $$->Base.TexSrcTarget);
 496
 497               /* If this texture unit was previously accessed and that access
 498                * had a different texture target, generate an error.
 499                *
 500                * If this texture unit was previously accessed and that access
 501                * had a different shadow mode, generate an error.
 502                */
 503               if ((state->prog->TexturesUsed[$10] != 0)
 504                   && ((state->prog->TexturesUsed[$10] != target_mask)
 505                       || ((state->prog->ShadowSamplers & tex_mask)
 506                           != shadow_tex))) {
 507                  yyerror(& @12, state,
 508                          "multiple targets used on one texture image unit");
 509                  YYERROR;
 510               }
 511
 512
 513               state->prog->TexturesUsed[$10] |= target_mask;
 514               state->prog->ShadowSamplers |= shadow_tex;
 515            }
 516         }
 517         ;
 518
 519 texImageUnit: TEXTURE_UNIT optTexImageUnitNum
 520         {
 521            $$ = $2;
 522         }
 523         ;
 524
 525 texTarget: TEX_1D  { $$ = TEXTURE_1D_INDEX; }
 526         | TEX_2D   { $$ = TEXTURE_2D_INDEX; }
 527         | TEX_3D   { $$ = TEXTURE_3D_INDEX; }
 528         | TEX_CUBE { $$ = TEXTURE_CUBE_INDEX; }
 529         | TEX_RECT { $$ = TEXTURE_RECT_INDEX; }
 530         | TEX_SHADOW1D   { $$ = -TEXTURE_1D_INDEX; }
 531         | TEX_SHADOW2D   { $$ = -TEXTURE_2D_INDEX; }
 532         | TEX_SHADOWRECT { $$ = -TEXTURE_RECT_INDEX; }
 533         | TEX_ARRAY1D         { $$ = TEXTURE_1D_ARRAY_INDEX; }
 534         | TEX_ARRAY2D         { $$ = TEXTURE_2D_ARRAY_INDEX; }
 535         | TEX_ARRAYSHADOW1D   { $$ = -TEXTURE_1D_ARRAY_INDEX; }
 536         | TEX_ARRAYSHADOW2D   { $$ = -TEXTURE_2D_ARRAY_INDEX; }
 537         ;
 538
 539 SWZ_instruction: SWZ maskedDstReg ',' srcReg ',' extendedSwizzle
 540         {
 541            /* FIXME: Is this correct?  Should the extenedSwizzle be applied
 542             * FIXME: to the existing swizzle?
 543             */
 544            $4.Base.Swizzle = $6.swizzle;
 545            $4.Base.Negate = $6.mask;
 546
 547            $$ = asm_instruction_copy_ctor(& $1, & $2, & $4, NULL, NULL);
 548         }
 549         ;
 550
 551 scalarSrcReg: optionalSign scalarUse
 552         {
 553            $$ = $2;
 554
 555            if ($1) {
 556               $$.Base.Negate = ~$$.Base.Negate;
 557            }
 558         }
 559         | optionalSign '|' scalarUse '|'
 560         {
 561            $$ = $3;
 562
 563            if (!state->option.NV_fragment) {
 564               yyerror(& @2, state, "unexpected character '|'");
 565               YYERROR;
 566            }
 567
 568            if ($1) {
 569               $$.Base.Negate = ~$$.Base.Negate;
 570            }
 571
 572            $$.Base.Abs = 1;
 573         }
 574         ;
 575
 576 scalarUse:  srcReg scalarSuffix
 577         {
 578            $$ = $1;
 579
 580            $$.Base.Swizzle = _mesa_combine_swizzles($$.Base.Swizzle,
 581                                                     $2.swizzle);
 582         }
 583         | paramConstScalarUse
 584         {
 585            struct asm_symbol temp_sym;
 586
 587            if (!state->option.NV_fragment) {
 588               yyerror(& @1, state, "expected scalar suffix");
 589               YYERROR;
 590            }
 591
 592            memset(& temp_sym, 0, sizeof(temp_sym));
 593            temp_sym.param_binding_begin = ~0;
 594            initialize_symbol_from_const(state->prog, & temp_sym, & $1, GL_TRUE);
 595
 596            set_src_reg_swz(& $$, PROGRAM_CONSTANT,
 597                            temp_sym.param_binding_begin,
 598                            temp_sym.param_binding_swizzle);
 599         }
 600         ;
 601
 602 swizzleSrcReg: optionalSign srcReg swizzleSuffix
 603         {
 604            $$ = $2;
 605
 606            if ($1) {
 607               $$.Base.Negate = ~$$.Base.Negate;
 608            }
 609
 610            $$.Base.Swizzle = _mesa_combine_swizzles($$.Base.Swizzle,
 611                                                     $3.swizzle);
 612         }
 613         | optionalSign '|' srcReg swizzleSuffix '|'
 614         {
 615            $$ = $3;
 616
 617            if (!state->option.NV_fragment) {
 618               yyerror(& @2, state, "unexpected character '|'");
 619               YYERROR;
 620            }
 621
 622            if ($1) {
 623               $$.Base.Negate = ~$$.Base.Negate;
 624            }
 625
 626            $$.Base.Abs = 1;
 627            $$.Base.Swizzle = _mesa_combine_swizzles($$.Base.Swizzle,
 628                                                     $4.swizzle);
 629         }
 630
 631         ;
 632
 633 maskedDstReg: dstReg optionalMask optionalCcMask
 634         {
 635            $$ = $1;
 636            $$.WriteMask = $2.mask;
 637            $$.CondMask = $3.CondMask;
 638            $$.CondSwizzle = $3.CondSwizzle;
 639
 640            if ($$.File == PROGRAM_OUTPUT) {
 641               /* Technically speaking, this should check that it is in
 642                * vertex program mode.  However, PositionInvariant can never be
 643                * set in fragment program mode, so it is somewhat irrelevant.
 644                */
 645               if (state->option.PositionInvariant
 646                && ($$.Index == VARYING_SLOT_POS)) {
 647                  yyerror(& @1, state, "position-invariant programs cannot "
 648                          "write position");
 649                  YYERROR;
 650               }
 651
 652               state->prog->OutputsWritten |= BITFIELD64_BIT($$.Index);
 653            }
 654         }
 655         ;
 656
 657 maskedAddrReg: addrReg addrWriteMask
 658         {
 659            set_dst_reg(& $$, PROGRAM_ADDRESS, 0);
 660            $$.WriteMask = $2.mask;
 661         }
 662         ;
 663
 664 extendedSwizzle: extSwizComp ',' extSwizComp ',' extSwizComp ',' extSwizComp
 665         {
 666            const unsigned xyzw_valid =
 667               ($1.xyzw_valid << 0)
 668               | ($3.xyzw_valid << 1)
 669               | ($5.xyzw_valid << 2)
 670               | ($7.xyzw_valid << 3);
 671            const unsigned rgba_valid =
 672               ($1.rgba_valid << 0)
 673               | ($3.rgba_valid << 1)
 674               | ($5.rgba_valid << 2)
 675               | ($7.rgba_valid << 3);
 676
 677            /* All of the swizzle components have to be valid in either RGBA
 678             * or XYZW.  Note that 0 and 1 are valid in both, so both masks
 679             * can have some bits set.
 680             *
 681             * We somewhat deviate from the spec here.  It would be really hard
 682             * to figure out which component is the error, and there probably
 683             * isn't a lot of benefit.
 684             */
 685            if ((rgba_valid != 0x0f) && (xyzw_valid != 0x0f)) {
 686               yyerror(& @1, state, "cannot combine RGBA and XYZW swizzle "
 687                       "components");
 688               YYERROR;
 689            }
 690
 691            $$.swizzle = MAKE_SWIZZLE4($1.swz, $3.swz, $5.swz, $7.swz);
 692            $$.mask = ($1.negate) | ($3.negate << 1) | ($5.negate << 2)
 693               | ($7.negate << 3);
 694         }
 695         ;
 696
 697 extSwizComp: optionalSign extSwizSel
 698         {
 699            $$ = $2;
 700            $$.negate = ($1) ? 1 : 0;
 701         }
 702         ;
 703
 704 extSwizSel: INTEGER
 705         {
 706            if (($1 != 0) && ($1 != 1)) {
 707               yyerror(& @1, state, "invalid extended swizzle selector");
 708               YYERROR;
 709            }
 710
 711            $$.swz = ($1 == 0) ? SWIZZLE_ZERO : SWIZZLE_ONE;
 712
 713            /* 0 and 1 are valid for both RGBA swizzle names and XYZW
 714             * swizzle names.
 715             */
 716            $$.xyzw_valid = 1;
 717            $$.rgba_valid = 1;
 718         }
 719         | string
 720         {
 721            char s;
 722
 723            if (strlen($1) > 1) {
 724               yyerror(& @1, state, "invalid extended swizzle selector");
 725               YYERROR;
 726            }
 727
 728            s = $1[0];
 729            free($1);
 730
 731            switch (s) {
 732            case 'x':
 733               $$.swz = SWIZZLE_X;
 734               $$.xyzw_valid = 1;
 735               break;
 736            case 'y':
 737               $$.swz = SWIZZLE_Y;
 738               $$.xyzw_valid = 1;
 739               break;
 740            case 'z':
 741               $$.swz = SWIZZLE_Z;
 742               $$.xyzw_valid = 1;
 743               break;
 744            case 'w':
 745               $$.swz = SWIZZLE_W;
 746               $$.xyzw_valid = 1;
 747               break;
 748
 749            case 'r':
 750               $$.swz = SWIZZLE_X;
 751               $$.rgba_valid = 1;
 752               break;
 753            case 'g':
 754               $$.swz = SWIZZLE_Y;
 755               $$.rgba_valid = 1;
 756               break;
 757            case 'b':
 758               $$.swz = SWIZZLE_Z;
 759               $$.rgba_valid = 1;
 760               break;
 761            case 'a':
 762               $$.swz = SWIZZLE_W;
 763               $$.rgba_valid = 1;
 764               break;
 765
 766            default:
 767               yyerror(& @1, state, "invalid extended swizzle selector");
 768               YYERROR;
 769               break;
 770            }
 771         }
 772         ;
 773
 774 srcReg: USED_IDENTIFIER /* temporaryReg | progParamSingle */
 775         {
 776            struct asm_symbol *const s = (struct asm_symbol *)
 777               _mesa_symbol_table_find_symbol(state->st, 0, $1);
 778
 779            free($1);
 780
 781            if (s == NULL) {
 782               yyerror(& @1, state, "invalid operand variable");
 783               YYERROR;
 784            } else if ((s->type != at_param) && (s->type != at_temp)
 785                       && (s->type != at_attrib)) {
 786               yyerror(& @1, state, "invalid operand variable");
 787               YYERROR;
 788            } else if ((s->type == at_param) && s->param_is_array) {
 789               yyerror(& @1, state, "non-array access to array PARAM");
 790               YYERROR;
 791            }
 792
 793            init_src_reg(& $$);
 794            switch (s->type) {
 795            case at_temp:
 796               set_src_reg(& $$, PROGRAM_TEMPORARY, s->temp_binding);
 797               break;
 798            case at_param:
 799               set_src_reg_swz(& $$, s->param_binding_type,
 800                               s->param_binding_begin,
 801                               s->param_binding_swizzle);
 802               break;
 803            case at_attrib:
 804               set_src_reg(& $$, PROGRAM_INPUT, s->attrib_binding);
 805               state->prog->InputsRead |= BITFIELD64_BIT($$.Base.Index);
 806
 807               if (!validate_inputs(& @1, state)) {
 808                  YYERROR;
 809               }
 810               break;
 811
 812            default:
 813               YYERROR;
 814               break;
 815            }
 816         }
 817         | attribBinding
 818         {
 819            set_src_reg(& $$, PROGRAM_INPUT, $1);
 820            state->prog->InputsRead |= BITFIELD64_BIT($$.Base.Index);
 821
 822            if (!validate_inputs(& @1, state)) {
 823               YYERROR;
 824            }
 825         }
 826         | progParamArray '[' progParamArrayMem ']'
 827         {
 828            if (! $3.Base.RelAddr
 829                && ((unsigned) $3.Base.Index >= $1->param_binding_length)) {
 830               yyerror(& @3, state, "out of bounds array access");
 831               YYERROR;
 832            }
 833
 834            init_src_reg(& $$);
 835            $$.Base.File = $1->param_binding_type;
 836
 837            if ($3.Base.RelAddr) {
 838               state->prog->IndirectRegisterFiles |= (1 << $$.Base.File);
 839               $1->param_accessed_indirectly = 1;
 840
 841               $$.Base.RelAddr = 1;
 842               $$.Base.Index = $3.Base.Index;
 843               $$.Symbol = $1;
 844            } else {
 845               $$.Base.Index = $1->param_binding_begin + $3.Base.Index;
 846            }
 847         }
 848         | paramSingleItemUse
 849         {
 850            gl_register_file file = ($1.name != NULL)
 851               ? $1.param_binding_type
 852               : PROGRAM_CONSTANT;
 853            set_src_reg_swz(& $$, file, $1.param_binding_begin,
 854                            $1.param_binding_swizzle);
 855         }
 856         ;
 857
 858 dstReg: resultBinding
 859         {
 860            set_dst_reg(& $$, PROGRAM_OUTPUT, $1);
 861         }
 862         | USED_IDENTIFIER /* temporaryReg | vertexResultReg */
 863         {
 864            struct asm_symbol *const s = (struct asm_symbol *)
 865               _mesa_symbol_table_find_symbol(state->st, 0, $1);
 866
 867            free($1);
 868
 869            if (s == NULL) {
 870               yyerror(& @1, state, "invalid operand variable");
 871               YYERROR;
 872            } else if ((s->type != at_output) && (s->type != at_temp)) {
 873               yyerror(& @1, state, "invalid operand variable");
 874               YYERROR;
 875            }
 876
 877            switch (s->type) {
 878            case at_temp:
 879               set_dst_reg(& $$, PROGRAM_TEMPORARY, s->temp_binding);
 880               break;
 881            case at_output:
 882               set_dst_reg(& $$, PROGRAM_OUTPUT, s->output_binding);
 883               break;
 884            default:
 885               set_dst_reg(& $$, s->param_binding_type, s->param_binding_begin);
 886               break;
 887            }
 888         }
 889         ;
 890
 891 progParamArray: USED_IDENTIFIER
 892         {
 893            struct asm_symbol *const s = (struct asm_symbol *)
 894               _mesa_symbol_table_find_symbol(state->st, 0, $1);
 895
 896            free($1);
 897
 898            if (s == NULL) {
 899               yyerror(& @1, state, "invalid operand variable");
 900               YYERROR;
 901            } else if ((s->type != at_param) || !s->param_is_array) {
 902               yyerror(& @1, state, "array access to non-PARAM variable");
 903               YYERROR;
 904            } else {
 905               $$ = s;
 906            }
 907         }
 908         ;
 909
 910 progParamArrayMem: progParamArrayAbs | progParamArrayRel;
 911
 912 progParamArrayAbs: INTEGER
 913         {
 914            init_src_reg(& $$);
 915            $$.Base.Index = $1;
 916         }
 917         ;
 918
 919 progParamArrayRel: addrReg addrComponent addrRegRelOffset
 920         {
 921            /* FINISHME: Add support for multiple address registers.
 922             */
 923            /* FINISHME: Add support for 4-component address registers.
 924             */
 925            init_src_reg(& $$);
 926            $$.Base.RelAddr = 1;
 927            $$.Base.Index = $3;
 928         }
 929         ;
 930
 931 addrRegRelOffset:              { $$ = 0; }
 932         | '+' addrRegPosOffset { $$ = $2; }
 933         | '-' addrRegNegOffset { $$ = -$2; }
 934         ;
 935
 936 addrRegPosOffset: INTEGER
 937         {
 938            if (($1 < 0) || ($1 > (state->limits->MaxAddressOffset - 1))) {
 939               char s[100];
 940               _mesa_snprintf(s, sizeof(s),
 941                              "relative address offset too large (%d)", $1);
 942               yyerror(& @1, state, s);
 943               YYERROR;
 944            } else {
 945               $$ = $1;
 946            }
 947         }
 948         ;
 949
 950 addrRegNegOffset: INTEGER
 951         {
 952            if (($1 < 0) || ($1 > state->limits->MaxAddressOffset)) {
 953               char s[100];
 954               _mesa_snprintf(s, sizeof(s),
 955                              "relative address offset too large (%d)", $1);
 956               yyerror(& @1, state, s);
 957               YYERROR;
 958            } else {
 959               $$ = $1;
 960            }
 961         }
 962         ;
 963
 964 addrReg: USED_IDENTIFIER
 965         {
 966            struct asm_symbol *const s = (struct asm_symbol *)
 967               _mesa_symbol_table_find_symbol(state->st, 0, $1);
 968
 969            free($1);
 970
 971            if (s == NULL) {
 972               yyerror(& @1, state, "invalid array member");
 973               YYERROR;
 974            } else if (s->type != at_address) {
 975               yyerror(& @1, state,
 976                       "invalid variable for indexed array access");
 977               YYERROR;
 978            } else {
 979               $$ = s;
 980            }
 981         }
 982         ;
 983
 984 addrComponent: MASK1
 985         {
 986            if ($1.mask != WRITEMASK_X) {
 987               yyerror(& @1, state, "invalid address component selector");
 988               YYERROR;
 989            } else {
 990               $$ = $1;
 991            }
 992         }
 993         ;
 994
 995 addrWriteMask: MASK1
 996         {
 997            if ($1.mask != WRITEMASK_X) {
 998               yyerror(& @1, state,
 999                       "address register write mask must be \".x\"");
1000               YYERROR;
1001            } else {
1002               $$ = $1;
1003            }
1004         }
1005         ;
1006
1007 scalarSuffix: MASK1;
1008
1009 swizzleSuffix: MASK1
1010         | MASK4
1011         | SWIZZLE
1012         |              { $$.swizzle = SWIZZLE_NOOP; $$.mask = WRITEMASK_XYZW; }
1013         ;
1014
1015 optionalMask: MASK4 | MASK3 | MASK2 | MASK1
1016         |              { $$.swizzle = SWIZZLE_NOOP; $$.mask = WRITEMASK_XYZW; }
1017         ;
1018
1019 optionalCcMask: '(' ccTest ')'
1020         {
1021            $$ = $2;
1022         }
1023         | '(' ccTest2 ')'
1024         {
1025            $$ = $2;
1026         }
1027         |
1028         {
1029            $$.CondMask = COND_TR;
1030            $$.CondSwizzle = SWIZZLE_NOOP;
1031         }
1032         ;
1033
1034 ccTest: ccMaskRule swizzleSuffix
1035         {
1036            $$ = $1;
1037            $$.CondSwizzle = $2.swizzle;
1038         }
1039         ;
1040
1041 ccTest2: ccMaskRule2 swizzleSuffix
1042         {
1043            $$ = $1;
1044            $$.CondSwizzle = $2.swizzle;
1045         }
1046         ;
1047
1048 ccMaskRule: IDENTIFIER
1049         {
1050            const int cond = _mesa_parse_cc($1);
1051            if ((cond == 0) || ($1[2] != '\0')) {
1052               char *const err_str =
1053                  make_error_string("invalid condition code \"%s\"", $1);
1054
1055               yyerror(& @1, state, (err_str != NULL)
1056                       ? err_str : "invalid condition code");
1057
1058               if (err_str != NULL) {
1059                  free(err_str);
1060               }
1061
1062               YYERROR;
1063            }
1064
1065            $$.CondMask = cond;
1066            $$.CondSwizzle = SWIZZLE_NOOP;
1067         }
1068         ;
1069
1070 ccMaskRule2: USED_IDENTIFIER
1071         {
1072            const int cond = _mesa_parse_cc($1);
1073            if ((cond == 0) || ($1[2] != '\0')) {
1074               char *const err_str =
1075                  make_error_string("invalid condition code \"%s\"", $1);
1076
1077               yyerror(& @1, state, (err_str != NULL)
1078                       ? err_str : "invalid condition code");
1079
1080               if (err_str != NULL) {
1081                  free(err_str);
1082               }
1083
1084               YYERROR;
1085            }
1086
1087            $$.CondMask = cond;
1088            $$.CondSwizzle = SWIZZLE_NOOP;
1089         }
1090         ;
1091
1092 namingStatement: ATTRIB_statement
1093         | PARAM_statement
1094         | TEMP_statement
1095         | ADDRESS_statement
1096         | OUTPUT_statement
1097         | ALIAS_statement
1098         ;
1099
1100 ATTRIB_statement: ATTRIB IDENTIFIER '=' attribBinding
1101         {
1102            struct asm_symbol *const s =
1103               declare_variable(state, $2, at_attrib, & @2);
1104
1105            if (s == NULL) {
1106               free($2);
1107               YYERROR;
1108            } else {
1109               s->attrib_binding = $4;
1110               state->InputsBound |= BITFIELD64_BIT(s->attrib_binding);
1111
1112               if (!validate_inputs(& @4, state)) {
1113                  YYERROR;
1114               }
1115            }
1116         }
1117         ;
1118
1119 attribBinding: VERTEX vtxAttribItem
1120         {
1121            $$ = $2;
1122         }
1123         | FRAGMENT fragAttribItem
1124         {
1125            $$ = $2;
1126         }
1127         ;
1128
1129 vtxAttribItem: POSITION
1130         {
1131            $$ = VERT_ATTRIB_POS;
1132         }
1133         | WEIGHT vtxOptWeightNum
1134         {
1135            $$ = VERT_ATTRIB_WEIGHT;
1136         }
1137         | NORMAL
1138         {
1139            $$ = VERT_ATTRIB_NORMAL;
1140         }
1141         | COLOR optColorType
1142         {
1143            if (!state->ctx->Extensions.EXT_secondary_color) {
1144               yyerror(& @2, state, "GL_EXT_secondary_color not supported");
1145               YYERROR;
1146            }
1147
1148            $$ = VERT_ATTRIB_COLOR0 + $2;
1149         }
1150         | FOGCOORD
1151         {
1152            if (!state->ctx->Extensions.EXT_fog_coord) {
1153               yyerror(& @1, state, "GL_EXT_fog_coord not supported");
1154               YYERROR;
1155            }
1156
1157            $$ = VERT_ATTRIB_FOG;
1158         }
1159         | TEXCOORD optTexCoordUnitNum
1160         {
1161            $$ = VERT_ATTRIB_TEX0 + $2;
1162         }
1163         | MATRIXINDEX '[' vtxWeightNum ']'
1164         {
1165            yyerror(& @1, state, "GL_ARB_matrix_palette not supported");
1166            YYERROR;
1167         }
1168         | VTXATTRIB '[' vtxAttribNum ']'
1169         {
1170            $$ = VERT_ATTRIB_GENERIC0 + $3;
1171         }
1172         ;
1173
1174 vtxAttribNum: INTEGER
1175         {
1176            if ((unsigned) $1 >= state->limits->MaxAttribs) {
1177               yyerror(& @1, state, "invalid vertex attribute reference");
1178               YYERROR;
1179            }
1180
1181            $$ = $1;
1182         }
1183         ;
1184
1185 vtxOptWeightNum:  | '[' vtxWeightNum ']';
1186 vtxWeightNum: INTEGER;
1187
1188 fragAttribItem: POSITION
1189         {
1190            $$ = FRAG_ATTRIB_WPOS;
1191         }
1192         | COLOR optColorType
1193         {
1194            $$ = FRAG_ATTRIB_COL0 + $2;
1195         }
1196         | FOGCOORD
1197         {
1198            $$ = FRAG_ATTRIB_FOGC;
1199         }
1200         | TEXCOORD optTexCoordUnitNum
1201         {
1202            $$ = FRAG_ATTRIB_TEX0 + $2;
1203         }
1204         ;
1205
1206 PARAM_statement: PARAM_singleStmt | PARAM_multipleStmt;
1207
1208 PARAM_singleStmt: PARAM IDENTIFIER paramSingleInit
1209         {
1210            struct asm_symbol *const s =
1211               declare_variable(state, $2, at_param, & @2);
1212
1213            if (s == NULL) {
1214               free($2);
1215               YYERROR;
1216            } else {
1217               s->param_binding_type = $3.param_binding_type;
1218               s->param_binding_begin = $3.param_binding_begin;
1219               s->param_binding_length = $3.param_binding_length;
1220               s->param_binding_swizzle = $3.param_binding_swizzle;
1221               s->param_is_array = 0;
1222            }
1223         }
1224         ;
1225
1226 PARAM_multipleStmt: PARAM IDENTIFIER '[' optArraySize ']' paramMultipleInit
1227         {
1228            if (($4 != 0) && ((unsigned) $4 != $6.param_binding_length)) {
1229               free($2);
1230               yyerror(& @4, state,
1231                       "parameter array size and number of bindings must match");
1232               YYERROR;
1233            } else {
1234               struct asm_symbol *const s =
1235                  declare_variable(state, $2, $6.type, & @2);
1236
1237               if (s == NULL) {
1238                  free($2);
1239                  YYERROR;
1240               } else {
1241                  s->param_binding_type = $6.param_binding_type;
1242                  s->param_binding_begin = $6.param_binding_begin;
1243                  s->param_binding_length = $6.param_binding_length;
1244                  s->param_binding_swizzle = SWIZZLE_XYZW;
1245                  s->param_is_array = 1;
1246               }
1247            }
1248         }
1249         ;
1250
1251 optArraySize:
1252         {
1253            $$ = 0;
1254         }
1255         | INTEGER
1256         {
1257            if (($1 < 1) || ((unsigned) $1 > state->limits->MaxParameters)) {
1258               char msg[100];
1259               _mesa_snprintf(msg, sizeof(msg),
1260                              "invalid parameter array size (size=%d max=%u)",
1261                              $1, state->limits->MaxParameters);
1262               yyerror(& @1, state, msg);
1263               YYERROR;
1264            } else {
1265               $$ = $1;
1266            }
1267         }
1268         ;
1269
1270 paramSingleInit: '=' paramSingleItemDecl
1271         {
1272            $$ = $2;
1273         }
1274         ;
1275
1276 paramMultipleInit: '=' '{' paramMultInitList '}'
1277         {
1278            $$ = $3;
1279         }
1280         ;
1281
1282 paramMultInitList: paramMultipleItem
1283         | paramMultInitList ',' paramMultipleItem
1284         {
1285            $1.param_binding_length += $3.param_binding_length;
1286            $$ = $1;
1287         }
1288         ;
1289
1290 paramSingleItemDecl: stateSingleItem
1291         {
1292            memset(& $$, 0, sizeof($$));
1293            $$.param_binding_begin = ~0;
1294            initialize_symbol_from_state(state->prog, & $$, $1);
1295         }
1296         | programSingleItem
1297         {
1298            memset(& $$, 0, sizeof($$));
1299            $$.param_binding_begin = ~0;
1300            initialize_symbol_from_param(state->prog, & $$, $1);
1301         }
1302         | paramConstDecl
1303         {
1304            memset(& $$, 0, sizeof($$));
1305            $$.param_binding_begin = ~0;
1306            initialize_symbol_from_const(state->prog, & $$, & $1, GL_TRUE);
1307         }
1308         ;
1309
1310 paramSingleItemUse: stateSingleItem
1311         {
1312            memset(& $$, 0, sizeof($$));
1313            $$.param_binding_begin = ~0;
1314            initialize_symbol_from_state(state->prog, & $$, $1);
1315         }
1316         | programSingleItem
1317         {
1318            memset(& $$, 0, sizeof($$));
1319            $$.param_binding_begin = ~0;
1320            initialize_symbol_from_param(state->prog, & $$, $1);
1321         }
1322         | paramConstUse
1323         {
1324            memset(& $$, 0, sizeof($$));
1325            $$.param_binding_begin = ~0;
1326            initialize_symbol_from_const(state->prog, & $$, & $1, GL_TRUE);
1327         }
1328         ;
1329
1330 paramMultipleItem: stateMultipleItem
1331         {
1332            memset(& $$, 0, sizeof($$));
1333            $$.param_binding_begin = ~0;
1334            initialize_symbol_from_state(state->prog, & $$, $1);
1335         }
1336         | programMultipleItem
1337         {
1338            memset(& $$, 0, sizeof($$));
1339            $$.param_binding_begin = ~0;
1340            initialize_symbol_from_param(state->prog, & $$, $1);
1341         }
1342         | paramConstDecl
1343         {
1344            memset(& $$, 0, sizeof($$));
1345            $$.param_binding_begin = ~0;
1346            initialize_symbol_from_const(state->prog, & $$, & $1, GL_FALSE);
1347         }
1348         ;
1349
1350 stateMultipleItem: stateSingleItem        { memcpy($$, $1, sizeof($$)); }
1351         | STATE stateMatrixRows           { memcpy($$, $2, sizeof($$)); }
1352         ;
1353
1354 stateSingleItem: STATE stateMaterialItem  { memcpy($$, $2, sizeof($$)); }
1355         | STATE stateLightItem            { memcpy($$, $2, sizeof($$)); }
1356         | STATE stateLightModelItem       { memcpy($$, $2, sizeof($$)); }
1357         | STATE stateLightProdItem        { memcpy($$, $2, sizeof($$)); }
1358         | STATE stateTexGenItem           { memcpy($$, $2, sizeof($$)); }
1359         | STATE stateTexEnvItem           { memcpy($$, $2, sizeof($$)); }
1360         | STATE stateFogItem              { memcpy($$, $2, sizeof($$)); }
1361         | STATE stateClipPlaneItem        { memcpy($$, $2, sizeof($$)); }
1362         | STATE statePointItem            { memcpy($$, $2, sizeof($$)); }
1363         | STATE stateMatrixRow            { memcpy($$, $2, sizeof($$)); }
1364         | STATE stateDepthItem            { memcpy($$, $2, sizeof($$)); }
1365         ;
1366
1367 stateMaterialItem: MATERIAL optFaceType stateMatProperty
1368         {
1369            memset($$, 0, sizeof($$));
1370            $$[0] = STATE_MATERIAL;
1371            $$[1] = $2;
1372            $$[2] = $3;
1373         }
1374         ;
1375
1376 stateMatProperty: ambDiffSpecProperty
1377         {
1378            $$ = $1;
1379         }
1380         | EMISSION
1381         {
1382            $$ = STATE_EMISSION;
1383         }
1384         | SHININESS
1385         {
1386            $$ = STATE_SHININESS;
1387         }
1388         ;
1389
1390 stateLightItem: LIGHT '[' stateLightNumber ']' stateLightProperty
1391         {
1392            memset($$, 0, sizeof($$));
1393            $$[0] = STATE_LIGHT;
1394            $$[1] = $3;
1395            $$[2] = $5;
1396         }
1397         ;
1398
1399 stateLightProperty: ambDiffSpecProperty
1400         {
1401            $$ = $1;
1402         }
1403         | POSITION
1404         {
1405            $$ = STATE_POSITION;
1406         }
1407         | ATTENUATION
1408         {
1409            if (!state->ctx->Extensions.EXT_point_parameters) {
1410               yyerror(& @1, state, "GL_ARB_point_parameters not supported");
1411               YYERROR;
1412            }
1413
1414            $$ = STATE_ATTENUATION;
1415         }
1416         | SPOT stateSpotProperty
1417         {
1418            $$ = $2;
1419         }
1420         | HALF
1421         {
1422            $$ = STATE_HALF_VECTOR;
1423         }
1424         ;
1425
1426 stateSpotProperty: DIRECTION
1427         {
1428            $$ = STATE_SPOT_DIRECTION;
1429         }
1430         ;
1431
1432 stateLightModelItem: LIGHTMODEL stateLModProperty
1433         {
1434            $$[0] = $2[0];
1435            $$[1] = $2[1];
1436         }
1437         ;
1438
1439 stateLModProperty: AMBIENT
1440         {
1441            memset($$, 0, sizeof($$));
1442            $$[0] = STATE_LIGHTMODEL_AMBIENT;
1443         }
1444         | optFaceType SCENECOLOR
1445         {
1446            memset($$, 0, sizeof($$));
1447            $$[0] = STATE_LIGHTMODEL_SCENECOLOR;
1448            $$[1] = $1;
1449         }
1450         ;
1451
1452 stateLightProdItem: LIGHTPROD '[' stateLightNumber ']' optFaceType stateLProdProperty
1453         {
1454            memset($$, 0, sizeof($$));
1455            $$[0] = STATE_LIGHTPROD;
1456            $$[1] = $3;
1457            $$[2] = $5;
1458            $$[3] = $6;
1459         }
1460         ;
1461
1462 stateLProdProperty: ambDiffSpecProperty;
1463
1464 stateTexEnvItem: TEXENV optLegacyTexUnitNum stateTexEnvProperty
1465         {
1466            memset($$, 0, sizeof($$));
1467            $$[0] = $3;
1468            $$[1] = $2;
1469         }
1470         ;
1471
1472 stateTexEnvProperty: COLOR
1473         {
1474            $$ = STATE_TEXENV_COLOR;
1475         }
1476         ;
1477
1478 ambDiffSpecProperty: AMBIENT
1479         {
1480            $$ = STATE_AMBIENT;
1481         }
1482         | DIFFUSE
1483         {
1484            $$ = STATE_DIFFUSE;
1485         }
1486         | SPECULAR
1487         {
1488            $$ = STATE_SPECULAR;
1489         }
1490         ;
1491
1492 stateLightNumber: INTEGER
1493         {
1494            if ((unsigned) $1 >= state->MaxLights) {
1495               yyerror(& @1, state, "invalid light selector");
1496               YYERROR;
1497            }
1498
1499            $$ = $1;
1500         }
1501         ;
1502
1503 stateTexGenItem: TEXGEN optTexCoordUnitNum stateTexGenType stateTexGenCoord
1504         {
1505            memset($$, 0, sizeof($$));
1506            $$[0] = STATE_TEXGEN;
1507            $$[1] = $2;
1508            $$[2] = $3 + $4;
1509         }
1510         ;
1511
1512 stateTexGenType: EYE
1513         {
1514            $$ = STATE_TEXGEN_EYE_S;
1515         }
1516         | OBJECT
1517         {
1518            $$ = STATE_TEXGEN_OBJECT_S;
1519         }
1520         ;
1521 stateTexGenCoord: TEXGEN_S
1522         {
1523            $$ = STATE_TEXGEN_EYE_S - STATE_TEXGEN_EYE_S;
1524         }
1525         | TEXGEN_T
1526         {
1527            $$ = STATE_TEXGEN_EYE_T - STATE_TEXGEN_EYE_S;
1528         }
1529         | TEXGEN_R
1530         {
1531            $$ = STATE_TEXGEN_EYE_R - STATE_TEXGEN_EYE_S;
1532         }
1533         | TEXGEN_Q
1534         {
1535            $$ = STATE_TEXGEN_EYE_Q - STATE_TEXGEN_EYE_S;
1536         }
1537         ;
1538
1539 stateFogItem: FOG stateFogProperty
1540         {
1541            memset($$, 0, sizeof($$));
1542            $$[0] = $2;
1543         }
1544         ;
1545
1546 stateFogProperty: COLOR
1547         {
1548            $$ = STATE_FOG_COLOR;
1549         }
1550         | PARAMS
1551         {
1552            $$ = STATE_FOG_PARAMS;
1553         }
1554         ;
1555
1556 stateClipPlaneItem: CLIP '[' stateClipPlaneNum ']' PLANE
1557         {
1558            memset($$, 0, sizeof($$));
1559            $$[0] = STATE_CLIPPLANE;
1560            $$[1] = $3;
1561         }
1562         ;
1563
1564 stateClipPlaneNum: INTEGER
1565         {
1566            if ((unsigned) $1 >= state->MaxClipPlanes) {
1567               yyerror(& @1, state, "invalid clip plane selector");
1568               YYERROR;
1569            }
1570
1571            $$ = $1;
1572         }
1573         ;
1574
1575 statePointItem: POINT_TOK statePointProperty
1576         {
1577            memset($$, 0, sizeof($$));
1578            $$[0] = $2;
1579         }
1580         ;
1581
1582 statePointProperty: SIZE_TOK
1583         {
1584            $$ = STATE_POINT_SIZE;
1585         }
1586         | ATTENUATION
1587         {
1588            $$ = STATE_POINT_ATTENUATION;
1589         }
1590         ;
1591
1592 stateMatrixRow: stateMatrixItem ROW '[' stateMatrixRowNum ']'
1593         {
1594            $$[0] = $1[0];
1595            $$[1] = $1[1];
1596            $$[2] = $4;
1597            $$[3] = $4;
1598            $$[4] = $1[2];
1599         }
1600         ;
1601
1602 stateMatrixRows: stateMatrixItem optMatrixRows
1603         {
1604            $$[0] = $1[0];
1605            $$[1] = $1[1];
1606            $$[2] = $2[2];
1607            $$[3] = $2[3];
1608            $$[4] = $1[2];
1609         }
1610         ;
1611
1612 optMatrixRows:
1613         {
1614            $$[2] = 0;
1615            $$[3] = 3;
1616         }
1617         | ROW '[' stateMatrixRowNum DOT_DOT stateMatrixRowNum ']'
1618         {
1619            /* It seems logical that the matrix row range specifier would have
1620             * to specify a range or more than one row (i.e., $5 > $3).
1621             * However, the ARB_vertex_program spec says "a program will fail
1622             * to load if <a> is greater than <b>."  This means that $3 == $5
1623             * is valid.
1624             */
1625            if ($3 > $5) {
1626               yyerror(& @3, state, "invalid matrix row range");
1627               YYERROR;
1628            }
1629
1630            $$[2] = $3;
1631            $$[3] = $5;
1632         }
1633         ;
1634
1635 stateMatrixItem: MATRIX stateMatrixName stateOptMatModifier
1636         {
1637            $$[0] = $2[0];
1638            $$[1] = $2[1];
1639            $$[2] = $3;
1640         }
1641         ;
1642
1643 stateOptMatModifier:
1644         {
1645            $$ = 0;
1646         }
1647         | stateMatModifier
1648         {
1649            $$ = $1;
1650         }
1651         ;
1652
1653 stateMatModifier: INVERSE
1654         {
1655            $$ = STATE_MATRIX_INVERSE;
1656         }
1657         | TRANSPOSE
1658         {
1659            $$ = STATE_MATRIX_TRANSPOSE;
1660         }
1661         | INVTRANS
1662         {
1663            $$ = STATE_MATRIX_INVTRANS;
1664         }
1665         ;
1666
1667 stateMatrixRowNum: INTEGER
1668         {
1669            if ($1 > 3) {
1670               yyerror(& @1, state, "invalid matrix row reference");
1671               YYERROR;
1672            }
1673
1674            $$ = $1;
1675         }
1676         ;
1677
1678 stateMatrixName: MODELVIEW stateOptModMatNum
1679         {
1680            $$[0] = STATE_MODELVIEW_MATRIX;
1681            $$[1] = $2;
1682         }
1683         | PROJECTION
1684         {
1685            $$[0] = STATE_PROJECTION_MATRIX;
1686            $$[1] = 0;
1687         }
1688         | MVP
1689         {
1690            $$[0] = STATE_MVP_MATRIX;
1691            $$[1] = 0;
1692         }
1693         | TEXTURE optTexCoordUnitNum
1694         {
1695            $$[0] = STATE_TEXTURE_MATRIX;
1696            $$[1] = $2;
1697         }
1698         | PALETTE '[' statePaletteMatNum ']'
1699         {
1700            yyerror(& @1, state, "GL_ARB_matrix_palette not supported");
1701            YYERROR;
1702         }
1703         | MAT_PROGRAM '[' stateProgramMatNum ']'
1704         {
1705            $$[0] = STATE_PROGRAM_MATRIX;
1706            $$[1] = $3;
1707         }
1708         ;
1709
1710 stateOptModMatNum:
1711         {
1712            $$ = 0;
1713         }
1714         | '[' stateModMatNum ']'
1715         {
1716            $$ = $2;
1717         }
1718         ;
1719 stateModMatNum: INTEGER
1720         {
1721            /* Since GL_ARB_vertex_blend isn't supported, only modelview matrix
1722             * zero is valid.
1723             */
1724            if ($1 != 0) {
1725               yyerror(& @1, state, "invalid modelview matrix index");
1726               YYERROR;
1727            }
1728
1729            $$ = $1;
1730         }
1731         ;
1732 statePaletteMatNum: INTEGER
1733         {
1734            /* Since GL_ARB_matrix_palette isn't supported, just let any value
1735             * through here.  The error will be generated later.
1736             */
1737            $$ = $1;
1738         }
1739         ;
1740 stateProgramMatNum: INTEGER
1741         {
1742            if ((unsigned) $1 >= state->MaxProgramMatrices) {
1743               yyerror(& @1, state, "invalid program matrix selector");
1744               YYERROR;
1745            }
1746
1747            $$ = $1;
1748         }
1749         ;
1750
1751 stateDepthItem: DEPTH RANGE
1752         {
1753            memset($$, 0, sizeof($$));
1754            $$[0] = STATE_DEPTH_RANGE;
1755         }
1756         ;
1757
1758
1759 programSingleItem: progEnvParam | progLocalParam;
1760
1761 programMultipleItem: progEnvParams | progLocalParams;
1762
1763 progEnvParams: PROGRAM ENV '[' progEnvParamNums ']'
1764         {
1765            memset($$, 0, sizeof($$));
1766            $$[0] = state->state_param_enum;
1767            $$[1] = STATE_ENV;
1768            $$[2] = $4[0];
1769            $$[3] = $4[1];
1770         }
1771         ;
1772
1773 progEnvParamNums: progEnvParamNum
1774         {
1775            $$[0] = $1;
1776            $$[1] = $1;
1777         }
1778         | progEnvParamNum DOT_DOT progEnvParamNum
1779         {
1780            $$[0] = $1;
1781            $$[1] = $3;
1782         }
1783         ;
1784
1785 progEnvParam: PROGRAM ENV '[' progEnvParamNum ']'
1786         {
1787            memset($$, 0, sizeof($$));
1788            $$[0] = state->state_param_enum;
1789            $$[1] = STATE_ENV;
1790            $$[2] = $4;
1791            $$[3] = $4;
1792         }
1793         ;
1794
1795 progLocalParams: PROGRAM LOCAL '[' progLocalParamNums ']'
1796         {
1797            memset($$, 0, sizeof($$));
1798            $$[0] = state->state_param_enum;
1799            $$[1] = STATE_LOCAL;
1800            $$[2] = $4[0];
1801            $$[3] = $4[1];
1802         }
1803
1804 progLocalParamNums: progLocalParamNum
1805         {
1806            $$[0] = $1;
1807            $$[1] = $1;
1808         }
1809         | progLocalParamNum DOT_DOT progLocalParamNum
1810         {
1811            $$[0] = $1;
1812            $$[1] = $3;
1813         }
1814         ;
1815
1816 progLocalParam: PROGRAM LOCAL '[' progLocalParamNum ']'
1817         {
1818            memset($$, 0, sizeof($$));
1819            $$[0] = state->state_param_enum;
1820            $$[1] = STATE_LOCAL;
1821            $$[2] = $4;
1822            $$[3] = $4;
1823         }
1824         ;
1825
1826 progEnvParamNum: INTEGER
1827         {
1828            if ((unsigned) $1 >= state->limits->MaxEnvParams) {
1829               yyerror(& @1, state, "invalid environment parameter reference");
1830               YYERROR;
1831            }
1832            $$ = $1;
1833         }
1834         ;
1835
1836 progLocalParamNum: INTEGER
1837         {
1838            if ((unsigned) $1 >= state->limits->MaxLocalParams) {
1839               yyerror(& @1, state, "invalid local parameter reference");
1840               YYERROR;
1841            }
1842            $$ = $1;
1843         }
1844         ;
1845
1846
1847
1848 paramConstDecl: paramConstScalarDecl | paramConstVector;
1849 paramConstUse: paramConstScalarUse | paramConstVector;
1850
1851 paramConstScalarDecl: signedFloatConstant
1852         {
1853            $$.count = 4;
1854            $$.data[0].f = $1;
1855            $$.data[1].f = $1;
1856            $$.data[2].f = $1;
1857            $$.data[3].f = $1;
1858         }
1859         ;
1860
1861 paramConstScalarUse: REAL
1862         {
1863            $$.count = 1;
1864            $$.data[0].f = $1;
1865            $$.data[1].f = $1;
1866            $$.data[2].f = $1;
1867            $$.data[3].f = $1;
1868         }
1869         | INTEGER
1870         {
1871            $$.count = 1;
1872            $$.data[0].f = (float) $1;
1873            $$.data[1].f = (float) $1;
1874            $$.data[2].f = (float) $1;
1875            $$.data[3].f = (float) $1;
1876         }
1877         ;
1878
1879 paramConstVector: '{' signedFloatConstant '}'
1880         {
1881            $$.count = 4;
1882            $$.data[0].f = $2;
1883            $$.data[1].f = 0.0f;
1884            $$.data[2].f = 0.0f;
1885            $$.data[3].f = 1.0f;
1886         }
1887         | '{' signedFloatConstant ',' signedFloatConstant '}'
1888         {
1889            $$.count = 4;
1890            $$.data[0].f = $2;
1891            $$.data[1].f = $4;
1892            $$.data[2].f = 0.0f;
1893            $$.data[3].f = 1.0f;
1894         }
1895         | '{' signedFloatConstant ',' signedFloatConstant ','
1896               signedFloatConstant '}'
1897         {
1898            $$.count = 4;
1899            $$.data[0].f = $2;
1900            $$.data[1].f = $4;
1901            $$.data[2].f = $6;
1902            $$.data[3].f = 1.0f;
1903         }
1904         | '{' signedFloatConstant ',' signedFloatConstant ','
1905               signedFloatConstant ',' signedFloatConstant '}'
1906         {
1907            $$.count = 4;
1908            $$.data[0].f = $2;
1909            $$.data[1].f = $4;
1910            $$.data[2].f = $6;
1911            $$.data[3].f = $8;
1912         }
1913         ;
1914
1915 signedFloatConstant: optionalSign REAL
1916         {
1917            $$ = ($1) ? -$2 : $2;
1918         }
1919         | optionalSign INTEGER
1920         {
1921            $$ = (float)(($1) ? -$2 : $2);
1922         }
1923         ;
1924
1925 optionalSign: '+'        { $$ = FALSE; }
1926         | '-'            { $$ = TRUE;  }
1927         |                { $$ = FALSE; }
1928         ;
1929
1930 TEMP_statement: optVarSize TEMP { $<integer>$ = $2; } varNameList
1931         ;
1932
1933 optVarSize: string
1934         {
1935            /* NV_fragment_program_option defines the size qualifiers in a
1936             * fairly broken way.  "SHORT" or "LONG" can optionally be used
1937             * before TEMP or OUTPUT.  However, neither is a reserved word!
1938             * This means that we have to parse it as an identifier, then check
1939             * to make sure it's one of the valid values.  *sigh*
1940             *
1941             * In addition, the grammar in the extension spec does *not* allow
1942             * the size specifier to be optional, but all known implementations
1943             * do.
1944             */
1945            if (!state->option.NV_fragment) {
1946               yyerror(& @1, state, "unexpected IDENTIFIER");
1947               YYERROR;
1948            }
1949
1950            if (strcmp("SHORT", $1) == 0) {
1951            } else if (strcmp("LONG", $1) == 0) {
1952            } else {
1953               char *const err_str =
1954                  make_error_string("invalid storage size specifier \"%s\"",
1955                                    $1);
1956
1957               yyerror(& @1, state, (err_str != NULL)
1958                       ? err_str : "invalid storage size specifier");
1959
1960               if (err_str != NULL) {
1961                  free(err_str);
1962               }
1963
1964               YYERROR;
1965            }
1966         }
1967         |
1968         {
1969         }
1970         ;
1971
1972 ADDRESS_statement: ADDRESS { $<integer>$ = $1; } varNameList
1973         ;
1974
1975 varNameList: varNameList ',' IDENTIFIER
1976         {
1977            if (!declare_variable(state, $3, $<integer>0, & @3)) {
1978               free($3);
1979               YYERROR;
1980            }
1981         }
1982         | IDENTIFIER
1983         {
1984            if (!declare_variable(state, $1, $<integer>0, & @1)) {
1985               free($1);
1986               YYERROR;
1987            }
1988         }
1989         ;
1990
1991 OUTPUT_statement: optVarSize OUTPUT IDENTIFIER '=' resultBinding
1992         {
1993            struct asm_symbol *const s =
1994               declare_variable(state, $3, at_output, & @3);
1995
1996            if (s == NULL) {
1997               free($3);
1998               YYERROR;
1999            } else {
2000               s->output_binding = $5;
2001            }
2002         }
2003         ;
2004
2005 resultBinding: RESULT POSITION
2006         {
2007            if (state->mode == ARB_vertex) {
2008               $$ = VARYING_SLOT_POS;
2009            } else {
2010               yyerror(& @2, state, "invalid program result name");
2011               YYERROR;
2012            }
2013         }
2014         | RESULT FOGCOORD
2015         {
2016            if (state->mode == ARB_vertex) {
2017               $$ = VARYING_SLOT_FOGC;
2018            } else {
2019               yyerror(& @2, state, "invalid program result name");
2020               YYERROR;
2021            }
2022         }
2023         | RESULT resultColBinding
2024         {
2025            $$ = $2;
2026         }
2027         | RESULT POINTSIZE
2028         {
2029            if (state->mode == ARB_vertex) {
2030               $$ = VARYING_SLOT_PSIZ;
2031            } else {
2032               yyerror(& @2, state, "invalid program result name");
2033               YYERROR;
2034            }
2035         }
2036         | RESULT TEXCOORD optTexCoordUnitNum
2037         {
2038            if (state->mode == ARB_vertex) {
2039               $$ = VARYING_SLOT_TEX0 + $3;
2040            } else {
2041               yyerror(& @2, state, "invalid program result name");
2042               YYERROR;
2043            }
2044         }
2045         | RESULT DEPTH
2046         {
2047            if (state->mode == ARB_fragment) {
2048               $$ = FRAG_RESULT_DEPTH;
2049            } else {
2050               yyerror(& @2, state, "invalid program result name");
2051               YYERROR;
2052            }
2053         }
2054         ;
2055
2056 resultColBinding: COLOR optResultFaceType optResultColorType
2057         {
2058            $$ = $2 + $3;
2059         }
2060         ;
2061
2062 optResultFaceType:
2063         {
2064            if (state->mode == ARB_vertex) {
2065               $$ = VARYING_SLOT_COL0;
2066            } else {
2067               if (state->option.DrawBuffers)
2068                  $$ = FRAG_RESULT_DATA0;
2069               else
2070                  $$ = FRAG_RESULT_COLOR;
2071            }
2072         }
2073         | '[' INTEGER ']'
2074         {
2075            if (state->mode == ARB_vertex) {
2076               yyerror(& @1, state, "invalid program result name");
2077               YYERROR;
2078            } else {
2079               if (!state->option.DrawBuffers) {
2080                  /* From the ARB_draw_buffers spec (same text exists
2081                   * for ATI_draw_buffers):
2082                   *
2083                   *     If this option is not specified, a fragment
2084                   *     program that attempts to bind
2085                   *     "result.color[n]" will fail to load, and only
2086                   *     "result.color" will be allowed.
2087                   */
2088                  yyerror(& @1, state,
2089                          "result.color[] used without "
2090                          "`OPTION ARB_draw_buffers' or "
2091                          "`OPTION ATI_draw_buffers'");
2092                  YYERROR;
2093               } else if ($2 >= state->MaxDrawBuffers) {
2094                  yyerror(& @1, state,
2095                          "result.color[] exceeds MAX_DRAW_BUFFERS_ARB");
2096                  YYERROR;
2097               }
2098               $$ = FRAG_RESULT_DATA0 + $2;
2099            }
2100         }
2101         | FRONT
2102         {
2103            if (state->mode == ARB_vertex) {
2104               $$ = VARYING_SLOT_COL0;
2105            } else {
2106               yyerror(& @1, state, "invalid program result name");
2107               YYERROR;
2108            }
2109         }
2110         | BACK
2111         {
2112            if (state->mode == ARB_vertex) {
2113               $$ = VARYING_SLOT_BFC0;
2114            } else {
2115               yyerror(& @1, state, "invalid program result name");
2116               YYERROR;
2117            }
2118         }
2119         ;
2120
2121 optResultColorType:
2122         {
2123            $$ = 0;
2124         }
2125         | PRIMARY
2126         {
2127            if (state->mode == ARB_vertex) {
2128               $$ = 0;
2129            } else {
2130               yyerror(& @1, state, "invalid program result name");
2131               YYERROR;
2132            }
2133         }
2134         | SECONDARY
2135         {
2136            if (state->mode == ARB_vertex) {
2137               $$ = 1;
2138            } else {
2139               yyerror(& @1, state, "invalid program result name");
2140               YYERROR;
2141            }
2142         }
2143         ;
2144
2145 optFaceType:    { $$ = 0; }
2146         | FRONT { $$ = 0; }
2147         | BACK  { $$ = 1; }
2148         ;
2149
2150 optColorType:       { $$ = 0; }
2151         | PRIMARY   { $$ = 0; }
2152         | SECONDARY { $$ = 1; }
2153         ;
2154
2155 optTexCoordUnitNum:                { $$ = 0; }
2156         | '[' texCoordUnitNum ']'  { $$ = $2; }
2157         ;
2158
2159 optTexImageUnitNum:                { $$ = 0; }
2160         | '[' texImageUnitNum ']'  { $$ = $2; }
2161         ;
2162
2163 optLegacyTexUnitNum:               { $$ = 0; }
2164         | '[' legacyTexUnitNum ']' { $$ = $2; }
2165         ;
2166
2167 texCoordUnitNum: INTEGER
2168         {
2169            if ((unsigned) $1 >= state->MaxTextureCoordUnits) {
2170               yyerror(& @1, state, "invalid texture coordinate unit selector");
2171               YYERROR;
2172            }
2173
2174            $$ = $1;
2175         }
2176         ;
2177
2178 texImageUnitNum: INTEGER
2179         {
2180            if ((unsigned) $1 >= state->MaxTextureImageUnits) {
2181               yyerror(& @1, state, "invalid texture image unit selector");
2182               YYERROR;
2183            }
2184
2185            $$ = $1;
2186         }
2187         ;
2188
2189 legacyTexUnitNum: INTEGER
2190         {
2191            if ((unsigned) $1 >= state->MaxTextureUnits) {
2192               yyerror(& @1, state, "invalid texture unit selector");
2193               YYERROR;
2194            }
2195
2196            $$ = $1;
2197         }
2198         ;
2199
2200 ALIAS_statement: ALIAS IDENTIFIER '=' USED_IDENTIFIER
2201         {
2202            struct asm_symbol *exist = (struct asm_symbol *)
2203               _mesa_symbol_table_find_symbol(state->st, 0, $2);
2204            struct asm_symbol *target = (struct asm_symbol *)
2205               _mesa_symbol_table_find_symbol(state->st, 0, $4);
2206
2207            free($4);
2208
2209            if (exist != NULL) {
2210               char m[1000];
2211               _mesa_snprintf(m, sizeof(m), "redeclared identifier: %s", $2);
2212               free($2);
2213               yyerror(& @2, state, m);
2214               YYERROR;
2215            } else if (target == NULL) {
2216               free($2);
2217               yyerror(& @4, state,
2218                       "undefined variable binding in ALIAS statement");
2219               YYERROR;
2220            } else {
2221               _mesa_symbol_table_add_symbol(state->st, 0, $2, target);
2222            }
2223         }
2224         ;
2225
2226 string: IDENTIFIER
2227         | USED_IDENTIFIER
2228         ;
2229
2230 %%
2231
2232 void
2233 asm_instruction_set_operands(struct asm_instruction *inst,
2234                              const struct prog_dst_register *dst,
2235                              const struct asm_src_register *src0,
2236                              const struct asm_src_register *src1,
2237                              const struct asm_src_register *src2)
2238 {
2239    /* In the core ARB extensions only the KIL instruction doesn't have a
2240     * destination register.
2241     */
2242    if (dst == NULL) {
2243       init_dst_reg(& inst->Base.DstReg);
2244    } else {
2245       inst->Base.DstReg = *dst;
2246    }
2247
2248    /* The only instruction that doesn't have any source registers is the
2249     * condition-code based KIL instruction added by NV_fragment_program_option.
2250     */
2251    if (src0 != NULL) {
2252       inst->Base.SrcReg[0] = src0->Base;
2253       inst->SrcReg[0] = *src0;
2254    } else {
2255       init_src_reg(& inst->SrcReg[0]);
2256    }
2257
2258    if (src1 != NULL) {
2259       inst->Base.SrcReg[1] = src1->Base;
2260       inst->SrcReg[1] = *src1;
2261    } else {
2262       init_src_reg(& inst->SrcReg[1]);
2263    }
2264
2265    if (src2 != NULL) {
2266       inst->Base.SrcReg[2] = src2->Base;
2267       inst->SrcReg[2] = *src2;
2268    } else {
2269       init_src_reg(& inst->SrcReg[2]);
2270    }
2271 }
2272
2273
2274 struct asm_instruction *
2275 asm_instruction_ctor(gl_inst_opcode op,
2276                      const struct prog_dst_register *dst,
2277                      const struct asm_src_register *src0,
2278                      const struct asm_src_register *src1,
2279                      const struct asm_src_register *src2)
2280 {
2281    struct asm_instruction *inst = CALLOC_STRUCT(asm_instruction);
2282
2283    if (inst) {
2284       _mesa_init_instructions(& inst->Base, 1);
2285       inst->Base.Opcode = op;
2286
2287       asm_instruction_set_operands(inst, dst, src0, src1, src2);
2288    }
2289
2290    return inst;
2291 }
2292
2293
2294 struct asm_instruction *
2295 asm_instruction_copy_ctor(const struct prog_instruction *base,
2296                           const struct prog_dst_register *dst,
2297                           const struct asm_src_register *src0,
2298                           const struct asm_src_register *src1,
2299                           const struct asm_src_register *src2)
2300 {
2301    struct asm_instruction *inst = CALLOC_STRUCT(asm_instruction);
2302
2303    if (inst) {
2304       _mesa_init_instructions(& inst->Base, 1);
2305       inst->Base.Opcode = base->Opcode;
2306       inst->Base.CondUpdate = base->CondUpdate;
2307       inst->Base.CondDst = base->CondDst;
2308       inst->Base.SaturateMode = base->SaturateMode;
2309       inst->Base.Precision = base->Precision;
2310
2311       asm_instruction_set_operands(inst, dst, src0, src1, src2);
2312    }
2313
2314    return inst;
2315 }
2316
2317
2318 void
2319 init_dst_reg(struct prog_dst_register *r)
2320 {
2321    memset(r, 0, sizeof(*r));
2322    r->File = PROGRAM_UNDEFINED;
2323    r->WriteMask = WRITEMASK_XYZW;
2324    r->CondMask = COND_TR;
2325    r->CondSwizzle = SWIZZLE_NOOP;
2326 }
2327
2328
2329 /** Like init_dst_reg() but set the File and Index fields. */
2330 void
2331 set_dst_reg(struct prog_dst_register *r, gl_register_file file, GLint index)
2332 {
2333    const GLint maxIndex = 1 << INST_INDEX_BITS;
2334    const GLint minIndex = 0;
2335    ASSERT(index >= minIndex);
2336    (void) minIndex;
2337    ASSERT(index <= maxIndex);
2338    (void) maxIndex;
2339    ASSERT(file == PROGRAM_TEMPORARY ||
2340           file == PROGRAM_ADDRESS ||
2341           file == PROGRAM_OUTPUT);
2342    memset(r, 0, sizeof(*r));
2343    r->File = file;
2344    r->Index = index;
2345    r->WriteMask = WRITEMASK_XYZW;
2346    r->CondMask = COND_TR;
2347    r->CondSwizzle = SWIZZLE_NOOP;
2348 }
2349
2350
2351 void
2352 init_src_reg(struct asm_src_register *r)
2353 {
2354    memset(r, 0, sizeof(*r));
2355    r->Base.File = PROGRAM_UNDEFINED;
2356    r->Base.Swizzle = SWIZZLE_NOOP;
2357    r->Symbol = NULL;
2358 }
2359
2360
2361 /** Like init_src_reg() but set the File and Index fields.
2362  * \return GL_TRUE if a valid src register, GL_FALSE otherwise
2363  */
2364 void
2365 set_src_reg(struct asm_src_register *r, gl_register_file file, GLint index)
2366 {
2367    set_src_reg_swz(r, file, index, SWIZZLE_XYZW);
2368 }
2369
2370
2371 void
2372 set_src_reg_swz(struct asm_src_register *r, gl_register_file file, GLint index,
2373                 GLuint swizzle)
2374 {
2375    const GLint maxIndex = (1 << INST_INDEX_BITS) - 1;
2376    const GLint minIndex = -(1 << INST_INDEX_BITS);
2377    ASSERT(file < PROGRAM_FILE_MAX);
2378    ASSERT(index >= minIndex);
2379    (void) minIndex;
2380    ASSERT(index <= maxIndex);
2381    (void) maxIndex;
2382    memset(r, 0, sizeof(*r));
2383    r->Base.File = file;
2384    r->Base.Index = index;
2385    r->Base.Swizzle = swizzle;
2386    r->Symbol = NULL;
2387 }
2388
2389
2390 /**
2391  * Validate the set of inputs used by a program
2392  *
2393  * Validates that legal sets of inputs are used by the program.  In this case
2394  * "used" included both reading the input or binding the input to a name using
2395  * the \c ATTRIB command.
2396  *
2397  * \return
2398  * \c TRUE if the combination of inputs used is valid, \c FALSE otherwise.
2399  */
2400 int
2401 validate_inputs(struct YYLTYPE *locp, struct asm_parser_state *state)
2402 {
2403    const GLbitfield64 inputs = state->prog->InputsRead | state->InputsBound;
2404
2405    if (((inputs & VERT_BIT_FF_ALL) & (inputs >> VERT_ATTRIB_GENERIC0)) != 0) {
2406       yyerror(locp, state, "illegal use of generic attribute and name attribute");
2407       return 0;
2408    }
2409
2410    return 1;
2411 }
2412
2413
2414 struct asm_symbol *
2415 declare_variable(struct asm_parser_state *state, char *name, enum asm_type t,
2416                  struct YYLTYPE *locp)
2417 {
2418    struct asm_symbol *s = NULL;
2419    struct asm_symbol *exist = (struct asm_symbol *)
2420       _mesa_symbol_table_find_symbol(state->st, 0, name);
2421
2422
2423    if (exist != NULL) {
2424       yyerror(locp, state, "redeclared identifier");
2425    } else {
2426       s = calloc(1, sizeof(struct asm_symbol));
2427       s->name = name;
2428       s->type = t;
2429
2430       switch (t) {
2431       case at_temp:
2432          if (state->prog->NumTemporaries >= state->limits->MaxTemps) {
2433             yyerror(locp, state, "too many temporaries declared");
2434             free(s);
2435             return NULL;
2436          }
2437
2438          s->temp_binding = state->prog->NumTemporaries;
2439          state->prog->NumTemporaries++;
2440          break;
2441
2442       case at_address:
2443          if (state->prog->NumAddressRegs >= state->limits->MaxAddressRegs) {
2444             yyerror(locp, state, "too many address registers declared");
2445             free(s);
2446             return NULL;
2447          }
2448
2449          /* FINISHME: Add support for multiple address registers.
2450           */
2451          state->prog->NumAddressRegs++;
2452          break;
2453
2454       default:
2455          break;
2456       }
2457
2458       _mesa_symbol_table_add_symbol(state->st, 0, s->name, s);
2459       s->next = state->sym;
2460       state->sym = s;
2461    }
2462
2463    return s;
2464 }
2465
2466
2467 int add_state_reference(struct gl_program_parameter_list *param_list,
2468                         const gl_state_index tokens[STATE_LENGTH])
2469 {
2470    const GLuint size = 4; /* XXX fix */
2471    char *name;
2472    GLint index;
2473
2474    name = _mesa_program_state_string(tokens);
2475    index = _mesa_add_parameter(param_list, PROGRAM_STATE_VAR, name,
2476                                size, GL_NONE, NULL, tokens);
2477    param_list->StateFlags |= _mesa_program_state_flags(tokens);
2478
2479    /* free name string here since we duplicated it in add_parameter() */
2480    free(name);
2481
2482    return index;
2483 }
2484
2485
2486 int
2487 initialize_symbol_from_state(struct gl_program *prog,
2488                              struct asm_symbol *param_var,
2489                              const gl_state_index tokens[STATE_LENGTH])
2490 {
2491    int idx = -1;
2492    gl_state_index state_tokens[STATE_LENGTH];
2493
2494
2495    memcpy(state_tokens, tokens, sizeof(state_tokens));
2496
2497    param_var->type = at_param;
2498    param_var->param_binding_type = PROGRAM_STATE_VAR;
2499
2500    /* If we are adding a STATE_MATRIX that has multiple rows, we need to
2501     * unroll it and call add_state_reference() for each row
2502     */
2503    if ((state_tokens[0] == STATE_MODELVIEW_MATRIX ||
2504         state_tokens[0] == STATE_PROJECTION_MATRIX ||
2505         state_tokens[0] == STATE_MVP_MATRIX ||
2506         state_tokens[0] == STATE_TEXTURE_MATRIX ||
2507         state_tokens[0] == STATE_PROGRAM_MATRIX)
2508        && (state_tokens[2] != state_tokens[3])) {
2509       int row;
2510       const int first_row = state_tokens[2];
2511       const int last_row = state_tokens[3];
2512
2513       for (row = first_row; row <= last_row; row++) {
2514          state_tokens[2] = state_tokens[3] = row;
2515
2516          idx = add_state_reference(prog->Parameters, state_tokens);
2517          if (param_var->param_binding_begin == ~0U) {
2518             param_var->param_binding_begin = idx;
2519             param_var->param_binding_swizzle = SWIZZLE_XYZW;
2520          }
2521
2522          param_var->param_binding_length++;
2523       }
2524    }
2525    else {
2526       idx = add_state_reference(prog->Parameters, state_tokens);
2527       if (param_var->param_binding_begin == ~0U) {
2528          param_var->param_binding_begin = idx;
2529          param_var->param_binding_swizzle = SWIZZLE_XYZW;
2530       }
2531       param_var->param_binding_length++;
2532    }
2533
2534    return idx;
2535 }
2536
2537
2538 int
2539 initialize_symbol_from_param(struct gl_program *prog,
2540                              struct asm_symbol *param_var,
2541                              const gl_state_index tokens[STATE_LENGTH])
2542 {
2543    int idx = -1;
2544    gl_state_index state_tokens[STATE_LENGTH];
2545
2546
2547    memcpy(state_tokens, tokens, sizeof(state_tokens));
2548
2549    assert((state_tokens[0] == STATE_VERTEX_PROGRAM)
2550           || (state_tokens[0] == STATE_FRAGMENT_PROGRAM));
2551    assert((state_tokens[1] == STATE_ENV)
2552           || (state_tokens[1] == STATE_LOCAL));
2553
2554    /*
2555     * The param type is STATE_VAR.  The program parameter entry will
2556     * effectively be a pointer into the LOCAL or ENV parameter array.
2557     */
2558    param_var->type = at_param;
2559    param_var->param_binding_type = PROGRAM_STATE_VAR;
2560
2561    /* If we are adding a STATE_ENV or STATE_LOCAL that has multiple elements,
2562     * we need to unroll it and call add_state_reference() for each row
2563     */
2564    if (state_tokens[2] != state_tokens[3]) {
2565       int row;
2566       const int first_row = state_tokens[2];
2567       const int last_row = state_tokens[3];
2568
2569       for (row = first_row; row <= last_row; row++) {
2570          state_tokens[2] = state_tokens[3] = row;
2571
2572          idx = add_state_reference(prog->Parameters, state_tokens);
2573          if (param_var->param_binding_begin == ~0U) {
2574             param_var->param_binding_begin = idx;
2575             param_var->param_binding_swizzle = SWIZZLE_XYZW;
2576          }
2577          param_var->param_binding_length++;
2578       }
2579    }
2580    else {
2581       idx = add_state_reference(prog->Parameters, state_tokens);
2582       if (param_var->param_binding_begin == ~0U) {
2583          param_var->param_binding_begin = idx;
2584          param_var->param_binding_swizzle = SWIZZLE_XYZW;
2585       }
2586       param_var->param_binding_length++;
2587    }
2588
2589    return idx;
2590 }
2591
2592
2593 /**
2594  * Put a float/vector constant/literal into the parameter list.
2595  * \param param_var  returns info about the parameter/constant's location,
2596  *                   binding, type, etc.
2597  * \param vec  the vector/constant to add
2598  * \param allowSwizzle  if true, try to consolidate constants which only differ
2599  *                      by a swizzle.  We don't want to do this when building
2600  *                      arrays of constants that may be indexed indirectly.
2601  * \return index of the constant in the parameter list.
2602  */
2603 int
2604 initialize_symbol_from_const(struct gl_program *prog,
2605                              struct asm_symbol *param_var,
2606                              const struct asm_vector *vec,
2607                              GLboolean allowSwizzle)
2608 {
2609    unsigned swizzle;
2610    const int idx = _mesa_add_unnamed_constant(prog->Parameters,
2611                                               vec->data, vec->count,
2612                                               allowSwizzle ? &swizzle : NULL);
2613
2614    param_var->type = at_param;
2615    param_var->param_binding_type = PROGRAM_CONSTANT;
2616
2617    if (param_var->param_binding_begin == ~0U) {
2618       param_var->param_binding_begin = idx;
2619       param_var->param_binding_swizzle = allowSwizzle ? swizzle : SWIZZLE_XYZW;
2620    }
2621    param_var->param_binding_length++;
2622
2623    return idx;
2624 }
2625
2626
2627 char *
2628 make_error_string(const char *fmt, ...)
2629 {
2630    int length;
2631    char *str;
2632    va_list args;
2633
2634
2635    /* Call vsnprintf once to determine how large the final string is.  Call it
2636     * again to do the actual formatting.  from the vsnprintf manual page:
2637     *
2638     *    Upon successful return, these functions return the number of
2639     *    characters printed  (not including the trailing '\0' used to end
2640     *    output to strings).
2641     */
2642    va_start(args, fmt);
2643    length = 1 + vsnprintf(NULL, 0, fmt, args);
2644    va_end(args);
2645
2646    str = malloc(length);
2647    if (str) {
2648       va_start(args, fmt);
2649       vsnprintf(str, length, fmt, args);
2650       va_end(args);
2651    }
2652
2653    return str;
2654 }
2655
2656
2657 void
2658 yyerror(YYLTYPE *locp, struct asm_parser_state *state, const char *s)
2659 {
2660    char *err_str;
2661
2662
2663    err_str = make_error_string("glProgramStringARB(%s)\n", s);
2664    if (err_str) {
2665       _mesa_error(state->ctx, GL_INVALID_OPERATION, "%s", err_str);
2666       free(err_str);
2667    }
2668
2669    err_str = make_error_string("line %u, char %u: error: %s\n",
2670                                locp->first_line, locp->first_column, s);
2671    _mesa_set_program_error(state->ctx, locp->position, err_str);
2672
2673    if (err_str) {
2674       free(err_str);
2675    }
2676 }
2677
2678
2679 GLboolean
2680 _mesa_parse_arb_program(struct gl_context *ctx, GLenum target, const GLubyte *str,
2681                         GLsizei len, struct asm_parser_state *state)
2682 {
2683    struct asm_instruction *inst;
2684    unsigned i;
2685    GLubyte *strz;
2686    GLboolean result = GL_FALSE;
2687    void *temp;
2688    struct asm_symbol *sym;
2689
2690    state->ctx = ctx;
2691    state->prog->Target = target;
2692    state->prog->Parameters = _mesa_new_parameter_list();
2693
2694    /* Make a copy of the program string and force it to be NUL-terminated.
2695     */
2696    strz = (GLubyte *) malloc(len + 1);
2697    if (strz == NULL) {
2698       _mesa_error(ctx, GL_OUT_OF_MEMORY, "glProgramStringARB");
2699       return GL_FALSE;
2700    }
2701    memcpy (strz, str, len);
2702    strz[len] = '\0';
2703
2704    state->prog->String = strz;
2705
2706    state->st = _mesa_symbol_table_ctor();
2707
2708    state->limits = (target == GL_VERTEX_PROGRAM_ARB)
2709       ? & ctx->Const.VertexProgram
2710       : & ctx->Const.FragmentProgram;
2711
2712    state->MaxTextureImageUnits = ctx->Const.MaxTextureImageUnits;
2713    state->MaxTextureCoordUnits = ctx->Const.MaxTextureCoordUnits;
2714    state->MaxTextureUnits = ctx->Const.MaxTextureUnits;
2715    state->MaxClipPlanes = ctx->Const.MaxClipPlanes;
2716    state->MaxLights = ctx->Const.MaxLights;
2717    state->MaxProgramMatrices = ctx->Const.MaxProgramMatrices;
2718    state->MaxDrawBuffers = ctx->Const.MaxDrawBuffers;
2719
2720    state->state_param_enum = (target == GL_VERTEX_PROGRAM_ARB)
2721       ? STATE_VERTEX_PROGRAM : STATE_FRAGMENT_PROGRAM;
2722
2723    _mesa_set_program_error(ctx, -1, NULL);
2724
2725    _mesa_program_lexer_ctor(& state->scanner, state, (const char *) str, len);
2726    yyparse(state);
2727    _mesa_program_lexer_dtor(state->scanner);
2728
2729
2730    if (ctx->Program.ErrorPos != -1) {
2731       goto error;
2732    }
2733
2734    if (! _mesa_layout_parameters(state)) {
2735       struct YYLTYPE loc;
2736
2737       loc.first_line = 0;
2738       loc.first_column = 0;
2739       loc.position = len;
2740
2741       yyerror(& loc, state, "invalid PARAM usage");
2742       goto error;
2743    }
2744
2745
2746
2747    /* Add one instruction to store the "END" instruction.
2748     */
2749    state->prog->Instructions =
2750       _mesa_alloc_instructions(state->prog->NumInstructions + 1);
2751    inst = state->inst_head;
2752    for (i = 0; i < state->prog->NumInstructions; i++) {
2753       struct asm_instruction *const temp = inst->next;
2754
2755       state->prog->Instructions[i] = inst->Base;
2756       inst = temp;
2757    }
2758
2759    /* Finally, tag on an OPCODE_END instruction */
2760    {
2761       const GLuint numInst = state->prog->NumInstructions;
2762       _mesa_init_instructions(state->prog->Instructions + numInst, 1);
2763       state->prog->Instructions[numInst].Opcode = OPCODE_END;
2764    }
2765    state->prog->NumInstructions++;
2766
2767    state->prog->NumParameters = state->prog->Parameters->NumParameters;
2768    state->prog->NumAttributes = _mesa_bitcount_64(state->prog->InputsRead);
2769
2770    /*
2771     * Initialize native counts to logical counts.  The device driver may
2772     * change them if program is translated into a hardware program.
2773     */
2774    state->prog->NumNativeInstructions = state->prog->NumInstructions;
2775    state->prog->NumNativeTemporaries = state->prog->NumTemporaries;
2776    state->prog->NumNativeParameters = state->prog->NumParameters;
2777    state->prog->NumNativeAttributes = state->prog->NumAttributes;
2778    state->prog->NumNativeAddressRegs = state->prog->NumAddressRegs;
2779
2780    result = GL_TRUE;
2781
2782 error:
2783    for (inst = state->inst_head; inst != NULL; inst = temp) {
2784       temp = inst->next;
2785       free(inst);
2786    }
2787
2788    state->inst_head = NULL;
2789    state->inst_tail = NULL;
2790
2791    for (sym = state->sym; sym != NULL; sym = temp) {
2792       temp = sym->next;
2793
2794       free((void *) sym->name);
2795       free(sym);
2796    }
2797    state->sym = NULL;
2798
2799    _mesa_symbol_table_dtor(state->st);
2800    state->st = NULL;
2801
2802    return result;
2803 }