litex/soc/software/libbase/linker-sdram.ld

   1 INCLUDE generated/output_format.ld
   2 ENTRY(_start)
   3
   4 __DYNAMIC = 0;
   5
   6 INCLUDE generated/regions.ld
   7
   8 SECTIONS
   9 {
  10         .text :
  11         {
  12                 _ftext = .;
  13                 *(.text .stub .text.* .gnu.linkonce.t.*)
  14                 _etext = .;
  15         } > main_ram
  16
  17         .got :
  18         {
  19                 _GLOBAL_OFFSET_TABLE_ = .;
  20                 *(.got)
  21         } > main_ram
  22
  23         .got.plt :
  24         {
  25                 *(.got.plt)
  26         } > main_ram
  27
  28         .rodata :
  29         {
  30                 . = ALIGN(4);
  31                 _frodata = .;
  32                 *(.rodata .rodata.* .gnu.linkonce.r.*)
  33                 *(.rodata1)
  34                 _erodata = .;
  35         } > main_ram
  36
  37         .data :
  38         {
  39                 . = ALIGN(4);
  40                 _fdata = .;
  41                 *(.data .data.* .gnu.linkonce.d.*)
  42                 *(.data1)
  43                 *(.sdata .sdata.* .gnu.linkonce.s.*)
  44                 _edata = .;
  45         } > main_ram
  46
  47         .bss :
  48         {
  49                 . = ALIGN(4);
  50                 _fbss = .;
  51                 *(.dynsbss)
  52                 *(.sbss .sbss.* .gnu.linkonce.sb.*)
  53                 *(.scommon)
  54                 *(.dynbss)
  55                 *(.bss .bss.* .gnu.linkonce.b.*)
  56                 *(COMMON)
  57                 . = ALIGN(4);
  58                 _ebss = .;
  59                 . = ALIGN(8);
  60                 _heapstart = .;
  61         } > main_ram
  62 }
  63
  64 PROVIDE(_fstack = ORIGIN(main_ram) + LENGTH(main_ram) - 4);