openpower/isa/simplev.mdwn

   1 <!-- This defines Draft SVP64 instructions to augment PowerISA Version 3.0 -->
   2 <!-- These are not described in book 1 -->
   3
   4 # svstep
   5
   6 SVL-Form
   7
   8 * svstep RT,SVi,vf
   9 * svstep. RT,SVi,vf
  10
  11 Pseudo-code:
  12
  13     step <- SVSTATE_NEXT(SVi, vf)
  14     RT <- [0]*57 || step
  15
  16 Special Registers Altered:
  17
  18     CR0                     (if Rc=1)
  19
  20 # setvl
  21
  22 SVL-Form
  23
  24 * setvl RT,RA,SVi,vf,vs,ms
  25 * setvl. RT,RA,SVi,vf,vs,ms
  26
  27 Pseudo-code:
  28
  29     if (vf & (¬vs) & ¬(ms)) = 1 then
  30         step <- SVSTATE_NEXT(SVi, 0b0)
  31         if _RT != 0b00000 then
  32            GPR(_RT) <- [0]*57 || step
  33     else
  34         VLimm <- SVi + 1
  35         if vs = 1 then
  36             if _RA != 0 then
  37                 VL <- (RA|0)[57:63]
  38             else
  39                 VL <- VLimm[0:6]
  40         else
  41             VL <- SVSTATE[7:13]
  42         if ms = 1 then
  43             MVL <- VLimm[0:6]
  44         else
  45             MVL <- SVSTATE[0:6]
  46         if VL > MVL then
  47             VL = MVL
  48         SVSTATE[0:6] <- MVL
  49         SVSTATE[7:13] <- VL
  50         if _RT != 0b00000 then
  51            GPR(_RT) <- [0]*57 || VL
  52         # set requested Vertical-First mode, clear persist
  53         SVSTATE[63] <- vf
  54         SVSTATE[62] <- 0b0
  55
  56 Special Registers Altered:
  57
  58     CR0                     (if Rc=1)
  59
  60 # svremap
  61
  62 SVRM-Form
  63
  64 * svremap SVme,mi0,mi1,mi2,mo0,mo1,pst
  65
  66 Pseudo-code:
  67
  68     # registers RA RB RC RT EA/FRS SVSHAPE0-3 indices
  69     SVSTATE[32:33] <- mi0
  70     SVSTATE[34:35] <- mi1
  71     SVSTATE[36:37] <- mi2
  72     SVSTATE[38:39] <- mo0
  73     SVSTATE[40:41] <- mo1
  74     # enable bit for RA RB RC RT EA/FRS
  75     SVSTATE[42:46] <- SVme
  76     # persistence bit (applies to more than one instruction)
  77     SVSTATE[62] <- pst
  78
  79 Special Registers Altered:
  80
  81     None
  82
  83 # svshape
  84
  85 SVM-Form
  86
  87 * svshape SVxd,SVyd,SVzd,SVRM,vf
  88
  89 Pseudo-code:
  90
  91     # for convenience, VL to be calculated and stored in SVSTATE
  92     vlen <- [0] * 7
  93     itercount[0:6] <- [0] * 7
  94     SVSTATE[0:31] <- [0] * 32
  95     # only overwrite REMAP if "persistence" is zero
  96     if (SVSTATE[62] = 0b0) then
  97         SVSTATE[32:33] <- 0b00
  98         SVSTATE[34:35] <- 0b00
  99         SVSTATE[36:37] <- 0b00
 100         SVSTATE[38:39] <- 0b00
 101         SVSTATE[40:41] <- 0b00
 102         SVSTATE[42:46] <- 0b00000
 103         SVSTATE[62] <- 0b0
 104         SVSTATE[63] <- 0b0
 105     # clear out all SVSHAPEs
 106     SVSHAPE0[0:31] <- [0] * 32
 107     SVSHAPE1[0:31] <- [0] * 32
 108     SVSHAPE2[0:31] <- [0] * 32
 109     SVSHAPE3[0:31] <- [0] * 32
 110     # set schedule up for multiply
 111     if (SVRM = 0b0000) then
 112         # VL in Matrix Multiply is xd*yd*zd
 113         n <- (0b00 || SVxd) * (0b00 || SVyd) * (0b00 || SVzd)
 114         vlen[0:6] <- n[14:20]
 115         # set up template in SVSHAPE0, then copy to 1-3
 116         SVSHAPE0[0:5] <- (0b0 || SVxd)   # xdim
 117         SVSHAPE0[6:11] <- (0b0 || SVyd)   # ydim
 118         SVSHAPE0[12:17] <- (0b0 || SVzd)   # zdim
 119         SVSHAPE0[28:29] <- 0b11           # skip z
 120         # copy
 121         SVSHAPE1[0:31] <- SVSHAPE0[0:31]
 122         SVSHAPE2[0:31] <- SVSHAPE0[0:31]
 123         SVSHAPE3[0:31] <- SVSHAPE0[0:31]
 124         # set up FRA
 125         SVSHAPE1[18:20] <- 0b001          # permute x,z,y
 126         SVSHAPE1[28:29] <- 0b01           # skip z
 127         # FRC
 128         SVSHAPE2[18:20] <- 0b001          # permute x,z,y
 129         SVSHAPE2[28:29] <- 0b11           # skip y
 130     # set schedule up for FFT butterfly
 131     if (SVRM = 0b0001) then
 132         # calculate O(N log2 N)
 133         n <- [0] * 3
 134         do while n < 5
 135            if SVxd[4-n] = 0 then
 136                leave
 137            n <- n + 1
 138         n <- ((0b0 || SVxd) + 1) * n
 139         vlen[0:6] <- n[1:7]
 140         # set up template in SVSHAPE0, then copy to 1-3
 141         # for FRA and FRT
 142         SVSHAPE0[0:5] <- (0b0 || SVxd)   # xdim
 143         SVSHAPE0[30:31] <- 0b01          # Butterfly mode
 144         # copy
 145         SVSHAPE1[0:31] <- SVSHAPE0[0:31]
 146         SVSHAPE2[0:31] <- SVSHAPE0[0:31]
 147         # set up FRB and FRS
 148         SVSHAPE1[28:29] <- 0b01           # j+halfstep schedule
 149         # FRC (coefficients)
 150         SVSHAPE2[28:29] <- 0b10           # k schedule
 151     # set schedule up for DCT Inner butterfly
 152     # SVRM Mode 2 is for pre-calculated coefficients,
 153     # SVRM Mode 4 is for on-the-fly (Vertical-First Mode)
 154     if (SVRM = 0b0010) | (SVRM = 0b0100) then
 155         # calculate O(N log2 N)
 156         n <- [0] * 3
 157         do while n < 5
 158            if SVxd[4-n] = 0 then
 159                leave
 160            n <- n + 1
 161         n <- ((0b0 || SVxd) + 1) * n
 162         vlen[0:6] <- n[1:7]
 163         # set up template in SVSHAPE0, then copy to 1-3
 164         # set up FRB and FRS
 165         SVSHAPE0[0:5] <- (0b0 || SVxd)   # xdim
 166         SVSHAPE0[30:31] <- 0b01          # DCT/FFT mode
 167         #if (SVRM = 0b0100) then
 168         SVSHAPE0[6:11] <- 0b000001       # DCT Inner Butterfly mode
 169         SVSHAPE0[18:20] <- 0b001         # DCT Inner Butterfly sub-mode
 170         SVSHAPE0[21:23] <- 0b001         # "inverse" on outer loop
 171         # copy
 172         SVSHAPE1[0:31] <- SVSHAPE0[0:31]
 173         SVSHAPE2[0:31] <- SVSHAPE0[0:31]
 174         SVSHAPE3[0:31] <- SVSHAPE0[0:31]
 175         # for FRA and FRT
 176         SVSHAPE0[28:29] <- 0b01           # j+halfstep schedule
 177         # for cos coefficient
 178         SVSHAPE2[28:29] <- 0b10           # ci schedule
 179         SVSHAPE3[28:29] <- 0b11           # size schedule
 180     # set schedule up for DCT Outer butterfly
 181     if (SVRM = 0b0011) then
 182         # calculate O(N log2 N) number of outer butterfly overlapping adds
 183         vlen[0:6] <- [0] * 7
 184         n <- 0b000
 185         size <- 0b0000001
 186         itercount[0:6] <- (0b00 || SVxd) + 0b0000001
 187         itercount[0:6] <- (0b0 || itercount[0:5])
 188         do while n < 5
 189            if SVxd[4-n] = 0 then
 190                leave
 191            n <- n + 1
 192            count <- (itercount - 0b0000001) * size
 193            vlen[0:6] <- vlen + count[7:13]
 194            size[0:6] <- (size[1:6] || 0b0)
 195            itercount[0:6] <- (0b0 || itercount[0:5])
 196         # set up template in SVSHAPE0, then copy to 1-3
 197         # set up FRB and FRS
 198         SVSHAPE0[0:5] <- (0b0 || SVxd)   # xdim
 199         SVSHAPE0[30:31] <- 0b01          # DCT/FFT mode
 200         SVSHAPE0[6:11] <- 0b000010       # DCT Butterfly mode
 201         SVSHAPE0[18:20] <- 0b100         # DCT Outer Butterfly sub-mode
 202         # copy
 203         SVSHAPE1[0:31] <- SVSHAPE0[0:31]
 204         SVSHAPE2[0:31] <- SVSHAPE0[0:31]
 205         # for FRA and FRT
 206         SVSHAPE1[28:29] <- 0b01           # j+halfstep schedule
 207     # set schedule up for DCT COS table generation
 208     if (SVRM = 0b0101) then
 209         # calculate O(N log2 N)
 210         vlen[0:6] <- [0] * 7
 211         itercount[0:6] <- (0b00 || SVxd) + 0b0000001
 212         itercount[0:6] <- (0b0 || itercount[0:5])
 213         n <- [0] * 3
 214         do while n < 5
 215            if SVxd[4-n] = 0 then
 216                leave
 217            n <- n + 1
 218            vlen[0:6] <- vlen + itercount
 219            itercount[0:6] <- (0b0 || itercount[0:5])
 220         # set up template in SVSHAPE0, then copy to 1-3
 221         # set up FRB and FRS
 222         SVSHAPE0[0:5] <- (0b0 || SVxd)   # xdim
 223         SVSHAPE0[30:31] <- 0b01          # DCT/FFT mode
 224         SVSHAPE0[6:11] <- 0b000100       # DCT Inner Butterfly COS-gen mode
 225         SVSHAPE0[21:23] <- 0b001         # "inverse" on outer loop
 226         # copy
 227         SVSHAPE1[0:31] <- SVSHAPE0[0:31]
 228         SVSHAPE2[0:31] <- SVSHAPE0[0:31]
 229         # for cos coefficient
 230         SVSHAPE1[28:29] <- 0b10           # ci schedule
 231         SVSHAPE2[28:29] <- 0b11           # size schedule
 232     # set VL, MVL and Vertical-First
 233     SVSTATE[0:6] <- vlen
 234     SVSTATE[7:13] <- vlen
 235     SVSTATE[63] <- vf
 236
 237 Special Registers Altered:
 238
 239     None
 240